sysdeps/i386/fpu/e_atanh.S

   1 /* ix87 specific implementation of arctanh function.
   2    Copyright (C) 1996-2024 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 #include <machine/asm.h>
  20 #include <i386-math-asm.h>
  21 #include <libm-alias-finite.h>
  22
  23         .section .rodata
  24
  25         .align ALIGNARG(4)
  26         .type half,@object
  27 half:   .double 0.5
  28         ASM_SIZE_DIRECTIVE(half)
  29         .type one,@object
  30 one:    .double 1.0
  31         ASM_SIZE_DIRECTIVE(one)
  32         .type limit,@object
  33 limit:  .double 0.29
  34         ASM_SIZE_DIRECTIVE(limit)
  35         .type ln2_2,@object
  36 ln2_2:  .quad  0xb17217f7d1cf79ac /* 0.3465735902799726547086160  */
  37         .short 0x3ffd
  38         ASM_SIZE_DIRECTIVE(ln2_2)
  39
  40 DEFINE_DBL_MIN
  41
  42 #ifdef PIC
  43 #define MO(op) op##@GOTOFF(%edx)
  44 #else
  45 #define MO(op) op
  46 #endif
  47
  48         .text
  49 ENTRY(__ieee754_atanh)
  50         movl    8(%esp), %ecx
  51
  52         movl    %ecx, %eax
  53         andl    $0x7fffffff, %eax
  54         cmpl    $0x7ff00000, %eax
  55         jae     5f
  56 7:
  57
  58 #ifdef PIC
  59         LOAD_PIC_REG (dx)
  60 #endif
  61
  62         andl    $0x80000000, %ecx // ECX == 0 iff X >= 0
  63
  64         fldt    MO(ln2_2)       // 0.5*ln2
  65         xorl    %ecx, 8(%esp)
  66         fldl    4(%esp)         // |x| : 0.5*ln2
  67         fcoml   MO(half)        // |x| : 0.5*ln2
  68         fld     %st             // |x| : |x| : 0.5*ln2
  69         fnstsw                  // |x| : |x| : 0.5*ln2
  70         sahf
  71         jae     2f
  72         fadd    %st, %st(1)     // |x| : 2*|x| : 0.5*ln2
  73         fld     %st             // |x| : |x| : 2*|x| : 0.5*ln2
  74         fsubrl  MO(one)         // 1-|x| : |x| : 2*|x| : 0.5*ln2
  75         fxch                    // |x| : 1-|x| : 2*|x| : 0.5*ln2
  76         fmul    %st(2)          // 2*|x|^2 : 1-|x| : 2*|x| : 0.5*ln2
  77         fdivp                   // (2*|x|^2)/(1-|x|) : 2*|x| : 0.5*ln2
  78         faddp                   // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  79         fcoml   MO(limit)       // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  80         fnstsw                  // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  81         sahf
  82         jae     4f
  83         fyl2xp1                 // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
  84         DBL_CHECK_FORCE_UFLOW_NONNEG
  85         jecxz   3f
  86         fchs                    // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
  87 3:      ret
  88
  89         .align ALIGNARG(4)
  90 4:      faddl   MO(one)         // 1+2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2
  91         fyl2x                   // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|))
  92         jecxz   3f
  93         fchs                    // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x))
  94 3:      ret
  95
  96         .align ALIGNARG(4)
  97 2:      faddl   MO(one)         // 1+|x| : |x| : 0.5*ln2
  98         fxch                    // |x| : 1+|x| : 0.5*ln2
  99         fsubrl  MO(one)         // 1-|x| : 1+|x| : 0.5*ln2
 100         fdivrp                  // (1+|x|)/(1-|x|) : 0.5*ln2
 101         fyl2x                   // 0.5*ln2*ld((1+|x|)/(1-|x|))
 102         jecxz   3f
 103         fchs                    // 0.5*ln2*ld((1+x)/(1-x))
 104 3:      ret
 105
 106         // x == NaN or ±Inf
 107 5:      ja      6f
 108         cmpl    $0, 4(%esp)
 109         je      7b
 110 6:      fldl    4(%esp)
 111         ret
 112 END(__ieee754_atanh)
 113 libm_alias_finite (__ieee754_atanh, __atanh)