m4/valgrind-tests.m4

   1 # valgrind-tests.m4 serial 4
   2 dnl Copyright (C) 2008-2019 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Simon Josefsson
   8
   9 # gl_VALGRIND_TESTS()
  10 # -------------------
  11 # Check if valgrind is available, and set VALGRIND to it if available.
  12 AC_DEFUN([gl_VALGRIND_TESTS],
  13 [
  14   AC_ARG_ENABLE([valgrind-tests],
  15     AS_HELP_STRING([--disable-valgrind-tests],
  16                    [don't try to run self tests under valgrind]),
  17     [opt_valgrind_tests=$enableval], [opt_valgrind_tests=yes])
  18
  19   # Run self-tests under valgrind?
  20   if test "$opt_valgrind_tests" = "yes" && test "$cross_compiling" = no; then
  21     AC_CHECK_PROGS([VALGRIND], [valgrind])
  22
  23     if test "$VALGRIND"; then
  24       AC_CACHE_CHECK([for valgrind options for tests],
  25         [gl_cv_opt_valgrind_tests],
  26         [gl_cv_opt_valgrind_tests="-q --error-exitcode=1 --leak-check=full"
  27          $VALGRIND $gl_valgrind_opts ls > /dev/null 2>&1 ||
  28            gl_cv_opt_valgrind_tests=no])
  29
  30       if test "$gl_cv_opt_valgrind_tests" != no; then
  31         VALGRIND="$VALGRIND $gl_cv_opt_valgrind_tests"
  32       else
  33         VALGRIND=
  34       fi
  35     fi
  36   fi
  37 ])