m4/imaxdiv.m4

   1 # imaxdiv.m4 serial 5
   2 dnl Copyright (C) 2006, 2009-2021 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_IMAXDIV],
   8 [
   9   AC_REQUIRE([gl_INTTYPES_H_DEFAULTS])
  10
  11   dnl On OSF/1 5.1 with cc, this function is declared but not defined.
  12   AC_CHECK_FUNCS_ONCE([imaxdiv])
  13   AC_CHECK_DECLS_ONCE([imaxdiv])
  14   if test "$ac_cv_have_decl_imaxdiv" != yes; then
  15     HAVE_DECL_IMAXDIV=0
  16   fi
  17
  18   AC_CACHE_CHECK([whether <inttypes.h> defines imaxdiv_t],
  19     [gl_cv_type_imaxdiv_t],
  20     [dnl Assume that if imaxdiv is declared, imaxdiv_t is defined.
  21      if test $ac_cv_have_decl_imaxdiv = yes; then
  22        gl_cv_type_imaxdiv_t=yes
  23      else
  24        AC_COMPILE_IFELSE(
  25          [AC_LANG_PROGRAM(
  26             [[#include <inttypes.h>
  27               imaxdiv_t x;
  28             ]])
  29          ],
  30          [gl_cv_type_imaxdiv_t=yes],
  31          [gl_cv_type_imaxdiv_t=no])
  32      fi
  33     ])
  34   if test $gl_cv_type_imaxdiv_t = no; then
  35     HAVE_IMAXDIV_T=0
  36   fi
  37 ])
  38
  39 # Prerequisites of lib/imaxdiv.c.
  40 AC_DEFUN([gl_PREREQ_IMAXDIV], [:])