m4/gl-openssl.m4

   1 # gl-openssl.m4 serial 3
   2 dnl Copyright (C) 2013-2019 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_SET_CRYPTO_CHECK_DEFAULT],
   8 [
   9   m4_define([gl_CRYPTO_CHECK_DEFAULT], [$1])
  10 ])
  11 gl_SET_CRYPTO_CHECK_DEFAULT([no])
  12
  13 AC_DEFUN([gl_CRYPTO_CHECK],
  14 [
  15   dnl gnulib users set this before gl_INIT with gl_SET_CRYPTO_CHECK_DEFAULT()
  16   m4_divert_once([DEFAULTS], [with_openssl_default='gl_CRYPTO_CHECK_DEFAULT'])
  17
  18   dnl Only clear once, so crypto routines can be checked for individually
  19   m4_divert_once([DEFAULTS], [LIB_CRYPTO=])
  20
  21   AC_ARG_WITH([openssl],
  22     [AS_HELP_STRING([--with-openssl],
  23       [use libcrypto hash routines. Valid ARGs are:
  24        'yes', 'no', 'auto' => use if available,
  25        'optional' => use if available and warn if not available;
  26        default is ']gl_CRYPTO_CHECK_DEFAULT['.
  27        Note also --with-linux-crypto, which will enable
  28        use of kernel crypto routines, which have precedence])],
  29     [],
  30     [with_openssl=$with_openssl_default])
  31
  32   if test "x$1" = xMD5; then
  33     ALG_header=md5.h
  34   else
  35     ALG_header=sha.h
  36   fi
  37
  38   AC_SUBST([LIB_CRYPTO])
  39   if test "x$with_openssl" != xno; then
  40     AC_CHECK_LIB([crypto], [$1],
  41       [AC_CHECK_HEADERS([openssl/$ALG_header],
  42          [LIB_CRYPTO=-lcrypto
  43           AC_DEFINE([HAVE_OPENSSL_$1], [1],
  44             [Define to 1 if libcrypto is used for $1.])])])
  45     if test "x$LIB_CRYPTO" = x; then
  46       if test "x$with_openssl" = xyes; then
  47         AC_MSG_ERROR([openssl development library not found for $1])
  48       elif test "x$with_openssl" = xoptional; then
  49         AC_MSG_WARN([openssl development library not found for $1])
  50       fi
  51     fi
  52   fi
  53 ])