m4/relocatable.m4

   1 # relocatable.m4 serial 23
   2 dnl Copyright (C) 2003, 2005-2007, 2009-2021 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 dnl gl_RELOCATABLE([RELOCWRAPPER-DIR])
  10 dnl ----------------------------------------------------------
  11 dnl Support for relocatable programs.
  12 dnl Supply RELOCWRAPPER-DIR as the directory where relocwrapper.c may be found.
  13 AC_DEFUN([gl_RELOCATABLE],
  14 [
  15   AC_REQUIRE([gl_RELOCATABLE_BODY])
  16   gl_RELOCATABLE_LIBRARY
  17   : ${RELOCATABLE_CONFIG_H_DIR='$(top_builddir)'}
  18   RELOCATABLE_SRC_DIR="\$(top_srcdir)/$gl_source_base"
  19   RELOCATABLE_BUILD_DIR="\$(top_builddir)/$gl_source_base"
  20 ])
  21 dnl The guts of gl_RELOCATABLE. Needs to be expanded only once.
  22 AC_DEFUN([gl_RELOCATABLE_BODY],
  23 [
  24   AC_REQUIRE([AC_PROG_INSTALL])
  25
  26   dnl This AC_BEFORE invocation leads to unjustified autoconf warnings
  27   dnl when gl_RELOCATABLE_BODY is invoked more than once.
  28   dnl
  29   dnl We need this AC_BEFORE because AC_PROG_INSTALL is documented to
  30   dnl overwrite earlier settings of INSTALL and INSTALL_PROGRAM (even
  31   dnl though in autoconf-2.52..2.60 it doesn't do so), but we want this
  32   dnl macro's setting of INSTALL_PROGRAM to persist.
  33   dnl Arghh: AC_BEFORE does not work in this setting :-(
  34   dnl AC_BEFORE([AC_PROG_INSTALL],[gl_RELOCATABLE_BODY])
  35   dnl
  36   dnl LT_INIT sets LIBTOOL, but we want this macro's setting of LIBTOOL to
  37   dnl persist.
  38   dnl Arghh: AC_BEFORE does not work in this setting :-(
  39   dnl AC_BEFORE([LT_INIT],[gl_RELOCATABLE_BODY])
  40
  41   AC_REQUIRE([AC_LIB_LIBPATH])
  42   AC_REQUIRE([gl_RELOCATABLE_LIBRARY_BODY])
  43   AC_REQUIRE([AC_CANONICAL_HOST])
  44   is_noop=no
  45   use_elf_origin_trick=no
  46   use_macos_tools=no
  47   use_wrapper=no
  48   if test $RELOCATABLE = yes; then
  49     # --enable-relocatable implies --disable-rpath
  50     enable_rpath=no
  51     AC_CHECK_HEADERS([mach-o/dyld.h])
  52     AC_CHECK_FUNCS([_NSGetExecutablePath])
  53     case "$host_os" in
  54       mingw*) is_noop=yes ;;
  55       # For the platforms that support $ORIGIN, see
  56       # <https://lekensteyn.nl/rpath.html>.
  57       # glibc systems, Linux with musl libc: yes. Android: no.
  58       linux*-android*) ;;
  59       linux* | kfreebsd*) use_elf_origin_trick=yes ;;
  60       # Hurd: <https://lists.gnu.org/r/bug-hurd/2019-02/msg00049.html>
  61       # only after the glibc commit from 2018-01-08
  62       # <https://sourceware.org/git/?p=glibc.git;a=commitdiff;h=311ba8dc4416467947eff2ab327854f124226309>
  63       gnu*)
  64         # Test for a glibc version >= 2.27.
  65         AC_CHECK_FUNCS([copy_file_range])
  66         if test $ac_cv_func_copy_file_range = yes; then
  67           use_elf_origin_trick=yes
  68         fi
  69         ;;
  70 changequote(,)dnl
  71       # FreeBSD >= 7.3, DragonFly >= 3.0: yes.
  72       freebsd | freebsd[1-7] | freebsd[1-6].* | freebsd7.[0-2]) ;;
  73       dragonfly | dragonfly[1-2] | dragonfly[1-2].*) ;;
  74       freebsd* | dragonfly*) use_elf_origin_trick=yes ;;
  75       # NetBSD >= 8.0: yes.
  76       netbsd | netbsd[1-7] | netbsd[1-7].*) ;;
  77       netbsdelf | netbsdelf[1-7] | netbsdelf[1-7].*) ;;
  78       netbsd*) use_elf_origin_trick=yes ;;
  79       # OpenBSD >= 5.4: yes.
  80       openbsd | openbsd[1-5] | openbsd[1-4].* | openbsd5.[0-3]) ;;
  81       openbsd*) use_elf_origin_trick=yes ;;
  82       # Solaris >= 10: yes.
  83       solaris | solaris2.[1-9] | solaris2.[1-9].*) ;;
  84       solaris*) use_elf_origin_trick=yes ;;
  85       # Haiku: yes.
  86       haiku*) use_elf_origin_trick=yes ;;
  87       # On Mac OS X 10.4 or newer, use Mac OS X tools. See
  88       # <https://wincent.com/wiki/@executable_path,_@load_path_and_@rpath>.
  89       darwin | darwin[1-7].*) ;;
  90       darwin*) use_macos_tools=yes ;;
  91 changequote([,])dnl
  92     esac
  93     if test $is_noop = yes; then
  94       RELOCATABLE_LDFLAGS=:
  95       AC_SUBST([RELOCATABLE_LDFLAGS])
  96     else
  97       if test $use_elf_origin_trick = yes || test $use_macos_tools = yes; then
  98         dnl Use the dynamic linker's support for relocatable programs.
  99         case "$ac_aux_dir" in
 100           /*) reloc_ldflags="$ac_aux_dir/reloc-ldflags" ;;
 101           *) reloc_ldflags="\$(top_builddir)/$ac_aux_dir/reloc-ldflags" ;;
 102         esac
 103         RELOCATABLE_LDFLAGS="\"$reloc_ldflags\" \"\$(host)\" \"\$(RELOCATABLE_LIBRARY_PATH)\""
 104         AC_SUBST([RELOCATABLE_LDFLAGS])
 105         if test $use_macos_tools = yes; then
 106           dnl Use a libtool wrapper that uses Mac OS X tools.
 107           case "$ac_aux_dir" in
 108             /*) LIBTOOL="${CONFIG_SHELL-$SHELL} $ac_aux_dir/libtool-reloc $LIBTOOL" ;;
 109             *) LIBTOOL="${CONFIG_SHELL-$SHELL} \$(top_builddir)/$ac_aux_dir/libtool-reloc $LIBTOOL" ;;
 110           esac
 111         fi
 112       else
 113         use_wrapper=yes
 114         dnl Unfortunately we cannot define INSTALL_PROGRAM to a command
 115         dnl consisting of more than one word - libtool doesn't support this.
 116         dnl So we abuse the INSTALL_PROGRAM_ENV hook, originally meant for the
 117         dnl 'install-strip' target.
 118         INSTALL_PROGRAM_ENV="RELOC_LIBRARY_PATH_VAR=\"$shlibpath_var\" RELOC_LIBRARY_PATH_VALUE=\"\$(RELOCATABLE_LIBRARY_PATH)\" RELOC_PREFIX=\"\$(prefix)\" RELOC_DESTDIR=\"\$(DESTDIR)\" RELOC_COMPILE_COMMAND=\"\$(CC) \$(CPPFLAGS) \$(CFLAGS) \$(LDFLAGS)\" RELOC_SRCDIR=\"\$(RELOCATABLE_SRC_DIR)\" RELOC_BUILDDIR=\"\$(RELOCATABLE_BUILD_DIR)\" RELOC_CONFIG_H_DIR=\"\$(RELOCATABLE_CONFIG_H_DIR)\" RELOC_EXEEXT=\"\$(EXEEXT)\" RELOC_STRIP_PROG=\"\$(RELOCATABLE_STRIP)\" RELOC_INSTALL_PROG=\"$INSTALL_PROGRAM\""
 119         AC_SUBST([INSTALL_PROGRAM_ENV])
 120         case "$ac_aux_dir" in
 121           /*) INSTALL_PROGRAM="$ac_aux_dir/install-reloc" ;;
 122           *) INSTALL_PROGRAM="\$(top_builddir)/$ac_aux_dir/install-reloc" ;;
 123         esac
 124       fi
 125     fi
 126   fi
 127   AM_CONDITIONAL([RELOCATABLE_VIA_LD],
 128     [test $is_noop = yes || test $use_elf_origin_trick = yes || test $use_macos_tools = yes])
 129   AM_CONDITIONAL([RELOCATABLE_VIA_WRAPPER], [test $use_wrapper = yes])
 130
 131   dnl RELOCATABLE_LIBRARY_PATH can be set in configure.ac. Default is empty.
 132   AC_SUBST([RELOCATABLE_LIBRARY_PATH])
 133
 134   AC_SUBST([RELOCATABLE_CONFIG_H_DIR])
 135   AC_SUBST([RELOCATABLE_SRC_DIR])
 136   AC_SUBST([RELOCATABLE_BUILD_DIR])
 137
 138   dnl Ensure RELOCATABLE_STRIP is defined in Makefiles (at least those
 139   dnl generated by automake), with value ':'.
 140   RELOCATABLE_STRIP=':'
 141   AC_SUBST([RELOCATABLE_STRIP])
 142 ])
 143
 144 dnl Determine the platform dependent parameters needed to use relocatability:
 145 dnl shlibpath_var.
 146 AC_DEFUN([AC_LIB_LIBPATH],
 147 [
 148   AC_REQUIRE([AC_LIB_PROG_LD])            dnl we use $LD
 149   AC_REQUIRE([AC_CANONICAL_HOST])         dnl we use $host
 150   AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT]) dnl we use $ac_aux_dir
 151   AC_CACHE_CHECK([for shared library path variable], [acl_cv_libpath], [
 152     LD="$LD" \
 153     ${CONFIG_SHELL-/bin/sh} "$ac_aux_dir/config.libpath" "$host" > conftest.sh
 154     . ./conftest.sh
 155     rm -f ./conftest.sh
 156     acl_cv_libpath=${acl_cv_shlibpath_var:-none}
 157   ])
 158   shlibpath_var="$acl_cv_shlibpath_var"
 159 ])