sysdeps/csky/abiv2/csky-mcount.S

   1 /* Implementation of profiling support.  C-SKY ABIV2 version.
   2    Copyright (C) 2018-2024 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21 /* Use an assembly stub with a special ABI.  The calling lr has been
  22    pushed to the stack (which will be misaligned).  We should preserve
  23    all registers except ip and pop a word off the stack.
  24
  25    NOTE: This assumes mcount_internal does not clobber any non-core
  26    (coprocessor) registers.  Currently this is true, but may require
  27    additional attention in the future.
  28
  29    The calling sequence looks something like:
  30 func:
  31    push lr
  32    jbsr _mount
  33    <function body>
  34 */
  35
  36 /* Don't call mcount when calling mcount...  */
  37 #undef PROF
  38
  39 ENTRY (_mcount)
  40         subi    sp, 20
  41         stw     a0, (sp, 0)
  42         stw     a1, (sp, 4)
  43         stw     a2, (sp, 8)
  44         stw     a3, (sp, 12)
  45         stw     lr, (sp, 16)
  46         mov     a1, lr
  47         ldw     a0, (sp, 20)
  48 #ifdef __PIC__
  49         grs     t1, .Lgetpc
  50 .Lgetpc:
  51         lrw     t0, .Lgetpc@GOTPC
  52         addu    t1, t0
  53         lrw     t0, __mcount_internal@PLT
  54         ldr.w   t0, (t1, t0 << 0)
  55         jsr     t0
  56 #else
  57         jsri    __mcount_internal
  58 #endif /* !__PIC__ */
  59         ldw     a0, (sp, 0)
  60         ldw     a1, (sp, 4)
  61         ldw     a2, (sp, 8)
  62         ldw     a3, (sp, 12)
  63         ldw     t1, (sp, 16)
  64         ldw     lr, (sp, 20)
  65         addi    sp, 24
  66         jmp     t1
  67 END (_mcount)