m4/tcgetsid.m4

   1 # tcgetsid.m4 serial 5
   2 dnl Copyright (C) 2010-2021 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_TCGETSID],
   8 [
   9   AC_REQUIRE([gl_TERMIOS_H_DEFAULTS])
  10
  11   dnl Persuade glibc <termios.h> to declare tcgetsid().
  12   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  13
  14   AC_CHECK_DECLS([tcgetsid], , , [[#include <termios.h>]])
  15   if test $ac_cv_have_decl_tcgetsid = no; then
  16     HAVE_DECL_TCGETSID=0
  17   fi
  18
  19   dnl We can't use AC_CHECK_FUNC here, because tcgetsid() is defined as a
  20   dnl static inline function when compiling for Android 4.4 or older.
  21   AC_CACHE_CHECK([for tcgetsid], [gl_cv_func_tcgetsid],
  22     [AC_LINK_IFELSE(
  23        [AC_LANG_PROGRAM(
  24           [[#include <termios.h>]],
  25           [[return tcgetsid(0);]])
  26        ],
  27        [gl_cv_func_tcgetsid=yes],
  28        [gl_cv_func_tcgetsid=no])
  29     ])
  30   if test $gl_cv_func_tcgetsid = yes; then
  31     HAVE_TCGETSID=1
  32   else
  33     HAVE_TCGETSID=0
  34   fi
  35 ])
  36
  37 # Prerequisites of lib/tcgetsid.c.
  38 AC_DEFUN([gl_PREREQ_TCGETSID], [
  39   :
  40 ])