m4/po.m4

   1 # po.m4 serial 24a
   2 dnl Copyright (C) 1995-2014, 2016, 2018-2019 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6 dnl
   7 dnl This file can be used in projects which are not available under
   8 dnl the GNU General Public License or the GNU Library General Public
   9 dnl License but which still want to provide support for the GNU gettext
  10 dnl functionality.
  11 dnl Please note that the actual code of the GNU gettext library is covered
  12 dnl by the GNU Library General Public License, and the rest of the GNU
  13 dnl gettext package is covered by the GNU General Public License.
  14 dnl They are *not* in the public domain.
  15
  16 dnl Authors:
  17 dnl   Ulrich Drepper <drepper@cygnus.com>, 1995-2000.
  18 dnl   Bruno Haible <haible@clisp.cons.org>, 2000-2003.
  19
  20 AC_PREREQ([2.60])
  21
  22 dnl Checks for all prerequisites of the po subdirectory.
  23 AC_DEFUN([AM_PO_SUBDIRS],
  24 [
  25   AC_REQUIRE([AC_PROG_MAKE_SET])dnl
  26   AC_REQUIRE([AC_PROG_INSTALL])dnl
  27   AC_REQUIRE([AC_PROG_MKDIR_P])dnl
  28   AC_REQUIRE([AC_PROG_SED])dnl
  29   AC_REQUIRE([AM_NLS])dnl
  30
  31   dnl Release version of the gettext macros. This is used to ensure that
  32   dnl the gettext macros and po/Makefile.in.in are in sync.
  33   AC_SUBST([GETTEXT_MACRO_VERSION], [0.19])
  34
  35   dnl Perform the following tests also if --disable-nls has been given,
  36   dnl because they are needed for "make dist" to work.
  37
  38   dnl Search for GNU msgfmt in the PATH.
  39   dnl The first test excludes Solaris msgfmt and early GNU msgfmt versions.
  40   dnl The second test excludes FreeBSD msgfmt.
  41   AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
  42     [$ac_dir/$ac_word --statistics /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 &&
  43      (if $ac_dir/$ac_word --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
  44     :)
  45   AC_PATH_PROG([GMSGFMT], [gmsgfmt], [$MSGFMT])
  46
  47   dnl Test whether it is GNU msgfmt >= 0.15.
  48 changequote(,)dnl
  49   case `$MSGFMT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in
  50     '' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) MSGFMT_015=: ;;
  51     *) MSGFMT_015=$MSGFMT ;;
  52   esac
  53 changequote([,])dnl
  54   AC_SUBST([MSGFMT_015])
  55 changequote(,)dnl
  56   case `$GMSGFMT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in
  57     '' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) GMSGFMT_015=: ;;
  58     *) GMSGFMT_015=$GMSGFMT ;;
  59   esac
  60 changequote([,])dnl
  61   AC_SUBST([GMSGFMT_015])
  62
  63   dnl Search for GNU xgettext 0.12 or newer in the PATH.
  64   dnl The first test excludes Solaris xgettext and early GNU xgettext versions.
  65   dnl The second test excludes FreeBSD xgettext.
  66   AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
  67     [$ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 &&
  68      (if $ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)],
  69     :)
  70   dnl Remove leftover from FreeBSD xgettext call.
  71   rm -f messages.po
  72
  73   dnl Test whether it is GNU xgettext >= 0.15.
  74 changequote(,)dnl
  75   case `$XGETTEXT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in
  76     '' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) XGETTEXT_015=: ;;
  77     *) XGETTEXT_015=$XGETTEXT ;;
  78   esac
  79 changequote([,])dnl
  80   AC_SUBST([XGETTEXT_015])
  81
  82   dnl Search for GNU msgmerge 0.11 or newer in the PATH.
  83   AM_PATH_PROG_WITH_TEST(MSGMERGE, msgmerge,
  84     [$ac_dir/$ac_word --update -q /dev/null /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1], :)
  85
  86   dnl Support for AM_XGETTEXT_OPTION.
  87   test -n "${XGETTEXT_EXTRA_OPTIONS+set}" || XGETTEXT_EXTRA_OPTIONS=
  88   AC_SUBST([XGETTEXT_EXTRA_OPTIONS])
  89
  90   AC_CONFIG_COMMANDS([po-directories], [[
  91     for ac_file in $CONFIG_FILES; do
  92       # Support "outfile[:infile[:infile...]]"
  93       case "$ac_file" in
  94         *:*) ac_file=`echo "$ac_file"|sed 's%:.*%%'` ;;
  95       esac
  96       # PO directories have a Makefile.in generated from Makefile.in.in.
  97       case "$ac_file" in */Makefile.in)
  98         # Adjust a relative srcdir.
  99         ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
 100         ac_dir_suffix=/`echo "$ac_dir"|sed 's%^\./%%'`
 101         ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
 102         # In autoconf-2.13 it is called $ac_given_srcdir.
 103         # In autoconf-2.50 it is called $srcdir.
 104         test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
 105         case "$ac_given_srcdir" in
 106           .)  top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
 107           /*) top_srcdir="$ac_given_srcdir" ;;
 108           *)  top_srcdir="$ac_dots$ac_given_srcdir" ;;
 109         esac
 110         # Treat a directory as a PO directory if and only if it has a
 111         # POTFILES.in file. This allows packages to have multiple PO
 112         # directories under different names or in different locations.
 113         if test -f "$ac_given_srcdir/$ac_dir/POTFILES.in"; then
 114           rm -f "$ac_dir/POTFILES"
 115           test -n "$as_me" && echo "$as_me: creating $ac_dir/POTFILES" || echo "creating $ac_dir/POTFILES"
 116           gt_tab=`printf '\t'`
 117           cat "$ac_given_srcdir/$ac_dir/POTFILES.in" | sed -e "/^#/d" -e "/^[ ${gt_tab}]*\$/d" -e "s,.*,     $top_srcdir/& \\\\," | sed -e "\$s/\(.*\) \\\\/\1/" > "$ac_dir/POTFILES"
 118           POMAKEFILEDEPS="POTFILES.in"
 119           # ALL_LINGUAS, POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES depend
 120           # on $ac_dir but don't depend on user-specified configuration
 121           # parameters.
 122           if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then
 123             # The LINGUAS file contains the set of available languages.
 124             if test -n "$OBSOLETE_ALL_LINGUAS"; then
 125               test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete"
 126             fi
 127             ALL_LINGUAS=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"`
 128             POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS"
 129           else
 130             # The set of available languages was given in configure.in.
 131             ALL_LINGUAS=$OBSOLETE_ALL_LINGUAS
 132           fi
 133           # Compute POFILES
 134           # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po)
 135           # Compute UPDATEPOFILES
 136           # as      $(foreach lang, $(ALL_LINGUAS), $(lang).po-update)
 137           # Compute DUMMYPOFILES
 138           # as      $(foreach lang, $(ALL_LINGUAS), $(lang).nop)
 139           # Compute GMOFILES
 140           # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo)
 141           case "$ac_given_srcdir" in
 142             .) srcdirpre= ;;
 143             *) srcdirpre='$(srcdir)/' ;;
 144           esac
 145           POFILES=
 146           UPDATEPOFILES=
 147           DUMMYPOFILES=
 148           GMOFILES=
 149           for lang in $ALL_LINGUAS; do
 150             POFILES="$POFILES $srcdirpre$lang.po"
 151             UPDATEPOFILES="$UPDATEPOFILES $lang.po-update"
 152             DUMMYPOFILES="$DUMMYPOFILES $lang.nop"
 153             GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 154           done
 155           # CATALOGS depends on both $ac_dir and the user's LINGUAS
 156           # environment variable.
 157           INST_LINGUAS=
 158           if test -n "$ALL_LINGUAS"; then
 159             for presentlang in $ALL_LINGUAS; do
 160               useit=no
 161               if test "%UNSET%" != "$LINGUAS"; then
 162                 desiredlanguages="$LINGUAS"
 163               else
 164                 desiredlanguages="$ALL_LINGUAS"
 165               fi
 166               for desiredlang in $desiredlanguages; do
 167                 # Use the presentlang catalog if desiredlang is
 168                 #   a. equal to presentlang, or
 169                 #   b. a variant of presentlang (because in this case,
 170                 #      presentlang can be used as a fallback for messages
 171                 #      which are not translated in the desiredlang catalog).
 172                 case "$desiredlang" in
 173                   "$presentlang"*) useit=yes;;
 174                 esac
 175               done
 176               if test $useit = yes; then
 177                 INST_LINGUAS="$INST_LINGUAS $presentlang"
 178               fi
 179             done
 180           fi
 181           CATALOGS=
 182           if test -n "$INST_LINGUAS"; then
 183             for lang in $INST_LINGUAS; do
 184               CATALOGS="$CATALOGS $lang.gmo"
 185             done
 186           fi
 187           test -n "$as_me" && echo "$as_me: creating $ac_dir/Makefile" || echo "creating $ac_dir/Makefile"
 188           sed -e "/^POTFILES =/r $ac_dir/POTFILES" -e "/^# Makevars/r $ac_given_srcdir/$ac_dir/Makevars" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@POMAKEFILEDEPS@|$POMAKEFILEDEPS|g" "$ac_dir/Makefile.in" > "$ac_dir/Makefile"
 189           for f in "$ac_given_srcdir/$ac_dir"/Rules-*; do
 190             if test -f "$f"; then
 191               case "$f" in
 192                 *.orig | *.bak | *~) ;;
 193                 *) cat "$f" >> "$ac_dir/Makefile" ;;
 194               esac
 195             fi
 196           done
 197         fi
 198         ;;
 199       esac
 200     done]],
 201    [# Capture the value of obsolete ALL_LINGUAS because we need it to compute
 202     # POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES, CATALOGS.
 203     OBSOLETE_ALL_LINGUAS="$ALL_LINGUAS"
 204     # Capture the value of LINGUAS because we need it to compute CATALOGS.
 205     LINGUAS="${LINGUAS-%UNSET%}"
 206    ])
 207 ])
 208
 209 dnl Postprocesses a Makefile in a directory containing PO files.
 210 AC_DEFUN([AM_POSTPROCESS_PO_MAKEFILE],
 211 [
 212   # When this code is run, in config.status, two variables have already been
 213   # set:
 214   # - OBSOLETE_ALL_LINGUAS is the value of LINGUAS set in configure.in,
 215   # - LINGUAS is the value of the environment variable LINGUAS at configure
 216   #   time.
 217
 218 changequote(,)dnl
 219   # Adjust a relative srcdir.
 220   ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'`
 221   ac_dir_suffix=/`echo "$ac_dir"|sed 's%^\./%%'`
 222   ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'`
 223   # In autoconf-2.13 it is called $ac_given_srcdir.
 224   # In autoconf-2.50 it is called $srcdir.
 225   test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir"
 226   case "$ac_given_srcdir" in
 227     .)  top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;;
 228     /*) top_srcdir="$ac_given_srcdir" ;;
 229     *)  top_srcdir="$ac_dots$ac_given_srcdir" ;;
 230   esac
 231
 232   # Find a way to echo strings without interpreting backslash.
 233   if test "X`(echo '\t') 2>/dev/null`" = 'X\t'; then
 234     gt_echo='echo'
 235   else
 236     if test "X`(printf '%s\n' '\t') 2>/dev/null`" = 'X\t'; then
 237       gt_echo='printf %s\n'
 238     else
 239       echo_func () {
 240         cat <<EOT
 241 $*
 242 EOT
 243       }
 244       gt_echo='echo_func'
 245     fi
 246   fi
 247
 248   # A sed script that extracts the value of VARIABLE from a Makefile.
 249   tab=`printf '\t'`
 250   sed_x_variable='
 251 # Test if the hold space is empty.
 252 x
 253 s/P/P/
 254 x
 255 ta
 256 # Yes it was empty. Look if we have the expected variable definition.
 257 /^['"${tab}"' ]*VARIABLE['"${tab}"' ]*=/{
 258   # Seen the first line of the variable definition.
 259   s/^['"${tab}"' ]*VARIABLE['"${tab}"' ]*=//
 260   ba
 261 }
 262 bd
 263 :a
 264 # Here we are processing a line from the variable definition.
 265 # Remove comment, more precisely replace it with a space.
 266 s/#.*$/ /
 267 # See if the line ends in a backslash.
 268 tb
 269 :b
 270 s/\\$//
 271 # Print the line, without the trailing backslash.
 272 p
 273 tc
 274 # There was no trailing backslash. The end of the variable definition is
 275 # reached. Clear the hold space.
 276 s/^.*$//
 277 x
 278 bd
 279 :c
 280 # A trailing backslash means that the variable definition continues in the
 281 # next line. Put a nonempty string into the hold space to indicate this.
 282 s/^.*$/P/
 283 x
 284 :d
 285 '
 286 changequote([,])dnl
 287
 288   # Set POTFILES to the value of the Makefile variable POTFILES.
 289   sed_x_POTFILES=`$gt_echo "$sed_x_variable" | sed -e '/^ *#/d' -e 's/VARIABLE/POTFILES/g'`
 290   POTFILES=`sed -n -e "$sed_x_POTFILES" < "$ac_file"`
 291   # Compute POTFILES_DEPS as
 292   #   $(foreach file, $(POTFILES), $(top_srcdir)/$(file))
 293   POTFILES_DEPS=
 294   for file in $POTFILES; do
 295     POTFILES_DEPS="$POTFILES_DEPS "'$(top_srcdir)/'"$file"
 296   done
 297   POMAKEFILEDEPS=""
 298
 299   if test -n "$OBSOLETE_ALL_LINGUAS"; then
 300     test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete"
 301   fi
 302   if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then
 303     # The LINGUAS file contains the set of available languages.
 304     ALL_LINGUAS=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"`
 305     POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS"
 306   else
 307     # Set ALL_LINGUAS to the value of the Makefile variable LINGUAS.
 308     sed_x_LINGUAS=`$gt_echo "$sed_x_variable" | sed -e '/^ *#/d' -e 's/VARIABLE/LINGUAS/g'`
 309     ALL_LINGUAS=`sed -n -e "$sed_x_LINGUAS" < "$ac_file"`
 310   fi
 311   # Compute POFILES
 312   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po)
 313   # Compute UPDATEPOFILES
 314   # as      $(foreach lang, $(ALL_LINGUAS), $(lang).po-update)
 315   # Compute DUMMYPOFILES
 316   # as      $(foreach lang, $(ALL_LINGUAS), $(lang).nop)
 317   # Compute GMOFILES
 318   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo)
 319   # Compute PROPERTIESFILES
 320   # as      $(foreach lang, $(ALL_LINGUAS), $(top_srcdir)/$(DOMAIN)_$(lang).properties)
 321   # Compute CLASSFILES
 322   # as      $(foreach lang, $(ALL_LINGUAS), $(top_srcdir)/$(DOMAIN)_$(lang).class)
 323   # Compute QMFILES
 324   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).qm)
 325   # Compute MSGFILES
 326   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang)).msg)
 327   # Compute RESOURCESDLLFILES
 328   # as      $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang))/$(DOMAIN).resources.dll)
 329   case "$ac_given_srcdir" in
 330     .) srcdirpre= ;;
 331     *) srcdirpre='$(srcdir)/' ;;
 332   esac
 333   POFILES=
 334   UPDATEPOFILES=
 335   DUMMYPOFILES=
 336   GMOFILES=
 337   PROPERTIESFILES=
 338   CLASSFILES=
 339   QMFILES=
 340   MSGFILES=
 341   RESOURCESDLLFILES=
 342   for lang in $ALL_LINGUAS; do
 343     POFILES="$POFILES $srcdirpre$lang.po"
 344     UPDATEPOFILES="$UPDATEPOFILES $lang.po-update"
 345     DUMMYPOFILES="$DUMMYPOFILES $lang.nop"
 346     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 347     PROPERTIESFILES="$PROPERTIESFILES \$(top_srcdir)/\$(DOMAIN)_$lang.properties"
 348     CLASSFILES="$CLASSFILES \$(top_srcdir)/\$(DOMAIN)_$lang.class"
 349     QMFILES="$QMFILES $srcdirpre$lang.qm"
 350     frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
 351     MSGFILES="$MSGFILES $srcdirpre$frobbedlang.msg"
 352     frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
 353     RESOURCESDLLFILES="$RESOURCESDLLFILES $srcdirpre$frobbedlang/\$(DOMAIN).resources.dll"
 354   done
 355   # CATALOGS depends on both $ac_dir and the user's LINGUAS
 356   # environment variable.
 357   INST_LINGUAS=
 358   if test -n "$ALL_LINGUAS"; then
 359     for presentlang in $ALL_LINGUAS; do
 360       useit=no
 361       if test "%UNSET%" != "$LINGUAS"; then
 362         desiredlanguages="$LINGUAS"
 363       else
 364         desiredlanguages="$ALL_LINGUAS"
 365       fi
 366       for desiredlang in $desiredlanguages; do
 367         # Use the presentlang catalog if desiredlang is
 368         #   a. equal to presentlang, or
 369         #   b. a variant of presentlang (because in this case,
 370         #      presentlang can be used as a fallback for messages
 371         #      which are not translated in the desiredlang catalog).
 372         case "$desiredlang" in
 373           "$presentlang"*) useit=yes;;
 374         esac
 375       done
 376       if test $useit = yes; then
 377         INST_LINGUAS="$INST_LINGUAS $presentlang"
 378       fi
 379     done
 380   fi
 381   CATALOGS=
 382   JAVACATALOGS=
 383   QTCATALOGS=
 384   TCLCATALOGS=
 385   CSHARPCATALOGS=
 386   if test -n "$INST_LINGUAS"; then
 387     for lang in $INST_LINGUAS; do
 388       CATALOGS="$CATALOGS $lang.gmo"
 389       JAVACATALOGS="$JAVACATALOGS \$(DOMAIN)_$lang.properties"
 390       QTCATALOGS="$QTCATALOGS $lang.qm"
 391       frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
 392       TCLCATALOGS="$TCLCATALOGS $frobbedlang.msg"
 393       frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
 394       CSHARPCATALOGS="$CSHARPCATALOGS $frobbedlang/\$(DOMAIN).resources.dll"
 395     done
 396   fi
 397
 398   sed -e "s|@POTFILES_DEPS@|$POTFILES_DEPS|g" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@PROPERTIESFILES@|$PROPERTIESFILES|g" -e "s|@CLASSFILES@|$CLASSFILES|g" -e "s|@QMFILES@|$QMFILES|g" -e "s|@MSGFILES@|$MSGFILES|g" -e "s|@RESOURCESDLLFILES@|$RESOURCESDLLFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@JAVACATALOGS@|$JAVACATALOGS|g" -e "s|@QTCATALOGS@|$QTCATALOGS|g" -e "s|@TCLCATALOGS@|$TCLCATALOGS|g" -e "s|@CSHARPCATALOGS@|$CSHARPCATALOGS|g" -e 's,^#distdir:,distdir:,' < "$ac_file" > "$ac_file.tmp"
 399   tab=`printf '\t'`
 400   if grep -l '@TCLCATALOGS@' "$ac_file" > /dev/null; then
 401     # Add dependencies that cannot be formulated as a simple suffix rule.
 402     for lang in $ALL_LINGUAS; do
 403       frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'`
 404       cat >> "$ac_file.tmp" <<EOF
 405 $frobbedlang.msg: $lang.po
 406 ${tab}@echo "\$(MSGFMT) -c --tcl -d \$(srcdir) -l $lang $srcdirpre$lang.po"; \
 407 ${tab}\$(MSGFMT) -c --tcl -d "\$(srcdir)" -l $lang $srcdirpre$lang.po || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; }
 408 EOF
 409     done
 410   fi
 411   if grep -l '@CSHARPCATALOGS@' "$ac_file" > /dev/null; then
 412     # Add dependencies that cannot be formulated as a simple suffix rule.
 413     for lang in $ALL_LINGUAS; do
 414       frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'`
 415       cat >> "$ac_file.tmp" <<EOF
 416 $frobbedlang/\$(DOMAIN).resources.dll: $lang.po
 417 ${tab}@echo "\$(MSGFMT) -c --csharp -d \$(srcdir) -l $lang $srcdirpre$lang.po -r \$(DOMAIN)"; \
 418 ${tab}\$(MSGFMT) -c --csharp -d "\$(srcdir)" -l $lang $srcdirpre$lang.po -r "\$(DOMAIN)" || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; }
 419 EOF
 420     done
 421   fi
 422   if test -n "$POMAKEFILEDEPS"; then
 423     cat >> "$ac_file.tmp" <<EOF
 424 Makefile: $POMAKEFILEDEPS
 425 EOF
 426   fi
 427   mv "$ac_file.tmp" "$ac_file"
 428 ])
 429
 430 dnl Initializes the accumulator used by AM_XGETTEXT_OPTION.
 431 AC_DEFUN([AM_XGETTEXT_OPTION_INIT],
 432 [
 433   XGETTEXT_EXTRA_OPTIONS=
 434 ])
 435
 436 dnl Registers an option to be passed to xgettext in the po subdirectory.
 437 AC_DEFUN([AM_XGETTEXT_OPTION],
 438 [
 439   AC_REQUIRE([AM_XGETTEXT_OPTION_INIT])
 440   XGETTEXT_EXTRA_OPTIONS="$XGETTEXT_EXTRA_OPTIONS $1"
 441 ])