m4/log.m4

   1 # log.m4 serial 7
   2 dnl Copyright (C) 2011-2018 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_LOG],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_log_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11
  12   dnl Determine LOG_LIBM.
  13   gl_COMMON_DOUBLE_MATHFUNC([log])
  14
  15   save_LIBS="$LIBS"
  16   LIBS="$LIBS $LOG_LIBM"
  17   gl_FUNC_LOG_WORKS
  18   LIBS="$save_LIBS"
  19   case "$gl_cv_func_log_works" in
  20     *yes) ;;
  21     *) REPLACE_LOG=1 ;;
  22   esac
  23
  24   m4_ifdef([gl_FUNC_LOG_IEEE], [
  25     if test $gl_log_required = ieee && test $REPLACE_LOG = 0; then
  26       AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  27       AC_CACHE_CHECK([whether log works according to ISO C 99 with IEC 60559],
  28         [gl_cv_func_log_ieee],
  29         [
  30           save_LIBS="$LIBS"
  31           LIBS="$LIBS $LOG_LIBM"
  32           AC_RUN_IFELSE(
  33             [AC_LANG_SOURCE([[
  34 #ifndef __NO_MATH_INLINES
  35 # define __NO_MATH_INLINES 1 /* for glibc */
  36 #endif
  37 #include <math.h>
  38 /* Compare two numbers with ==.
  39    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
  40    'x == x' test.  */
  41 static int
  42 numeric_equal (double x, double y)
  43 {
  44   return x == y;
  45 }
  46 static double dummy (double x) { return 0; }
  47 int main (int argc, char *argv[])
  48 {
  49   double (*my_log) (double) = argc ? log : dummy;
  50   /* Test log(negative).
  51      This test fails on NetBSD 5.1, Solaris 11.0.  */
  52   double y = my_log (-1.0);
  53   if (numeric_equal (y, y))
  54     return 1;
  55   return 0;
  56 }
  57             ]])],
  58             [gl_cv_func_log_ieee=yes],
  59             [gl_cv_func_log_ieee=no],
  60             [case "$host_os" in
  61                               # Guess yes on glibc systems.
  62                *-gnu* | gnu*) gl_cv_func_log_ieee="guessing yes" ;;
  63                               # Guess yes on native Windows.
  64                mingw*)        gl_cv_func_log_ieee="guessing yes" ;;
  65                               # If we don't know, assume the worst.
  66                *)             gl_cv_func_log_ieee="guessing no" ;;
  67              esac
  68             ])
  69           LIBS="$save_LIBS"
  70         ])
  71       case "$gl_cv_func_log_ieee" in
  72         *yes) ;;
  73         *) REPLACE_LOG=1 ;;
  74       esac
  75     fi
  76   ])
  77 ])
  78
  79 dnl Test whether log() works.
  80 dnl On OSF/1 5.1, log(-0.0) is NaN.
  81 AC_DEFUN([gl_FUNC_LOG_WORKS],
  82 [
  83   AC_REQUIRE([AC_PROG_CC])
  84   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  85   AC_CACHE_CHECK([whether log works], [gl_cv_func_log_works],
  86     [
  87       AC_RUN_IFELSE(
  88         [AC_LANG_SOURCE([[
  89 #include <math.h>
  90 volatile double x;
  91 double y;
  92 int main ()
  93 {
  94   x = -0.0;
  95   y = log (x);
  96   if (!(y + y == y))
  97     return 1;
  98   return 0;
  99 }
 100 ]])],
 101         [gl_cv_func_log_works=yes],
 102         [gl_cv_func_log_works=no],
 103         [case "$host_os" in
 104            osf*)   gl_cv_func_log_works="guessing no" ;;
 105                    # Guess yes on native Windows.
 106            mingw*) gl_cv_func_log_works="guessing yes" ;;
 107            *)      gl_cv_func_log_works="guessing yes" ;;
 108          esac
 109         ])
 110     ])
 111 ])