?  search:
summary | log | graphiclog1 | graphiclog2 | commit | commitdiff | tree | refs | edit | fork
blame | history | raw | HEAD
git-svn: stop using path names as refnames with --follow-parent
[git/dscho.git] / git-svn.perl
blob4f7938ab7e08f8944aa9782234895e40957c64d2
1 #!/usr/bin/env perl
2 # Copyright (C) 2006, Eric Wong <normalperson@yhbt.net>
3 # License: GPL v2 or later
4 use warnings;
5 use strict;
6 use vars qw/ $AUTHOR $VERSION
7 $SVN_URL
8 $GIT_SVN_INDEX $GIT_SVN
9 $GIT_DIR $GIT_SVN_DIR $REVDB
10 $_follow_parent $sha1 $sha1_short $_revision
11 $_cp_remote $_upgrade $_rmdir $_q $_cp_similarity
12 $_find_copies_harder $_l $_authors %users/;
13 $AUTHOR = 'Eric Wong <normalperson@yhbt.net>';
14 $VERSION = '@@GIT_VERSION@@';
15
16 $ENV{GIT_DIR} ||= '.git';
17 $Git::SVN::default_repo_id = 'git-svn';
18 $Git::SVN::default_ref_id = $ENV{GIT_SVN_ID} || 'git-svn';
19
20 my $LC_ALL = $ENV{LC_ALL};
21 $Git::SVN::Log::TZ = $ENV{TZ};
22 # make sure the svn binary gives consistent output between locales and TZs:
23 $ENV{TZ} = 'UTC';
24 $ENV{LC_ALL} = 'C';
25 $| = 1; # unbuffer STDOUT
26
27 sub fatal (@) { print STDERR @_; exit 1 }
28 require SVN::Core; # use()-ing this causes segfaults for me... *shrug*
29 require SVN::Ra;
30 require SVN::Delta;
31 if ($SVN::Core::VERSION lt '1.1.0') {
32 fatal "Need SVN::Core 1.1.0 or better (got $SVN::Core::VERSION)\n";
33 }
34 push @Git::SVN::Ra::ISA, 'SVN::Ra';
35 push @SVN::Git::Editor::ISA, 'SVN::Delta::Editor';
36 push @SVN::Git::Fetcher::ISA, 'SVN::Delta::Editor';
37 use Carp qw/croak/;
38 use IO::File qw//;
39 use File::Basename qw/dirname basename/;
40 use File::Path qw/mkpath/;
41 use Getopt::Long qw/:config gnu_getopt no_ignore_case auto_abbrev pass_through/;
42 use IPC::Open3;
43 use Git;
44
45 BEGIN {
46 my $s;
47 foreach (qw/command command_oneline command_noisy command_output_pipe
48 command_input_pipe command_close_pipe/) {
49 $s .= "*SVN::Git::Editor::$_ = *SVN::Git::Fetcher::$_ = ".
50 "*Git::SVN::Migration::$_ = ".
51 "*Git::SVN::Log::$_ = *Git::SVN::$_ = *$_ = *Git::$_; ";
52 }
53 eval $s;
54 }
55
56 my ($SVN);
57
58 my $_optimize_commits = 1 unless $ENV{GIT_SVN_NO_OPTIMIZE_COMMITS};
59 $sha1 = qr/[a-f\d]{40}/;
60 $sha1_short = qr/[a-f\d]{4,40}/;
61 my ($_stdin, $_help, $_edit,
62 $_repack, $_repack_nr, $_repack_flags,
63 $_message, $_file, $_no_metadata,
64 $_template, $_shared,
65 $_version, $_upgrade,
66 $_merge, $_strategy, $_dry_run,
67 $_prefix);
68
69 my %remote_opts = ( 'username=s' => \$Git::SVN::Prompt::_username,
70 'config-dir=s' => \$Git::SVN::Ra::config_dir,
71 'no-auth-cache' => \$Git::SVN::Prompt::_no_auth_cache );
72 my %fc_opts = ( 'follow-parent|follow' => \$_follow_parent,
73 'authors-file|A=s' => \$_authors,
74 'repack:i' => \$_repack,
75 'no-metadata' => \$_no_metadata,
76 'quiet|q' => \$_q,
77 'repack-flags|repack-args|repack-opts=s' => \$_repack_flags,
78 %remote_opts );
79
80 my ($_trunk, $_tags, $_branches);
81 my %multi_opts = ( 'trunk|T=s' => \$_trunk,
82 'tags|t=s' => \$_tags,
83 'branches|b=s' => \$_branches );
84 my %init_opts = ( 'template=s' => \$_template, 'shared' => \$_shared );
85 my %cmt_opts = ( 'edit|e' => \$_edit,
86 'rmdir' => \$_rmdir,
87 'find-copies-harder' => \$_find_copies_harder,
88 'l=i' => \$_l,
89 'copy-similarity|C=i'=> \$_cp_similarity
90 );
91
92 my %cmd = (
93 fetch => [ \&cmd_fetch, "Download new revisions from SVN",
94 { 'revision|r=s' => \$_revision, %fc_opts } ],
95 init => [ \&cmd_init, "Initialize a repo for tracking" .
96 " (requires URL argument)",
97 \%init_opts ],
98 dcommit => [ \&cmd_dcommit,
99 'Commit several diffs to merge with upstream',
100 { 'merge|m|M' => \$_merge,
101 'strategy|s=s' => \$_strategy,
102 'dry-run|n' => \$_dry_run,
103 %cmt_opts, %fc_opts } ],
104 'set-tree' => [ \&cmd_set_tree,
105 "Set an SVN repository to a git tree-ish",
106 { 'stdin|' => \$_stdin, %cmt_opts, %fc_opts, } ],
107 'show-ignore' => [ \&cmd_show_ignore, "Show svn:ignore listings",
108 { 'revision|r=i' => \$_revision } ],
109 rebuild => [ \&cmd_rebuild, "Rebuild git-svn metadata (after git clone)",
110 { 'copy-remote|remote=s' => \$_cp_remote,
111 'upgrade' => \$_upgrade } ],
112 'multi-init' => [ \&cmd_multi_init,
113 'Initialize multiple trees (like git-svnimport)',
114 { %multi_opts, %init_opts, %remote_opts,
115 'revision|r=i' => \$_revision,
116 'prefix=s' => \$_prefix,
117 } ],
118 'multi-fetch' => [ \&cmd_multi_fetch,
119 'Fetch multiple trees (like git-svnimport)',
120 \%fc_opts ],
121 'migrate' => [ sub { },
122 # no-op, we automatically run this anyways,
123 'Migrate configuration/metadata/layout from
124 previous versions of git-svn',
125 \%remote_opts ],
126 'log' => [ \&Git::SVN::Log::cmd_show_log, 'Show commit logs',
127 { 'limit=i' => \$Git::SVN::Log::limit,
128 'revision|r=s' => \$_revision,
129 'verbose|v' => \$Git::SVN::Log::verbose,
130 'incremental' => \$Git::SVN::Log::incremental,
131 'oneline' => \$Git::SVN::Log::oneline,
132 'show-commit' => \$Git::SVN::Log::show_commit,
133 'non-recursive' => \$Git::SVN::Log::non_recursive,
134 'authors-file|A=s' => \$_authors,
135 'color' => \$Git::SVN::Log::color,
136 'pager=s' => \$Git::SVN::Log::pager,
137 } ],
138 'commit-diff' => [ \&cmd_commit_diff,
139 'Commit a diff between two trees',
140 { 'message|m=s' => \$_message,
141 'file|F=s' => \$_file,
142 'revision|r=s' => \$_revision,
143 %cmt_opts } ],
144 );
145
146 my $cmd;
147 for (my $i = 0; $i < @ARGV; $i++) {
148 if (defined $cmd{$ARGV[$i]}) {
149 $cmd = $ARGV[$i];
150 splice @ARGV, $i, 1;
151 last;
152 }
153 };
154
155 my %opts = %{$cmd{$cmd}->[2]} if (defined $cmd);
156
157 read_repo_config(\%opts);
158 my $rv = GetOptions(%opts, 'help|H|h' => \$_help,
159 'version|V' => \$_version,
160 'minimize-connections' =>
161 \$Git::SVN::Migration::_minimize,
162 'id|i=s' => \$Git::SVN::default_ref_id);
163 exit 1 if (!$rv && $cmd ne 'log');
164
165 usage(0) if $_help;
166 version() if $_version;
167 usage(1) unless defined $cmd;
168 load_authors() if $_authors;
169 unless ($cmd =~ /^(?:init|rebuild|multi-init|commit-diff)$/) {
170 Git::SVN::Migration::migration_check();
171 }
172 eval {
173 Git::SVN::verify_remotes_sanity();
174 $cmd{$cmd}->[0]->(@ARGV);
175 };
176 fatal $@ if $@;
177 exit 0;
178
179 ####################### primary functions ######################
180 sub usage {
181 my $exit = shift || 0;
182 my $fd = $exit ? \*STDERR : \*STDOUT;
183 print $fd <<"";
184 git-svn - bidirectional operations between a single Subversion tree and git
185 Usage: $0 <command> [options] [arguments]\n
186
187 print $fd "Available commands:\n" unless $cmd;
188
189 foreach (sort keys %cmd) {
190 next if $cmd && $cmd ne $_;
191 print $fd ' ',pack('A17',$_),$cmd{$_}->[1],"\n";
192 foreach (keys %{$cmd{$_}->[2]}) {
193 # prints out arguments as they should be passed:
194 my $x = s#[:=]s$## ? '<arg>' : s#[:=]i$## ? '<num>' : '';
195 print $fd ' ' x 21, join(', ', map { length $_ > 1 ?
196 "--$_" : "-$_" }
197 split /\|/,$_)," $x\n";
198 }
199 }
200 print $fd <<"";
201 \nGIT_SVN_ID may be set in the environment or via the --id/-i switch to an
202 arbitrary identifier if you're tracking multiple SVN branches/repositories in
203 one git repository and want to keep them separate. See git-svn(1) for more
204 information.
205
206 exit $exit;
207 }
208
209 sub version {
210 print "git-svn version $VERSION (svn $SVN::Core::VERSION)\n";
211 exit 0;
212 }
213
214 sub cmd_rebuild {
215 my $url = shift;
216 my $gs = $url ? Git::SVN->init($url)
217 : eval { Git::SVN->new };
218 $gs ||= Git::SVN->_new;
219 if (!verify_ref($gs->refname.'^0')) {
220 $gs->copy_remote_ref;
221 }
222
223 my ($rev_list, $ctx) = command_output_pipe("rev-list", $gs->refname);
224 my $latest;
225 my $svn_uuid;
226 while (<$rev_list>) {
227 chomp;
228 my $c = $_;
229 fatal "Non-SHA1: $c\n" unless $c =~ /^$sha1$/o;
230 my ($url, $rev, $uuid) = cmt_metadata($c);
231
232 # ignore merges (from set-tree)
233 next if (!defined $rev || !$uuid);
234
235 # if we merged or otherwise started elsewhere, this is
236 # how we break out of it
237 if ((defined $svn_uuid && ($uuid ne $svn_uuid)) ||
238 ($gs->{url} && $url && ($url ne $gs->{url}))) {
239 next;
240 }
241
242 unless (defined $latest) {
243 if (!$gs->{url} && !$url) {
244 fatal "SVN repository location required\n";
245 }
246 $gs = Git::SVN->init($url);
247 $latest = $rev;
248 }
249 $gs->rev_db_set($rev, $c);
250 print "r$rev = $c\n";
251 }
252 command_close_pipe($rev_list, $ctx);
253 }
254
255 sub do_git_init_db {
256 unless (-d $ENV{GIT_DIR}) {
257 my @init_db = ('init');
258 push @init_db, "--template=$_template" if defined $_template;
259 push @init_db, "--shared" if defined $_shared;
260 command_noisy(@init_db);
261 }
262 }
263
264 sub cmd_init {
265 my $url = shift or die "SVN repository location required " .
266 "as a command-line argument\n";
267 if (my $repo_path = shift) {
268 unless (-d $repo_path) {
269 mkpath([$repo_path]);
270 }
271 chdir $repo_path or croak $!;
272 $ENV{GIT_DIR} = $repo_path . "/.git";
273 }
274 do_git_init_db();
275
276 Git::SVN->init($url);
277 }
278
279 sub cmd_fetch {
280 if (@_) {
281 die "Additional fetch arguments are no longer supported.\n",
282 "Use --follow-parent if you have moved/copied directories
283 instead.\n";
284 }
285 my $gs = Git::SVN->new;
286 $gs->fetch(parse_revision_argument());
287 if ($gs->{last_commit} && !verify_ref('refs/heads/master^0')) {
288 command_noisy(qw(update-ref refs/heads/master),
289 $gs->{last_commit});
290 }
291 }
292
293 sub cmd_set_tree {
294 my (@commits) = @_;
295 if ($_stdin || !@commits) {
296 print "Reading from stdin...\n";
297 @commits = ();
298 while (<STDIN>) {
299 if (/\b($sha1_short)\b/o) {
300 unshift @commits, $1;
301 }
302 }
303 }
304 my @revs;
305 foreach my $c (@commits) {
306 my @tmp = command('rev-parse',$c);
307 if (scalar @tmp == 1) {
308 push @revs, $tmp[0];
309 } elsif (scalar @tmp > 1) {
310 push @revs, reverse(command('rev-list',@tmp));
311 } else {
312 fatal "Failed to rev-parse $c\n";
313 }
314 }
315 my $gs = Git::SVN->new;
316 my ($r_last, $cmt_last) = $gs->last_rev_commit;
317 $gs->fetch;
318 if (defined $gs->{last_rev} && $r_last != $gs->{last_rev}) {
319 fatal "There are new revisions that were fetched ",
320 "and need to be merged (or acknowledged) ",
321 "before committing.\nlast rev: $r_last\n",
322 " current: $gs->{last_rev}\n";
323 }
324 $gs->set_tree($_) foreach @revs;
325 print "Done committing ",scalar @revs," revisions to SVN\n";
326 }
327
328 sub cmd_dcommit {
329 my $head = shift;
330 my $gs = Git::SVN->new;
331 $head ||= 'HEAD';
332 my @refs = command(qw/rev-list --no-merges/, $gs->refname."..$head");
333 my $last_rev;
334 foreach my $d (reverse @refs) {
335 if (!verify_ref("$d~1")) {
336 fatal "Commit $d\n",
337 "has no parent commit, and therefore ",
338 "nothing to diff against.\n",
339 "You should be working from a repository ",
340 "originally created by git-svn\n";
341 }
342 unless (defined $last_rev) {
343 (undef, $last_rev, undef) = cmt_metadata("$d~1");
344 unless (defined $last_rev) {
345 fatal "Unable to extract revision information ",
346 "from commit $d~1\n";
347 }
348 }
349 if ($_dry_run) {
350 print "diff-tree $d~1 $d\n";
351 } else {
352 my %ed_opts = ( r => $last_rev,
353 log => get_commit_entry($d)->{log},
354 ra => $gs->ra,
355 tree_a => "$d~1",
356 tree_b => $d,
357 editor_cb => sub {
358 print "Committed r$_[0]\n";
359 $last_rev = $_[0]; },
360 svn_path => $gs->{path} );
361 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
362 print "No changes\n$d~1 == $d\n";
363 }
364 }
365 }
366 return if $_dry_run;
367 $gs->fetch;
368 # we always want to rebase against the current HEAD, not any
369 # head that was passed to us
370 my @diff = command('diff-tree', 'HEAD', $gs->refname, '--');
371 my @finish;
372 if (@diff) {
373 @finish = qw/rebase/;
374 push @finish, qw/--merge/ if $_merge;
375 push @finish, "--strategy=$_strategy" if $_strategy;
376 print STDERR "W: HEAD and ", $gs->refname, " differ, ",
377 "using @finish:\n", "@diff";
378 } else {
379 print "No changes between current HEAD and ",
380 $gs->refname, "\nResetting to the latest ",
381 $gs->refname, "\n";
382 @finish = qw/reset --mixed/;
383 }
384 command_noisy(@finish, $gs->refname);
385 }
386
387 sub cmd_show_ignore {
388 my $gs = Git::SVN->new;
389 my $r = (defined $_revision ? $_revision : $gs->ra->get_latest_revnum);
390 $gs->traverse_ignore(\*STDOUT, '', $r);
391 }
392
393 sub cmd_multi_init {
394 my $url = shift;
395 unless (defined $_trunk || defined $_branches || defined $_tags) {
396 usage(1);
397 }
398 do_git_init_db();
399 $_prefix = '' unless defined $_prefix;
400 $url =~ s#/+$## if defined $url;
401 if (defined $_trunk) {
402 my $trunk_ref = $_prefix . 'trunk';
403 # try both old-style and new-style lookups:
404 my $gs_trunk = eval { Git::SVN->new($trunk_ref) };
405 unless ($gs_trunk) {
406 my ($trunk_url, $trunk_path) =
407 complete_svn_url($url, $_trunk);
408 $gs_trunk = Git::SVN->init($trunk_url, $trunk_path,
409 undef, $trunk_ref);
410 }
411 }
412 return unless defined $_branches || defined $_tags;
413 my $ra = $url ? Git::SVN::Ra->new($url) : undef;
414 complete_url_ls_init($ra, $_branches, '--branches/-b', $_prefix);
415 complete_url_ls_init($ra, $_tags, '--tags/-t', $_prefix . 'tags/');
416 }
417
418 sub cmd_multi_fetch {
419 my $remotes = Git::SVN::read_all_remotes();
420 foreach my $repo_id (sort keys %$remotes) {
421 my $url = $remotes->{$repo_id}->{url} or next;
422 my $fetch = $remotes->{$repo_id}->{fetch} or next;
423 Git::SVN::fetch_all($repo_id, $url, $fetch);
424 }
425 }
426
427 # this command is special because it requires no metadata
428 sub cmd_commit_diff {
429 my ($ta, $tb, $url) = @_;
430 my $usage = "Usage: $0 commit-diff -r<revision> ".
431 "<tree-ish> <tree-ish> [<URL>]\n";
432 fatal($usage) if (!defined $ta || !defined $tb);
433 my $svn_path;
434 if (!defined $url) {
435 my $gs = eval { Git::SVN->new };
436 if (!$gs) {
437 fatal("Needed URL or usable git-svn --id in ",
438 "the command-line\n", $usage);
439 }
440 $url = $gs->{url};
441 $svn_path = $gs->{path};
442 }
443 unless (defined $_revision) {
444 fatal("-r|--revision is a required argument\n", $usage);
445 }
446 if (defined $_message && defined $_file) {
447 fatal("Both --message/-m and --file/-F specified ",
448 "for the commit message.\n",
449 "I have no idea what you mean\n");
450 }
451 if (defined $_file) {
452 $_message = file_to_s($_file);
453 } else {
454 $_message ||= get_commit_entry($tb)->{log};
455 }
456 my $ra ||= Git::SVN::Ra->new($url);
457 $svn_path ||= $ra->{svn_path};
458 my $r = $_revision;
459 if ($r eq 'HEAD') {
460 $r = $ra->get_latest_revnum;
461 } elsif ($r !~ /^\d+$/) {
462 die "revision argument: $r not understood by git-svn\n";
463 }
464 my %ed_opts = ( r => $r,
465 log => $_message,
466 ra => $ra,
467 tree_a => $ta,
468 tree_b => $tb,
469 editor_cb => sub { print "Committed r$_[0]\n" },
470 svn_path => $svn_path );
471 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
472 print "No changes\n$ta == $tb\n";
473 }
474 }
475
476 ########################### utility functions #########################
477
478 sub parse_revision_argument {
479 if (!defined $_revision || $_revision eq 'BASE:HEAD') {
480 return (undef, undef);
481 }
482 return ($1, $2) if ($_revision =~ /^(\d+):(\d+)$/);
483 return ($_revision, $_revision) if ($_revision =~ /^\d+$/);
484 return (undef, $1) if ($_revision =~ /^BASE:(\d+)$/);
485 return ($1, undef) if ($_revision =~ /^(\d+):HEAD$/);
486 die "revision argument: $_revision not understood by git-svn\n",
487 "Try using the command-line svn client instead\n";
488 }
489
490 sub complete_svn_url {
491 my ($url, $path) = @_;
492 $path =~ s#/+$##;
493 if ($path !~ m#^[a-z\+]+://#) {
494 if (!defined $url || $url !~ m#^[a-z\+]+://#) {
495 fatal("E: '$path' is not a complete URL ",
496 "and a separate URL is not specified\n");
497 }
498 return ($url, $path);
499 }
500 return ($path, '');
501 }
502
503 sub complete_url_ls_init {
504 my ($ra, $repo_path, $switch, $pfx) = @_;
505 unless ($repo_path) {
506 print STDERR "W: $switch not specified\n";
507 return;
508 }
509 $repo_path =~ s#/+$##;
510 if ($repo_path =~ m#^[a-z\+]+://#) {
511 $ra = Git::SVN::Ra->new($repo_path);
512 $repo_path = '';
513 } else {
514 $repo_path =~ s#^/+##;
515 unless ($ra) {
516 fatal("E: '$repo_path' is not a complete URL ",
517 "and a separate URL is not specified\n");
518 }
519 }
520 my $r = defined $_revision ? $_revision : $ra->get_latest_revnum;
521 my ($dirent, undef, undef) = $ra->get_dir($repo_path, $r);
522 my $url = $ra->{url};
523 foreach my $d (sort keys %$dirent) {
524 next if ($dirent->{$d}->kind != $SVN::Node::dir);
525 my $path = "$repo_path/$d";
526 my $ref = "$pfx$d";
527 my $gs = eval { Git::SVN->new($ref) };
528 # don't try to init already existing refs
529 unless ($gs) {
530 print "init $url/$path => $ref\n";
531 Git::SVN->init($url, $path, undef, $ref);
532 }
533 }
534 }
535
536 sub verify_ref {
537 my ($ref) = @_;
538 eval { command_oneline([ 'rev-parse', '--verify', $ref ],
539 { STDERR => 0 }); };
540 }
541
542 sub get_tree_from_treeish {
543 my ($treeish) = @_;
544 # $treeish can be a symbolic ref, too:
545 my $type = command_oneline(qw/cat-file -t/, $treeish);
546 my $expected;
547 while ($type eq 'tag') {
548 ($treeish, $type) = command(qw/cat-file tag/, $treeish);
549 }
550 if ($type eq 'commit') {
551 $expected = (grep /^tree /, command(qw/cat-file commit/,
552 $treeish))[0];
553 ($expected) = ($expected =~ /^tree ($sha1)$/o);
554 die "Unable to get tree from $treeish\n" unless $expected;
555 } elsif ($type eq 'tree') {
556 $expected = $treeish;
557 } else {
558 die "$treeish is a $type, expected tree, tag or commit\n";
559 }
560 return $expected;
561 }
562
563 sub get_commit_entry {
564 my ($treeish) = shift;
565 my %log_entry = ( log => '', tree => get_tree_from_treeish($treeish) );
566 my $commit_editmsg = "$ENV{GIT_DIR}/COMMIT_EDITMSG";
567 my $commit_msg = "$ENV{GIT_DIR}/COMMIT_MSG";
568 open my $log_fh, '>', $commit_editmsg or croak $!;
569
570 my $type = command_oneline(qw/cat-file -t/, $treeish);
571 if ($type eq 'commit' || $type eq 'tag') {
572 my ($msg_fh, $ctx) = command_output_pipe('cat-file',
573 $type, $treeish);
574 my $in_msg = 0;
575 while (<$msg_fh>) {
576 if (!$in_msg) {
577 $in_msg = 1 if (/^\s*$/);
578 } elsif (/^git-svn-id: /) {
579 # skip this for now, we regenerate the
580 # correct one on re-fetch anyways
581 # TODO: set *:merge properties or like...
582 } else {
583 print $log_fh $_ or croak $!;
584 }
585 }
586 command_close_pipe($msg_fh, $ctx);
587 }
588 close $log_fh or croak $!;
589
590 if ($_edit || ($type eq 'tree')) {
591 my $editor = $ENV{VISUAL} || $ENV{EDITOR} || 'vi';
592 # TODO: strip out spaces, comments, like git-commit.sh
593 system($editor, $commit_editmsg);
594 }
595 rename $commit_editmsg, $commit_msg or croak $!;
596 open $log_fh, '<', $commit_msg or croak $!;
597 { local $/; chomp($log_entry{log} = <$log_fh>); }
598 close $log_fh or croak $!;
599 unlink $commit_msg;
600 \%log_entry;
601 }
602
603 sub s_to_file {
604 my ($str, $file, $mode) = @_;
605 open my $fd,'>',$file or croak $!;
606 print $fd $str,"\n" or croak $!;
607 close $fd or croak $!;
608 chmod ($mode &~ umask, $file) if (defined $mode);
609 }
610
611 sub file_to_s {
612 my $file = shift;
613 open my $fd,'<',$file or croak "$!: file: $file\n";
614 local $/;
615 my $ret = <$fd>;
616 close $fd or croak $!;
617 $ret =~ s/\s*$//s;
618 return $ret;
619 }
620
621 # '<svn username> = real-name <email address>' mapping based on git-svnimport:
622 sub load_authors {
623 open my $authors, '<', $_authors or die "Can't open $_authors $!\n";
624 my $log = $cmd eq 'log';
625 while (<$authors>) {
626 chomp;
627 next unless /^(\S+?|\(no author\))\s*=\s*(.+?)\s*<(.+)>\s*$/;
628 my ($user, $name, $email) = ($1, $2, $3);
629 if ($log) {
630 $Git::SVN::Log::rusers{"$name <$email>"} = $user;
631 } else {
632 $users{$user} = [$name, $email];
633 }
634 }
635 close $authors or croak $!;
636 }
637
638 # convert GetOpt::Long specs for use by git-config
639 sub read_repo_config {
640 return unless -d $ENV{GIT_DIR};
641 my $opts = shift;
642 foreach my $o (keys %$opts) {
643 my $v = $opts->{$o};
644 my ($key) = ($o =~ /^([a-z\-]+)/);
645 $key =~ s/-//g;
646 my $arg = 'git-config';
647 $arg .= ' --int' if ($o =~ /[:=]i$/);
648 $arg .= ' --bool' if ($o !~ /[:=][sfi]$/);
649 if (ref $v eq 'ARRAY') {
650 chomp(my @tmp = `$arg --get-all svn.$key`);
651 @$v = @tmp if @tmp;
652 } else {
653 chomp(my $tmp = `$arg --get svn.$key`);
654 if ($tmp && !($arg =~ / --bool/ && $tmp eq 'false')) {
655 $$v = $tmp;
656 }
657 }
658 }
659 }
660
661 sub extract_metadata {
662 my $id = shift or return (undef, undef, undef);
663 my ($url, $rev, $uuid) = ($id =~ /^git-svn-id:\s(\S+?)\@(\d+)
664 \s([a-f\d\-]+)$/x);
665 if (!defined $rev || !$uuid || !$url) {
666 # some of the original repositories I made had
667 # identifiers like this:
668 ($rev, $uuid) = ($id =~/^git-svn-id:\s(\d+)\@([a-f\d\-]+)/);
669 }
670 return ($url, $rev, $uuid);
671 }
672
673 sub cmt_metadata {
674 return extract_metadata((grep(/^git-svn-id: /,
675 command(qw/cat-file commit/, shift)))[-1]);
676 }
677
678 package Git::SVN;
679 use strict;
680 use warnings;
681 use vars qw/$default_repo_id $default_ref_id/;
682 use Carp qw/croak/;
683 use File::Path qw/mkpath/;
684 use IPC::Open3;
685
686 # properties that we do not log:
687 my %SKIP_PROP;
688 BEGIN {
689 %SKIP_PROP = map { $_ => 1 } qw/svn:wc:ra_dav:version-url
690 svn:special svn:executable
691 svn:entry:committed-rev
692 svn:entry:last-author
693 svn:entry:uuid
694 svn:entry:committed-date/;
695 }
696
697 sub fetch_all {
698 my ($repo_id, $url, $fetch) = @_;
699 my @gs;
700 my $ra = Git::SVN::Ra->new($url);
701 my $head = $ra->get_latest_revnum;
702 my $base = $head;
703 my $new_remote;
704 foreach my $p (sort keys %$fetch) {
705 my $gs = Git::SVN->new($fetch->{$p}, $repo_id, $p);
706 my $lr = $gs->last_rev;
707 if (defined $lr) {
708 $base = $lr if ($lr < $base);
709 } else {
710 $new_remote = 1;
711 }
712 push @gs, $gs;
713 }
714 $base = 0 if $new_remote;
715 return if (++$base > $head);
716 $ra->gs_fetch_loop_common($base, $head, @gs);
717 }
718
719 sub read_all_remotes {
720 my $r = {};
721 foreach (grep { s/^svn-remote\.// } command(qw/config -l/)) {
722 if (m!^(.+)\.fetch=\s*(.*)\s*:\s*refs/remotes/(.+)\s*$!) {
723 $r->{$1}->{fetch}->{$2} = $3;
724 } elsif (m!^(.+)\.url=\s*(.*)\s*$!) {
725 $r->{$1}->{url} = $2;
726 }
727 }
728 $r;
729 }
730
731 sub verify_remotes_sanity {
732 return unless -d $ENV{GIT_DIR};
733 my %seen;
734 foreach (command(qw/config -l/)) {
735 if (m!^svn-remote\.(?:.+)\.fetch=.*:refs/remotes/(\S+)\s*$!) {
736 if ($seen{$1}) {
737 die "Remote ref refs/remote/$1 is tracked by",
738 "\n \"$_\"\nand\n \"$seen{$1}\"\n",
739 "Please resolve this ambiguity in ",
740 "your git configuration file before ",
741 "continuing\n";
742 }
743 $seen{$1} = $_;
744 }
745 }
746 }
747
748 # we allow more chars than remotes2config.sh...
749 sub sanitize_remote_name {
750 my ($name) = @_;
751 $name =~ tr{A-Za-z0-9:,/+-}{.}c;
752 $name;
753 }
754
755 sub find_existing_remote {
756 my ($url, $remotes) = @_;
757 my $existing;
758 foreach my $repo_id (keys %$remotes) {
759 my $u = $remotes->{$repo_id}->{url} or next;
760 next if $u ne $url;
761 $existing = $repo_id;
762 last;
763 }
764 $existing;
765 }
766
767 sub init_remote_config {
768 my ($self, $url) = @_;
769 $url =~ s!/+$!!; # strip trailing slash
770 my $r = read_all_remotes();
771 my $existing = find_existing_remote($url, $r);
772 if ($existing) {
773 print STDERR "Using existing ",
774 "[svn-remote \"$existing\"]\n";
775 $self->{repo_id} = $existing;
776 } else {
777 my $min_url = Git::SVN::Ra->new($url)->minimize_url;
778 $existing = find_existing_remote($min_url, $r);
779 if ($existing) {
780 print STDERR "Using existing ",
781 "[svn-remote \"$existing\"]\n";
782 $self->{repo_id} = $existing;
783 }
784 if ($min_url ne $url) {
785 print STDERR "Using higher level of URL: ",
786 "$url => $min_url\n";
787 my $old_path = $self->{path};
788 $self->{path} = $url;
789 $self->{path} =~ s!^\Q$min_url\E/*!!;
790 if (length $old_path) {
791 $self->{path} .= "/$old_path";
792 }
793 $url = $min_url;
794 }
795 }
796 my $orig_url;
797 if (!$existing) {
798 # verify that we aren't overwriting anything:
799 $orig_url = eval {
800 command_oneline('config', '--get',
801 "svn-remote.$self->{repo_id}.url")
802 };
803 if ($orig_url && ($orig_url ne $url)) {
804 die "svn-remote.$self->{repo_id}.url already set: ",
805 "$orig_url\nwanted to set to: $url\n";
806 }
807 }
808 my ($xrepo_id, $xpath) = find_ref($self->refname);
809 if (defined $xpath) {
810 die "svn-remote.$xrepo_id.fetch already set to track ",
811 "$xpath:refs/remotes/", $self->refname, "\n";
812 }
813 command_noisy('config',
814 "svn-remote.$self->{repo_id}.url", $url);
815 command_noisy('config', '--add',
816 "svn-remote.$self->{repo_id}.fetch",
817 "$self->{path}:".$self->refname);
818 $self->{url} = $url;
819 }
820
821 sub init {
822 my ($class, $url, $path, $repo_id, $ref_id) = @_;
823 my $self = _new($class, $repo_id, $ref_id, $path);
824 if (defined $url) {
825 $self->init_remote_config($url);
826 }
827 $self;
828 }
829
830 sub find_ref {
831 my ($ref_id) = @_;
832 foreach (command(qw/config -l/)) {
833 next unless m!^svn-remote\.(.+)\.fetch=
834 \s*(.*)\s*:\s*refs/remotes/(.+)\s*$!x;
835 my ($repo_id, $path, $ref) = ($1, $2, $3);
836 if ($ref eq $ref_id) {
837 $path = '' if ($path =~ m#^\./?#);
838 return ($repo_id, $path);
839 }
840 }
841 (undef, undef, undef);
842 }
843
844 sub new {
845 my ($class, $ref_id, $repo_id, $path) = @_;
846 if (defined $ref_id && !defined $repo_id && !defined $path) {
847 ($repo_id, $path) = find_ref($ref_id);
848 if (!defined $repo_id) {
849 die "Could not find a \"svn-remote.*.fetch\" key ",
850 "in the repository configuration matching: ",
851 "refs/remotes/$ref_id\n";
852 }
853 }
854 my $self = _new($class, $repo_id, $ref_id, $path);
855 if (!defined $self->{path} || !length $self->{path}) {
856 my $fetch = command_oneline('config', '--get',
857 "svn-remote.$repo_id.fetch",
858 ":refs/remotes/$ref_id\$") or
859 die "Failed to read \"svn-remote.$repo_id.fetch\" ",
860 "\":refs/remotes/$ref_id\$\" in config\n";
861 ($self->{path}, undef) = split(/\s*:\s*/, $fetch);
862 }
863 $self->{url} = command_oneline('config', '--get',
864 "svn-remote.$repo_id.url") or
865 die "Failed to read \"svn-remote.$repo_id.url\" in config\n";
866 $self;
867 }
868
869 sub refname { "refs/remotes/$_[0]->{ref_id}" }
870
871 sub ra {
872 my ($self) = shift;
873 $self->{ra} ||= Git::SVN::Ra->new($self->{url});
874 }
875
876 sub rel_path {
877 my ($self) = @_;
878 my $repos_root = $self->ra->{repos_root};
879 return $self->{path} if ($self->{url} eq $repos_root);
880 my $url = $self->{url} .
881 (length $self->{path} ? "/$self->{path}" : $self->{path});
882 $url =~ s!^\Q$repos_root\E/*!!g;
883 $url;
884 }
885
886 sub copy_remote_ref {
887 my ($self) = @_;
888 my $origin = $::_cp_remote ? $::_cp_remote : 'origin';
889 my $ref = $self->refname;
890 if (command('ls-remote', $origin, $ref)) {
891 command_noisy('fetch', $origin, "$ref:$ref");
892 } elsif ($::_cp_remote && !$::_upgrade) {
893 die "Unable to find remote reference: $ref on $origin\n";
894 }
895 }
896
897 sub traverse_ignore {
898 my ($self, $fh, $path, $r) = @_;
899 $path =~ s#^/+##g;
900 my ($dirent, undef, $props) = $self->ra->get_dir($path, $r);
901 my $p = $path;
902 $p =~ s#^\Q$self->{ra}->{svn_path}\E/##;
903 print $fh length $p ? "\n# $p\n" : "\n# /\n";
904 if (my $s = $props->{'svn:ignore'}) {
905 $s =~ s/[\r\n]+/\n/g;
906 chomp $s;
907 if (length $p == 0) {
908 $s =~ s#\n#\n/$p#g;
909 print $fh "/$s\n";
910 } else {
911 $s =~ s#\n#\n/$p/#g;
912 print $fh "/$p/$s\n";
913 }
914 }
915 foreach (sort keys %$dirent) {
916 next if $dirent->{$_}->kind != $SVN::Node::dir;
917 $self->traverse_ignore($fh, "$path/$_", $r);
918 }
919 }
920
921 sub last_rev { ($_[0]->last_rev_commit)[0] }
922 sub last_commit { ($_[0]->last_rev_commit)[1] }
923
924 # returns the newest SVN revision number and newest commit SHA1
925 sub last_rev_commit {
926 my ($self) = @_;
927 if (defined $self->{last_rev} && defined $self->{last_commit}) {
928 return ($self->{last_rev}, $self->{last_commit});
929 }
930 my $c = ::verify_ref($self->refname.'^0');
931 if ($c) {
932 my $rev = (::cmt_metadata($c))[1];
933 if (defined $rev) {
934 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
935 return ($rev, $c);
936 }
937 }
938 my $offset = -41; # from tail
939 my $rl;
940 open my $fh, '<', $self->{db_path} or
941 croak "$self->{db_path} not readable: $!\n";
942 seek $fh, $offset, 2;
943 $rl = readline $fh;
944 defined $rl or return (undef, undef);
945 chomp $rl;
946 while ($c ne $rl && tell $fh != 0) {
947 $offset -= 41;
948 seek $fh, $offset, 2;
949 $rl = readline $fh;
950 defined $rl or return (undef, undef);
951 chomp $rl;
952 }
953 my $rev = tell $fh;
954 croak $! if ($rev < 0);
955 $rev = ($rev - 41) / 41;
956 close $fh or croak $!;
957 ($self->{last_rev}, $self->{last_commit}) = ($rev, $c);
958 return ($rev, $c);
959 }
960
961 sub get_fetch_range {
962 my ($self, $min, $max) = @_;
963 $max ||= $self->ra->get_latest_revnum;
964 $min ||= $self->last_rev || 0;
965 (++$min, $max);
966 }
967
968 sub tmp_index_do {
969 my ($self, $sub) = @_;
970 my $old_index = $ENV{GIT_INDEX_FILE};
971 $ENV{GIT_INDEX_FILE} = $self->{index};
972 my @ret = &$sub;
973 if ($old_index) {
974 $ENV{GIT_INDEX_FILE} = $old_index;
975 } else {
976 delete $ENV{GIT_INDEX_FILE};
977 }
978 wantarray ? @ret : $ret[0];
979 }
980
981 sub assert_index_clean {
982 my ($self, $treeish) = @_;
983
984 $self->tmp_index_do(sub {
985 command_noisy('read-tree', $treeish) unless -e $self->{index};
986 my $x = command_oneline('write-tree');
987 my ($y) = (command(qw/cat-file commit/, $treeish) =~
988 /^tree ($::sha1)/mo);
989 if ($y ne $x) {
990 unlink $self->{index} or croak $!;
991 command_noisy('read-tree', $treeish);
992 }
993 $x = command_oneline('write-tree');
994 if ($y ne $x) {
995 ::fatal "trees ($treeish) $y != $x\n",
996 "Something is seriously wrong...\n";
997 }
998 });
999 }
1000
1001 sub get_commit_parents {
1002 my ($self, $log_entry) = @_;
1003 my (%seen, @ret, @tmp);
1004 # legacy support for 'set-tree'; this is only used by set_tree_cb:
1005 if (my $ip = $self->{inject_parents}) {
1006 if (my $commit = delete $ip->{$log_entry->{revision}}) {
1007 push @tmp, $commit;
1008 }
1009 }
1010 if (my $cur = ::verify_ref($self->refname.'^0')) {
1011 push @tmp, $cur;
1012 }
1013 push @tmp, $_ foreach (@{$log_entry->{parents}}, @tmp);
1014 while (my $p = shift @tmp) {
1015 next if $seen{$p};
1016 $seen{$p} = 1;
1017 push @ret, $p;
1018 # MAXPARENT is defined to 16 in commit-tree.c:
1019 last if @ret >= 16;
1020 }
1021 if (@tmp) {
1022 die "r$log_entry->{revision}: No room for parents:\n\t",
1023 join("\n\t", @tmp), "\n";
1024 }
1025 @ret;
1026 }
1027
1028 sub full_url {
1029 my ($self) = @_;
1030 $self->ra->{url} . (length $self->{path} ? '/' . $self->{path} : '');
1031 }
1032
1033 sub do_git_commit {
1034 my ($self, $log_entry) = @_;
1035 if (my $c = $self->rev_db_get($log_entry->{revision})) {
1036 croak "$log_entry->{revision} = $c already exists! ",
1037 "Why are we refetching it?\n";
1038 }
1039 my $author = $log_entry->{author};
1040 my ($name, $email) = (defined $::users{$author} ? @{$::users{$author}}
1041 : ($author, "$author\@".$self->ra->uuid));
1042 $ENV{GIT_AUTHOR_NAME} = $ENV{GIT_COMMITTER_NAME} = $name;
1043 $ENV{GIT_AUTHOR_EMAIL} = $ENV{GIT_COMMITTER_EMAIL} = $email;
1044 $ENV{GIT_AUTHOR_DATE} = $ENV{GIT_COMMITTER_DATE} = $log_entry->{date};
1045
1046 my $tree = $log_entry->{tree};
1047 if (!defined $tree) {
1048 $tree = $self->tmp_index_do(sub {
1049 command_oneline('write-tree') });
1050 }
1051 die "Tree is not a valid sha1: $tree\n" if $tree !~ /^$::sha1$/o;
1052
1053 my @exec = ('git-commit-tree', $tree);
1054 foreach ($self->get_commit_parents($log_entry)) {
1055 push @exec, '-p', $_;
1056 }
1057 defined(my $pid = open3(my $msg_fh, my $out_fh, '>&STDERR', @exec))
1058 or croak $!;
1059 print $msg_fh $log_entry->{log} or croak $!;
1060 print $msg_fh "\ngit-svn-id: ", $self->full_url, '@',
1061 $log_entry->{revision}, ' ',
1062 $self->ra->uuid, "\n" or croak $!;
1063 $msg_fh->flush == 0 or croak $!;
1064 close $msg_fh or croak $!;
1065 chomp(my $commit = do { local $/; <$out_fh> });
1066 close $out_fh or croak $!;
1067 waitpid $pid, 0;
1068 croak $? if $?;
1069 if ($commit !~ /^$::sha1$/o) {
1070 die "Failed to commit, invalid sha1: $commit\n";
1071 }
1072
1073 command_noisy('update-ref',$self->refname, $commit);
1074 $self->rev_db_set($log_entry->{revision}, $commit);
1075
1076 $self->{last_rev} = $log_entry->{revision};
1077 $self->{last_commit} = $commit;
1078 print "r$log_entry->{revision} = $commit\n";
1079 return $commit;
1080 }
1081
1082 sub revisions_eq {
1083 my ($self, $r0, $r1) = @_;
1084 return 1 if $r0 == $r1;
1085 my $nr = 0;
1086 $self->ra->get_log([$self->{path}], $r0, $r1,
1087 0, 0, 1, sub { $nr++ });
1088 return 0 if ($nr > 1);
1089 return 1;
1090 }
1091
1092 sub find_parent_branch {
1093 my ($self, $paths, $rev) = @_;
1094 return undef unless $::_follow_parent;
1095 unless (defined $paths) {
1096 $self->ra->get_log([$self->{path}], $rev, $rev, 0, 1, 1,
1097 sub { $paths = dup_changed_paths($_[0]) });
1098 }
1099 return undef unless defined $paths;
1100
1101 # look for a parent from another branch:
1102 my @b_path_components = split m#/#, $self->rel_path;
1103 my @a_path_components;
1104 my $i;
1105 while (@b_path_components) {
1106 $i = $paths->{'/'.join('/', @b_path_components)};
1107 last if $i;
1108 unshift(@a_path_components, pop(@b_path_components));
1109 }
1110 goto not_found unless defined $i;
1111 my $branch_from = $i->{copyfrom_path} or goto not_found;
1112 if (@a_path_components) {
1113 print STDERR "branch_from: $branch_from => ";
1114 $branch_from .= '/'.join('/', @a_path_components);
1115 print STDERR $branch_from, "\n";
1116 }
1117 my $r = $i->{copyfrom_rev};
1118 my $repos_root = $self->ra->{repos_root};
1119 my $url = $self->ra->{url};
1120 my $new_url = $repos_root . $branch_from;
1121 print STDERR "Found possible branch point: ",
1122 "$new_url => ", $self->full_url, ", $r\n";
1123 $branch_from =~ s#^/##;
1124 my $remotes = read_all_remotes();
1125 my $gs;
1126 foreach my $repo_id (keys %$remotes) {
1127 my $u = $remotes->{$repo_id}->{url} or next;
1128 next if $url ne $u;
1129 my $fetch = $remotes->{$repo_id}->{fetch};
1130 foreach my $f (keys %$fetch) {
1131 next if $f ne $branch_from;
1132 $gs = Git::SVN->new($fetch->{$f}, $repo_id, $f);
1133 last;
1134 }
1135 last if $gs;
1136 }
1137 unless ($gs) {
1138 my $ref_id = $self->{ref_id};
1139 $ref_id =~ s/\@\d+$//;
1140 $ref_id .= "\@$r";
1141 # just grow a tail if we're not unique enough :x
1142 $ref_id .= '-' while find_ref($ref_id);
1143 print STDERR "Initializing parent: $ref_id\n";
1144 $gs = Git::SVN->init($new_url, '', $ref_id, $ref_id);
1145 }
1146 my ($r0, $parent) = $gs->find_rev_before($r, 1);
1147 if ($::_follow_parent && (!defined $r0 || !defined $parent)) {
1148 $gs->fetch(0, $r);
1149 ($r0, $parent) = $gs->last_rev_commit;
1150 }
1151 if (defined $r0 && defined $parent && $gs->revisions_eq($r0, $r)) {
1152 print STDERR "Found branch parent: ($self->{ref_id}) $parent\n";
1153 $self->assert_index_clean($parent);
1154 my $ed;
1155 if ($self->ra->can_do_switch) {
1156 print STDERR "Following parent with do_switch\n";
1157 # do_switch works with svn/trunk >= r22312, but that
1158 # is not included with SVN 1.4.3 (the latest version
1159 # at the moment), so we can't rely on it
1160 $self->{last_commit} = $parent;
1161 $ed = SVN::Git::Fetcher->new($self);
1162 $gs->ra->gs_do_switch($r0, $rev, $gs->{path}, 1,
1163 $self->full_url, $ed)
1164 or die "SVN connection failed somewhere...\n";
1165 } else {
1166 print STDERR "Following parent with do_update\n";
1167 $ed = SVN::Git::Fetcher->new($self);
1168 $self->ra->gs_do_update($rev, $rev, $self->{path},
1169 1, $ed)
1170 or die "SVN connection failed somewhere...\n";
1171 }
1172 $ed->{new_fetch} = 1;
1173 return $self->make_log_entry($rev, [$parent], $ed);
1174 }
1175 not_found:
1176 print STDERR "Branch parent for path: '/",
1177 $self->rel_path, "' @ r$rev not found:\n";
1178 return undef unless $paths;
1179 print STDERR "Changed paths:\n";
1180 foreach my $x (sort keys %$paths) {
1181 my $p = $paths->{$x};
1182 print STDERR "\t$p->{action}\t$x";
1183 if ($p->{copyfrom_path}) {
1184 print STDERR "(from $p->{copyfrom_path}: ",
1185 "$p->{copyfrom_rev})";
1186 }
1187 print STDERR "\n";
1188 }
1189 print STDERR '-'x72, "\n";
1190 return undef;
1191 }
1192
1193 sub do_fetch {
1194 my ($self, $paths, $rev) = @_;
1195 my $ed;
1196 my ($last_rev, @parents);
1197 if ($self->{last_commit}) {
1198 $ed = SVN::Git::Fetcher->new($self);
1199 $last_rev = $self->{last_rev};
1200 $ed->{c} = $self->{last_commit};
1201 @parents = ($self->{last_commit});
1202 } else {
1203 $last_rev = $rev;
1204 if (my $log_entry = $self->find_parent_branch($paths, $rev)) {
1205 return $log_entry;
1206 }
1207 $ed = SVN::Git::Fetcher->new($self);
1208 $ed->{new_fetch} = 1;
1209 }
1210 unless ($self->ra->gs_do_update($last_rev, $rev,
1211 $self->{path}, 1, $ed)) {
1212 die "SVN connection failed somewhere...\n";
1213 }
1214 $self->make_log_entry($rev, \@parents, $ed);
1215 }
1216
1217 sub get_untracked {
1218 my ($self, $ed) = @_;
1219 my @out;
1220 my $h = $ed->{empty};
1221 foreach (sort keys %$h) {
1222 my $act = $h->{$_} ? '+empty_dir' : '-empty_dir';
1223 push @out, " $act: " . uri_encode($_);
1224 warn "W: $act: $_\n";
1225 }
1226 foreach my $t (qw/dir_prop file_prop/) {
1227 $h = $ed->{$t} or next;
1228 foreach my $path (sort keys %$h) {
1229 my $ppath = $path eq '' ? '.' : $path;
1230 foreach my $prop (sort keys %{$h->{$path}}) {
1231 next if $SKIP_PROP{$prop};
1232 my $v = $h->{$path}->{$prop};
1233 my $t_ppath_prop = "$t: " .
1234 uri_encode($ppath) . ' ' .
1235 uri_encode($prop);
1236 if (defined $v) {
1237 push @out, " +$t_ppath_prop " .
1238 uri_encode($v);
1239 } else {
1240 push @out, " -$t_ppath_prop";
1241 }
1242 }
1243 }
1244 }
1245 foreach my $t (qw/absent_file absent_directory/) {
1246 $h = $ed->{$t} or next;
1247 foreach my $parent (sort keys %$h) {
1248 foreach my $path (sort @{$h->{$parent}}) {
1249 push @out, " $t: " .
1250 uri_encode("$parent/$path");
1251 warn "W: $t: $parent/$path ",
1252 "Insufficient permissions?\n";
1253 }
1254 }
1255 }
1256 \@out;
1257 }
1258
1259 sub parse_svn_date {
1260 my $date = shift || return '+0000 1970-01-01 00:00:00';
1261 my ($Y,$m,$d,$H,$M,$S) = ($date =~ /^(\d{4})\-(\d\d)\-(\d\d)T
1262 (\d\d)\:(\d\d)\:(\d\d).\d+Z$/x) or
1263 croak "Unable to parse date: $date\n";
1264 "+0000 $Y-$m-$d $H:$M:$S";
1265 }
1266
1267 sub check_author {
1268 my ($author) = @_;
1269 if (!defined $author || length $author == 0) {
1270 $author = '(no author)';
1271 }
1272 if (defined $::_authors && ! defined $::users{$author}) {
1273 die "Author: $author not defined in $::_authors file\n";
1274 }
1275 $author;
1276 }
1277
1278 sub make_log_entry {
1279 my ($self, $rev, $parents, $ed) = @_;
1280 my $untracked = $self->get_untracked($ed);
1281
1282 return undef if (! $ed->{new_fetch} && ! $ed->{nr} && ! @$untracked);
1283
1284 open my $un, '>>', "$self->{dir}/unhandled.log" or croak $!;
1285 print $un "r$rev\n" or croak $!;
1286 print $un $_, "\n" foreach @$untracked;
1287 my %log_entry = ( parents => $parents || [], revision => $rev,
1288 log => '');
1289 my $rp = $self->ra->rev_proplist($rev);
1290 foreach (sort keys %$rp) {
1291 my $v = $rp->{$_};
1292 if (/^svn:(author|date|log)$/) {
1293 $log_entry{$1} = $v;
1294 } else {
1295 print $un " rev_prop: ", uri_encode($_), ' ',
1296 uri_encode($v), "\n";
1297 }
1298 }
1299 close $un or croak $!;
1300
1301 $log_entry{date} = parse_svn_date($log_entry{date});
1302 $log_entry{author} = check_author($log_entry{author});
1303 $log_entry{log} .= "\n";
1304 \%log_entry;
1305 }
1306
1307 sub fetch {
1308 my ($self, $min_rev, $max_rev, @parents) = @_;
1309 my ($last_rev, $last_commit) = $self->last_rev_commit;
1310 my ($base, $head) = $self->get_fetch_range($min_rev, $max_rev);
1311 return if ($base > $head);
1312 $self->ra->gs_fetch_loop_common($base, $head, $self);
1313 }
1314
1315 sub set_tree_cb {
1316 my ($self, $log_entry, $tree, $rev, $date, $author) = @_;
1317 # TODO: enable and test optimized commits:
1318 if (0 && $rev == ($self->{last_rev} + 1)) {
1319 $log_entry->{revision} = $rev;
1320 $log_entry->{author} = $author;
1321 $self->do_git_commit($log_entry, "$rev=$tree");
1322 } else {
1323 $self->{inject_parents} = { $rev => $tree };
1324 $self->fetch(undef, undef);
1325 }
1326 }
1327
1328 sub set_tree {
1329 my ($self, $tree) = (shift, shift);
1330 my $log_entry = ::get_commit_entry($tree);
1331 unless ($self->{last_rev}) {
1332 fatal("Must have an existing revision to commit\n");
1333 }
1334 my %ed_opts = ( r => $self->{last_rev},
1335 log => $log_entry->{log},
1336 ra => $self->ra,
1337 tree_a => $self->{last_commit},
1338 tree_b => $tree,
1339 editor_cb => sub {
1340 $self->set_tree_cb($log_entry, $tree, @_) },
1341 svn_path => $self->{path} );
1342 if (!SVN::Git::Editor->new(\%ed_opts)->apply_diff) {
1343 print "No changes\nr$self->{last_rev} = $tree\n";
1344 }
1345 }
1346
1347 # rev_db:
1348 # Tie::File seems to be prone to offset errors if revisions get sparse,
1349 # it's not that fast, either. Tie::File is also not in Perl 5.6. So
1350 # one of my favorite modules is out :< Next up would be one of the DBM
1351 # modules, but I'm not sure which is most portable... So I'll just
1352 # go with something that's plain-text, but still capable of
1353 # being randomly accessed. So here's my ultra-simple fixed-width
1354 # database. All records are 40 characters + "\n", so it's easy to seek
1355 # to a revision: (41 * rev) is the byte offset.
1356 # A record of 40 0s denotes an empty revision.
1357 # And yes, it's still pretty fast (faster than Tie::File).
1358
1359 sub rev_db_set {
1360 my ($self, $rev, $commit) = @_;
1361 length $commit == 40 or croak "arg3 must be a full SHA1 hexsum\n";
1362 open my $fh, '+<', $self->{db_path} or croak $!;
1363 my $offset = $rev * 41;
1364 # assume that append is the common case:
1365 seek $fh, 0, 2 or croak $!;
1366 my $pos = tell $fh;
1367 if ($pos < $offset) {
1368 print $fh (('0' x 40),"\n") x (($offset - $pos) / 41)
1369 or croak $!;
1370 }
1371 seek $fh, $offset, 0 or croak $!;
1372 print $fh $commit,"\n" or croak $!;
1373 close $fh or croak $!;
1374 }
1375
1376 sub rev_db_get {
1377 my ($self, $rev) = @_;
1378 my $ret;
1379 my $offset = $rev * 41;
1380 open my $fh, '<', $self->{db_path} or croak $!;
1381 if (seek $fh, $offset, 0) {
1382 $ret = readline $fh;
1383 if (defined $ret) {
1384 chomp $ret;
1385 $ret = undef if ($ret =~ /^0{40}$/);
1386 }
1387 }
1388 close $fh or croak $!;
1389 $ret;
1390 }
1391
1392 sub find_rev_before {
1393 my ($self, $rev, $eq_ok) = @_;
1394 --$rev unless $eq_ok;
1395 while ($rev > 0) {
1396 if (my $c = $self->rev_db_get($rev)) {
1397 return ($rev, $c);
1398 }
1399 --$rev;
1400 }
1401 return (undef, undef);
1402 }
1403
1404 sub _new {
1405 my ($class, $repo_id, $ref_id, $path) = @_;
1406 unless (defined $repo_id && length $repo_id) {
1407 $repo_id = $Git::SVN::default_repo_id;
1408 }
1409 unless (defined $ref_id && length $ref_id) {
1410 $_[2] = $ref_id = $Git::SVN::default_ref_id;
1411 }
1412 $_[1] = $repo_id = sanitize_remote_name($repo_id);
1413 my $dir = "$ENV{GIT_DIR}/svn/$ref_id";
1414 $_[3] = $path = '' unless (defined $path);
1415 mkpath([$dir]);
1416 unless (-f "$dir/.rev_db") {
1417 open my $fh, '>>', "$dir/.rev_db" or croak $!;
1418 close $fh or croak $!;
1419 }
1420 bless { ref_id => $ref_id, dir => $dir, index => "$dir/index",
1421 path => $path,
1422 db_path => "$dir/.rev_db", repo_id => $repo_id }, $class;
1423 }
1424
1425 sub uri_encode {
1426 my ($f) = @_;
1427 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1428 $f
1429 }
1430
1431 package Git::SVN::Prompt;
1432 use strict;
1433 use warnings;
1434 require SVN::Core;
1435 use vars qw/$_no_auth_cache $_username/;
1436
1437 sub simple {
1438 my ($cred, $realm, $default_username, $may_save, $pool) = @_;
1439 $may_save = undef if $_no_auth_cache;
1440 $default_username = $_username if defined $_username;
1441 if (defined $default_username && length $default_username) {
1442 if (defined $realm && length $realm) {
1443 print STDERR "Authentication realm: $realm\n";
1444 STDERR->flush;
1445 }
1446 $cred->username($default_username);
1447 } else {
1448 username($cred, $realm, $may_save, $pool);
1449 }
1450 $cred->password(_read_password("Password for '" .
1451 $cred->username . "': ", $realm));
1452 $cred->may_save($may_save);
1453 $SVN::_Core::SVN_NO_ERROR;
1454 }
1455
1456 sub ssl_server_trust {
1457 my ($cred, $realm, $failures, $cert_info, $may_save, $pool) = @_;
1458 $may_save = undef if $_no_auth_cache;
1459 print STDERR "Error validating server certificate for '$realm':\n";
1460 if ($failures & $SVN::Auth::SSL::UNKNOWNCA) {
1461 print STDERR " - The certificate is not issued by a trusted ",
1462 "authority. Use the\n",
1463 " fingerprint to validate the certificate manually!\n";
1464 }
1465 if ($failures & $SVN::Auth::SSL::CNMISMATCH) {
1466 print STDERR " - The certificate hostname does not match.\n";
1467 }
1468 if ($failures & $SVN::Auth::SSL::NOTYETVALID) {
1469 print STDERR " - The certificate is not yet valid.\n";
1470 }
1471 if ($failures & $SVN::Auth::SSL::EXPIRED) {
1472 print STDERR " - The certificate has expired.\n";
1473 }
1474 if ($failures & $SVN::Auth::SSL::OTHER) {
1475 print STDERR " - The certificate has an unknown error.\n";
1476 }
1477 printf STDERR
1478 "Certificate information:\n".
1479 " - Hostname: %s\n".
1480 " - Valid: from %s until %s\n".
1481 " - Issuer: %s\n".
1482 " - Fingerprint: %s\n",
1483 map $cert_info->$_, qw(hostname valid_from valid_until
1484 issuer_dname fingerprint);
1485 my $choice;
1486 prompt:
1487 print STDERR $may_save ?
1488 "(R)eject, accept (t)emporarily or accept (p)ermanently? " :
1489 "(R)eject or accept (t)emporarily? ";
1490 STDERR->flush;
1491 $choice = lc(substr(<STDIN> || 'R', 0, 1));
1492 if ($choice =~ /^t$/i) {
1493 $cred->may_save(undef);
1494 } elsif ($choice =~ /^r$/i) {
1495 return -1;
1496 } elsif ($may_save && $choice =~ /^p$/i) {
1497 $cred->may_save($may_save);
1498 } else {
1499 goto prompt;
1500 }
1501 $cred->accepted_failures($failures);
1502 $SVN::_Core::SVN_NO_ERROR;
1503 }
1504
1505 sub ssl_client_cert {
1506 my ($cred, $realm, $may_save, $pool) = @_;
1507 $may_save = undef if $_no_auth_cache;
1508 print STDERR "Client certificate filename: ";
1509 STDERR->flush;
1510 chomp(my $filename = <STDIN>);
1511 $cred->cert_file($filename);
1512 $cred->may_save($may_save);
1513 $SVN::_Core::SVN_NO_ERROR;
1514 }
1515
1516 sub ssl_client_cert_pw {
1517 my ($cred, $realm, $may_save, $pool) = @_;
1518 $may_save = undef if $_no_auth_cache;
1519 $cred->password(_read_password("Password: ", $realm));
1520 $cred->may_save($may_save);
1521 $SVN::_Core::SVN_NO_ERROR;
1522 }
1523
1524 sub username {
1525 my ($cred, $realm, $may_save, $pool) = @_;
1526 $may_save = undef if $_no_auth_cache;
1527 if (defined $realm && length $realm) {
1528 print STDERR "Authentication realm: $realm\n";
1529 }
1530 my $username;
1531 if (defined $_username) {
1532 $username = $_username;
1533 } else {
1534 print STDERR "Username: ";
1535 STDERR->flush;
1536 chomp($username = <STDIN>);
1537 }
1538 $cred->username($username);
1539 $cred->may_save($may_save);
1540 $SVN::_Core::SVN_NO_ERROR;
1541 }
1542
1543 sub _read_password {
1544 my ($prompt, $realm) = @_;
1545 print STDERR $prompt;
1546 STDERR->flush;
1547 require Term::ReadKey;
1548 Term::ReadKey::ReadMode('noecho');
1549 my $password = '';
1550 while (defined(my $key = Term::ReadKey::ReadKey(0))) {
1551 last if $key =~ /[\012\015]/; # \n\r
1552 $password .= $key;
1553 }
1554 Term::ReadKey::ReadMode('restore');
1555 print STDERR "\n";
1556 STDERR->flush;
1557 $password;
1558 }
1559
1560 package main;
1561
1562 sub uri_encode {
1563 my ($f) = @_;
1564 $f =~ s#([^a-zA-Z0-9\*!\:_\./\-])#uc sprintf("%%%02x",ord($1))#eg;
1565 $f
1566 }
1567
1568 sub uri_decode {
1569 my ($f) = @_;
1570 $f =~ tr/+/ /;
1571 $f =~ s/%([A-F0-9]{2})/chr hex($1)/ge;
1572 $f
1573 }
1574
1575 {
1576 my $kill_stupid_warnings = $SVN::Node::none.$SVN::Node::file.
1577 $SVN::Node::dir.$SVN::Node::unknown.
1578 $SVN::Node::none.$SVN::Node::file.
1579 $SVN::Node::dir.$SVN::Node::unknown.
1580 $SVN::Auth::SSL::CNMISMATCH.
1581 $SVN::Auth::SSL::NOTYETVALID.
1582 $SVN::Auth::SSL::EXPIRED.
1583 $SVN::Auth::SSL::UNKNOWNCA.
1584 $SVN::Auth::SSL::OTHER;
1585 }
1586
1587 package SVN::Git::Fetcher;
1588 use vars qw/@ISA/;
1589 use strict;
1590 use warnings;
1591 use Carp qw/croak/;
1592 use IO::File qw//;
1593
1594 # file baton members: path, mode_a, mode_b, pool, fh, blob, base
1595 sub new {
1596 my ($class, $git_svn) = @_;
1597 my $self = SVN::Delta::Editor->new;
1598 bless $self, $class;
1599 $self->{c} = $git_svn->{last_commit} if exists $git_svn->{last_commit};
1600 $self->{empty} = {};
1601 $self->{dir_prop} = {};
1602 $self->{file_prop} = {};
1603 $self->{absent_dir} = {};
1604 $self->{absent_file} = {};
1605 $self->{gii} = $git_svn->tmp_index_do(sub { Git::IndexInfo->new });
1606 require Digest::MD5;
1607 $self;
1608 }
1609
1610 sub set_path_strip {
1611 my ($self, $path) = @_;
1612 $self->{path_strip} = qr/^\Q$path\E\/?/;
1613 }
1614
1615 sub open_root {
1616 { path => '' };
1617 }
1618
1619 sub open_directory {
1620 my ($self, $path, $pb, $rev) = @_;
1621 { path => $path };
1622 }
1623
1624 sub git_path {
1625 my ($self, $path) = @_;
1626 if ($self->{path_strip}) {
1627 $path =~ s!$self->{path_strip}!! or
1628 die "Failed to strip path '$path' ($self->{path_strip})\n";
1629 }
1630 $path;
1631 }
1632
1633 sub delete_entry {
1634 my ($self, $path, $rev, $pb) = @_;
1635
1636 my $gpath = $self->git_path($path);
1637 # remove entire directories.
1638 if (command('ls-tree', $self->{c}, '--', $gpath) =~ /^040000 tree/) {
1639 my ($ls, $ctx) = command_output_pipe(qw/ls-tree
1640 -r --name-only -z/,
1641 $self->{c}, '--', $gpath);
1642 local $/ = "\0";
1643 while (<$ls>) {
1644 chomp;
1645 $self->{gii}->remove($_);
1646 print "\tD\t$_\n" unless $self->{q};
1647 }
1648 print "\tD\t$gpath/\n" unless $self->{q};
1649 command_close_pipe($ls, $ctx);
1650 $self->{empty}->{$path} = 0
1651 } else {
1652 $self->{gii}->remove($gpath);
1653 print "\tD\t$gpath\n" unless $self->{q};
1654 }
1655 undef;
1656 }
1657
1658 sub open_file {
1659 my ($self, $path, $pb, $rev) = @_;
1660 my $gpath = $self->git_path($path);
1661 my ($mode, $blob) = (command('ls-tree', $self->{c}, '--', $gpath)
1662 =~ /^(\d{6}) blob ([a-f\d]{40})\t/);
1663 unless (defined $mode && defined $blob) {
1664 die "$path was not found in commit $self->{c} (r$rev)\n";
1665 }
1666 { path => $path, mode_a => $mode, mode_b => $mode, blob => $blob,
1667 pool => SVN::Pool->new, action => 'M' };
1668 }
1669
1670 sub add_file {
1671 my ($self, $path, $pb, $cp_path, $cp_rev) = @_;
1672 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1673 delete $self->{empty}->{$dir};
1674 { path => $path, mode_a => 100644, mode_b => 100644,
1675 pool => SVN::Pool->new, action => 'A' };
1676 }
1677
1678 sub add_directory {
1679 my ($self, $path, $cp_path, $cp_rev) = @_;
1680 my ($dir, $file) = ($path =~ m#^(.*?)/?([^/]+)$#);
1681 delete $self->{empty}->{$dir};
1682 $self->{empty}->{$path} = 1;
1683 { path => $path };
1684 }
1685
1686 sub change_dir_prop {
1687 my ($self, $db, $prop, $value) = @_;
1688 $self->{dir_prop}->{$db->{path}} ||= {};
1689 $self->{dir_prop}->{$db->{path}}->{$prop} = $value;
1690 undef;
1691 }
1692
1693 sub absent_directory {
1694 my ($self, $path, $pb) = @_;
1695 $self->{absent_dir}->{$pb->{path}} ||= [];
1696 push @{$self->{absent_dir}->{$pb->{path}}}, $path;
1697 undef;
1698 }
1699
1700 sub absent_file {
1701 my ($self, $path, $pb) = @_;
1702 $self->{absent_file}->{$pb->{path}} ||= [];
1703 push @{$self->{absent_file}->{$pb->{path}}}, $path;
1704 undef;
1705 }
1706
1707 sub change_file_prop {
1708 my ($self, $fb, $prop, $value) = @_;
1709 if ($prop eq 'svn:executable') {
1710 if ($fb->{mode_b} != 120000) {
1711 $fb->{mode_b} = defined $value ? 100755 : 100644;
1712 }
1713 } elsif ($prop eq 'svn:special') {
1714 $fb->{mode_b} = defined $value ? 120000 : 100644;
1715 } else {
1716 $self->{file_prop}->{$fb->{path}} ||= {};
1717 $self->{file_prop}->{$fb->{path}}->{$prop} = $value;
1718 }
1719 undef;
1720 }
1721
1722 sub apply_textdelta {
1723 my ($self, $fb, $exp) = @_;
1724 my $fh = IO::File->new_tmpfile;
1725 $fh->autoflush(1);
1726 # $fh gets auto-closed() by SVN::TxDelta::apply(),
1727 # (but $base does not,) so dup() it for reading in close_file
1728 open my $dup, '<&', $fh or croak $!;
1729 my $base = IO::File->new_tmpfile;
1730 $base->autoflush(1);
1731 if ($fb->{blob}) {
1732 defined (my $pid = fork) or croak $!;
1733 if (!$pid) {
1734 open STDOUT, '>&', $base or croak $!;
1735 print STDOUT 'link ' if ($fb->{mode_a} == 120000);
1736 exec qw/git-cat-file blob/, $fb->{blob} or croak $!;
1737 }
1738 waitpid $pid, 0;
1739 croak $? if $?;
1740
1741 if (defined $exp) {
1742 seek $base, 0, 0 or croak $!;
1743 my $md5 = Digest::MD5->new;
1744 $md5->addfile($base);
1745 my $got = $md5->hexdigest;
1746 die "Checksum mismatch: $fb->{path} $fb->{blob}\n",
1747 "expected: $exp\n",
1748 " got: $got\n" if ($got ne $exp);
1749 }
1750 }
1751 seek $base, 0, 0 or croak $!;
1752 $fb->{fh} = $dup;
1753 $fb->{base} = $base;
1754 [ SVN::TxDelta::apply($base, $fh, undef, $fb->{path}, $fb->{pool}) ];
1755 }
1756
1757 sub close_file {
1758 my ($self, $fb, $exp) = @_;
1759 my $hash;
1760 my $path = $self->git_path($fb->{path});
1761 if (my $fh = $fb->{fh}) {
1762 seek($fh, 0, 0) or croak $!;
1763 my $md5 = Digest::MD5->new;
1764 $md5->addfile($fh);
1765 my $got = $md5->hexdigest;
1766 die "Checksum mismatch: $path\n",
1767 "expected: $exp\n got: $got\n" if ($got ne $exp);
1768 seek($fh, 0, 0) or croak $!;
1769 if ($fb->{mode_b} == 120000) {
1770 read($fh, my $buf, 5) == 5 or croak $!;
1771 $buf eq 'link ' or die "$path has mode 120000",
1772 "but is not a link\n";
1773 }
1774 defined(my $pid = open my $out,'-|') or die "Can't fork: $!\n";
1775 if (!$pid) {
1776 open STDIN, '<&', $fh or croak $!;
1777 exec qw/git-hash-object -w --stdin/ or croak $!;
1778 }
1779 chomp($hash = do { local $/; <$out> });
1780 close $out or croak $!;
1781 close $fh or croak $!;
1782 $hash =~ /^[a-f\d]{40}$/ or die "not a sha1: $hash\n";
1783 close $fb->{base} or croak $!;
1784 } else {
1785 $hash = $fb->{blob} or die "no blob information\n";
1786 }
1787 $fb->{pool}->clear;
1788 $self->{gii}->update($fb->{mode_b}, $hash, $path) or croak $!;
1789 print "\t$fb->{action}\t$path\n" if $fb->{action} && ! $self->{q};
1790 undef;
1791 }
1792
1793 sub abort_edit {
1794 my $self = shift;
1795 $self->{nr} = $self->{gii}->{nr};
1796 delete $self->{gii};
1797 $self->SUPER::abort_edit(@_);
1798 }
1799
1800 sub close_edit {
1801 my $self = shift;
1802 $self->{git_commit_ok} = 1;
1803 $self->{nr} = $self->{gii}->{nr};
1804 delete $self->{gii};
1805 $self->SUPER::close_edit(@_);
1806 }
1807
1808 package SVN::Git::Editor;
1809 use vars qw/@ISA/;
1810 use strict;
1811 use warnings;
1812 use Carp qw/croak/;
1813 use IO::File;
1814
1815 sub new {
1816 my ($class, $opts) = @_;
1817 foreach (qw/svn_path r ra tree_a tree_b log editor_cb/) {
1818 die "$_ required!\n" unless (defined $opts->{$_});
1819 }
1820
1821 my $pool = SVN::Pool->new;
1822 my $mods = generate_diff($opts->{tree_a}, $opts->{tree_b});
1823 my $types = check_diff_paths($opts->{ra}, $opts->{svn_path},
1824 $opts->{r}, $mods);
1825
1826 # $opts->{ra} functions should not be used after this:
1827 my @ce = $opts->{ra}->get_commit_editor($opts->{log},
1828 $opts->{editor_cb}, $pool);
1829 my $self = SVN::Delta::Editor->new(@ce, $pool);
1830 bless $self, $class;
1831 foreach (qw/svn_path r tree_a tree_b/) {
1832 $self->{$_} = $opts->{$_};
1833 }
1834 $self->{url} = $opts->{ra}->{url};
1835 $self->{mods} = $mods;
1836 $self->{types} = $types;
1837 $self->{pool} = $pool;
1838 $self->{bat} = { '' => $self->open_root($self->{r}, $self->{pool}) };
1839 $self->{rm} = { };
1840 $self->{path_prefix} = length $self->{svn_path} ?
1841 "$self->{svn_path}/" : '';
1842 require Digest::MD5;
1843 return $self;
1844 }
1845
1846 sub generate_diff {
1847 my ($tree_a, $tree_b) = @_;
1848 my @diff_tree = qw(diff-tree -z -r);
1849 if ($::_cp_similarity) {
1850 push @diff_tree, "-C$::_cp_similarity";
1851 } else {
1852 push @diff_tree, '-C';
1853 }
1854 push @diff_tree, '--find-copies-harder' if $::_find_copies_harder;
1855 push @diff_tree, "-l$::_l" if defined $::_l;
1856 push @diff_tree, $tree_a, $tree_b;
1857 my ($diff_fh, $ctx) = command_output_pipe(@diff_tree);
1858 local $/ = "\0";
1859 my $state = 'meta';
1860 my @mods;
1861 while (<$diff_fh>) {
1862 chomp $_; # this gets rid of the trailing "\0"
1863 if ($state eq 'meta' && /^:(\d{6})\s(\d{6})\s
1864 $::sha1\s($::sha1)\s
1865 ([MTCRAD])\d*$/xo) {
1866 push @mods, { mode_a => $1, mode_b => $2,
1867 sha1_b => $3, chg => $4 };
1868 if ($4 =~ /^(?:C|R)$/) {
1869 $state = 'file_a';
1870 } else {
1871 $state = 'file_b';
1872 }
1873 } elsif ($state eq 'file_a') {
1874 my $x = $mods[$#mods] or croak "Empty array\n";
1875 if ($x->{chg} !~ /^(?:C|R)$/) {
1876 croak "Error parsing $_, $x->{chg}\n";
1877 }
1878 $x->{file_a} = $_;
1879 $state = 'file_b';
1880 } elsif ($state eq 'file_b') {
1881 my $x = $mods[$#mods] or croak "Empty array\n";
1882 if (exists $x->{file_a} && $x->{chg} !~ /^(?:C|R)$/) {
1883 croak "Error parsing $_, $x->{chg}\n";
1884 }
1885 if (!exists $x->{file_a} && $x->{chg} =~ /^(?:C|R)$/) {
1886 croak "Error parsing $_, $x->{chg}\n";
1887 }
1888 $x->{file_b} = $_;
1889 $state = 'meta';
1890 } else {
1891 croak "Error parsing $_\n";
1892 }
1893 }
1894 command_close_pipe($diff_fh, $ctx);
1895 \@mods;
1896 }
1897
1898 sub check_diff_paths {
1899 my ($ra, $pfx, $rev, $mods) = @_;
1900 my %types;
1901 $pfx .= '/' if length $pfx;
1902
1903 sub type_diff_paths {
1904 my ($ra, $types, $path, $rev) = @_;
1905 my @p = split m#/+#, $path;
1906 my $c = shift @p;
1907 unless (defined $types->{$c}) {
1908 $types->{$c} = $ra->check_path($c, $rev);
1909 }
1910 while (@p) {
1911 $c .= '/' . shift @p;
1912 next if defined $types->{$c};
1913 $types->{$c} = $ra->check_path($c, $rev);
1914 }
1915 }
1916
1917 foreach my $m (@$mods) {
1918 foreach my $f (qw/file_a file_b/) {
1919 next unless defined $m->{$f};
1920 my ($dir) = ($m->{$f} =~ m#^(.*?)/?(?:[^/]+)$#);
1921 if (length $pfx.$dir && ! defined $types{$dir}) {
1922 type_diff_paths($ra, \%types, $pfx.$dir, $rev);
1923 }
1924 }
1925 }
1926 \%types;
1927 }
1928
1929 sub split_path {
1930 return ($_[0] =~ m#^(.*?)/?([^/]+)$#);
1931 }
1932
1933 sub repo_path {
1934 my ($self, $path) = @_;
1935 $self->{path_prefix}.(defined $path ? $path : '');
1936 }
1937
1938 sub url_path {
1939 my ($self, $path) = @_;
1940 $self->{url} . '/' . $self->repo_path($path);
1941 }
1942
1943 sub rmdirs {
1944 my ($self) = @_;
1945 my $rm = $self->{rm};
1946 delete $rm->{''}; # we never delete the url we're tracking
1947 return unless %$rm;
1948
1949 foreach (keys %$rm) {
1950 my @d = split m#/#, $_;
1951 my $c = shift @d;
1952 $rm->{$c} = 1;
1953 while (@d) {
1954 $c .= '/' . shift @d;
1955 $rm->{$c} = 1;
1956 }
1957 }
1958 delete $rm->{$self->{svn_path}};
1959 delete $rm->{''}; # we never delete the url we're tracking
1960 return unless %$rm;
1961
1962 my ($fh, $ctx) = command_output_pipe(qw/ls-tree --name-only -r -z/,
1963 $self->{tree_b});
1964 local $/ = "\0";
1965 while (<$fh>) {
1966 chomp;
1967 my @dn = split m#/#, $_;
1968 while (pop @dn) {
1969 delete $rm->{join '/', @dn};
1970 }
1971 unless (%$rm) {
1972 close $fh;
1973 return;
1974 }
1975 }
1976 command_close_pipe($fh, $ctx);
1977
1978 my ($r, $p, $bat) = ($self->{r}, $self->{pool}, $self->{bat});
1979 foreach my $d (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$rm) {
1980 $self->close_directory($bat->{$d}, $p);
1981 my ($dn) = ($d =~ m#^(.*?)/?(?:[^/]+)$#);
1982 print "\tD+\t$d/\n" unless $::_q;
1983 $self->SUPER::delete_entry($d, $r, $bat->{$dn}, $p);
1984 delete $bat->{$d};
1985 }
1986 }
1987
1988 sub open_or_add_dir {
1989 my ($self, $full_path, $baton) = @_;
1990 my $t = $self->{types}->{$full_path};
1991 if (!defined $t) {
1992 die "$full_path not known in r$self->{r} or we have a bug!\n";
1993 }
1994 if ($t == $SVN::Node::none) {
1995 return $self->add_directory($full_path, $baton,
1996 undef, -1, $self->{pool});
1997 } elsif ($t == $SVN::Node::dir) {
1998 return $self->open_directory($full_path, $baton,
1999 $self->{r}, $self->{pool});
2000 }
2001 print STDERR "$full_path already exists in repository at ",
2002 "r$self->{r} and it is not a directory (",
2003 ($t == $SVN::Node::file ? 'file' : 'unknown'),"/$t)\n";
2004 exit 1;
2005 }
2006
2007 sub ensure_path {
2008 my ($self, $path) = @_;
2009 my $bat = $self->{bat};
2010 my $repo_path = $self->repo_path($path);
2011 return $bat->{''} unless (length $repo_path);
2012 my @p = split m#/+#, $repo_path;
2013 my $c = shift @p;
2014 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{''});
2015 while (@p) {
2016 my $c0 = $c;
2017 $c .= '/' . shift @p;
2018 $bat->{$c} ||= $self->open_or_add_dir($c, $bat->{$c0});
2019 }
2020 return $bat->{$c};
2021 }
2022
2023 sub A {
2024 my ($self, $m) = @_;
2025 my ($dir, $file) = split_path($m->{file_b});
2026 my $pbat = $self->ensure_path($dir);
2027 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2028 undef, -1);
2029 print "\tA\t$m->{file_b}\n" unless $::_q;
2030 $self->chg_file($fbat, $m);
2031 $self->close_file($fbat,undef,$self->{pool});
2032 }
2033
2034 sub C {
2035 my ($self, $m) = @_;
2036 my ($dir, $file) = split_path($m->{file_b});
2037 my $pbat = $self->ensure_path($dir);
2038 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2039 $self->url_path($m->{file_a}), $self->{r});
2040 print "\tC\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2041 $self->chg_file($fbat, $m);
2042 $self->close_file($fbat,undef,$self->{pool});
2043 }
2044
2045 sub delete_entry {
2046 my ($self, $path, $pbat) = @_;
2047 my $rpath = $self->repo_path($path);
2048 my ($dir, $file) = split_path($rpath);
2049 $self->{rm}->{$dir} = 1;
2050 $self->SUPER::delete_entry($rpath, $self->{r}, $pbat, $self->{pool});
2051 }
2052
2053 sub R {
2054 my ($self, $m) = @_;
2055 my ($dir, $file) = split_path($m->{file_b});
2056 my $pbat = $self->ensure_path($dir);
2057 my $fbat = $self->add_file($self->repo_path($m->{file_b}), $pbat,
2058 $self->url_path($m->{file_a}), $self->{r});
2059 print "\tR\t$m->{file_a} => $m->{file_b}\n" unless $::_q;
2060 $self->chg_file($fbat, $m);
2061 $self->close_file($fbat,undef,$self->{pool});
2062
2063 ($dir, $file) = split_path($m->{file_a});
2064 $pbat = $self->ensure_path($dir);
2065 $self->delete_entry($m->{file_a}, $pbat);
2066 }
2067
2068 sub M {
2069 my ($self, $m) = @_;
2070 my ($dir, $file) = split_path($m->{file_b});
2071 my $pbat = $self->ensure_path($dir);
2072 my $fbat = $self->open_file($self->repo_path($m->{file_b}),
2073 $pbat,$self->{r},$self->{pool});
2074 print "\t$m->{chg}\t$m->{file_b}\n" unless $::_q;
2075 $self->chg_file($fbat, $m);
2076 $self->close_file($fbat,undef,$self->{pool});
2077 }
2078
2079 sub T { shift->M(@_) }
2080
2081 sub change_file_prop {
2082 my ($self, $fbat, $pname, $pval) = @_;
2083 $self->SUPER::change_file_prop($fbat, $pname, $pval, $self->{pool});
2084 }
2085
2086 sub chg_file {
2087 my ($self, $fbat, $m) = @_;
2088 if ($m->{mode_b} =~ /755$/ && $m->{mode_a} !~ /755$/) {
2089 $self->change_file_prop($fbat,'svn:executable','*');
2090 } elsif ($m->{mode_b} !~ /755$/ && $m->{mode_a} =~ /755$/) {
2091 $self->change_file_prop($fbat,'svn:executable',undef);
2092 }
2093 my $fh = IO::File->new_tmpfile or croak $!;
2094 if ($m->{mode_b} =~ /^120/) {
2095 print $fh 'link ' or croak $!;
2096 $self->change_file_prop($fbat,'svn:special','*');
2097 } elsif ($m->{mode_a} =~ /^120/ && $m->{mode_b} !~ /^120/) {
2098 $self->change_file_prop($fbat,'svn:special',undef);
2099 }
2100 defined(my $pid = fork) or croak $!;
2101 if (!$pid) {
2102 open STDOUT, '>&', $fh or croak $!;
2103 exec qw/git-cat-file blob/, $m->{sha1_b} or croak $!;
2104 }
2105 waitpid $pid, 0;
2106 croak $? if $?;
2107 $fh->flush == 0 or croak $!;
2108 seek $fh, 0, 0 or croak $!;
2109
2110 my $md5 = Digest::MD5->new;
2111 $md5->addfile($fh) or croak $!;
2112 seek $fh, 0, 0 or croak $!;
2113
2114 my $exp = $md5->hexdigest;
2115 my $pool = SVN::Pool->new;
2116 my $atd = $self->apply_textdelta($fbat, undef, $pool);
2117 my $got = SVN::TxDelta::send_stream($fh, @$atd, $pool);
2118 die "Checksum mismatch\nexpected: $exp\ngot: $got\n" if ($got ne $exp);
2119 $pool->clear;
2120
2121 close $fh or croak $!;
2122 }
2123
2124 sub D {
2125 my ($self, $m) = @_;
2126 my ($dir, $file) = split_path($m->{file_b});
2127 my $pbat = $self->ensure_path($dir);
2128 print "\tD\t$m->{file_b}\n" unless $::_q;
2129 $self->delete_entry($m->{file_b}, $pbat);
2130 }
2131
2132 sub close_edit {
2133 my ($self) = @_;
2134 my ($p,$bat) = ($self->{pool}, $self->{bat});
2135 foreach (sort { $b =~ tr#/#/# <=> $a =~ tr#/#/# } keys %$bat) {
2136 $self->close_directory($bat->{$_}, $p);
2137 }
2138 $self->SUPER::close_edit($p);
2139 $p->clear;
2140 }
2141
2142 sub abort_edit {
2143 my ($self) = @_;
2144 $self->SUPER::abort_edit($self->{pool});
2145 }
2146
2147 sub DESTROY {
2148 my $self = shift;
2149 $self->SUPER::DESTROY(@_);
2150 $self->{pool}->clear;
2151 }
2152
2153 # this drives the editor
2154 sub apply_diff {
2155 my ($self) = @_;
2156 my $mods = $self->{mods};
2157 my %o = ( D => 1, R => 0, C => -1, A => 3, M => 3, T => 3 );
2158 foreach my $m (sort { $o{$a->{chg}} <=> $o{$b->{chg}} } @$mods) {
2159 my $f = $m->{chg};
2160 if (defined $o{$f}) {
2161 $self->$f($m);
2162 } else {
2163 fatal("Invalid change type: $f\n");
2164 }
2165 }
2166 $self->rmdirs if $::_rmdir;
2167 if (@$mods == 0) {
2168 $self->abort_edit;
2169 } else {
2170 $self->close_edit;
2171 }
2172 return scalar @$mods;
2173 }
2174
2175 package Git::SVN::Ra;
2176 use vars qw/@ISA $config_dir/;
2177 use strict;
2178 use warnings;
2179 my ($can_do_switch);
2180 my %RA;
2181
2182 BEGIN {
2183 # enforce temporary pool usage for some simple functions
2184 my $e;
2185 foreach (qw/get_latest_revnum rev_proplist get_file
2186 check_path get_dir get_uuid get_repos_root/) {
2187 $e .= "sub $_ {
2188 my \$self = shift;
2189 my \$pool = SVN::Pool->new;
2190 my \@ret = \$self->SUPER::$_(\@_,\$pool);
2191 \$pool->clear;
2192 wantarray ? \@ret : \$ret[0]; }\n";
2193 }
2194 eval $e;
2195 }
2196
2197 sub new {
2198 my ($class, $url) = @_;
2199 $url =~ s!/+$!!;
2200 return $RA{$url} if $RA{$url};
2201
2202 SVN::_Core::svn_config_ensure($config_dir, undef);
2203 my ($baton, $callbacks) = SVN::Core::auth_open_helper([
2204 SVN::Client::get_simple_provider(),
2205 SVN::Client::get_ssl_server_trust_file_provider(),
2206 SVN::Client::get_simple_prompt_provider(
2207 \&Git::SVN::Prompt::simple, 2),
2208 SVN::Client::get_ssl_client_cert_prompt_provider(
2209 \&Git::SVN::Prompt::ssl_client_cert, 2),
2210 SVN::Client::get_ssl_client_cert_pw_prompt_provider(
2211 \&Git::SVN::Prompt::ssl_client_cert_pw, 2),
2212 SVN::Client::get_username_provider(),
2213 SVN::Client::get_ssl_server_trust_prompt_provider(
2214 \&Git::SVN::Prompt::ssl_server_trust),
2215 SVN::Client::get_username_prompt_provider(
2216 \&Git::SVN::Prompt::username, 2),
2217 ]);
2218 my $config = SVN::Core::config_get_config($config_dir);
2219 my $self = SVN::Ra->new(url => $url, auth => $baton,
2220 config => $config,
2221 pool => SVN::Pool->new,
2222 auth_provider_callbacks => $callbacks);
2223 $self->{svn_path} = $url;
2224 $self->{repos_root} = $self->get_repos_root;
2225 $self->{svn_path} =~ s#^\Q$self->{repos_root}\E/*##;
2226 $RA{$url} = bless $self, $class;
2227 }
2228
2229 sub DESTROY {
2230 # do not call the real DESTROY since we store ourselves in %RA
2231 }
2232
2233 sub get_log {
2234 my ($self, @args) = @_;
2235 my $pool = SVN::Pool->new;
2236 splice(@args, 3, 1) if ($SVN::Core::VERSION le '1.2.0');
2237 my $ret = $self->SUPER::get_log(@args, $pool);
2238 $pool->clear;
2239 $ret;
2240 }
2241
2242 sub get_commit_editor {
2243 my ($self, $log, $cb, $pool) = @_;
2244 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef, 0) : ();
2245 $self->SUPER::get_commit_editor($log, $cb, @lock, $pool);
2246 }
2247
2248 sub uuid {
2249 my ($self) = @_;
2250 $self->{uuid} ||= $self->get_uuid;
2251 }
2252
2253 sub gs_do_update {
2254 my ($self, $rev_a, $rev_b, $path, $recurse, $editor) = @_;
2255 my $pool = SVN::Pool->new;
2256 $editor->set_path_strip($path);
2257 my (@pc) = split m#/#, $path;
2258 my $reporter = $self->do_update($rev_b, (@pc ? shift @pc : ''),
2259 $recurse, $editor, $pool);
2260 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2261
2262 # Since we can't rely on svn_ra_reparent being available, we'll
2263 # just have to do some magic with set_path to make it so
2264 # we only want a partial path.
2265 my $sp = '';
2266 my $final = join('/', @pc);
2267 while (@pc) {
2268 $reporter->set_path($sp, $rev_b, 0, @lock, $pool);
2269 $sp .= '/' if length $sp;
2270 $sp .= shift @pc;
2271 }
2272 die "BUG: '$sp' != '$final'\n" if ($sp ne $final);
2273
2274 my $new = ($rev_a == $rev_b);
2275 $reporter->set_path($sp, $rev_a, $new, @lock, $pool);
2276
2277 $reporter->finish_report($pool);
2278 $pool->clear;
2279 $editor->{git_commit_ok};
2280 }
2281
2282 # this requires SVN 1.4.3 or later (do_switch didn't work before 1.4.3, and
2283 # svn_ra_reparent didn't work before 1.4)
2284 sub gs_do_switch {
2285 my ($self, $rev_a, $rev_b, $path, $recurse, $url_b, $editor) = @_;
2286 my $pool = SVN::Pool->new;
2287
2288 my $full_url = $self->{url};
2289 my $old_url = $full_url;
2290 $full_url .= "/$path" if length $path;
2291 SVN::_Ra::svn_ra_reparent($self->{session}, $full_url, $pool);
2292 $self->{url} = $full_url;
2293
2294 my $reporter = $self->do_switch($rev_b, '',
2295 $recurse, $url_b, $editor, $pool);
2296 my @lock = $SVN::Core::VERSION ge '1.2.0' ? (undef) : ();
2297 $reporter->set_path('', $rev_a, 0, @lock, $pool);
2298 $reporter->finish_report($pool);
2299
2300 SVN::_Ra::svn_ra_reparent($self->{session}, $old_url, $pool);
2301 $self->{url} = $old_url;
2302
2303 $pool->clear;
2304 $editor->{git_commit_ok};
2305 }
2306
2307 sub gs_fetch_loop_common {
2308 my ($self, $base, $head, @gs) = @_;
2309 my $inc = 1000;
2310 my ($min, $max) = ($base, $head < $base + $inc ? $head : $base + $inc);
2311 my $err_handler = $SVN::Error::handler;
2312 my $err;
2313 $SVN::Error::handler = sub { ($err) = @_; skip_unknown_revs($err); };
2314 my @paths = @gs == 1 ? ($gs[0]->{path}) : ('');
2315 foreach my $gs (@gs) {
2316 if (my $last_commit = $gs->last_commit) {
2317 $gs->assert_index_clean($last_commit);
2318 }
2319 $gs->{path_regex} = qr/^\/\Q$gs->{path}\E\/?/;
2320 }
2321 while (1) {
2322 my @revs;
2323 $self->get_log(\@paths, $min, $max, 0, 1, 1,
2324 sub { push @revs, [ dup_changed_paths($_[0]), $_[1] ]; });
2325 if (! @revs && $err && $max >= $head) {
2326 print STDERR "Branch probably deleted:\n ",
2327 $err->expanded_message,
2328 "\nWill attempt to follow revisions ",
2329 "r$min .. r$max ",
2330 "committed before the deletion\n";
2331 @revs = map { [ undef, $_ ] } ($min .. $max);
2332 }
2333 foreach (@revs) {
2334 my ($paths, $r) = @$_;
2335 foreach my $gs (@gs) {
2336 if ($paths) {
2337 grep /$gs->{path_regex}/, keys %$paths
2338 or next;
2339 }
2340 next if defined $gs->rev_db_get($r);
2341 if (my $log_entry = $gs->do_fetch($paths, $r)) {
2342 $gs->do_git_commit($log_entry);
2343 }
2344 }
2345 }
2346 last if $max >= $head;
2347 $min = $max + 1;
2348 $max += $inc;
2349 $max = $head if ($max > $head);
2350 }
2351 $SVN::Error::handler = $err_handler;
2352 }
2353
2354 sub minimize_url {
2355 my ($self) = @_;
2356 return $self->{url} if ($self->{url} eq $self->{repos_root});
2357 my $url = $self->{repos_root};
2358 my @components = split(m!/!, $self->{svn_path});
2359 my $c = '';
2360 do {
2361 $url .= "/$c" if length $c;
2362 eval { (ref $self)->new($url)->get_latest_revnum };
2363 } while ($@ && ($c = shift @components));
2364 $url;
2365 }
2366
2367 sub can_do_switch {
2368 my $self = shift;
2369 unless (defined $can_do_switch) {
2370 my $pool = SVN::Pool->new;
2371 my $rep = eval {
2372 $self->do_switch(1, '', 0, $self->{url},
2373 SVN::Delta::Editor->new, $pool);
2374 };
2375 if ($@) {
2376 $can_do_switch = 0;
2377 } else {
2378 $rep->abort_report($pool);
2379 $can_do_switch = 1;
2380 }
2381 $pool->clear;
2382 }
2383 $can_do_switch;
2384 }
2385
2386 sub skip_unknown_revs {
2387 my ($err) = @_;
2388 my $errno = $err->apr_err();
2389 # Maybe the branch we're tracking didn't
2390 # exist when the repo started, so it's
2391 # not an error if it doesn't, just continue
2392 #
2393 # Wonderfully consistent library, eh?
2394 # 160013 - svn:// and file://
2395 # 175002 - http(s)://
2396 # 175007 - http(s):// (this repo required authorization, too...)
2397 # More codes may be discovered later...
2398 if ($errno == 175007 || $errno == 175002 || $errno == 160013) {
2399 return;
2400 }
2401 die "Error from SVN, ($errno): ", $err->expanded_message,"\n";
2402 }
2403
2404 # svn_log_changed_path_t objects passed to get_log are likely to be
2405 # overwritten even if only the refs are copied to an external variable,
2406 # so we should dup the structures in their entirety. Using an externally
2407 # passed pool (instead of our temporary and quickly cleared pool in
2408 # Git::SVN::Ra) does not help matters at all...
2409 sub dup_changed_paths {
2410 my ($paths) = @_;
2411 return undef unless $paths;
2412 my %ret;
2413 foreach my $p (keys %$paths) {
2414 my $i = $paths->{$p};
2415 my %s = map { $_ => $i->$_ }
2416 qw/copyfrom_path copyfrom_rev action/;
2417 $ret{$p} = \%s;
2418 }
2419 \%ret;
2420 }
2421
2422 package Git::SVN::Log;
2423 use strict;
2424 use warnings;
2425 use POSIX qw/strftime/;
2426 use vars qw/$TZ $limit $color $pager $non_recursive $verbose $oneline
2427 %rusers $show_commit $incremental/;
2428 my $l_fmt;
2429
2430 sub cmt_showable {
2431 my ($c) = @_;
2432 return 1 if defined $c->{r};
2433 if ($c->{l} && $c->{l}->[-1] eq "...\n" &&
2434 $c->{a_raw} =~ /\@([a-f\d\-]+)>$/) {
2435 my @log = command(qw/cat-file commit/, $c->{c});
2436 shift @log while ($log[0] ne "\n");
2437 shift @log;
2438 @{$c->{l}} = grep !/^git-svn-id: /, @log;
2439
2440 (undef, $c->{r}, undef) = ::extract_metadata(
2441 (grep(/^git-svn-id: /, @log))[-1]);
2442 }
2443 return defined $c->{r};
2444 }
2445
2446 sub log_use_color {
2447 return 1 if $color;
2448 my ($dc, $dcvar);
2449 $dcvar = 'color.diff';
2450 $dc = `git-config --get $dcvar`;
2451 if ($dc eq '') {
2452 # nothing at all; fallback to "diff.color"
2453 $dcvar = 'diff.color';
2454 $dc = `git-config --get $dcvar`;
2455 }
2456 chomp($dc);
2457 if ($dc eq 'auto') {
2458 my $pc;
2459 $pc = `git-config --get color.pager`;
2460 if ($pc eq '') {
2461 # does not have it -- fallback to pager.color
2462 $pc = `git-config --bool --get pager.color`;
2463 }
2464 else {
2465 $pc = `git-config --bool --get color.pager`;
2466 if ($?) {
2467 $pc = 'false';
2468 }
2469 }
2470 chomp($pc);
2471 if (-t *STDOUT || (defined $pager && $pc eq 'true')) {
2472 return ($ENV{TERM} && $ENV{TERM} ne 'dumb');
2473 }
2474 return 0;
2475 }
2476 return 0 if $dc eq 'never';
2477 return 1 if $dc eq 'always';
2478 chomp($dc = `git-config --bool --get $dcvar`);
2479 return ($dc eq 'true');
2480 }
2481
2482 sub git_svn_log_cmd {
2483 my ($r_min, $r_max) = @_;
2484 my $gs = Git::SVN->_new;
2485 my @cmd = (qw/log --abbrev-commit --pretty=raw --default/,
2486 $gs->refname);
2487 push @cmd, '-r' unless $non_recursive;
2488 push @cmd, qw/--raw --name-status/ if $verbose;
2489 push @cmd, '--color' if log_use_color();
2490 return @cmd unless defined $r_max;
2491 if ($r_max == $r_min) {
2492 push @cmd, '--max-count=1';
2493 if (my $c = $gs->rev_db_get($r_max)) {
2494 push @cmd, $c;
2495 }
2496 } else {
2497 my ($c_min, $c_max);
2498 $c_max = $gs->rev_db_get($r_max);
2499 $c_min = $gs->rev_db_get($r_min);
2500 if (defined $c_min && defined $c_max) {
2501 if ($r_max > $r_max) {
2502 push @cmd, "$c_min..$c_max";
2503 } else {
2504 push @cmd, "$c_max..$c_min";
2505 }
2506 } elsif ($r_max > $r_min) {
2507 push @cmd, $c_max;
2508 } else {
2509 push @cmd, $c_min;
2510 }
2511 }
2512 return @cmd;
2513 }
2514
2515 # adapted from pager.c
2516 sub config_pager {
2517 $pager ||= $ENV{GIT_PAGER} || $ENV{PAGER};
2518 if (!defined $pager) {
2519 $pager = 'less';
2520 } elsif (length $pager == 0 || $pager eq 'cat') {
2521 $pager = undef;
2522 }
2523 }
2524
2525 sub run_pager {
2526 return unless -t *STDOUT;
2527 pipe my $rfd, my $wfd or return;
2528 defined(my $pid = fork) or ::fatal "Can't fork: $!\n";
2529 if (!$pid) {
2530 open STDOUT, '>&', $wfd or
2531 ::fatal "Can't redirect to stdout: $!\n";
2532 return;
2533 }
2534 open STDIN, '<&', $rfd or ::fatal "Can't redirect stdin: $!\n";
2535 $ENV{LESS} ||= 'FRSX';
2536 exec $pager or ::fatal "Can't run pager: $! ($pager)\n";
2537 }
2538
2539 sub tz_to_s_offset {
2540 my ($tz) = @_;
2541 $tz =~ s/(\d\d)$//;
2542 return ($1 * 60) + ($tz * 3600);
2543 }
2544
2545 sub get_author_info {
2546 my ($dest, $author, $t, $tz) = @_;
2547 $author =~ s/(?:^\s*|\s*$)//g;
2548 $dest->{a_raw} = $author;
2549 my $au;
2550 if ($::_authors) {
2551 $au = $rusers{$author} || undef;
2552 }
2553 if (!$au) {
2554 ($au) = ($author =~ /<([^>]+)\@[^>]+>$/);
2555 }
2556 $dest->{t} = $t;
2557 $dest->{tz} = $tz;
2558 $dest->{a} = $au;
2559 # Date::Parse isn't in the standard Perl distro :(
2560 if ($tz =~ s/^\+//) {
2561 $t += tz_to_s_offset($tz);
2562 } elsif ($tz =~ s/^\-//) {
2563 $t -= tz_to_s_offset($tz);
2564 }
2565 $dest->{t_utc} = $t;
2566 }
2567
2568 sub process_commit {
2569 my ($c, $r_min, $r_max, $defer) = @_;
2570 if (defined $r_min && defined $r_max) {
2571 if ($r_min == $c->{r} && $r_min == $r_max) {
2572 show_commit($c);
2573 return 0;
2574 }
2575 return 1 if $r_min == $r_max;
2576 if ($r_min < $r_max) {
2577 # we need to reverse the print order
2578 return 0 if (defined $limit && --$limit < 0);
2579 push @$defer, $c;
2580 return 1;
2581 }
2582 if ($r_min != $r_max) {
2583 return 1 if ($r_min < $c->{r});
2584 return 1 if ($r_max > $c->{r});
2585 }
2586 }
2587 return 0 if (defined $limit && --$limit < 0);
2588 show_commit($c);
2589 return 1;
2590 }
2591
2592 sub show_commit {
2593 my $c = shift;
2594 if ($oneline) {
2595 my $x = "\n";
2596 if (my $l = $c->{l}) {
2597 while ($l->[0] =~ /^\s*$/) { shift @$l }
2598 $x = $l->[0];
2599 }
2600 $l_fmt ||= 'A' . length($c->{r});
2601 print 'r',pack($l_fmt, $c->{r}),' | ';
2602 print "$c->{c} | " if $show_commit;
2603 print $x;
2604 } else {
2605 show_commit_normal($c);
2606 }
2607 }
2608
2609 sub show_commit_changed_paths {
2610 my ($c) = @_;
2611 return unless $c->{changed};
2612 print "Changed paths:\n", @{$c->{changed}};
2613 }
2614
2615 sub show_commit_normal {
2616 my ($c) = @_;
2617 print '-' x72, "\nr$c->{r} | ";
2618 print "$c->{c} | " if $show_commit;
2619 print "$c->{a} | ", strftime("%Y-%m-%d %H:%M:%S %z (%a, %d %b %Y)",
2620 localtime($c->{t_utc})), ' | ';
2621 my $nr_line = 0;
2622
2623 if (my $l = $c->{l}) {
2624 while ($l->[$#$l] eq "\n" && $#$l > 0
2625 && $l->[($#$l - 1)] eq "\n") {
2626 pop @$l;
2627 }
2628 $nr_line = scalar @$l;
2629 if (!$nr_line) {
2630 print "1 line\n\n\n";
2631 } else {
2632 if ($nr_line == 1) {
2633 $nr_line = '1 line';
2634 } else {
2635 $nr_line .= ' lines';
2636 }
2637 print $nr_line, "\n";
2638 show_commit_changed_paths($c);
2639 print "\n";
2640 print $_ foreach @$l;
2641 }
2642 } else {
2643 print "1 line\n";
2644 show_commit_changed_paths($c);
2645 print "\n";
2646
2647 }
2648 foreach my $x (qw/raw diff/) {
2649 if ($c->{$x}) {
2650 print "\n";
2651 print $_ foreach @{$c->{$x}}
2652 }
2653 }
2654 }
2655
2656 sub cmd_show_log {
2657 my (@args) = @_;
2658 my ($r_min, $r_max);
2659 my $r_last = -1; # prevent dupes
2660 if (defined $TZ) {
2661 $ENV{TZ} = $TZ;
2662 } else {
2663 delete $ENV{TZ};
2664 }
2665 if (defined $::_revision) {
2666 if ($::_revision =~ /^(\d+):(\d+)$/) {
2667 ($r_min, $r_max) = ($1, $2);
2668 } elsif ($::_revision =~ /^\d+$/) {
2669 $r_min = $r_max = $::_revision;
2670 } else {
2671 ::fatal "-r$::_revision is not supported, use ",
2672 "standard \'git log\' arguments instead\n";
2673 }
2674 }
2675
2676 config_pager();
2677 @args = (git_svn_log_cmd($r_min, $r_max), @args);
2678 my $log = command_output_pipe(@args);
2679 run_pager();
2680 my (@k, $c, $d);
2681 my $esc_color = qr/(?:\033\[(?:(?:\d+;)*\d*)?m)*/;
2682 while (<$log>) {
2683 if (/^${esc_color}commit ($::sha1_short)/o) {
2684 my $cmt = $1;
2685 if ($c && cmt_showable($c) && $c->{r} != $r_last) {
2686 $r_last = $c->{r};
2687 process_commit($c, $r_min, $r_max, \@k) or
2688 goto out;
2689 }
2690 $d = undef;
2691 $c = { c => $cmt };
2692 } elsif (/^${esc_color}author (.+) (\d+) ([\-\+]?\d+)$/o) {
2693 get_author_info($c, $1, $2, $3);
2694 } elsif (/^${esc_color}(?:tree|parent|committer) /o) {
2695 # ignore
2696 } elsif (/^${esc_color}:\d{6} \d{6} $::sha1_short/o) {
2697 push @{$c->{raw}}, $_;
2698 } elsif (/^${esc_color}[ACRMDT]\t/) {
2699 # we could add $SVN->{svn_path} here, but that requires
2700 # remote access at the moment (repo_path_split)...
2701 s#^(${esc_color})([ACRMDT])\t#$1 $2 #o;
2702 push @{$c->{changed}}, $_;
2703 } elsif (/^${esc_color}diff /o) {
2704 $d = 1;
2705 push @{$c->{diff}}, $_;
2706 } elsif ($d) {
2707 push @{$c->{diff}}, $_;
2708 } elsif (/^${esc_color} (git-svn-id:.+)$/o) {
2709 ($c->{url}, $c->{r}, undef) = ::extract_metadata($1);
2710 } elsif (s/^${esc_color} //o) {
2711 push @{$c->{l}}, $_;
2712 }
2713 }
2714 if ($c && defined $c->{r} && $c->{r} != $r_last) {
2715 $r_last = $c->{r};
2716 process_commit($c, $r_min, $r_max, \@k);
2717 }
2718 if (@k) {
2719 my $swap = $r_max;
2720 $r_max = $r_min;
2721 $r_min = $swap;
2722 process_commit($_, $r_min, $r_max) foreach reverse @k;
2723 }
2724 out:
2725 close $log;
2726 print '-' x72,"\n" unless $incremental || $oneline;
2727 }
2728
2729 package Git::SVN::Migration;
2730 # these version numbers do NOT correspond to actual version numbers
2731 # of git nor git-svn. They are just relative.
2732 #
2733 # v0 layout: .git/$id/info/url, refs/heads/$id-HEAD
2734 #
2735 # v1 layout: .git/$id/info/url, refs/remotes/$id
2736 #
2737 # v2 layout: .git/svn/$id/info/url, refs/remotes/$id
2738 #
2739 # v3 layout: .git/svn/$id, refs/remotes/$id
2740 # - info/url may remain for backwards compatibility
2741 # - this is what we migrate up to this layout automatically,
2742 # - this will be used by git svn init on single branches
2743 #
2744 # v4 layout: .git/svn/$repo_id/$id, refs/remotes/$repo_id/$id
2745 # - this is only created for newly multi-init-ed
2746 # repositories. Similar in spirit to the
2747 # --use-separate-remotes option in git-clone (now default)
2748 # - we do not automatically migrate to this (following
2749 # the example set by core git)
2750 use strict;
2751 use warnings;
2752 use Carp qw/croak/;
2753 use File::Path qw/mkpath/;
2754 use File::Basename qw/dirname basename/;
2755 use vars qw/$_minimize/;
2756
2757 sub migrate_from_v0 {
2758 my $git_dir = $ENV{GIT_DIR};
2759 return undef unless -d $git_dir;
2760 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2761 my $migrated = 0;
2762 while (<$fh>) {
2763 chomp;
2764 my ($id, $orig_ref) = ($_, $_);
2765 next unless $id =~ s#^refs/heads/(.+)-HEAD$#$1#;
2766 next unless -f "$git_dir/$id/info/url";
2767 my $new_ref = "refs/remotes/$id";
2768 if (::verify_ref("$new_ref^0")) {
2769 print STDERR "W: $orig_ref is probably an old ",
2770 "branch used by an ancient version of ",
2771 "git-svn.\n",
2772 "However, $new_ref also exists.\n",
2773 "We will not be able ",
2774 "to use this branch until this ",
2775 "ambiguity is resolved.\n";
2776 next;
2777 }
2778 print STDERR "Migrating from v0 layout...\n" if !$migrated;
2779 print STDERR "Renaming ref: $orig_ref => $new_ref\n";
2780 command_noisy('update-ref', $new_ref, $orig_ref);
2781 command_noisy('update-ref', '-d', $orig_ref, $orig_ref);
2782 $migrated++;
2783 }
2784 command_close_pipe($fh, $ctx);
2785 print STDERR "Done migrating from v0 layout...\n" if $migrated;
2786 $migrated;
2787 }
2788
2789 sub migrate_from_v1 {
2790 my $git_dir = $ENV{GIT_DIR};
2791 my $migrated = 0;
2792 return $migrated unless -d $git_dir;
2793 my $svn_dir = "$git_dir/svn";
2794
2795 # just in case somebody used 'svn' as their $id at some point...
2796 return $migrated if -d $svn_dir && ! -f "$svn_dir/info/url";
2797
2798 print STDERR "Migrating from a git-svn v1 layout...\n";
2799 mkpath([$svn_dir]);
2800 print STDERR "Data from a previous version of git-svn exists, but\n\t",
2801 "$svn_dir\n\t(required for this version ",
2802 "($::VERSION) of git-svn) does not. exist\n";
2803 my ($fh, $ctx) = command_output_pipe(qw/rev-parse --symbolic --all/);
2804 while (<$fh>) {
2805 my $x = $_;
2806 next unless $x =~ s#^refs/remotes/##;
2807 chomp $x;
2808 next unless -f "$git_dir/$x/info/url";
2809 my $u = eval { ::file_to_s("$git_dir/$x/info/url") };
2810 next unless $u;
2811 my $dn = dirname("$git_dir/svn/$x");
2812 mkpath([$dn]) unless -d $dn;
2813 if ($x eq 'svn') { # they used 'svn' as GIT_SVN_ID:
2814 mkpath(["$git_dir/svn/svn"]);
2815 print STDERR " - $git_dir/$x/info => ",
2816 "$git_dir/svn/$x/info\n";
2817 rename "$git_dir/$x/info", "$git_dir/svn/$x/info" or
2818 croak "$!: $x";
2819 # don't worry too much about these, they probably
2820 # don't exist with repos this old (save for index,
2821 # and we can easily regenerate that)
2822 foreach my $f (qw/unhandled.log index .rev_db/) {
2823 rename "$git_dir/$x/$f", "$git_dir/svn/$x/$f";
2824 }
2825 } else {
2826 print STDERR " - $git_dir/$x => $git_dir/svn/$x\n";
2827 rename "$git_dir/$x", "$git_dir/svn/$x" or
2828 croak "$!: $x";
2829 }
2830 $migrated++;
2831 }
2832 command_close_pipe($fh, $ctx);
2833 print STDERR "Done migrating from a git-svn v1 layout\n";
2834 $migrated;
2835 }
2836
2837 sub read_old_urls {
2838 my ($l_map, $pfx, $path) = @_;
2839 my @dir;
2840 foreach (<$path/*>) {
2841 if (-r "$_/info/url") {
2842 $pfx .= '/' if $pfx && $pfx !~ m!/$!;
2843 my $ref_id = $pfx . basename $_;
2844 my $url = ::file_to_s("$_/info/url");
2845 $l_map->{$ref_id} = $url;
2846 } elsif (-d $_) {
2847 push @dir, $_;
2848 }
2849 }
2850 foreach (@dir) {
2851 my $x = $_;
2852 $x =~ s!^\Q$ENV{GIT_DIR}\E/svn/!!o;
2853 read_old_urls($l_map, $x, $_);
2854 }
2855 }
2856
2857 sub migrate_from_v2 {
2858 my @cfg = command(qw/config -l/);
2859 return if grep /^svn-remote\..+\.url=/, @cfg;
2860 my %l_map;
2861 read_old_urls(\%l_map, '', "$ENV{GIT_DIR}/svn");
2862 my $migrated = 0;
2863
2864 foreach my $ref_id (sort keys %l_map) {
2865 Git::SVN->init($l_map{$ref_id}, '', $ref_id, $ref_id);
2866 $migrated++;
2867 }
2868 $migrated;
2869 }
2870
2871 sub minimize_connections {
2872 my $r = Git::SVN::read_all_remotes();
2873 my $new_urls = {};
2874 my $root_repos = {};
2875 foreach my $repo_id (keys %$r) {
2876 my $url = $r->{$repo_id}->{url} or next;
2877 my $fetch = $r->{$repo_id}->{fetch} or next;
2878 my $ra = Git::SVN::Ra->new($url);
2879
2880 # skip existing cases where we already connect to the root
2881 if (($ra->{url} eq $ra->{repos_root}) ||
2882 (Git::SVN::sanitize_remote_name($ra->{repos_root}) eq
2883 $repo_id)) {
2884 $root_repos->{$ra->{url}} = $repo_id;
2885 next;
2886 }
2887
2888 my $root_ra = Git::SVN::Ra->new($ra->{repos_root});
2889 my $root_path = $ra->{url};
2890 $root_path =~ s#^\Q$ra->{repos_root}\E/*##;
2891 foreach my $path (keys %$fetch) {
2892 my $ref_id = $fetch->{$path};
2893 my $gs = Git::SVN->new($ref_id, $repo_id, $path);
2894
2895 # make sure we can read when connecting to
2896 # a higher level of a repository
2897 my ($last_rev, undef) = $gs->last_rev_commit;
2898 if (!defined $last_rev) {
2899 $last_rev = eval {
2900 $root_ra->get_latest_revnum;
2901 };
2902 next if $@;
2903 }
2904 my $new = $root_path;
2905 $new .= length $path ? "/$path" : '';
2906 eval {
2907 $root_ra->get_log([$new], $last_rev, $last_rev,
2908 0, 0, 1, sub { });
2909 };
2910 next if $@;
2911 $new_urls->{$ra->{repos_root}}->{$new} =
2912 { ref_id => $ref_id,
2913 old_repo_id => $repo_id,
2914 old_path => $path };
2915 }
2916 }
2917
2918 my @emptied;
2919 foreach my $url (keys %$new_urls) {
2920 # see if we can re-use an existing [svn-remote "repo_id"]
2921 # instead of creating a(n ugly) new section:
2922 my $repo_id = $root_repos->{$url} ||
2923 Git::SVN::sanitize_remote_name($url);
2924
2925 my $fetch = $new_urls->{$url};
2926 foreach my $path (keys %$fetch) {
2927 my $x = $fetch->{$path};
2928 Git::SVN->init($url, $path, $repo_id, $x->{ref_id});
2929 my $pfx = "svn-remote.$x->{old_repo_id}";
2930
2931 my $old_fetch = quotemeta("$x->{old_path}:".
2932 "refs/remotes/$x->{ref_id}");
2933 command_noisy(qw/config --unset/,
2934 "$pfx.fetch", '^'. $old_fetch . '$');
2935 delete $r->{$x->{old_repo_id}}->
2936 {fetch}->{$x->{old_path}};
2937 if (!keys %{$r->{$x->{old_repo_id}}->{fetch}}) {
2938 command_noisy(qw/config --unset/,
2939 "$pfx.url");
2940 push @emptied, $x->{old_repo_id}
2941 }
2942 }
2943 }
2944 if (@emptied) {
2945 my $file = $ENV{GIT_CONFIG} || $ENV{GIT_CONFIG_LOCAL} ||
2946 "$ENV{GIT_DIR}/config";
2947 print STDERR <<EOF;
2948 The following [svn-remote] sections in your config file ($file) are empty
2949 and can be safely removed:
2950 EOF
2951 print STDERR "[svn-remote \"$_\"]\n" foreach @emptied;
2952 }
2953 }
2954
2955 sub migration_check {
2956 migrate_from_v0();
2957 migrate_from_v1();
2958 migrate_from_v2();
2959 minimize_connections() if $_minimize;
2960 }
2961
2962 package Git::IndexInfo;
2963 use strict;
2964 use warnings;
2965 use Git qw/command_input_pipe command_close_pipe/;
2966
2967 sub new {
2968 my ($class) = @_;
2969 my ($gui, $ctx) = command_input_pipe(qw/update-index -z --index-info/);
2970 bless { gui => $gui, ctx => $ctx, nr => 0}, $class;
2971 }
2972
2973 sub remove {
2974 my ($self, $path) = @_;
2975 if (print { $self->{gui} } '0 ', 0 x 40, "\t", $path, "\0") {
2976 return ++$self->{nr};
2977 }
2978 undef;
2979 }
2980
2981 sub update {
2982 my ($self, $mode, $hash, $path) = @_;
2983 if (print { $self->{gui} } $mode, ' ', $hash, "\t", $path, "\0") {
2984 return ++$self->{nr};
2985 }
2986 undef;
2987 }
2988
2989 sub DESTROY {
2990 my ($self) = @_;
2991 command_close_pipe($self->{gui}, $self->{ctx});
2992 }
2993
2994 __END__
2995
2996 Data structures:
2997
2998 $log_entry hashref as returned by libsvn_log_entry()
2999 {
3000 log => 'whitespace-formatted log entry
3001 ', # trailing newline is preserved
3002 revision => '8', # integer
3003 date => '2004-02-24T17:01:44.108345Z', # commit date
3004 author => 'committer name'
3005 };
3006
3007
3008 # this is generated by generate_diff();
3009 @mods = array of diff-index line hashes, each element represents one line
3010 of diff-index output
3011
3012 diff-index line ($m hash)
3013 {
3014 mode_a => first column of diff-index output, no leading ':',
3015 mode_b => second column of diff-index output,
3016 sha1_b => sha1sum of the final blob,
3017 chg => change type [MCRADT],
3018 file_a => original file name of a file (iff chg is 'C' or 'R')
3019 file_b => new/current file name of a file (any chg)
3020 }
3021 ;
3022
3023 # retval of read_url_paths{,_all}();
3024 $l_map = {
3025 # repository root url
3026 'https://svn.musicpd.org' => {
3027 # repository path # GIT_SVN_ID
3028 'mpd/trunk' => 'trunk',
3029 'mpd/tags/0.11.5' => 'tags/0.11.5',
3030 },
3031 }
3032
3033 Notes:
3034 I don't trust the each() function on unless I created %hash myself
3035 because the internal iterator may not have started at base.
Dscho's miscellaneous git branches