m4/truncate.m4

   1 # truncate.m4 serial 3   -*- Autoconf -*-
   2 dnl Copyright (C) 2017-2021 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_TRUNCATE],
   8 [
   9   AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST])
  11
  12   AC_CHECK_FUNCS_ONCE([truncate])
  13   dnl AC_CHECK_FUNC is not enough here, because when compiling for Android 4.4
  14   dnl or older with _FILE_OFFSET_BITS=64, truncate() is not declared.  There
  15   dnl is a function 'truncate' in libc, but it is unsuitable, because it takes
  16   dnl only a 32-bit offset argument.
  17   AC_CHECK_DECL([truncate], , , [[#include <unistd.h>]])
  18   if test $ac_cv_have_decl_truncate = yes; then
  19     m4_ifdef([gl_LARGEFILE], [
  20       case "$host_os" in
  21         mingw*)
  22           dnl Native Windows, and Large File Support is requested.
  23           dnl The mingw64 truncate64() function is based on ftruncate64(),
  24           dnl which is unreliable (it may delete the file, see
  25           dnl <https://web.archive.org/web/20160425005423/http://mingw-w64.sourcearchive.com/documentation/2.0-1/ftruncate64_8c_source.html>).
  26           dnl Use gnulib's ftruncate() and truncate() implementation instead.
  27           REPLACE_TRUNCATE=1
  28           ;;
  29       esac
  30     ], [
  31       :
  32     ])
  33     if test $REPLACE_TRUNCATE = 0; then
  34       dnl Check for AIX 7.2 bug with trailing slash.
  35       AC_CACHE_CHECK([whether truncate rejects trailing slashes],
  36         [gl_cv_func_truncate_works],
  37         [echo foo > conftest.tmp
  38          AC_RUN_IFELSE(
  39            [AC_LANG_PROGRAM(
  40               [[#include <unistd.h>
  41               ]],
  42               [[int result = 0;
  43                 if (!truncate ("conftest.tmp/", 2))
  44                   result |= 1;
  45                 return result;
  46               ]])
  47            ],
  48            [gl_cv_func_truncate_works=yes],
  49            [gl_cv_func_truncate_works=no],
  50            [case "$host_os" in
  51                                # Guess yes on Linux systems.
  52               linux-* | linux) gl_cv_func_truncate_works="guessing yes" ;;
  53                                # Guess yes on glibc systems.
  54               *-gnu* | gnu*)   gl_cv_func_truncate_works="guessing yes" ;;
  55                                # Guess no on AIX systems.
  56               aix*)            gl_cv_func_truncate_works="guessing no" ;;
  57                                # If we don't know, obey --enable-cross-guesses.
  58               *)               gl_cv_func_truncate_works="$gl_cross_guess_normal" ;;
  59             esac
  60            ])
  61          rm -f conftest.tmp
  62         ])
  63       case "$gl_cv_func_truncate_works" in
  64         *yes) ;;
  65         *)
  66            AC_DEFINE([TRUNCATE_TRAILING_SLASH_BUG], [1],
  67              [Define to 1 if truncate mishandles trailing slash.])
  68            REPLACE_TRUNCATE=1
  69            ;;
  70       esac
  71     fi
  72   else
  73     HAVE_DECL_TRUNCATE=0
  74     if test $ac_cv_func_truncate = yes; then
  75       dnl Avoid a conflict with the 'truncate' in libc.
  76       REPLACE_TRUNCATE=1
  77     fi
  78   fi
  79 ])
  80
  81 # Prerequisites of lib/truncate.c.
  82 AC_DEFUN([gl_PREREQ_TRUNCATE], [:])