m4/remainderl.m4

   1 # remainderl.m4 serial 9
   2 dnl Copyright (C) 2012-2019 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_REMAINDERL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_remainderl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_LONG_DOUBLE_VS_DOUBLE])
  12   AC_REQUIRE([gl_FUNC_REMAINDER])
  13
  14   dnl Persuade glibc <math.h> to declare remainderl().
  15   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  16
  17   dnl Test whether remainderl() exists. Assume that remainderl(), if it exists, is
  18   dnl defined in the same library as remainder().
  19   save_LIBS="$LIBS"
  20   LIBS="$LIBS $REMAINDER_LIBM"
  21   AC_CACHE_CHECK([for remainderl],
  22     [gl_cv_func_remainderl],
  23     [
  24       AC_LINK_IFELSE(
  25         [AC_LANG_PROGRAM(
  26            [[#ifndef __NO_MATH_INLINES
  27              # define __NO_MATH_INLINES 1 /* for glibc */
  28              #endif
  29              #include <math.h>
  30              extern
  31              #ifdef __cplusplus
  32              "C"
  33              #endif
  34              long double remainderl (long double, long double);
  35              long double (*funcptr) (long double, long double) = remainderl;
  36              long double x;
  37              long double y;]],
  38            [[return funcptr (x, y) > 1
  39                     || remainderl (x, y) > 1;]])],
  40         [gl_cv_func_remainderl=yes],
  41         [gl_cv_func_remainderl=no])
  42     ])
  43   LIBS="$save_LIBS"
  44   if test $gl_cv_func_remainderl = yes; then
  45     HAVE_REMAINDERL=1
  46     REMAINDERL_LIBM="$REMAINDER_LIBM"
  47     dnl Also check whether it's declared.
  48     dnl IRIX 6.5 has remainderl() in libm but doesn't declare it in <math.h>.
  49     AC_CHECK_DECLS([remainderl], , [HAVE_DECL_REMAINDERL=0], [[#include <math.h>]])
  50
  51     save_LIBS="$LIBS"
  52     LIBS="$LIBS $REMAINDERL_LIBM"
  53     gl_FUNC_REMAINDERL_WORKS
  54     LIBS="$save_LIBS"
  55     case "$gl_cv_func_remainderl_works" in
  56       *yes) ;;
  57       *) REPLACE_REMAINDERL=1 ;;
  58     esac
  59
  60     m4_ifdef([gl_FUNC_REMAINDERL_IEEE], [
  61       if test $gl_remainderl_required = ieee && test $REPLACE_REMAINDERL = 0; then
  62         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  63         AC_CACHE_CHECK([whether remainderl works according to ISO C 99 with IEC 60559],
  64           [gl_cv_func_remainderl_ieee],
  65           [
  66             save_LIBS="$LIBS"
  67             LIBS="$LIBS $REMAINDERL_LIBM"
  68             AC_RUN_IFELSE(
  69               [AC_LANG_SOURCE([[
  70 #ifndef __NO_MATH_INLINES
  71 # define __NO_MATH_INLINES 1 /* for glibc */
  72 #endif
  73 #include <math.h>
  74 extern
  75 #ifdef __cplusplus
  76 "C"
  77 #endif
  78 long double remainderl (long double, long double);
  79 /* Compare two numbers with ==.
  80    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
  81    'x == x' test.  */
  82 static int
  83 numeric_equal (long double x, long double y)
  84 {
  85   return x == y;
  86 }
  87 static long double dummy (long double x, long double y) { return 0; }
  88 int main (int argc, char *argv[])
  89 {
  90   long double (*my_remainderl) (long double, long double) = argc ? remainderl : dummy;
  91   long double f;
  92   /* Test remainderl(...,0.0L).
  93      This test fails on OSF/1 5.1.  */
  94   f = my_remainderl (2.0L, 0.0L);
  95   if (numeric_equal (f, f))
  96     return 1;
  97   return 0;
  98 }
  99               ]])],
 100               [gl_cv_func_remainderl_ieee=yes],
 101               [gl_cv_func_remainderl_ieee=no],
 102               [case "$host_os" in
 103                                 # Guess yes on glibc systems.
 104                  *-gnu* | gnu*) gl_cv_func_remainderl_ieee="guessing yes" ;;
 105                                 # Guess yes on native Windows.
 106                  mingw*)        gl_cv_func_remainderl_ieee="guessing yes" ;;
 107                                 # If we don't know, assume the worst.
 108                  *)             gl_cv_func_remainderl_ieee="guessing no" ;;
 109                esac
 110               ])
 111             LIBS="$save_LIBS"
 112           ])
 113         case "$gl_cv_func_remainderl_ieee" in
 114           *yes) ;;
 115           *) REPLACE_REMAINDERL=1 ;;
 116         esac
 117       fi
 118     ])
 119   else
 120     HAVE_REMAINDERL=0
 121     HAVE_DECL_REMAINDERL=0
 122   fi
 123   if test $HAVE_REMAINDERL = 0 || test $REPLACE_REMAINDERL = 1; then
 124     dnl Find libraries needed to link lib/remainderl.c.
 125     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
 126       REMAINDERL_LIBM="$REMAINDER_LIBM"
 127     else
 128       AC_REQUIRE([gl_FUNC_FABSL])
 129       AC_REQUIRE([gl_FUNC_FMODL])
 130       AC_REQUIRE([gl_FUNC_ISNANL])
 131       REMAINDERL_LIBM=
 132       dnl Append $FABSL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
 133       case " $REMAINDERL_LIBM " in
 134         *" $FABSL_LIBM "*) ;;
 135         *) REMAINDERL_LIBM="$REMAINDERL_LIBM $FABSL_LIBM" ;;
 136       esac
 137       dnl Append $FMODL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
 138       case " $REMAINDERL_LIBM " in
 139         *" $FMODL_LIBM "*) ;;
 140         *) REMAINDERL_LIBM="$REMAINDERL_LIBM $FMODL_LIBM" ;;
 141       esac
 142       dnl Append $ISNANL_LIBM to REMAINDERL_LIBM, avoiding gratuitous duplicates.
 143       case " $REMAINDERL_LIBM " in
 144         *" $ISNANL_LIBM "*) ;;
 145         *) REMAINDERL_LIBM="$REMAINDERL_LIBM $ISNANL_LIBM" ;;
 146       esac
 147     fi
 148   fi
 149   AC_SUBST([REMAINDERL_LIBM])
 150 ])
 151
 152 dnl Test whether remainderl() works.
 153 dnl It produces completely wrong values on OpenBSD 5.1/SPARC.
 154 AC_DEFUN([gl_FUNC_REMAINDERL_WORKS],
 155 [
 156   AC_REQUIRE([AC_PROG_CC])
 157   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 158   AC_CACHE_CHECK([whether remainderl works], [gl_cv_func_remainderl_works],
 159     [
 160       AC_RUN_IFELSE(
 161         [AC_LANG_SOURCE([[
 162 #ifndef __NO_MATH_INLINES
 163 # define __NO_MATH_INLINES 1 /* for glibc */
 164 #endif
 165 #include <math.h>
 166 extern
 167 #ifdef __cplusplus
 168 "C"
 169 #endif
 170 long double remainderl (long double, long double);
 171 volatile long double x;
 172 volatile long double y;
 173 long double z;
 174 int main ()
 175 {
 176   /* This test fails on OpenBSD 5.1/SPARC.  */
 177   x = 9.245907126L;
 178   y = 3.141592654L;
 179   z = remainderl (x, y);
 180   if (z >= 0.0L)
 181     return 1;
 182   return 0;
 183 }
 184 ]])],
 185         [gl_cv_func_remainderl_works=yes],
 186         [gl_cv_func_remainderl_works=no],
 187         [case "$host_os" in
 188            openbsd*) gl_cv_func_remainderl_works="guessing no" ;;
 189                      # Guess yes on native Windows.
 190            mingw*)   gl_cv_func_remainderl_works="guessing yes" ;;
 191            *)        gl_cv_func_remainderl_works="guessing yes" ;;
 192          esac
 193         ])
 194     ])
 195 ])