m4/hypotl.m4

   1 # hypotl.m4 serial 7
   2 dnl Copyright (C) 2012-2017 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_HYPOTL],
   8 [
   9   m4_divert_text([DEFAULTS], [gl_hypotl_required=plain])
  10   AC_REQUIRE([gl_MATH_H_DEFAULTS])
  11   AC_REQUIRE([gl_FUNC_HYPOT])
  12
  13   dnl Persuade glibc <math.h> to declare hypotl().
  14   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  15
  16   dnl Test whether hypotl() exists. Assume that hypotl(), if it exists, is
  17   dnl defined in the same library as hypot().
  18   save_LIBS="$LIBS"
  19   LIBS="$LIBS $HYPOT_LIBM"
  20   AC_CHECK_FUNCS([hypotl])
  21   LIBS="$save_LIBS"
  22   if test $ac_cv_func_hypotl = yes; then
  23     HYPOTL_LIBM="$HYPOT_LIBM"
  24
  25     save_LIBS="$LIBS"
  26     LIBS="$LIBS $HYPOTL_LIBM"
  27     gl_FUNC_HYPOTL_WORKS
  28     LIBS="$save_LIBS"
  29     case "$gl_cv_func_hypotl_works" in
  30       *yes) ;;
  31       *) REPLACE_HYPOTL=1 ;;
  32     esac
  33
  34     m4_ifdef([gl_FUNC_HYPOTL_IEEE], [
  35       if test $gl_hypotl_required = ieee && test $REPLACE_HYPOTL = 0; then
  36         AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  37         AC_CACHE_CHECK([whether hypotl works according to ISO C 99 with IEC 60559],
  38           [gl_cv_func_hypotl_ieee],
  39           [
  40             save_LIBS="$LIBS"
  41             LIBS="$LIBS $HYPOTL_LIBM"
  42             AC_RUN_IFELSE(
  43               [AC_LANG_SOURCE([[
  44 #ifndef __NO_MATH_INLINES
  45 # define __NO_MATH_INLINES 1 /* for glibc */
  46 #endif
  47 #include <math.h>
  48 /* Compare two numbers with ==.
  49    This is a separate function because IRIX 6.5 "cc -O" miscompiles an
  50    'x == x' test.  */
  51 static int
  52 numeric_equal (long double x, long double y)
  53 {
  54   return x == y;
  55 }
  56 static long double dummy (long double x, long double y) { return 0; }
  57 long double zero;
  58 long double one = 1.0L;
  59 int main (int argc, char *argv[])
  60 {
  61   long double (*my_hypotl) (long double, long double) = argc ? hypotl : dummy;
  62   long double f;
  63   /* Test hypotl(NaN,Infinity).
  64      This test fails on OSF/1 5.1 and native Windows.  */
  65   f = my_hypotl (zero / zero, one / zero);
  66   if (!numeric_equal (f, f))
  67     return 1;
  68   return 0;
  69 }
  70               ]])],
  71               [gl_cv_func_hypotl_ieee=yes],
  72               [gl_cv_func_hypotl_ieee=no],
  73               [case "$host_os" in
  74                          # Guess yes on glibc systems.
  75                  *-gnu*) gl_cv_func_hypotl_ieee="guessing yes" ;;
  76                          # Guess yes on native Windows.
  77                  mingw*) gl_cv_func_hypotl_ieee="guessing yes" ;;
  78                          # If we don't know, assume the worst.
  79                  *)      gl_cv_func_hypotl_ieee="guessing no" ;;
  80                esac
  81               ])
  82             LIBS="$save_LIBS"
  83           ])
  84         case "$gl_cv_func_hypotl_ieee" in
  85           *yes) ;;
  86           *) REPLACE_HYPOTL=1 ;;
  87         esac
  88       fi
  89     ])
  90   else
  91     HAVE_HYPOTL=0
  92     dnl If the function is declared but does not appear to exist, it may be
  93     dnl defined as an inline function. In order to avoid a conflict, we have
  94     dnl to define rpl_hypotl, not hypotl.
  95     AC_CHECK_DECLS([hypotl], [REPLACE_HYPOTL=1], , [[#include <math.h>]])
  96   fi
  97   if test $HAVE_HYPOTL = 0 || test $REPLACE_HYPOTL = 1; then
  98     dnl Find libraries needed to link lib/hypotl.c.
  99     if test $HAVE_SAME_LONG_DOUBLE_AS_DOUBLE = 1; then
 100       HYPOTL_LIBM="$HYPOT_LIBM"
 101     else
 102       AC_REQUIRE([gl_FUNC_FABSL])
 103       AC_REQUIRE([gl_FUNC_FREXPL])
 104       AC_REQUIRE([gl_FUNC_LDEXPL])
 105       AC_REQUIRE([gl_FUNC_SQRTL])
 106       HYPOTL_LIBM=
 107       dnl Append $FABSL_LIBM to HYPOTL_LIBM, avoiding gratuitous duplicates.
 108       case " $HYPOTL_LIBM " in
 109         *" $FABSL_LIBM "*) ;;
 110         *) HYPOTL_LIBM="$HYPOTL_LIBM $FABSL_LIBM" ;;
 111       esac
 112       dnl Append $FREXPL_LIBM to HYPOTL_LIBM, avoiding gratuitous duplicates.
 113       case " $HYPOTL_LIBM " in
 114         *" $FREXPL_LIBM "*) ;;
 115         *) HYPOTL_LIBM="$HYPOTL_LIBM $FREXPL_LIBM" ;;
 116       esac
 117       dnl Append $LDEXPL_LIBM to HYPOTL_LIBM, avoiding gratuitous duplicates.
 118       case " $HYPOTL_LIBM " in
 119         *" $LDEXPL_LIBM "*) ;;
 120         *) HYPOTL_LIBM="$HYPOTL_LIBM $LDEXPL_LIBM" ;;
 121       esac
 122       dnl Append $SQRTL_LIBM to HYPOTL_LIBM, avoiding gratuitous duplicates.
 123       case " $HYPOTL_LIBM " in
 124         *" $SQRTL_LIBM "*) ;;
 125         *) HYPOTL_LIBM="$HYPOTL_LIBM $SQRTL_LIBM" ;;
 126       esac
 127     fi
 128   fi
 129   AC_SUBST([HYPOTL_LIBM])
 130 ])
 131
 132 dnl Test whether hypotl() works.
 133 dnl On OpenBSD 5.1/SPARC,
 134 dnl hypotl (2.5541394760659556563446062497337725156L, 7.7893454113437840832487794525518765265L)
 135 dnl has rounding errors that eat up the last 8 to 9 decimal digits.
 136 AC_DEFUN([gl_FUNC_HYPOTL_WORKS],
 137 [
 138   AC_REQUIRE([AC_PROG_CC])
 139   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
 140   AC_CACHE_CHECK([whether hypotl works], [gl_cv_func_hypotl_works],
 141     [
 142       AC_RUN_IFELSE(
 143         [AC_LANG_SOURCE([[
 144 #include <float.h>
 145 #include <math.h>
 146 static long double
 147 my_ldexpl (long double x, int d)
 148 {
 149   for (; d > 0; d--)
 150     x *= 2.0L;
 151   for (; d < 0; d++)
 152     x *= 0.5L;
 153   return x;
 154 }
 155 volatile long double x;
 156 volatile long double y;
 157 volatile long double z;
 158 int main ()
 159 {
 160   long double err;
 161
 162   x = 2.5541394760659556563446062497337725156L;
 163   y = 7.7893454113437840832487794525518765265L;
 164   z = hypotl (x, y);
 165   err = z * z - (x * x + y * y);
 166   err = my_ldexpl (err, LDBL_MANT_DIG);
 167   if (err < 0)
 168     err = - err;
 169   if (err > 1000.0L)
 170     return 1;
 171   return 0;
 172 }
 173 ]])],
 174         [gl_cv_func_hypotl_works=yes],
 175         [gl_cv_func_hypotl_works=no],
 176         [case "$host_os" in
 177            openbsd*) gl_cv_func_hypotl_works="guessing no" ;;
 178                      # Guess yes on native Windows.
 179            mingw*)   gl_cv_func_hypotl_works="guessing yes" ;;
 180            *)        gl_cv_func_hypotl_works="guessing yes" ;;
 181          esac
 182         ])
 183     ])
 184 ])