m4/ptsname.m4

   1 # ptsname.m4 serial 5
   2 dnl Copyright (C) 2010-2018 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_PTSNAME],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  11
  12   dnl Persuade glibc <stdlib.h> to declare ptsname().
  13   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  14
  15   AC_CHECK_FUNCS([ptsname])
  16   if test $ac_cv_func_ptsname = no; then
  17     HAVE_PTSNAME=0
  18   else
  19     AC_CACHE_CHECK([whether ptsname sets errno on failure],
  20       [gl_cv_func_ptsname_sets_errno],
  21       [AC_RUN_IFELSE(
  22          [AC_LANG_PROGRAM([[#include <errno.h>
  23       ]], [[
  24       return ptsname (-1) || !errno;
  25            ]])],
  26          [gl_cv_func_ptsname_sets_errno=yes],
  27          [gl_cv_func_ptsname_sets_errno=no],
  28          [case "$host_os" in
  29                            # Guess yes on glibc systems.
  30             *-gnu* | gnu*) gl_cv_func_ptsname_sets_errno="guessing yes" ;;
  31                            # If we don't know, assume the worst.
  32             *)             gl_cv_func_ptsname_sets_errno="guessing no" ;;
  33           esac
  34          ])])
  35     case $gl_cv_func_ptsname_sets_errno in
  36       *no) REPLACE_PTSNAME=1 ;;
  37     esac
  38   fi
  39 ])
  40
  41 # Prerequisites of lib/ptsname.c.
  42 AC_DEFUN([gl_PREREQ_PTSNAME], [
  43   :
  44 ])