contrib/mw-to-git/git-remote-mediawiki

   1 #! /usr/bin/perl
   2
   3 # Copyright (C) 2011
   4 #     Jérémie Nikaes <jeremie.nikaes@ensimag.imag.fr>
   5 #     Arnaud Lacurie <arnaud.lacurie@ensimag.imag.fr>
   6 #     Claire Fousse <claire.fousse@ensimag.imag.fr>
   7 #     David Amouyal <david.amouyal@ensimag.imag.fr>
   8 #     Matthieu Moy <matthieu.moy@grenoble-inp.fr>
   9 # License: GPL v2 or later
  10
  11 # Gateway between Git and MediaWiki.
  12 #   https://github.com/Bibzball/Git-Mediawiki/wiki
  13 #
  14 # Known limitations:
  15 #
  16 # - Only wiki pages are managed, no support for [[File:...]]
  17 #   attachments.
  18 #
  19 # - Poor performance in the best case: it takes forever to check
  20 #   whether we're up-to-date (on fetch or push) or to fetch a few
  21 #   revisions from a large wiki, because we use exclusively a
  22 #   page-based synchronization. We could switch to a wiki-wide
  23 #   synchronization when the synchronization involves few revisions
  24 #   but the wiki is large.
  25 #
  26 # - Git renames could be turned into MediaWiki renames (see TODO
  27 #   below)
  28 #
  29 # - login/password support requires the user to write the password
  30 #   cleartext in a file (see TODO below).
  31 #
  32 # - No way to import "one page, and all pages included in it"
  33 #
  34 # - Multiple remote MediaWikis have not been very well tested.
  35
  36 use strict;
  37 use MediaWiki::API;
  38 use DateTime::Format::ISO8601;
  39 use encoding 'utf8';
  40
  41 # use encoding 'utf8' doesn't change STDERROR
  42 # but we're going to output UTF-8 filenames to STDERR
  43 binmode STDERR, ":utf8";
  44
  45 use URI::Escape;
  46 use warnings;
  47
  48 # Mediawiki filenames can contain forward slashes. This variable decides by which pattern they should be replaced
  49 use constant SLASH_REPLACEMENT => "%2F";
  50
  51 # It's not always possible to delete pages (may require some
  52 # priviledges). Deleted pages are replaced with this content.
  53 use constant DELETED_CONTENT => "[[Category:Deleted]]\n";
  54
  55 # It's not possible to create empty pages. New empty files in Git are
  56 # sent with this content instead.
  57 use constant EMPTY_CONTENT => "<!-- empty page -->\n";
  58
  59 # used to reflect file creation or deletion in diff.
  60 use constant NULL_SHA1 => "0000000000000000000000000000000000000000";
  61
  62 my $remotename = $ARGV[0];
  63 my $url = $ARGV[1];
  64
  65 # Accept both space-separated and multiple keys in config file.
  66 # Spaces should be written as _ anyway because we'll use chomp.
  67 my @tracked_pages = split(/[ \n]/, run_git("config --get-all remote.". $remotename .".pages"));
  68 chomp(@tracked_pages);
  69
  70 # Just like @tracked_pages, but for MediaWiki categories.
  71 my @tracked_categories = split(/[ \n]/, run_git("config --get-all remote.". $remotename .".categories"));
  72 chomp(@tracked_categories);
  73
  74 my $wiki_login = run_git("config --get remote.". $remotename .".mwLogin");
  75 # TODO: ideally, this should be able to read from keyboard, but we're
  76 # inside a remote helper, so our stdin is connect to git, not to a
  77 # terminal.
  78 my $wiki_passwd = run_git("config --get remote.". $remotename .".mwPassword");
  79 chomp($wiki_login);
  80 chomp($wiki_passwd);
  81
  82 # Import only last revisions (both for clone and fetch)
  83 my $shallow_import = run_git("config --get --bool remote.". $remotename .".shallow");
  84 chomp($shallow_import);
  85 $shallow_import = ($shallow_import eq "true");
  86
  87 # Dumb push: don't update notes and mediawiki ref to reflect the last push.
  88 #
  89 # Configurable with mediawiki.dumbPush, or per-remote with
  90 # remote.<remotename>.dumbPush.
  91 #
  92 # This means the user will have to re-import the just-pushed
  93 # revisions. On the other hand, this means that the Git revisions
  94 # corresponding to MediaWiki revisions are all imported from the wiki,
  95 # regardless of whether they were initially created in Git or from the
  96 # web interface, hence all users will get the same history (i.e. if
  97 # the push from Git to MediaWiki loses some information, everybody
  98 # will get the history with information lost). If the import is
  99 # deterministic, this means everybody gets the same sha1 for each
 100 # MediaWiki revision.
 101 my $dumb_push = run_git("config --get --bool remote.$remotename.dumbPush");
 102 unless ($dumb_push) {
 103         $dumb_push = run_git("config --get --bool mediawiki.dumbPush");
 104 }
 105 chomp($dumb_push);
 106 $dumb_push = ($dumb_push eq "true");
 107
 108 my $wiki_name = $url;
 109 $wiki_name =~ s/[^\/]*:\/\///;
 110
 111 # Commands parser
 112 my $entry;
 113 my @cmd;
 114 while (<STDIN>) {
 115         chomp;
 116         @cmd = split(/ /);
 117         if (defined($cmd[0])) {
 118                 # Line not blank
 119                 if ($cmd[0] eq "capabilities") {
 120                         die("Too many arguments for capabilities") unless (!defined($cmd[1]));
 121                         mw_capabilities();
 122                 } elsif ($cmd[0] eq "list") {
 123                         die("Too many arguments for list") unless (!defined($cmd[2]));
 124                         mw_list($cmd[1]);
 125                 } elsif ($cmd[0] eq "import") {
 126                         die("Invalid arguments for import") unless ($cmd[1] ne "" && !defined($cmd[2]));
 127                         mw_import($cmd[1]);
 128                 } elsif ($cmd[0] eq "option") {
 129                         die("Too many arguments for option") unless ($cmd[1] ne "" && $cmd[2] ne "" && !defined($cmd[3]));
 130                         mw_option($cmd[1],$cmd[2]);
 131                 } elsif ($cmd[0] eq "push") {
 132                         mw_push($cmd[1]);
 133                 } else {
 134                         print STDERR "Unknown command. Aborting...\n";
 135                         last;
 136                 }
 137         } else {
 138                 # blank line: we should terminate
 139                 last;
 140         }
 141
 142         BEGIN { $| = 1 } # flush STDOUT, to make sure the previous
 143                          # command is fully processed.
 144 }
 145
 146 ########################## Functions ##############################
 147
 148 # MediaWiki API instance, created lazily.
 149 my $mediawiki;
 150
 151 sub mw_connect_maybe {
 152         if ($mediawiki) {
 153             return;
 154         }
 155         $mediawiki = MediaWiki::API->new;
 156         $mediawiki->{config}->{api_url} = "$url/api.php";
 157         if ($wiki_login) {
 158                 if (!$mediawiki->login({
 159                         lgname => $wiki_login,
 160                         lgpassword => $wiki_passwd,
 161                 })) {
 162                         print STDERR "Failed to log in mediawiki user \"$wiki_login\" on $url\n";
 163                         print STDERR "(error " .
 164                             $mediawiki->{error}->{code} . ': ' .
 165                             $mediawiki->{error}->{details} . ")\n";
 166                         exit 1;
 167                 } else {
 168                         print STDERR "Logged in with user \"$wiki_login\".\n";
 169                 }
 170         }
 171 }
 172
 173 sub get_mw_first_pages {
 174         my $some_pages = shift;
 175         my @some_pages = @{$some_pages};
 176
 177         my $pages = shift;
 178
 179         # pattern 'page1|page2|...' required by the API
 180         my $titles = join('|', @some_pages);
 181
 182         my $mw_pages = $mediawiki->api({
 183                 action => 'query',
 184                 titles => $titles,
 185         });
 186         if (!defined($mw_pages)) {
 187                 print STDERR "fatal: could not query the list of wiki pages.\n";
 188                 print STDERR "fatal: '$url' does not appear to be a mediawiki\n";
 189                 print STDERR "fatal: make sure '$url/api.php' is a valid page.\n";
 190                 exit 1;
 191         }
 192         while (my ($id, $page) = each(%{$mw_pages->{query}->{pages}})) {
 193                 if ($id < 0) {
 194                         print STDERR "Warning: page $page->{title} not found on wiki\n";
 195                 } else {
 196                         $pages->{$page->{title}} = $page;
 197                 }
 198         }
 199 }
 200
 201 sub get_mw_pages {
 202         mw_connect_maybe();
 203
 204         my %pages; # hash on page titles to avoid duplicates
 205         my $user_defined;
 206         if (@tracked_pages) {
 207                 $user_defined = 1;
 208                 # The user provided a list of pages titles, but we
 209                 # still need to query the API to get the page IDs.
 210
 211                 my @some_pages = @tracked_pages;
 212                 while (@some_pages) {
 213                         my $last = 50;
 214                         if ($#some_pages < $last) {
 215                                 $last = $#some_pages;
 216                         }
 217                         my @slice = @some_pages[0..$last];
 218                         get_mw_first_pages(\@slice, \%pages);
 219                         @some_pages = @some_pages[51..$#some_pages];
 220                 }
 221         }
 222         if (@tracked_categories) {
 223                 $user_defined = 1;
 224                 foreach my $category (@tracked_categories) {
 225                         if (index($category, ':') < 0) {
 226                                 # Mediawiki requires the Category
 227                                 # prefix, but let's not force the user
 228                                 # to specify it.
 229                                 $category = "Category:" . $category;
 230                         }
 231                         my $mw_pages = $mediawiki->list( {
 232                                 action => 'query',
 233                                 list => 'categorymembers',
 234                                 cmtitle => $category,
 235                                 cmlimit => 'max' } )
 236                             || die $mediawiki->{error}->{code} . ': ' . $mediawiki->{error}->{details};
 237                         foreach my $page (@{$mw_pages}) {
 238                                 $pages{$page->{title}} = $page;
 239                         }
 240                 }
 241         }
 242         if (!$user_defined) {
 243                 # No user-provided list, get the list of pages from
 244                 # the API.
 245                 my $mw_pages = $mediawiki->list({
 246                         action => 'query',
 247                         list => 'allpages',
 248                         aplimit => 500,
 249                 });
 250                 if (!defined($mw_pages)) {
 251                         print STDERR "fatal: could not get the list of wiki pages.\n";
 252                         print STDERR "fatal: '$url' does not appear to be a mediawiki\n";
 253                         print STDERR "fatal: make sure '$url/api.php' is a valid page.\n";
 254                         exit 1;
 255                 }
 256                 foreach my $page (@{$mw_pages}) {
 257                         $pages{$page->{title}} = $page;
 258                 }
 259         }
 260         return values(%pages);
 261 }
 262
 263 sub run_git {
 264         open(my $git, "-|:encoding(UTF-8)", "git " . $_[0]);
 265         my $res = do { local $/; <$git> };
 266         close($git);
 267
 268         return $res;
 269 }
 270
 271
 272 sub get_last_local_revision {
 273         # Get note regarding last mediawiki revision
 274         my $note = run_git("notes --ref=$remotename/mediawiki show refs/mediawiki/$remotename/master 2>/dev/null");
 275         my @note_info = split(/ /, $note);
 276
 277         my $lastrevision_number;
 278         if (!(defined($note_info[0]) && $note_info[0] eq "mediawiki_revision:")) {
 279                 print STDERR "No previous mediawiki revision found";
 280                 $lastrevision_number = 0;
 281         } else {
 282                 # Notes are formatted : mediawiki_revision: #number
 283                 $lastrevision_number = $note_info[1];
 284                 chomp($lastrevision_number);
 285                 print STDERR "Last local mediawiki revision found is $lastrevision_number";
 286         }
 287         return $lastrevision_number;
 288 }
 289
 290 sub get_last_remote_revision {
 291         mw_connect_maybe();
 292
 293         my @pages = get_mw_pages();
 294
 295         my $max_rev_num = 0;
 296
 297         foreach my $page (@pages) {
 298                 my $id = $page->{pageid};
 299
 300                 my $query = {
 301                         action => 'query',
 302                         prop => 'revisions',
 303                         rvprop => 'ids',
 304                         pageids => $id,
 305                 };
 306
 307                 my $result = $mediawiki->api($query);
 308
 309                 my $lastrev = pop(@{$result->{query}->{pages}->{$id}->{revisions}});
 310
 311                 $max_rev_num = ($lastrev->{revid} > $max_rev_num ? $lastrev->{revid} : $max_rev_num);
 312         }
 313
 314         print STDERR "Last remote revision found is $max_rev_num.\n";
 315         return $max_rev_num;
 316 }
 317
 318 # Clean content before sending it to MediaWiki
 319 sub mediawiki_clean {
 320         my $string = shift;
 321         my $page_created = shift;
 322         # Mediawiki does not allow blank space at the end of a page and ends with a single \n.
 323         # This function right trims a string and adds a \n at the end to follow this rule
 324         $string =~ s/\s+$//;
 325         if ($string eq "" && $page_created) {
 326                 # Creating empty pages is forbidden.
 327                 $string = EMPTY_CONTENT;
 328         }
 329         return $string."\n";
 330 }
 331
 332 # Filter applied on MediaWiki data before adding them to Git
 333 sub mediawiki_smudge {
 334         my $string = shift;
 335         if ($string eq EMPTY_CONTENT) {
 336                 $string = "";
 337         }
 338         # This \n is important. This is due to mediawiki's way to handle end of files.
 339         return $string."\n";
 340 }
 341
 342 sub mediawiki_clean_filename {
 343         my $filename = shift;
 344         $filename =~ s/@{[SLASH_REPLACEMENT]}/\//g;
 345         # [, ], |, {, and } are forbidden by MediaWiki, even URL-encoded.
 346         # Do a variant of URL-encoding, i.e. looks like URL-encoding,
 347         # but with _ added to prevent MediaWiki from thinking this is
 348         # an actual special character.
 349         $filename =~ s/[\[\]\{\}\|]/sprintf("_%%_%x", ord($&))/ge;
 350         # If we use the uri escape before
 351         # we should unescape here, before anything
 352
 353         return $filename;
 354 }
 355
 356 sub mediawiki_smudge_filename {
 357         my $filename = shift;
 358         $filename =~ s/\//@{[SLASH_REPLACEMENT]}/g;
 359         $filename =~ s/ /_/g;
 360         # Decode forbidden characters encoded in mediawiki_clean_filename
 361         $filename =~ s/_%_([0-9a-fA-F][0-9a-fA-F])/sprintf("%c", hex($1))/ge;
 362         return $filename;
 363 }
 364
 365 sub literal_data {
 366         my ($content) = @_;
 367         print STDOUT "data ", bytes::length($content), "\n", $content;
 368 }
 369
 370 sub mw_capabilities {
 371         # Revisions are imported to the private namespace
 372         # refs/mediawiki/$remotename/ by the helper and fetched into
 373         # refs/remotes/$remotename later by fetch.
 374         print STDOUT "refspec refs/heads/*:refs/mediawiki/$remotename/*\n";
 375         print STDOUT "import\n";
 376         print STDOUT "list\n";
 377         print STDOUT "push\n";
 378         print STDOUT "\n";
 379 }
 380
 381 sub mw_list {
 382         # MediaWiki do not have branches, we consider one branch arbitrarily
 383         # called master, and HEAD pointing to it.
 384         print STDOUT "? refs/heads/master\n";
 385         print STDOUT "\@refs/heads/master HEAD\n";
 386         print STDOUT "\n";
 387 }
 388
 389 sub mw_option {
 390         print STDERR "remote-helper command 'option $_[0]' not yet implemented\n";
 391         print STDOUT "unsupported\n";
 392 }
 393
 394 sub fetch_mw_revisions_for_page {
 395         my $page = shift;
 396         my $id = shift;
 397         my $fetch_from = shift;
 398         my @page_revs = ();
 399         my $query = {
 400                 action => 'query',
 401                 prop => 'revisions',
 402                 rvprop => 'ids',
 403                 rvdir => 'newer',
 404                 rvstartid => $fetch_from,
 405                 rvlimit => 500,
 406                 pageids => $id,
 407         };
 408
 409         my $revnum = 0;
 410         # Get 500 revisions at a time due to the mediawiki api limit
 411         while (1) {
 412                 my $result = $mediawiki->api($query);
 413
 414                 # Parse each of those 500 revisions
 415                 foreach my $revision (@{$result->{query}->{pages}->{$id}->{revisions}}) {
 416                         my $page_rev_ids;
 417                         $page_rev_ids->{pageid} = $page->{pageid};
 418                         $page_rev_ids->{revid} = $revision->{revid};
 419                         push(@page_revs, $page_rev_ids);
 420                         $revnum++;
 421                 }
 422                 last unless $result->{'query-continue'};
 423                 $query->{rvstartid} = $result->{'query-continue'}->{revisions}->{rvstartid};
 424         }
 425         if ($shallow_import && @page_revs) {
 426                 print STDERR "  Found 1 revision (shallow import).\n";
 427                 @page_revs = sort {$b->{revid} <=> $a->{revid}} (@page_revs);
 428                 return $page_revs[0];
 429         }
 430         print STDERR "  Found ", $revnum, " revision(s).\n";
 431         return @page_revs;
 432 }
 433
 434 sub fetch_mw_revisions {
 435         my $pages = shift; my @pages = @{$pages};
 436         my $fetch_from = shift;
 437
 438         my @revisions = ();
 439         my $n = 1;
 440         foreach my $page (@pages) {
 441                 my $id = $page->{pageid};
 442
 443                 print STDERR "page $n/", scalar(@pages), ": ". $page->{title} ."\n";
 444                 $n++;
 445                 my @page_revs = fetch_mw_revisions_for_page($page, $id, $fetch_from);
 446                 @revisions = (@page_revs, @revisions);
 447         }
 448
 449         return ($n, @revisions);
 450 }
 451
 452 sub import_file_revision {
 453         my $commit = shift;
 454         my %commit = %{$commit};
 455         my $full_import = shift;
 456         my $n = shift;
 457
 458         my $title = $commit{title};
 459         my $comment = $commit{comment};
 460         my $content = $commit{content};
 461         my $author = $commit{author};
 462         my $date = $commit{date};
 463
 464         print STDOUT "commit refs/mediawiki/$remotename/master\n";
 465         print STDOUT "mark :$n\n";
 466         print STDOUT "committer $author <$author\@$wiki_name> ", $date->epoch, " +0000\n";
 467         literal_data($comment);
 468
 469         # If it's not a clone, we need to know where to start from
 470         if (!$full_import && $n == 1) {
 471                 print STDOUT "from refs/mediawiki/$remotename/master^0\n";
 472         }
 473         if ($content ne DELETED_CONTENT) {
 474                 print STDOUT "M 644 inline $title.mw\n";
 475                 literal_data($content);
 476                 print STDOUT "\n\n";
 477         } else {
 478                 print STDOUT "D $title.mw\n";
 479         }
 480
 481         # mediawiki revision number in the git note
 482         if ($full_import && $n == 1) {
 483                 print STDOUT "reset refs/notes/$remotename/mediawiki\n";
 484         }
 485         print STDOUT "commit refs/notes/$remotename/mediawiki\n";
 486         print STDOUT "committer $author <$author\@$wiki_name> ", $date->epoch, " +0000\n";
 487         literal_data("Note added by git-mediawiki during import");
 488         if (!$full_import && $n == 1) {
 489                 print STDOUT "from refs/notes/$remotename/mediawiki^0\n";
 490         }
 491         print STDOUT "N inline :$n\n";
 492         literal_data("mediawiki_revision: " . $commit{mw_revision});
 493         print STDOUT "\n\n";
 494 }
 495
 496 # parse a sequence of
 497 # <cmd> <arg1>
 498 # <cmd> <arg2>
 499 # \n
 500 # (like batch sequence of import and sequence of push statements)
 501 sub get_more_refs {
 502         my $cmd = shift;
 503         my @refs;
 504         while (1) {
 505                 my $line = <STDIN>;
 506                 if ($line =~ m/^$cmd (.*)$/) {
 507                         push(@refs, $1);
 508                 } elsif ($line eq "\n") {
 509                         return @refs;
 510                 } else {
 511                         die("Invalid command in a '$cmd' batch: ". $_);
 512                 }
 513         }
 514 }
 515
 516 sub mw_import {
 517         # multiple import commands can follow each other.
 518         my @refs = (shift, get_more_refs("import"));
 519         foreach my $ref (@refs) {
 520                 mw_import_ref($ref);
 521         }
 522         print STDOUT "done\n";
 523 }
 524
 525 sub mw_import_ref {
 526         my $ref = shift;
 527         # The remote helper will call "import HEAD" and
 528         # "import refs/heads/master".
 529         # Since HEAD is a symbolic ref to master (by convention,
 530         # followed by the output of the command "list" that we gave),
 531         # we don't need to do anything in this case.
 532         if ($ref eq "HEAD") {
 533                 return;
 534         }
 535
 536         mw_connect_maybe();
 537
 538         my @pages = get_mw_pages();
 539
 540         print STDERR "Searching revisions...\n";
 541         my $last_local = get_last_local_revision();
 542         my $fetch_from = $last_local + 1;
 543         if ($fetch_from == 1) {
 544                 print STDERR ", fetching from beginning.\n";
 545         } else {
 546                 print STDERR ", fetching from here.\n";
 547         }
 548         my ($n, @revisions) = fetch_mw_revisions(\@pages, $fetch_from);
 549
 550         # Creation of the fast-import stream
 551         print STDERR "Fetching & writing export data...\n";
 552
 553         $n = 0;
 554         my $last_timestamp = 0; # Placeholer in case $rev->timestamp is undefined
 555
 556         foreach my $pagerevid (sort {$a->{revid} <=> $b->{revid}} @revisions) {
 557                 # fetch the content of the pages
 558                 my $query = {
 559                         action => 'query',
 560                         prop => 'revisions',
 561                         rvprop => 'content|timestamp|comment|user|ids',
 562                         revids => $pagerevid->{revid},
 563                 };
 564
 565                 my $result = $mediawiki->api($query);
 566
 567                 my $rev = pop(@{$result->{query}->{pages}->{$pagerevid->{pageid}}->{revisions}});
 568
 569                 $n++;
 570
 571                 my %commit;
 572                 $commit{author} = $rev->{user} || 'Anonymous';
 573                 $commit{comment} = $rev->{comment} || '*Empty MediaWiki Message*';
 574                 $commit{title} = mediawiki_smudge_filename(
 575                         $result->{query}->{pages}->{$pagerevid->{pageid}}->{title}
 576                     );
 577                 $commit{mw_revision} = $pagerevid->{revid};
 578                 $commit{content} = mediawiki_smudge($rev->{'*'});
 579
 580                 if (!defined($rev->{timestamp})) {
 581                         $last_timestamp++;
 582                 } else {
 583                         $last_timestamp = $rev->{timestamp};
 584                 }
 585                 $commit{date} = DateTime::Format::ISO8601->parse_datetime($last_timestamp);
 586
 587                 print STDERR "$n/", scalar(@revisions), ": Revision #$pagerevid->{revid} of $commit{title}\n";
 588
 589                 import_file_revision(\%commit, ($fetch_from == 1), $n);
 590         }
 591
 592         if ($fetch_from == 1 && $n == 0) {
 593                 print STDERR "You appear to have cloned an empty MediaWiki.\n";
 594                 # Something has to be done remote-helper side. If nothing is done, an error is
 595                 # thrown saying that HEAD is refering to unknown object 0000000000000000000
 596                 # and the clone fails.
 597         }
 598 }
 599
 600 sub error_non_fast_forward {
 601         # Native git-push would show this after the summary.
 602         # We can't ask it to display it cleanly, so print it
 603         # ourselves before.
 604         print STDERR "To prevent you from losing history, non-fast-forward updates were rejected\n";
 605         print STDERR "Merge the remote changes (e.g. 'git pull') before pushing again. See the\n";
 606         print STDERR "'Note about fast-forwards' section of 'git push --help' for details.\n";
 607
 608         print STDOUT "error $_[0] \"non-fast-forward\"\n";
 609         return 0;
 610 }
 611
 612 sub mw_push_file {
 613         my $diff_info = shift;
 614         # $diff_info contains a string in this format:
 615         # 100644 100644 <sha1_of_blob_before_commit> <sha1_of_blob_now> <status>
 616         my @diff_info_split = split(/[ \t]/, $diff_info);
 617
 618         # Filename, including .mw extension
 619         my $complete_file_name = shift;
 620         # Commit message
 621         my $summary = shift;
 622         # MediaWiki revision number. Keep the previous one by default,
 623         # in case there's no edit to perform.
 624         my $newrevid = shift;
 625
 626         my $new_sha1 = $diff_info_split[3];
 627         my $old_sha1 = $diff_info_split[2];
 628         my $page_created = ($old_sha1 eq NULL_SHA1);
 629         my $page_deleted = ($new_sha1 eq NULL_SHA1);
 630         $complete_file_name = mediawiki_clean_filename($complete_file_name);
 631
 632         if (substr($complete_file_name,-3) eq ".mw") {
 633                 my $title = substr($complete_file_name,0,-3);
 634
 635                 my $file_content;
 636                 if ($page_deleted) {
 637                         # Deleting a page usually requires
 638                         # special priviledges. A common
 639                         # convention is to replace the page
 640                         # with this content instead:
 641                         $file_content = DELETED_CONTENT;
 642                 } else {
 643                         $file_content = run_git("cat-file blob $new_sha1");
 644                 }
 645
 646                 mw_connect_maybe();
 647
 648                 my $result = $mediawiki->edit( {
 649                         action => 'edit',
 650                         summary => $summary,
 651                         title => $title,
 652                         text => mediawiki_clean($file_content, $page_created),
 653                                   }, {
 654                                           skip_encoding => 1 # Helps with names with accentuated characters
 655                                   }) || die 'Fatal: Error ' .
 656                                   $mediawiki->{error}->{code} .
 657                                   ' from mediwiki: ' . $mediawiki->{error}->{details};
 658                 $newrevid = $result->{edit}->{newrevid};
 659                 print STDERR "Pushed file : $new_sha1 - $title\n";
 660         } else {
 661                 print STDERR "$complete_file_name not a mediawiki file (Not pushable on this version of git-remote-mediawiki).\n"
 662         }
 663         return $newrevid;
 664 }
 665
 666 sub mw_push {
 667         # multiple push statements can follow each other
 668         my @refsspecs = (shift, get_more_refs("push"));
 669         my %status;
 670         my $pushed;
 671         for my $refspec (@refsspecs) {
 672                 my ($force, $local, $remote) = $refspec =~ /^(\+)?([^:]*):([^:]*)$/
 673                     or die("Invalid refspec for push. Expected <src>:<dst> or +<src>:<dst>");
 674                 if ($force) {
 675                         print STDERR "Warning: forced push not allowed on a MediaWiki.\n";
 676                 }
 677                 if ($local eq "") {
 678                         print STDERR "Cannot delete remote branch on a MediaWiki\n";
 679                         print STDOUT "error $remote cannot delete\n";
 680                         next;
 681                 }
 682                 if ($remote ne "refs/heads/master") {
 683                         print STDERR "Only push to the branch 'master' is supported on a MediaWiki\n";
 684                         print STDOUT "error $remote only master allowed\n";
 685                         next;
 686                 }
 687                 if (mw_push_revision($local, $remote)) {
 688                         $pushed = 1;
 689                 }
 690         }
 691
 692         # Notify Git that the push is done
 693         print STDOUT "\n";
 694
 695         if ($pushed && $dumb_push) {
 696                 print STDERR "Just pushed some revisions to MediaWiki.\n";
 697                 print STDERR "The pushed revisions now have to be re-imported, and your current branch\n";
 698                 print STDERR "needs to be updated with these re-imported commits. You can do this with\n";
 699                 print STDERR "\n";
 700                 print STDERR "  git pull --rebase\n";
 701                 print STDERR "\n";
 702         }
 703 }
 704
 705 sub mw_push_revision {
 706         my $local = shift;
 707         my $remote = shift; # actually, this has to be "refs/heads/master" at this point.
 708         my $last_local_revid = get_last_local_revision();
 709         print STDERR ".\n"; # Finish sentence started by get_last_local_revision()
 710         my $last_remote_revid = get_last_remote_revision();
 711         my $mw_revision = $last_remote_revid;
 712
 713         # Get sha1 of commit pointed by local HEAD
 714         my $HEAD_sha1 = run_git("rev-parse $local 2>/dev/null"); chomp($HEAD_sha1);
 715         # Get sha1 of commit pointed by remotes/$remotename/master
 716         my $remoteorigin_sha1 = run_git("rev-parse refs/remotes/$remotename/master 2>/dev/null");
 717         chomp($remoteorigin_sha1);
 718
 719         if ($last_local_revid > 0 &&
 720             $last_local_revid < $last_remote_revid) {
 721                 return error_non_fast_forward($remote);
 722         }
 723
 724         if ($HEAD_sha1 eq $remoteorigin_sha1) {
 725                 # nothing to push
 726                 return 0;
 727         }
 728
 729         # Get every commit in between HEAD and refs/remotes/origin/master,
 730         # including HEAD and refs/remotes/origin/master
 731         my @commit_pairs = ();
 732         if ($last_local_revid > 0) {
 733                 my $parsed_sha1 = $remoteorigin_sha1;
 734                 # Find a path from last MediaWiki commit to pushed commit
 735                 while ($parsed_sha1 ne $HEAD_sha1) {
 736                         my @commit_info =  grep(/^$parsed_sha1/, split(/\n/, run_git("rev-list --children $local")));
 737                         if (!@commit_info) {
 738                                 return error_non_fast_forward($remote);
 739                         }
 740                         my @commit_info_split = split(/ |\n/, $commit_info[0]);
 741                         # $commit_info_split[1] is the sha1 of the commit to export
 742                         # $commit_info_split[0] is the sha1 of its direct child
 743                         push(@commit_pairs, \@commit_info_split);
 744                         $parsed_sha1 = $commit_info_split[1];
 745                 }
 746         } else {
 747                 # No remote mediawiki revision. Export the whole
 748                 # history (linearized with --first-parent)
 749                 print STDERR "Warning: no common ancestor, pushing complete history\n";
 750                 my $history = run_git("rev-list --first-parent --children $local");
 751                 my @history = split('\n', $history);
 752                 @history = @history[1..$#history];
 753                 foreach my $line (reverse @history) {
 754                         my @commit_info_split = split(/ |\n/, $line);
 755                         push(@commit_pairs, \@commit_info_split);
 756                 }
 757         }
 758
 759         foreach my $commit_info_split (@commit_pairs) {
 760                 my $sha1_child = @{$commit_info_split}[0];
 761                 my $sha1_commit = @{$commit_info_split}[1];
 762                 my $diff_infos = run_git("diff-tree -r --raw -z $sha1_child $sha1_commit");
 763                 # TODO: we could detect rename, and encode them with a #redirect on the wiki.
 764                 # TODO: for now, it's just a delete+add
 765                 my @diff_info_list = split(/\0/, $diff_infos);
 766                 # Keep the first line of the commit message as mediawiki comment for the revision
 767                 my $commit_msg = (split(/\n/, run_git("show --pretty=format:\"%s\" $sha1_commit")))[0];
 768                 chomp($commit_msg);
 769                 # Push every blob
 770                 while (@diff_info_list) {
 771                         # git diff-tree -z gives an output like
 772                         # <metadata>\0<filename1>\0
 773                         # <metadata>\0<filename2>\0
 774                         # and we've split on \0.
 775                         my $info = shift(@diff_info_list);
 776                         my $file = shift(@diff_info_list);
 777                         $mw_revision = mw_push_file($info, $file, $commit_msg, $mw_revision);
 778                 }
 779                 unless ($dumb_push) {
 780                         run_git("notes --ref=$remotename/mediawiki add -m \"mediawiki_revision: $mw_revision\" $sha1_commit");
 781                         run_git("update-ref -m \"Git-MediaWiki push\" refs/mediawiki/$remotename/master $sha1_commit $sha1_child");
 782                 }
 783         }
 784
 785         print STDOUT "ok $remote\n";
 786         return 1;
 787 }