sysdeps/sparc/sparc64/fpu/multiarch/s_nearbyintf-vis3.S

   1 /* Round float to int floating-point values without generating
   2    an inexact exception, sparc64 vis3 version.
   3
   4    Copyright (C) 2013-2024 Free Software Foundation, Inc.
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <https://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22
  23         /* We pop constants into the FPU registers using the incoming
  24            argument stack slots, since this avoid having to use any PIC
  25            references.  We also thus avoid having to allocate a register
  26            window.
  27
  28            VIS instructions are used to facilitate the formation of
  29            easier constants, and the propagation of the sign bit.  */
  30
  31 #define TWO_TWENTYTHREE 0x4b000000              /* 2**23 */
  32
  33 #define ZERO            %f10                    /* 0.0 */
  34 #define SIGN_BIT        %f12                    /* -0.0 */
  35
  36 ENTRY (__nearbyintf_vis3)
  37         fcmps   %fcc3, %f1, %f1                 /* Check for sNaN */
  38         stx     %fsr, [%sp + STACK_BIAS + 144]
  39         sethi   %hi(0xf8003e0), %o5
  40         sethi   %hi(TWO_TWENTYTHREE), %o2
  41         ldx     [%sp + STACK_BIAS + 144], %o4
  42         or      %o5, %lo(0xf8003e0), %o5
  43         fzeros  ZERO
  44         andn    %o4, %o5, %o4
  45         fnegs   ZERO, SIGN_BIT
  46         movwtos %o2, %f16
  47         stx     %o4, [%sp + STACK_BIAS + 136]
  48         ldx     [%sp + STACK_BIAS + 136], %fsr
  49         fabss   %f1, %f14
  50         fcmps   %fcc3, %f14, %f16
  51         fmovsuge %fcc3, ZERO, %f16
  52         fands   %f1, SIGN_BIT, SIGN_BIT
  53         fors    %f16, SIGN_BIT, %f16
  54         fadds   %f1, %f16, %f5
  55         fsubs   %f5, %f16, %f0
  56         fabss   %f0, %f0
  57         fors    %f0, SIGN_BIT, %f0
  58         retl
  59          ldx    [%sp + STACK_BIAS + 144], %fsr
  60 END (__nearbyintf_vis3)