| blob | 0b314d73593c18f92bb10ac9027e884aa602de32 |
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
4 AC_PREREQ(2.59)
5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
7 AC_CONFIG_SRCDIR([git.c])
9 config_file=config.mak.autogen
10 config_append=config.mak.append
11 config_in=config.mak.in
13 echo "# ${config_append}. Generated by configure." > "${config_append}"
16 ## Definitions of macros
17 # GIT_CONF_APPEND_LINE(LINE)
18 # --------------------------
19 # Append LINE to file ${config_append}
20 AC_DEFUN([GIT_CONF_APPEND_LINE],
21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
22 #
23 # GIT_ARG_SET_PATH(PROGRAM)
24 # -------------------------
25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
26 AC_DEFUN([GIT_ARG_SET_PATH],
27 [AC_ARG_WITH([$1],
28 [AS_HELP_STRING([--with-$1=PATH],
29 [provide PATH to $1])],
30 [GIT_CONF_APPEND_PATH($1)],[])
31 ])# GIT_ARG_SET_PATH
32 #
33 # GIT_CONF_APPEND_PATH(PROGRAM)
34 # ------------------------------
35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
36 # Used by GIT_ARG_SET_PATH(PROGRAM)
37 AC_DEFUN([GIT_CONF_APPEND_PATH],
38 [PROGRAM=m4_toupper($1); \
39 if test "$withval" = "no"; then \
40 AC_MSG_ERROR([You cannot use git without $1]); \
41 else \
42 if test "$withval" = "yes"; then \
43 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
44 else \
45 m4_toupper($1)_PATH=$withval; \
46 AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
47 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
48 fi; \
49 fi; \
50 ]) # GIT_CONF_APPEND_PATH
51 #
52 # GIT_PARSE_WITH(PACKAGE)
53 # -----------------------
54 # For use in AC_ARG_WITH action-if-found, for packages default ON.
55 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
56 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
57 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
58 AC_DEFUN([GIT_PARSE_WITH],
59 [PACKAGE=m4_toupper($1); \
60 if test "$withval" = "no"; then \
61 m4_toupper(NO_$1)=YesPlease; \
62 elif test "$withval" = "yes"; then \
63 m4_toupper(NO_$1)=; \
64 else \
65 m4_toupper(NO_$1)=; \
66 m4_toupper($1)DIR=$withval; \
67 AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
68 GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
69 fi \
70 ])# GIT_PARSE_WITH
72 dnl
73 dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
74 dnl -----------------------------------------
75 dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
76 dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
77 dnl -Wall), it does not work. By looking for function definition in
78 dnl libraries, this problem can be worked around.
79 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
80 AC_SEARCH_LIBS([$1],,
81 [$2],[$3])
82 ],[$3])])
83 ## Site configuration related to programs (before tests)
84 ## --with-PACKAGE[=ARG] and --without-PACKAGE
85 #
86 # Set lib to alternative name of lib directory (e.g. lib64)
87 AC_ARG_WITH([lib],
88 [AS_HELP_STRING([--with-lib=ARG],
89 [ARG specifies alternative name for lib directory])],
90 [if test "$withval" = "no" || test "$withval" = "yes"; then \
91 AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
92 else \
93 lib=$withval; \
94 AC_MSG_NOTICE([Setting lib to '$lib']); \
95 GIT_CONF_APPEND_LINE(lib=$withval); \
96 fi; \
97 ],[])
99 if test -z "$lib"; then
100 AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
101 lib=lib
102 fi
103 #
104 # Define SHELL_PATH to provide path to shell.
105 GIT_ARG_SET_PATH(shell)
106 #
107 # Define PERL_PATH to provide path to Perl.
108 GIT_ARG_SET_PATH(perl)
109 #
110 # Define ZLIB_PATH to provide path to zlib.
111 GIT_ARG_SET_PATH(zlib)
112 #
113 # Declare the with-tcltk/without-tcltk options.
114 AC_ARG_WITH(tcltk,
115 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
116 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
117 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
118 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
119 GIT_PARSE_WITH(tcltk))
120 #
123 ## Checks for programs.
124 AC_MSG_NOTICE([CHECKS for programs])
125 #
126 AC_PROG_CC([cc gcc])
127 # which switch to pass runtime path to dynamic libraries to the linker
128 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
129 SAVE_LDFLAGS="${LDFLAGS}"
130 LDFLAGS="${SAVE_LDFLAGS} -R /"
131 AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
132 LDFLAGS="${SAVE_LDFLAGS}"
133 ])
134 if test "$git_cv_ld_dashr" = "yes"; then
135 AC_SUBST(CC_LD_DYNPATH, [-R])
136 else
137 AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
138 SAVE_LDFLAGS="${LDFLAGS}"
139 LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
140 AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
141 LDFLAGS="${SAVE_LDFLAGS}"
142 ])
143 if test "$git_cv_ld_wl_rpath" = "yes"; then
144 AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
145 else
146 AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
147 SAVE_LDFLAGS="${LDFLAGS}"
148 LDFLAGS="${SAVE_LDFLAGS} -rpath /"
149 AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
150 LDFLAGS="${SAVE_LDFLAGS}"
151 ])
152 if test "$git_cv_ld_rpath" = "yes"; then
153 AC_SUBST(CC_LD_DYNPATH, [-rpath])
154 else
155 AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
156 fi
157 fi
158 fi
159 #AC_PROG_INSTALL # needs install-sh or install.sh in sources
160 AC_CHECK_TOOLS(AR, [gar ar], :)
161 AC_CHECK_PROGS(TAR, [gtar tar])
162 # TCLTK_PATH will be set to some value if we want Tcl/Tk
163 # or will be empty otherwise.
164 if test -z "$NO_TCLTK"; then
165 if test "$with_tcltk" = ""; then
166 # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
167 TCLTK_PATH=wish
168 AC_SUBST(TCLTK_PATH)
169 elif test "$with_tcltk" = "yes"; then
170 # Tcl/Tk check requested.
171 AC_CHECK_PROGS(TCLTK_PATH, [wish], )
172 else
173 AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
174 TCLTK_PATH="$with_tcltk"
175 AC_SUBST(TCLTK_PATH)
176 fi
177 fi
178 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
179 if test -n "$ASCIIDOC"; then
180 AC_MSG_CHECKING([for asciidoc version])
181 asciidoc_version=`$ASCIIDOC --version 2>&1`
182 case "${asciidoc_version}" in
183 asciidoc' '8*)
184 ASCIIDOC8=YesPlease
185 AC_MSG_RESULT([${asciidoc_version} > 7])
186 ;;
187 asciidoc' '7*)
188 ASCIIDOC8=
189 AC_MSG_RESULT([${asciidoc_version}])
190 ;;
191 *)
192 ASCIIDOC8=
193 AC_MSG_RESULT([${asciidoc_version} (unknown)])
194 ;;
195 esac
196 fi
197 AC_SUBST(ASCIIDOC8)
200 ## Checks for libraries.
201 AC_MSG_NOTICE([CHECKS for libraries])
202 #
203 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
204 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
205 AC_CHECK_LIB([crypto], [SHA1_Init],
206 [NEEDS_SSL_WITH_CRYPTO=],
207 [AC_CHECK_LIB([ssl], [SHA1_Init],
208 [NEEDS_SSL_WITH_CRYPTO=YesPlease
209 NEEDS_SSL_WITH_CRYPTO=],
210 [NO_OPENSSL=YesPlease])])
211 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
212 AC_SUBST(NO_OPENSSL)
213 #
214 # Define NO_CURL if you do not have libcurl installed. git-http-pull and
215 # git-http-push are not built, and you cannot use http:// and https://
216 # transports.
217 AC_CHECK_LIB([curl], [curl_global_init],
218 [NO_CURL=],
219 [NO_CURL=YesPlease])
220 AC_SUBST(NO_CURL)
221 #
222 # Define NO_EXPAT if you do not have expat installed. git-http-push is
223 # not built, and you cannot push using http:// and https:// transports.
224 AC_CHECK_LIB([expat], [XML_ParserCreate],
225 [NO_EXPAT=],
226 [NO_EXPAT=YesPlease])
227 AC_SUBST(NO_EXPAT)
228 #
229 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
230 # some Solaris installations).
231 # Define NO_ICONV if neither libc nor libiconv support iconv.
232 AC_DEFUN([ICONVTEST_SRC], [
233 #include <iconv.h>
235 int main(void)
236 {
237 iconv_open("", "");
238 return 0;
239 }
240 ])
241 AC_MSG_CHECKING([for iconv in -lc])
242 AC_LINK_IFELSE(ICONVTEST_SRC,
243 [AC_MSG_RESULT([yes])
244 NEEDS_LIBICONV=],
245 [AC_MSG_RESULT([no])
246 old_LIBS="$LIBS"
247 LIBS="$LIBS -liconv"
248 AC_MSG_CHECKING([for iconv in -liconv])
249 AC_LINK_IFELSE(ICONVTEST_SRC,
250 [AC_MSG_RESULT([yes])
251 NEEDS_LIBICONV=YesPlease],
252 [AC_MSG_RESULT([no])
253 NO_ICONV=YesPlease])
254 LIBS="$old_LIBS"])
255 AC_SUBST(NEEDS_LIBICONV)
256 AC_SUBST(NO_ICONV)
257 test -n "$NEEDS_LIBICONV" && LIBS="$LIBS -liconv"
258 #
259 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
260 AC_DEFUN([ZLIBTEST_SRC], [
261 #include <zlib.h>
263 int main(void)
264 {
265 deflateBound(0, 0);
266 return 0;
267 }
268 ])
269 AC_MSG_CHECKING([for deflateBound in -lz])
270 old_LIBS="$LIBS"
271 LIBS="$LIBS -lz"
272 AC_LINK_IFELSE(ZLIBTEST_SRC,
273 [AC_MSG_RESULT([yes])],
274 [AC_MSG_RESULT([no])
275 NO_DEFLATE_BOUND=yes])
276 LIBS="$old_LIBS"
277 AC_SUBST(NO_DEFLATE_BOUND)
278 #
279 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
280 # Patrick Mauritz).
281 AC_CHECK_LIB([c], [socket],
282 [NEEDS_SOCKET=],
283 [NEEDS_SOCKET=YesPlease])
284 AC_SUBST(NEEDS_SOCKET)
285 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
288 ## Checks for header files.
289 AC_MSG_NOTICE([CHECKS for header files])
290 #
291 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
292 AC_CHECK_HEADER([sys/select.h],
293 [NO_SYS_SELECT_H=],
294 [NO_SYS_SELECT_H=UnfortunatelyYes])
295 AC_SUBST(NO_SYS_SELECT_H)
296 #
297 # Define OLD_ICONV if your library has an old iconv(), where the second
298 # (input buffer pointer) parameter is declared with type (const char **).
299 AC_DEFUN([OLDICONVTEST_SRC], [[
300 #include <iconv.h>
302 extern size_t iconv(iconv_t cd,
303 char **inbuf, size_t *inbytesleft,
304 char **outbuf, size_t *outbytesleft);
306 int main(void)
307 {
308 return 0;
309 }
310 ]])
311 AC_MSG_CHECKING([for old iconv()])
312 AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
313 [AC_MSG_RESULT([no])],
314 [AC_MSG_RESULT([yes])
315 OLD_ICONV=UnfortunatelyYes])
316 AC_SUBST(OLD_ICONV)
319 ## Checks for typedefs, structures, and compiler characteristics.
320 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
321 #
322 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
323 AC_CHECK_MEMBER(struct dirent.d_ino,
324 [NO_D_INO_IN_DIRENT=],
325 [NO_D_INO_IN_DIRENT=YesPlease],
326 [#include <dirent.h>])
327 AC_SUBST(NO_D_INO_IN_DIRENT)
328 #
329 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
330 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
331 AC_CHECK_MEMBER(struct dirent.d_type,
332 [NO_D_TYPE_IN_DIRENT=],
333 [NO_D_TYPE_IN_DIRENT=YesPlease],
334 [#include <dirent.h>])
335 AC_SUBST(NO_D_TYPE_IN_DIRENT)
336 #
337 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
338 # sockaddr_storage.
339 AC_CHECK_TYPE(struct sockaddr_storage,
340 [NO_SOCKADDR_STORAGE=],
341 [NO_SOCKADDR_STORAGE=YesPlease],[
342 #include <sys/types.h>
343 #include <sys/socket.h>
344 ])
345 AC_SUBST(NO_SOCKADDR_STORAGE)
346 #
347 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
348 AC_CHECK_TYPE([struct addrinfo],[
349 GIT_CHECK_FUNC([getaddrinfo],
350 [NO_IPV6=],
351 [NO_IPV6=YesPlease])
352 ],[NO_IPV6=YesPlease],[
353 #include <sys/types.h>
354 #include <sys/socket.h>
355 #include <netdb.h>
356 ])
357 AC_SUBST(NO_IPV6)
358 #
359 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
360 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
361 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
362 # some C compilers supported these specifiers prior to C99 as an extension.
363 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
364 [ac_cv_c_c99_format],
365 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
366 AC_RUN_IFELSE(
367 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
368 [[char buf[64];
369 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
370 return 1;
371 else if (strcmp(buf, "12345"))
372 return 2;]])],
373 [ac_cv_c_c99_format=yes],
374 [ac_cv_c_c99_format=no])
375 ])
376 if test $ac_cv_c_c99_format = no; then
377 NO_C99_FORMAT=YesPlease
378 else
379 NO_C99_FORMAT=
380 fi
381 AC_SUBST(NO_C99_FORMAT)
382 #
383 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
384 # when attempting to read from an fopen'ed directory.
385 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
386 [ac_cv_fread_reads_directories],
387 [
388 AC_RUN_IFELSE(
389 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
390 [[char c;
391 FILE *f = fopen(".", "r");
392 return f && fread(&c, 1, 1, f)]])],
393 [ac_cv_fread_reads_directories=no],
394 [ac_cv_fread_reads_directories=yes])
395 ])
396 if test $ac_cv_fread_reads_directories = yes; then
397 FREAD_READS_DIRECTORIES=UnfortunatelyYes
398 else
399 FREAD_READS_DIRECTORIES=
400 fi
401 AC_SUBST(FREAD_READS_DIRECTORIES)
402 #
403 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
404 # or vsnprintf() return -1 instead of number of characters which would
405 # have been written to the final string if enough space had been available.
406 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
407 [ac_cv_snprintf_returns_bogus],
408 [
409 AC_RUN_IFELSE(
410 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
411 #include "stdarg.h"
413 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
414 {
415 int ret;
416 va_list ap;
417 va_start(ap, format);
418 ret = vsnprintf(str, maxsize, format, ap);
419 va_end(ap);
420 return ret;
421 }],
422 [[char buf[6];
423 if (test_vsnprintf(buf, 3, "%s", "12345") != 5
424 || strcmp(buf, "12")) return 1;
425 if (snprintf(buf, 3, "%s", "12345") != 5
426 || strcmp(buf, "12")) return 1]])],
427 [ac_cv_snprintf_returns_bogus=no],
428 [ac_cv_snprintf_returns_bogus=yes])
429 ])
430 if test $ac_cv_snprintf_returns_bogus = yes; then
431 SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
432 else
433 SNPRINTF_RETURNS_BOGUS=
434 fi
435 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
438 ## Checks for library functions.
439 ## (in default C library and libraries checked by AC_CHECK_LIB)
440 AC_MSG_NOTICE([CHECKS for library functions])
441 #
442 # Define NO_STRCASESTR if you don't have strcasestr.
443 GIT_CHECK_FUNC(strcasestr,
444 [NO_STRCASESTR=],
445 [NO_STRCASESTR=YesPlease])
446 AC_SUBST(NO_STRCASESTR)
447 #
448 # Define NO_MEMMEM if you don't have memmem.
449 GIT_CHECK_FUNC(memmem,
450 [NO_MEMMEM=],
451 [NO_MEMMEM=YesPlease])
452 AC_SUBST(NO_MEMMEM)
453 #
454 # Define NO_STRLCPY if you don't have strlcpy.
455 GIT_CHECK_FUNC(strlcpy,
456 [NO_STRLCPY=],
457 [NO_STRLCPY=YesPlease])
458 AC_SUBST(NO_STRLCPY)
459 #
460 # Define NO_UINTMAX_T if your platform does not have uintmax_t
461 AC_CHECK_TYPE(uintmax_t,
462 [NO_UINTMAX_T=],
463 [NO_UINTMAX_T=YesPlease],[
464 #include <inttypes.h>
465 ])
466 AC_SUBST(NO_UINTMAX_T)
467 #
468 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
469 GIT_CHECK_FUNC(strtoumax,
470 [NO_STRTOUMAX=],
471 [NO_STRTOUMAX=YesPlease])
472 AC_SUBST(NO_STRTOUMAX)
473 #
474 # Define NO_SETENV if you don't have setenv in the C library.
475 GIT_CHECK_FUNC(setenv,
476 [NO_SETENV=],
477 [NO_SETENV=YesPlease])
478 AC_SUBST(NO_SETENV)
479 #
480 # Define NO_UNSETENV if you don't have unsetenv in the C library.
481 GIT_CHECK_FUNC(unsetenv,
482 [NO_UNSETENV=],
483 [NO_UNSETENV=YesPlease])
484 AC_SUBST(NO_UNSETENV)
485 #
486 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
487 GIT_CHECK_FUNC(mkdtemp,
488 [NO_MKDTEMP=],
489 [NO_MKDTEMP=YesPlease])
490 AC_SUBST(NO_MKDTEMP)
491 #
492 # Define NO_MMAP if you want to avoid mmap.
493 #
494 # Define NO_ICONV if your libc does not properly support iconv.
497 ## Other checks.
498 # Define USE_PIC if you need the main git objects to be built with -fPIC
499 # in order to build and link perl/Git.so. x86-64 seems to need this.
500 #
501 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
502 # Enable it on Windows. By default, symrefs are still used.
503 #
504 # Define NO_PTHREADS if we do not have pthreads
505 #
506 # Define PTHREAD_LIBS to the linker flag used for Pthread support and define
507 # THREADED_DELTA_SEARCH if Pthreads are available.
508 AC_LANG_CONFTEST([AC_LANG_PROGRAM(
509 [[#include <pthread.h>]],
510 [[pthread_mutex_t test_mutex;]]
511 )])
512 ${CC} -pthread conftest.c -o conftest.o > /dev/null 2>&1
513 if test $? -eq 0;then
514 PTHREAD_LIBS="-pthread"
515 THREADED_DELTA_SEARCH=YesPlease
516 else
517 ${CC} -lpthread conftest.c -o conftest.o > /dev/null 2>&1
518 if test $? -eq 0;then
519 PTHREAD_LIBS="-lpthread"
520 THREADED_DELTA_SEARCH=YesPlease
521 else
522 NO_PTHREADS=UnfortunatelyYes
523 fi
524 fi
525 AC_SUBST(PTHREAD_LIBS)
526 AC_SUBST(NO_PTHREADS)
527 AC_SUBST(THREADED_DELTA_SEARCH)
529 ## Site configuration (override autodetection)
530 ## --with-PACKAGE[=ARG] and --without-PACKAGE
531 AC_MSG_NOTICE([CHECKS for site configuration])
532 #
533 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
534 # tests. These tests take up a significant amount of the total test time
535 # but are not needed unless you plan to talk to SVN repos.
536 #
537 # Define MOZILLA_SHA1 environment variable when running make to make use of
538 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
539 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
540 # choice) has very fast version optimized for i586.
541 #
542 # Define PPC_SHA1 environment variable when running make to make use of
543 # a bundled SHA1 routine optimized for PowerPC.
544 #
545 # Define ARM_SHA1 environment variable when running make to make use of
546 # a bundled SHA1 routine optimized for ARM.
547 #
548 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
549 # This also implies MOZILLA_SHA1.
550 #
551 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
552 # /foo/bar/include and /foo/bar/lib directories.
553 AC_ARG_WITH(openssl,
554 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
555 AS_HELP_STRING([], [ARG can be prefix for openssl library and headers]),\
556 GIT_PARSE_WITH(openssl))
557 #
558 # Define NO_CURL if you do not have curl installed. git-http-pull and
559 # git-http-push are not built, and you cannot use http:// and https://
560 # transports.
561 #
562 # Define CURLDIR=/foo/bar if your curl header and library files are in
563 # /foo/bar/include and /foo/bar/lib directories.
564 AC_ARG_WITH(curl,
565 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
566 AS_HELP_STRING([], [ARG can be also prefix for curl library and headers]),
567 GIT_PARSE_WITH(curl))
568 #
569 # Define NO_EXPAT if you do not have expat installed. git-http-push is
570 # not built, and you cannot push using http:// and https:// transports.
571 #
572 # Define EXPATDIR=/foo/bar if your expat header and library files are in
573 # /foo/bar/include and /foo/bar/lib directories.
574 AC_ARG_WITH(expat,
575 AS_HELP_STRING([--with-expat],
576 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
577 AS_HELP_STRING([], [ARG can be also prefix for expat library and headers]),
578 GIT_PARSE_WITH(expat))
579 #
580 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
581 # installed in /sw, but don't want GIT to link against any libraries
582 # installed there. If defined you may specify your own (or Fink's)
583 # include directories and library directories by defining CFLAGS
584 # and LDFLAGS appropriately.
585 #
586 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
587 # have DarwinPorts installed in /opt/local, but don't want GIT to
588 # link against any libraries installed there. If defined you may
589 # specify your own (or DarwinPort's) include directories and
590 # library directories by defining CFLAGS and LDFLAGS appropriately.
591 #
592 # Define NO_MMAP if you want to avoid mmap.
593 #
594 # Define NO_ICONV if your libc does not properly support iconv.
595 AC_ARG_WITH(iconv,
596 AS_HELP_STRING([--without-iconv],
597 [if your architecture doesn't properly support iconv])
598 AS_HELP_STRING([--with-iconv=PATH],
599 [PATH is prefix for libiconv library and headers])
600 AS_HELP_STRING([],
601 [used only if you need linking with libiconv]),
602 GIT_PARSE_WITH(iconv))
604 ## --enable-FEATURE[=ARG] and --disable-FEATURE
605 #
606 # Define USE_NSEC below if you want git to care about sub-second file mtimes
607 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
608 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
609 # randomly break unless your underlying filesystem supports those sub-second
610 # times (my ext3 doesn't).
611 #
612 # Define USE_STDEV below if you want git to care about the underlying device
613 # change being considered an inode change from the update-index perspective.
616 ## Output files
617 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
618 AC_OUTPUT
621 ## Cleanup
622 rm -f "${config_append}"