git-gui/git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title "git-gui: fatal error" \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86         if {[tk windowingsystem] eq "win32"} { console show }
  87 }
  88
  89 ######################################################################
  90 ##
  91 ## Internationalization (i18n) through msgcat and gettext. See
  92 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  93
  94 package require msgcat
  95
  96 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
  97 if {[tk windowingsystem] eq "win32"
  98         && [package vcompare [package provide msgcat] 1.4.4] < 0
  99 } then {
 100         proc _mc_update_locale {} {
 101                 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 102                 if {![catch {
 103                         package require registry
 104                         set uilocale [registry get $key "PreferredUILanguages"]
 105                         msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 106                 } uilocale]} {
 107                         if {[string length $uilocale] > 0} {
 108                                 msgcat::mclocale $uilocale
 109                         }
 110                 }
 111         }
 112         _mc_update_locale
 113 }
 114
 115 proc _mc_trim {fmt} {
 116         set cmk [string first @@ $fmt]
 117         if {$cmk > 0} {
 118                 return [string range $fmt 0 [expr {$cmk - 1}]]
 119         }
 120         return $fmt
 121 }
 122
 123 proc mc {en_fmt args} {
 124         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 125         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 126                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 127         }
 128         return $msg
 129 }
 130
 131 proc strcat {args} {
 132         return [join $args {}]
 133 }
 134
 135 ::msgcat::mcload $oguimsg
 136 unset oguimsg
 137
 138 ######################################################################
 139 ##
 140 ## read only globals
 141
 142 set _appname {Git Gui}
 143 set _gitdir {}
 144 set _gitworktree {}
 145 set _isbare {}
 146 set _gitexec {}
 147 set _githtmldir {}
 148 set _reponame {}
 149 set _iscygwin {}
 150 set _search_path {}
 151 set _shellpath {@@SHELL_PATH@@}
 152
 153 set _trace [lsearch -exact $argv --trace]
 154 if {$_trace >= 0} {
 155         set argv [lreplace $argv $_trace $_trace]
 156         set _trace 1
 157 } else {
 158         set _trace 0
 159 }
 160
 161 # variable for the last merged branch (useful for a default when deleting
 162 # branches).
 163 set _last_merged_branch {}
 164
 165 proc shellpath {} {
 166         global _shellpath env
 167         if {[string match @@* $_shellpath]} {
 168                 if {[info exists env(SHELL)]} {
 169                         return $env(SHELL)
 170                 } else {
 171                         return /bin/sh
 172                 }
 173         }
 174         return $_shellpath
 175 }
 176
 177 proc appname {} {
 178         global _appname
 179         return $_appname
 180 }
 181
 182 proc gitdir {args} {
 183         global _gitdir
 184         if {$args eq {}} {
 185                 return $_gitdir
 186         }
 187         return [eval [list file join $_gitdir] $args]
 188 }
 189
 190 proc gitexec {args} {
 191         global _gitexec
 192         if {$_gitexec eq {}} {
 193                 if {[catch {set _gitexec [git --exec-path]} err]} {
 194                         error "Git not installed?\n\n$err"
 195                 }
 196                 if {[is_Cygwin]} {
 197                         set _gitexec [exec cygpath \
 198                                 --windows \
 199                                 --absolute \
 200                                 $_gitexec]
 201                 } else {
 202                         set _gitexec [file normalize $_gitexec]
 203                 }
 204         }
 205         if {$args eq {}} {
 206                 return $_gitexec
 207         }
 208         return [eval [list file join $_gitexec] $args]
 209 }
 210
 211 proc githtmldir {args} {
 212         global _githtmldir
 213         if {$_githtmldir eq {}} {
 214                 if {[catch {set _githtmldir [git --html-path]}]} {
 215                         # Git not installed or option not yet supported
 216                         return {}
 217                 }
 218                 if {[is_Cygwin]} {
 219                         set _githtmldir [exec cygpath \
 220                                 --windows \
 221                                 --absolute \
 222                                 $_githtmldir]
 223                 } else {
 224                         set _githtmldir [file normalize $_githtmldir]
 225                 }
 226         }
 227         if {$args eq {}} {
 228                 return $_githtmldir
 229         }
 230         return [eval [list file join $_githtmldir] $args]
 231 }
 232
 233 proc reponame {} {
 234         return $::_reponame
 235 }
 236
 237 proc is_MacOSX {} {
 238         if {[tk windowingsystem] eq {aqua}} {
 239                 return 1
 240         }
 241         return 0
 242 }
 243
 244 proc is_Windows {} {
 245         if {$::tcl_platform(platform) eq {windows}} {
 246                 return 1
 247         }
 248         return 0
 249 }
 250
 251 proc is_Cygwin {} {
 252         global _iscygwin
 253         if {$_iscygwin eq {}} {
 254                 if {$::tcl_platform(platform) eq {windows}} {
 255                         if {[catch {set p [exec cygpath --windir]} err]} {
 256                                 set _iscygwin 0
 257                         } else {
 258                                 set _iscygwin 1
 259                         }
 260                 } else {
 261                         set _iscygwin 0
 262                 }
 263         }
 264         return $_iscygwin
 265 }
 266
 267 proc is_enabled {option} {
 268         global enabled_options
 269         if {[catch {set on $enabled_options($option)}]} {return 0}
 270         return $on
 271 }
 272
 273 proc enable_option {option} {
 274         global enabled_options
 275         set enabled_options($option) 1
 276 }
 277
 278 proc disable_option {option} {
 279         global enabled_options
 280         set enabled_options($option) 0
 281 }
 282
 283 ######################################################################
 284 ##
 285 ## config
 286
 287 proc is_many_config {name} {
 288         switch -glob -- $name {
 289         gui.recentrepo -
 290         remote.*.fetch -
 291         remote.*.push
 292                 {return 1}
 293         *
 294                 {return 0}
 295         }
 296 }
 297
 298 proc is_config_true {name} {
 299         global repo_config
 300         if {[catch {set v $repo_config($name)}]} {
 301                 return 0
 302         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 303                 return 1
 304         } else {
 305                 return 0
 306         }
 307 }
 308
 309 proc is_config_false {name} {
 310         global repo_config
 311         if {[catch {set v $repo_config($name)}]} {
 312                 return 0
 313         } elseif {$v eq {false} || $v eq {0} || $v eq {no}} {
 314                 return 1
 315         } else {
 316                 return 0
 317         }
 318 }
 319
 320 proc get_config {name} {
 321         global repo_config
 322         if {[catch {set v $repo_config($name)}]} {
 323                 return {}
 324         } else {
 325                 return $v
 326         }
 327 }
 328
 329 proc is_bare {} {
 330         global _isbare
 331         global _gitdir
 332         global _gitworktree
 333
 334         if {$_isbare eq {}} {
 335                 if {[catch {
 336                         set _bare [git rev-parse --is-bare-repository]
 337                         switch  -- $_bare {
 338                         true { set _isbare 1 }
 339                         false { set _isbare 0}
 340                         default { throw }
 341                         }
 342                 }]} {
 343                         if {[is_config_true core.bare]
 344                                 || ($_gitworktree eq {}
 345                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 346                                 set _isbare 1
 347                         } else {
 348                                 set _isbare 0
 349                         }
 350                 }
 351         }
 352         return $_isbare
 353 }
 354
 355 ######################################################################
 356 ##
 357 ## handy utils
 358
 359 proc _trace_exec {cmd} {
 360         if {!$::_trace} return
 361         set d {}
 362         foreach v $cmd {
 363                 if {$d ne {}} {
 364                         append d { }
 365                 }
 366                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 367                         set v [sq $v]
 368                 }
 369                 append d $v
 370         }
 371         puts stderr $d
 372 }
 373
 374 #'"  fix poor old emacs font-lock mode
 375
 376 proc _git_cmd {name} {
 377         global _git_cmd_path
 378
 379         if {[catch {set v $_git_cmd_path($name)}]} {
 380                 switch -- $name {
 381                   version   -
 382                 --version   -
 383                 --exec-path { return [list $::_git $name] }
 384                 }
 385
 386                 set p [gitexec git-$name$::_search_exe]
 387                 if {[file exists $p]} {
 388                         set v [list $p]
 389                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 390                         # Try to determine what sort of magic will make
 391                         # git-$name go and do its thing, because native
 392                         # Tcl on Windows doesn't know it.
 393                         #
 394                         set p [gitexec git-$name]
 395                         set f [open $p r]
 396                         set s [gets $f]
 397                         close $f
 398
 399                         switch -glob -- [lindex $s 0] {
 400                         #!*sh     { set i sh     }
 401                         #!*perl   { set i perl   }
 402                         #!*python { set i python }
 403                         default   { error "git-$name is not supported: $s" }
 404                         }
 405
 406                         upvar #0 _$i interp
 407                         if {![info exists interp]} {
 408                                 set interp [_which $i]
 409                         }
 410                         if {$interp eq {}} {
 411                                 error "git-$name requires $i (not in PATH)"
 412                         }
 413                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 414                 } else {
 415                         # Assume it is builtin to git somehow and we
 416                         # aren't actually able to see a file for it.
 417                         #
 418                         set v [list $::_git $name]
 419                 }
 420                 set _git_cmd_path($name) $v
 421         }
 422         return $v
 423 }
 424
 425 proc _which {what args} {
 426         global env _search_exe _search_path
 427
 428         if {$_search_path eq {}} {
 429                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 430                         set _search_path [split [exec cygpath \
 431                                 --windows \
 432                                 --path \
 433                                 --absolute \
 434                                 $env(PATH)] {;}]
 435                         set _search_exe .exe
 436                 } elseif {[is_Windows]} {
 437                         set gitguidir [file dirname [info script]]
 438                         regsub -all ";" $gitguidir "\\;" gitguidir
 439                         set env(PATH) "$gitguidir;$env(PATH)"
 440                         set _search_path [split $env(PATH) {;}]
 441                         set _search_exe .exe
 442                 } else {
 443                         set _search_path [split $env(PATH) :]
 444                         set _search_exe {}
 445                 }
 446         }
 447
 448         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 449                 set suffix {}
 450         } else {
 451                 set suffix $_search_exe
 452         }
 453
 454         foreach p $_search_path {
 455                 set p [file join $p $what$suffix]
 456                 if {[file exists $p]} {
 457                         return [file normalize $p]
 458                 }
 459         }
 460         return {}
 461 }
 462
 463 proc _lappend_nice {cmd_var} {
 464         global _nice
 465         upvar $cmd_var cmd
 466
 467         if {![info exists _nice]} {
 468                 set _nice [_which nice]
 469                 if {[catch {exec $_nice git version}]} {
 470                         set _nice {}
 471                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 472                         set _nice {}
 473                 }
 474         }
 475         if {$_nice ne {}} {
 476                 lappend cmd $_nice
 477         }
 478 }
 479
 480 proc git {args} {
 481         set opt [list]
 482
 483         while {1} {
 484                 switch -- [lindex $args 0] {
 485                 --nice {
 486                         _lappend_nice opt
 487                 }
 488
 489                 default {
 490                         break
 491                 }
 492
 493                 }
 494
 495                 set args [lrange $args 1 end]
 496         }
 497
 498         set cmdp [_git_cmd [lindex $args 0]]
 499         set args [lrange $args 1 end]
 500
 501         _trace_exec [concat $opt $cmdp $args]
 502         set result [eval exec $opt $cmdp $args]
 503         if {$::_trace} {
 504                 puts stderr "< $result"
 505         }
 506         return $result
 507 }
 508
 509 proc _open_stdout_stderr {cmd} {
 510         _trace_exec $cmd
 511         if {[catch {
 512                         set fd [open [concat [list | ] $cmd] r]
 513                 } err]} {
 514                 if {   [lindex $cmd end] eq {2>@1}
 515                     && $err eq {can not find channel named "1"}
 516                         } {
 517                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 518                         # redirect operator.  Fallback to |& cat for those.
 519                         # The command was not actually started, so its safe
 520                         # to try to start it a second time.
 521                         #
 522                         set fd [open [concat \
 523                                 [list | ] \
 524                                 [lrange $cmd 0 end-1] \
 525                                 [list |& cat] \
 526                                 ] r]
 527                 } else {
 528                         error $err
 529                 }
 530         }
 531         fconfigure $fd -eofchar {}
 532         return $fd
 533 }
 534
 535 proc git_read {args} {
 536         set opt [list]
 537
 538         while {1} {
 539                 switch -- [lindex $args 0] {
 540                 --nice {
 541                         _lappend_nice opt
 542                 }
 543
 544                 --stderr {
 545                         lappend args 2>@1
 546                 }
 547
 548                 default {
 549                         break
 550                 }
 551
 552                 }
 553
 554                 set args [lrange $args 1 end]
 555         }
 556
 557         set cmdp [_git_cmd [lindex $args 0]]
 558         set args [lrange $args 1 end]
 559
 560         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 561 }
 562
 563 proc git_write {args} {
 564         set opt [list]
 565
 566         while {1} {
 567                 switch -- [lindex $args 0] {
 568                 --nice {
 569                         _lappend_nice opt
 570                 }
 571
 572                 default {
 573                         break
 574                 }
 575
 576                 }
 577
 578                 set args [lrange $args 1 end]
 579         }
 580
 581         set cmdp [_git_cmd [lindex $args 0]]
 582         set args [lrange $args 1 end]
 583
 584         _trace_exec [concat $opt $cmdp $args]
 585         return [open [concat [list | ] $opt $cmdp $args] w]
 586 }
 587
 588 proc githook_read {hook_name args} {
 589         set pchook [gitdir hooks $hook_name]
 590         lappend args 2>@1
 591
 592         # On Windows [file executable] might lie so we need to ask
 593         # the shell if the hook is executable.  Yes that's annoying.
 594         #
 595         if {[is_Windows]} {
 596                 upvar #0 _sh interp
 597                 if {![info exists interp]} {
 598                         set interp [_which sh]
 599                 }
 600                 if {$interp eq {}} {
 601                         error "hook execution requires sh (not in PATH)"
 602                 }
 603
 604                 set scr {if test -x "$1";then exec "$@";fi}
 605                 set sh_c [list $interp -c $scr $interp $pchook]
 606                 return [_open_stdout_stderr [concat $sh_c $args]]
 607         }
 608
 609         if {[file executable $pchook]} {
 610                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 611         }
 612
 613         return {}
 614 }
 615
 616 proc kill_file_process {fd} {
 617         set process [pid $fd]
 618
 619         catch {
 620                 if {[is_Windows]} {
 621                         # Use a Cygwin-specific flag to allow killing
 622                         # native Windows processes
 623                         exec kill -f $process
 624                 } else {
 625                         exec kill $process
 626                 }
 627         }
 628 }
 629
 630 proc gitattr {path attr default} {
 631         if {[catch {set r [git check-attr $attr -- $path]}]} {
 632                 set r unspecified
 633         } else {
 634                 set r [join [lrange [split $r :] 2 end] :]
 635                 regsub {^ } $r {} r
 636         }
 637         if {$r eq {unspecified}} {
 638                 return $default
 639         }
 640         return $r
 641 }
 642
 643 proc sq {value} {
 644         regsub -all ' $value "'\\''" value
 645         return "'$value'"
 646 }
 647
 648 proc load_current_branch {} {
 649         global current_branch is_detached
 650
 651         set fd [open [gitdir HEAD] r]
 652         if {[gets $fd ref] < 1} {
 653                 set ref {}
 654         }
 655         close $fd
 656
 657         set pfx {ref: refs/heads/}
 658         set len [string length $pfx]
 659         if {[string equal -length $len $pfx $ref]} {
 660                 # We're on a branch.  It might not exist.  But
 661                 # HEAD looks good enough to be a branch.
 662                 #
 663                 set current_branch [string range $ref $len end]
 664                 set is_detached 0
 665         } else {
 666                 # Assume this is a detached head.
 667                 #
 668                 set current_branch HEAD
 669                 set is_detached 1
 670         }
 671 }
 672
 673 auto_load tk_optionMenu
 674 rename tk_optionMenu real__tkOptionMenu
 675 proc tk_optionMenu {w varName args} {
 676         set m [eval real__tkOptionMenu $w $varName $args]
 677         $m configure -font font_ui
 678         $w configure -font font_ui
 679         return $m
 680 }
 681
 682 proc rmsel_tag {text} {
 683         $text tag conf sel \
 684                 -background [$text cget -background] \
 685                 -foreground [$text cget -foreground] \
 686                 -borderwidth 0
 687         $text tag conf in_sel -background lightgray
 688         bind $text <Motion> break
 689         return $text
 690 }
 691
 692 wm withdraw .
 693 set root_exists 0
 694 bind . <Visibility> {
 695         bind . <Visibility> {}
 696         set root_exists 1
 697 }
 698
 699 if {[is_Windows]} {
 700         wm iconbitmap . -default $oguilib/git-gui.ico
 701         set ::tk::AlwaysShowSelection 1
 702         bind . <Control-F2> {console show}
 703
 704         # Spoof an X11 display for SSH
 705         if {![info exists env(DISPLAY)]} {
 706                 set env(DISPLAY) :9999
 707         }
 708 } else {
 709         catch {
 710                 image create photo gitlogo -width 16 -height 16
 711
 712                 gitlogo put #33CC33 -to  7  0  9  2
 713                 gitlogo put #33CC33 -to  4  2 12  4
 714                 gitlogo put #33CC33 -to  7  4  9  6
 715                 gitlogo put #CC3333 -to  4  6 12  8
 716                 gitlogo put gray26  -to  4  9  6 10
 717                 gitlogo put gray26  -to  3 10  6 12
 718                 gitlogo put gray26  -to  8  9 13 11
 719                 gitlogo put gray26  -to  8 11 10 12
 720                 gitlogo put gray26  -to 11 11 13 14
 721                 gitlogo put gray26  -to  3 12  5 14
 722                 gitlogo put gray26  -to  5 13
 723                 gitlogo put gray26  -to 10 13
 724                 gitlogo put gray26  -to  4 14 12 15
 725                 gitlogo put gray26  -to  5 15 11 16
 726                 gitlogo redither
 727
 728                 wm iconphoto . -default gitlogo
 729         }
 730 }
 731
 732 ######################################################################
 733 ##
 734 ## config defaults
 735
 736 set cursor_ptr arrow
 737 font create font_ui
 738 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 739         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 740         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 741 } else {
 742         font create font_diff -family Courier -size 10
 743         catch {
 744                 label .dummy
 745                 eval font configure font_ui [font actual [.dummy cget -font]]
 746                 destroy .dummy
 747         }
 748 }
 749
 750 font create font_uiitalic
 751 font create font_uibold
 752 font create font_diffbold
 753 font create font_diffitalic
 754
 755 foreach class {Button Checkbutton Entry Label
 756                 Labelframe Listbox Message
 757                 Radiobutton Spinbox Text} {
 758         option add *$class.font font_ui
 759 }
 760 if {![is_MacOSX]} {
 761         option add *Menu.font font_ui
 762         option add *Entry.borderWidth 1 startupFile
 763         option add *Entry.relief sunken startupFile
 764         option add *RadioButton.anchor w startupFile
 765 }
 766 unset class
 767
 768 if {[is_Windows] || [is_MacOSX]} {
 769         option add *Menu.tearOff 0
 770 }
 771
 772 if {[is_MacOSX]} {
 773         set M1B M1
 774         set M1T Cmd
 775 } else {
 776         set M1B Control
 777         set M1T Ctrl
 778 }
 779
 780 proc bind_button3 {w cmd} {
 781         bind $w <Any-Button-3> $cmd
 782         if {[is_MacOSX]} {
 783                 # Mac OS X sends Button-2 on right click through three-button mouse,
 784                 # or through trackpad right-clicking (two-finger touch + click).
 785                 bind $w <Any-Button-2> $cmd
 786                 bind $w <Control-Button-1> $cmd
 787         }
 788 }
 789
 790 proc apply_config {} {
 791         global repo_config font_descs
 792
 793         foreach option $font_descs {
 794                 set name [lindex $option 0]
 795                 set font [lindex $option 1]
 796                 if {[catch {
 797                         set need_weight 1
 798                         foreach {cn cv} $repo_config(gui.$name) {
 799                                 if {$cn eq {-weight}} {
 800                                         set need_weight 0
 801                                 }
 802                                 font configure $font $cn $cv
 803                         }
 804                         if {$need_weight} {
 805                                 font configure $font -weight normal
 806                         }
 807                         } err]} {
 808                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 809                 }
 810                 foreach {cn cv} [font configure $font] {
 811                         font configure ${font}bold $cn $cv
 812                         font configure ${font}italic $cn $cv
 813                 }
 814                 font configure ${font}bold -weight bold
 815                 font configure ${font}italic -slant italic
 816         }
 817
 818         global use_ttk NS
 819         set use_ttk 0
 820         set NS {}
 821         if {$repo_config(gui.usettk)} {
 822                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 823                 if {$use_ttk} {
 824                         set NS ttk
 825                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 826                         pave_toplevel .
 827                 }
 828         }
 829 }
 830
 831 set default_config(branch.autosetupmerge) true
 832 set default_config(merge.tool) {}
 833 set default_config(mergetool.keepbackup) true
 834 set default_config(merge.diffstat) true
 835 set default_config(merge.summary) false
 836 set default_config(merge.verbosity) 2
 837 set default_config(user.name) {}
 838 set default_config(user.email) {}
 839
 840 set default_config(gui.encoding) [encoding system]
 841 set default_config(gui.matchtrackingbranch) false
 842 set default_config(gui.textconv) true
 843 set default_config(gui.pruneduringfetch) false
 844 set default_config(gui.trustmtime) false
 845 set default_config(gui.fastcopyblame) false
 846 set default_config(gui.copyblamethreshold) 40
 847 set default_config(gui.blamehistoryctx) 7
 848 set default_config(gui.diffcontext) 5
 849 set default_config(gui.commitmsgwidth) 75
 850 set default_config(gui.newbranchtemplate) {}
 851 set default_config(gui.spellingdictionary) {}
 852 set default_config(gui.fontui) [font configure font_ui]
 853 set default_config(gui.fontdiff) [font configure font_diff]
 854 # TODO: this option should be added to the git-config documentation
 855 set default_config(gui.maxfilesdisplayed) 5000
 856 set default_config(gui.usettk) 1
 857 set font_descs {
 858         {fontui   font_ui   {mc "Main Font"}}
 859         {fontdiff font_diff {mc "Diff/Console Font"}}
 860 }
 861
 862 ######################################################################
 863 ##
 864 ## find git
 865
 866 set _git  [_which git]
 867 if {$_git eq {}} {
 868         catch {wm withdraw .}
 869         tk_messageBox \
 870                 -icon error \
 871                 -type ok \
 872                 -title [mc "git-gui: fatal error"] \
 873                 -message [mc "Cannot find git in PATH."]
 874         exit 1
 875 }
 876
 877 ######################################################################
 878 ##
 879 ## version check
 880
 881 if {[catch {set _git_version [git --version]} err]} {
 882         catch {wm withdraw .}
 883         tk_messageBox \
 884                 -icon error \
 885                 -type ok \
 886                 -title [mc "git-gui: fatal error"] \
 887                 -message "Cannot determine Git version:
 888
 889 $err
 890
 891 [appname] requires Git 1.5.0 or later."
 892         exit 1
 893 }
 894 if {![regsub {^git version } $_git_version {} _git_version]} {
 895         catch {wm withdraw .}
 896         tk_messageBox \
 897                 -icon error \
 898                 -type ok \
 899                 -title [mc "git-gui: fatal error"] \
 900                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 901         exit 1
 902 }
 903
 904 proc get_trimmed_version {s} {
 905     set r {}
 906     foreach x [split $s -._] {
 907         if {[string is integer -strict $x]} {
 908             lappend r $x
 909         } else {
 910             break
 911         }
 912     }
 913     return [join $r .]
 914 }
 915 set _real_git_version $_git_version
 916 set _git_version [get_trimmed_version $_git_version]
 917
 918 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 919         catch {wm withdraw .}
 920         if {[tk_messageBox \
 921                 -icon warning \
 922                 -type yesno \
 923                 -default no \
 924                 -title "[appname]: warning" \
 925                  -message [mc "Git version cannot be determined.
 926
 927 %s claims it is version '%s'.
 928
 929 %s requires at least Git 1.5.0 or later.
 930
 931 Assume '%s' is version 1.5.0?
 932 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 933                 set _git_version 1.5.0
 934         } else {
 935                 exit 1
 936         }
 937 }
 938 unset _real_git_version
 939
 940 proc git-version {args} {
 941         global _git_version
 942
 943         switch [llength $args] {
 944         0 {
 945                 return $_git_version
 946         }
 947
 948         2 {
 949                 set op [lindex $args 0]
 950                 set vr [lindex $args 1]
 951                 set cm [package vcompare $_git_version $vr]
 952                 return [expr $cm $op 0]
 953         }
 954
 955         4 {
 956                 set type [lindex $args 0]
 957                 set name [lindex $args 1]
 958                 set parm [lindex $args 2]
 959                 set body [lindex $args 3]
 960
 961                 if {($type ne {proc} && $type ne {method})} {
 962                         error "Invalid arguments to git-version"
 963                 }
 964                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 965                         error "Last arm of $type $name must be default"
 966                 }
 967
 968                 foreach {op vr cb} [lrange $body 0 end-2] {
 969                         if {[git-version $op $vr]} {
 970                                 return [uplevel [list $type $name $parm $cb]]
 971                         }
 972                 }
 973
 974                 return [uplevel [list $type $name $parm [lindex $body end]]]
 975         }
 976
 977         default {
 978                 error "git-version >= x"
 979         }
 980
 981         }
 982 }
 983
 984 if {[git-version < 1.5]} {
 985         catch {wm withdraw .}
 986         tk_messageBox \
 987                 -icon error \
 988                 -type ok \
 989                 -title [mc "git-gui: fatal error"] \
 990                 -message "[appname] requires Git 1.5.0 or later.
 991
 992 You are using [git-version]:
 993
 994 [git --version]"
 995         exit 1
 996 }
 997
 998 ######################################################################
 999 ##
1000 ## configure our library
1001
1002 set idx [file join $oguilib tclIndex]
1003 if {[catch {set fd [open $idx r]} err]} {
1004         catch {wm withdraw .}
1005         tk_messageBox \
1006                 -icon error \
1007                 -type ok \
1008                 -title [mc "git-gui: fatal error"] \
1009                 -message $err
1010         exit 1
1011 }
1012 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1013         set idx [list]
1014         while {[gets $fd n] >= 0} {
1015                 if {$n ne {} && ![string match #* $n]} {
1016                         lappend idx $n
1017                 }
1018         }
1019 } else {
1020         set idx {}
1021 }
1022 close $fd
1023
1024 if {$idx ne {}} {
1025         set loaded [list]
1026         foreach p $idx {
1027                 if {[lsearch -exact $loaded $p] >= 0} continue
1028                 source [file join $oguilib $p]
1029                 lappend loaded $p
1030         }
1031         unset loaded p
1032 } else {
1033         set auto_path [concat [list $oguilib] $auto_path]
1034 }
1035 unset -nocomplain idx fd
1036
1037 ######################################################################
1038 ##
1039 ## config file parsing
1040
1041 git-version proc _parse_config {arr_name args} {
1042         >= 1.5.3 {
1043                 upvar $arr_name arr
1044                 array unset arr
1045                 set buf {}
1046                 catch {
1047                         set fd_rc [eval \
1048                                 [list git_read config] \
1049                                 $args \
1050                                 [list --null --list]]
1051                         fconfigure $fd_rc -translation binary
1052                         set buf [read $fd_rc]
1053                         close $fd_rc
1054                 }
1055                 foreach line [split $buf "\0"] {
1056                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1057                                 if {[is_many_config $name]} {
1058                                         lappend arr($name) $value
1059                                 } else {
1060                                         set arr($name) $value
1061                                 }
1062                         }
1063                 }
1064         }
1065         default {
1066                 upvar $arr_name arr
1067                 array unset arr
1068                 catch {
1069                         set fd_rc [eval [list git_read config --list] $args]
1070                         while {[gets $fd_rc line] >= 0} {
1071                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1072                                         if {[is_many_config $name]} {
1073                                                 lappend arr($name) $value
1074                                         } else {
1075                                                 set arr($name) $value
1076                                         }
1077                                 }
1078                         }
1079                         close $fd_rc
1080                 }
1081         }
1082 }
1083
1084 proc load_config {include_global} {
1085         global repo_config global_config system_config default_config
1086
1087         if {$include_global} {
1088                 _parse_config system_config --system
1089                 _parse_config global_config --global
1090         }
1091         _parse_config repo_config
1092
1093         foreach name [array names default_config] {
1094                 if {[catch {set v $system_config($name)}]} {
1095                         set system_config($name) $default_config($name)
1096                 }
1097         }
1098         foreach name [array names system_config] {
1099                 if {[catch {set v $global_config($name)}]} {
1100                         set global_config($name) $system_config($name)
1101                 }
1102                 if {[catch {set v $repo_config($name)}]} {
1103                         set repo_config($name) $system_config($name)
1104                 }
1105         }
1106 }
1107
1108 ######################################################################
1109 ##
1110 ## feature option selection
1111
1112 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1113         unset _junk
1114 } else {
1115         set subcommand gui
1116 }
1117 if {$subcommand eq {gui.sh}} {
1118         set subcommand gui
1119 }
1120 if {$subcommand eq {gui} && [llength $argv] > 0} {
1121         set subcommand [lindex $argv 0]
1122         set argv [lrange $argv 1 end]
1123 }
1124
1125 enable_option multicommit
1126 enable_option branch
1127 enable_option transport
1128 disable_option bare
1129
1130 switch -- $subcommand {
1131 browser -
1132 blame {
1133         enable_option bare
1134
1135         disable_option multicommit
1136         disable_option branch
1137         disable_option transport
1138 }
1139 citool {
1140         enable_option singlecommit
1141         enable_option retcode
1142
1143         disable_option multicommit
1144         disable_option branch
1145         disable_option transport
1146
1147         while {[llength $argv] > 0} {
1148                 set a [lindex $argv 0]
1149                 switch -- $a {
1150                 --amend {
1151                         enable_option initialamend
1152                 }
1153                 --nocommit {
1154                         enable_option nocommit
1155                         enable_option nocommitmsg
1156                 }
1157                 --commitmsg {
1158                         disable_option nocommitmsg
1159                 }
1160                 default {
1161                         break
1162                 }
1163                 }
1164
1165                 set argv [lrange $argv 1 end]
1166         }
1167 }
1168 }
1169
1170 ######################################################################
1171 ##
1172 ## execution environment
1173
1174 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1175
1176 # Suggest our implementation of askpass, if none is set
1177 if {![info exists env(SSH_ASKPASS)]} {
1178         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1179 }
1180
1181 ######################################################################
1182 ##
1183 ## repository setup
1184
1185 set picked 0
1186 if {[catch {
1187                 set _gitdir $env(GIT_DIR)
1188                 set _prefix {}
1189                 }]
1190         && [catch {
1191                 # beware that from the .git dir this sets _gitdir to .
1192                 # and _prefix to the empty string
1193                 set _gitdir [git rev-parse --git-dir]
1194                 set _prefix [git rev-parse --show-prefix]
1195         } err]} {
1196         load_config 1
1197         apply_config
1198         choose_repository::pick
1199         set picked 1
1200 }
1201
1202 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1203 # run from the .git dir itself) lest the routines to find the worktree
1204 # get confused
1205 if {$_gitdir eq "."} {
1206         set _gitdir [pwd]
1207 }
1208
1209 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1210         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1211 }
1212 if {![file isdirectory $_gitdir]} {
1213         catch {wm withdraw .}
1214         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1215         exit 1
1216 }
1217 # _gitdir exists, so try loading the config
1218 load_config 0
1219 apply_config
1220
1221 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1222 if {[package vsatisfies $_git_version 1.7.0]} {
1223         set _gitworktree [git rev-parse --show-toplevel]
1224 } else {
1225         # try to set work tree from environment, core.worktree or use
1226         # cdup to obtain a relative path to the top of the worktree. If
1227         # run from the top, the ./ prefix ensures normalize expands pwd.
1228         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1229                 set _gitworktree [get_config core.worktree]
1230                 if {$_gitworktree eq ""} {
1231                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1232                 }
1233         }
1234 }
1235
1236 if {$_prefix ne {}} {
1237         if {$_gitworktree eq {}} {
1238                 regsub -all {[^/]+/} $_prefix ../ cdup
1239         } else {
1240                 set cdup $_gitworktree
1241         }
1242         if {[catch {cd $cdup} err]} {
1243                 catch {wm withdraw .}
1244                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1245                 exit 1
1246         }
1247         set _gitworktree [pwd]
1248         unset cdup
1249 } elseif {![is_enabled bare]} {
1250         if {[is_bare]} {
1251                 catch {wm withdraw .}
1252                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1253                 exit 1
1254         }
1255         if {$_gitworktree eq {}} {
1256                 set _gitworktree [file dirname $_gitdir]
1257         }
1258         if {[catch {cd $_gitworktree} err]} {
1259                 catch {wm withdraw .}
1260                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1261                 exit 1
1262         }
1263         set _gitworktree [pwd]
1264 }
1265 set _reponame [file split [file normalize $_gitdir]]
1266 if {[lindex $_reponame end] eq {.git}} {
1267         set _reponame [lindex $_reponame end-1]
1268 } else {
1269         set _reponame [lindex $_reponame end]
1270 }
1271
1272 ######################################################################
1273 ##
1274 ## global init
1275
1276 set current_diff_path {}
1277 set current_diff_side {}
1278 set diff_actions [list]
1279
1280 set HEAD {}
1281 set PARENT {}
1282 set MERGE_HEAD [list]
1283 set commit_type {}
1284 set empty_tree {}
1285 set current_branch {}
1286 set is_detached 0
1287 set current_diff_path {}
1288 set is_3way_diff 0
1289 set is_submodule_diff 0
1290 set is_conflict_diff 0
1291 set selected_commit_type new
1292 set diff_empty_count 0
1293
1294 set nullid "0000000000000000000000000000000000000000"
1295 set nullid2 "0000000000000000000000000000000000000001"
1296
1297 ######################################################################
1298 ##
1299 ## task management
1300
1301 set rescan_active 0
1302 set diff_active 0
1303 set last_clicked {}
1304
1305 set disable_on_lock [list]
1306 set index_lock_type none
1307
1308 proc lock_index {type} {
1309         global index_lock_type disable_on_lock
1310
1311         if {$index_lock_type eq {none}} {
1312                 set index_lock_type $type
1313                 foreach w $disable_on_lock {
1314                         uplevel #0 $w disabled
1315                 }
1316                 return 1
1317         } elseif {$index_lock_type eq "begin-$type"} {
1318                 set index_lock_type $type
1319                 return 1
1320         }
1321         return 0
1322 }
1323
1324 proc unlock_index {} {
1325         global index_lock_type disable_on_lock
1326
1327         set index_lock_type none
1328         foreach w $disable_on_lock {
1329                 uplevel #0 $w normal
1330         }
1331 }
1332
1333 ######################################################################
1334 ##
1335 ## status
1336
1337 proc repository_state {ctvar hdvar mhvar} {
1338         global current_branch
1339         upvar $ctvar ct $hdvar hd $mhvar mh
1340
1341         set mh [list]
1342
1343         load_current_branch
1344         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1345                 set hd {}
1346                 set ct initial
1347                 return
1348         }
1349
1350         set merge_head [gitdir MERGE_HEAD]
1351         if {[file exists $merge_head]} {
1352                 set ct merge
1353                 set fd_mh [open $merge_head r]
1354                 while {[gets $fd_mh line] >= 0} {
1355                         lappend mh $line
1356                 }
1357                 close $fd_mh
1358                 return
1359         }
1360
1361         set ct normal
1362 }
1363
1364 proc PARENT {} {
1365         global PARENT empty_tree
1366
1367         set p [lindex $PARENT 0]
1368         if {$p ne {}} {
1369                 return $p
1370         }
1371         if {$empty_tree eq {}} {
1372                 set empty_tree [git mktree << {}]
1373         }
1374         return $empty_tree
1375 }
1376
1377 proc force_amend {} {
1378         global selected_commit_type
1379         global HEAD PARENT MERGE_HEAD commit_type
1380
1381         repository_state newType newHEAD newMERGE_HEAD
1382         set HEAD $newHEAD
1383         set PARENT $newHEAD
1384         set MERGE_HEAD $newMERGE_HEAD
1385         set commit_type $newType
1386
1387         set selected_commit_type amend
1388         do_select_commit_type
1389 }
1390
1391 proc rescan {after {honor_trustmtime 1}} {
1392         global HEAD PARENT MERGE_HEAD commit_type
1393         global ui_index ui_workdir ui_comm
1394         global rescan_active file_states
1395         global repo_config
1396
1397         if {$rescan_active > 0 || ![lock_index read]} return
1398
1399         repository_state newType newHEAD newMERGE_HEAD
1400         if {[string match amend* $commit_type]
1401                 && $newType eq {normal}
1402                 && $newHEAD eq $HEAD} {
1403         } else {
1404                 set HEAD $newHEAD
1405                 set PARENT $newHEAD
1406                 set MERGE_HEAD $newMERGE_HEAD
1407                 set commit_type $newType
1408         }
1409
1410         array unset file_states
1411
1412         if {!$::GITGUI_BCK_exists &&
1413                 (![$ui_comm edit modified]
1414                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1415                 if {[string match amend* $commit_type]} {
1416                 } elseif {[load_message GITGUI_MSG]} {
1417                 } elseif {[run_prepare_commit_msg_hook]} {
1418                 } elseif {[load_message MERGE_MSG]} {
1419                 } elseif {[load_message SQUASH_MSG]} {
1420                 }
1421                 $ui_comm edit reset
1422                 $ui_comm edit modified false
1423         }
1424
1425         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1426                 rescan_stage2 {} $after
1427         } else {
1428                 set rescan_active 1
1429                 ui_status [mc "Refreshing file status..."]
1430                 set fd_rf [git_read update-index \
1431                         -q \
1432                         --unmerged \
1433                         --ignore-missing \
1434                         --refresh \
1435                         ]
1436                 fconfigure $fd_rf -blocking 0 -translation binary
1437                 fileevent $fd_rf readable \
1438                         [list rescan_stage2 $fd_rf $after]
1439         }
1440 }
1441
1442 if {[is_Cygwin]} {
1443         set is_git_info_exclude {}
1444         proc have_info_exclude {} {
1445                 global is_git_info_exclude
1446
1447                 if {$is_git_info_exclude eq {}} {
1448                         if {[catch {exec test -f [gitdir info exclude]}]} {
1449                                 set is_git_info_exclude 0
1450                         } else {
1451                                 set is_git_info_exclude 1
1452                         }
1453                 }
1454                 return $is_git_info_exclude
1455         }
1456 } else {
1457         proc have_info_exclude {} {
1458                 return [file readable [gitdir info exclude]]
1459         }
1460 }
1461
1462 proc rescan_stage2 {fd after} {
1463         global rescan_active buf_rdi buf_rdf buf_rlo
1464
1465         if {$fd ne {}} {
1466                 read $fd
1467                 if {![eof $fd]} return
1468                 close $fd
1469         }
1470
1471         if {[package vsatisfies $::_git_version 1.6.3]} {
1472                 set ls_others [list --exclude-standard]
1473         } else {
1474                 set ls_others [list --exclude-per-directory=.gitignore]
1475                 if {[have_info_exclude]} {
1476                         lappend ls_others "--exclude-from=[gitdir info exclude]"
1477                 }
1478                 set user_exclude [get_config core.excludesfile]
1479                 if {$user_exclude ne {} && [file readable $user_exclude]} {
1480                         lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1481                 }
1482         }
1483
1484         set buf_rdi {}
1485         set buf_rdf {}
1486         set buf_rlo {}
1487
1488         set rescan_active 3
1489         ui_status [mc "Scanning for modified files ..."]
1490         set fd_di [git_read diff-index --cached -z [PARENT]]
1491         set fd_df [git_read diff-files -z]
1492         set fd_lo [eval git_read ls-files --others -z $ls_others]
1493
1494         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1495         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1496         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1497         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1498         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1499         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1500 }
1501
1502 proc load_message {file} {
1503         global ui_comm
1504
1505         set f [gitdir $file]
1506         if {[file isfile $f]} {
1507                 if {[catch {set fd [open $f r]}]} {
1508                         return 0
1509                 }
1510                 fconfigure $fd -eofchar {}
1511                 set content [string trim [read $fd]]
1512                 close $fd
1513                 regsub -all -line {[ \r\t]+$} $content {} content
1514                 $ui_comm delete 0.0 end
1515                 $ui_comm insert end $content
1516                 return 1
1517         }
1518         return 0
1519 }
1520
1521 proc run_prepare_commit_msg_hook {} {
1522         global pch_error
1523
1524         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1525         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1526         # empty file but existant file.
1527
1528         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1529
1530         if {[file isfile [gitdir MERGE_MSG]]} {
1531                 set pcm_source "merge"
1532                 set fd_mm [open [gitdir MERGE_MSG] r]
1533                 puts -nonewline $fd_pcm [read $fd_mm]
1534                 close $fd_mm
1535         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1536                 set pcm_source "squash"
1537                 set fd_sm [open [gitdir SQUASH_MSG] r]
1538                 puts -nonewline $fd_pcm [read $fd_sm]
1539                 close $fd_sm
1540         } else {
1541                 set pcm_source ""
1542         }
1543
1544         close $fd_pcm
1545
1546         set fd_ph [githook_read prepare-commit-msg \
1547                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1548         if {$fd_ph eq {}} {
1549                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1550                 return 0;
1551         }
1552
1553         ui_status [mc "Calling prepare-commit-msg hook..."]
1554         set pch_error {}
1555
1556         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1557         fileevent $fd_ph readable \
1558                 [list prepare_commit_msg_hook_wait $fd_ph]
1559
1560         return 1;
1561 }
1562
1563 proc prepare_commit_msg_hook_wait {fd_ph} {
1564         global pch_error
1565
1566         append pch_error [read $fd_ph]
1567         fconfigure $fd_ph -blocking 1
1568         if {[eof $fd_ph]} {
1569                 if {[catch {close $fd_ph}]} {
1570                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1571                         hook_failed_popup prepare-commit-msg $pch_error
1572                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1573                         exit 1
1574                 } else {
1575                         load_message PREPARE_COMMIT_MSG
1576                 }
1577                 set pch_error {}
1578                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1579                 return
1580         }
1581         fconfigure $fd_ph -blocking 0
1582         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1583 }
1584
1585 proc read_diff_index {fd after} {
1586         global buf_rdi
1587
1588         append buf_rdi [read $fd]
1589         set c 0
1590         set n [string length $buf_rdi]
1591         while {$c < $n} {
1592                 set z1 [string first "\0" $buf_rdi $c]
1593                 if {$z1 == -1} break
1594                 incr z1
1595                 set z2 [string first "\0" $buf_rdi $z1]
1596                 if {$z2 == -1} break
1597
1598                 incr c
1599                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1600                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1601                 merge_state \
1602                         [encoding convertfrom $p] \
1603                         [lindex $i 4]? \
1604                         [list [lindex $i 0] [lindex $i 2]] \
1605                         [list]
1606                 set c $z2
1607                 incr c
1608         }
1609         if {$c < $n} {
1610                 set buf_rdi [string range $buf_rdi $c end]
1611         } else {
1612                 set buf_rdi {}
1613         }
1614
1615         rescan_done $fd buf_rdi $after
1616 }
1617
1618 proc read_diff_files {fd after} {
1619         global buf_rdf
1620
1621         append buf_rdf [read $fd]
1622         set c 0
1623         set n [string length $buf_rdf]
1624         while {$c < $n} {
1625                 set z1 [string first "\0" $buf_rdf $c]
1626                 if {$z1 == -1} break
1627                 incr z1
1628                 set z2 [string first "\0" $buf_rdf $z1]
1629                 if {$z2 == -1} break
1630
1631                 incr c
1632                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1633                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1634                 merge_state \
1635                         [encoding convertfrom $p] \
1636                         ?[lindex $i 4] \
1637                         [list] \
1638                         [list [lindex $i 0] [lindex $i 2]]
1639                 set c $z2
1640                 incr c
1641         }
1642         if {$c < $n} {
1643                 set buf_rdf [string range $buf_rdf $c end]
1644         } else {
1645                 set buf_rdf {}
1646         }
1647
1648         rescan_done $fd buf_rdf $after
1649 }
1650
1651 proc read_ls_others {fd after} {
1652         global buf_rlo
1653
1654         append buf_rlo [read $fd]
1655         set pck [split $buf_rlo "\0"]
1656         set buf_rlo [lindex $pck end]
1657         foreach p [lrange $pck 0 end-1] {
1658                 set p [encoding convertfrom $p]
1659                 if {[string index $p end] eq {/}} {
1660                         set p [string range $p 0 end-1]
1661                 }
1662                 merge_state $p ?O
1663         }
1664         rescan_done $fd buf_rlo $after
1665 }
1666
1667 proc rescan_done {fd buf after} {
1668         global rescan_active current_diff_path
1669         global file_states repo_config
1670         upvar $buf to_clear
1671
1672         if {![eof $fd]} return
1673         set to_clear {}
1674         close $fd
1675         if {[incr rescan_active -1] > 0} return
1676
1677         prune_selection
1678         unlock_index
1679         display_all_files
1680         if {$current_diff_path ne {}} { reshow_diff $after }
1681         if {$current_diff_path eq {}} { select_first_diff $after }
1682 }
1683
1684 proc prune_selection {} {
1685         global file_states selected_paths
1686
1687         foreach path [array names selected_paths] {
1688                 if {[catch {set still_here $file_states($path)}]} {
1689                         unset selected_paths($path)
1690                 }
1691         }
1692 }
1693
1694 ######################################################################
1695 ##
1696 ## ui helpers
1697
1698 proc mapicon {w state path} {
1699         global all_icons
1700
1701         if {[catch {set r $all_icons($state$w)}]} {
1702                 puts "error: no icon for $w state={$state} $path"
1703                 return file_plain
1704         }
1705         return $r
1706 }
1707
1708 proc mapdesc {state path} {
1709         global all_descs
1710
1711         if {[catch {set r $all_descs($state)}]} {
1712                 puts "error: no desc for state={$state} $path"
1713                 return $state
1714         }
1715         return $r
1716 }
1717
1718 proc ui_status {msg} {
1719         global main_status
1720         if {[info exists main_status]} {
1721                 $main_status show $msg
1722         }
1723 }
1724
1725 proc ui_ready {{test {}}} {
1726         global main_status
1727         if {[info exists main_status]} {
1728                 $main_status show [mc "Ready."] $test
1729         }
1730 }
1731
1732 proc escape_path {path} {
1733         regsub -all {\\} $path "\\\\" path
1734         regsub -all "\n" $path "\\n" path
1735         return $path
1736 }
1737
1738 proc short_path {path} {
1739         return [escape_path [lindex [file split $path] end]]
1740 }
1741
1742 set next_icon_id 0
1743 set null_sha1 [string repeat 0 40]
1744
1745 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1746         global file_states next_icon_id null_sha1
1747
1748         set s0 [string index $new_state 0]
1749         set s1 [string index $new_state 1]
1750
1751         if {[catch {set info $file_states($path)}]} {
1752                 set state __
1753                 set icon n[incr next_icon_id]
1754         } else {
1755                 set state [lindex $info 0]
1756                 set icon [lindex $info 1]
1757                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1758                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1759         }
1760
1761         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1762         elseif {$s0 eq {_}} {set s0 _}
1763
1764         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1765         elseif {$s1 eq {_}} {set s1 _}
1766
1767         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1768                 set head_info [list 0 $null_sha1]
1769         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1770                 && $head_info eq {}} {
1771                 set head_info $index_info
1772         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1773                 set index_info $head_info
1774                 set head_info {}
1775         }
1776
1777         set file_states($path) [list $s0$s1 $icon \
1778                 $head_info $index_info \
1779                 ]
1780         return $state
1781 }
1782
1783 proc display_file_helper {w path icon_name old_m new_m} {
1784         global file_lists
1785
1786         if {$new_m eq {_}} {
1787                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1788                 if {$lno >= 0} {
1789                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1790                         incr lno
1791                         $w conf -state normal
1792                         $w delete $lno.0 [expr {$lno + 1}].0
1793                         $w conf -state disabled
1794                 }
1795         } elseif {$old_m eq {_} && $new_m ne {_}} {
1796                 lappend file_lists($w) $path
1797                 set file_lists($w) [lsort -unique $file_lists($w)]
1798                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1799                 incr lno
1800                 $w conf -state normal
1801                 $w image create $lno.0 \
1802                         -align center -padx 5 -pady 1 \
1803                         -name $icon_name \
1804                         -image [mapicon $w $new_m $path]
1805                 $w insert $lno.1 "[escape_path $path]\n"
1806                 $w conf -state disabled
1807         } elseif {$old_m ne $new_m} {
1808                 $w conf -state normal
1809                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1810                 $w conf -state disabled
1811         }
1812 }
1813
1814 proc display_file {path state} {
1815         global file_states selected_paths
1816         global ui_index ui_workdir
1817
1818         set old_m [merge_state $path $state]
1819         set s $file_states($path)
1820         set new_m [lindex $s 0]
1821         set icon_name [lindex $s 1]
1822
1823         set o [string index $old_m 0]
1824         set n [string index $new_m 0]
1825         if {$o eq {U}} {
1826                 set o _
1827         }
1828         if {$n eq {U}} {
1829                 set n _
1830         }
1831         display_file_helper     $ui_index $path $icon_name $o $n
1832
1833         if {[string index $old_m 0] eq {U}} {
1834                 set o U
1835         } else {
1836                 set o [string index $old_m 1]
1837         }
1838         if {[string index $new_m 0] eq {U}} {
1839                 set n U
1840         } else {
1841                 set n [string index $new_m 1]
1842         }
1843         display_file_helper     $ui_workdir $path $icon_name $o $n
1844
1845         if {$new_m eq {__}} {
1846                 unset file_states($path)
1847                 catch {unset selected_paths($path)}
1848         }
1849 }
1850
1851 proc display_all_files_helper {w path icon_name m} {
1852         global file_lists
1853
1854         lappend file_lists($w) $path
1855         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1856         $w image create end \
1857                 -align center -padx 5 -pady 1 \
1858                 -name $icon_name \
1859                 -image [mapicon $w $m $path]
1860         $w insert end "[escape_path $path]\n"
1861 }
1862
1863 set files_warning 0
1864 proc display_all_files {} {
1865         global ui_index ui_workdir
1866         global file_states file_lists
1867         global last_clicked
1868         global files_warning
1869
1870         $ui_index conf -state normal
1871         $ui_workdir conf -state normal
1872
1873         $ui_index delete 0.0 end
1874         $ui_workdir delete 0.0 end
1875         set last_clicked {}
1876
1877         set file_lists($ui_index) [list]
1878         set file_lists($ui_workdir) [list]
1879
1880         set to_display [lsort [array names file_states]]
1881         set display_limit [get_config gui.maxfilesdisplayed]
1882         if {[llength $to_display] > $display_limit} {
1883                 if {!$files_warning} {
1884                         # do not repeatedly warn:
1885                         set files_warning 1
1886                         info_popup [mc "Displaying only %s of %s files." \
1887                                 $display_limit [llength $to_display]]
1888                 }
1889                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1890         }
1891         foreach path $to_display {
1892                 set s $file_states($path)
1893                 set m [lindex $s 0]
1894                 set icon_name [lindex $s 1]
1895
1896                 set s [string index $m 0]
1897                 if {$s ne {U} && $s ne {_}} {
1898                         display_all_files_helper $ui_index $path \
1899                                 $icon_name $s
1900                 }
1901
1902                 if {[string index $m 0] eq {U}} {
1903                         set s U
1904                 } else {
1905                         set s [string index $m 1]
1906                 }
1907                 if {$s ne {_}} {
1908                         display_all_files_helper $ui_workdir $path \
1909                                 $icon_name $s
1910                 }
1911         }
1912
1913         $ui_index conf -state disabled
1914         $ui_workdir conf -state disabled
1915 }
1916
1917 ######################################################################
1918 ##
1919 ## icons
1920
1921 set filemask {
1922 #define mask_width 14
1923 #define mask_height 15
1924 static unsigned char mask_bits[] = {
1925    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1926    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1927    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1928 }
1929
1930 image create bitmap file_plain -background white -foreground black -data {
1931 #define plain_width 14
1932 #define plain_height 15
1933 static unsigned char plain_bits[] = {
1934    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1935    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1936    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1937 } -maskdata $filemask
1938
1939 image create bitmap file_mod -background white -foreground blue -data {
1940 #define mod_width 14
1941 #define mod_height 15
1942 static unsigned char mod_bits[] = {
1943    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1944    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1945    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1946 } -maskdata $filemask
1947
1948 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1949 #define file_fulltick_width 14
1950 #define file_fulltick_height 15
1951 static unsigned char file_fulltick_bits[] = {
1952    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1953    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1954    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1955 } -maskdata $filemask
1956
1957 image create bitmap file_question -background white -foreground black -data {
1958 #define file_question_width 14
1959 #define file_question_height 15
1960 static unsigned char file_question_bits[] = {
1961    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1962    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1963    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1964 } -maskdata $filemask
1965
1966 image create bitmap file_removed -background white -foreground red -data {
1967 #define file_removed_width 14
1968 #define file_removed_height 15
1969 static unsigned char file_removed_bits[] = {
1970    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1971    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1972    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1973 } -maskdata $filemask
1974
1975 image create bitmap file_merge -background white -foreground blue -data {
1976 #define file_merge_width 14
1977 #define file_merge_height 15
1978 static unsigned char file_merge_bits[] = {
1979    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1980    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1981    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1982 } -maskdata $filemask
1983
1984 image create bitmap file_statechange -background white -foreground green -data {
1985 #define file_statechange_width 14
1986 #define file_statechange_height 15
1987 static unsigned char file_statechange_bits[] = {
1988    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1989    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1990    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1991 } -maskdata $filemask
1992
1993 set ui_index .vpane.files.index.list
1994 set ui_workdir .vpane.files.workdir.list
1995
1996 set all_icons(_$ui_index)   file_plain
1997 set all_icons(A$ui_index)   file_plain
1998 set all_icons(M$ui_index)   file_fulltick
1999 set all_icons(D$ui_index)   file_removed
2000 set all_icons(U$ui_index)   file_merge
2001 set all_icons(T$ui_index)   file_statechange
2002
2003 set all_icons(_$ui_workdir) file_plain
2004 set all_icons(M$ui_workdir) file_mod
2005 set all_icons(D$ui_workdir) file_question
2006 set all_icons(U$ui_workdir) file_merge
2007 set all_icons(O$ui_workdir) file_plain
2008 set all_icons(T$ui_workdir) file_statechange
2009
2010 set max_status_desc 0
2011 foreach i {
2012                 {__ {mc "Unmodified"}}
2013
2014                 {_M {mc "Modified, not staged"}}
2015                 {M_ {mc "Staged for commit"}}
2016                 {MM {mc "Portions staged for commit"}}
2017                 {MD {mc "Staged for commit, missing"}}
2018
2019                 {_T {mc "File type changed, not staged"}}
2020                 {MT {mc "File type changed, old type staged for commit"}}
2021                 {AT {mc "File type changed, old type staged for commit"}}
2022                 {T_ {mc "File type changed, staged"}}
2023                 {TM {mc "File type change staged, modification not staged"}}
2024                 {TD {mc "File type change staged, file missing"}}
2025
2026                 {_O {mc "Untracked, not staged"}}
2027                 {A_ {mc "Staged for commit"}}
2028                 {AM {mc "Portions staged for commit"}}
2029                 {AD {mc "Staged for commit, missing"}}
2030
2031                 {_D {mc "Missing"}}
2032                 {D_ {mc "Staged for removal"}}
2033                 {DO {mc "Staged for removal, still present"}}
2034
2035                 {_U {mc "Requires merge resolution"}}
2036                 {U_ {mc "Requires merge resolution"}}
2037                 {UU {mc "Requires merge resolution"}}
2038                 {UM {mc "Requires merge resolution"}}
2039                 {UD {mc "Requires merge resolution"}}
2040                 {UT {mc "Requires merge resolution"}}
2041         } {
2042         set text [eval [lindex $i 1]]
2043         if {$max_status_desc < [string length $text]} {
2044                 set max_status_desc [string length $text]
2045         }
2046         set all_descs([lindex $i 0]) $text
2047 }
2048 unset i
2049
2050 ######################################################################
2051 ##
2052 ## util
2053
2054 proc scrollbar2many {list mode args} {
2055         foreach w $list {eval $w $mode $args}
2056 }
2057
2058 proc many2scrollbar {list mode sb top bottom} {
2059         $sb set $top $bottom
2060         foreach w $list {$w $mode moveto $top}
2061 }
2062
2063 proc incr_font_size {font {amt 1}} {
2064         set sz [font configure $font -size]
2065         incr sz $amt
2066         font configure $font -size $sz
2067         font configure ${font}bold -size $sz
2068         font configure ${font}italic -size $sz
2069 }
2070
2071 ######################################################################
2072 ##
2073 ## ui commands
2074
2075 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2076
2077 proc do_gitk {revs {is_submodule false}} {
2078         global current_diff_path file_states current_diff_side ui_index
2079         global _gitworktree
2080
2081         # -- Always start gitk through whatever we were loaded with.  This
2082         #    lets us bypass using shell process on Windows systems.
2083         #
2084         set exe [_which gitk -script]
2085         set cmd [list [info nameofexecutable] $exe]
2086         if {$exe eq {}} {
2087                 error_popup [mc "Couldn't find gitk in PATH"]
2088         } else {
2089                 global env
2090
2091                 if {[info exists env(GIT_DIR)]} {
2092                         set old_GIT_DIR $env(GIT_DIR)
2093                 } else {
2094                         set old_GIT_DIR {}
2095                 }
2096
2097                 set pwd [pwd]
2098
2099                 if {!$is_submodule} {
2100                         if {![is_bare]} {
2101                                 cd $_gitworktree
2102                         }
2103                         set env(GIT_DIR) [file normalize [gitdir]]
2104                 } else {
2105                         cd $current_diff_path
2106                         if {$revs eq {--}} {
2107                                 set s $file_states($current_diff_path)
2108                                 set old_sha1 {}
2109                                 set new_sha1 {}
2110                                 switch -glob -- [lindex $s 0] {
2111                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2112                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2113                                 MM {
2114                                         if {$current_diff_side eq $ui_index} {
2115                                                 set old_sha1 [lindex [lindex $s 2] 1]
2116                                                 set new_sha1 [lindex [lindex $s 3] 1]
2117                                         } else {
2118                                                 set old_sha1 [lindex [lindex $s 3] 1]
2119                                         }
2120                                 }
2121                                 }
2122                                 set revs $old_sha1...$new_sha1
2123                         }
2124                         if {[info exists env(GIT_DIR)]} {
2125                                 unset env(GIT_DIR)
2126                         }
2127                 }
2128                 eval exec $cmd $revs "--" "--" &
2129
2130                 if {$old_GIT_DIR ne {}} {
2131                         set env(GIT_DIR) $old_GIT_DIR
2132                 }
2133                 cd $pwd
2134
2135                 ui_status $::starting_gitk_msg
2136                 after 10000 {
2137                         ui_ready $starting_gitk_msg
2138                 }
2139         }
2140 }
2141
2142 proc do_git_gui {} {
2143         global current_diff_path
2144
2145         # -- Always start git gui through whatever we were loaded with.  This
2146         #    lets us bypass using shell process on Windows systems.
2147         #
2148         set exe [list [_which git]]
2149         if {$exe eq {}} {
2150                 error_popup [mc "Couldn't find git gui in PATH"]
2151         } else {
2152                 global env
2153
2154                 if {[info exists env(GIT_DIR)]} {
2155                         set old_GIT_DIR $env(GIT_DIR)
2156                         unset env(GIT_DIR)
2157                 } else {
2158                         set old_GIT_DIR {}
2159                 }
2160
2161                 set pwd [pwd]
2162                 cd $current_diff_path
2163
2164                 eval exec $exe gui &
2165
2166                 if {$old_GIT_DIR ne {}} {
2167                         set env(GIT_DIR) $old_GIT_DIR
2168                 }
2169                 cd $pwd
2170
2171                 ui_status $::starting_gitk_msg
2172                 after 10000 {
2173                         ui_ready $starting_gitk_msg
2174                 }
2175         }
2176 }
2177
2178 proc do_explore {} {
2179         global _gitworktree
2180         set explorer {}
2181         if {[is_Cygwin] || [is_Windows]} {
2182                 set explorer "explorer.exe"
2183         } elseif {[is_MacOSX]} {
2184                 set explorer "open"
2185         } else {
2186                 # freedesktop.org-conforming system is our best shot
2187                 set explorer "xdg-open"
2188         }
2189         eval exec $explorer [list [file nativename $_gitworktree]] &
2190 }
2191
2192 set is_quitting 0
2193 set ret_code    1
2194
2195 proc terminate_me {win} {
2196         global ret_code
2197         if {$win ne {.}} return
2198         exit $ret_code
2199 }
2200
2201 proc do_quit {{rc {1}}} {
2202         global ui_comm is_quitting repo_config commit_type
2203         global GITGUI_BCK_exists GITGUI_BCK_i
2204         global ui_comm_spell
2205         global ret_code use_ttk
2206
2207         if {$is_quitting} return
2208         set is_quitting 1
2209
2210         if {[winfo exists $ui_comm]} {
2211                 # -- Stash our current commit buffer.
2212                 #
2213                 set save [gitdir GITGUI_MSG]
2214                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2215                         file rename -force [gitdir GITGUI_BCK] $save
2216                         set GITGUI_BCK_exists 0
2217                 } else {
2218                         set msg [string trim [$ui_comm get 0.0 end]]
2219                         regsub -all -line {[ \r\t]+$} $msg {} msg
2220                         if {(![string match amend* $commit_type]
2221                                 || [$ui_comm edit modified])
2222                                 && $msg ne {}} {
2223                                 catch {
2224                                         set fd [open $save w]
2225                                         puts -nonewline $fd $msg
2226                                         close $fd
2227                                 }
2228                         } else {
2229                                 catch {file delete $save}
2230                         }
2231                 }
2232
2233                 # -- Cancel our spellchecker if its running.
2234                 #
2235                 if {[info exists ui_comm_spell]} {
2236                         $ui_comm_spell stop
2237                 }
2238
2239                 # -- Remove our editor backup, its not needed.
2240                 #
2241                 after cancel $GITGUI_BCK_i
2242                 if {$GITGUI_BCK_exists} {
2243                         catch {file delete [gitdir GITGUI_BCK]}
2244                 }
2245
2246                 # -- Stash our current window geometry into this repository.
2247                 #
2248                 set cfg_wmstate [wm state .]
2249                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2250                         set rc_wmstate {}
2251                 }
2252                 if {$cfg_wmstate ne $rc_wmstate} {
2253                         catch {git config gui.wmstate $cfg_wmstate}
2254                 }
2255                 if {$cfg_wmstate eq {zoomed}} {
2256                         # on Windows wm geometry will lie about window
2257                         # position (but not size) when window is zoomed
2258                         # restore the window before querying wm geometry
2259                         wm state . normal
2260                 }
2261                 set cfg_geometry [list]
2262                 lappend cfg_geometry [wm geometry .]
2263                 if {$use_ttk} {
2264                         lappend cfg_geometry [.vpane sashpos 0]
2265                         lappend cfg_geometry [.vpane.files sashpos 0]
2266                 } else {
2267                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2268                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2269                 }
2270                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2271                         set rc_geometry {}
2272                 }
2273                 if {$cfg_geometry ne $rc_geometry} {
2274                         catch {git config gui.geometry $cfg_geometry}
2275                 }
2276         }
2277
2278         set ret_code $rc
2279
2280         # Briefly enable send again, working around Tk bug
2281         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2282         tk appname [appname]
2283
2284         destroy .
2285 }
2286
2287 proc do_rescan {} {
2288         rescan ui_ready
2289 }
2290
2291 proc ui_do_rescan {} {
2292         rescan {force_first_diff ui_ready}
2293 }
2294
2295 proc do_commit {} {
2296         commit_tree
2297 }
2298
2299 proc next_diff {{after {}}} {
2300         global next_diff_p next_diff_w next_diff_i
2301         show_diff $next_diff_p $next_diff_w {} {} $after
2302 }
2303
2304 proc find_anchor_pos {lst name} {
2305         set lid [lsearch -sorted -exact $lst $name]
2306
2307         if {$lid == -1} {
2308                 set lid 0
2309                 foreach lname $lst {
2310                         if {$lname >= $name} break
2311                         incr lid
2312                 }
2313         }
2314
2315         return $lid
2316 }
2317
2318 proc find_file_from {flist idx delta path mmask} {
2319         global file_states
2320
2321         set len [llength $flist]
2322         while {$idx >= 0 && $idx < $len} {
2323                 set name [lindex $flist $idx]
2324
2325                 if {$name ne $path && [info exists file_states($name)]} {
2326                         set state [lindex $file_states($name) 0]
2327
2328                         if {$mmask eq {} || [regexp $mmask $state]} {
2329                                 return $idx
2330                         }
2331                 }
2332
2333                 incr idx $delta
2334         }
2335
2336         return {}
2337 }
2338
2339 proc find_next_diff {w path {lno {}} {mmask {}}} {
2340         global next_diff_p next_diff_w next_diff_i
2341         global file_lists ui_index ui_workdir
2342
2343         set flist $file_lists($w)
2344         if {$lno eq {}} {
2345                 set lno [find_anchor_pos $flist $path]
2346         } else {
2347                 incr lno -1
2348         }
2349
2350         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2351                 if {$w eq $ui_index} {
2352                         set mmask "^$mmask"
2353                 } else {
2354                         set mmask "$mmask\$"
2355                 }
2356         }
2357
2358         set idx [find_file_from $flist $lno 1 $path $mmask]
2359         if {$idx eq {}} {
2360                 incr lno -1
2361                 set idx [find_file_from $flist $lno -1 $path $mmask]
2362         }
2363
2364         if {$idx ne {}} {
2365                 set next_diff_w $w
2366                 set next_diff_p [lindex $flist $idx]
2367                 set next_diff_i [expr {$idx+1}]
2368                 return 1
2369         } else {
2370                 return 0
2371         }
2372 }
2373
2374 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2375         global current_diff_path
2376
2377         if {$path ne $current_diff_path} {
2378                 return {}
2379         } elseif {[find_next_diff $w $path $lno $mmask]} {
2380                 return {next_diff;}
2381         } else {
2382                 return {reshow_diff;}
2383         }
2384 }
2385
2386 proc select_first_diff {after} {
2387         global ui_workdir
2388
2389         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2390             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2391                 next_diff $after
2392         } else {
2393                 uplevel #0 $after
2394         }
2395 }
2396
2397 proc force_first_diff {after} {
2398         global ui_workdir current_diff_path file_states
2399
2400         if {[info exists file_states($current_diff_path)]} {
2401                 set state [lindex $file_states($current_diff_path) 0]
2402         } else {
2403                 set state {OO}
2404         }
2405
2406         set reselect 0
2407         if {[string first {U} $state] >= 0} {
2408                 # Already a conflict, do nothing
2409         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2410                 set reselect 1
2411         } elseif {[string index $state 1] ne {O}} {
2412                 # Already a diff & no conflicts, do nothing
2413         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2414                 set reselect 1
2415         }
2416
2417         if {$reselect} {
2418                 next_diff $after
2419         } else {
2420                 uplevel #0 $after
2421         }
2422 }
2423
2424 proc toggle_or_diff {w x y} {
2425         global file_states file_lists current_diff_path ui_index ui_workdir
2426         global last_clicked selected_paths
2427
2428         set pos [split [$w index @$x,$y] .]
2429         set lno [lindex $pos 0]
2430         set col [lindex $pos 1]
2431         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2432         if {$path eq {}} {
2433                 set last_clicked {}
2434                 return
2435         }
2436
2437         set last_clicked [list $w $lno]
2438         array unset selected_paths
2439         $ui_index tag remove in_sel 0.0 end
2440         $ui_workdir tag remove in_sel 0.0 end
2441
2442         # Determine the state of the file
2443         if {[info exists file_states($path)]} {
2444                 set state [lindex $file_states($path) 0]
2445         } else {
2446                 set state {__}
2447         }
2448
2449         # Restage the file, or simply show the diff
2450         if {$col == 0 && $y > 1} {
2451                 # Conflicts need special handling
2452                 if {[string first {U} $state] >= 0} {
2453                         # $w must always be $ui_workdir, but...
2454                         if {$w ne $ui_workdir} { set lno {} }
2455                         merge_stage_workdir $path $lno
2456                         return
2457                 }
2458
2459                 if {[string index $state 1] eq {O}} {
2460                         set mmask {}
2461                 } else {
2462                         set mmask {[^O]}
2463                 }
2464
2465                 set after [next_diff_after_action $w $path $lno $mmask]
2466
2467                 if {$w eq $ui_index} {
2468                         update_indexinfo \
2469                                 "Unstaging [short_path $path] from commit" \
2470                                 [list $path] \
2471                                 [concat $after [list ui_ready]]
2472                 } elseif {$w eq $ui_workdir} {
2473                         update_index \
2474                                 "Adding [short_path $path]" \
2475                                 [list $path] \
2476                                 [concat $after [list ui_ready]]
2477                 }
2478         } else {
2479                 show_diff $path $w $lno
2480         }
2481 }
2482
2483 proc add_one_to_selection {w x y} {
2484         global file_lists last_clicked selected_paths
2485
2486         set lno [lindex [split [$w index @$x,$y] .] 0]
2487         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2488         if {$path eq {}} {
2489                 set last_clicked {}
2490                 return
2491         }
2492
2493         if {$last_clicked ne {}
2494                 && [lindex $last_clicked 0] ne $w} {
2495                 array unset selected_paths
2496                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2497         }
2498
2499         set last_clicked [list $w $lno]
2500         if {[catch {set in_sel $selected_paths($path)}]} {
2501                 set in_sel 0
2502         }
2503         if {$in_sel} {
2504                 unset selected_paths($path)
2505                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2506         } else {
2507                 set selected_paths($path) 1
2508                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2509         }
2510 }
2511
2512 proc add_range_to_selection {w x y} {
2513         global file_lists last_clicked selected_paths
2514
2515         if {[lindex $last_clicked 0] ne $w} {
2516                 toggle_or_diff $w $x $y
2517                 return
2518         }
2519
2520         set lno [lindex [split [$w index @$x,$y] .] 0]
2521         set lc [lindex $last_clicked 1]
2522         if {$lc < $lno} {
2523                 set begin $lc
2524                 set end $lno
2525         } else {
2526                 set begin $lno
2527                 set end $lc
2528         }
2529
2530         foreach path [lrange $file_lists($w) \
2531                 [expr {$begin - 1}] \
2532                 [expr {$end - 1}]] {
2533                 set selected_paths($path) 1
2534         }
2535         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2536 }
2537
2538 proc show_more_context {} {
2539         global repo_config
2540         if {$repo_config(gui.diffcontext) < 99} {
2541                 incr repo_config(gui.diffcontext)
2542                 reshow_diff
2543         }
2544 }
2545
2546 proc show_less_context {} {
2547         global repo_config
2548         if {$repo_config(gui.diffcontext) > 1} {
2549                 incr repo_config(gui.diffcontext) -1
2550                 reshow_diff
2551         }
2552 }
2553
2554 ######################################################################
2555 ##
2556 ## ui construction
2557
2558 set ui_comm {}
2559
2560 # -- Menu Bar
2561 #
2562 menu .mbar -tearoff 0
2563 if {[is_MacOSX]} {
2564         # -- Apple Menu (Mac OS X only)
2565         #
2566         .mbar add cascade -label Apple -menu .mbar.apple
2567         menu .mbar.apple
2568 }
2569 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2570 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2571 if {[is_enabled branch]} {
2572         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2573 }
2574 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2575         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2576 }
2577 if {[is_enabled transport]} {
2578         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2579         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2580 }
2581 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2582         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2583 }
2584
2585 # -- Repository Menu
2586 #
2587 menu .mbar.repository
2588
2589 if {![is_bare]} {
2590         .mbar.repository add command \
2591                 -label [mc "Explore Working Copy"] \
2592                 -command {do_explore}
2593         .mbar.repository add separator
2594 }
2595
2596 .mbar.repository add command \
2597         -label [mc "Browse Current Branch's Files"] \
2598         -command {browser::new $current_branch}
2599 set ui_browse_current [.mbar.repository index last]
2600 .mbar.repository add command \
2601         -label [mc "Browse Branch Files..."] \
2602         -command browser_open::dialog
2603 .mbar.repository add separator
2604
2605 .mbar.repository add command \
2606         -label [mc "Visualize Current Branch's History"] \
2607         -command {do_gitk $current_branch}
2608 set ui_visualize_current [.mbar.repository index last]
2609 .mbar.repository add command \
2610         -label [mc "Visualize All Branch History"] \
2611         -command {do_gitk --all}
2612 .mbar.repository add separator
2613
2614 proc current_branch_write {args} {
2615         global current_branch
2616         .mbar.repository entryconf $::ui_browse_current \
2617                 -label [mc "Browse %s's Files" $current_branch]
2618         .mbar.repository entryconf $::ui_visualize_current \
2619                 -label [mc "Visualize %s's History" $current_branch]
2620 }
2621 trace add variable current_branch write current_branch_write
2622
2623 if {[is_enabled multicommit]} {
2624         .mbar.repository add command -label [mc "Database Statistics"] \
2625                 -command do_stats
2626
2627         .mbar.repository add command -label [mc "Compress Database"] \
2628                 -command do_gc
2629
2630         .mbar.repository add command -label [mc "Verify Database"] \
2631                 -command do_fsck_objects
2632
2633         .mbar.repository add separator
2634
2635         if {[is_Cygwin]} {
2636                 .mbar.repository add command \
2637                         -label [mc "Create Desktop Icon"] \
2638                         -command do_cygwin_shortcut
2639         } elseif {[is_Windows]} {
2640                 .mbar.repository add command \
2641                         -label [mc "Create Desktop Icon"] \
2642                         -command do_windows_shortcut
2643         } elseif {[is_MacOSX]} {
2644                 .mbar.repository add command \
2645                         -label [mc "Create Desktop Icon"] \
2646                         -command do_macosx_app
2647         }
2648 }
2649
2650 if {[is_MacOSX]} {
2651         proc ::tk::mac::Quit {args} { do_quit }
2652 } else {
2653         .mbar.repository add command -label [mc Quit] \
2654                 -command do_quit \
2655                 -accelerator $M1T-Q
2656 }
2657
2658 # -- Edit Menu
2659 #
2660 menu .mbar.edit
2661 .mbar.edit add command -label [mc Undo] \
2662         -command {catch {[focus] edit undo}} \
2663         -accelerator $M1T-Z
2664 .mbar.edit add command -label [mc Redo] \
2665         -command {catch {[focus] edit redo}} \
2666         -accelerator $M1T-Y
2667 .mbar.edit add separator
2668 .mbar.edit add command -label [mc Cut] \
2669         -command {catch {tk_textCut [focus]}} \
2670         -accelerator $M1T-X
2671 .mbar.edit add command -label [mc Copy] \
2672         -command {catch {tk_textCopy [focus]}} \
2673         -accelerator $M1T-C
2674 .mbar.edit add command -label [mc Paste] \
2675         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2676         -accelerator $M1T-V
2677 .mbar.edit add command -label [mc Delete] \
2678         -command {catch {[focus] delete sel.first sel.last}} \
2679         -accelerator Del
2680 .mbar.edit add separator
2681 .mbar.edit add command -label [mc "Select All"] \
2682         -command {catch {[focus] tag add sel 0.0 end}} \
2683         -accelerator $M1T-A
2684
2685 # -- Branch Menu
2686 #
2687 if {[is_enabled branch]} {
2688         menu .mbar.branch
2689
2690         .mbar.branch add command -label [mc "Create..."] \
2691                 -command branch_create::dialog \
2692                 -accelerator $M1T-N
2693         lappend disable_on_lock [list .mbar.branch entryconf \
2694                 [.mbar.branch index last] -state]
2695
2696         .mbar.branch add command -label [mc "Checkout..."] \
2697                 -command branch_checkout::dialog \
2698                 -accelerator $M1T-O
2699         lappend disable_on_lock [list .mbar.branch entryconf \
2700                 [.mbar.branch index last] -state]
2701
2702         .mbar.branch add command -label [mc "Rename..."] \
2703                 -command branch_rename::dialog
2704         lappend disable_on_lock [list .mbar.branch entryconf \
2705                 [.mbar.branch index last] -state]
2706
2707         .mbar.branch add command -label [mc "Delete..."] \
2708                 -command branch_delete::dialog
2709         lappend disable_on_lock [list .mbar.branch entryconf \
2710                 [.mbar.branch index last] -state]
2711
2712         .mbar.branch add command -label [mc "Reset..."] \
2713                 -command merge::reset_hard
2714         lappend disable_on_lock [list .mbar.branch entryconf \
2715                 [.mbar.branch index last] -state]
2716 }
2717
2718 # -- Commit Menu
2719 #
2720 proc commit_btn_caption {} {
2721         if {[is_enabled nocommit]} {
2722                 return [mc "Done"]
2723         } else {
2724                 return [mc Commit@@verb]
2725         }
2726 }
2727
2728 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2729         menu .mbar.commit
2730
2731         if {![is_enabled nocommit]} {
2732                 .mbar.commit add radiobutton \
2733                         -label [mc "New Commit"] \
2734                         -command do_select_commit_type \
2735                         -variable selected_commit_type \
2736                         -value new
2737                 lappend disable_on_lock \
2738                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2739
2740                 .mbar.commit add radiobutton \
2741                         -label [mc "Amend Last Commit"] \
2742                         -command do_select_commit_type \
2743                         -variable selected_commit_type \
2744                         -value amend
2745                 lappend disable_on_lock \
2746                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2747
2748                 .mbar.commit add separator
2749         }
2750
2751         .mbar.commit add command -label [mc Rescan] \
2752                 -command ui_do_rescan \
2753                 -accelerator F5
2754         lappend disable_on_lock \
2755                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2756
2757         .mbar.commit add command -label [mc "Stage To Commit"] \
2758                 -command do_add_selection \
2759                 -accelerator $M1T-T
2760         lappend disable_on_lock \
2761                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2762
2763         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2764                 -command do_add_all \
2765                 -accelerator $M1T-I
2766         lappend disable_on_lock \
2767                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2768
2769         .mbar.commit add command -label [mc "Unstage From Commit"] \
2770                 -command do_unstage_selection \
2771                 -accelerator $M1T-U
2772         lappend disable_on_lock \
2773                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2774
2775         .mbar.commit add command -label [mc "Revert Changes"] \
2776                 -command do_revert_selection \
2777                 -accelerator $M1T-J
2778         lappend disable_on_lock \
2779                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2780
2781         .mbar.commit add separator
2782
2783         .mbar.commit add command -label [mc "Show Less Context"] \
2784                 -command show_less_context \
2785                 -accelerator $M1T-\-
2786
2787         .mbar.commit add command -label [mc "Show More Context"] \
2788                 -command show_more_context \
2789                 -accelerator $M1T-=
2790
2791         .mbar.commit add separator
2792
2793         if {![is_enabled nocommitmsg]} {
2794                 .mbar.commit add command -label [mc "Sign Off"] \
2795                         -command do_signoff \
2796                         -accelerator $M1T-S
2797         }
2798
2799         .mbar.commit add command -label [commit_btn_caption] \
2800                 -command do_commit \
2801                 -accelerator $M1T-Return
2802         lappend disable_on_lock \
2803                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2804 }
2805
2806 # -- Merge Menu
2807 #
2808 if {[is_enabled branch]} {
2809         menu .mbar.merge
2810         .mbar.merge add command -label [mc "Local Merge..."] \
2811                 -command merge::dialog \
2812                 -accelerator $M1T-M
2813         lappend disable_on_lock \
2814                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2815         .mbar.merge add command -label [mc "Abort Merge..."] \
2816                 -command merge::reset_hard
2817         lappend disable_on_lock \
2818                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2819 }
2820
2821 # -- Transport Menu
2822 #
2823 if {[is_enabled transport]} {
2824         menu .mbar.remote
2825
2826         .mbar.remote add command \
2827                 -label [mc "Add..."] \
2828                 -command remote_add::dialog \
2829                 -accelerator $M1T-A
2830         .mbar.remote add command \
2831                 -label [mc "Push..."] \
2832                 -command do_push_anywhere \
2833                 -accelerator $M1T-P
2834         .mbar.remote add command \
2835                 -label [mc "Delete Branch..."] \
2836                 -command remote_branch_delete::dialog
2837 }
2838
2839 if {[is_MacOSX]} {
2840         proc ::tk::mac::ShowPreferences {} {do_options}
2841 } else {
2842         # -- Edit Menu
2843         #
2844         .mbar.edit add separator
2845         .mbar.edit add command -label [mc "Options..."] \
2846                 -command do_options
2847 }
2848
2849 # -- Tools Menu
2850 #
2851 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2852         set tools_menubar .mbar.tools
2853         menu $tools_menubar
2854         $tools_menubar add separator
2855         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2856         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2857         set tools_tailcnt 3
2858         if {[array names repo_config guitool.*.cmd] ne {}} {
2859                 tools_populate_all
2860         }
2861 }
2862
2863 # -- Help Menu
2864 #
2865 .mbar add cascade -label [mc Help] -menu .mbar.help
2866 menu .mbar.help
2867
2868 if {[is_MacOSX]} {
2869         .mbar.apple add command -label [mc "About %s" [appname]] \
2870                 -command do_about
2871         .mbar.apple add separator
2872 } else {
2873         .mbar.help add command -label [mc "About %s" [appname]] \
2874                 -command do_about
2875 }
2876 . configure -menu .mbar
2877
2878 set doc_path [githtmldir]
2879 if {$doc_path ne {}} {
2880         set doc_path [file join $doc_path index.html]
2881
2882         if {[is_Cygwin]} {
2883                 set doc_path [exec cygpath --mixed $doc_path]
2884         }
2885 }
2886
2887 if {[file isfile $doc_path]} {
2888         set doc_url "file:$doc_path"
2889 } else {
2890         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2891 }
2892
2893 proc start_browser {url} {
2894         git "web--browse" $url
2895 }
2896
2897 .mbar.help add command -label [mc "Online Documentation"] \
2898         -command [list start_browser $doc_url]
2899
2900 .mbar.help add command -label [mc "Show SSH Key"] \
2901         -command do_ssh_key
2902
2903 unset doc_path doc_url
2904
2905 # -- Standard bindings
2906 #
2907 wm protocol . WM_DELETE_WINDOW do_quit
2908 bind all <$M1B-Key-q> do_quit
2909 bind all <$M1B-Key-Q> do_quit
2910 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2911 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2912
2913 set subcommand_args {}
2914 proc usage {} {
2915         set s "usage: $::argv0 $::subcommand $::subcommand_args"
2916         if {[tk windowingsystem] eq "win32"} {
2917                 wm withdraw .
2918                 tk_messageBox -icon info -message $s \
2919                         -title [mc "Usage"]
2920         } else {
2921                 puts stderr $s
2922         }
2923         exit 1
2924 }
2925
2926 proc normalize_relpath {path} {
2927         set elements {}
2928         foreach item [file split $path] {
2929                 if {$item eq {.}} continue
2930                 if {$item eq {..} && [llength $elements] > 0
2931                     && [lindex $elements end] ne {..}} {
2932                         set elements [lrange $elements 0 end-1]
2933                         continue
2934                 }
2935                 lappend elements $item
2936         }
2937         return [eval file join $elements]
2938 }
2939
2940 # -- Not a normal commit type invocation?  Do that instead!
2941 #
2942 switch -- $subcommand {
2943 browser -
2944 blame {
2945         if {$subcommand eq "blame"} {
2946                 set subcommand_args {[--line=<num>] rev? path}
2947         } else {
2948                 set subcommand_args {rev? path}
2949         }
2950         if {$argv eq {}} usage
2951         set head {}
2952         set path {}
2953         set jump_spec {}
2954         set is_path 0
2955         foreach a $argv {
2956                 if {$is_path || [file exists $_prefix$a]} {
2957                         if {$path ne {}} usage
2958                         set path [normalize_relpath $_prefix$a]
2959                         break
2960                 } elseif {$a eq {--}} {
2961                         if {$path ne {}} {
2962                                 if {$head ne {}} usage
2963                                 set head $path
2964                                 set path {}
2965                         }
2966                         set is_path 1
2967                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2968                         if {$jump_spec ne {} || $head ne {}} usage
2969                         set jump_spec [list $lnum]
2970                 } elseif {$head eq {}} {
2971                         if {$head ne {}} usage
2972                         set head $a
2973                         set is_path 1
2974                 } else {
2975                         usage
2976                 }
2977         }
2978         unset is_path
2979
2980         if {$head ne {} && $path eq {}} {
2981                 set path [normalize_relpath $_prefix$head]
2982                 set head {}
2983         }
2984
2985         if {$head eq {}} {
2986                 load_current_branch
2987         } else {
2988                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2989                         if {[catch {
2990                                         set head [git rev-parse --verify $head]
2991                                 } err]} {
2992                                 if {[tk windowingsystem] eq "win32"} {
2993                                         tk_messageBox -icon error -title [mc Error] -message $err
2994                                 } else {
2995                                         puts stderr $err
2996                                 }
2997                                 exit 1
2998                         }
2999                 }
3000                 set current_branch $head
3001         }
3002
3003         wm deiconify .
3004         switch -- $subcommand {
3005         browser {
3006                 if {$jump_spec ne {}} usage
3007                 if {$head eq {}} {
3008                         if {$path ne {} && [file isdirectory $path]} {
3009                                 set head $current_branch
3010                         } else {
3011                                 set head $path
3012                                 set path {}
3013                         }
3014                 }
3015                 browser::new $head $path
3016         }
3017         blame   {
3018                 if {$head eq {} && ![file exists $path]} {
3019                         catch {wm withdraw .}
3020                         tk_messageBox \
3021                                 -icon error \
3022                                 -type ok \
3023                                 -title [mc "git-gui: fatal error"] \
3024                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3025                         exit 1
3026                 }
3027                 blame::new $head $path $jump_spec
3028         }
3029         }
3030         return
3031 }
3032 citool -
3033 gui {
3034         if {[llength $argv] != 0} {
3035                 usage
3036         }
3037         # fall through to setup UI for commits
3038 }
3039 default {
3040         set err "usage: $argv0 \[{blame|browser|citool}\]"
3041         if {[tk windowingsystem] eq "win32"} {
3042                 wm withdraw .
3043                 tk_messageBox -icon error -message $err \
3044                         -title [mc "Usage"]
3045         } else {
3046                 puts stderr $err
3047         }
3048         exit 1
3049 }
3050 }
3051
3052 # -- Branch Control
3053 #
3054 ${NS}::frame .branch
3055 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3056 ${NS}::label .branch.l1 \
3057         -text [mc "Current Branch:"] \
3058         -anchor w \
3059         -justify left
3060 ${NS}::label .branch.cb \
3061         -textvariable current_branch \
3062         -anchor w \
3063         -justify left
3064 pack .branch.l1 -side left
3065 pack .branch.cb -side left -fill x
3066 pack .branch -side top -fill x
3067
3068 # -- Main Window Layout
3069 #
3070 ${NS}::panedwindow .vpane -orient horizontal
3071 ${NS}::panedwindow .vpane.files -orient vertical
3072 if {$use_ttk} {
3073         .vpane add .vpane.files
3074 } else {
3075         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3076 }
3077 pack .vpane -anchor n -side top -fill both -expand 1
3078
3079 # -- Index File List
3080 #
3081 ${NS}::frame .vpane.files.index -height 100 -width 200
3082 tlabel .vpane.files.index.title \
3083         -text [mc "Staged Changes (Will Commit)"] \
3084         -background lightgreen -foreground black
3085 text $ui_index -background white -foreground black \
3086         -borderwidth 0 \
3087         -width 20 -height 10 \
3088         -wrap none \
3089         -cursor $cursor_ptr \
3090         -xscrollcommand {.vpane.files.index.sx set} \
3091         -yscrollcommand {.vpane.files.index.sy set} \
3092         -state disabled
3093 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3094 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3095 pack .vpane.files.index.title -side top -fill x
3096 pack .vpane.files.index.sx -side bottom -fill x
3097 pack .vpane.files.index.sy -side right -fill y
3098 pack $ui_index -side left -fill both -expand 1
3099
3100 # -- Working Directory File List
3101 #
3102 ${NS}::frame .vpane.files.workdir -height 100 -width 200
3103 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3104         -background lightsalmon -foreground black
3105 text $ui_workdir -background white -foreground black \
3106         -borderwidth 0 \
3107         -width 20 -height 10 \
3108         -wrap none \
3109         -cursor $cursor_ptr \
3110         -xscrollcommand {.vpane.files.workdir.sx set} \
3111         -yscrollcommand {.vpane.files.workdir.sy set} \
3112         -state disabled
3113 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3114 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3115 pack .vpane.files.workdir.title -side top -fill x
3116 pack .vpane.files.workdir.sx -side bottom -fill x
3117 pack .vpane.files.workdir.sy -side right -fill y
3118 pack $ui_workdir -side left -fill both -expand 1
3119
3120 .vpane.files add .vpane.files.workdir
3121 .vpane.files add .vpane.files.index
3122 if {!$use_ttk} {
3123         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3124         .vpane.files paneconfigure .vpane.files.index -sticky news
3125 }
3126
3127 foreach i [list $ui_index $ui_workdir] {
3128         rmsel_tag $i
3129         $i tag conf in_diff -background [$i tag cget in_sel -background]
3130 }
3131 unset i
3132
3133 # -- Diff and Commit Area
3134 #
3135 ${NS}::frame .vpane.lower -height 300 -width 400
3136 ${NS}::frame .vpane.lower.commarea
3137 ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1
3138 pack .vpane.lower.diff -fill both -expand 1
3139 pack .vpane.lower.commarea -side bottom -fill x
3140 .vpane add .vpane.lower
3141 if {!$use_ttk} {.vpane paneconfigure .vpane.lower -sticky nsew}
3142
3143 # -- Commit Area Buttons
3144 #
3145 ${NS}::frame .vpane.lower.commarea.buttons
3146 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3147         -anchor w \
3148         -justify left
3149 pack .vpane.lower.commarea.buttons.l -side top -fill x
3150 pack .vpane.lower.commarea.buttons -side left -fill y
3151
3152 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3153         -command ui_do_rescan
3154 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3155 lappend disable_on_lock \
3156         {.vpane.lower.commarea.buttons.rescan conf -state}
3157
3158 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3159         -command do_add_all
3160 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3161 lappend disable_on_lock \
3162         {.vpane.lower.commarea.buttons.incall conf -state}
3163
3164 if {![is_enabled nocommitmsg]} {
3165         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3166                 -command do_signoff
3167         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3168 }
3169
3170 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3171         -command do_commit
3172 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3173 lappend disable_on_lock \
3174         {.vpane.lower.commarea.buttons.commit conf -state}
3175
3176 if {![is_enabled nocommit]} {
3177         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3178                 -command do_push_anywhere
3179         pack .vpane.lower.commarea.buttons.push -side top -fill x
3180 }
3181
3182 # -- Commit Message Buffer
3183 #
3184 ${NS}::frame .vpane.lower.commarea.buffer
3185 ${NS}::frame .vpane.lower.commarea.buffer.header
3186 set ui_comm .vpane.lower.commarea.buffer.t
3187 set ui_coml .vpane.lower.commarea.buffer.header.l
3188
3189 if {![is_enabled nocommit]} {
3190         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3191                 -text [mc "New Commit"] \
3192                 -command do_select_commit_type \
3193                 -variable selected_commit_type \
3194                 -value new
3195         lappend disable_on_lock \
3196                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3197         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3198                 -text [mc "Amend Last Commit"] \
3199                 -command do_select_commit_type \
3200                 -variable selected_commit_type \
3201                 -value amend
3202         lappend disable_on_lock \
3203                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3204 }
3205
3206 ${NS}::label $ui_coml \
3207         -anchor w \
3208         -justify left
3209 proc trace_commit_type {varname args} {
3210         global ui_coml commit_type
3211         switch -glob -- $commit_type {
3212         initial       {set txt [mc "Initial Commit Message:"]}
3213         amend         {set txt [mc "Amended Commit Message:"]}
3214         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3215         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3216         merge         {set txt [mc "Merge Commit Message:"]}
3217         *             {set txt [mc "Commit Message:"]}
3218         }
3219         $ui_coml conf -text $txt
3220 }
3221 trace add variable commit_type write trace_commit_type
3222 pack $ui_coml -side left -fill x
3223
3224 if {![is_enabled nocommit]} {
3225         pack .vpane.lower.commarea.buffer.header.amend -side right
3226         pack .vpane.lower.commarea.buffer.header.new -side right
3227 }
3228
3229 text $ui_comm -background white -foreground black \
3230         -borderwidth 1 \
3231         -undo true \
3232         -maxundo 20 \
3233         -autoseparators true \
3234         -relief sunken \
3235         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3236         -font font_diff \
3237         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3238 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3239         -command [list $ui_comm yview]
3240 pack .vpane.lower.commarea.buffer.header -side top -fill x
3241 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3242 pack $ui_comm -side left -fill y
3243 pack .vpane.lower.commarea.buffer -side left -fill y
3244
3245 # -- Commit Message Buffer Context Menu
3246 #
3247 set ctxm .vpane.lower.commarea.buffer.ctxm
3248 menu $ctxm -tearoff 0
3249 $ctxm add command \
3250         -label [mc Cut] \
3251         -command {tk_textCut $ui_comm}
3252 $ctxm add command \
3253         -label [mc Copy] \
3254         -command {tk_textCopy $ui_comm}
3255 $ctxm add command \
3256         -label [mc Paste] \
3257         -command {tk_textPaste $ui_comm}
3258 $ctxm add command \
3259         -label [mc Delete] \
3260         -command {catch {$ui_comm delete sel.first sel.last}}
3261 $ctxm add separator
3262 $ctxm add command \
3263         -label [mc "Select All"] \
3264         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3265 $ctxm add command \
3266         -label [mc "Copy All"] \
3267         -command {
3268                 $ui_comm tag add sel 0.0 end
3269                 tk_textCopy $ui_comm
3270                 $ui_comm tag remove sel 0.0 end
3271         }
3272 $ctxm add separator
3273 $ctxm add command \
3274         -label [mc "Sign Off"] \
3275         -command do_signoff
3276 set ui_comm_ctxm $ctxm
3277
3278 # -- Diff Header
3279 #
3280 proc trace_current_diff_path {varname args} {
3281         global current_diff_path diff_actions file_states
3282         if {$current_diff_path eq {}} {
3283                 set s {}
3284                 set f {}
3285                 set p {}
3286                 set o disabled
3287         } else {
3288                 set p $current_diff_path
3289                 set s [mapdesc [lindex $file_states($p) 0] $p]
3290                 set f [mc "File:"]
3291                 set p [escape_path $p]
3292                 set o normal
3293         }
3294
3295         .vpane.lower.diff.header.status configure -text $s
3296         .vpane.lower.diff.header.file configure -text $f
3297         .vpane.lower.diff.header.path configure -text $p
3298         foreach w $diff_actions {
3299                 uplevel #0 $w $o
3300         }
3301 }
3302 trace add variable current_diff_path write trace_current_diff_path
3303
3304 gold_frame .vpane.lower.diff.header
3305 tlabel .vpane.lower.diff.header.status \
3306         -background gold \
3307         -foreground black \
3308         -width $max_status_desc \
3309         -anchor w \
3310         -justify left
3311 tlabel .vpane.lower.diff.header.file \
3312         -background gold \
3313         -foreground black \
3314         -anchor w \
3315         -justify left
3316 tlabel .vpane.lower.diff.header.path \
3317         -background gold \
3318         -foreground black \
3319         -anchor w \
3320         -justify left
3321 pack .vpane.lower.diff.header.status -side left
3322 pack .vpane.lower.diff.header.file -side left
3323 pack .vpane.lower.diff.header.path -fill x
3324 set ctxm .vpane.lower.diff.header.ctxm
3325 menu $ctxm -tearoff 0
3326 $ctxm add command \
3327         -label [mc Copy] \
3328         -command {
3329                 clipboard clear
3330                 clipboard append \
3331                         -format STRING \
3332                         -type STRING \
3333                         -- $current_diff_path
3334         }
3335 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3336 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3337
3338 # -- Diff Body
3339 #
3340 ${NS}::frame .vpane.lower.diff.body
3341 set ui_diff .vpane.lower.diff.body.t
3342 text $ui_diff -background white -foreground black \
3343         -borderwidth 0 \
3344         -width 80 -height 5 -wrap none \
3345         -font font_diff \
3346         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3347         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3348         -state disabled
3349 catch {$ui_diff configure -tabstyle wordprocessor}
3350 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3351         -command [list $ui_diff xview]
3352 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3353         -command [list $ui_diff yview]
3354 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3355 pack .vpane.lower.diff.body.sby -side right -fill y
3356 pack $ui_diff -side left -fill both -expand 1
3357 pack .vpane.lower.diff.header -side top -fill x
3358 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3359
3360 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3361         $ui_diff tag configure clr4$n -background $c
3362         $ui_diff tag configure clri4$n -foreground $c
3363         $ui_diff tag configure clr3$n -foreground $c
3364         $ui_diff tag configure clri3$n -background $c
3365 }
3366 $ui_diff tag configure clr1 -font font_diffbold
3367
3368 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3369
3370 $ui_diff tag conf d_cr -elide true
3371 $ui_diff tag conf d_@ -font font_diffbold
3372 $ui_diff tag conf d_+ -foreground {#00a000}
3373 $ui_diff tag conf d_- -foreground red
3374
3375 $ui_diff tag conf d_++ -foreground {#00a000}
3376 $ui_diff tag conf d_-- -foreground red
3377 $ui_diff tag conf d_+s \
3378         -foreground {#00a000} \
3379         -background {#e2effa}
3380 $ui_diff tag conf d_-s \
3381         -foreground red \
3382         -background {#e2effa}
3383 $ui_diff tag conf d_s+ \
3384         -foreground {#00a000} \
3385         -background ivory1
3386 $ui_diff tag conf d_s- \
3387         -foreground red \
3388         -background ivory1
3389
3390 $ui_diff tag conf d< \
3391         -foreground orange \
3392         -font font_diffbold
3393 $ui_diff tag conf d= \
3394         -foreground orange \
3395         -font font_diffbold
3396 $ui_diff tag conf d> \
3397         -foreground orange \
3398         -font font_diffbold
3399
3400 $ui_diff tag raise sel
3401
3402 # -- Diff Body Context Menu
3403 #
3404
3405 proc create_common_diff_popup {ctxm} {
3406         $ctxm add command \
3407                 -label [mc Refresh] \
3408                 -command reshow_diff
3409         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3410         $ctxm add command \
3411                 -label [mc Copy] \
3412                 -command {tk_textCopy $ui_diff}
3413         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3414         $ctxm add command \
3415                 -label [mc "Select All"] \
3416                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3417         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3418         $ctxm add command \
3419                 -label [mc "Copy All"] \
3420                 -command {
3421                         $ui_diff tag add sel 0.0 end
3422                         tk_textCopy $ui_diff
3423                         $ui_diff tag remove sel 0.0 end
3424                 }
3425         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3426         $ctxm add separator
3427         $ctxm add command \
3428                 -label [mc "Decrease Font Size"] \
3429                 -command {incr_font_size font_diff -1}
3430         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3431         $ctxm add command \
3432                 -label [mc "Increase Font Size"] \
3433                 -command {incr_font_size font_diff 1}
3434         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3435         $ctxm add separator
3436         set emenu $ctxm.enc
3437         menu $emenu
3438         build_encoding_menu $emenu [list force_diff_encoding]
3439         $ctxm add cascade \
3440                 -label [mc "Encoding"] \
3441                 -menu $emenu
3442         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3443         $ctxm add separator
3444         $ctxm add command -label [mc "Options..."] \
3445                 -command do_options
3446 }
3447
3448 set ctxm .vpane.lower.diff.body.ctxm
3449 menu $ctxm -tearoff 0
3450 $ctxm add command \
3451         -label [mc "Apply/Reverse Hunk"] \
3452         -command {apply_hunk $cursorX $cursorY}
3453 set ui_diff_applyhunk [$ctxm index last]
3454 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3455 $ctxm add command \
3456         -label [mc "Apply/Reverse Line"] \
3457         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3458 set ui_diff_applyline [$ctxm index last]
3459 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3460 $ctxm add separator
3461 $ctxm add command \
3462         -label [mc "Show Less Context"] \
3463         -command show_less_context
3464 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3465 $ctxm add command \
3466         -label [mc "Show More Context"] \
3467         -command show_more_context
3468 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3469 $ctxm add separator
3470 create_common_diff_popup $ctxm
3471
3472 set ctxmmg .vpane.lower.diff.body.ctxmmg
3473 menu $ctxmmg -tearoff 0
3474 $ctxmmg add command \
3475         -label [mc "Run Merge Tool"] \
3476         -command {merge_resolve_tool}
3477 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3478 $ctxmmg add separator
3479 $ctxmmg add command \
3480         -label [mc "Use Remote Version"] \
3481         -command {merge_resolve_one 3}
3482 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3483 $ctxmmg add command \
3484         -label [mc "Use Local Version"] \
3485         -command {merge_resolve_one 2}
3486 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3487 $ctxmmg add command \
3488         -label [mc "Revert To Base"] \
3489         -command {merge_resolve_one 1}
3490 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3491 $ctxmmg add separator
3492 $ctxmmg add command \
3493         -label [mc "Show Less Context"] \
3494         -command show_less_context
3495 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3496 $ctxmmg add command \
3497         -label [mc "Show More Context"] \
3498         -command show_more_context
3499 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3500 $ctxmmg add separator
3501 create_common_diff_popup $ctxmmg
3502
3503 set ctxmsm .vpane.lower.diff.body.ctxmsm
3504 menu $ctxmsm -tearoff 0
3505 $ctxmsm add command \
3506         -label [mc "Visualize These Changes In The Submodule"] \
3507         -command {do_gitk -- true}
3508 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3509 $ctxmsm add command \
3510         -label [mc "Visualize Current Branch History In The Submodule"] \
3511         -command {do_gitk {} true}
3512 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3513 $ctxmsm add command \
3514         -label [mc "Visualize All Branch History In The Submodule"] \
3515         -command {do_gitk --all true}
3516 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3517 $ctxmsm add separator
3518 $ctxmsm add command \
3519         -label [mc "Start git gui In The Submodule"] \
3520         -command {do_git_gui}
3521 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3522 $ctxmsm add separator
3523 create_common_diff_popup $ctxmsm
3524
3525 proc has_textconv {path} {
3526         if {[is_config_false gui.textconv]} {
3527                 return 0
3528         }
3529         set filter [gitattr $path diff set]
3530         set textconv [get_config [join [list diff $filter textconv] .]]
3531         if {$filter ne {set} && $textconv ne {}} {
3532                 return 1
3533         } else {
3534                 return 0
3535         }
3536 }
3537
3538 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3539         global current_diff_path file_states
3540         set ::cursorX $x
3541         set ::cursorY $y
3542         if {[info exists file_states($current_diff_path)]} {
3543                 set state [lindex $file_states($current_diff_path) 0]
3544         } else {
3545                 set state {__}
3546         }
3547         if {[string first {U} $state] >= 0} {
3548                 tk_popup $ctxmmg $X $Y
3549         } elseif {$::is_submodule_diff} {
3550                 tk_popup $ctxmsm $X $Y
3551         } else {
3552                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3553                 if {$::ui_index eq $::current_diff_side} {
3554                         set l [mc "Unstage Hunk From Commit"]
3555                         if {$has_range} {
3556                                 set t [mc "Unstage Lines From Commit"]
3557                         } else {
3558                                 set t [mc "Unstage Line From Commit"]
3559                         }
3560                 } else {
3561                         set l [mc "Stage Hunk For Commit"]
3562                         if {$has_range} {
3563                                 set t [mc "Stage Lines For Commit"]
3564                         } else {
3565                                 set t [mc "Stage Line For Commit"]
3566                         }
3567                 }
3568                 if {$::is_3way_diff
3569                         || $current_diff_path eq {}
3570                         || {__} eq $state
3571                         || {_O} eq $state
3572                         || [string match {?T} $state]
3573                         || [string match {T?} $state]
3574                         || [has_textconv $current_diff_path]} {
3575                         set s disabled
3576                 } else {
3577                         set s normal
3578                 }
3579                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3580                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3581                 tk_popup $ctxm $X $Y
3582         }
3583 }
3584 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3585
3586 # -- Status Bar
3587 #
3588 set main_status [::status_bar::new .status]
3589 pack .status -anchor w -side bottom -fill x
3590 $main_status show [mc "Initializing..."]
3591
3592 # -- Load geometry
3593 #
3594 proc on_ttk_pane_mapped {w pane pos} {
3595         bind $w <Map> {}
3596         after 0 [list after idle [list $w sashpos $pane $pos]]
3597 }
3598 proc on_tk_pane_mapped {w pane x y} {
3599         bind $w <Map> {}
3600         after 0 [list after idle [list $w sash place $pane $x $y]]
3601 }
3602 proc on_application_mapped {} {
3603         global repo_config use_ttk
3604         bind . <Map> {}
3605         set gm $repo_config(gui.geometry)
3606         if {$use_ttk} {
3607                 bind .vpane <Map> \
3608                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3609                 bind .vpane.files <Map> \
3610                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3611         } else {
3612                 bind .vpane <Map> \
3613                     [list on_tk_pane_mapped %W 0 \
3614                          [lindex $gm 1] \
3615                          [lindex [.vpane sash coord 0] 1]]
3616                 bind .vpane.files <Map> \
3617                     [list on_tk_pane_mapped %W 0 \
3618                          [lindex [.vpane.files sash coord 0] 0] \
3619                          [lindex $gm 2]]
3620         }
3621         wm geometry . [lindex $gm 0]
3622 }
3623 if {[info exists repo_config(gui.geometry)]} {
3624         bind . <Map> [list on_application_mapped]
3625         wm geometry . [lindex $repo_config(gui.geometry) 0]
3626 }
3627
3628 # -- Load window state
3629 #
3630 if {[info exists repo_config(gui.wmstate)]} {
3631         catch {wm state . $repo_config(gui.wmstate)}
3632 }
3633
3634 # -- Key Bindings
3635 #
3636 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3637 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3638 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3639 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3640 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3641 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3642 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3643 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3644 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3645 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3646 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3647 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3648 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3649 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3650 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3651 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3652 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3653 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3654 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3655 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3656 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3657 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3658
3659 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3660 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3661 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3662 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3663 bind $ui_diff <$M1B-Key-v> {break}
3664 bind $ui_diff <$M1B-Key-V> {break}
3665 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3666 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3667 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3668 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3669 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3670 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3671 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3672 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3673 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3674 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3675 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3676 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3677 bind $ui_diff <Button-1>   {focus %W}
3678
3679 if {[is_enabled branch]} {
3680         bind . <$M1B-Key-n> branch_create::dialog
3681         bind . <$M1B-Key-N> branch_create::dialog
3682         bind . <$M1B-Key-o> branch_checkout::dialog
3683         bind . <$M1B-Key-O> branch_checkout::dialog
3684         bind . <$M1B-Key-m> merge::dialog
3685         bind . <$M1B-Key-M> merge::dialog
3686 }
3687 if {[is_enabled transport]} {
3688         bind . <$M1B-Key-p> do_push_anywhere
3689         bind . <$M1B-Key-P> do_push_anywhere
3690 }
3691
3692 bind .   <Key-F5>     ui_do_rescan
3693 bind .   <$M1B-Key-r> ui_do_rescan
3694 bind .   <$M1B-Key-R> ui_do_rescan
3695 bind .   <$M1B-Key-s> do_signoff
3696 bind .   <$M1B-Key-S> do_signoff
3697 bind .   <$M1B-Key-t> do_add_selection
3698 bind .   <$M1B-Key-T> do_add_selection
3699 bind .   <$M1B-Key-j> do_revert_selection
3700 bind .   <$M1B-Key-J> do_revert_selection
3701 bind .   <$M1B-Key-i> do_add_all
3702 bind .   <$M1B-Key-I> do_add_all
3703 bind .   <$M1B-Key-minus> {show_less_context;break}
3704 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3705 bind .   <$M1B-Key-equal> {show_more_context;break}
3706 bind .   <$M1B-Key-plus> {show_more_context;break}
3707 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3708 bind .   <$M1B-Key-Return> do_commit
3709 foreach i [list $ui_index $ui_workdir] {
3710         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3711         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3712         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3713 }
3714 unset i
3715
3716 set file_lists($ui_index) [list]
3717 set file_lists($ui_workdir) [list]
3718
3719 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3720 focus -force $ui_comm
3721
3722 # -- Warn the user about environmental problems.  Cygwin's Tcl
3723 #    does *not* pass its env array onto any processes it spawns.
3724 #    This means that git processes get none of our environment.
3725 #
3726 if {[is_Cygwin]} {
3727         set ignored_env 0
3728         set suggest_user {}
3729         set msg [mc "Possible environment issues exist.
3730
3731 The following environment variables are probably
3732 going to be ignored by any Git subprocess run
3733 by %s:
3734
3735 " [appname]]
3736         foreach name [array names env] {
3737                 switch -regexp -- $name {
3738                 {^GIT_INDEX_FILE$} -
3739                 {^GIT_OBJECT_DIRECTORY$} -
3740                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3741                 {^GIT_DIFF_OPTS$} -
3742                 {^GIT_EXTERNAL_DIFF$} -
3743                 {^GIT_PAGER$} -
3744                 {^GIT_TRACE$} -
3745                 {^GIT_CONFIG$} -
3746                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3747                         append msg " - $name\n"
3748                         incr ignored_env
3749                 }
3750                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3751                         append msg " - $name\n"
3752                         incr ignored_env
3753                         set suggest_user $name
3754                 }
3755                 }
3756         }
3757         if {$ignored_env > 0} {
3758                 append msg [mc "
3759 This is due to a known issue with the
3760 Tcl binary distributed by Cygwin."]
3761
3762                 if {$suggest_user ne {}} {
3763                         append msg [mc "
3764
3765 A good replacement for %s
3766 is placing values for the user.name and
3767 user.email settings into your personal
3768 ~/.gitconfig file.
3769 " $suggest_user]
3770                 }
3771                 warn_popup $msg
3772         }
3773         unset ignored_env msg suggest_user name
3774 }
3775
3776 # -- Only initialize complex UI if we are going to stay running.
3777 #
3778 if {[is_enabled transport]} {
3779         load_all_remotes
3780
3781         set n [.mbar.remote index end]
3782         populate_remotes_menu
3783         set n [expr {[.mbar.remote index end] - $n}]
3784         if {$n > 0} {
3785                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3786                 .mbar.remote insert $n separator
3787         }
3788         unset n
3789 }
3790
3791 if {[winfo exists $ui_comm]} {
3792         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3793
3794         # -- If both our backup and message files exist use the
3795         #    newer of the two files to initialize the buffer.
3796         #
3797         if {$GITGUI_BCK_exists} {
3798                 set m [gitdir GITGUI_MSG]
3799                 if {[file isfile $m]} {
3800                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3801                                 catch {file delete [gitdir GITGUI_MSG]}
3802                         } else {
3803                                 $ui_comm delete 0.0 end
3804                                 $ui_comm edit reset
3805                                 $ui_comm edit modified false
3806                                 catch {file delete [gitdir GITGUI_BCK]}
3807                                 set GITGUI_BCK_exists 0
3808                         }
3809                 }
3810                 unset m
3811         }
3812
3813         proc backup_commit_buffer {} {
3814                 global ui_comm GITGUI_BCK_exists
3815
3816                 set m [$ui_comm edit modified]
3817                 if {$m || $GITGUI_BCK_exists} {
3818                         set msg [string trim [$ui_comm get 0.0 end]]
3819                         regsub -all -line {[ \r\t]+$} $msg {} msg
3820
3821                         if {$msg eq {}} {
3822                                 if {$GITGUI_BCK_exists} {
3823                                         catch {file delete [gitdir GITGUI_BCK]}
3824                                         set GITGUI_BCK_exists 0
3825                                 }
3826                         } elseif {$m} {
3827                                 catch {
3828                                         set fd [open [gitdir GITGUI_BCK] w]
3829                                         puts -nonewline $fd $msg
3830                                         close $fd
3831                                         set GITGUI_BCK_exists 1
3832                                 }
3833                         }
3834
3835                         $ui_comm edit modified false
3836                 }
3837
3838                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3839         }
3840
3841         backup_commit_buffer
3842
3843         # -- If the user has aspell available we can drive it
3844         #    in pipe mode to spellcheck the commit message.
3845         #
3846         set spell_cmd [list |]
3847         set spell_dict [get_config gui.spellingdictionary]
3848         lappend spell_cmd aspell
3849         if {$spell_dict ne {}} {
3850                 lappend spell_cmd --master=$spell_dict
3851         }
3852         lappend spell_cmd --mode=none
3853         lappend spell_cmd --encoding=utf-8
3854         lappend spell_cmd pipe
3855         if {$spell_dict eq {none}
3856          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3857                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3858         } else {
3859                 set ui_comm_spell [spellcheck::init \
3860                         $spell_fd \
3861                         $ui_comm \
3862                         $ui_comm_ctxm \
3863                 ]
3864         }
3865         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3866 }
3867
3868 lock_index begin-read
3869 if {![winfo ismapped .]} {
3870         wm deiconify .
3871 }
3872 after 1 {
3873         if {[is_enabled initialamend]} {
3874                 force_amend
3875         } else {
3876                 do_rescan
3877         }
3878
3879         if {[is_enabled nocommitmsg]} {
3880                 $ui_comm configure -state disabled -background gray
3881         }
3882 }
3883 if {[is_enabled multicommit]} {
3884         after 1000 hint_gc
3885 }
3886 if {[is_enabled retcode]} {
3887         bind . <Destroy> {+terminate_me %W}
3888 }
3889 if {$picked && [is_config_true gui.autoexplore]} {
3890         do_explore
3891 }
3892
3893 # Local variables:
3894 # mode: tcl
3895 # indent-tabs-mode: t
3896 # tab-width: 4
3897 # End: