m4/calloc.m4

   1 # calloc.m4 serial 18
   2
   3 # Copyright (C) 2004-2018 Free Software Foundation, Inc.
   4 # This file is free software; the Free Software Foundation
   5 # gives unlimited permission to copy and/or distribute it,
   6 # with or without modifications, as long as this notice is preserved.
   7
   8 # Written by Jim Meyering.
   9
  10 # Determine whether calloc (N, S) returns non-NULL when N*S is zero,
  11 # and returns NULL when N*S overflows.
  12 # If so, define HAVE_CALLOC.  Otherwise, define calloc to rpl_calloc
  13 # and arrange to use a calloc wrapper function that does work in that case.
  14
  15 # _AC_FUNC_CALLOC_IF([IF-WORKS], [IF-NOT])
  16 # -------------------------------------
  17 # If 'calloc (0, 0)' is properly handled, run IF-WORKS, otherwise, IF-NOT.
  18 AC_DEFUN([_AC_FUNC_CALLOC_IF],
  19 [
  20   AC_REQUIRE([AC_TYPE_SIZE_T])dnl
  21   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  22   AC_CACHE_CHECK([for GNU libc compatible calloc],
  23     [ac_cv_func_calloc_0_nonnull],
  24     [AC_RUN_IFELSE(
  25        [AC_LANG_PROGRAM(
  26           [AC_INCLUDES_DEFAULT],
  27           [[int result = 0;
  28             char *p = calloc (0, 0);
  29             if (!p)
  30               result |= 1;
  31             free (p);
  32             p = calloc ((size_t) -1 / 8 + 1, 8);
  33             if (p)
  34               result |= 2;
  35             free (p);
  36             return result;
  37           ]])],
  38        [ac_cv_func_calloc_0_nonnull=yes],
  39        [ac_cv_func_calloc_0_nonnull=no],
  40        [case "$host_os" in
  41                          # Guess yes on glibc systems.
  42           *-gnu* | gnu*) ac_cv_func_calloc_0_nonnull="guessing yes" ;;
  43                          # Guess yes on native Windows.
  44           mingw*)        ac_cv_func_calloc_0_nonnull="guessing yes" ;;
  45                          # If we don't know, assume the worst.
  46           *)             ac_cv_func_calloc_0_nonnull="guessing no" ;;
  47         esac
  48        ])])
  49   case "$ac_cv_func_calloc_0_nonnull" in
  50     *yes)
  51       $1
  52       ;;
  53     *)
  54       $2
  55       ;;
  56   esac
  57 ])# AC_FUNC_CALLOC
  58
  59
  60 # gl_FUNC_CALLOC_GNU
  61 # ------------------
  62 # Report whether 'calloc (0, 0)' is properly handled, and replace calloc if
  63 # needed.
  64 AC_DEFUN([gl_FUNC_CALLOC_GNU],
  65 [
  66   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  67   _AC_FUNC_CALLOC_IF(
  68     [AC_DEFINE([HAVE_CALLOC_GNU], [1],
  69                [Define to 1 if your system has a GNU libc compatible 'calloc'
  70                 function, and to 0 otherwise.])],
  71     [AC_DEFINE([HAVE_CALLOC_GNU], [0])
  72      REPLACE_CALLOC=1
  73     ])
  74 ])# gl_FUNC_CALLOC_GNU
  75
  76
  77 # gl_FUNC_CALLOC_POSIX
  78 # --------------------
  79 # Test whether 'calloc' is POSIX compliant (sets errno to ENOMEM when it
  80 # fails), and replace calloc if it is not.
  81 AC_DEFUN([gl_FUNC_CALLOC_POSIX],
  82 [
  83   AC_REQUIRE([gl_STDLIB_H_DEFAULTS])
  84   AC_REQUIRE([gl_CHECK_MALLOC_POSIX])
  85   if test $gl_cv_func_malloc_posix = yes; then
  86     AC_DEFINE([HAVE_CALLOC_POSIX], [1],
  87       [Define if the 'calloc' function is POSIX compliant.])
  88   else
  89     REPLACE_CALLOC=1
  90   fi
  91 ])