?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
gitweb: Make project description in projects list link to summary view
[git/dscho.git] / git-svn.perl
blob0a47b1f9fd4bfcbfabb41433049ab7a1361dd449
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $SVN_URL $SVN_INFO $SVN_WC $SVN_UUID
8 $GIT_SVN_INDEX $GIT_SVN
9 $GIT_DIR $GIT_SVN_DIR $REVDB/;
10 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
11 $VERSION = '@@GIT_VERSION@@';
12
13 use Cwd qw/abs_path/;
14 $GIT_DIR = abs_path($ENV{GIT_DIR} || '.git');
15 $ENV{GIT_DIR} = $GIT_DIR;
16
17 my $LC_ALL = $ENV{LC_ALL};
18 my $TZ = $ENV{TZ};
19 # make sure the svn binary gives consistent output between locales and TZs:
20 $ENV{TZ} = 'UTC';
21 $ENV{LC_ALL} = 'C';
22 $| = 1; # unbuffer STDOUT
23
24 sub fatal (@) { print STDERR $@; exit 1 }
25 # If SVN:: library support is added, please make the dependencies
26 # optional and preserve the capability to use the command-line client.
27 # use eval { require SVN::... } to make it lazy load
28 # We don't use any modules not in the standard Perl distribution:
29 use Carp qw/croak/;
30 use IO::File qw//;
31 use File::Basename qw/dirname basename/;
32 use File::Path qw/mkpath/;
33 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev pass_through/;
34 use File::Spec qw//;
35 use File::Copy qw/copy/;
36 use POSIX qw/strftime/;
37 use IPC::Open3;
38 use Memoize;
39 memoize('revisions_eq');
40 memoize('cmt_metadata');
41 memoize('get_commit_time');
42
43 my ($SVN, $_use_lib);
44
45 sub nag_lib {
46 print STDERR <<EOF;
47 ! Please consider installing the SVN Perl libraries (version 1.1.0 or
48 ! newer). You will generally get better performance and fewer bugs,
49 ! especially if you:
50 ! 1) have a case-insensitive filesystem
51 ! 2) replace symlinks with files (and vice-versa) in commits
52
53 EOF
54 }
55
56 $_use_lib = 1 unless $ENV{GIT_SVN_NO_LIB};
57 libsvn_load();
58 nag_lib() unless $_use_lib;
59
60 my $_optimize_commits = 1 unless $ENV{GIT_SVN_NO_OPTIMIZE_COMMITS};
61 my $sha1 = qr/[a-f\d]{40}/;
62 my $sha1_short = qr/[a-f\d]{4,40}/;
63 my ($_revision,$_stdin,$_no_ignore_ext,$_no_stop_copy,$_help,$_rmdir,$_edit,
64 $_find_copies_harder, $_l, $_cp_similarity, $_cp_remote,
65 $_repack, $_repack_nr, $_repack_flags, $_q,
66 $_message, $_file, $_follow_parent, $_no_metadata,
67 $_template, $_shared, $_no_default_regex, $_no_graft_copy,
68 $_limit, $_verbose, $_incremental, $_oneline, $_l_fmt, $_show_commit,
69 $_version, $_upgrade, $_authors, $_branch_all_refs, @_opt_m,
70 $_merge, $_strategy, $_dry_run, $_ignore_nodate, $_non_recursive,
71 $_username, $_config_dir, $_no_auth_cache);
72 my (@_branch_from, %tree_map, %users, %rusers, %equiv);
73 my ($_svn_co_url_revs, $_svn_pg_peg_revs);
74 my @repo_path_split_cache;
75
76 my %fc_opts = ( 'no-ignore-externals' => \$_no_ignore_ext,
77 'branch|b=s' => \@_branch_from,
78 'follow-parent|follow' => \$_follow_parent,
79 'branch-all-refs|B' => \$_branch_all_refs,
80 'authors-file|A=s' => \$_authors,
81 'repack:i' => \$_repack,
82 'no-metadata' => \$_no_metadata,
83 'quiet|q' => \$_q,
84 'username=s' => \$_username,
85 'config-dir=s' => \$_config_dir,
86 'no-auth-cache' => \$_no_auth_cache,
87 'ignore-nodate' => \$_ignore_nodate,
88 'repack-flags|repack-args|repack-opts=s' => \$_repack_flags);
89
90 my ($_trunk, $_tags, $_branches);
91 my %multi_opts = ( 'trunk|T=s' => \$_trunk,
92 'tags|t=s' => \$_tags,
93 'branches|b=s' => \$_branches );
94 my %init_opts = ( 'template=s' => \$_template, 'shared' => \$_shared );
95 my %cmt_opts = ( 'edit|e' => \$_edit,
96 'rmdir' => \$_rmdir,
97 'find-copies-harder' => \$_find_copies_harder,
98 'l=i' => \$_l,
99 'copy-similarity|C=i'=> \$_cp_similarity
100 );
101
102 my %cmd = (
103 fetch => [ \&fetch, "Download new revisions from SVN",
104 { 'revision|r=s' => \$_revision, %fc_opts } ],
105 init => [ \&init, "Initialize a repo for tracking" .
106 " (requires URL argument)",
107 \%init_opts ],
108 commit => [ \&commit, "Commit git revisions to SVN",
109 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
110 'show-ignore' => [ \&show_ignore, "Show svn:ignore listings",
111 { 'revision|r=i' => \$_revision } ],
112 rebuild => [ \&rebuild, "Rebuild git-svn metadata (after git clone)",
113 { 'no-ignore-externals' => \$_no_ignore_ext,
114 'copy-remote|remote=s' => \$_cp_remote,
115 'upgrade' => \$_upgrade } ],
116 'graft-branches' => [ \&graft_branches,
117 'Detect merges/branches from already imported history',
118 { 'merge-rx|m' => \@_opt_m,
119 'branch|b=s' => \@_branch_from,
120 'branch-all-refs|B' => \$_branch_all_refs,
121 'no-default-regex' => \$_no_default_regex,
122 'no-graft-copy' => \$_no_graft_copy } ],
123 'multi-init' => [ \&multi_init,
124 'Initialize multiple trees (like git-svnimport)',
125 { %multi_opts, %fc_opts } ],
126 'multi-fetch' => [ \&multi_fetch,
127 'Fetch multiple trees (like git-svnimport)',
128 \%fc_opts ],
129 'log' => [ \&show_log, 'Show commit logs',
130 { 'limit=i' => \$_limit,
131 'revision|r=s' => \$_revision,
132 'verbose|v' => \$_verbose,
133 'incremental' => \$_incremental,
134 'oneline' => \$_oneline,
135 'show-commit' => \$_show_commit,
136 'non-recursive' => \$_non_recursive,
137 'authors-file|A=s' => \$_authors,
138 } ],
139 'commit-diff' => [ \&commit_diff, 'Commit a diff between two trees',
140 { 'message|m=s' => \$_message,
141 'file|F=s' => \$_file,
142 'revision|r=s' => \$_revision,
143 %cmt_opts } ],
144 dcommit => [ \&dcommit, 'Commit several diffs to merge with upstream',
145 { 'merge|m|M' => \$_merge,
146 'strategy|s=s' => \$_strategy,
147 'dry-run|n' => \$_dry_run,
148 %cmt_opts } ],
149 );
150
151 my $cmd;
152 for (my $i = 0; $i < @ARGV; $i++) {
153 if (defined $cmd{$ARGV[$i]}) {
154 $cmd = $ARGV[$i];
155 splice @ARGV, $i, 1;
156 last;
157 }
158 };
159
160 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
161
162 read_repo_config(\%opts);
163 my $rv = GetOptions(%opts, 'help|H|h' => \$_help,
164 'version|V' => \$_version,
165 'id|i=s' => \$GIT_SVN);
166 exit 1 if (!$rv && $cmd ne 'log');
167
168 set_default_vals();
169 usage(0) if $_help;
170 version() if $_version;
171 usage(1) unless defined $cmd;
172 init_vars();
173 load_authors() if $_authors;
174 load_all_refs() if $_branch_all_refs;
175 svn_compat_check() unless $_use_lib;
176 migration_check() unless $cmd =~ /^(?:init|rebuild|multi-init|commit-diff)$/;
177 $cmd{$cmd}->[0]->(@ARGV);
178 exit 0;
179
180 ####################### primary functions ######################
181 sub usage {
182 my $exit = shift || 0;
183 my $fd = $exit ? \*STDERR : \*STDOUT;
184 print $fd <<"";
185 git-svn - bidirectional operations between a single Subversion tree and git
186 Usage: $0 <command> [options] [arguments]\n
187
188 print $fd "Available commands:\n" unless $cmd;
189
190 foreach (sort keys %cmd) {
191 next if $cmd && $cmd ne $_;
192 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
193 foreach (keys %{$cmd{$_}->[2]}) {
194 # prints out arguments as they should be passed:
195 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
196 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
197 "--$_" : "-$_" }
198 split /\|/,$_)," $x\n";
199 }
200 }
201 print $fd <<"";
202 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
203 arbitrary identifier if you're tracking multiple SVN branches/repositories in
204 one git repository and want to keep them separate. See git-svn(1) for more
205 information.
206
207 exit $exit;
208 }
209
210 sub version {
211 print "git-svn version $VERSION\n";
212 exit 0;
213 }
214
215 sub rebuild {
216 if (quiet_run(qw/git-rev-parse --verify/,"refs/remotes/$GIT_SVN^0")) {
217 copy_remote_ref();
218 }
219 $SVN_URL = shift or undef;
220 my $newest_rev = 0;
221 if ($_upgrade) {
222 sys('git-update-ref',"refs/remotes/$GIT_SVN","$GIT_SVN-HEAD");
223 } else {
224 check_upgrade_needed();
225 }
226
227 my $pid = open(my $rev_list,'-|');
228 defined $pid or croak $!;
229 if ($pid == 0) {
230 exec("git-rev-list","refs/remotes/$GIT_SVN") or croak $!;
231 }
232 my $latest;
233 while (<$rev_list>) {
234 chomp;
235 my $c = $_;
236 croak "Non-SHA1: $c\n" unless $c =~ /^$sha1$/o;
237 my @commit = grep(/^git-svn-id: /,`git-cat-file commit $c`);
238 next if (!@commit); # skip merges
239 my ($url, $rev, $uuid) = extract_metadata($commit[$#commit]);
240 if (!defined $rev || !$uuid) {
241 croak "Unable to extract revision or UUID from ",
242 "$c, $commit[$#commit]\n";
243 }
244
245 # if we merged or otherwise started elsewhere, this is
246 # how we break out of it
247 next if (defined $SVN_UUID && ($uuid ne $SVN_UUID));
248 next if (defined $SVN_URL && defined $url && ($url ne $SVN_URL));
249
250 unless (defined $latest) {
251 if (!$SVN_URL && !$url) {
252 croak "SVN repository location required: $url\n";
253 }
254 $SVN_URL ||= $url;
255 $SVN_UUID ||= $uuid;
256 setup_git_svn();
257 $latest = $rev;
258 }
259 revdb_set($REVDB, $rev, $c);
260 print "r$rev = $c\n";
261 $newest_rev = $rev if ($rev > $newest_rev);
262 }
263 close $rev_list or croak $?;
264
265 goto out if $_use_lib;
266 if (!chdir $SVN_WC) {
267 svn_cmd_checkout($SVN_URL, $latest, $SVN_WC);
268 chdir $SVN_WC or croak $!;
269 }
270
271 $pid = fork;
272 defined $pid or croak $!;
273 if ($pid == 0) {
274 my @svn_up = qw(svn up);
275 push @svn_up, '--ignore-externals' unless $_no_ignore_ext;
276 sys(@svn_up,"-r$newest_rev");
277 $ENV{GIT_INDEX_FILE} = $GIT_SVN_INDEX;
278 index_changes();
279 exec('git-write-tree') or croak $!;
280 }
281 waitpid $pid, 0;
282 croak $? if $?;
283 out:
284 if ($_upgrade) {
285 print STDERR <<"";
286 Keeping deprecated refs/head/$GIT_SVN-HEAD for now. Please remove it
287 when you have upgraded your tools and habits to use refs/remotes/$GIT_SVN
288
289 }
290 }
291
292 sub init {
293 my $url = shift or die "SVN repository location required " .
294 "as a command-line argument\n";
295 $url =~ s!/+$!!; # strip trailing slash
296
297 if (my $repo_path = shift) {
298 unless (-d $repo_path) {
299 mkpath([$repo_path]);
300 }
301 $GIT_DIR = $ENV{GIT_DIR} = $repo_path . "/.git";
302 init_vars();
303 }
304
305 $SVN_URL = $url;
306 unless (-d $GIT_DIR) {
307 my @init_db = ('git-init-db');
308 push @init_db, "--template=$_template" if defined $_template;
309 push @init_db, "--shared" if defined $_shared;
310 sys(@init_db);
311 }
312 setup_git_svn();
313 }
314
315 sub fetch {
316 check_upgrade_needed();
317 $SVN_URL ||= file_to_s("$GIT_SVN_DIR/info/url");
318 my $ret = $_use_lib ? fetch_lib(@_) : fetch_cmd(@_);
319 if ($ret->{commit} && quiet_run(qw(git-rev-parse --verify
320 refs/heads/master^0))) {
321 sys(qw(git-update-ref refs/heads/master),$ret->{commit});
322 }
323 return $ret;
324 }
325
326 sub fetch_cmd {
327 my (@parents) = @_;
328 my @log_args = -d $SVN_WC ? ($SVN_WC) : ($SVN_URL);
329 unless ($_revision) {
330 $_revision = -d $SVN_WC ? 'BASE:HEAD' : '0:HEAD';
331 }
332 push @log_args, "-r$_revision";
333 push @log_args, '--stop-on-copy' unless $_no_stop_copy;
334
335 my $svn_log = svn_log_raw(@log_args);
336
337 my $base = next_log_entry($svn_log) or croak "No base revision!\n";
338 # don't need last_revision from grab_base_rev() because
339 # user could've specified a different revision to skip (they
340 # didn't want to import certain revisions into git for whatever
341 # reason, so trust $base->{revision} instead.
342 my (undef, $last_commit) = svn_grab_base_rev();
343 unless (-d $SVN_WC) {
344 svn_cmd_checkout($SVN_URL,$base->{revision},$SVN_WC);
345 chdir $SVN_WC or croak $!;
346 read_uuid();
347 $last_commit = git_commit($base, @parents);
348 assert_tree($last_commit);
349 } else {
350 chdir $SVN_WC or croak $!;
351 read_uuid();
352 # looks like a user manually cp'd and svn switch'ed
353 unless ($last_commit) {
354 sys(qw/svn revert -R ./);
355 assert_svn_wc_clean($base->{revision});
356 $last_commit = git_commit($base, @parents);
357 assert_tree($last_commit);
358 }
359 }
360 my @svn_up = qw(svn up);
361 push @svn_up, '--ignore-externals' unless $_no_ignore_ext;
362 my $last = $base;
363 while (my $log_msg = next_log_entry($svn_log)) {
364 if ($last->{revision} >= $log_msg->{revision}) {
365 croak "Out of order: last >= current: ",
366 "$last->{revision} >= $log_msg->{revision}\n";
367 }
368 # Revert is needed for cases like:
369 # https://svn.musicpd.org/Jamming/trunk (r166:167), but
370 # I can't seem to reproduce something like that on a test...
371 sys(qw/svn revert -R ./);
372 assert_svn_wc_clean($last->{revision});
373 sys(@svn_up,"-r$log_msg->{revision}");
374 $last_commit = git_commit($log_msg, $last_commit, @parents);
375 $last = $log_msg;
376 }
377 close $svn_log->{fh};
378 $last->{commit} = $last_commit;
379 return $last;
380 }
381
382 sub fetch_lib {
383 my (@parents) = @_;
384 $SVN_URL ||= file_to_s("$GIT_SVN_DIR/info/url");
385 $SVN ||= libsvn_connect($SVN_URL);
386 my ($last_rev, $last_commit) = svn_grab_base_rev();
387 my ($base, $head) = libsvn_parse_revision($last_rev);
388 if ($base > $head) {
389 return { revision => $last_rev, commit => $last_commit }
390 }
391 my $index = set_index($GIT_SVN_INDEX);
392
393 # limit ourselves and also fork() since get_log won't release memory
394 # after processing a revision and SVN stuff seems to leak
395 my $inc = 1000;
396 my ($min, $max) = ($base, $head < $base+$inc ? $head : $base+$inc);
397 read_uuid();
398 if (defined $last_commit) {
399 unless (-e $GIT_SVN_INDEX) {
400 sys(qw/git-read-tree/, $last_commit);
401 }
402 chomp (my $x = `git-write-tree`);
403 my ($y) = (`git-cat-file commit $last_commit`
404 =~ /^tree ($sha1)/m);
405 if ($y ne $x) {
406 unlink $GIT_SVN_INDEX or croak $!;
407 sys(qw/git-read-tree/, $last_commit);
408 }
409 chomp ($x = `git-write-tree`);
410 if ($y ne $x) {
411 print STDERR "trees ($last_commit) $y != $x\n",
412 "Something is seriously wrong...\n";
413 }
414 }
415 while (1) {
416 # fork, because using SVN::Pool with get_log() still doesn't
417 # seem to help enough to keep memory usage down.
418 defined(my $pid = fork) or croak $!;
419 if (!$pid) {
420 $SVN::Error::handler = \&libsvn_skip_unknown_revs;
421
422 # Yes I'm perfectly aware that the fourth argument
423 # below is the limit revisions number. Unfortunately
424 # performance sucks with it enabled, so it's much
425 # faster to fetch revision ranges instead of relying
426 # on the limiter.
427 libsvn_get_log(libsvn_dup_ra($SVN), [''],
428 $min, $max, 0, 1, 1,
429 sub {
430 my $log_msg;
431 if ($last_commit) {
432 $log_msg = libsvn_fetch(
433 $last_commit, @_);
434 $last_commit = git_commit(
435 $log_msg,
436 $last_commit,
437 @parents);
438 } else {
439 $log_msg = libsvn_new_tree(@_);
440 $last_commit = git_commit(
441 $log_msg, @parents);
442 }
443 });
444 exit 0;
445 }
446 waitpid $pid, 0;
447 croak $? if $?;
448 ($last_rev, $last_commit) = svn_grab_base_rev();
449 last if ($max >= $head);
450 $min = $max + 1;
451 $max += $inc;
452 $max = $head if ($max > $head);
453 }
454 restore_index($index);
455 return { revision => $last_rev, commit => $last_commit };
456 }
457
458 sub commit {
459 my (@commits) = @_;
460 check_upgrade_needed();
461 if ($_stdin || !@commits) {
462 print "Reading from stdin...\n";
463 @commits = ();
464 while (<STDIN>) {
465 if (/\b($sha1_short)\b/o) {
466 unshift @commits, $1;
467 }
468 }
469 }
470 my @revs;
471 foreach my $c (@commits) {
472 chomp(my @tmp = safe_qx('git-rev-parse',$c));
473 if (scalar @tmp == 1) {
474 push @revs, $tmp[0];
475 } elsif (scalar @tmp > 1) {
476 push @revs, reverse (safe_qx('git-rev-list',@tmp));
477 } else {
478 die "Failed to rev-parse $c\n";
479 }
480 }
481 chomp @revs;
482 $_use_lib ? commit_lib(@revs) : commit_cmd(@revs);
483 print "Done committing ",scalar @revs," revisions to SVN\n";
484 }
485
486 sub commit_cmd {
487 my (@revs) = @_;
488
489 chdir $SVN_WC or croak "Unable to chdir $SVN_WC: $!\n";
490 my $info = svn_info('.');
491 my $fetched = fetch();
492 if ($info->{Revision} != $fetched->{revision}) {
493 print STDERR "There are new revisions that were fetched ",
494 "and need to be merged (or acknowledged) ",
495 "before committing.\n";
496 exit 1;
497 }
498 $info = svn_info('.');
499 read_uuid($info);
500 my $last = $fetched;
501 foreach my $c (@revs) {
502 my $mods = svn_checkout_tree($last, $c);
503 if (scalar @$mods == 0) {
504 print "Skipping, no changes detected\n";
505 next;
506 }
507 $last = svn_commit_tree($last, $c);
508 }
509 }
510
511 sub commit_lib {
512 my (@revs) = @_;
513 my ($r_last, $cmt_last) = svn_grab_base_rev();
514 defined $r_last or die "Must have an existing revision to commit\n";
515 my $fetched = fetch();
516 if ($r_last != $fetched->{revision}) {
517 print STDERR "There are new revisions that were fetched ",
518 "and need to be merged (or acknowledged) ",
519 "before committing.\n",
520 "last rev: $r_last\n",
521 " current: $fetched->{revision}\n";
522 exit 1;
523 }
524 read_uuid();
525 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
526 my $commit_msg = "$GIT_SVN_DIR/.svn-commit.tmp.$$";
527
528 my $repo;
529 set_svn_commit_env();
530 foreach my $c (@revs) {
531 my $log_msg = get_commit_message($c, $commit_msg);
532
533 # fork for each commit because there's a memory leak I
534 # can't track down... (it's probably in the SVN code)
535 defined(my $pid = open my $fh, '-|') or croak $!;
536 if (!$pid) {
537 my $ed = SVN::Git::Editor->new(
538 { r => $r_last,
539 ra => libsvn_dup_ra($SVN),
540 c => $c,
541 svn_path => $SVN->{svn_path},
542 },
543 $SVN->get_commit_editor(
544 $log_msg->{msg},
545 sub {
546 libsvn_commit_cb(
547 @_, $c,
548 $log_msg->{msg},
549 $r_last,
550 $cmt_last)
551 },
552 @lock)
553 );
554 my $mods = libsvn_checkout_tree($cmt_last, $c, $ed);
555 if (@$mods == 0) {
556 print "No changes\nr$r_last = $cmt_last\n";
557 $ed->abort_edit;
558 } else {
559 $ed->close_edit;
560 }
561 exit 0;
562 }
563 my ($r_new, $cmt_new, $no);
564 while (<$fh>) {
565 print $_;
566 chomp;
567 if (/^r(\d+) = ($sha1)$/o) {
568 ($r_new, $cmt_new) = ($1, $2);
569 } elsif ($_ eq 'No changes') {
570 $no = 1;
571 }
572 }
573 close $fh or exit 1;
574 if (! defined $r_new && ! defined $cmt_new) {
575 unless ($no) {
576 die "Failed to parse revision information\n";
577 }
578 } else {
579 ($r_last, $cmt_last) = ($r_new, $cmt_new);
580 }
581 }
582 $ENV{LC_ALL} = 'C';
583 unlink $commit_msg;
584 }
585
586 sub dcommit {
587 my $gs = "refs/remotes/$GIT_SVN";
588 chomp(my @refs = safe_qx(qw/git-rev-list --no-merges/, "$gs..HEAD"));
589 my $last_rev;
590 foreach my $d (reverse @refs) {
591 if (quiet_run('git-rev-parse','--verify',"$d~1") != 0) {
592 die "Commit $d\n",
593 "has no parent commit, and therefore ",
594 "nothing to diff against.\n",
595 "You should be working from a repository ",
596 "originally created by git-svn\n";
597 }
598 unless (defined $last_rev) {
599 (undef, $last_rev, undef) = cmt_metadata("$d~1");
600 unless (defined $last_rev) {
601 die "Unable to extract revision information ",
602 "from commit $d~1\n";
603 }
604 }
605 if ($_dry_run) {
606 print "diff-tree $d~1 $d\n";
607 } else {
608 if (my $r = commit_diff("$d~1", $d, undef, $last_rev)) {
609 $last_rev = $r;
610 } # else: no changes, same $last_rev
611 }
612 }
613 return if $_dry_run;
614 fetch();
615 my @diff = safe_qx(qw/git-diff-tree HEAD/, $gs);
616 my @finish;
617 if (@diff) {
618 @finish = qw/rebase/;
619 push @finish, qw/--merge/ if $_merge;
620 push @finish, "--strategy=$_strategy" if $_strategy;
621 print STDERR "W: HEAD and $gs differ, using @finish:\n", @diff;
622 } else {
623 print "No changes between current HEAD and $gs\n",
624 "Hard resetting to the latest $gs\n";
625 @finish = qw/reset --mixed/;
626 }
627 sys('git', @finish, $gs);
628 }
629
630 sub show_ignore {
631 $SVN_URL ||= file_to_s("$GIT_SVN_DIR/info/url");
632 $_use_lib ? show_ignore_lib() : show_ignore_cmd();
633 }
634
635 sub show_ignore_cmd {
636 require File::Find or die $!;
637 if (defined $_revision) {
638 die "-r/--revision option doesn't work unless the Perl SVN ",
639 "libraries are used\n";
640 }
641 chdir $SVN_WC or croak $!;
642 my %ign;
643 File::Find::find({wanted=>sub{if(lstat $_ && -d _ && -d "$_/.svn"){
644 s#^\./##;
645 @{$ign{$_}} = svn_propget_base('svn:ignore', $_);
646 }}, no_chdir=>1},'.');
647
648 print "\n# /\n";
649 foreach (@{$ign{'.'}}) { print '/',$_ if /\S/ }
650 delete $ign{'.'};
651 foreach my $i (sort keys %ign) {
652 print "\n# ",$i,"\n";
653 foreach (@{$ign{$i}}) { print '/',$i,'/',$_ if /\S/ }
654 }
655 }
656
657 sub show_ignore_lib {
658 my $repo;
659 $SVN ||= libsvn_connect($SVN_URL);
660 my $r = defined $_revision ? $_revision : $SVN->get_latest_revnum;
661 libsvn_traverse_ignore(\*STDOUT, $SVN->{svn_path}, $r);
662 }
663
664 sub graft_branches {
665 my $gr_file = "$GIT_DIR/info/grafts";
666 my ($grafts, $comments) = read_grafts($gr_file);
667 my $gr_sha1;
668
669 if (%$grafts) {
670 # temporarily disable our grafts file to make this idempotent
671 chomp($gr_sha1 = safe_qx(qw/git-hash-object -w/,$gr_file));
672 rename $gr_file, "$gr_file~$gr_sha1" or croak $!;
673 }
674
675 my $l_map = read_url_paths();
676 my @re = map { qr/$_/is } @_opt_m if @_opt_m;
677 unless ($_no_default_regex) {
678 push @re, (qr/\b(?:merge|merging|merged)\s+with\s+([\w\.\-]+)/i,
679 qr/\b(?:merge|merging|merged)\s+([\w\.\-]+)/i,
680 qr/\b(?:from|of)\s+([\w\.\-]+)/i );
681 }
682 foreach my $u (keys %$l_map) {
683 if (@re) {
684 foreach my $p (keys %{$l_map->{$u}}) {
685 graft_merge_msg($grafts,$l_map,$u,$p,@re);
686 }
687 }
688 unless ($_no_graft_copy) {
689 if ($_use_lib) {
690 graft_file_copy_lib($grafts,$l_map,$u);
691 } else {
692 graft_file_copy_cmd($grafts,$l_map,$u);
693 }
694 }
695 }
696 graft_tree_joins($grafts);
697
698 write_grafts($grafts, $comments, $gr_file);
699 unlink "$gr_file~$gr_sha1" if $gr_sha1;
700 }
701
702 sub multi_init {
703 my $url = shift;
704 $_trunk ||= 'trunk';
705 $_trunk =~ s#/+$##;
706 $url =~ s#/+$## if $url;
707 if ($_trunk !~ m#^[a-z\+]+://#) {
708 $_trunk = '/' . $_trunk if ($_trunk !~ m#^/#);
709 unless ($url) {
710 print STDERR "E: '$_trunk' is not a complete URL ",
711 "and a separate URL is not specified\n";
712 exit 1;
713 }
714 $_trunk = $url . $_trunk;
715 }
716 my $ch_id;
717 if ($GIT_SVN eq 'git-svn') {
718 $ch_id = 1;
719 $GIT_SVN = $ENV{GIT_SVN_ID} = 'trunk';
720 }
721 init_vars();
722 unless (-d $GIT_SVN_DIR) {
723 print "GIT_SVN_ID set to 'trunk' for $_trunk\n" if $ch_id;
724 init($_trunk);
725 sys('git-repo-config', 'svn.trunk', $_trunk);
726 }
727 complete_url_ls_init($url, $_branches, '--branches/-b', '');
728 complete_url_ls_init($url, $_tags, '--tags/-t', 'tags/');
729 }
730
731 sub multi_fetch {
732 # try to do trunk first, since branches/tags
733 # may be descended from it.
734 if (-e "$GIT_DIR/svn/trunk/info/url") {
735 fetch_child_id('trunk', @_);
736 }
737 rec_fetch('', "$GIT_DIR/svn", @_);
738 }
739
740 sub show_log {
741 my (@args) = @_;
742 my ($r_min, $r_max);
743 my $r_last = -1; # prevent dupes
744 rload_authors() if $_authors;
745 if (defined $TZ) {
746 $ENV{TZ} = $TZ;
747 } else {
748 delete $ENV{TZ};
749 }
750 if (defined $_revision) {
751 if ($_revision =~ /^(\d+):(\d+)$/) {
752 ($r_min, $r_max) = ($1, $2);
753 } elsif ($_revision =~ /^\d+$/) {
754 $r_min = $r_max = $_revision;
755 } else {
756 print STDERR "-r$_revision is not supported, use ",
757 "standard \'git log\' arguments instead\n";
758 exit 1;
759 }
760 }
761
762 my $pid = open(my $log,'-|');
763 defined $pid or croak $!;
764 if (!$pid) {
765 exec(git_svn_log_cmd($r_min,$r_max), @args) or croak $!;
766 }
767 setup_pager();
768 my (@k, $c, $d);
769
770 while (<$log>) {
771 if (/^commit ($sha1_short)/o) {
772 my $cmt = $1;
773 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
774 $r_last = $c->{r};
775 process_commit($c, $r_min, $r_max, \@k) or
776 goto out;
777 }
778 $d = undef;
779 $c = { c => $cmt };
780 } elsif (/^author (.+) (\d+) ([\-\+]?\d+)$/) {
781 get_author_info($c, $1, $2, $3);
782 } elsif (/^(?:tree|parent|committer) /) {
783 # ignore
784 } elsif (/^:\d{6} \d{6} $sha1_short/o) {
785 push @{$c->{raw}}, $_;
786 } elsif (/^[ACRMDT]\t/) {
787 # we could add $SVN->{svn_path} here, but that requires
788 # remote access at the moment (repo_path_split)...
789 s#^([ACRMDT])\t# $1 #;
790 push @{$c->{changed}}, $_;
791 } elsif (/^diff /) {
792 $d = 1;
793 push @{$c->{diff}}, $_;
794 } elsif ($d) {
795 push @{$c->{diff}}, $_;
796 } elsif (/^ (git-svn-id:.+)$/) {
797 ($c->{url}, $c->{r}, undef) = extract_metadata($1);
798 } elsif (s/^ //) {
799 push @{$c->{l}}, $_;
800 }
801 }
802 if ($c && defined $c->{r} && $c->{r} != $r_last) {
803 $r_last = $c->{r};
804 process_commit($c, $r_min, $r_max, \@k);
805 }
806 if (@k) {
807 my $swap = $r_max;
808 $r_max = $r_min;
809 $r_min = $swap;
810 process_commit($_, $r_min, $r_max) foreach reverse @k;
811 }
812 out:
813 close $log;
814 print '-' x72,"\n" unless $_incremental || $_oneline;
815 }
816
817 sub commit_diff_usage {
818 print STDERR "Usage: $0 commit-diff <tree-ish> <tree-ish> [<URL>]\n";
819 exit 1
820 }
821
822 sub commit_diff {
823 if (!$_use_lib) {
824 print STDERR "commit-diff must be used with SVN libraries\n";
825 exit 1;
826 }
827 my $ta = shift or commit_diff_usage();
828 my $tb = shift or commit_diff_usage();
829 if (!eval { $SVN_URL = shift || file_to_s("$GIT_SVN_DIR/info/url") }) {
830 print STDERR "Needed URL or usable git-svn id command-line\n";
831 commit_diff_usage();
832 }
833 my $r = shift;
834 unless (defined $r) {
835 if (defined $_revision) {
836 $r = $_revision
837 } else {
838 die "-r|--revision is a required argument\n";
839 }
840 }
841 if (defined $_message && defined $_file) {
842 print STDERR "Both --message/-m and --file/-F specified ",
843 "for the commit message.\n",
844 "I have no idea what you mean\n";
845 exit 1;
846 }
847 if (defined $_file) {
848 $_message = file_to_s($_file);
849 } else {
850 $_message ||= get_commit_message($tb,
851 "$GIT_DIR/.svn-commit.tmp.$$")->{msg};
852 }
853 $SVN ||= libsvn_connect($SVN_URL);
854 if ($r eq 'HEAD') {
855 $r = $SVN->get_latest_revnum;
856 } elsif ($r !~ /^\d+$/) {
857 die "revision argument: $r not understood by git-svn\n";
858 }
859 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
860 my $rev_committed;
861 my $ed = SVN::Git::Editor->new({ r => $r,
862 ra => libsvn_dup_ra($SVN),
863 c => $tb,
864 svn_path => $SVN->{svn_path}
865 },
866 $SVN->get_commit_editor($_message,
867 sub {
868 $rev_committed = $_[0];
869 print "Committed $_[0]\n";
870 }, @lock)
871 );
872 eval {
873 my $mods = libsvn_checkout_tree($ta, $tb, $ed);
874 if (@$mods == 0) {
875 print "No changes\n$ta == $tb\n";
876 $ed->abort_edit;
877 } else {
878 $ed->close_edit;
879 }
880 };
881 fatal "$@\n" if $@;
882 $_message = $_file = undef;
883 return $rev_committed;
884 }
885
886 ########################### utility functions #########################
887
888 sub cmt_showable {
889 my ($c) = @_;
890 return 1 if defined $c->{r};
891 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
892 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
893 my @msg = safe_qx(qw/git-cat-file commit/, $c->{c});
894 shift @msg while ($msg[0] ne "\n");
895 shift @msg;
896 @{$c->{l}} = grep !/^git-svn-id: /, @msg;
897
898 (undef, $c->{r}, undef) = extract_metadata(
899 (grep(/^git-svn-id: /, @msg))[-1]);
900 }
901 return defined $c->{r};
902 }
903
904 sub git_svn_log_cmd {
905 my ($r_min, $r_max) = @_;
906 my @cmd = (qw/git-log --abbrev-commit --pretty=raw
907 --default/, "refs/remotes/$GIT_SVN");
908 push @cmd, '-r' unless $_non_recursive;
909 push @cmd, qw/--raw --name-status/ if $_verbose;
910 return @cmd unless defined $r_max;
911 if ($r_max == $r_min) {
912 push @cmd, '--max-count=1';
913 if (my $c = revdb_get($REVDB, $r_max)) {
914 push @cmd, $c;
915 }
916 } else {
917 my ($c_min, $c_max);
918 $c_max = revdb_get($REVDB, $r_max);
919 $c_min = revdb_get($REVDB, $r_min);
920 if (defined $c_min && defined $c_max) {
921 if ($r_max > $r_max) {
922 push @cmd, "$c_min..$c_max";
923 } else {
924 push @cmd, "$c_max..$c_min";
925 }
926 } elsif ($r_max > $r_min) {
927 push @cmd, $c_max;
928 } else {
929 push @cmd, $c_min;
930 }
931 }
932 return @cmd;
933 }
934
935 sub fetch_child_id {
936 my $id = shift;
937 print "Fetching $id\n";
938 my $ref = "$GIT_DIR/refs/remotes/$id";
939 defined(my $pid = open my $fh, '-|') or croak $!;
940 if (!$pid) {
941 $_repack = undef;
942 $GIT_SVN = $ENV{GIT_SVN_ID} = $id;
943 init_vars();
944 fetch(@_);
945 exit 0;
946 }
947 while (<$fh>) {
948 print $_;
949 check_repack() if (/^r\d+ = $sha1/);
950 }
951 close $fh or croak $?;
952 }
953
954 sub rec_fetch {
955 my ($pfx, $p, @args) = @_;
956 my @dir;
957 foreach (sort <$p/*>) {
958 if (-r "$_/info/url") {
959 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
960 my $id = $pfx . basename $_;
961 next if $id eq 'trunk';
962 fetch_child_id($id, @args);
963 } elsif (-d $_) {
964 push @dir, $_;
965 }
966 }
967 foreach (@dir) {
968 my $x = $_;
969 $x =~ s!^\Q$GIT_DIR\E/svn/!!;
970 rec_fetch($x, $_);
971 }
972 }
973
974 sub complete_url_ls_init {
975 my ($url, $var, $switch, $pfx) = @_;
976 unless ($var) {
977 print STDERR "W: $switch not specified\n";
978 return;
979 }
980 $var =~ s#/+$##;
981 if ($var !~ m#^[a-z\+]+://#) {
982 $var = '/' . $var if ($var !~ m#^/#);
983 unless ($url) {
984 print STDERR "E: '$var' is not a complete URL ",
985 "and a separate URL is not specified\n";
986 exit 1;
987 }
988 $var = $url . $var;
989 }
990 chomp(my @ls = $_use_lib ? libsvn_ls_fullurl($var)
991 : safe_qx(qw/svn ls --non-interactive/, $var));
992 my $old = $GIT_SVN;
993 defined(my $pid = fork) or croak $!;
994 if (!$pid) {
995 foreach my $u (map { "$var/$_" } (grep m!/$!, @ls)) {
996 $u =~ s#/+$##;
997 if ($u !~ m!\Q$var\E/(.+)$!) {
998 print STDERR "W: Unrecognized URL: $u\n";
999 die "This should never happen\n";
1000 }
1001 # don't try to init already existing refs
1002 my $id = $pfx.$1;
1003 $GIT_SVN = $ENV{GIT_SVN_ID} = $id;
1004 init_vars();
1005 unless (-d $GIT_SVN_DIR) {
1006 print "init $u => $id\n";
1007 init($u);
1008 }
1009 }
1010 exit 0;
1011 }
1012 waitpid $pid, 0;
1013 croak $? if $?;
1014 my ($n) = ($switch =~ /^--(\w+)/);
1015 sys('git-repo-config', "svn.$n", $var);
1016 }
1017
1018 sub common_prefix {
1019 my $paths = shift;
1020 my %common;
1021 foreach (@$paths) {
1022 my @tmp = split m#/#, $_;
1023 my $p = '';
1024 while (my $x = shift @tmp) {
1025 $p .= "/$x";
1026 $common{$p} ||= 0;
1027 $common{$p}++;
1028 }
1029 }
1030 foreach (sort {length $b <=> length $a} keys %common) {
1031 if ($common{$_} == @$paths) {
1032 return $_;
1033 }
1034 }
1035 return '';
1036 }
1037
1038 # grafts set here are 'stronger' in that they're based on actual tree
1039 # matches, and won't be deleted from merge-base checking in write_grafts()
1040 sub graft_tree_joins {
1041 my $grafts = shift;
1042 map_tree_joins() if (@_branch_from && !%tree_map);
1043 return unless %tree_map;
1044
1045 git_svn_each(sub {
1046 my $i = shift;
1047 defined(my $pid = open my $fh, '-|') or croak $!;
1048 if (!$pid) {
1049 exec qw/git-rev-list --pretty=raw/,
1050 "refs/remotes/$i" or croak $!;
1051 }
1052 while (<$fh>) {
1053 next unless /^commit ($sha1)$/o;
1054 my $c = $1;
1055 my ($t) = (<$fh> =~ /^tree ($sha1)$/o);
1056 next unless $tree_map{$t};
1057
1058 my $l;
1059 do {
1060 $l = readline $fh;
1061 } until ($l =~ /^committer (?:.+) (\d+) ([\-\+]?\d+)$/);
1062
1063 my ($s, $tz) = ($1, $2);
1064 if ($tz =~ s/^\+//) {
1065 $s += tz_to_s_offset($tz);
1066 } elsif ($tz =~ s/^\-//) {
1067 $s -= tz_to_s_offset($tz);
1068 }
1069
1070 my ($url_a, $r_a, $uuid_a) = cmt_metadata($c);
1071
1072 foreach my $p (@{$tree_map{$t}}) {
1073 next if $p eq $c;
1074 my $mb = eval {
1075 safe_qx('git-merge-base', $c, $p)
1076 };
1077 next unless ($@ || $?);
1078 if (defined $r_a) {
1079 # see if SVN says it's a relative
1080 my ($url_b, $r_b, $uuid_b) =
1081 cmt_metadata($p);
1082 next if (defined $url_b &&
1083 defined $url_a &&
1084 ($url_a eq $url_b) &&
1085 ($uuid_a eq $uuid_b));
1086 if ($uuid_a eq $uuid_b) {
1087 if ($r_b < $r_a) {
1088 $grafts->{$c}->{$p} = 2;
1089 next;
1090 } elsif ($r_b > $r_a) {
1091 $grafts->{$p}->{$c} = 2;
1092 next;
1093 }
1094 }
1095 }
1096 my $ct = get_commit_time($p);
1097 if ($ct < $s) {
1098 $grafts->{$c}->{$p} = 2;
1099 } elsif ($ct > $s) {
1100 $grafts->{$p}->{$c} = 2;
1101 }
1102 # what should we do when $ct == $s ?
1103 }
1104 }
1105 close $fh or croak $?;
1106 });
1107 }
1108
1109 # this isn't funky-filename safe, but good enough for now...
1110 sub graft_file_copy_cmd {
1111 my ($grafts, $l_map, $u) = @_;
1112 my $paths = $l_map->{$u};
1113 my $pfx = common_prefix([keys %$paths]);
1114 $SVN_URL ||= $u.$pfx;
1115 my $pid = open my $fh, '-|';
1116 defined $pid or croak $!;
1117 unless ($pid) {
1118 my @exec = qw/svn log -v/;
1119 push @exec, "-r$_revision" if defined $_revision;
1120 exec @exec, $u.$pfx or croak $!;
1121 }
1122 my ($r, $mp) = (undef, undef);
1123 while (<$fh>) {
1124 chomp;
1125 if (/^\-{72}$/) {
1126 $mp = $r = undef;
1127 } elsif (/^r(\d+) \| /) {
1128 $r = $1 unless defined $r;
1129 } elsif (/^Changed paths:/) {
1130 $mp = 1;
1131 } elsif ($mp && m#^ [AR] /(\S.*?) \(from /(\S+?):(\d+)\)$#) {
1132 my ($p1, $p0, $r0) = ($1, $2, $3);
1133 my $c = find_graft_path_commit($paths, $p1, $r);
1134 next unless $c;
1135 find_graft_path_parents($grafts, $paths, $c, $p0, $r0);
1136 }
1137 }
1138 }
1139
1140 sub graft_file_copy_lib {
1141 my ($grafts, $l_map, $u) = @_;
1142 my $tree_paths = $l_map->{$u};
1143 my $pfx = common_prefix([keys %$tree_paths]);
1144 my ($repo, $path) = repo_path_split($u.$pfx);
1145 $SVN = libsvn_connect($repo);
1146
1147 my ($base, $head) = libsvn_parse_revision();
1148 my $inc = 1000;
1149 my ($min, $max) = ($base, $head < $base+$inc ? $head : $base+$inc);
1150 my $eh = $SVN::Error::handler;
1151 $SVN::Error::handler = \&libsvn_skip_unknown_revs;
1152 while (1) {
1153 my $pool = SVN::Pool->new;
1154 libsvn_get_log(libsvn_dup_ra($SVN), [$path],
1155 $min, $max, 0, 1, 1,
1156 sub {
1157 libsvn_graft_file_copies($grafts, $tree_paths,
1158 $path, @_);
1159 }, $pool);
1160 $pool->clear;
1161 last if ($max >= $head);
1162 $min = $max + 1;
1163 $max += $inc;
1164 $max = $head if ($max > $head);
1165 }
1166 $SVN::Error::handler = $eh;
1167 }
1168
1169 sub process_merge_msg_matches {
1170 my ($grafts, $l_map, $u, $p, $c, @matches) = @_;
1171 my (@strong, @weak);
1172 foreach (@matches) {
1173 # merging with ourselves is not interesting
1174 next if $_ eq $p;
1175 if ($l_map->{$u}->{$_}) {
1176 push @strong, $_;
1177 } else {
1178 push @weak, $_;
1179 }
1180 }
1181 foreach my $w (@weak) {
1182 last if @strong;
1183 # no exact match, use branch name as regexp.
1184 my $re = qr/\Q$w\E/i;
1185 foreach (keys %{$l_map->{$u}}) {
1186 if (/$re/) {
1187 push @strong, $l_map->{$u}->{$_};
1188 last;
1189 }
1190 }
1191 last if @strong;
1192 $w = basename($w);
1193 $re = qr/\Q$w\E/i;
1194 foreach (keys %{$l_map->{$u}}) {
1195 if (/$re/) {
1196 push @strong, $l_map->{$u}->{$_};
1197 last;
1198 }
1199 }
1200 }
1201 my ($rev) = ($c->{m} =~ /^git-svn-id:\s(?:\S+?)\@(\d+)
1202 \s(?:[a-f\d\-]+)$/xsm);
1203 unless (defined $rev) {
1204 ($rev) = ($c->{m} =~/^git-svn-id:\s(\d+)
1205 \@(?:[a-f\d\-]+)/xsm);
1206 return unless defined $rev;
1207 }
1208 foreach my $m (@strong) {
1209 my ($r0, $s0) = find_rev_before($rev, $m, 1);
1210 $grafts->{$c->{c}}->{$s0} = 1 if defined $s0;
1211 }
1212 }
1213
1214 sub graft_merge_msg {
1215 my ($grafts, $l_map, $u, $p, @re) = @_;
1216
1217 my $x = $l_map->{$u}->{$p};
1218 my $rl = rev_list_raw($x);
1219 while (my $c = next_rev_list_entry($rl)) {
1220 foreach my $re (@re) {
1221 my (@br) = ($c->{m} =~ /$re/g);
1222 next unless @br;
1223 process_merge_msg_matches($grafts,$l_map,$u,$p,$c,@br);
1224 }
1225 }
1226 }
1227
1228 sub read_uuid {
1229 return if $SVN_UUID;
1230 if ($_use_lib) {
1231 my $pool = SVN::Pool->new;
1232 $SVN_UUID = $SVN->get_uuid($pool);
1233 $pool->clear;
1234 } else {
1235 my $info = shift || svn_info('.');
1236 $SVN_UUID = $info->{'Repository UUID'} or
1237 croak "Repository UUID unreadable\n";
1238 }
1239 }
1240
1241 sub quiet_run {
1242 my $pid = fork;
1243 defined $pid or croak $!;
1244 if (!$pid) {
1245 open my $null, '>', '/dev/null' or croak $!;
1246 open STDERR, '>&', $null or croak $!;
1247 open STDOUT, '>&', $null or croak $!;
1248 exec @_ or croak $!;
1249 }
1250 waitpid $pid, 0;
1251 return $?;
1252 }
1253
1254 sub repo_path_split {
1255 my $full_url = shift;
1256 $full_url =~ s#/+$##;
1257
1258 foreach (@repo_path_split_cache) {
1259 if ($full_url =~ s#$_##) {
1260 my $u = $1;
1261 $full_url =~ s#^/+##;
1262 return ($u, $full_url);
1263 }
1264 }
1265 if ($_use_lib) {
1266 my $tmp = libsvn_connect($full_url);
1267 return ($tmp->{repos_root}, $tmp->{svn_path});
1268 } else {
1269 my ($url, $path) = ($full_url =~ m!^([a-z\+]+://[^/]*)(.*)$!i);
1270 $path =~ s#^/+##;
1271 my @paths = split(m#/+#, $path);
1272 while (quiet_run(qw/svn ls --non-interactive/, $url)) {
1273 my $n = shift @paths || last;
1274 $url .= "/$n";
1275 }
1276 push @repo_path_split_cache, qr/^(\Q$url\E)/;
1277 $path = join('/',@paths);
1278 return ($url, $path);
1279 }
1280 }
1281
1282 sub setup_git_svn {
1283 defined $SVN_URL or croak "SVN repository location required\n";
1284 unless (-d $GIT_DIR) {
1285 croak "GIT_DIR=$GIT_DIR does not exist!\n";
1286 }
1287 mkpath([$GIT_SVN_DIR]);
1288 mkpath(["$GIT_SVN_DIR/info"]);
1289 open my $fh, '>>',$REVDB or croak $!;
1290 close $fh;
1291 s_to_file($SVN_URL,"$GIT_SVN_DIR/info/url");
1292
1293 }
1294
1295 sub assert_svn_wc_clean {
1296 return if $_use_lib;
1297 my ($svn_rev) = @_;
1298 croak "$svn_rev is not an integer!\n" unless ($svn_rev =~ /^\d+$/);
1299 my $lcr = svn_info('.')->{'Last Changed Rev'};
1300 if ($svn_rev != $lcr) {
1301 print STDERR "Checking for copy-tree ... ";
1302 my @diff = grep(/^Index: /,(safe_qx(qw(svn diff),
1303 "-r$lcr:$svn_rev")));
1304 if (@diff) {
1305 croak "Nope! Expected r$svn_rev, got r$lcr\n";
1306 } else {
1307 print STDERR "OK!\n";
1308 }
1309 }
1310 my @status = grep(!/^Performing status on external/,(`svn status`));
1311 @status = grep(!/^\s*$/,@status);
1312 @status = grep(!/^X/,@status) if $_no_ignore_ext;
1313 if (scalar @status) {
1314 print STDERR "Tree ($SVN_WC) is not clean:\n";
1315 print STDERR $_ foreach @status;
1316 croak;
1317 }
1318 }
1319
1320 sub get_tree_from_treeish {
1321 my ($treeish) = @_;
1322 croak "Not a sha1: $treeish\n" unless $treeish =~ /^$sha1$/o;
1323 chomp(my $type = `git-cat-file -t $treeish`);
1324 my $expected;
1325 while ($type eq 'tag') {
1326 chomp(($treeish, $type) = `git-cat-file tag $treeish`);
1327 }
1328 if ($type eq 'commit') {
1329 $expected = (grep /^tree /,`git-cat-file commit $treeish`)[0];
1330 ($expected) = ($expected =~ /^tree ($sha1)$/);
1331 die "Unable to get tree from $treeish\n" unless $expected;
1332 } elsif ($type eq 'tree') {
1333 $expected = $treeish;
1334 } else {
1335 die "$treeish is a $type, expected tree, tag or commit\n";
1336 }
1337 return $expected;
1338 }
1339
1340 sub assert_tree {
1341 return if $_use_lib;
1342 my ($treeish) = @_;
1343 my $expected = get_tree_from_treeish($treeish);
1344
1345 my $tmpindex = $GIT_SVN_INDEX.'.assert-tmp';
1346 if (-e $tmpindex) {
1347 unlink $tmpindex or croak $!;
1348 }
1349 my $old_index = set_index($tmpindex);
1350 index_changes(1);
1351 chomp(my $tree = `git-write-tree`);
1352 restore_index($old_index);
1353 if ($tree ne $expected) {
1354 croak "Tree mismatch, Got: $tree, Expected: $expected\n";
1355 }
1356 unlink $tmpindex;
1357 }
1358
1359 sub parse_diff_tree {
1360 my $diff_fh = shift;
1361 local $/ = "\0";
1362 my $state = 'meta';
1363 my @mods;
1364 while (<$diff_fh>) {
1365 chomp $_; # this gets rid of the trailing "\0"
1366 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
1367 $sha1\s($sha1)\s([MTCRAD])\d*$/xo) {
1368 push @mods, { mode_a => $1, mode_b => $2,
1369 sha1_b => $3, chg => $4 };
1370 if ($4 =~ /^(?:C|R)$/) {
1371 $state = 'file_a';
1372 } else {
1373 $state = 'file_b';
1374 }
1375 } elsif ($state eq 'file_a') {
1376 my $x = $mods[$#mods] or croak "Empty array\n";
1377 if ($x->{chg} !~ /^(?:C|R)$/) {
1378 croak "Error parsing $_, $x->{chg}\n";
1379 }
1380 $x->{file_a} = $_;
1381 $state = 'file_b';
1382 } elsif ($state eq 'file_b') {
1383 my $x = $mods[$#mods] or croak "Empty array\n";
1384 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
1385 croak "Error parsing $_, $x->{chg}\n";
1386 }
1387 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
1388 croak "Error parsing $_, $x->{chg}\n";
1389 }
1390 $x->{file_b} = $_;
1391 $state = 'meta';
1392 } else {
1393 croak "Error parsing $_\n";
1394 }
1395 }
1396 close $diff_fh or croak $?;
1397
1398 return \@mods;
1399 }
1400
1401 sub svn_check_prop_executable {
1402 my $m = shift;
1403 return if -l $m->{file_b};
1404 if ($m->{mode_b} =~ /755$/) {
1405 chmod((0755 &~ umask),$m->{file_b}) or croak $!;
1406 if ($m->{mode_a} !~ /755$/) {
1407 sys(qw(svn propset svn:executable 1), $m->{file_b});
1408 }
1409 -x $m->{file_b} or croak "$m->{file_b} is not executable!\n";
1410 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
1411 sys(qw(svn propdel svn:executable), $m->{file_b});
1412 chmod((0644 &~ umask),$m->{file_b}) or croak $!;
1413 -x $m->{file_b} and croak "$m->{file_b} is executable!\n";
1414 }
1415 }
1416
1417 sub svn_ensure_parent_path {
1418 my $dir_b = dirname(shift);
1419 svn_ensure_parent_path($dir_b) if ($dir_b ne File::Spec->curdir);
1420 mkpath([$dir_b]) unless (-d $dir_b);
1421 sys(qw(svn add -N), $dir_b) unless (-d "$dir_b/.svn");
1422 }
1423
1424 sub precommit_check {
1425 my $mods = shift;
1426 my (%rm_file, %rmdir_check, %added_check);
1427
1428 my %o = ( D => 0, R => 1, C => 2, A => 3, M => 3, T => 3 );
1429 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
1430 if ($m->{chg} eq 'R') {
1431 if (-d $m->{file_b}) {
1432 err_dir_to_file("$m->{file_a} => $m->{file_b}");
1433 }
1434 # dir/$file => dir/file/$file
1435 my $dirname = dirname($m->{file_b});
1436 while ($dirname ne File::Spec->curdir) {
1437 if ($dirname ne $m->{file_a}) {
1438 $dirname = dirname($dirname);
1439 next;
1440 }
1441 err_file_to_dir("$m->{file_a} => $m->{file_b}");
1442 }
1443 # baz/zzz => baz (baz is a file)
1444 $dirname = dirname($m->{file_a});
1445 while ($dirname ne File::Spec->curdir) {
1446 if ($dirname ne $m->{file_b}) {
1447 $dirname = dirname($dirname);
1448 next;
1449 }
1450 err_dir_to_file("$m->{file_a} => $m->{file_b}");
1451 }
1452 }
1453 if ($m->{chg} =~ /^(D|R)$/) {
1454 my $t = $1 eq 'D' ? 'file_b' : 'file_a';
1455 $rm_file{ $m->{$t} } = 1;
1456 my $dirname = dirname( $m->{$t} );
1457 my $basename = basename( $m->{$t} );
1458 $rmdir_check{$dirname}->{$basename} = 1;
1459 } elsif ($m->{chg} =~ /^(?:A|C)$/) {
1460 if (-d $m->{file_b}) {
1461 err_dir_to_file($m->{file_b});
1462 }
1463 my $dirname = dirname( $m->{file_b} );
1464 my $basename = basename( $m->{file_b} );
1465 $added_check{$dirname}->{$basename} = 1;
1466 while ($dirname ne File::Spec->curdir) {
1467 if ($rm_file{$dirname}) {
1468 err_file_to_dir($m->{file_b});
1469 }
1470 $dirname = dirname $dirname;
1471 }
1472 }
1473 }
1474 return (\%rmdir_check, \%added_check);
1475
1476 sub err_dir_to_file {
1477 my $file = shift;
1478 print STDERR "Node change from directory to file ",
1479 "is not supported by Subversion: ",$file,"\n";
1480 exit 1;
1481 }
1482 sub err_file_to_dir {
1483 my $file = shift;
1484 print STDERR "Node change from file to directory ",
1485 "is not supported by Subversion: ",$file,"\n";
1486 exit 1;
1487 }
1488 }
1489
1490
1491 sub get_diff {
1492 my ($from, $treeish) = @_;
1493 assert_tree($from);
1494 print "diff-tree $from $treeish\n";
1495 my $pid = open my $diff_fh, '-|';
1496 defined $pid or croak $!;
1497 if ($pid == 0) {
1498 my @diff_tree = qw(git-diff-tree -z -r);
1499 if ($_cp_similarity) {
1500 push @diff_tree, "-C$_cp_similarity";
1501 } else {
1502 push @diff_tree, '-C';
1503 }
1504 push @diff_tree, '--find-copies-harder' if $_find_copies_harder;
1505 push @diff_tree, "-l$_l" if defined $_l;
1506 exec(@diff_tree, $from, $treeish) or croak $!;
1507 }
1508 return parse_diff_tree($diff_fh);
1509 }
1510
1511 sub svn_checkout_tree {
1512 my ($from, $treeish) = @_;
1513 my $mods = get_diff($from->{commit}, $treeish);
1514 return $mods unless (scalar @$mods);
1515 my ($rm, $add) = precommit_check($mods);
1516
1517 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
1518 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
1519 if ($m->{chg} eq 'C') {
1520 svn_ensure_parent_path( $m->{file_b} );
1521 sys(qw(svn cp), $m->{file_a}, $m->{file_b});
1522 apply_mod_line_blob($m);
1523 svn_check_prop_executable($m);
1524 } elsif ($m->{chg} eq 'D') {
1525 sys(qw(svn rm --force), $m->{file_b});
1526 } elsif ($m->{chg} eq 'R') {
1527 svn_ensure_parent_path( $m->{file_b} );
1528 sys(qw(svn mv --force), $m->{file_a}, $m->{file_b});
1529 apply_mod_line_blob($m);
1530 svn_check_prop_executable($m);
1531 } elsif ($m->{chg} eq 'M') {
1532 apply_mod_line_blob($m);
1533 svn_check_prop_executable($m);
1534 } elsif ($m->{chg} eq 'T') {
1535 svn_check_prop_executable($m);
1536 apply_mod_line_blob($m);
1537 if ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
1538 sys(qw(svn propdel svn:special), $m->{file_b});
1539 } else {
1540 sys(qw(svn propset svn:special *),$m->{file_b});
1541 }
1542 } elsif ($m->{chg} eq 'A') {
1543 svn_ensure_parent_path( $m->{file_b} );
1544 apply_mod_line_blob($m);
1545 sys(qw(svn add), $m->{file_b});
1546 svn_check_prop_executable($m);
1547 } else {
1548 croak "Invalid chg: $m->{chg}\n";
1549 }
1550 }
1551
1552 assert_tree($treeish);
1553 if ($_rmdir) { # remove empty directories
1554 handle_rmdir($rm, $add);
1555 }
1556 assert_tree($treeish);
1557 return $mods;
1558 }
1559
1560 sub libsvn_checkout_tree {
1561 my ($from, $treeish, $ed) = @_;
1562 my $mods = get_diff($from, $treeish);
1563 return $mods unless (scalar @$mods);
1564 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
1565 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
1566 my $f = $m->{chg};
1567 if (defined $o{$f}) {
1568 $ed->$f($m, $_q);
1569 } else {
1570 croak "Invalid change type: $f\n";
1571 }
1572 }
1573 $ed->rmdirs($_q) if $_rmdir;
1574 return $mods;
1575 }
1576
1577 # svn ls doesn't work with respect to the current working tree, but what's
1578 # in the repository. There's not even an option for it... *sigh*
1579 # (added files don't show up and removed files remain in the ls listing)
1580 sub svn_ls_current {
1581 my ($dir, $rm, $add) = @_;
1582 chomp(my @ls = safe_qx('svn','ls',$dir));
1583 my @ret = ();
1584 foreach (@ls) {
1585 s#/$##; # trailing slashes are evil
1586 push @ret, $_ unless $rm->{$dir}->{$_};
1587 }
1588 if (exists $add->{$dir}) {
1589 push @ret, keys %{$add->{$dir}};
1590 }
1591 return \@ret;
1592 }
1593
1594 sub handle_rmdir {
1595 my ($rm, $add) = @_;
1596
1597 foreach my $dir (sort {length $b <=> length $a} keys %$rm) {
1598 my $ls = svn_ls_current($dir, $rm, $add);
1599 next if (scalar @$ls);
1600 sys(qw(svn rm --force),$dir);
1601
1602 my $dn = dirname $dir;
1603 $rm->{ $dn }->{ basename $dir } = 1;
1604 $ls = svn_ls_current($dn, $rm, $add);
1605 while (scalar @$ls == 0 && $dn ne File::Spec->curdir) {
1606 sys(qw(svn rm --force),$dn);
1607 $dir = basename $dn;
1608 $dn = dirname $dn;
1609 $rm->{ $dn }->{ $dir } = 1;
1610 $ls = svn_ls_current($dn, $rm, $add);
1611 }
1612 }
1613 }
1614
1615 sub get_commit_message {
1616 my ($commit, $commit_msg) = (@_);
1617 my %log_msg = ( msg => '' );
1618 open my $msg, '>', $commit_msg or croak $!;
1619
1620 chomp(my $type = `git-cat-file -t $commit`);
1621 if ($type eq 'commit' || $type eq 'tag') {
1622 my $pid = open my $msg_fh, '-|';
1623 defined $pid or croak $!;
1624
1625 if ($pid == 0) {
1626 exec('git-cat-file', $type, $commit) or croak $!;
1627 }
1628 my $in_msg = 0;
1629 while (<$msg_fh>) {
1630 if (!$in_msg) {
1631 $in_msg = 1 if (/^\s*$/);
1632 } elsif (/^git-svn-id: /) {
1633 # skip this, we regenerate the correct one
1634 # on re-fetch anyways
1635 } else {
1636 print $msg $_ or croak $!;
1637 }
1638 }
1639 close $msg_fh or croak $?;
1640 }
1641 close $msg or croak $!;
1642
1643 if ($_edit || ($type eq 'tree')) {
1644 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
1645 system($editor, $commit_msg);
1646 }
1647
1648 # file_to_s removes all trailing newlines, so just use chomp() here:
1649 open $msg, '<', $commit_msg or croak $!;
1650 { local $/; chomp($log_msg{msg} = <$msg>); }
1651 close $msg or croak $!;
1652
1653 return \%log_msg;
1654 }
1655
1656 sub set_svn_commit_env {
1657 if (defined $LC_ALL) {
1658 $ENV{LC_ALL} = $LC_ALL;
1659 } else {
1660 delete $ENV{LC_ALL};
1661 }
1662 }
1663
1664 sub svn_commit_tree {
1665 my ($last, $commit) = @_;
1666 my $commit_msg = "$GIT_SVN_DIR/.svn-commit.tmp.$$";
1667 my $log_msg = get_commit_message($commit, $commit_msg);
1668 my ($oneline) = ($log_msg->{msg} =~ /([^\n\r]+)/);
1669 print "Committing $commit: $oneline\n";
1670
1671 set_svn_commit_env();
1672 my @ci_output = safe_qx(qw(svn commit -F),$commit_msg);
1673 $ENV{LC_ALL} = 'C';
1674 unlink $commit_msg;
1675 my ($committed) = ($ci_output[$#ci_output] =~ /(\d+)/);
1676 if (!defined $committed) {
1677 my $out = join("\n",@ci_output);
1678 print STDERR "W: Trouble parsing \`svn commit' output:\n\n",
1679 $out, "\n\nAssuming English locale...";
1680 ($committed) = ($out =~ /^Committed revision \d+\./sm);
1681 defined $committed or die " FAILED!\n",
1682 "Commit output failed to parse committed revision!\n",
1683 print STDERR " OK\n";
1684 }
1685
1686 my @svn_up = qw(svn up);
1687 push @svn_up, '--ignore-externals' unless $_no_ignore_ext;
1688 if ($_optimize_commits && ($committed == ($last->{revision} + 1))) {
1689 push @svn_up, "-r$committed";
1690 sys(@svn_up);
1691 my $info = svn_info('.');
1692 my $date = $info->{'Last Changed Date'} or die "Missing date\n";
1693 if ($info->{'Last Changed Rev'} != $committed) {
1694 croak "$info->{'Last Changed Rev'} != $committed\n"
1695 }
1696 my ($Y,$m,$d,$H,$M,$S,$tz) = ($date =~
1697 /(\d{4})\-(\d\d)\-(\d\d)\s
1698 (\d\d)\:(\d\d)\:(\d\d)\s([\-\+]\d+)/x)
1699 or croak "Failed to parse date: $date\n";
1700 $log_msg->{date} = "$tz $Y-$m-$d $H:$M:$S";
1701 $log_msg->{author} = $info->{'Last Changed Author'};
1702 $log_msg->{revision} = $committed;
1703 $log_msg->{msg} .= "\n";
1704 $log_msg->{parents} = [ $last->{commit} ];
1705 $log_msg->{commit} = git_commit($log_msg, $commit);
1706 return $log_msg;
1707 }
1708 # resync immediately
1709 push @svn_up, "-r$last->{revision}";
1710 sys(@svn_up);
1711 return fetch("$committed=$commit");
1712 }
1713
1714 sub rev_list_raw {
1715 my (@args) = @_;
1716 my $pid = open my $fh, '-|';
1717 defined $pid or croak $!;
1718 if (!$pid) {
1719 exec(qw/git-rev-list --pretty=raw/, @args) or croak $!;
1720 }
1721 return { fh => $fh, t => { } };
1722 }
1723
1724 sub next_rev_list_entry {
1725 my $rl = shift;
1726 my $fh = $rl->{fh};
1727 my $x = $rl->{t};
1728 while (<$fh>) {
1729 if (/^commit ($sha1)$/o) {
1730 if ($x->{c}) {
1731 $rl->{t} = { c => $1 };
1732 return $x;
1733 } else {
1734 $x->{c} = $1;
1735 }
1736 } elsif (/^parent ($sha1)$/o) {
1737 $x->{p}->{$1} = 1;
1738 } elsif (s/^ //) {
1739 $x->{m} ||= '';
1740 $x->{m} .= $_;
1741 }
1742 }
1743 return ($x != $rl->{t}) ? $x : undef;
1744 }
1745
1746 # read the entire log into a temporary file (which is removed ASAP)
1747 # and store the file handle + parser state
1748 sub svn_log_raw {
1749 my (@log_args) = @_;
1750 my $log_fh = IO::File->new_tmpfile or croak $!;
1751 my $pid = fork;
1752 defined $pid or croak $!;
1753 if (!$pid) {
1754 open STDOUT, '>&', $log_fh or croak $!;
1755 exec (qw(svn log), @log_args) or croak $!
1756 }
1757 waitpid $pid, 0;
1758 croak $? if $?;
1759 seek $log_fh, 0, 0 or croak $!;
1760 return { state => 'sep', fh => $log_fh };
1761 }
1762
1763 sub next_log_entry {
1764 my $log = shift; # retval of svn_log_raw()
1765 my $ret = undef;
1766 my $fh = $log->{fh};
1767
1768 while (<$fh>) {
1769 chomp;
1770 if (/^\-{72}$/) {
1771 if ($log->{state} eq 'msg') {
1772 if ($ret->{lines}) {
1773 $ret->{msg} .= $_."\n";
1774 unless(--$ret->{lines}) {
1775 $log->{state} = 'sep';
1776 }
1777 } else {
1778 croak "Log parse error at: $_\n",
1779 $ret->{revision},
1780 "\n";
1781 }
1782 next;
1783 }
1784 if ($log->{state} ne 'sep') {
1785 croak "Log parse error at: $_\n",
1786 "state: $log->{state}\n",
1787 $ret->{revision},
1788 "\n";
1789 }
1790 $log->{state} = 'rev';
1791
1792 # if we have an empty log message, put something there:
1793 if ($ret) {
1794 $ret->{msg} ||= "\n";
1795 delete $ret->{lines};
1796 return $ret;
1797 }
1798 next;
1799 }
1800 if ($log->{state} eq 'rev' && s/^r(\d+)\s*\|\s*//) {
1801 my $rev = $1;
1802 my ($author, $date, $lines) = split(/\s*\|\s*/, $_, 3);
1803 ($lines) = ($lines =~ /(\d+)/);
1804 $date = '1970-01-01 00:00:00 +0000'
1805 if ($_ignore_nodate && $date eq '(no date)');
1806 my ($Y,$m,$d,$H,$M,$S,$tz) = ($date =~
1807 /(\d{4})\-(\d\d)\-(\d\d)\s
1808 (\d\d)\:(\d\d)\:(\d\d)\s([\-\+]\d+)/x)
1809 or croak "Failed to parse date: $date\n";
1810 $ret = { revision => $rev,
1811 date => "$tz $Y-$m-$d $H:$M:$S",
1812 author => $author,
1813 lines => $lines,
1814 msg => '' };
1815 if (defined $_authors && ! defined $users{$author}) {
1816 die "Author: $author not defined in ",
1817 "$_authors file\n";
1818 }
1819 $log->{state} = 'msg_start';
1820 next;
1821 }
1822 # skip the first blank line of the message:
1823 if ($log->{state} eq 'msg_start' && /^$/) {
1824 $log->{state} = 'msg';
1825 } elsif ($log->{state} eq 'msg') {
1826 if ($ret->{lines}) {
1827 $ret->{msg} .= $_."\n";
1828 unless (--$ret->{lines}) {
1829 $log->{state} = 'sep';
1830 }
1831 } else {
1832 croak "Log parse error at: $_\n",
1833 $ret->{revision},"\n";
1834 }
1835 }
1836 }
1837 return $ret;
1838 }
1839
1840 sub svn_info {
1841 my $url = shift || $SVN_URL;
1842
1843 my $pid = open my $info_fh, '-|';
1844 defined $pid or croak $!;
1845
1846 if ($pid == 0) {
1847 exec(qw(svn info),$url) or croak $!;
1848 }
1849
1850 my $ret = {};
1851 # only single-lines seem to exist in svn info output
1852 while (<$info_fh>) {
1853 chomp $_;
1854 if (m#^([^:]+)\s*:\s*(\S.*)$#) {
1855 $ret->{$1} = $2;
1856 push @{$ret->{-order}}, $1;
1857 }
1858 }
1859 close $info_fh or croak $?;
1860 return $ret;
1861 }
1862
1863 sub sys { system(@_) == 0 or croak $? }
1864
1865 sub do_update_index {
1866 my ($z_cmd, $cmd, $no_text_base) = @_;
1867
1868 my $z = open my $p, '-|';
1869 defined $z or croak $!;
1870 unless ($z) { exec @$z_cmd or croak $! }
1871
1872 my $pid = open my $ui, '|-';
1873 defined $pid or croak $!;
1874 unless ($pid) {
1875 exec('git-update-index',"--$cmd",'-z','--stdin') or croak $!;
1876 }
1877 local $/ = "\0";
1878 while (my $x = <$p>) {
1879 chomp $x;
1880 if (!$no_text_base && lstat $x && ! -l _ &&
1881 svn_propget_base('svn:keywords', $x)) {
1882 my $mode = -x _ ? 0755 : 0644;
1883 my ($v,$d,$f) = File::Spec->splitpath($x);
1884 my $tb = File::Spec->catfile($d, '.svn', 'tmp',
1885 'text-base',"$f.svn-base");
1886 $tb =~ s#^/##;
1887 unless (-f $tb) {
1888 $tb = File::Spec->catfile($d, '.svn',
1889 'text-base',"$f.svn-base");
1890 $tb =~ s#^/##;
1891 }
1892 my @s = stat($x);
1893 unlink $x or croak $!;
1894 copy($tb, $x);
1895 chmod(($mode &~ umask), $x) or croak $!;
1896 utime $s[8], $s[9], $x;
1897 }
1898 print $ui $x,"\0";
1899 }
1900 close $ui or croak $?;
1901 }
1902
1903 sub index_changes {
1904 return if $_use_lib;
1905
1906 if (!-f "$GIT_SVN_DIR/info/exclude") {
1907 open my $fd, '>>', "$GIT_SVN_DIR/info/exclude" or croak $!;
1908 print $fd '.svn',"\n";
1909 close $fd or croak $!;
1910 }
1911 my $no_text_base = shift;
1912 do_update_index([qw/git-diff-files --name-only -z/],
1913 'remove',
1914 $no_text_base);
1915 do_update_index([qw/git-ls-files -z --others/,
1916 "--exclude-from=$GIT_SVN_DIR/info/exclude"],
1917 'add',
1918 $no_text_base);
1919 }
1920
1921 sub s_to_file {
1922 my ($str, $file, $mode) = @_;
1923 open my $fd,'>',$file or croak $!;
1924 print $fd $str,"\n" or croak $!;
1925 close $fd or croak $!;
1926 chmod ($mode &~ umask, $file) if (defined $mode);
1927 }
1928
1929 sub file_to_s {
1930 my $file = shift;
1931 open my $fd,'<',$file or croak "$!: file: $file\n";
1932 local $/;
1933 my $ret = <$fd>;
1934 close $fd or croak $!;
1935 $ret =~ s/\s*$//s;
1936 return $ret;
1937 }
1938
1939 sub assert_revision_unknown {
1940 my $r = shift;
1941 if (my $c = revdb_get($REVDB, $r)) {
1942 croak "$r = $c already exists! Why are we refetching it?";
1943 }
1944 }
1945
1946 sub trees_eq {
1947 my ($x, $y) = @_;
1948 my @x = safe_qx('git-cat-file','commit',$x);
1949 my @y = safe_qx('git-cat-file','commit',$y);
1950 if (($y[0] ne $x[0]) || $x[0] !~ /^tree $sha1\n$/
1951 || $y[0] !~ /^tree $sha1\n$/) {
1952 print STDERR "Trees not equal: $y[0] != $x[0]\n";
1953 return 0
1954 }
1955 return 1;
1956 }
1957
1958 sub git_commit {
1959 my ($log_msg, @parents) = @_;
1960 assert_revision_unknown($log_msg->{revision});
1961 map_tree_joins() if (@_branch_from && !%tree_map);
1962
1963 my (@tmp_parents, @exec_parents, %seen_parent);
1964 if (my $lparents = $log_msg->{parents}) {
1965 @tmp_parents = @$lparents
1966 }
1967 # commit parents can be conditionally bound to a particular
1968 # svn revision via: "svn_revno=commit_sha1", filter them out here:
1969 foreach my $p (@parents) {
1970 next unless defined $p;
1971 if ($p =~ /^(\d+)=($sha1_short)$/o) {
1972 if ($1 == $log_msg->{revision}) {
1973 push @tmp_parents, $2;
1974 }
1975 } else {
1976 push @tmp_parents, $p if $p =~ /$sha1_short/o;
1977 }
1978 }
1979 my $tree = $log_msg->{tree};
1980 if (!defined $tree) {
1981 my $index = set_index($GIT_SVN_INDEX);
1982 index_changes();
1983 chomp($tree = `git-write-tree`);
1984 croak $? if $?;
1985 restore_index($index);
1986 }
1987
1988 # just in case we clobber the existing ref, we still want that ref
1989 # as our parent:
1990 if (my $cur = eval { file_to_s("$GIT_DIR/refs/remotes/$GIT_SVN") }) {
1991 push @tmp_parents, $cur;
1992 }
1993
1994 if (exists $tree_map{$tree}) {
1995 foreach my $p (@{$tree_map{$tree}}) {
1996 my $skip;
1997 foreach (@tmp_parents) {
1998 # see if a common parent is found
1999 my $mb = eval {
2000 safe_qx('git-merge-base', $_, $p)
2001 };
2002 next if ($@ || $?);
2003 $skip = 1;
2004 last;
2005 }
2006 next if $skip;
2007 my ($url_p, $r_p, $uuid_p) = cmt_metadata($p);
2008 next if (($SVN_UUID eq $uuid_p) &&
2009 ($log_msg->{revision} > $r_p));
2010 next if (defined $url_p && defined $SVN_URL &&
2011 ($SVN_UUID eq $uuid_p) &&
2012 ($url_p eq $SVN_URL));
2013 push @tmp_parents, $p;
2014 }
2015 }
2016 foreach (@tmp_parents) {
2017 next if $seen_parent{$_};
2018 $seen_parent{$_} = 1;
2019 push @exec_parents, $_;
2020 # MAXPARENT is defined to 16 in commit-tree.c:
2021 last if @exec_parents > 16;
2022 }
2023
2024 set_commit_env($log_msg);
2025 my @exec = ('git-commit-tree', $tree);
2026 push @exec, '-p', $_ foreach @exec_parents;
2027 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
2028 or croak $!;
2029 print $msg_fh $log_msg->{msg} or croak $!;
2030 unless ($_no_metadata) {
2031 print $msg_fh "\ngit-svn-id: $SVN_URL\@$log_msg->{revision}",
2032 " $SVN_UUID\n" or croak $!;
2033 }
2034 $msg_fh->flush == 0 or croak $!;
2035 close $msg_fh or croak $!;
2036 chomp(my $commit = do { local $/; <$out_fh> });
2037 close $out_fh or croak $!;
2038 waitpid $pid, 0;
2039 croak $? if $?;
2040 if ($commit !~ /^$sha1$/o) {
2041 die "Failed to commit, invalid sha1: $commit\n";
2042 }
2043 sys('git-update-ref',"refs/remotes/$GIT_SVN",$commit);
2044 revdb_set($REVDB, $log_msg->{revision}, $commit);
2045
2046 # this output is read via pipe, do not change:
2047 print "r$log_msg->{revision} = $commit\n";
2048 check_repack();
2049 return $commit;
2050 }
2051
2052 sub check_repack {
2053 if ($_repack && (--$_repack_nr == 0)) {
2054 $_repack_nr = $_repack;
2055 sys("git repack $_repack_flags");
2056 }
2057 }
2058
2059 sub set_commit_env {
2060 my ($log_msg) = @_;
2061 my $author = $log_msg->{author};
2062 if (!defined $author || length $author == 0) {
2063 $author = '(no author)';
2064 }
2065 my ($name,$email) = defined $users{$author} ? @{$users{$author}}
2066 : ($author,"$author\@$SVN_UUID");
2067 $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
2068 $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
2069 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_msg->{date};
2070 }
2071
2072 sub apply_mod_line_blob {
2073 my $m = shift;
2074 if ($m->{mode_b} =~ /^120/) {
2075 blob_to_symlink($m->{sha1_b}, $m->{file_b});
2076 } else {
2077 blob_to_file($m->{sha1_b}, $m->{file_b});
2078 }
2079 }
2080
2081 sub blob_to_symlink {
2082 my ($blob, $link) = @_;
2083 defined $link or croak "\$link not defined!\n";
2084 croak "Not a sha1: $blob\n" unless $blob =~ /^$sha1$/o;
2085 if (-l $link || -f _) {
2086 unlink $link or croak $!;
2087 }
2088
2089 my $dest = `git-cat-file blob $blob`; # no newline, so no chomp
2090 symlink $dest, $link or croak $!;
2091 }
2092
2093 sub blob_to_file {
2094 my ($blob, $file) = @_;
2095 defined $file or croak "\$file not defined!\n";
2096 croak "Not a sha1: $blob\n" unless $blob =~ /^$sha1$/o;
2097 if (-l $file || -f _) {
2098 unlink $file or croak $!;
2099 }
2100
2101 open my $blob_fh, '>', $file or croak "$!: $file\n";
2102 my $pid = fork;
2103 defined $pid or croak $!;
2104
2105 if ($pid == 0) {
2106 open STDOUT, '>&', $blob_fh or croak $!;
2107 exec('git-cat-file','blob',$blob) or croak $!;
2108 }
2109 waitpid $pid, 0;
2110 croak $? if $?;
2111
2112 close $blob_fh or croak $!;
2113 }
2114
2115 sub safe_qx {
2116 my $pid = open my $child, '-|';
2117 defined $pid or croak $!;
2118 if ($pid == 0) {
2119 exec(@_) or croak $!;
2120 }
2121 my @ret = (<$child>);
2122 close $child or croak $?;
2123 die $? if $?; # just in case close didn't error out
2124 return wantarray ? @ret : join('',@ret);
2125 }
2126
2127 sub svn_compat_check {
2128 if ($_follow_parent) {
2129 print STDERR 'E: --follow-parent functionality is only ',
2130 "available when SVN libraries are used\n";
2131 exit 1;
2132 }
2133 my @co_help = safe_qx(qw(svn co -h));
2134 unless (grep /ignore-externals/,@co_help) {
2135 print STDERR "W: Installed svn version does not support ",
2136 "--ignore-externals\n";
2137 $_no_ignore_ext = 1;
2138 }
2139 if (grep /usage: checkout URL\[\@REV\]/,@co_help) {
2140 $_svn_co_url_revs = 1;
2141 }
2142 if (grep /\[TARGET\[\@REV\]\.\.\.\]/, `svn propget -h`) {
2143 $_svn_pg_peg_revs = 1;
2144 }
2145
2146 # I really, really hope nobody hits this...
2147 unless (grep /stop-on-copy/, (safe_qx(qw(svn log -h)))) {
2148 print STDERR <<'';
2149 W: The installed svn version does not support the --stop-on-copy flag in
2150 the log command.
2151 Lets hope the directory you're tracking is not a branch or tag
2152 and was never moved within the repository...
2153
2154 $_no_stop_copy = 1;
2155 }
2156 }
2157
2158 # *sigh*, new versions of svn won't honor -r<rev> without URL@<rev>,
2159 # (and they won't honor URL@<rev> without -r<rev>, too!)
2160 sub svn_cmd_checkout {
2161 my ($url, $rev, $dir) = @_;
2162 my @cmd = ('svn','co', "-r$rev");
2163 push @cmd, '--ignore-externals' unless $_no_ignore_ext;
2164 $url .= "\@$rev" if $_svn_co_url_revs;
2165 sys(@cmd, $url, $dir);
2166 }
2167
2168 sub check_upgrade_needed {
2169 if (!-r $REVDB) {
2170 -d $GIT_SVN_DIR or mkpath([$GIT_SVN_DIR]);
2171 open my $fh, '>>',$REVDB or croak $!;
2172 close $fh;
2173 }
2174 my $old = eval {
2175 my $pid = open my $child, '-|';
2176 defined $pid or croak $!;
2177 if ($pid == 0) {
2178 close STDERR;
2179 exec('git-rev-parse',"$GIT_SVN-HEAD") or croak $!;
2180 }
2181 my @ret = (<$child>);
2182 close $child or croak $?;
2183 die $? if $?; # just in case close didn't error out
2184 return wantarray ? @ret : join('',@ret);
2185 };
2186 return unless $old;
2187 my $head = eval { safe_qx('git-rev-parse',"refs/remotes/$GIT_SVN") };
2188 if ($@ || !$head) {
2189 print STDERR "Please run: $0 rebuild --upgrade\n";
2190 exit 1;
2191 }
2192 }
2193
2194 # fills %tree_map with a reverse mapping of trees to commits. Useful
2195 # for finding parents to commit on.
2196 sub map_tree_joins {
2197 my %seen;
2198 foreach my $br (@_branch_from) {
2199 my $pid = open my $pipe, '-|';
2200 defined $pid or croak $!;
2201 if ($pid == 0) {
2202 exec(qw(git-rev-list --topo-order --pretty=raw), $br)
2203 or croak $!;
2204 }
2205 while (<$pipe>) {
2206 if (/^commit ($sha1)$/o) {
2207 my $commit = $1;
2208
2209 # if we've seen a commit,
2210 # we've seen its parents
2211 last if $seen{$commit};
2212 my ($tree) = (<$pipe> =~ /^tree ($sha1)$/o);
2213 unless (defined $tree) {
2214 die "Failed to parse commit $commit\n";
2215 }
2216 push @{$tree_map{$tree}}, $commit;
2217 $seen{$commit} = 1;
2218 }
2219 }
2220 close $pipe; # we could be breaking the pipe early
2221 }
2222 }
2223
2224 sub load_all_refs {
2225 if (@_branch_from) {
2226 print STDERR '--branch|-b parameters are ignored when ',
2227 "--branch-all-refs|-B is passed\n";
2228 }
2229
2230 # don't worry about rev-list on non-commit objects/tags,
2231 # it shouldn't blow up if a ref is a blob or tree...
2232 chomp(@_branch_from = `git-rev-parse --symbolic --all`);
2233 }
2234
2235 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
2236 sub load_authors {
2237 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
2238 while (<$authors>) {
2239 chomp;
2240 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
2241 my ($user, $name, $email) = ($1, $2, $3);
2242 $users{$user} = [$name, $email];
2243 }
2244 close $authors or croak $!;
2245 }
2246
2247 sub rload_authors {
2248 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
2249 while (<$authors>) {
2250 chomp;
2251 next unless /^(\S+?)\s*=\s*(.+?)\s*<(.+)>\s*$/;
2252 my ($user, $name, $email) = ($1, $2, $3);
2253 $rusers{"$name <$email>"} = $user;
2254 }
2255 close $authors or croak $!;
2256 }
2257
2258 sub svn_propget_base {
2259 my ($p, $f) = @_;
2260 $f .= '@BASE' if $_svn_pg_peg_revs;
2261 return safe_qx(qw/svn propget/, $p, $f);
2262 }
2263
2264 sub git_svn_each {
2265 my $sub = shift;
2266 foreach (`git-rev-parse --symbolic --all`) {
2267 next unless s#^refs/remotes/##;
2268 chomp $_;
2269 next unless -f "$GIT_DIR/svn/$_/info/url";
2270 &$sub($_);
2271 }
2272 }
2273
2274 sub migrate_revdb {
2275 git_svn_each(sub {
2276 my $id = shift;
2277 defined(my $pid = fork) or croak $!;
2278 if (!$pid) {
2279 $GIT_SVN = $ENV{GIT_SVN_ID} = $id;
2280 init_vars();
2281 exit 0 if -r $REVDB;
2282 print "Upgrading svn => git mapping...\n";
2283 -d $GIT_SVN_DIR or mkpath([$GIT_SVN_DIR]);
2284 open my $fh, '>>',$REVDB or croak $!;
2285 close $fh;
2286 rebuild();
2287 print "Done upgrading. You may now delete the ",
2288 "deprecated $GIT_SVN_DIR/revs directory\n";
2289 exit 0;
2290 }
2291 waitpid $pid, 0;
2292 croak $? if $?;
2293 });
2294 }
2295
2296 sub migration_check {
2297 migrate_revdb() unless (-e $REVDB);
2298 return if (-d "$GIT_DIR/svn" || !-d $GIT_DIR);
2299 print "Upgrading repository...\n";
2300 unless (-d "$GIT_DIR/svn") {
2301 mkdir "$GIT_DIR/svn" or croak $!;
2302 }
2303 print "Data from a previous version of git-svn exists, but\n\t",
2304 "$GIT_SVN_DIR\n\t(required for this version ",
2305 "($VERSION) of git-svn) does not.\n";
2306
2307 foreach my $x (`git-rev-parse --symbolic --all`) {
2308 next unless $x =~ s#^refs/remotes/##;
2309 chomp $x;
2310 next unless -f "$GIT_DIR/$x/info/url";
2311 my $u = eval { file_to_s("$GIT_DIR/$x/info/url") };
2312 next unless $u;
2313 my $dn = dirname("$GIT_DIR/svn/$x");
2314 mkpath([$dn]) unless -d $dn;
2315 rename "$GIT_DIR/$x", "$GIT_DIR/svn/$x" or croak "$!: $x";
2316 }
2317 migrate_revdb() if (-d $GIT_SVN_DIR && !-w $REVDB);
2318 print "Done upgrading.\n";
2319 }
2320
2321 sub find_rev_before {
2322 my ($r, $id, $eq_ok) = @_;
2323 my $f = "$GIT_DIR/svn/$id/.rev_db";
2324 return (undef,undef) unless -r $f;
2325 --$r unless $eq_ok;
2326 while ($r > 0) {
2327 if (my $c = revdb_get($f, $r)) {
2328 return ($r, $c);
2329 }
2330 --$r;
2331 }
2332 return (undef, undef);
2333 }
2334
2335 sub init_vars {
2336 $GIT_SVN ||= $ENV{GIT_SVN_ID} || 'git-svn';
2337 $GIT_SVN_DIR = "$GIT_DIR/svn/$GIT_SVN";
2338 $REVDB = "$GIT_SVN_DIR/.rev_db";
2339 $GIT_SVN_INDEX = "$GIT_SVN_DIR/index";
2340 $SVN_URL = undef;
2341 $SVN_WC = "$GIT_SVN_DIR/tree";
2342 %tree_map = ();
2343 }
2344
2345 # convert GetOpt::Long specs for use by git-repo-config
2346 sub read_repo_config {
2347 return unless -d $GIT_DIR;
2348 my $opts = shift;
2349 foreach my $o (keys %$opts) {
2350 my $v = $opts->{$o};
2351 my ($key) = ($o =~ /^([a-z\-]+)/);
2352 $key =~ s/-//g;
2353 my $arg = 'git-repo-config';
2354 $arg .= ' --int' if ($o =~ /[:=]i$/);
2355 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
2356 if (ref $v eq 'ARRAY') {
2357 chomp(my @tmp = `$arg --get-all svn.$key`);
2358 @$v = @tmp if @tmp;
2359 } else {
2360 chomp(my $tmp = `$arg --get svn.$key`);
2361 if ($tmp && !($arg =~ / --bool / && $tmp eq 'false')) {
2362 $$v = $tmp;
2363 }
2364 }
2365 }
2366 }
2367
2368 sub set_default_vals {
2369 if (defined $_repack) {
2370 $_repack = 1000 if ($_repack <= 0);
2371 $_repack_nr = $_repack;
2372 $_repack_flags ||= '-d';
2373 }
2374 }
2375
2376 sub read_grafts {
2377 my $gr_file = shift;
2378 my ($grafts, $comments) = ({}, {});
2379 if (open my $fh, '<', $gr_file) {
2380 my @tmp;
2381 while (<$fh>) {
2382 if (/^($sha1)\s+/) {
2383 my $c = $1;
2384 if (@tmp) {
2385 @{$comments->{$c}} = @tmp;
2386 @tmp = ();
2387 }
2388 foreach my $p (split /\s+/, $_) {
2389 $grafts->{$c}->{$p} = 1;
2390 }
2391 } else {
2392 push @tmp, $_;
2393 }
2394 }
2395 close $fh or croak $!;
2396 @{$comments->{'END'}} = @tmp if @tmp;
2397 }
2398 return ($grafts, $comments);
2399 }
2400
2401 sub write_grafts {
2402 my ($grafts, $comments, $gr_file) = @_;
2403
2404 open my $fh, '>', $gr_file or croak $!;
2405 foreach my $c (sort keys %$grafts) {
2406 if ($comments->{$c}) {
2407 print $fh $_ foreach @{$comments->{$c}};
2408 }
2409 my $p = $grafts->{$c};
2410 my %x; # real parents
2411 delete $p->{$c}; # commits are not self-reproducing...
2412 my $pid = open my $ch, '-|';
2413 defined $pid or croak $!;
2414 if (!$pid) {
2415 exec(qw/git-cat-file commit/, $c) or croak $!;
2416 }
2417 while (<$ch>) {
2418 if (/^parent ($sha1)/) {
2419 $x{$1} = $p->{$1} = 1;
2420 } else {
2421 last unless /^\S/;
2422 }
2423 }
2424 close $ch; # breaking the pipe
2425
2426 # if real parents are the only ones in the grafts, drop it
2427 next if join(' ',sort keys %$p) eq join(' ',sort keys %x);
2428
2429 my (@ip, @jp, $mb);
2430 my %del = %x;
2431 @ip = @jp = keys %$p;
2432 foreach my $i (@ip) {
2433 next if $del{$i} || $p->{$i} == 2;
2434 foreach my $j (@jp) {
2435 next if $i eq $j || $del{$j} || $p->{$j} == 2;
2436 $mb = eval { safe_qx('git-merge-base',$i,$j) };
2437 next unless $mb;
2438 chomp $mb;
2439 next if $x{$mb};
2440 if ($mb eq $j) {
2441 delete $p->{$i};
2442 $del{$i} = 1;
2443 } elsif ($mb eq $i) {
2444 delete $p->{$j};
2445 $del{$j} = 1;
2446 }
2447 }
2448 }
2449
2450 # if real parents are the only ones in the grafts, drop it
2451 next if join(' ',sort keys %$p) eq join(' ',sort keys %x);
2452
2453 print $fh $c, ' ', join(' ', sort keys %$p),"\n";
2454 }
2455 if ($comments->{'END'}) {
2456 print $fh $_ foreach @{$comments->{'END'}};
2457 }
2458 close $fh or croak $!;
2459 }
2460
2461 sub read_url_paths_all {
2462 my ($l_map, $pfx, $p) = @_;
2463 my @dir;
2464 foreach (<$p/*>) {
2465 if (-r "$_/info/url") {
2466 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
2467 my $id = $pfx . basename $_;
2468 my $url = file_to_s("$_/info/url");
2469 my ($u, $p) = repo_path_split($url);
2470 $l_map->{$u}->{$p} = $id;
2471 } elsif (-d $_) {
2472 push @dir, $_;
2473 }
2474 }
2475 foreach (@dir) {
2476 my $x = $_;
2477 $x =~ s!^\Q$GIT_DIR\E/svn/!!o;
2478 read_url_paths_all($l_map, $x, $_);
2479 }
2480 }
2481
2482 # this one only gets ids that have been imported, not new ones
2483 sub read_url_paths {
2484 my $l_map = {};
2485 git_svn_each(sub { my $x = shift;
2486 my $url = file_to_s("$GIT_DIR/svn/$x/info/url");
2487 my ($u, $p) = repo_path_split($url);
2488 $l_map->{$u}->{$p} = $x;
2489 });
2490 return $l_map;
2491 }
2492
2493 sub extract_metadata {
2494 my $id = shift or return (undef, undef, undef);
2495 my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
2496 \s([a-f\d\-]+)$/x);
2497 if (!defined $rev || !$uuid || !$url) {
2498 # some of the original repositories I made had
2499 # identifiers like this:
2500 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
2501 }
2502 return ($url, $rev, $uuid);
2503 }
2504
2505 sub cmt_metadata {
2506 return extract_metadata((grep(/^git-svn-id: /,
2507 safe_qx(qw/git-cat-file commit/, shift)))[-1]);
2508 }
2509
2510 sub get_commit_time {
2511 my $cmt = shift;
2512 defined(my $pid = open my $fh, '-|') or croak $!;
2513 if (!$pid) {
2514 exec qw/git-rev-list --pretty=raw -n1/, $cmt or croak $!;
2515 }
2516 while (<$fh>) {
2517 /^committer\s(?:.+) (\d+) ([\-\+]?\d+)$/ or next;
2518 my ($s, $tz) = ($1, $2);
2519 if ($tz =~ s/^\+//) {
2520 $s += tz_to_s_offset($tz);
2521 } elsif ($tz =~ s/^\-//) {
2522 $s -= tz_to_s_offset($tz);
2523 }
2524 close $fh;
2525 return $s;
2526 }
2527 die "Can't get commit time for commit: $cmt\n";
2528 }
2529
2530 sub tz_to_s_offset {
2531 my ($tz) = @_;
2532 $tz =~ s/(\d\d)$//;
2533 return ($1 * 60) + ($tz * 3600);
2534 }
2535
2536 sub setup_pager { # translated to Perl from pager.c
2537 return unless (-t *STDOUT);
2538 my $pager = $ENV{PAGER};
2539 if (!defined $pager) {
2540 $pager = 'less';
2541 } elsif (length $pager == 0 || $pager eq 'cat') {
2542 return;
2543 }
2544 pipe my $rfd, my $wfd or return;
2545 defined(my $pid = fork) or croak $!;
2546 if (!$pid) {
2547 open STDOUT, '>&', $wfd or croak $!;
2548 return;
2549 }
2550 open STDIN, '<&', $rfd or croak $!;
2551 $ENV{LESS} ||= '-S';
2552 exec $pager or croak "Can't run pager: $!\n";;
2553 }
2554
2555 sub get_author_info {
2556 my ($dest, $author, $t, $tz) = @_;
2557 $author =~ s/(?:^\s*|\s*$)//g;
2558 $dest->{a_raw} = $author;
2559 my $_a;
2560 if ($_authors) {
2561 $_a = $rusers{$author} || undef;
2562 }
2563 if (!$_a) {
2564 ($_a) = ($author =~ /<([^>]+)\@[^>]+>$/);
2565 }
2566 $dest->{t} = $t;
2567 $dest->{tz} = $tz;
2568 $dest->{a} = $_a;
2569 # Date::Parse isn't in the standard Perl distro :(
2570 if ($tz =~ s/^\+//) {
2571 $t += tz_to_s_offset($tz);
2572 } elsif ($tz =~ s/^\-//) {
2573 $t -= tz_to_s_offset($tz);
2574 }
2575 $dest->{t_utc} = $t;
2576 }
2577
2578 sub process_commit {
2579 my ($c, $r_min, $r_max, $defer) = @_;
2580 if (defined $r_min && defined $r_max) {
2581 if ($r_min == $c->{r} && $r_min == $r_max) {
2582 show_commit($c);
2583 return 0;
2584 }
2585 return 1 if $r_min == $r_max;
2586 if ($r_min < $r_max) {
2587 # we need to reverse the print order
2588 return 0 if (defined $_limit && --$_limit < 0);
2589 push @$defer, $c;
2590 return 1;
2591 }
2592 if ($r_min != $r_max) {
2593 return 1 if ($r_min < $c->{r});
2594 return 1 if ($r_max > $c->{r});
2595 }
2596 }
2597 return 0 if (defined $_limit && --$_limit < 0);
2598 show_commit($c);
2599 return 1;
2600 }
2601
2602 sub show_commit {
2603 my $c = shift;
2604 if ($_oneline) {
2605 my $x = "\n";
2606 if (my $l = $c->{l}) {
2607 while ($l->[0] =~ /^\s*$/) { shift @$l }
2608 $x = $l->[0];
2609 }
2610 $_l_fmt ||= 'A' . length($c->{r});
2611 print 'r',pack($_l_fmt, $c->{r}),' | ';
2612 print "$c->{c} | " if $_show_commit;
2613 print $x;
2614 } else {
2615 show_commit_normal($c);
2616 }
2617 }
2618
2619 sub show_commit_changed_paths {
2620 my ($c) = @_;
2621 return unless $c->{changed};
2622 print "Changed paths:\n", @{$c->{changed}};
2623 }
2624
2625 sub show_commit_normal {
2626 my ($c) = @_;
2627 print '-' x72, "\nr$c->{r} | ";
2628 print "$c->{c} | " if $_show_commit;
2629 print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
2630 localtime($c->{t_utc})), ' | ';
2631 my $nr_line = 0;
2632
2633 if (my $l = $c->{l}) {
2634 while ($l->[$#$l] eq "\n" && $#$l > 0
2635 && $l->[($#$l - 1)] eq "\n") {
2636 pop @$l;
2637 }
2638 $nr_line = scalar @$l;
2639 if (!$nr_line) {
2640 print "1 line\n\n\n";
2641 } else {
2642 if ($nr_line == 1) {
2643 $nr_line = '1 line';
2644 } else {
2645 $nr_line .= ' lines';
2646 }
2647 print $nr_line, "\n";
2648 show_commit_changed_paths($c);
2649 print "\n";
2650 print $_ foreach @$l;
2651 }
2652 } else {
2653 print "1 line\n";
2654 show_commit_changed_paths($c);
2655 print "\n";
2656
2657 }
2658 foreach my $x (qw/raw diff/) {
2659 if ($c->{$x}) {
2660 print "\n";
2661 print $_ foreach @{$c->{$x}}
2662 }
2663 }
2664 }
2665
2666 sub libsvn_load {
2667 return unless $_use_lib;
2668 $_use_lib = eval {
2669 require SVN::Core;
2670 if ($SVN::Core::VERSION lt '1.1.0') {
2671 die "Need SVN::Core 1.1.0 or better ",
2672 "(got $SVN::Core::VERSION) ",
2673 "Falling back to command-line svn\n";
2674 }
2675 require SVN::Ra;
2676 require SVN::Delta;
2677 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
2678 my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
2679 $SVN::Node::dir.$SVN::Node::unknown.
2680 $SVN::Node::none.$SVN::Node::file.
2681 $SVN::Node::dir.$SVN::Node::unknown.
2682 $SVN::Auth::SSL::CNMISMATCH.
2683 $SVN::Auth::SSL::NOTYETVALID.
2684 $SVN::Auth::SSL::EXPIRED.
2685 $SVN::Auth::SSL::UNKNOWNCA.
2686 $SVN::Auth::SSL::OTHER;
2687 1;
2688 };
2689 }
2690
2691 sub _simple_prompt {
2692 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
2693 $may_save = undef if $_no_auth_cache;
2694 $default_username = $_username if defined $_username;
2695 if (defined $default_username && length $default_username) {
2696 if (defined $realm && length $realm) {
2697 print "Authentication realm: $realm\n";
2698 }
2699 $cred->username($default_username);
2700 } else {
2701 _username_prompt($cred, $realm, $may_save, $pool);
2702 }
2703 $cred->password(_read_password("Password for '" .
2704 $cred->username . "': ", $realm));
2705 $cred->may_save($may_save);
2706 $SVN::_Core::SVN_NO_ERROR;
2707 }
2708
2709 sub _ssl_server_trust_prompt {
2710 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
2711 $may_save = undef if $_no_auth_cache;
2712 print "Error validating server certificate for '$realm':\n";
2713 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
2714 print " - The certificate is not issued by a trusted ",
2715 "authority. Use the\n",
2716 " fingerprint to validate the certificate manually!\n";
2717 }
2718 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
2719 print " - The certificate hostname does not match.\n";
2720 }
2721 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
2722 print " - The certificate is not yet valid.\n";
2723 }
2724 if ($failures & $SVN::Auth::SSL::EXPIRED) {
2725 print " - The certificate has expired.\n";
2726 }
2727 if ($failures & $SVN::Auth::SSL::OTHER) {
2728 print " - The certificate has an unknown error.\n";
2729 }
2730 printf( "Certificate information:\n".
2731 " - Hostname: %s\n".
2732 " - Valid: from %s until %s\n".
2733 " - Issuer: %s\n".
2734 " - Fingerprint: %s\n",
2735 map $cert_info->$_, qw(hostname valid_from valid_until
2736 issuer_dname fingerprint) );
2737 my $choice;
2738 prompt:
2739 print $may_save ?
2740 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
2741 "(R)eject or accept (t)emporarily? ";
2742 $choice = lc(substr(<STDIN> || 'R', 0, 1));
2743 if ($choice =~ /^t$/i) {
2744 $cred->may_save(undef);
2745 } elsif ($choice =~ /^r$/i) {
2746 return -1;
2747 } elsif ($may_save && $choice =~ /^p$/i) {
2748 $cred->may_save($may_save);
2749 } else {
2750 goto prompt;
2751 }
2752 $cred->accepted_failures($failures);
2753 $SVN::_Core::SVN_NO_ERROR;
2754 }
2755
2756 sub _ssl_client_cert_prompt {
2757 my ($cred, $realm, $may_save, $pool) = @_;
2758 $may_save = undef if $_no_auth_cache;
2759 print "Client certificate filename: ";
2760 chomp(my $filename = <STDIN>);
2761 $cred->cert_file($filename);
2762 $cred->may_save($may_save);
2763 $SVN::_Core::SVN_NO_ERROR;
2764 }
2765
2766 sub _ssl_client_cert_pw_prompt {
2767 my ($cred, $realm, $may_save, $pool) = @_;
2768 $may_save = undef if $_no_auth_cache;
2769 $cred->password(_read_password("Password: ", $realm));
2770 $cred->may_save($may_save);
2771 $SVN::_Core::SVN_NO_ERROR;
2772 }
2773
2774 sub _username_prompt {
2775 my ($cred, $realm, $may_save, $pool) = @_;
2776 $may_save = undef if $_no_auth_cache;
2777 if (defined $realm && length $realm) {
2778 print "Authentication realm: $realm\n";
2779 }
2780 my $username;
2781 if (defined $_username) {
2782 $username = $_username;
2783 } else {
2784 print "Username: ";
2785 chomp($username = <STDIN>);
2786 }
2787 $cred->username($username);
2788 $cred->may_save($may_save);
2789 $SVN::_Core::SVN_NO_ERROR;
2790 }
2791
2792 sub _read_password {
2793 my ($prompt, $realm) = @_;
2794 print $prompt;
2795 require Term::ReadKey;
2796 Term::ReadKey::ReadMode('noecho');
2797 my $password = '';
2798 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
2799 last if $key =~ /[\012\015]/; # \n\r
2800 $password .= $key;
2801 }
2802 Term::ReadKey::ReadMode('restore');
2803 print "\n";
2804 $password;
2805 }
2806
2807 sub libsvn_connect {
2808 my ($url) = @_;
2809 SVN::_Core::svn_config_ensure($_config_dir, undef);
2810 my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2811 SVN::Client::get_simple_provider(),
2812 SVN::Client::get_ssl_server_trust_file_provider(),
2813 SVN::Client::get_simple_prompt_provider(
2814 \&_simple_prompt, 2),
2815 SVN::Client::get_ssl_client_cert_prompt_provider(
2816 \&_ssl_client_cert_prompt, 2),
2817 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2818 \&_ssl_client_cert_pw_prompt, 2),
2819 SVN::Client::get_username_provider(),
2820 SVN::Client::get_ssl_server_trust_prompt_provider(
2821 \&_ssl_server_trust_prompt),
2822 SVN::Client::get_username_prompt_provider(
2823 \&_username_prompt, 2),
2824 ]);
2825 my $ra = SVN::Ra->new(url => $url, auth => $baton,
2826 pool => SVN::Pool->new,
2827 auth_provider_callbacks => $callbacks);
2828 $ra->{svn_path} = $url;
2829 $ra->{repos_root} = $ra->get_repos_root;
2830 $ra->{svn_path} =~ s#^\Q$ra->{repos_root}\E/*##;
2831 push @repo_path_split_cache, qr/^(\Q$ra->{repos_root}\E)/;
2832 return $ra;
2833 }
2834
2835 sub libsvn_dup_ra {
2836 my ($ra) = @_;
2837 SVN::Ra->new(map { $_ => $ra->{$_} }
2838 qw/url auth auth_provider_callbacks repos_root svn_path/);
2839 }
2840
2841 sub libsvn_get_file {
2842 my ($gui, $f, $rev, $chg) = @_;
2843 $f =~ s#^/##;
2844 print "\t$chg\t$f\n" unless $_q;
2845
2846 my ($hash, $pid, $in, $out);
2847 my $pool = SVN::Pool->new;
2848 defined($pid = open3($in, $out, '>&STDERR',
2849 qw/git-hash-object -w --stdin/)) or croak $!;
2850 # redirect STDOUT for SVN 1.1.x compatibility
2851 open my $stdout, '>&', \*STDOUT or croak $!;
2852 open STDOUT, '>&', $in or croak $!;
2853 my ($r, $props) = $SVN->get_file($f, $rev, \*STDOUT, $pool);
2854 $in->flush == 0 or croak $!;
2855 open STDOUT, '>&', $stdout or croak $!;
2856 close $in or croak $!;
2857 close $stdout or croak $!;
2858 $pool->clear;
2859 chomp($hash = do { local $/; <$out> });
2860 close $out or croak $!;
2861 waitpid $pid, 0;
2862 $hash =~ /^$sha1$/o or die "not a sha1: $hash\n";
2863
2864 my $mode = exists $props->{'svn:executable'} ? '100755' : '100644';
2865 if (exists $props->{'svn:special'}) {
2866 $mode = '120000';
2867 my $link = `git-cat-file blob $hash`;
2868 $link =~ s/^link // or die "svn:special file with contents: <",
2869 $link, "> is not understood\n";
2870 defined($pid = open3($in, $out, '>&STDERR',
2871 qw/git-hash-object -w --stdin/)) or croak $!;
2872 print $in $link;
2873 $in->flush == 0 or croak $!;
2874 close $in or croak $!;
2875 chomp($hash = do { local $/; <$out> });
2876 close $out or croak $!;
2877 waitpid $pid, 0;
2878 $hash =~ /^$sha1$/o or die "not a sha1: $hash\n";
2879 }
2880 print $gui $mode,' ',$hash,"\t",$f,"\0" or croak $!;
2881 }
2882
2883 sub libsvn_log_entry {
2884 my ($rev, $author, $date, $msg, $parents) = @_;
2885 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
2886 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x)
2887 or die "Unable to parse date: $date\n";
2888 if (defined $_authors && ! defined $users{$author}) {
2889 die "Author: $author not defined in $_authors file\n";
2890 }
2891 $msg = '' if ($rev == 0 && !defined $msg);
2892 return { revision => $rev, date => "+0000 $Y-$m-$d $H:$M:$S",
2893 author => $author, msg => $msg."\n", parents => $parents || [] }
2894 }
2895
2896 sub process_rm {
2897 my ($gui, $last_commit, $f) = @_;
2898 # remove entire directories.
2899 if (safe_qx('git-ls-tree',$last_commit,'--',$f) =~ /^040000 tree/) {
2900 defined(my $pid = open my $ls, '-|') or croak $!;
2901 if (!$pid) {
2902 exec(qw/git-ls-tree -r --name-only -z/,
2903 $last_commit,'--',$f) or croak $!;
2904 }
2905 local $/ = "\0";
2906 while (<$ls>) {
2907 print $gui '0 ',0 x 40,"\t",$_ or croak $!;
2908 }
2909 close $ls or croak $?;
2910 } else {
2911 print $gui '0 ',0 x 40,"\t",$f,"\0" or croak $!;
2912 }
2913 }
2914
2915 sub libsvn_fetch {
2916 my ($last_commit, $paths, $rev, $author, $date, $msg) = @_;
2917 open my $gui, '| git-update-index -z --index-info' or croak $!;
2918 my @amr;
2919 my $p = $SVN->{svn_path};
2920 foreach my $f (keys %$paths) {
2921 my $m = $paths->{$f}->action();
2922 $f =~ s#^/\Q$p\E/##;
2923 next if $f =~ m#^/#;
2924 if ($m =~ /^[DR]$/) {
2925 print "\t$m\t$f\n" unless $_q;
2926 process_rm($gui, $last_commit, $f);
2927 next if $m eq 'D';
2928 # 'R' can be file replacements, too, right?
2929 }
2930 my $pool = SVN::Pool->new;
2931 my $t = $SVN->check_path($f, $rev, $pool);
2932 if ($t == $SVN::Node::file) {
2933 if ($m =~ /^[AMR]$/) {
2934 push @amr, [ $m, $f ];
2935 } else {
2936 die "Unrecognized action: $m, ($f r$rev)\n";
2937 }
2938 } elsif ($t == $SVN::Node::dir && $m =~ /^[AR]$/) {
2939 my @traversed = ();
2940 libsvn_traverse($gui, '', $f, $rev, \@traversed);
2941 foreach (@traversed) {
2942 push @amr, [ $m, $_ ]
2943 }
2944 }
2945 $pool->clear;
2946 }
2947 foreach (@amr) {
2948 libsvn_get_file($gui, $_->[1], $rev, $_->[0]);
2949 }
2950 close $gui or croak $?;
2951 return libsvn_log_entry($rev, $author, $date, $msg, [$last_commit]);
2952 }
2953
2954 sub svn_grab_base_rev {
2955 defined(my $pid = open my $fh, '-|') or croak $!;
2956 if (!$pid) {
2957 open my $null, '>', '/dev/null' or croak $!;
2958 open STDERR, '>&', $null or croak $!;
2959 exec qw/git-rev-parse --verify/,"refs/remotes/$GIT_SVN^0"
2960 or croak $!;
2961 }
2962 chomp(my $c = do { local $/; <$fh> });
2963 close $fh;
2964 if (defined $c && length $c) {
2965 my ($url, $rev, $uuid) = cmt_metadata($c);
2966 return ($rev, $c) if defined $rev;
2967 }
2968 if ($_no_metadata) {
2969 my $offset = -41; # from tail
2970 my $rl;
2971 open my $fh, '<', $REVDB or
2972 die "--no-metadata specified and $REVDB not readable\n";
2973 seek $fh, $offset, 2;
2974 $rl = readline $fh;
2975 defined $rl or return (undef, undef);
2976 chomp $rl;
2977 while ($c ne $rl && tell $fh != 0) {
2978 $offset -= 41;
2979 seek $fh, $offset, 2;
2980 $rl = readline $fh;
2981 defined $rl or return (undef, undef);
2982 chomp $rl;
2983 }
2984 my $rev = tell $fh;
2985 croak $! if ($rev < -1);
2986 $rev = ($rev - 41) / 41;
2987 close $fh or croak $!;
2988 return ($rev, $c);
2989 }
2990 return (undef, undef);
2991 }
2992
2993 sub libsvn_parse_revision {
2994 my $base = shift;
2995 my $head = $SVN->get_latest_revnum();
2996 if (!defined $_revision || $_revision eq 'BASE:HEAD') {
2997 return ($base + 1, $head) if (defined $base);
2998 return (0, $head);
2999 }
3000 return ($1, $2) if ($_revision =~ /^(\d+):(\d+)$/);
3001 return ($_revision, $_revision) if ($_revision =~ /^\d+$/);
3002 if ($_revision =~ /^BASE:(\d+)$/) {
3003 return ($base + 1, $1) if (defined $base);
3004 return (0, $head);
3005 }
3006 return ($1, $head) if ($_revision =~ /^(\d+):HEAD$/);
3007 die "revision argument: $_revision not understood by git-svn\n",
3008 "Try using the command-line svn client instead\n";
3009 }
3010
3011 sub libsvn_traverse {
3012 my ($gui, $pfx, $path, $rev, $files) = @_;
3013 my $cwd = length $pfx ? "$pfx/$path" : $path;
3014 my $pool = SVN::Pool->new;
3015 $cwd =~ s#^\Q$SVN->{svn_path}\E##;
3016 my ($dirent, $r, $props) = $SVN->get_dir($cwd, $rev, $pool);
3017 foreach my $d (keys %$dirent) {
3018 my $t = $dirent->{$d}->kind;
3019 if ($t == $SVN::Node::dir) {
3020 libsvn_traverse($gui, $cwd, $d, $rev, $files);
3021 } elsif ($t == $SVN::Node::file) {
3022 my $file = "$cwd/$d";
3023 if (defined $files) {
3024 push @$files, $file;
3025 } else {
3026 libsvn_get_file($gui, $file, $rev, 'A');
3027 }
3028 }
3029 }
3030 $pool->clear;
3031 }
3032
3033 sub libsvn_traverse_ignore {
3034 my ($fh, $path, $r) = @_;
3035 $path =~ s#^/+##g;
3036 my $pool = SVN::Pool->new;
3037 my ($dirent, undef, $props) = $SVN->get_dir($path, $r, $pool);
3038 my $p = $path;
3039 $p =~ s#^\Q$SVN->{svn_path}\E/##;
3040 print $fh length $p ? "\n# $p\n" : "\n# /\n";
3041 if (my $s = $props->{'svn:ignore'}) {
3042 $s =~ s/[\r\n]+/\n/g;
3043 chomp $s;
3044 if (length $p == 0) {
3045 $s =~ s#\n#\n/$p#g;
3046 print $fh "/$s\n";
3047 } else {
3048 $s =~ s#\n#\n/$p/#g;
3049 print $fh "/$p/$s\n";
3050 }
3051 }
3052 foreach (sort keys %$dirent) {
3053 next if $dirent->{$_}->kind != $SVN::Node::dir;
3054 libsvn_traverse_ignore($fh, "$path/$_", $r);
3055 }
3056 $pool->clear;
3057 }
3058
3059 sub revisions_eq {
3060 my ($path, $r0, $r1) = @_;
3061 return 1 if $r0 == $r1;
3062 my $nr = 0;
3063 if ($_use_lib) {
3064 # should be OK to use Pool here (r1 - r0) should be small
3065 my $pool = SVN::Pool->new;
3066 libsvn_get_log($SVN, [$path], $r0, $r1,
3067 0, 1, 1, sub {$nr++}, $pool);
3068 $pool->clear;
3069 } else {
3070 my ($url, undef) = repo_path_split($SVN_URL);
3071 my $svn_log = svn_log_raw("$url/$path","-r$r0:$r1");
3072 while (next_log_entry($svn_log)) { $nr++ }
3073 close $svn_log->{fh};
3074 }
3075 return 0 if ($nr > 1);
3076 return 1;
3077 }
3078
3079 sub libsvn_find_parent_branch {
3080 my ($paths, $rev, $author, $date, $msg) = @_;
3081 my $svn_path = '/'.$SVN->{svn_path};
3082
3083 # look for a parent from another branch:
3084 my $i = $paths->{$svn_path} or return;
3085 my $branch_from = $i->copyfrom_path or return;
3086 my $r = $i->copyfrom_rev;
3087 print STDERR "Found possible branch point: ",
3088 "$branch_from => $svn_path, $r\n";
3089 $branch_from =~ s#^/##;
3090 my $l_map = {};
3091 read_url_paths_all($l_map, '', "$GIT_DIR/svn");
3092 my $url = $SVN->{repos_root};
3093 defined $l_map->{$url} or return;
3094 my $id = $l_map->{$url}->{$branch_from};
3095 if (!defined $id && $_follow_parent) {
3096 print STDERR "Following parent: $branch_from\@$r\n";
3097 # auto create a new branch and follow it
3098 $id = basename($branch_from);
3099 $id .= '@'.$r if -r "$GIT_DIR/svn/$id";
3100 while (-r "$GIT_DIR/svn/$id") {
3101 # just grow a tail if we're not unique enough :x
3102 $id .= '-';
3103 }
3104 }
3105 return unless defined $id;
3106
3107 my ($r0, $parent) = find_rev_before($r,$id,1);
3108 if ($_follow_parent && (!defined $r0 || !defined $parent)) {
3109 defined(my $pid = fork) or croak $!;
3110 if (!$pid) {
3111 $GIT_SVN = $ENV{GIT_SVN_ID} = $id;
3112 init_vars();
3113 $SVN_URL = "$url/$branch_from";
3114 $SVN = undef;
3115 setup_git_svn();
3116 # we can't assume SVN_URL exists at r+1:
3117 $_revision = "0:$r";
3118 fetch_lib();
3119 exit 0;
3120 }
3121 waitpid $pid, 0;
3122 croak $? if $?;
3123 ($r0, $parent) = find_rev_before($r,$id,1);
3124 }
3125 return unless (defined $r0 && defined $parent);
3126 if (revisions_eq($branch_from, $r0, $r)) {
3127 unlink $GIT_SVN_INDEX;
3128 print STDERR "Found branch parent: ($GIT_SVN) $parent\n";
3129 sys(qw/git-read-tree/, $parent);
3130 return libsvn_fetch($parent, $paths, $rev,
3131 $author, $date, $msg);
3132 }
3133 print STDERR "Nope, branch point not imported or unknown\n";
3134 return undef;
3135 }
3136
3137 sub libsvn_get_log {
3138 my ($ra, @args) = @_;
3139 if ($SVN::Core::VERSION le '1.2.0') {
3140 splice(@args, 3, 1);
3141 }
3142 $ra->get_log(@args);
3143 }
3144
3145 sub libsvn_new_tree {
3146 if (my $log_entry = libsvn_find_parent_branch(@_)) {
3147 return $log_entry;
3148 }
3149 my ($paths, $rev, $author, $date, $msg) = @_;
3150 open my $gui, '| git-update-index -z --index-info' or croak $!;
3151 libsvn_traverse($gui, '', $SVN->{svn_path}, $rev);
3152 close $gui or croak $?;
3153 return libsvn_log_entry($rev, $author, $date, $msg);
3154 }
3155
3156 sub find_graft_path_commit {
3157 my ($tree_paths, $p1, $r1) = @_;
3158 foreach my $x (keys %$tree_paths) {
3159 next unless ($p1 =~ /^\Q$x\E/);
3160 my $i = $tree_paths->{$x};
3161 my ($r0, $parent) = find_rev_before($r1,$i,1);
3162 return $parent if (defined $r0 && $r0 == $r1);
3163 print STDERR "r$r1 of $i not imported\n";
3164 next;
3165 }
3166 return undef;
3167 }
3168
3169 sub find_graft_path_parents {
3170 my ($grafts, $tree_paths, $c, $p0, $r0) = @_;
3171 foreach my $x (keys %$tree_paths) {
3172 next unless ($p0 =~ /^\Q$x\E/);
3173 my $i = $tree_paths->{$x};
3174 my ($r, $parent) = find_rev_before($r0, $i, 1);
3175 if (defined $r && defined $parent && revisions_eq($x,$r,$r0)) {
3176 my ($url_b, undef, $uuid_b) = cmt_metadata($c);
3177 my ($url_a, undef, $uuid_a) = cmt_metadata($parent);
3178 next if ($url_a && $url_b && $url_a eq $url_b &&
3179 $uuid_b eq $uuid_a);
3180 $grafts->{$c}->{$parent} = 1;
3181 }
3182 }
3183 }
3184
3185 sub libsvn_graft_file_copies {
3186 my ($grafts, $tree_paths, $path, $paths, $rev) = @_;
3187 foreach (keys %$paths) {
3188 my $i = $paths->{$_};
3189 my ($m, $p0, $r0) = ($i->action, $i->copyfrom_path,
3190 $i->copyfrom_rev);
3191 next unless (defined $p0 && defined $r0);
3192
3193 my $p1 = $_;
3194 $p1 =~ s#^/##;
3195 $p0 =~ s#^/##;
3196 my $c = find_graft_path_commit($tree_paths, $p1, $rev);
3197 next unless $c;
3198 find_graft_path_parents($grafts, $tree_paths, $c, $p0, $r0);
3199 }
3200 }
3201
3202 sub set_index {
3203 my $old = $ENV{GIT_INDEX_FILE};
3204 $ENV{GIT_INDEX_FILE} = shift;
3205 return $old;
3206 }
3207
3208 sub restore_index {
3209 my ($old) = @_;
3210 if (defined $old) {
3211 $ENV{GIT_INDEX_FILE} = $old;
3212 } else {
3213 delete $ENV{GIT_INDEX_FILE};
3214 }
3215 }
3216
3217 sub libsvn_commit_cb {
3218 my ($rev, $date, $committer, $c, $msg, $r_last, $cmt_last) = @_;
3219 if ($_optimize_commits && $rev == ($r_last + 1)) {
3220 my $log = libsvn_log_entry($rev,$committer,$date,$msg);
3221 $log->{tree} = get_tree_from_treeish($c);
3222 my $cmt = git_commit($log, $cmt_last, $c);
3223 my @diff = safe_qx('git-diff-tree', $cmt, $c);
3224 if (@diff) {
3225 print STDERR "Trees differ: $cmt $c\n",
3226 join('',@diff),"\n";
3227 exit 1;
3228 }
3229 } else {
3230 fetch("$rev=$c");
3231 }
3232 }
3233
3234 sub libsvn_ls_fullurl {
3235 my $fullurl = shift;
3236 $SVN ||= libsvn_connect($fullurl);
3237 my @ret;
3238 my $pool = SVN::Pool->new;
3239 my ($dirent, undef, undef) = $SVN->get_dir($SVN->{svn_path},
3240 $SVN->get_latest_revnum, $pool);
3241 foreach my $d (keys %$dirent) {
3242 if ($dirent->{$d}->kind == $SVN::Node::dir) {
3243 push @ret, "$d/"; # add '/' for compat with cli svn
3244 }
3245 }
3246 $pool->clear;
3247 return @ret;
3248 }
3249
3250
3251 sub libsvn_skip_unknown_revs {
3252 my $err = shift;
3253 my $errno = $err->apr_err();
3254 # Maybe the branch we're tracking didn't
3255 # exist when the repo started, so it's
3256 # not an error if it doesn't, just continue
3257 #
3258 # Wonderfully consistent library, eh?
3259 # 160013 - svn:// and file://
3260 # 175002 - http(s)://
3261 # 175007 - http(s):// (this repo required authorization, too...)
3262 # More codes may be discovered later...
3263 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
3264 return;
3265 }
3266 croak "Error from SVN, ($errno): ", $err->expanded_message,"\n";
3267 };
3268
3269 # Tie::File seems to be prone to offset errors if revisions get sparse,
3270 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
3271 # one of my favorite modules is out :< Next up would be one of the DBM
3272 # modules, but I'm not sure which is most portable... So I'll just
3273 # go with something that's plain-text, but still capable of
3274 # being randomly accessed. So here's my ultra-simple fixed-width
3275 # database. All records are 40 characters + "\n", so it's easy to seek
3276 # to a revision: (41 * rev) is the byte offset.
3277 # A record of 40 0s denotes an empty revision.
3278 # And yes, it's still pretty fast (faster than Tie::File).
3279 sub revdb_set {
3280 my ($file, $rev, $commit) = @_;
3281 length $commit == 40 or croak "arg3 must be a full SHA1 hexsum\n";
3282 open my $fh, '+<', $file or croak $!;
3283 my $offset = $rev * 41;
3284 # assume that append is the common case:
3285 seek $fh, 0, 2 or croak $!;
3286 my $pos = tell $fh;
3287 if ($pos < $offset) {
3288 print $fh (('0' x 40),"\n") x (($offset - $pos) / 41);
3289 }
3290 seek $fh, $offset, 0 or croak $!;
3291 print $fh $commit,"\n";
3292 close $fh or croak $!;
3293 }
3294
3295 sub revdb_get {
3296 my ($file, $rev) = @_;
3297 my $ret;
3298 my $offset = $rev * 41;
3299 open my $fh, '<', $file or croak $!;
3300 seek $fh, $offset, 0;
3301 if (tell $fh == $offset) {
3302 $ret = readline $fh;
3303 if (defined $ret) {
3304 chomp $ret;
3305 $ret = undef if ($ret =~ /^0{40}$/);
3306 }
3307 }
3308 close $fh or croak $!;
3309 return $ret;
3310 }
3311
3312 sub copy_remote_ref {
3313 my $origin = $_cp_remote ? $_cp_remote : 'origin';
3314 my $ref = "refs/remotes/$GIT_SVN";
3315 if (safe_qx('git-ls-remote', $origin, $ref)) {
3316 sys(qw/git fetch/, $origin, "$ref:$ref");
3317 } elsif ($_cp_remote && !$_upgrade) {
3318 die "Unable to find remote reference: ",
3319 "refs/remotes/$GIT_SVN on $origin\n";
3320 }
3321 }
3322
3323 package SVN::Git::Editor;
3324 use vars qw/@ISA/;
3325 use strict;
3326 use warnings;
3327 use Carp qw/croak/;
3328 use IO::File;
3329
3330 sub new {
3331 my $class = shift;
3332 my $git_svn = shift;
3333 my $self = SVN::Delta::Editor->new(@_);
3334 bless $self, $class;
3335 foreach (qw/svn_path c r ra /) {
3336 die "$_ required!\n" unless (defined $git_svn->{$_});
3337 $self->{$_} = $git_svn->{$_};
3338 }
3339 $self->{pool} = SVN::Pool->new;
3340 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
3341 $self->{rm} = { };
3342 require Digest::MD5;
3343 return $self;
3344 }
3345
3346 sub split_path {
3347 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
3348 }
3349
3350 sub repo_path {
3351 (defined $_[1] && length $_[1]) ? $_[1] : ''
3352 }
3353
3354 sub url_path {
3355 my ($self, $path) = @_;
3356 $self->{ra}->{url} . '/' . $self->repo_path($path);
3357 }
3358
3359 sub rmdirs {
3360 my ($self, $q) = @_;
3361 my $rm = $self->{rm};
3362 delete $rm->{''}; # we never delete the url we're tracking
3363 return unless %$rm;
3364
3365 foreach (keys %$rm) {
3366 my @d = split m#/#, $_;
3367 my $c = shift @d;
3368 $rm->{$c} = 1;
3369 while (@d) {
3370 $c .= '/' . shift @d;
3371 $rm->{$c} = 1;
3372 }
3373 }
3374 delete $rm->{$self->{svn_path}};
3375 delete $rm->{''}; # we never delete the url we're tracking
3376 return unless %$rm;
3377
3378 defined(my $pid = open my $fh,'-|') or croak $!;
3379 if (!$pid) {
3380 exec qw/git-ls-tree --name-only -r -z/, $self->{c} or croak $!;
3381 }
3382 local $/ = "\0";
3383 while (<$fh>) {
3384 chomp;
3385 my @dn = split m#/#, $_;
3386 while (pop @dn) {
3387 delete $rm->{join '/', @dn};
3388 }
3389 unless (%$rm) {
3390 close $fh;
3391 return;
3392 }
3393 }
3394 close $fh;
3395
3396 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
3397 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
3398 $self->close_directory($bat->{$d}, $p);
3399 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
3400 print "\tD+\t/$d/\n" unless $q;
3401 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
3402 delete $bat->{$d};
3403 }
3404 }
3405
3406 sub open_or_add_dir {
3407 my ($self, $full_path, $baton) = @_;
3408 my $p = SVN::Pool->new;
3409 my $t = $self->{ra}->check_path($full_path, $self->{r}, $p);
3410 $p->clear;
3411 if ($t == $SVN::Node::none) {
3412 return $self->add_directory($full_path, $baton,
3413 undef, -1, $self->{pool});
3414 } elsif ($t == $SVN::Node::dir) {
3415 return $self->open_directory($full_path, $baton,
3416 $self->{r}, $self->{pool});
3417 }
3418 print STDERR "$full_path already exists in repository at ",
3419 "r$self->{r} and it is not a directory (",
3420 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
3421 exit 1;
3422 }
3423
3424 sub ensure_path {
3425 my ($self, $path) = @_;
3426 my $bat = $self->{bat};
3427 $path = $self->repo_path($path);
3428 return $bat->{''} unless (length $path);
3429 my @p = split m#/+#, $path;
3430 my $c = shift @p;
3431 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
3432 while (@p) {
3433 my $c0 = $c;
3434 $c .= '/' . shift @p;
3435 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
3436 }
3437 return $bat->{$c};
3438 }
3439
3440 sub A {
3441 my ($self, $m, $q) = @_;
3442 my ($dir, $file) = split_path($m->{file_b});
3443 my $pbat = $self->ensure_path($dir);
3444 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3445 undef, -1);
3446 print "\tA\t$m->{file_b}\n" unless $q;
3447 $self->chg_file($fbat, $m);
3448 $self->close_file($fbat,undef,$self->{pool});
3449 }
3450
3451 sub C {
3452 my ($self, $m, $q) = @_;
3453 my ($dir, $file) = split_path($m->{file_b});
3454 my $pbat = $self->ensure_path($dir);
3455 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3456 $self->url_path($m->{file_a}), $self->{r});
3457 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $q;
3458 $self->chg_file($fbat, $m);
3459 $self->close_file($fbat,undef,$self->{pool});
3460 }
3461
3462 sub delete_entry {
3463 my ($self, $path, $pbat) = @_;
3464 my $rpath = $self->repo_path($path);
3465 my ($dir, $file) = split_path($rpath);
3466 $self->{rm}->{$dir} = 1;
3467 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
3468 }
3469
3470 sub R {
3471 my ($self, $m, $q) = @_;
3472 my ($dir, $file) = split_path($m->{file_b});
3473 my $pbat = $self->ensure_path($dir);
3474 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
3475 $self->url_path($m->{file_a}), $self->{r});
3476 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $q;
3477 $self->chg_file($fbat, $m);
3478 $self->close_file($fbat,undef,$self->{pool});
3479
3480 ($dir, $file) = split_path($m->{file_a});
3481 $pbat = $self->ensure_path($dir);
3482 $self->delete_entry($m->{file_a}, $pbat);
3483 }
3484
3485 sub M {
3486 my ($self, $m, $q) = @_;
3487 my ($dir, $file) = split_path($m->{file_b});
3488 my $pbat = $self->ensure_path($dir);
3489 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
3490 $pbat,$self->{r},$self->{pool});
3491 print "\t$m->{chg}\t$m->{file_b}\n" unless $q;
3492 $self->chg_file($fbat, $m);
3493 $self->close_file($fbat,undef,$self->{pool});
3494 }
3495
3496 sub T { shift->M(@_) }
3497
3498 sub change_file_prop {
3499 my ($self, $fbat, $pname, $pval) = @_;
3500 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
3501 }
3502
3503 sub chg_file {
3504 my ($self, $fbat, $m) = @_;
3505 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
3506 $self->change_file_prop($fbat,'svn:executable','*');
3507 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
3508 $self->change_file_prop($fbat,'svn:executable',undef);
3509 }
3510 my $fh = IO::File->new_tmpfile or croak $!;
3511 if ($m->{mode_b} =~ /^120/) {
3512 print $fh 'link ' or croak $!;
3513 $self->change_file_prop($fbat,'svn:special','*');
3514 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
3515 $self->change_file_prop($fbat,'svn:special',undef);
3516 }
3517 defined(my $pid = fork) or croak $!;
3518 if (!$pid) {
3519 open STDOUT, '>&', $fh or croak $!;
3520 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
3521 }
3522 waitpid $pid, 0;
3523 croak $? if $?;
3524 $fh->flush == 0 or croak $!;
3525 seek $fh, 0, 0 or croak $!;
3526
3527 my $md5 = Digest::MD5->new;
3528 $md5->addfile($fh) or croak $!;
3529 seek $fh, 0, 0 or croak $!;
3530
3531 my $exp = $md5->hexdigest;
3532 my $pool = SVN::Pool->new;
3533 my $atd = $self->apply_textdelta($fbat, undef, $pool);
3534 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
3535 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
3536 $pool->clear;
3537
3538 close $fh or croak $!;
3539 }
3540
3541 sub D {
3542 my ($self, $m, $q) = @_;
3543 my ($dir, $file) = split_path($m->{file_b});
3544 my $pbat = $self->ensure_path($dir);
3545 print "\tD\t$m->{file_b}\n" unless $q;
3546 $self->delete_entry($m->{file_b}, $pbat);
3547 }
3548
3549 sub close_edit {
3550 my ($self) = @_;
3551 my ($p,$bat) = ($self->{pool}, $self->{bat});
3552 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
3553 $self->close_directory($bat->{$_}, $p);
3554 }
3555 $self->SUPER::close_edit($p);
3556 $p->clear;
3557 }
3558
3559 sub abort_edit {
3560 my ($self) = @_;
3561 $self->SUPER::abort_edit($self->{pool});
3562 $self->{pool}->clear;
3563 }
3564
3565 __END__
3566
3567 Data structures:
3568
3569 $svn_log hashref (as returned by svn_log_raw)
3570 {
3571 fh => file handle of the log file,
3572 state => state of the log file parser (sep/msg/rev/msg_start...)
3573 }
3574
3575 $log_msg hashref as returned by next_log_entry($svn_log)
3576 {
3577 msg => 'whitespace-formatted log entry
3578 ', # trailing newline is preserved
3579 revision => '8', # integer
3580 date => '2004-02-24T17:01:44.108345Z', # commit date
3581 author => 'committer name'
3582 };
3583
3584
3585 @mods = array of diff-index line hashes, each element represents one line
3586 of diff-index output
3587
3588 diff-index line ($m hash)
3589 {
3590 mode_a => first column of diff-index output, no leading ':',
3591 mode_b => second column of diff-index output,
3592 sha1_b => sha1sum of the final blob,
3593 chg => change type [MCRADT],
3594 file_a => original file name of a file (iff chg is 'C' or 'R')
3595 file_b => new/current file name of a file (any chg)
3596 }
3597 ;
3598
3599 # retval of read_url_paths{,_all}();
3600 $l_map = {
3601 # repository root url
3602 'https://svn.musicpd.org' => {
3603 # repository path # GIT_SVN_ID
3604 'mpd/trunk' => 'trunk',
3605 'mpd/tags/0.11.5' => 'tags/0.11.5',
3606 },
3607 }
3608
3609 Notes:
3610 I don't trust the each() function on unless I created %hash myself
3611 because the internal iterator may not have started at base.
Dscho's miscellaneous git branches