sysdeps/mach/configure.ac

   1 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   2
   3 AC_CHECK_TOOL(MIG, mig, MISSING)
   4 if test "x$MIG" = xMISSING; then
   5   AC_MSG_ERROR([cannot find required build tool mig])
   6 fi
   7 LIBC_CONFIG_VAR([MIG], [$MIG])
   8
   9 OLD_CPPFLAGS=$CPPFLAGS
  10 if test -n "$sysheaders"; then
  11   CPPFLAGS="$CPPFLAGS $SYSINCLUDES"
  12 fi
  13
  14 ### Sanity checks for Mach header installation
  15 CPPFLAGS="$CPPFLAGS -ffreestanding"
  16 AC_CHECK_HEADER(mach/mach_types.h,,
  17                 [AC_MSG_ERROR([cannot find Mach headers])], -)
  18 AC_CHECK_HEADER(mach/mach_types.defs,, [dnl
  19 AC_MSG_ERROR([cannot find Mach .defs files])], -)
  20
  21 dnl
  22 dnl mach_TYPE_CHECK(foo_t, bar_t)
  23 dnl
  24 dnl Check if foo_t is defined by <mach/mach_types.h>.
  25 dnl If not, compile with -Dfoo_t=bar_t.
  26 dnl
  27 AC_DEFUN([mach_TYPE_CHECK], [dnl
  28 AC_CACHE_CHECK(for $1 in mach/mach_types.h, libc_cv_mach_$1,
  29 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <mach/mach_types.h>]], [[extern $1 foo;]])],
  30 [libc_cv_mach_$1=$1], [libc_cv_mach_$1=$2]))
  31 if test [$]libc_cv_mach_$1 != $1; then
  32   DEFINES="$DEFINES -D$1=$2"
  33 fi])
  34
  35 dnl
  36 dnl OSF Mach has renamed these typedefs for some reason.
  37 dnl
  38 mach_TYPE_CHECK(task_t, task_port_t)
  39 mach_TYPE_CHECK(thread_t, thread_port_t)
  40
  41 dnl
  42 dnl The creation_time field is a GNU Mach addition the other variants lack.
  43 dnl
  44 AC_CACHE_CHECK(for creation_time in task_basic_info,
  45                libc_cv_mach_task_creation_time, [dnl
  46 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <mach/task_info.h>]], [[
  47 extern struct task_basic_info *i;
  48 long s = i->creation_time.seconds;
  49 ]])], [libc_cv_mach_task_creation_time=yes], [libc_cv_mach_task_creation_time=no])])
  50 if test $libc_cv_mach_task_creation_time = no; then
  51   AC_MSG_ERROR([you need Mach headers supporting task_info.creation_time])
  52 fi
  53
  54 dnl
  55 dnl The Darwin variant no longer has <mach/mach.defs>
  56 dnl but instead has several constituent .defs files.
  57 dnl In this scenario we will presume there is a <mach/mach_interface.h>
  58 dnl that contains an #include for each constituent header file,
  59 dnl but we don't do a check for that here because in a bare
  60 dnl environment the compile against those headers will fail.
  61 dnl
  62 mach_interface_list=
  63 for ifc in mach mach4 gnumach \
  64            clock clock_priv host_priv host_security ledger lock_set \
  65            processor processor_set task task_notify thread_act vm_map \
  66            memory_object memory_object_default i386/mach_i386 x86_64/mach_i386 \
  67            ; do
  68   AC_CHECK_HEADER(mach/${ifc}.defs, [dnl
  69   mach_interface_list="$mach_interface_list $ifc"],, -)
  70 done
  71 if test "x$mach_interface_list" = x; then
  72   AC_MSG_ERROR([what manner of Mach is this?])
  73 fi
  74
  75 dnl
  76 dnl mach_RPC_CHECK(interface.defs, rpc_method, define)
  77 dnl
  78 dnl Check if rpc_method RPC is defined by interface.defs
  79 dnl and define `define`.
  80 dnl
  81 AC_DEFUN([mach_RPC_CHECK], [dnl
  82 AC_CACHE_CHECK(for $2 in $1, libc_cv_mach_rpc_$2, [dnl
  83 AC_EGREP_HEADER($2, mach/$1,
  84                 libc_cv_mach_rpc_$2=yes,
  85                 libc_cv_mach_rpc_$2=no)])
  86 if test $libc_cv_mach_rpc_$2 = yes; then
  87   AC_DEFINE([$3])
  88 fi
  89 ])
  90
  91
  92 mach_RPC_CHECK(mach_host.defs, host_page_size,
  93                HAVE_HOST_PAGE_SIZE)
  94 mach_RPC_CHECK(gnumach.defs, thread_set_name,
  95                HAVE_MACH_THREAD_SET_NAME)
  96 mach_RPC_CHECK(gnumach.defs, thread_get_name,
  97                HAVE_MACH_THREAD_GET_NAME)
  98
  99 AC_CHECK_HEADER(mach/machine/ndr_def.h, [dnl
 100   DEFINES="$DEFINES -DNDR_DEF_HEADER='<mach/machine/ndr_def.h>'"], [dnl
 101 AC_CHECK_HEADER(machine/ndr_def.h, [dnl
 102   DEFINES="$DEFINES -DNDR_DEF_HEADER='<machine/ndr_def.h>'"],, -)], -)
 103
 104 AC_CACHE_CHECK(for i386_io_perm_modify in mach_i386.defs,
 105                libc_cv_mach_i386_ioports, [dnl
 106 AC_EGREP_HEADER(i386_io_perm_modify, mach/machine/mach_i386.defs,
 107                 libc_cv_mach_i386_ioports=yes,
 108                 libc_cv_mach_i386_ioports=no)])
 109 if test $libc_cv_mach_i386_ioports = yes; then
 110   AC_DEFINE([HAVE_I386_IO_PERM_MODIFY])
 111 fi
 112
 113 AC_CACHE_CHECK(for i386_set_gdt in mach_i386.defs,
 114                libc_cv_mach_i386_gdt, [dnl
 115 AC_EGREP_HEADER(i386_set_gdt, mach/machine/mach_i386.defs,
 116                 libc_cv_mach_i386_gdt=yes,
 117                 libc_cv_mach_i386_gdt=no)])
 118 if test $libc_cv_mach_i386_gdt = yes; then
 119   AC_DEFINE([HAVE_I386_SET_GDT])
 120 fi
 121
 122 CPPFLAGS=$OLD_CPPFLAGS