git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67     --smtp-debug            <0|1>  * Disable, enable Net::SMTP debug.
  68
  69   Automating:
  70     --identity              <str>  * Use the sendemail.<id> options.
  71     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  72     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  73     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  74     --[no-]suppress-from           * Send to self. Default off.
  75     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default off.
  76     --[no-]thread                  * Use In-Reply-To: field. Default on.
  77
  78   Administering:
  79     --confirm               <str>  * Confirm recipients before sending;
  80                                      auto, cc, compose, always, or never.
  81     --quiet                        * Output one line of info per email.
  82     --dry-run                      * Don't actually send the emails.
  83     --[no-]validate                * Perform patch sanity checks. Default on.
  84     --[no-]format-patch            * understand any non optional arguments as
  85                                      `git format-patch` ones.
  86
  87 EOT
  88         exit(1);
  89 }
  90
  91 # most mail servers generate the Date: header, but not all...
  92 sub format_2822_time {
  93         my ($time) = @_;
  94         my @localtm = localtime($time);
  95         my @gmttm = gmtime($time);
  96         my $localmin = $localtm[1] + $localtm[2] * 60;
  97         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  98         if ($localtm[0] != $gmttm[0]) {
  99                 die "local zone differs from GMT by a non-minute interval\n";
 100         }
 101         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 102                 $localmin += 1440;
 103         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 104                 $localmin -= 1440;
 105         } elsif ($gmttm[6] != $localtm[6]) {
 106                 die "local time offset greater than or equal to 24 hours\n";
 107         }
 108         my $offset = $localmin - $gmtmin;
 109         my $offhour = $offset / 60;
 110         my $offmin = abs($offset % 60);
 111         if (abs($offhour) >= 24) {
 112                 die ("local time offset greater than or equal to 24 hours\n");
 113         }
 114
 115         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 116                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 117                        $localtm[3],
 118                        qw(Jan Feb Mar Apr May Jun
 119                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 120                        $localtm[5]+1900,
 121                        $localtm[2],
 122                        $localtm[1],
 123                        $localtm[0],
 124                        ($offset >= 0) ? '+' : '-',
 125                        abs($offhour),
 126                        $offmin,
 127                        );
 128 }
 129
 130 my $have_email_valid = eval { require Email::Valid; 1 };
 131 my $have_mail_address = eval { require Mail::Address; 1 };
 132 my $smtp;
 133 my $auth;
 134
 135 sub unique_email_list(@);
 136 sub cleanup_compose_files();
 137
 138 # Variables we fill in automatically, or via prompting:
 139 my (@to,@cc,@initial_cc,@bcclist,@xh,
 140         $initial_reply_to,$initial_subject,@files,
 141         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 142
 143 my $envelope_sender;
 144
 145 # Example reply to:
 146 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 147
 148 my $repo = eval { Git->repository() };
 149 my @repo = $repo ? ($repo) : ();
 150 my $term = eval {
 151         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 152                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 153                 : new Term::ReadLine 'git-send-email';
 154 };
 155 if ($@) {
 156         $term = new FakeTerm "$@: going non-interactive";
 157 }
 158
 159 # Behavior modification variables
 160 my ($quiet, $dry_run) = (0, 0);
 161 my $format_patch;
 162 my $compose_filename;
 163
 164 # Handle interactive edition of files.
 165 my $multiedit;
 166 my $editor = Git::command_oneline('var', 'GIT_EDITOR');
 167
 168 sub do_edit {
 169         if (defined($multiedit) && !$multiedit) {
 170                 map {
 171                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 172                         if (($? & 127) || ($? >> 8)) {
 173                                 die("the editor exited uncleanly, aborting everything");
 174                         }
 175                 } @_;
 176         } else {
 177                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 178                 if (($? & 127) || ($? >> 8)) {
 179                         die("the editor exited uncleanly, aborting everything");
 180                 }
 181         }
 182 }
 183
 184 # Variables with corresponding config settings
 185 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 186 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 187 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 188 my ($validate, $confirm);
 189 my (@suppress_cc);
 190
 191 my ($debug_net_smtp) = 0;               # Net::SMTP, see send_message()
 192
 193 my $not_set_by_user = "true but not set by the user";
 194
 195 my %config_bool_settings = (
 196     "thread" => [\$thread, 1],
 197     "chainreplyto" => [\$chain_reply_to, $not_set_by_user],
 198     "suppressfrom" => [\$suppress_from, undef],
 199     "signedoffbycc" => [\$signed_off_by_cc, undef],
 200     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 201     "validate" => [\$validate, 1],
 202 );
 203
 204 my %config_settings = (
 205     "smtpserver" => \$smtp_server,
 206     "smtpserverport" => \$smtp_server_port,
 207     "smtpuser" => \$smtp_authuser,
 208     "smtppass" => \$smtp_authpass,
 209     "to" => \@to,
 210     "cc" => \@initial_cc,
 211     "cccmd" => \$cc_cmd,
 212     "aliasfiletype" => \$aliasfiletype,
 213     "bcc" => \@bcclist,
 214     "aliasesfile" => \@alias_files,
 215     "suppresscc" => \@suppress_cc,
 216     "envelopesender" => \$envelope_sender,
 217     "multiedit" => \$multiedit,
 218     "confirm"   => \$confirm,
 219     "from" => \$sender,
 220 );
 221
 222 # Help users prepare for 1.7.0
 223 sub chain_reply_to {
 224         if (defined $chain_reply_to &&
 225             $chain_reply_to eq $not_set_by_user) {
 226                 print STDERR
 227                     "In git 1.7.0, the default has changed to --no-chain-reply-to\n" .
 228                     "Set sendemail.chainreplyto configuration variable to true if\n" .
 229                     "you want to keep --chain-reply-to as your default.\n";
 230                 $chain_reply_to = 0;
 231         }
 232         return $chain_reply_to;
 233 }
 234
 235 # Handle Uncouth Termination
 236 sub signal_handler {
 237
 238         # Make text normal
 239         print color("reset"), "\n";
 240
 241         # SMTP password masked
 242         system "stty echo";
 243
 244         # tmp files from --compose
 245         if (defined $compose_filename) {
 246                 if (-e $compose_filename) {
 247                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 248                 }
 249                 if (-e ($compose_filename . ".final")) {
 250                         print "'$compose_filename.final' contains the composed email.\n"
 251                 }
 252         }
 253
 254         exit;
 255 };
 256
 257 $SIG{TERM} = \&signal_handler;
 258 $SIG{INT}  = \&signal_handler;
 259
 260 # Begin by accumulating all the variables (defined above), that we will end up
 261 # needing, first, from the command line:
 262
 263 my $rc = GetOptions("sender|from=s" => \$sender,
 264                     "in-reply-to=s" => \$initial_reply_to,
 265                     "subject=s" => \$initial_subject,
 266                     "to=s" => \@to,
 267                     "cc=s" => \@initial_cc,
 268                     "bcc=s" => \@bcclist,
 269                     "chain-reply-to!" => \$chain_reply_to,
 270                     "smtp-server=s" => \$smtp_server,
 271                     "smtp-server-port=s" => \$smtp_server_port,
 272                     "smtp-user=s" => \$smtp_authuser,
 273                     "smtp-pass:s" => \$smtp_authpass,
 274                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 275                     "smtp-encryption=s" => \$smtp_encryption,
 276                     "smtp-debug:i" => \$debug_net_smtp,
 277                     "identity=s" => \$identity,
 278                     "annotate" => \$annotate,
 279                     "compose" => \$compose,
 280                     "quiet" => \$quiet,
 281                     "cc-cmd=s" => \$cc_cmd,
 282                     "suppress-from!" => \$suppress_from,
 283                     "suppress-cc=s" => \@suppress_cc,
 284                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 285                     "confirm=s" => \$confirm,
 286                     "dry-run" => \$dry_run,
 287                     "envelope-sender=s" => \$envelope_sender,
 288                     "thread!" => \$thread,
 289                     "validate!" => \$validate,
 290                     "format-patch!" => \$format_patch,
 291          );
 292
 293 unless ($rc) {
 294     usage();
 295 }
 296
 297 die "Cannot run git format-patch from outside a repository\n"
 298         if $format_patch and not $repo;
 299
 300 # Now, let's fill any that aren't set in with defaults:
 301
 302 sub read_config {
 303         my ($prefix) = @_;
 304
 305         foreach my $setting (keys %config_bool_settings) {
 306                 my $target = $config_bool_settings{$setting}->[0];
 307                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 308         }
 309
 310         foreach my $setting (keys %config_settings) {
 311                 my $target = $config_settings{$setting};
 312                 if (ref($target) eq "ARRAY") {
 313                         unless (@$target) {
 314                                 my @values = Git::config(@repo, "$prefix.$setting");
 315                                 @$target = @values if (@values && defined $values[0]);
 316                         }
 317                 }
 318                 else {
 319                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 320                 }
 321         }
 322
 323         if (!defined $smtp_encryption) {
 324                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 325                 if (defined $enc) {
 326                         $smtp_encryption = $enc;
 327                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 328                         $smtp_encryption = 'ssl';
 329                 }
 330         }
 331 }
 332
 333 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 334 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 335 read_config("sendemail.$identity") if (defined $identity);
 336 read_config("sendemail");
 337
 338 # fall back on builtin bool defaults
 339 foreach my $setting (values %config_bool_settings) {
 340         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 341 }
 342
 343 # 'default' encryption is none -- this only prevents a warning
 344 $smtp_encryption = '' unless (defined $smtp_encryption);
 345
 346 # Set CC suppressions
 347 my(%suppress_cc);
 348 if (@suppress_cc) {
 349         foreach my $entry (@suppress_cc) {
 350                 die "Unknown --suppress-cc field: '$entry'\n"
 351                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 352                 $suppress_cc{$entry} = 1;
 353         }
 354 }
 355
 356 if ($suppress_cc{'all'}) {
 357         foreach my $entry (qw (cccmd cc author self sob body bodycc)) {
 358                 $suppress_cc{$entry} = 1;
 359         }
 360         delete $suppress_cc{'all'};
 361 }
 362
 363 # If explicit old-style ones are specified, they trump --suppress-cc.
 364 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 365 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 366
 367 if ($suppress_cc{'body'}) {
 368         foreach my $entry (qw (sob bodycc)) {
 369                 $suppress_cc{$entry} = 1;
 370         }
 371         delete $suppress_cc{'body'};
 372 }
 373
 374 # Set confirm's default value
 375 my $confirm_unconfigured = !defined $confirm;
 376 if ($confirm_unconfigured) {
 377         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 378 };
 379 die "Unknown --confirm setting: '$confirm'\n"
 380         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 381
 382 # Debugging, print out the suppressions.
 383 if (0) {
 384         print "suppressions:\n";
 385         foreach my $entry (keys %suppress_cc) {
 386                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 387         }
 388 }
 389
 390 my ($repoauthor, $repocommitter);
 391 ($repoauthor) = Git::ident_person(@repo, 'author');
 392 ($repocommitter) = Git::ident_person(@repo, 'committer');
 393
 394 # Verify the user input
 395
 396 foreach my $entry (@to) {
 397         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 398 }
 399
 400 foreach my $entry (@initial_cc) {
 401         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 402 }
 403
 404 foreach my $entry (@bcclist) {
 405         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 406 }
 407
 408 sub parse_address_line {
 409         if ($have_mail_address) {
 410                 return map { $_->format } Mail::Address->parse($_[0]);
 411         } else {
 412                 return split_addrs($_[0]);
 413         }
 414 }
 415
 416 sub split_addrs {
 417         return quotewords('\s*,\s*', 1, @_);
 418 }
 419
 420 my %aliases;
 421 my %parse_alias = (
 422         # multiline formats can be supported in the future
 423         mutt => sub { my $fh = shift; while (<$fh>) {
 424                 if (/^\s*alias\s+(?:-group\s+\S+\s+)*(\S+)\s+(.*)$/) {
 425                         my ($alias, $addr) = ($1, $2);
 426                         $addr =~ s/#.*$//; # mutt allows # comments
 427                          # commas delimit multiple addresses
 428                         $aliases{$alias} = [ split_addrs($addr) ];
 429                 }}},
 430         mailrc => sub { my $fh = shift; while (<$fh>) {
 431                 if (/^alias\s+(\S+)\s+(.*)$/) {
 432                         # spaces delimit multiple addresses
 433                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 434                 }}},
 435         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 436                 for (my $x = ''; defined($x); $x = $_) {
 437                         chomp $x;
 438                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 439                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 440                         $aliases{$1} = [ split_addrs($2) ];
 441                 }},
 442         elm => sub  { my $fh = shift;
 443                       while (<$fh>) {
 444                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 445                               my ($alias, $addr) = ($1, $2);
 446                                $aliases{$alias} = [ split_addrs($addr) ];
 447                           }
 448                       } },
 449
 450         gnus => sub { my $fh = shift; while (<$fh>) {
 451                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 452                         $aliases{$1} = [ $2 ];
 453                 }}}
 454 );
 455
 456 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 457         foreach my $file (@alias_files) {
 458                 open my $fh, '<', $file or die "opening $file: $!\n";
 459                 $parse_alias{$aliasfiletype}->($fh);
 460                 close $fh;
 461         }
 462 }
 463
 464 ($sender) = expand_aliases($sender) if defined $sender;
 465
 466 # returns 1 if the conflict must be solved using it as a format-patch argument
 467 sub check_file_rev_conflict($) {
 468         return unless $repo;
 469         my $f = shift;
 470         try {
 471                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 472                 if (defined($format_patch)) {
 473                         return $format_patch;
 474                 }
 475                 die(<<EOF);
 476 File '$f' exists but it could also be the range of commits
 477 to produce patches for.  Please disambiguate by...
 478
 479     * Saying "./$f" if you mean a file; or
 480     * Giving --format-patch option if you mean a range.
 481 EOF
 482         } catch Git::Error::Command with {
 483                 return 0;
 484         }
 485 }
 486
 487 # Now that all the defaults are set, process the rest of the command line
 488 # arguments and collect up the files that need to be processed.
 489 my @rev_list_opts;
 490 while (defined(my $f = shift @ARGV)) {
 491         if ($f eq "--") {
 492                 push @rev_list_opts, "--", @ARGV;
 493                 @ARGV = ();
 494         } elsif (-d $f and !check_file_rev_conflict($f)) {
 495                 opendir(DH,$f)
 496                         or die "Failed to opendir $f: $!";
 497
 498                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 499                                 sort readdir(DH);
 500                 closedir(DH);
 501         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 502                 push @files, $f;
 503         } else {
 504                 push @rev_list_opts, $f;
 505         }
 506 }
 507
 508 if (@rev_list_opts) {
 509         die "Cannot run git format-patch from outside a repository\n"
 510                 unless $repo;
 511         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 512 }
 513
 514 if ($validate) {
 515         foreach my $f (@files) {
 516                 unless (-p $f) {
 517                         my $error = validate_patch($f);
 518                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 519                 }
 520         }
 521 }
 522
 523 if (@files) {
 524         unless ($quiet) {
 525                 print $_,"\n" for (@files);
 526         }
 527 } else {
 528         print STDERR "\nNo patch files specified!\n\n";
 529         usage();
 530 }
 531
 532 sub get_patch_subject($) {
 533         my $fn = shift;
 534         open (my $fh, '<', $fn);
 535         while (my $line = <$fh>) {
 536                 next unless ($line =~ /^Subject: (.*)$/);
 537                 close $fh;
 538                 return "GIT: $1\n";
 539         }
 540         close $fh;
 541         die "No subject line in $fn ?";
 542 }
 543
 544 if ($compose) {
 545         # Note that this does not need to be secure, but we will make a small
 546         # effort to have it be unique
 547         $compose_filename = ($repo ?
 548                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 549                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 550         open(C,">",$compose_filename)
 551                 or die "Failed to open for writing $compose_filename: $!";
 552
 553
 554         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 555         my $tpl_subject = $initial_subject || '';
 556         my $tpl_reply_to = $initial_reply_to || '';
 557
 558         print C <<EOT;
 559 From $tpl_sender # This line is ignored.
 560 GIT: Lines beginning in "GIT:" will be removed.
 561 GIT: Consider including an overall diffstat or table of contents
 562 GIT: for the patch you are writing.
 563 GIT:
 564 GIT: Clear the body content if you don't wish to send a summary.
 565 From: $tpl_sender
 566 Subject: $tpl_subject
 567 In-Reply-To: $tpl_reply_to
 568
 569 EOT
 570         for my $f (@files) {
 571                 print C get_patch_subject($f);
 572         }
 573         close(C);
 574
 575         if ($annotate) {
 576                 do_edit($compose_filename, @files);
 577         } else {
 578                 do_edit($compose_filename);
 579         }
 580
 581         open(C2,">",$compose_filename . ".final")
 582                 or die "Failed to open $compose_filename.final : " . $!;
 583
 584         open(C,"<",$compose_filename)
 585                 or die "Failed to open $compose_filename : " . $!;
 586
 587         my $need_8bit_cte = file_has_nonascii($compose_filename);
 588         my $in_body = 0;
 589         my $summary_empty = 1;
 590         while(<C>) {
 591                 next if m/^GIT:/;
 592                 if ($in_body) {
 593                         $summary_empty = 0 unless (/^\n$/);
 594                 } elsif (/^\n$/) {
 595                         $in_body = 1;
 596                         if ($need_8bit_cte) {
 597                                 print C2 "MIME-Version: 1.0\n",
 598                                          "Content-Type: text/plain; ",
 599                                            "charset=UTF-8\n",
 600                                          "Content-Transfer-Encoding: 8bit\n";
 601                         }
 602                 } elsif (/^MIME-Version:/i) {
 603                         $need_8bit_cte = 0;
 604                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 605                         $initial_subject = $1;
 606                         my $subject = $initial_subject;
 607                         $_ = "Subject: " .
 608                                 ($subject =~ /[^[:ascii:]]/ ?
 609                                  quote_rfc2047($subject) :
 610                                  $subject) .
 611                                 "\n";
 612                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 613                         $initial_reply_to = $1;
 614                         next;
 615                 } elsif (/^From:\s*(.+)\s*$/i) {
 616                         $sender = $1;
 617                         next;
 618                 } elsif (/^(?:To|Cc|Bcc):/i) {
 619                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 620                         next;
 621                 }
 622                 print C2 $_;
 623         }
 624         close(C);
 625         close(C2);
 626
 627         if ($summary_empty) {
 628                 print "Summary email is empty, skipping it\n";
 629                 $compose = -1;
 630         }
 631 } elsif ($annotate) {
 632         do_edit(@files);
 633 }
 634
 635 sub ask {
 636         my ($prompt, %arg) = @_;
 637         my $valid_re = $arg{valid_re};
 638         my $default = $arg{default};
 639         my $resp;
 640         my $i = 0;
 641         return defined $default ? $default : undef
 642                 unless defined $term->IN and defined fileno($term->IN) and
 643                        defined $term->OUT and defined fileno($term->OUT);
 644         while ($i++ < 10) {
 645                 $resp = $term->readline($prompt);
 646                 if (!defined $resp) { # EOF
 647                         print "\n";
 648                         return defined $default ? $default : undef;
 649                 }
 650                 if ($resp eq '' and defined $default) {
 651                         return $default;
 652                 }
 653                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 654                         return $resp;
 655                 }
 656         }
 657         return undef;
 658 }
 659
 660 my $prompting = 0;
 661 if (!defined $sender) {
 662         $sender = $repoauthor || $repocommitter || '';
 663         $sender = ask("Who should the emails appear to be from? [$sender] ",
 664                       default => $sender);
 665         print "Emails will be sent from: ", $sender, "\n";
 666         $prompting++;
 667 }
 668
 669 if (!@to) {
 670         my $to = ask("Who should the emails be sent to? ");
 671         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 672         $prompting++;
 673 }
 674
 675 sub expand_aliases {
 676         return map { expand_one_alias($_) } @_;
 677 }
 678
 679 my %EXPANDED_ALIASES;
 680 sub expand_one_alias {
 681         my $alias = shift;
 682         if ($EXPANDED_ALIASES{$alias}) {
 683                 die "fatal: alias '$alias' expands to itself\n";
 684         }
 685         local $EXPANDED_ALIASES{$alias} = 1;
 686         return $aliases{$alias} ? expand_aliases(@{$aliases{$alias}}) : $alias;
 687 }
 688
 689 @to = expand_aliases(@to);
 690 @to = (map { sanitize_address($_) } @to);
 691 @initial_cc = expand_aliases(@initial_cc);
 692 @bcclist = expand_aliases(@bcclist);
 693
 694 if ($thread && !defined $initial_reply_to && $prompting) {
 695         $initial_reply_to = ask(
 696                 "Message-ID to be used as In-Reply-To for the first email? ");
 697 }
 698 if (defined $initial_reply_to) {
 699         $initial_reply_to =~ s/^\s*<?//;
 700         $initial_reply_to =~ s/>?\s*$//;
 701         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 702 }
 703
 704 if (!defined $smtp_server) {
 705         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 706                 if (-x $_) {
 707                         $smtp_server = $_;
 708                         last;
 709                 }
 710         }
 711         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 712 }
 713
 714 if ($compose && $compose > 0) {
 715         @files = ($compose_filename . ".final", @files);
 716 }
 717
 718 # Variables we set as part of the loop over files
 719 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 720         $needs_confirm, $message_num, $ask_default);
 721
 722 sub extract_valid_address {
 723         my $address = shift;
 724         my $local_part_regexp = '[^<>"\s@]+';
 725         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 726
 727         # check for a local address:
 728         return $address if ($address =~ /^($local_part_regexp)$/);
 729
 730         $address =~ s/^\s*<(.*)>\s*$/$1/;
 731         if ($have_email_valid) {
 732                 return scalar Email::Valid->address($address);
 733         } else {
 734                 # less robust/correct than the monster regexp in Email::Valid,
 735                 # but still does a 99% job, and one less dependency
 736                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 737                 return $1;
 738         }
 739 }
 740
 741 # Usually don't need to change anything below here.
 742
 743 # we make a "fake" message id by taking the current number
 744 # of seconds since the beginning of Unix time and tacking on
 745 # a random number to the end, in case we are called quicker than
 746 # 1 second since the last time we were called.
 747
 748 # We'll setup a template for the message id, using the "from" address:
 749
 750 my ($message_id_stamp, $message_id_serial);
 751 sub make_message_id
 752 {
 753         my $uniq;
 754         if (!defined $message_id_stamp) {
 755                 $message_id_stamp = sprintf("%s-%s", time, $$);
 756                 $message_id_serial = 0;
 757         }
 758         $message_id_serial++;
 759         $uniq = "$message_id_stamp-$message_id_serial";
 760
 761         my $du_part;
 762         for ($sender, $repocommitter, $repoauthor) {
 763                 $du_part = extract_valid_address(sanitize_address($_));
 764                 last if (defined $du_part and $du_part ne '');
 765         }
 766         if (not defined $du_part or $du_part eq '') {
 767                 use Sys::Hostname qw();
 768                 $du_part = 'user@' . Sys::Hostname::hostname();
 769         }
 770         my $message_id_template = "<%s-git-send-email-%s>";
 771         $message_id = sprintf($message_id_template, $uniq, $du_part);
 772         #print "new message id = $message_id\n"; # Was useful for debugging
 773 }
 774
 775
 776
 777 $time = time - scalar $#files;
 778
 779 sub unquote_rfc2047 {
 780         local ($_) = @_;
 781         my $encoding;
 782         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 783                 $encoding = $1;
 784                 s/_/ /g;
 785                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 786         }
 787         return wantarray ? ($_, $encoding) : $_;
 788 }
 789
 790 sub quote_rfc2047 {
 791         local $_ = shift;
 792         my $encoding = shift || 'UTF-8';
 793         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 794         s/(.*)/=\?$encoding\?q\?$1\?=/;
 795         return $_;
 796 }
 797
 798 sub is_rfc2047_quoted {
 799         my $s = shift;
 800         my $token = '[^][()<>@,;:"\/?.= \000-\037\177-\377]+';
 801         my $encoded_text = '[!->@-~]+';
 802         length($s) <= 75 &&
 803         $s =~ m/^(?:"[[:ascii:]]*"|=\?$token\?$token\?$encoded_text\?=)$/o;
 804 }
 805
 806 # use the simplest quoting being able to handle the recipient
 807 sub sanitize_address
 808 {
 809         my ($recipient) = @_;
 810         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 811
 812         if (not $recipient_name) {
 813                 return "$recipient";
 814         }
 815
 816         # if recipient_name is already quoted, do nothing
 817         if (is_rfc2047_quoted($recipient_name)) {
 818                 return $recipient;
 819         }
 820
 821         # rfc2047 is needed if a non-ascii char is included
 822         if ($recipient_name =~ /[^[:ascii:]]/) {
 823                 $recipient_name =~ s/^"(.*)"$/$1/;
 824                 $recipient_name = quote_rfc2047($recipient_name);
 825         }
 826
 827         # double quotes are needed if specials or CTLs are included
 828         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 829                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 830                 $recipient_name = "\"$recipient_name\"";
 831         }
 832
 833         return "$recipient_name $recipient_addr";
 834
 835 }
 836
 837 # Returns 1 if the message was sent, and 0 otherwise.
 838 # In actuality, the whole program dies when there
 839 # is an error sending a message.
 840
 841 sub send_message
 842 {
 843         my @recipients = unique_email_list(@to);
 844         @cc = (grep { my $cc = extract_valid_address($_);
 845                       not grep { $cc eq $_ } @recipients
 846                     }
 847                map { sanitize_address($_) }
 848                @cc);
 849         my $to = join (",\n\t", @recipients);
 850         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 851         @recipients = (map { extract_valid_address($_) } @recipients);
 852         my $date = format_2822_time($time++);
 853         my $gitversion = '@@GIT_VERSION@@';
 854         if ($gitversion =~ m/..GIT_VERSION../) {
 855             $gitversion = Git::version();
 856         }
 857
 858         my $cc = join(",\n\t", unique_email_list(@cc));
 859         my $ccline = "";
 860         if ($cc ne '') {
 861                 $ccline = "\nCc: $cc";
 862         }
 863         my $sanitized_sender = sanitize_address($sender);
 864         make_message_id() unless defined($message_id);
 865
 866         my $header = "From: $sanitized_sender
 867 To: $to${ccline}
 868 Subject: $subject
 869 Date: $date
 870 Message-Id: $message_id
 871 X-Mailer: git-send-email $gitversion
 872 ";
 873         if ($reply_to) {
 874
 875                 $header .= "In-Reply-To: $reply_to\n";
 876                 $header .= "References: $references\n";
 877         }
 878         if (@xh) {
 879                 $header .= join("\n", @xh) . "\n";
 880         }
 881
 882         my @sendmail_parameters = ('-i', @recipients);
 883         my $raw_from = $sanitized_sender;
 884         if (defined $envelope_sender && $envelope_sender ne "auto") {
 885                 $raw_from = $envelope_sender;
 886         }
 887         $raw_from = extract_valid_address($raw_from);
 888         unshift (@sendmail_parameters,
 889                         '-f', $raw_from) if(defined $envelope_sender);
 890
 891         if ($needs_confirm && !$dry_run) {
 892                 print "\n$header\n";
 893                 if ($needs_confirm eq "inform") {
 894                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 895                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 896                         print "    The Cc list above has been expanded by additional\n";
 897                         print "    addresses found in the patch commit message. By default\n";
 898                         print "    send-email prompts before sending whenever this occurs.\n";
 899                         print "    This behavior is controlled by the sendemail.confirm\n";
 900                         print "    configuration setting.\n";
 901                         print "\n";
 902                         print "    For additional information, run 'git send-email --help'.\n";
 903                         print "    To retain the current behavior, but squelch this message,\n";
 904                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 905                 }
 906                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 907                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 908                          default => $ask_default);
 909                 die "Send this email reply required" unless defined $_;
 910                 if (/^n/i) {
 911                         return 0;
 912                 } elsif (/^q/i) {
 913                         cleanup_compose_files();
 914                         exit(0);
 915                 } elsif (/^a/i) {
 916                         $confirm = 'never';
 917                 }
 918         }
 919
 920         if ($dry_run) {
 921                 # We don't want to send the email.
 922         } elsif ($smtp_server =~ m#^/#) {
 923                 my $pid = open my $sm, '|-';
 924                 defined $pid or die $!;
 925                 if (!$pid) {
 926                         exec($smtp_server, @sendmail_parameters) or die $!;
 927                 }
 928                 print $sm "$header\n$message";
 929                 close $sm or die $?;
 930         } else {
 931
 932                 if (!defined $smtp_server) {
 933                         die "The required SMTP server is not properly defined."
 934                 }
 935
 936                 if ($smtp_encryption eq 'ssl') {
 937                         $smtp_server_port ||= 465; # ssmtp
 938                         require Net::SMTP::SSL;
 939                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 940                 }
 941                 else {
 942                         require Net::SMTP;
 943                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 944                                                  ? "$smtp_server:$smtp_server_port"
 945                                                  : $smtp_server,
 946                                                  Debug => $debug_net_smtp);
 947                         if ($smtp_encryption eq 'tls' && $smtp) {
 948                                 require Net::SMTP::SSL;
 949                                 $smtp->command('STARTTLS');
 950                                 $smtp->response();
 951                                 if ($smtp->code == 220) {
 952                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 953                                                 or die "STARTTLS failed! ".$smtp->message;
 954                                         $smtp_encryption = '';
 955                                         # Send EHLO again to receive fresh
 956                                         # supported commands
 957                                         $smtp->hello();
 958                                 } else {
 959                                         die "Server does not support STARTTLS! ".$smtp->message;
 960                                 }
 961                         }
 962                 }
 963
 964                 if (!$smtp) {
 965                         die "Unable to initialize SMTP properly. Check config and use --smtp-debug. ",
 966                             "VALUES: server=$smtp_server ",
 967                             "encryption=$smtp_encryption ",
 968                             defined $smtp_server_port ? "port=$smtp_server_port" : "";
 969                 }
 970
 971                 if (defined $smtp_authuser) {
 972
 973                         if (!defined $smtp_authpass) {
 974
 975                                 system "stty -echo";
 976
 977                                 do {
 978                                         print "Password: ";
 979                                         $_ = <STDIN>;
 980                                         print "\n";
 981                                 } while (!defined $_);
 982
 983                                 chomp($smtp_authpass = $_);
 984
 985                                 system "stty echo";
 986                         }
 987
 988                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 989                 }
 990
 991                 $smtp->mail( $raw_from ) or die $smtp->message;
 992                 $smtp->to( @recipients ) or die $smtp->message;
 993                 $smtp->data or die $smtp->message;
 994                 $smtp->datasend("$header\n$message") or die $smtp->message;
 995                 $smtp->dataend() or die $smtp->message;
 996                 $smtp->code =~ /250|200/ or die "Failed to send $subject\n".$smtp->message;
 997         }
 998         if ($quiet) {
 999                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
1000         } else {
1001                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
1002                 if ($smtp_server !~ m#^/#) {
1003                         print "Server: $smtp_server\n";
1004                         print "MAIL FROM:<$raw_from>\n";
1005                         foreach my $entry (@recipients) {
1006                             print "RCPT TO:<$entry>\n";
1007                         }
1008                 } else {
1009                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
1010                 }
1011                 print $header, "\n";
1012                 if ($smtp) {
1013                         print "Result: ", $smtp->code, ' ',
1014                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
1015                 } else {
1016                         print "Result: OK\n";
1017                 }
1018         }
1019
1020         return 1;
1021 }
1022
1023 $reply_to = $initial_reply_to;
1024 $references = $initial_reply_to || '';
1025 $subject = $initial_subject;
1026 $message_num = 0;
1027
1028 foreach my $t (@files) {
1029         open(F,"<",$t) or die "can't open file $t";
1030
1031         my $author = undef;
1032         my $author_encoding;
1033         my $has_content_type;
1034         my $body_encoding;
1035         @cc = ();
1036         @xh = ();
1037         my $input_format = undef;
1038         my @header = ();
1039         $message = "";
1040         $message_num++;
1041         # First unfold multiline header fields
1042         while(<F>) {
1043                 last if /^\s*$/;
1044                 if (/^\s+\S/ and @header) {
1045                         chomp($header[$#header]);
1046                         s/^\s+/ /;
1047                         $header[$#header] .= $_;
1048             } else {
1049                         push(@header, $_);
1050                 }
1051         }
1052         # Now parse the header
1053         foreach(@header) {
1054                 if (/^From /) {
1055                         $input_format = 'mbox';
1056                         next;
1057                 }
1058                 chomp;
1059                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1060                         $input_format = 'mbox';
1061                 }
1062
1063                 if (defined $input_format && $input_format eq 'mbox') {
1064                         if (/^Subject:\s+(.*)$/) {
1065                                 $subject = $1;
1066                         }
1067                         elsif (/^From:\s+(.*)$/) {
1068                                 ($author, $author_encoding) = unquote_rfc2047($1);
1069                                 next if $suppress_cc{'author'};
1070                                 next if $suppress_cc{'self'} and $author eq $sender;
1071                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1072                                         $1, $_) unless $quiet;
1073                                 push @cc, $1;
1074                         }
1075                         elsif (/^Cc:\s+(.*)$/) {
1076                                 foreach my $addr (parse_address_line($1)) {
1077                                         if (unquote_rfc2047($addr) eq $sender) {
1078                                                 next if ($suppress_cc{'self'});
1079                                         } else {
1080                                                 next if ($suppress_cc{'cc'});
1081                                         }
1082                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1083                                                 $addr, $_) unless $quiet;
1084                                         push @cc, $addr;
1085                                 }
1086                         }
1087                         elsif (/^Content-type:/i) {
1088                                 $has_content_type = 1;
1089                                 if (/charset="?([^ "]+)/) {
1090                                         $body_encoding = $1;
1091                                 }
1092                                 push @xh, $_;
1093                         }
1094                         elsif (/^Message-Id: (.*)/i) {
1095                                 $message_id = $1;
1096                         }
1097                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1098                                 push @xh, $_;
1099                         }
1100
1101                 } else {
1102                         # In the traditional
1103                         # "send lots of email" format,
1104                         # line 1 = cc
1105                         # line 2 = subject
1106                         # So let's support that, too.
1107                         $input_format = 'lots';
1108                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1109                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1110                                         $_, $_) unless $quiet;
1111                                 push @cc, $_;
1112                         } elsif (!defined $subject) {
1113                                 $subject = $_;
1114                         }
1115                 }
1116         }
1117         # Now parse the message body
1118         while(<F>) {
1119                 $message .=  $_;
1120                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1121                         chomp;
1122                         my ($what, $c) = ($1, $2);
1123                         chomp $c;
1124                         if ($c eq $sender) {
1125                                 next if ($suppress_cc{'self'});
1126                         } else {
1127                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1128                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1129                         }
1130                         push @cc, $c;
1131                         printf("(body) Adding cc: %s from line '%s'\n",
1132                                 $c, $_) unless $quiet;
1133                 }
1134         }
1135         close F;
1136
1137         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1138                 open(F, "$cc_cmd \Q$t\E |")
1139                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1140                 while(<F>) {
1141                         my $c = $_;
1142                         $c =~ s/^\s*//g;
1143                         $c =~ s/\n$//g;
1144                         next if ($c eq $sender and $suppress_from);
1145                         push @cc, $c;
1146                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1147                                 $c, $cc_cmd) unless $quiet;
1148                 }
1149                 close F
1150                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1151         }
1152
1153         if (defined $author and $author ne $sender) {
1154                 $message = "From: $author\n\n$message";
1155                 if (defined $author_encoding) {
1156                         if ($has_content_type) {
1157                                 if ($body_encoding eq $author_encoding) {
1158                                         # ok, we already have the right encoding
1159                                 }
1160                                 else {
1161                                         # uh oh, we should re-encode
1162                                 }
1163                         }
1164                         else {
1165                                 push @xh,
1166                                   'MIME-Version: 1.0',
1167                                   "Content-Type: text/plain; charset=$author_encoding",
1168                                   'Content-Transfer-Encoding: 8bit';
1169                         }
1170                 }
1171         }
1172
1173         $needs_confirm = (
1174                 $confirm eq "always" or
1175                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1176                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1177         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1178
1179         @cc = (@initial_cc, @cc);
1180
1181         my $message_was_sent = send_message();
1182
1183         # set up for the next message
1184         if ($thread && $message_was_sent &&
1185                 (chain_reply_to() || !defined $reply_to || length($reply_to) == 0)) {
1186                 $reply_to = $message_id;
1187                 if (length $references > 0) {
1188                         $references .= "\n $message_id";
1189                 } else {
1190                         $references = "$message_id";
1191                 }
1192         }
1193         $message_id = undef;
1194 }
1195
1196 cleanup_compose_files();
1197
1198 sub cleanup_compose_files() {
1199         unlink($compose_filename, $compose_filename . ".final") if $compose;
1200 }
1201
1202 $smtp->quit if $smtp;
1203
1204 sub unique_email_list(@) {
1205         my %seen;
1206         my @emails;
1207
1208         foreach my $entry (@_) {
1209                 if (my $clean = extract_valid_address($entry)) {
1210                         $seen{$clean} ||= 0;
1211                         next if $seen{$clean}++;
1212                         push @emails, $entry;
1213                 } else {
1214                         print STDERR "W: unable to extract a valid address",
1215                                         " from: $entry\n";
1216                 }
1217         }
1218         return @emails;
1219 }
1220
1221 sub validate_patch {
1222         my $fn = shift;
1223         open(my $fh, '<', $fn)
1224                 or die "unable to open $fn: $!\n";
1225         while (my $line = <$fh>) {
1226                 if (length($line) > 998) {
1227                         return "$.: patch contains a line longer than 998 characters";
1228                 }
1229         }
1230         return undef;
1231 }
1232
1233 sub file_has_nonascii {
1234         my $fn = shift;
1235         open(my $fh, '<', $fn)
1236                 or die "unable to open $fn: $!\n";
1237         while (my $line = <$fh>) {
1238                 return 1 if $line =~ /[^[:ascii:]]/;
1239         }
1240         return 0;
1241 }