git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3 exec wish "$0" -- "$@"
   4
   5 set appvers {@@GIT_VERSION@@}
   6 set copyright {
   7 Copyright © 2006, 2007 Shawn Pearce, Paul Mackerras.
   8
   9 This program is free software; you can redistribute it and/or modify
  10 it under the terms of the GNU General Public License as published by
  11 the Free Software Foundation; either version 2 of the License, or
  12 (at your option) any later version.
  13
  14 This program is distributed in the hope that it will be useful,
  15 but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 GNU General Public License for more details.
  18
  19 You should have received a copy of the GNU General Public License
  20 along with this program; if not, write to the Free Software
  21 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  22
  23 ######################################################################
  24 ##
  25 ## read only globals
  26
  27 set _appname [lindex [file split $argv0] end]
  28 set _gitdir {}
  29 set _reponame {}
  30
  31 proc appname {} {
  32         global _appname
  33         return $_appname
  34 }
  35
  36 proc gitdir {args} {
  37         global _gitdir
  38         if {$args eq {}} {
  39                 return $_gitdir
  40         }
  41         return [eval [concat [list file join $_gitdir] $args]]
  42 }
  43
  44 proc reponame {} {
  45         global _reponame
  46         return $_reponame
  47 }
  48
  49 ######################################################################
  50 ##
  51 ## config
  52
  53 proc is_many_config {name} {
  54         switch -glob -- $name {
  55         remote.*.fetch -
  56         remote.*.push
  57                 {return 1}
  58         *
  59                 {return 0}
  60         }
  61 }
  62
  63 proc load_config {include_global} {
  64         global repo_config global_config default_config
  65
  66         array unset global_config
  67         if {$include_global} {
  68                 catch {
  69                         set fd_rc [open "| git repo-config --global --list" r]
  70                         while {[gets $fd_rc line] >= 0} {
  71                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  72                                         if {[is_many_config $name]} {
  73                                                 lappend global_config($name) $value
  74                                         } else {
  75                                                 set global_config($name) $value
  76                                         }
  77                                 }
  78                         }
  79                         close $fd_rc
  80                 }
  81         }
  82
  83         array unset repo_config
  84         catch {
  85                 set fd_rc [open "| git repo-config --list" r]
  86                 while {[gets $fd_rc line] >= 0} {
  87                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
  88                                 if {[is_many_config $name]} {
  89                                         lappend repo_config($name) $value
  90                                 } else {
  91                                         set repo_config($name) $value
  92                                 }
  93                         }
  94                 }
  95                 close $fd_rc
  96         }
  97
  98         foreach name [array names default_config] {
  99                 if {[catch {set v $global_config($name)}]} {
 100                         set global_config($name) $default_config($name)
 101                 }
 102                 if {[catch {set v $repo_config($name)}]} {
 103                         set repo_config($name) $default_config($name)
 104                 }
 105         }
 106 }
 107
 108 proc save_config {} {
 109         global default_config font_descs
 110         global repo_config global_config
 111         global repo_config_new global_config_new
 112
 113         foreach option $font_descs {
 114                 set name [lindex $option 0]
 115                 set font [lindex $option 1]
 116                 font configure $font \
 117                         -family $global_config_new(gui.$font^^family) \
 118                         -size $global_config_new(gui.$font^^size)
 119                 font configure ${font}bold \
 120                         -family $global_config_new(gui.$font^^family) \
 121                         -size $global_config_new(gui.$font^^size)
 122                 set global_config_new(gui.$name) [font configure $font]
 123                 unset global_config_new(gui.$font^^family)
 124                 unset global_config_new(gui.$font^^size)
 125         }
 126
 127         foreach name [array names default_config] {
 128                 set value $global_config_new($name)
 129                 if {$value ne $global_config($name)} {
 130                         if {$value eq $default_config($name)} {
 131                                 catch {exec git repo-config --global --unset $name}
 132                         } else {
 133                                 regsub -all "\[{}\]" $value {"} value
 134                                 exec git repo-config --global $name $value
 135                         }
 136                         set global_config($name) $value
 137                         if {$value eq $repo_config($name)} {
 138                                 catch {exec git repo-config --unset $name}
 139                                 set repo_config($name) $value
 140                         }
 141                 }
 142         }
 143
 144         foreach name [array names default_config] {
 145                 set value $repo_config_new($name)
 146                 if {$value ne $repo_config($name)} {
 147                         if {$value eq $global_config($name)} {
 148                                 catch {exec git repo-config --unset $name}
 149                         } else {
 150                                 regsub -all "\[{}\]" $value {"} value
 151                                 exec git repo-config $name $value
 152                         }
 153                         set repo_config($name) $value
 154                 }
 155         }
 156 }
 157
 158 proc error_popup {msg} {
 159         set title [appname]
 160         if {[reponame] ne {}} {
 161                 append title " ([reponame])"
 162         }
 163         set cmd [list tk_messageBox \
 164                 -icon error \
 165                 -type ok \
 166                 -title "$title: error" \
 167                 -message $msg]
 168         if {[winfo ismapped .]} {
 169                 lappend cmd -parent .
 170         }
 171         eval $cmd
 172 }
 173
 174 proc warn_popup {msg} {
 175         set title [appname]
 176         if {[reponame] ne {}} {
 177                 append title " ([reponame])"
 178         }
 179         set cmd [list tk_messageBox \
 180                 -icon warning \
 181                 -type ok \
 182                 -title "$title: warning" \
 183                 -message $msg]
 184         if {[winfo ismapped .]} {
 185                 lappend cmd -parent .
 186         }
 187         eval $cmd
 188 }
 189
 190 proc info_popup {msg} {
 191         set title [appname]
 192         if {[reponame] ne {}} {
 193                 append title " ([reponame])"
 194         }
 195         tk_messageBox \
 196                 -parent . \
 197                 -icon info \
 198                 -type ok \
 199                 -title $title \
 200                 -message $msg
 201 }
 202
 203 proc ask_popup {msg} {
 204         set title [appname]
 205         if {[reponame] ne {}} {
 206                 append title " ([reponame])"
 207         }
 208         return [tk_messageBox \
 209                 -parent . \
 210                 -icon question \
 211                 -type yesno \
 212                 -title $title \
 213                 -message $msg]
 214 }
 215
 216 ######################################################################
 217 ##
 218 ## repository setup
 219
 220 if {   [catch {set _gitdir $env(GIT_DIR)}]
 221         && [catch {set _gitdir [exec git rev-parse --git-dir]} err]} {
 222         catch {wm withdraw .}
 223         error_popup "Cannot find the git directory:\n\n$err"
 224         exit 1
 225 }
 226 if {![file isdirectory $_gitdir]} {
 227         catch {wm withdraw .}
 228         error_popup "Git directory not found:\n\n$_gitdir"
 229         exit 1
 230 }
 231 if {[lindex [file split $_gitdir] end] ne {.git}} {
 232         catch {wm withdraw .}
 233         error_popup "Cannot use funny .git directory:\n\n$gitdir"
 234         exit 1
 235 }
 236 if {[catch {cd [file dirname $_gitdir]} err]} {
 237         catch {wm withdraw .}
 238         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 239         exit 1
 240 }
 241 set _reponame [lindex [file split \
 242         [file normalize [file dirname $_gitdir]]] \
 243         end]
 244
 245 set single_commit 0
 246 if {[appname] eq {git-citool}} {
 247         set single_commit 1
 248 }
 249
 250 ######################################################################
 251 ##
 252 ## task management
 253
 254 set rescan_active 0
 255 set diff_active 0
 256 set last_clicked {}
 257
 258 set disable_on_lock [list]
 259 set index_lock_type none
 260
 261 proc lock_index {type} {
 262         global index_lock_type disable_on_lock
 263
 264         if {$index_lock_type eq {none}} {
 265                 set index_lock_type $type
 266                 foreach w $disable_on_lock {
 267                         uplevel #0 $w disabled
 268                 }
 269                 return 1
 270         } elseif {$index_lock_type eq "begin-$type"} {
 271                 set index_lock_type $type
 272                 return 1
 273         }
 274         return 0
 275 }
 276
 277 proc unlock_index {} {
 278         global index_lock_type disable_on_lock
 279
 280         set index_lock_type none
 281         foreach w $disable_on_lock {
 282                 uplevel #0 $w normal
 283         }
 284 }
 285
 286 ######################################################################
 287 ##
 288 ## status
 289
 290 proc repository_state {ctvar hdvar mhvar} {
 291         global current_branch
 292         upvar $ctvar ct $hdvar hd $mhvar mh
 293
 294         set mh [list]
 295
 296         if {[catch {set current_branch [exec git symbolic-ref HEAD]}]} {
 297                 set current_branch {}
 298         } else {
 299                 regsub ^refs/((heads|tags|remotes)/)? \
 300                         $current_branch \
 301                         {} \
 302                         current_branch
 303         }
 304
 305         if {[catch {set hd [exec git rev-parse --verify HEAD]}]} {
 306                 set hd {}
 307                 set ct initial
 308                 return
 309         }
 310
 311         set merge_head [gitdir MERGE_HEAD]
 312         if {[file exists $merge_head]} {
 313                 set ct merge
 314                 set fd_mh [open $merge_head r]
 315                 while {[gets $fd_mh line] >= 0} {
 316                         lappend mh $line
 317                 }
 318                 close $fd_mh
 319                 return
 320         }
 321
 322         set ct normal
 323 }
 324
 325 proc PARENT {} {
 326         global PARENT empty_tree
 327
 328         set p [lindex $PARENT 0]
 329         if {$p ne {}} {
 330                 return $p
 331         }
 332         if {$empty_tree eq {}} {
 333                 set empty_tree [exec git mktree << {}]
 334         }
 335         return $empty_tree
 336 }
 337
 338 proc rescan {after} {
 339         global HEAD PARENT MERGE_HEAD commit_type
 340         global ui_index ui_workdir ui_status_value ui_comm
 341         global rescan_active file_states
 342         global repo_config
 343
 344         if {$rescan_active > 0 || ![lock_index read]} return
 345
 346         repository_state newType newHEAD newMERGE_HEAD
 347         if {[string match amend* $commit_type]
 348                 && $newType eq {normal}
 349                 && $newHEAD eq $HEAD} {
 350         } else {
 351                 set HEAD $newHEAD
 352                 set PARENT $newHEAD
 353                 set MERGE_HEAD $newMERGE_HEAD
 354                 set commit_type $newType
 355         }
 356
 357         array unset file_states
 358
 359         if {![$ui_comm edit modified]
 360                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 361                 if {[load_message GITGUI_MSG]} {
 362                 } elseif {[load_message MERGE_MSG]} {
 363                 } elseif {[load_message SQUASH_MSG]} {
 364                 }
 365                 $ui_comm edit reset
 366                 $ui_comm edit modified false
 367         }
 368
 369         if {$repo_config(gui.trustmtime) eq {true}} {
 370                 rescan_stage2 {} $after
 371         } else {
 372                 set rescan_active 1
 373                 set ui_status_value {Refreshing file status...}
 374                 set cmd [list git update-index]
 375                 lappend cmd -q
 376                 lappend cmd --unmerged
 377                 lappend cmd --ignore-missing
 378                 lappend cmd --refresh
 379                 set fd_rf [open "| $cmd" r]
 380                 fconfigure $fd_rf -blocking 0 -translation binary
 381                 fileevent $fd_rf readable \
 382                         [list rescan_stage2 $fd_rf $after]
 383         }
 384 }
 385
 386 proc rescan_stage2 {fd after} {
 387         global ui_status_value
 388         global rescan_active buf_rdi buf_rdf buf_rlo
 389
 390         if {$fd ne {}} {
 391                 read $fd
 392                 if {![eof $fd]} return
 393                 close $fd
 394         }
 395
 396         set ls_others [list | git ls-files --others -z \
 397                 --exclude-per-directory=.gitignore]
 398         set info_exclude [gitdir info exclude]
 399         if {[file readable $info_exclude]} {
 400                 lappend ls_others "--exclude-from=$info_exclude"
 401         }
 402
 403         set buf_rdi {}
 404         set buf_rdf {}
 405         set buf_rlo {}
 406
 407         set rescan_active 3
 408         set ui_status_value {Scanning for modified files ...}
 409         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 410         set fd_df [open "| git diff-files -z" r]
 411         set fd_lo [open $ls_others r]
 412
 413         fconfigure $fd_di -blocking 0 -translation binary
 414         fconfigure $fd_df -blocking 0 -translation binary
 415         fconfigure $fd_lo -blocking 0 -translation binary
 416         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 417         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 418         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 419 }
 420
 421 proc load_message {file} {
 422         global ui_comm
 423
 424         set f [gitdir $file]
 425         if {[file isfile $f]} {
 426                 if {[catch {set fd [open $f r]}]} {
 427                         return 0
 428                 }
 429                 set content [string trim [read $fd]]
 430                 close $fd
 431                 $ui_comm delete 0.0 end
 432                 $ui_comm insert end $content
 433                 return 1
 434         }
 435         return 0
 436 }
 437
 438 proc read_diff_index {fd after} {
 439         global buf_rdi
 440
 441         append buf_rdi [read $fd]
 442         set c 0
 443         set n [string length $buf_rdi]
 444         while {$c < $n} {
 445                 set z1 [string first "\0" $buf_rdi $c]
 446                 if {$z1 == -1} break
 447                 incr z1
 448                 set z2 [string first "\0" $buf_rdi $z1]
 449                 if {$z2 == -1} break
 450
 451                 incr c
 452                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 453                 merge_state \
 454                         [string range $buf_rdi $z1 [expr {$z2 - 1}]] \
 455                         [lindex $i 4]? \
 456                         [list [lindex $i 0] [lindex $i 2]] \
 457                         [list]
 458                 set c $z2
 459                 incr c
 460         }
 461         if {$c < $n} {
 462                 set buf_rdi [string range $buf_rdi $c end]
 463         } else {
 464                 set buf_rdi {}
 465         }
 466
 467         rescan_done $fd buf_rdi $after
 468 }
 469
 470 proc read_diff_files {fd after} {
 471         global buf_rdf
 472
 473         append buf_rdf [read $fd]
 474         set c 0
 475         set n [string length $buf_rdf]
 476         while {$c < $n} {
 477                 set z1 [string first "\0" $buf_rdf $c]
 478                 if {$z1 == -1} break
 479                 incr z1
 480                 set z2 [string first "\0" $buf_rdf $z1]
 481                 if {$z2 == -1} break
 482
 483                 incr c
 484                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 485                 merge_state \
 486                         [string range $buf_rdf $z1 [expr {$z2 - 1}]] \
 487                         ?[lindex $i 4] \
 488                         [list] \
 489                         [list [lindex $i 0] [lindex $i 2]]
 490                 set c $z2
 491                 incr c
 492         }
 493         if {$c < $n} {
 494                 set buf_rdf [string range $buf_rdf $c end]
 495         } else {
 496                 set buf_rdf {}
 497         }
 498
 499         rescan_done $fd buf_rdf $after
 500 }
 501
 502 proc read_ls_others {fd after} {
 503         global buf_rlo
 504
 505         append buf_rlo [read $fd]
 506         set pck [split $buf_rlo "\0"]
 507         set buf_rlo [lindex $pck end]
 508         foreach p [lrange $pck 0 end-1] {
 509                 merge_state $p ?O
 510         }
 511         rescan_done $fd buf_rlo $after
 512 }
 513
 514 proc rescan_done {fd buf after} {
 515         global rescan_active
 516         global file_states repo_config
 517         upvar $buf to_clear
 518
 519         if {![eof $fd]} return
 520         set to_clear {}
 521         close $fd
 522         if {[incr rescan_active -1] > 0} return
 523
 524         prune_selection
 525         unlock_index
 526         display_all_files
 527
 528         if {$repo_config(gui.partialinclude) ne {true}} {
 529                 set pathList [list]
 530                 foreach path [array names file_states] {
 531                         switch -- [lindex $file_states($path) 0] {
 532                         A? -
 533                         M? {lappend pathList $path}
 534                         }
 535                 }
 536                 if {$pathList ne {}} {
 537                         update_index \
 538                                 "Updating included files" \
 539                                 $pathList \
 540                                 [concat {reshow_diff;} $after]
 541                         return
 542                 }
 543         }
 544
 545         reshow_diff
 546         uplevel #0 $after
 547 }
 548
 549 proc prune_selection {} {
 550         global file_states selected_paths
 551
 552         foreach path [array names selected_paths] {
 553                 if {[catch {set still_here $file_states($path)}]} {
 554                         unset selected_paths($path)
 555                 }
 556         }
 557 }
 558
 559 ######################################################################
 560 ##
 561 ## diff
 562
 563 proc clear_diff {} {
 564         global ui_diff current_diff ui_index ui_workdir
 565
 566         $ui_diff conf -state normal
 567         $ui_diff delete 0.0 end
 568         $ui_diff conf -state disabled
 569
 570         set current_diff {}
 571
 572         $ui_index tag remove in_diff 0.0 end
 573         $ui_workdir tag remove in_diff 0.0 end
 574 }
 575
 576 proc reshow_diff {} {
 577         global current_diff ui_status_value file_states
 578
 579         if {$current_diff eq {}
 580                 || [catch {set s $file_states($current_diff)}]} {
 581                 clear_diff
 582         } else {
 583                 show_diff $current_diff
 584         }
 585 }
 586
 587 proc handle_empty_diff {} {
 588         global current_diff file_states file_lists
 589
 590         set path $current_diff
 591         set s $file_states($path)
 592         if {[lindex $s 0] ne {_M}} return
 593
 594         info_popup "No differences detected.
 595
 596 [short_path $path] has no changes.
 597
 598 The modification date of this file was updated
 599 by another application and you currently have
 600 the Trust File Modification Timestamps option
 601 enabled, so Git did not automatically detect
 602 that there are no content differences in this
 603 file.
 604
 605 This file will now be removed from the modified
 606 files list, to prevent possible confusion.
 607 "
 608         if {[catch {exec git update-index -- $path} err]} {
 609                 error_popup "Failed to refresh index:\n\n$err"
 610         }
 611
 612         clear_diff
 613         display_file $path __
 614 }
 615
 616 proc show_diff {path {w {}} {lno {}}} {
 617         global file_states file_lists
 618         global is_3way_diff diff_active repo_config
 619         global ui_diff current_diff ui_status_value
 620
 621         if {$diff_active || ![lock_index read]} return
 622
 623         clear_diff
 624         if {$w eq {} || $lno == {}} {
 625                 foreach w [array names file_lists] {
 626                         set lno [lsearch -sorted $file_lists($w) $path]
 627                         if {$lno >= 0} {
 628                                 incr lno
 629                                 break
 630                         }
 631                 }
 632         }
 633         if {$w ne {} && $lno >= 1} {
 634                 $w tag add in_diff $lno.0 [expr {$lno + 1}].0
 635         }
 636
 637         set s $file_states($path)
 638         set m [lindex $s 0]
 639         set is_3way_diff 0
 640         set diff_active 1
 641         set current_diff $path
 642         set ui_status_value "Loading diff of [escape_path $path]..."
 643
 644         set cmd [list | git diff-index]
 645         lappend cmd --no-color
 646         if {$repo_config(gui.diffcontext) > 0} {
 647                 lappend cmd "-U$repo_config(gui.diffcontext)"
 648         }
 649         lappend cmd -p
 650
 651         switch $m {
 652         MM {
 653                 lappend cmd -c
 654         }
 655         _O {
 656                 if {[catch {
 657                                 set fd [open $path r]
 658                                 set content [read $fd]
 659                                 close $fd
 660                         } err ]} {
 661                         set diff_active 0
 662                         unlock_index
 663                         set ui_status_value "Unable to display [escape_path $path]"
 664                         error_popup "Error loading file:\n\n$err"
 665                         return
 666                 }
 667                 $ui_diff conf -state normal
 668                 $ui_diff insert end $content
 669                 $ui_diff conf -state disabled
 670                 set diff_active 0
 671                 unlock_index
 672                 set ui_status_value {Ready.}
 673                 return
 674         }
 675         }
 676
 677         lappend cmd [PARENT]
 678         lappend cmd --
 679         lappend cmd $path
 680
 681         if {[catch {set fd [open $cmd r]} err]} {
 682                 set diff_active 0
 683                 unlock_index
 684                 set ui_status_value "Unable to display [escape_path $path]"
 685                 error_popup "Error loading diff:\n\n$err"
 686                 return
 687         }
 688
 689         fconfigure $fd -blocking 0 -translation auto
 690         fileevent $fd readable [list read_diff $fd]
 691 }
 692
 693 proc read_diff {fd} {
 694         global ui_diff ui_status_value is_3way_diff diff_active
 695         global repo_config
 696
 697         $ui_diff conf -state normal
 698         while {[gets $fd line] >= 0} {
 699                 # -- Cleanup uninteresting diff header lines.
 700                 #
 701                 if {[string match {diff --git *}      $line]} continue
 702                 if {[string match {diff --combined *} $line]} continue
 703                 if {[string match {--- *}             $line]} continue
 704                 if {[string match {+++ *}             $line]} continue
 705                 if {$line eq {deleted file mode 120000}} {
 706                         set line "deleted symlink"
 707                 }
 708
 709                 # -- Automatically detect if this is a 3 way diff.
 710                 #
 711                 if {[string match {@@@ *} $line]} {set is_3way_diff 1}
 712
 713                 # -- Reformat a 3 way diff, 'cause its too weird.
 714                 #
 715                 if {$is_3way_diff} {
 716                         set op [string range $line 0 1]
 717                         switch -- $op {
 718                         {@@} {set tags d_@}
 719                         {++} {set tags d_+ ; set op { +}}
 720                         {--} {set tags d_- ; set op { -}}
 721                         { +} {set tags d_++; set op {++}}
 722                         { -} {set tags d_--; set op {--}}
 723                         {+ } {set tags d_-+; set op {-+}}
 724                         {- } {set tags d_+-; set op {+-}}
 725                         default {set tags {}}
 726                         }
 727                         set line [string replace $line 0 1 $op]
 728                 } else {
 729                         switch -- [string index $line 0] {
 730                         @ {set tags d_@}
 731                         + {set tags d_+}
 732                         - {set tags d_-}
 733                         default {set tags {}}
 734                         }
 735                 }
 736                 $ui_diff insert end $line $tags
 737                 $ui_diff insert end "\n" $tags
 738         }
 739         $ui_diff conf -state disabled
 740
 741         if {[eof $fd]} {
 742                 close $fd
 743                 set diff_active 0
 744                 unlock_index
 745                 set ui_status_value {Ready.}
 746
 747                 if {$repo_config(gui.trustmtime) eq {true}
 748                         && [$ui_diff index end] eq {2.0}} {
 749                         handle_empty_diff
 750                 }
 751         }
 752 }
 753
 754 ######################################################################
 755 ##
 756 ## commit
 757
 758 proc load_last_commit {} {
 759         global HEAD PARENT MERGE_HEAD commit_type ui_comm
 760
 761         if {[llength $PARENT] == 0} {
 762                 error_popup {There is nothing to amend.
 763
 764 You are about to create the initial commit.
 765 There is no commit before this to amend.
 766 }
 767                 return
 768         }
 769
 770         repository_state curType curHEAD curMERGE_HEAD
 771         if {$curType eq {merge}} {
 772                 error_popup {Cannot amend while merging.
 773
 774 You are currently in the middle of a merge that
 775 has not been fully completed.  You cannot amend
 776 the prior commit unless you first abort the
 777 current merge activity.
 778 }
 779                 return
 780         }
 781
 782         set msg {}
 783         set parents [list]
 784         if {[catch {
 785                         set fd [open "| git cat-file commit $curHEAD" r]
 786                         while {[gets $fd line] > 0} {
 787                                 if {[string match {parent *} $line]} {
 788                                         lappend parents [string range $line 7 end]
 789                                 }
 790                         }
 791                         set msg [string trim [read $fd]]
 792                         close $fd
 793                 } err]} {
 794                 error_popup "Error loading commit data for amend:\n\n$err"
 795                 return
 796         }
 797
 798         set HEAD $curHEAD
 799         set PARENT $parents
 800         set MERGE_HEAD [list]
 801         switch -- [llength $parents] {
 802         0       {set commit_type amend-initial}
 803         1       {set commit_type amend}
 804         default {set commit_type amend-merge}
 805         }
 806
 807         $ui_comm delete 0.0 end
 808         $ui_comm insert end $msg
 809         $ui_comm edit reset
 810         $ui_comm edit modified false
 811         rescan {set ui_status_value {Ready.}}
 812 }
 813
 814 proc create_new_commit {} {
 815         global commit_type ui_comm
 816
 817         set commit_type normal
 818         $ui_comm delete 0.0 end
 819         $ui_comm edit reset
 820         $ui_comm edit modified false
 821         rescan {set ui_status_value {Ready.}}
 822 }
 823
 824 set GIT_COMMITTER_IDENT {}
 825
 826 proc committer_ident {} {
 827         global GIT_COMMITTER_IDENT
 828
 829         if {$GIT_COMMITTER_IDENT eq {}} {
 830                 if {[catch {set me [exec git var GIT_COMMITTER_IDENT]} err]} {
 831                         error_popup "Unable to obtain your identity:\n\n$err"
 832                         return {}
 833                 }
 834                 if {![regexp {^(.*) [0-9]+ [-+0-9]+$} \
 835                         $me me GIT_COMMITTER_IDENT]} {
 836                         error_popup "Invalid GIT_COMMITTER_IDENT:\n\n$me"
 837                         return {}
 838                 }
 839         }
 840
 841         return $GIT_COMMITTER_IDENT
 842 }
 843
 844 proc commit_tree {} {
 845         global HEAD commit_type file_states ui_comm repo_config
 846
 847         if {![lock_index update]} return
 848         if {[committer_ident] eq {}} return
 849
 850         # -- Our in memory state should match the repository.
 851         #
 852         repository_state curType curHEAD curMERGE_HEAD
 853         if {[string match amend* $commit_type]
 854                 && $curType eq {normal}
 855                 && $curHEAD eq $HEAD} {
 856         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
 857                 info_popup {Last scanned state does not match repository state.
 858
 859 Another Git program has modified this repository
 860 since the last scan.  A rescan must be performed
 861 before another commit can be created.
 862
 863 The rescan will be automatically started now.
 864 }
 865                 unlock_index
 866                 rescan {set ui_status_value {Ready.}}
 867                 return
 868         }
 869
 870         # -- At least one file should differ in the index.
 871         #
 872         set files_ready 0
 873         foreach path [array names file_states] {
 874                 switch -glob -- [lindex $file_states($path) 0] {
 875                 _? {continue}
 876                 A? -
 877                 D? -
 878                 M? {set files_ready 1; break}
 879                 U? {
 880                         error_popup "Unmerged files cannot be committed.
 881
 882 File [short_path $path] has merge conflicts.
 883 You must resolve them and include the file before committing.
 884 "
 885                         unlock_index
 886                         return
 887                 }
 888                 default {
 889                         error_popup "Unknown file state [lindex $s 0] detected.
 890
 891 File [short_path $path] cannot be committed by this program.
 892 "
 893                 }
 894                 }
 895         }
 896         if {!$files_ready} {
 897                 error_popup {No included files to commit.
 898
 899 You must include at least 1 file before you can commit.
 900 }
 901                 unlock_index
 902                 return
 903         }
 904
 905         # -- A message is required.
 906         #
 907         set msg [string trim [$ui_comm get 1.0 end]]
 908         if {$msg eq {}} {
 909                 error_popup {Please supply a commit message.
 910
 911 A good commit message has the following format:
 912
 913 - First line: Describe in one sentance what you did.
 914 - Second line: Blank
 915 - Remaining lines: Describe why this change is good.
 916 }
 917                 unlock_index
 918                 return
 919         }
 920
 921         # -- Update included files if partialincludes are off.
 922         #
 923         if {$repo_config(gui.partialinclude) ne {true}} {
 924                 set pathList [list]
 925                 foreach path [array names file_states] {
 926                         switch -glob -- [lindex $file_states($path) 0] {
 927                         A? -
 928                         M? {lappend pathList $path}
 929                         }
 930                 }
 931                 if {$pathList ne {}} {
 932                         unlock_index
 933                         update_index \
 934                                 "Updating included files" \
 935                                 $pathList \
 936                                 [concat {lock_index update;} \
 937                                         [list commit_prehook $curHEAD $msg]]
 938                         return
 939                 }
 940         }
 941
 942         commit_prehook $curHEAD $msg
 943 }
 944
 945 proc commit_prehook {curHEAD msg} {
 946         global ui_status_value pch_error
 947
 948         set pchook [gitdir hooks pre-commit]
 949
 950         # On Cygwin [file executable] might lie so we need to ask
 951         # the shell if the hook is executable.  Yes that's annoying.
 952         #
 953         if {[is_Windows] && [file isfile $pchook]} {
 954                 set pchook [list sh -c [concat \
 955                         "if test -x \"$pchook\";" \
 956                         "then exec \"$pchook\" 2>&1;" \
 957                         "fi"]]
 958         } elseif {[file executable $pchook]} {
 959                 set pchook [list $pchook |& cat]
 960         } else {
 961                 commit_writetree $curHEAD $msg
 962                 return
 963         }
 964
 965         set ui_status_value {Calling pre-commit hook...}
 966         set pch_error {}
 967         set fd_ph [open "| $pchook" r]
 968         fconfigure $fd_ph -blocking 0 -translation binary
 969         fileevent $fd_ph readable \
 970                 [list commit_prehook_wait $fd_ph $curHEAD $msg]
 971 }
 972
 973 proc commit_prehook_wait {fd_ph curHEAD msg} {
 974         global pch_error ui_status_value
 975
 976         append pch_error [read $fd_ph]
 977         fconfigure $fd_ph -blocking 1
 978         if {[eof $fd_ph]} {
 979                 if {[catch {close $fd_ph}]} {
 980                         set ui_status_value {Commit declined by pre-commit hook.}
 981                         hook_failed_popup pre-commit $pch_error
 982                         unlock_index
 983                 } else {
 984                         commit_writetree $curHEAD $msg
 985                 }
 986                 set pch_error {}
 987                 return
 988         }
 989         fconfigure $fd_ph -blocking 0
 990 }
 991
 992 proc commit_writetree {curHEAD msg} {
 993         global ui_status_value
 994
 995         set ui_status_value {Committing changes...}
 996         set fd_wt [open "| git write-tree" r]
 997         fileevent $fd_wt readable \
 998                 [list commit_committree $fd_wt $curHEAD $msg]
 999 }
1000
1001 proc commit_committree {fd_wt curHEAD msg} {
1002         global HEAD PARENT MERGE_HEAD commit_type
1003         global single_commit
1004         global ui_status_value ui_comm selected_commit_type
1005         global file_states selected_paths rescan_active
1006
1007         gets $fd_wt tree_id
1008         if {$tree_id eq {} || [catch {close $fd_wt} err]} {
1009                 error_popup "write-tree failed:\n\n$err"
1010                 set ui_status_value {Commit failed.}
1011                 unlock_index
1012                 return
1013         }
1014
1015         # -- Create the commit.
1016         #
1017         set cmd [list git commit-tree $tree_id]
1018         set parents [concat $PARENT $MERGE_HEAD]
1019         if {[llength $parents] > 0} {
1020                 foreach p $parents {
1021                         lappend cmd -p $p
1022                 }
1023         } else {
1024                 # git commit-tree writes to stderr during initial commit.
1025                 lappend cmd 2>/dev/null
1026         }
1027         lappend cmd << $msg
1028         if {[catch {set cmt_id [eval exec $cmd]} err]} {
1029                 error_popup "commit-tree failed:\n\n$err"
1030                 set ui_status_value {Commit failed.}
1031                 unlock_index
1032                 return
1033         }
1034
1035         # -- Update the HEAD ref.
1036         #
1037         set reflogm commit
1038         if {$commit_type ne {normal}} {
1039                 append reflogm " ($commit_type)"
1040         }
1041         set i [string first "\n" $msg]
1042         if {$i >= 0} {
1043                 append reflogm {: } [string range $msg 0 [expr {$i - 1}]]
1044         } else {
1045                 append reflogm {: } $msg
1046         }
1047         set cmd [list git update-ref -m $reflogm HEAD $cmt_id $curHEAD]
1048         if {[catch {eval exec $cmd} err]} {
1049                 error_popup "update-ref failed:\n\n$err"
1050                 set ui_status_value {Commit failed.}
1051                 unlock_index
1052                 return
1053         }
1054
1055         # -- Cleanup after ourselves.
1056         #
1057         catch {file delete [gitdir MERGE_HEAD]}
1058         catch {file delete [gitdir MERGE_MSG]}
1059         catch {file delete [gitdir SQUASH_MSG]}
1060         catch {file delete [gitdir GITGUI_MSG]}
1061
1062         # -- Let rerere do its thing.
1063         #
1064         if {[file isdirectory [gitdir rr-cache]]} {
1065                 catch {exec git rerere}
1066         }
1067
1068         # -- Run the post-commit hook.
1069         #
1070         set pchook [gitdir hooks post-commit]
1071         if {[is_Windows] && [file isfile $pchook]} {
1072                 set pchook [list sh -c [concat \
1073                         "if test -x \"$pchook\";" \
1074                         "then exec \"$pchook\";" \
1075                         "fi"]]
1076         } elseif {![file executable $pchook]} {
1077                 set pchook {}
1078         }
1079         if {$pchook ne {}} {
1080                 catch {exec $pchook &}
1081         }
1082
1083         $ui_comm delete 0.0 end
1084         $ui_comm edit reset
1085         $ui_comm edit modified false
1086
1087         if {$single_commit} do_quit
1088
1089         # -- Update in memory status
1090         #
1091         set selected_commit_type new
1092         set commit_type normal
1093         set HEAD $cmt_id
1094         set PARENT $cmt_id
1095         set MERGE_HEAD [list]
1096
1097         foreach path [array names file_states] {
1098                 set s $file_states($path)
1099                 set m [lindex $s 0]
1100                 switch -glob -- $m {
1101                 _O -
1102                 _M -
1103                 _D {continue}
1104                 __ -
1105                 A_ -
1106                 M_ -
1107                 D_ {
1108                         unset file_states($path)
1109                         catch {unset selected_paths($path)}
1110                 }
1111                 DO {
1112                         set file_states($path) [list _O [lindex $s 1] {} {}]
1113                 }
1114                 AM -
1115                 AD -
1116                 MM -
1117                 MD {
1118                         set file_states($path) [list \
1119                                 _[string index $m 1] \
1120                                 [lindex $s 1] \
1121                                 [lindex $s 3] \
1122                                 {}]
1123                 }
1124                 }
1125         }
1126
1127         display_all_files
1128         unlock_index
1129         reshow_diff
1130         set ui_status_value \
1131                 "Changes committed as [string range $cmt_id 0 7]."
1132 }
1133
1134 ######################################################################
1135 ##
1136 ## fetch pull push
1137
1138 proc fetch_from {remote} {
1139         set w [new_console "fetch $remote" \
1140                 "Fetching new changes from $remote"]
1141         set cmd [list git fetch]
1142         lappend cmd $remote
1143         console_exec $w $cmd
1144 }
1145
1146 proc pull_remote {remote branch} {
1147         global HEAD commit_type file_states repo_config
1148
1149         if {![lock_index update]} return
1150
1151         # -- Our in memory state should match the repository.
1152         #
1153         repository_state curType curHEAD curMERGE_HEAD
1154         if {$commit_type ne $curType || $HEAD ne $curHEAD} {
1155                 info_popup {Last scanned state does not match repository state.
1156
1157 Another Git program has modified this repository
1158 since the last scan.  A rescan must be performed
1159 before a pull operation can be started.
1160
1161 The rescan will be automatically started now.
1162 }
1163                 unlock_index
1164                 rescan {set ui_status_value {Ready.}}
1165                 return
1166         }
1167
1168         # -- No differences should exist before a pull.
1169         #
1170         if {[array size file_states] != 0} {
1171                 error_popup {Uncommitted but modified files are present.
1172
1173 You should not perform a pull with unmodified
1174 files in your working directory as Git will be
1175 unable to recover from an incorrect merge.
1176
1177 You should commit or revert all changes before
1178 starting a pull operation.
1179 }
1180                 unlock_index
1181                 return
1182         }
1183
1184         set w [new_console "pull $remote $branch" \
1185                 "Pulling new changes from branch $branch in $remote"]
1186         set cmd [list git pull]
1187         if {$repo_config(gui.pullsummary) eq {false}} {
1188                 lappend cmd --no-summary
1189         }
1190         lappend cmd $remote
1191         lappend cmd $branch
1192         console_exec $w $cmd [list post_pull_remote $remote $branch]
1193 }
1194
1195 proc post_pull_remote {remote branch success} {
1196         global HEAD PARENT MERGE_HEAD commit_type selected_commit_type
1197         global ui_status_value
1198
1199         unlock_index
1200         if {$success} {
1201                 repository_state commit_type HEAD MERGE_HEAD
1202                 set PARENT $HEAD
1203                 set selected_commit_type new
1204                 set ui_status_value "Pulling $branch from $remote complete."
1205         } else {
1206                 rescan [list set ui_status_value \
1207                         "Conflicts detected while pulling $branch from $remote."]
1208         }
1209 }
1210
1211 proc push_to {remote} {
1212         set w [new_console "push $remote" \
1213                 "Pushing changes to $remote"]
1214         set cmd [list git push]
1215         lappend cmd $remote
1216         console_exec $w $cmd
1217 }
1218
1219 ######################################################################
1220 ##
1221 ## ui helpers
1222
1223 proc mapicon {w state path} {
1224         global all_icons
1225
1226         if {[catch {set r $all_icons($state$w)}]} {
1227                 puts "error: no icon for $w state={$state} $path"
1228                 return file_plain
1229         }
1230         return $r
1231 }
1232
1233 proc mapdesc {state path} {
1234         global all_descs
1235
1236         if {[catch {set r $all_descs($state)}]} {
1237                 puts "error: no desc for state={$state} $path"
1238                 return $state
1239         }
1240         return $r
1241 }
1242
1243 proc escape_path {path} {
1244         regsub -all "\n" $path "\\n" path
1245         return $path
1246 }
1247
1248 proc short_path {path} {
1249         return [escape_path [lindex [file split $path] end]]
1250 }
1251
1252 set next_icon_id 0
1253 set null_sha1 [string repeat 0 40]
1254
1255 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1256         global file_states next_icon_id null_sha1
1257
1258         set s0 [string index $new_state 0]
1259         set s1 [string index $new_state 1]
1260
1261         if {[catch {set info $file_states($path)}]} {
1262                 set state __
1263                 set icon n[incr next_icon_id]
1264         } else {
1265                 set state [lindex $info 0]
1266                 set icon [lindex $info 1]
1267                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1268                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1269         }
1270
1271         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1272         elseif {$s0 eq {_}} {set s0 _}
1273
1274         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1275         elseif {$s1 eq {_}} {set s1 _}
1276
1277         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1278                 set head_info [list 0 $null_sha1]
1279         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1280                 && $head_info eq {}} {
1281                 set head_info $index_info
1282         }
1283
1284         set file_states($path) [list $s0$s1 $icon \
1285                 $head_info $index_info \
1286                 ]
1287         return $state
1288 }
1289
1290 proc display_file_helper {w path icon_name old_m new_m} {
1291         global file_lists
1292
1293         if {$new_m eq {_}} {
1294                 set lno [lsearch -sorted $file_lists($w) $path]
1295                 if {$lno >= 0} {
1296                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1297                         incr lno
1298                         $w conf -state normal
1299                         $w delete $lno.0 [expr {$lno + 1}].0
1300                         $w conf -state disabled
1301                 }
1302         } elseif {$old_m eq {_} && $new_m ne {_}} {
1303                 lappend file_lists($w) $path
1304                 set file_lists($w) [lsort -unique $file_lists($w)]
1305                 set lno [lsearch -sorted $file_lists($w) $path]
1306                 incr lno
1307                 $w conf -state normal
1308                 $w image create $lno.0 \
1309                         -align center -padx 5 -pady 1 \
1310                         -name $icon_name \
1311                         -image [mapicon $w $new_m $path]
1312                 $w insert $lno.1 "[escape_path $path]\n"
1313                 $w conf -state disabled
1314         } elseif {$old_m ne $new_m} {
1315                 $w conf -state normal
1316                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1317                 $w conf -state disabled
1318         }
1319 }
1320
1321 proc display_file {path state} {
1322         global file_states selected_paths
1323         global ui_index ui_workdir
1324
1325         set old_m [merge_state $path $state]
1326         set s $file_states($path)
1327         set new_m [lindex $s 0]
1328         set icon_name [lindex $s 1]
1329
1330         display_file_helper     $ui_index $path $icon_name \
1331                 [string index $old_m 0] \
1332                 [string index $new_m 0]
1333         display_file_helper     $ui_workdir $path $icon_name \
1334                 [string index $old_m 1] \
1335                 [string index $new_m 1]
1336
1337         if {$new_m eq {__}} {
1338                 unset file_states($path)
1339                 catch {unset selected_paths($path)}
1340         }
1341 }
1342
1343 proc display_all_files_helper {w path icon_name m} {
1344         global file_lists
1345
1346         lappend file_lists($w) $path
1347         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1348         $w image create end \
1349                 -align center -padx 5 -pady 1 \
1350                 -name $icon_name \
1351                 -image [mapicon $w $m $path]
1352         $w insert end "[escape_path $path]\n"
1353 }
1354
1355 proc display_all_files {} {
1356         global ui_index ui_workdir
1357         global file_states file_lists
1358         global last_clicked
1359
1360         $ui_index conf -state normal
1361         $ui_workdir conf -state normal
1362
1363         $ui_index delete 0.0 end
1364         $ui_workdir delete 0.0 end
1365         set last_clicked {}
1366
1367         set file_lists($ui_index) [list]
1368         set file_lists($ui_workdir) [list]
1369
1370         foreach path [lsort [array names file_states]] {
1371                 set s $file_states($path)
1372                 set m [lindex $s 0]
1373                 set icon_name [lindex $s 1]
1374
1375                 if {[string index $m 0] ne {_}} {
1376                         display_all_files_helper $ui_index $path \
1377                                 $icon_name [string index $m 0]
1378                 }
1379                 if {[string index $m 1] ne {_}} {
1380                         display_all_files_helper $ui_workdir $path \
1381                                 $icon_name [string index $m 1]
1382                 }
1383         }
1384
1385         $ui_index conf -state disabled
1386         $ui_workdir conf -state disabled
1387 }
1388
1389 proc update_indexinfo {msg pathList after} {
1390         global update_index_cp ui_status_value
1391
1392         if {![lock_index update]} return
1393
1394         set update_index_cp 0
1395         set pathList [lsort $pathList]
1396         set totalCnt [llength $pathList]
1397         set batch [expr {int($totalCnt * .01) + 1}]
1398         if {$batch > 25} {set batch 25}
1399
1400         set ui_status_value [format \
1401                 "$msg... %i/%i files (%.2f%%)" \
1402                 $update_index_cp \
1403                 $totalCnt \
1404                 0.0]
1405         set fd [open "| git update-index -z --index-info" w]
1406         fconfigure $fd \
1407                 -blocking 0 \
1408                 -buffering full \
1409                 -buffersize 512 \
1410                 -translation binary
1411         fileevent $fd writable [list \
1412                 write_update_indexinfo \
1413                 $fd \
1414                 $pathList \
1415                 $totalCnt \
1416                 $batch \
1417                 $msg \
1418                 $after \
1419                 ]
1420 }
1421
1422 proc write_update_indexinfo {fd pathList totalCnt batch msg after} {
1423         global update_index_cp ui_status_value
1424         global file_states current_diff
1425
1426         if {$update_index_cp >= $totalCnt} {
1427                 close $fd
1428                 unlock_index
1429                 uplevel #0 $after
1430                 return
1431         }
1432
1433         for {set i $batch} \
1434                 {$update_index_cp < $totalCnt && $i > 0} \
1435                 {incr i -1} {
1436                 set path [lindex $pathList $update_index_cp]
1437                 incr update_index_cp
1438
1439                 set s $file_states($path)
1440                 switch -glob -- [lindex $s 0] {
1441                 A? {set new _O}
1442                 M? {set new _M}
1443                 D_ {set new _D}
1444                 D? {set new _?}
1445                 ?? {continue}
1446                 }
1447                 set info [lindex $s 2]
1448                 if {$info eq {}} continue
1449
1450                 puts -nonewline $fd "$info\t$path\0"
1451                 display_file $path $new
1452         }
1453
1454         set ui_status_value [format \
1455                 "$msg... %i/%i files (%.2f%%)" \
1456                 $update_index_cp \
1457                 $totalCnt \
1458                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1459 }
1460
1461 proc update_index {msg pathList after} {
1462         global update_index_cp ui_status_value
1463
1464         if {![lock_index update]} return
1465
1466         set update_index_cp 0
1467         set pathList [lsort $pathList]
1468         set totalCnt [llength $pathList]
1469         set batch [expr {int($totalCnt * .01) + 1}]
1470         if {$batch > 25} {set batch 25}
1471
1472         set ui_status_value [format \
1473                 "$msg... %i/%i files (%.2f%%)" \
1474                 $update_index_cp \
1475                 $totalCnt \
1476                 0.0]
1477         set fd [open "| git update-index --add --remove -z --stdin" w]
1478         fconfigure $fd \
1479                 -blocking 0 \
1480                 -buffering full \
1481                 -buffersize 512 \
1482                 -translation binary
1483         fileevent $fd writable [list \
1484                 write_update_index \
1485                 $fd \
1486                 $pathList \
1487                 $totalCnt \
1488                 $batch \
1489                 $msg \
1490                 $after \
1491                 ]
1492 }
1493
1494 proc write_update_index {fd pathList totalCnt batch msg after} {
1495         global update_index_cp ui_status_value
1496         global file_states current_diff
1497
1498         if {$update_index_cp >= $totalCnt} {
1499                 close $fd
1500                 unlock_index
1501                 uplevel #0 $after
1502                 return
1503         }
1504
1505         for {set i $batch} \
1506                 {$update_index_cp < $totalCnt && $i > 0} \
1507                 {incr i -1} {
1508                 set path [lindex $pathList $update_index_cp]
1509                 incr update_index_cp
1510
1511                 switch -glob -- [lindex $file_states($path) 0] {
1512                 AD {set new __}
1513                 ?D {set new D_}
1514                 _O -
1515                 AM {set new A_}
1516                 U_ -
1517                 ?M {set new M_}
1518                 ?? {continue}
1519                 }
1520                 puts -nonewline $fd "$path\0"
1521                 display_file $path $new
1522         }
1523
1524         set ui_status_value [format \
1525                 "$msg... %i/%i files (%.2f%%)" \
1526                 $update_index_cp \
1527                 $totalCnt \
1528                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1529 }
1530
1531 proc checkout_index {msg pathList after} {
1532         global update_index_cp ui_status_value
1533
1534         if {![lock_index update]} return
1535
1536         set update_index_cp 0
1537         set pathList [lsort $pathList]
1538         set totalCnt [llength $pathList]
1539         set batch [expr {int($totalCnt * .01) + 1}]
1540         if {$batch > 25} {set batch 25}
1541
1542         set ui_status_value [format \
1543                 "$msg... %i/%i files (%.2f%%)" \
1544                 $update_index_cp \
1545                 $totalCnt \
1546                 0.0]
1547         set cmd [list git checkout-index]
1548         lappend cmd --index
1549         lappend cmd --quiet
1550         lappend cmd --force
1551         lappend cmd -z
1552         lappend cmd --stdin
1553         set fd [open "| $cmd " w]
1554         fconfigure $fd \
1555                 -blocking 0 \
1556                 -buffering full \
1557                 -buffersize 512 \
1558                 -translation binary
1559         fileevent $fd writable [list \
1560                 write_checkout_index \
1561                 $fd \
1562                 $pathList \
1563                 $totalCnt \
1564                 $batch \
1565                 $msg \
1566                 $after \
1567                 ]
1568 }
1569
1570 proc write_checkout_index {fd pathList totalCnt batch msg after} {
1571         global update_index_cp ui_status_value
1572         global file_states current_diff
1573
1574         if {$update_index_cp >= $totalCnt} {
1575                 close $fd
1576                 unlock_index
1577                 uplevel #0 $after
1578                 return
1579         }
1580
1581         for {set i $batch} \
1582                 {$update_index_cp < $totalCnt && $i > 0} \
1583                 {incr i -1} {
1584                 set path [lindex $pathList $update_index_cp]
1585                 incr update_index_cp
1586                 switch -glob -- [lindex $file_states($path) 0] {
1587                 U? {continue}
1588                 ?M -
1589                 ?D {
1590                         puts -nonewline $fd "$path\0"
1591                         display_file $path ?_
1592                 }
1593                 }
1594         }
1595
1596         set ui_status_value [format \
1597                 "$msg... %i/%i files (%.2f%%)" \
1598                 $update_index_cp \
1599                 $totalCnt \
1600                 [expr {100.0 * $update_index_cp / $totalCnt}]]
1601 }
1602
1603 ######################################################################
1604 ##
1605 ## branch management
1606
1607 proc load_all_heads {} {
1608         global all_heads tracking_branches
1609
1610         set all_heads [list]
1611         set cmd [list git for-each-ref]
1612         lappend cmd --format=%(refname)
1613         lappend cmd refs/heads
1614         set fd [open "| $cmd" r]
1615         while {[gets $fd line] > 0} {
1616                 if {![catch {set info $tracking_branches($line)}]} continue
1617                 if {![regsub ^refs/heads/ $line {} name]} continue
1618                 lappend all_heads $name
1619         }
1620         close $fd
1621
1622         set all_heads [lsort $all_heads]
1623 }
1624
1625 proc populate_branch_menu {} {
1626         global all_heads disable_on_lock
1627
1628         set m .mbar.branch
1629         set last [$m index last]
1630         for {set i 0} {$i <= $last} {incr i} {
1631                 if {[$m type $i] eq {separator}} {
1632                         $m delete $i last
1633                         set new_dol [list]
1634                         foreach a $disable_on_lock {
1635                                 if {[lindex $a 0] ne $m || [lindex $a 2] < $i} {
1636                                         lappend new_dol $a
1637                                 }
1638                         }
1639                         set disable_on_lock $new_dol
1640                         break
1641                 }
1642         }
1643
1644         $m add separator
1645         foreach b $all_heads {
1646                 $m add radiobutton \
1647                         -label $b \
1648                         -command [list switch_branch $b] \
1649                         -variable current_branch \
1650                         -value $b \
1651                         -font font_ui
1652                 lappend disable_on_lock \
1653                         [list $m entryconf [$m index last] -state]
1654         }
1655 }
1656
1657 proc do_create_branch_action {w} {
1658         global all_heads null_sha1
1659         global create_branch_checkout create_branch_revtype
1660         global create_branch_head create_branch_trackinghead
1661
1662         set newbranch [string trim [$w.name.t get 0.0 end]]
1663         if {![catch {exec git show-ref --verify -- "refs/heads/$newbranch"}]} {
1664                 tk_messageBox \
1665                         -icon error \
1666                         -type ok \
1667                         -title [wm title $w] \
1668                         -parent $w \
1669                         -message "Branch '$newbranch' already exists."
1670                 focus $w.name.t
1671                 return
1672         }
1673         if {[catch {exec git check-ref-format "heads/$newbranch"}]} {
1674                 tk_messageBox \
1675                         -icon error \
1676                         -type ok \
1677                         -title [wm title $w] \
1678                         -parent $w \
1679                         -message "We do not like '$newbranch' as a branch name."
1680                 focus $w.name.t
1681                 return
1682         }
1683
1684         set rev {}
1685         switch -- $create_branch_revtype {
1686         head {set rev $create_branch_head}
1687         tracking {set rev $create_branch_trackinghead}
1688         expression {set rev [string trim [$w.from.exp.t get 0.0 end]]}
1689         }
1690         if {[catch {set cmt [exec git rev-parse --verify "${rev}^0"]}]} {
1691                 tk_messageBox \
1692                         -icon error \
1693                         -type ok \
1694                         -title [wm title $w] \
1695                         -parent $w \
1696                         -message "Invalid starting revision: $rev"
1697                 return
1698         }
1699         set cmd [list git update-ref]
1700         lappend cmd -m
1701         lappend cmd "branch: Created from $rev"
1702         lappend cmd "refs/heads/$newbranch"
1703         lappend cmd $cmt
1704         lappend cmd $null_sha1
1705         if {[catch {eval exec $cmd} err]} {
1706                 tk_messageBox \
1707                         -icon error \
1708                         -type ok \
1709                         -title [wm title $w] \
1710                         -parent $w \
1711                         -message "Failed to create '$newbranch'.\n\n$err"
1712                 return
1713         }
1714
1715         lappend all_heads $newbranch
1716         set all_heads [lsort $all_heads]
1717         populate_branch_menu
1718         destroy $w
1719 }
1720
1721 proc do_create_branch {} {
1722         global all_heads current_branch tracking_branches
1723         global create_branch_checkout create_branch_revtype
1724         global create_branch_head create_branch_trackinghead
1725
1726         set create_branch_checkout true
1727         set create_branch_revtype head
1728         set create_branch_head $current_branch
1729         set create_branch_trackinghead {}
1730
1731         set w .branch_editor
1732         toplevel $w
1733         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1734
1735         label $w.header -text {Create New Branch} \
1736                 -font font_uibold
1737         pack $w.header -side top -fill x
1738
1739         frame $w.buttons
1740         button $w.buttons.create -text Create \
1741                 -font font_ui \
1742                 -default active \
1743                 -command [list do_create_branch_action $w]
1744         pack $w.buttons.create -side right
1745         button $w.buttons.cancel -text {Cancel} \
1746                 -font font_ui \
1747                 -command [list destroy $w]
1748         pack $w.buttons.cancel -side right -padx 5
1749         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1750
1751         labelframe $w.name \
1752                 -text {Branch Description} \
1753                 -font font_ui
1754         label $w.name.l -text {Name:} -font font_ui
1755         text $w.name.t \
1756                 -height 1 \
1757                 -width 40 \
1758                 -font font_ui
1759         bind $w.name.t <Shift-Key-Tab> "focus $w.postActions.checkout;break"
1760         bind $w.name.t <Key-Tab> "focus $w.from.exp.t;break"
1761         bind $w.name.t <Key-Return> "do_create_branch_action $w;break"
1762         bind $w.name.t <Key> {
1763                 if {{%K} ne {BackSpace}
1764                         && {%K} ne {Tab}
1765                         && {%K} ne {Escape}
1766                         && {%K} ne {Return}} {
1767                         if {%k <= 32} break
1768                         if {[string first %A {~^:?*[}] >= 0} break
1769                 }
1770         }
1771         pack $w.name.l -side left -padx 5
1772         pack $w.name.t -side left -fill x -expand 1
1773         pack $w.name -anchor nw -fill x -pady 5 -padx 5
1774
1775         set all_trackings [list]
1776         foreach b [array names tracking_branches] {
1777                 regsub ^refs/(heads|remotes)/ $b {} b
1778                 lappend all_trackings $b
1779         }
1780         set all_trackings [lsort -unique $all_trackings]
1781         if {$all_trackings ne {}} {
1782                 set create_branch_trackinghead [lindex $all_trackings 0]
1783         }
1784
1785         labelframe $w.from \
1786                 -text {Starting Revision} \
1787                 -font font_ui
1788         frame $w.from.head
1789         radiobutton $w.from.head.r \
1790                 -text {Local Branch:} \
1791                 -value head \
1792                 -variable create_branch_revtype \
1793                 -font font_ui
1794         eval tk_optionMenu $w.from.head.m create_branch_head $all_heads
1795         pack $w.from.head.r -side left
1796         pack $w.from.head.m -side left
1797         frame $w.from.tracking
1798         radiobutton $w.from.tracking.r \
1799                 -text {Tracking Branch:} \
1800                 -value tracking \
1801                 -variable create_branch_revtype \
1802                 -font font_ui
1803         eval tk_optionMenu $w.from.tracking.m \
1804                 create_branch_trackinghead \
1805                 $all_trackings
1806         pack $w.from.tracking.r -side left
1807         pack $w.from.tracking.m -side left
1808         frame $w.from.exp
1809         radiobutton $w.from.exp.r \
1810                 -text {Revision Expression:} \
1811                 -value expression \
1812                 -variable create_branch_revtype \
1813                 -font font_ui
1814         text $w.from.exp.t \
1815                 -height 1 \
1816                 -width 50 \
1817                 -font font_ui
1818         bind $w.from.exp.t <Shift-Key-Tab> "focus $w.name.t;break"
1819         bind $w.from.exp.t <Key-Tab> "focus $w.postActions.checkout;break"
1820         bind $w.from.exp.t <Key-Return> "do_create_branch_action $w;break"
1821         pack $w.from.exp.r -side left
1822         pack $w.from.exp.t -side left -fill x -expand 1
1823         pack $w.from.head -padx 5 -fill x -expand 1
1824         pack $w.from.tracking -padx 5 -fill x -expand 1
1825         pack $w.from.exp -padx 5 -fill x -expand 1
1826         pack $w.from -anchor nw -fill x -pady 5 -padx 5
1827
1828         labelframe $w.postActions \
1829                 -text {Post Creation Actions} \
1830                 -font font_ui
1831         checkbutton $w.postActions.checkout \
1832                 -text {Checkout after creation} \
1833                 -offvalue false \
1834                 -onvalue true \
1835                 -variable create_branch_checkout \
1836                 -font font_ui
1837         pack $w.postActions.checkout -anchor nw
1838         pack $w.postActions -anchor nw -fill x -pady 5 -padx 5
1839
1840         bind $w <Visibility> "grab $w; focus $w.name.t"
1841         bind $w <Key-Escape> "destroy $w"
1842         bind $w <Key-Return> "do_create_branch_action $w;break"
1843         wm title $w "[appname] ([reponame]): Create Branch"
1844         tkwait window $w
1845 }
1846
1847 proc do_delete_branch_action {w} {
1848         global all_heads
1849         global delete_branch_checkhead delete_branch_head
1850
1851         set to_delete [list]
1852         set msg {Are you sure you want to delete the following branches?
1853
1854 }
1855         foreach i [$w.list.l curselection] {
1856                 set b [$w.list.l get $i]
1857                 if {[catch {set o [exec git rev-parse --verify $b]}]} continue
1858                 if {$delete_branch_checkhead} {
1859                         if {[catch {set m [exec git merge-base $o $delete_branch_head]}]} continue
1860                         if {$o ne $m} continue
1861                 }
1862                 lappend to_delete [list $b $o]
1863                 append msg " - $b\n"
1864         }
1865         if {$to_delete eq {}} {
1866                 tk_messageBox \
1867                         -icon info \
1868                         -type ok \
1869                         -title [wm title $w] \
1870                         -parent $w \
1871                         -message {No branches are able to be deleted.
1872
1873 This is likely because you did not select any branches,
1874 or all selected branches are not completely merged.
1875 }
1876                 return
1877         }
1878         append msg {
1879 It can be difficult to recover deleted branches.
1880
1881 Delete the above branches?}
1882         if {[tk_messageBox \
1883                 -icon warning \
1884                 -type yesno \
1885                 -title [wm title $w] \
1886                 -parent $w \
1887                 -message $msg] ne yes} {
1888                 return
1889         }
1890
1891         set failed {}
1892         foreach i $to_delete {
1893                 set b [lindex $i 0]
1894                 set o [lindex $i 1]
1895                 if {[catch {exec git update-ref -d "refs/heads/$b" $o} err]} {
1896                         append failed " - $b: $err\n"
1897                 } else {
1898                         set x [lsearch -sorted $all_heads $b]
1899                         if {$x >= 0} {
1900                                 set all_heads [lreplace $all_heads $x $x]
1901                         }
1902                 }
1903         }
1904
1905         if {$failed ne {}} {
1906                 tk_messageBox \
1907                         -icon error \
1908                         -type ok \
1909                         -title [wm title $w] \
1910                         -parent $w \
1911                         -message "Failed to delete branches:\n$failed"
1912         }
1913
1914         set all_heads [lsort $all_heads]
1915         populate_branch_menu
1916         destroy $w
1917 }
1918
1919 proc do_delete_branch {} {
1920         global all_heads tracking_branches current_branch
1921         global delete_branch_checkhead delete_branch_head
1922
1923         set delete_branch_checkhead 1
1924         set delete_branch_head $current_branch
1925
1926         set w .branch_editor
1927         toplevel $w
1928         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
1929
1930         label $w.header -text {Delete Local Branch} \
1931                 -font font_uibold
1932         pack $w.header -side top -fill x
1933
1934         frame $w.buttons
1935         button $w.buttons.create -text Delete \
1936                 -font font_ui \
1937                 -command [list do_delete_branch_action $w]
1938         pack $w.buttons.create -side right
1939         button $w.buttons.cancel -text {Cancel} \
1940                 -font font_ui \
1941                 -command [list destroy $w]
1942         pack $w.buttons.cancel -side right -padx 5
1943         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
1944
1945         labelframe $w.list \
1946                 -text {Local Branches} \
1947                 -font font_ui
1948         listbox $w.list.l \
1949                 -height 10 \
1950                 -width 50 \
1951                 -selectmode extended \
1952                 -font font_ui
1953         foreach h $all_heads {
1954                 if {$h ne $current_branch} {
1955                         $w.list.l insert end $h
1956                 }
1957         }
1958         pack $w.list.l -fill both -pady 5 -padx 5
1959         pack $w.list -fill both -pady 5 -padx 5
1960
1961         set all_trackings [list]
1962         foreach b [array names tracking_branches] {
1963                 regsub ^refs/(heads|remotes)/ $b {} b
1964                 lappend all_trackings $b
1965         }
1966
1967         labelframe $w.validate \
1968                 -text {Only Delete If} \
1969                 -font font_ui
1970         frame $w.validate.head
1971         checkbutton $w.validate.head.r \
1972                 -text {Already Merged Into:} \
1973                 -variable delete_branch_checkhead \
1974                 -font font_ui
1975         eval tk_optionMenu $w.validate.head.m delete_branch_head \
1976                 $all_heads \
1977                 [lsort -unique $all_trackings]
1978         pack $w.validate.head.r -side left
1979         pack $w.validate.head.m -side left
1980         pack $w.validate.head -padx 5 -fill x -expand 1
1981         pack $w.validate -anchor nw -fill x -pady 5 -padx 5
1982
1983         bind $w <Visibility> "grab $w; focus $w"
1984         bind $w <Key-Escape> "destroy $w"
1985         wm title $w "[appname] ([reponame]): Delete Branch"
1986         tkwait window $w
1987 }
1988
1989 proc switch_branch {b} {
1990         global HEAD commit_type file_states current_branch
1991         global selected_commit_type ui_comm
1992
1993         if {![lock_index switch]} return
1994
1995         # -- Backup the selected branch (repository_state resets it)
1996         #
1997         set new_branch $current_branch
1998
1999         # -- Our in memory state should match the repository.
2000         #
2001         repository_state curType curHEAD curMERGE_HEAD
2002         if {[string match amend* $commit_type]
2003                 && $curType eq {normal}
2004                 && $curHEAD eq $HEAD} {
2005         } elseif {$commit_type ne $curType || $HEAD ne $curHEAD} {
2006                 info_popup {Last scanned state does not match repository state.
2007
2008 Another Git program has modified this repository
2009 since the last scan.  A rescan must be performed
2010 before the current branch can be changed.
2011
2012 The rescan will be automatically started now.
2013 }
2014                 unlock_index
2015                 rescan {set ui_status_value {Ready.}}
2016                 return
2017         }
2018
2019         # -- Toss the message buffer if we are in amend mode.
2020         #
2021         if {[string match amend* $curType]} {
2022                 $ui_comm delete 0.0 end
2023                 $ui_comm edit reset
2024                 $ui_comm edit modified false
2025         }
2026
2027         set selected_commit_type new
2028         set current_branch $new_branch
2029
2030         unlock_index
2031         error "NOT FINISHED"
2032 }
2033
2034 ######################################################################
2035 ##
2036 ## remote management
2037
2038 proc load_all_remotes {} {
2039         global repo_config
2040         global all_remotes tracking_branches
2041
2042         set all_remotes [list]
2043         array unset tracking_branches
2044
2045         set rm_dir [gitdir remotes]
2046         if {[file isdirectory $rm_dir]} {
2047                 set all_remotes [glob \
2048                         -types f \
2049                         -tails \
2050                         -nocomplain \
2051                         -directory $rm_dir *]
2052
2053                 foreach name $all_remotes {
2054                         catch {
2055                                 set fd [open [file join $rm_dir $name] r]
2056                                 while {[gets $fd line] >= 0} {
2057                                         if {![regexp {^Pull:[   ]*([^:]+):(.+)$} \
2058                                                 $line line src dst]} continue
2059                                         if {![regexp ^refs/ $dst]} {
2060                                                 set dst "refs/heads/$dst"
2061                                         }
2062                                         set tracking_branches($dst) [list $name $src]
2063                                 }
2064                                 close $fd
2065                         }
2066                 }
2067         }
2068
2069         foreach line [array names repo_config remote.*.url] {
2070                 if {![regexp ^remote\.(.*)\.url\$ $line line name]} continue
2071                 lappend all_remotes $name
2072
2073                 if {[catch {set fl $repo_config(remote.$name.fetch)}]} {
2074                         set fl {}
2075                 }
2076                 foreach line $fl {
2077                         if {![regexp {^([^:]+):(.+)$} $line line src dst]} continue
2078                         if {![regexp ^refs/ $dst]} {
2079                                 set dst "refs/heads/$dst"
2080                         }
2081                         set tracking_branches($dst) [list $name $src]
2082                 }
2083         }
2084
2085         set all_remotes [lsort -unique $all_remotes]
2086 }
2087
2088 proc populate_fetch_menu {m} {
2089         global all_remotes repo_config
2090
2091         foreach r $all_remotes {
2092                 set enable 0
2093                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2094                         if {![catch {set a $repo_config(remote.$r.fetch)}]} {
2095                                 set enable 1
2096                         }
2097                 } else {
2098                         catch {
2099                                 set fd [open [gitdir remotes $r] r]
2100                                 while {[gets $fd n] >= 0} {
2101                                         if {[regexp {^Pull:[ \t]*([^:]+):} $n]} {
2102                                                 set enable 1
2103                                                 break
2104                                         }
2105                                 }
2106                                 close $fd
2107                         }
2108                 }
2109
2110                 if {$enable} {
2111                         $m add command \
2112                                 -label "Fetch from $r..." \
2113                                 -command [list fetch_from $r] \
2114                                 -font font_ui
2115                 }
2116         }
2117 }
2118
2119 proc populate_push_menu {m} {
2120         global all_remotes repo_config
2121
2122         foreach r $all_remotes {
2123                 set enable 0
2124                 if {![catch {set a $repo_config(remote.$r.url)}]} {
2125                         if {![catch {set a $repo_config(remote.$r.push)}]} {
2126                                 set enable 1
2127                         }
2128                 } else {
2129                         catch {
2130                                 set fd [open [gitdir remotes $r] r]
2131                                 while {[gets $fd n] >= 0} {
2132                                         if {[regexp {^Push:[ \t]*([^:]+):} $n]} {
2133                                                 set enable 1
2134                                                 break
2135                                         }
2136                                 }
2137                                 close $fd
2138                         }
2139                 }
2140
2141                 if {$enable} {
2142                         $m add command \
2143                                 -label "Push to $r..." \
2144                                 -command [list push_to $r] \
2145                                 -font font_ui
2146                 }
2147         }
2148 }
2149
2150 proc populate_pull_menu {m} {
2151         global repo_config all_remotes disable_on_lock
2152
2153         foreach remote $all_remotes {
2154                 set rb_list [list]
2155                 if {[array get repo_config remote.$remote.url] ne {}} {
2156                         if {[array get repo_config remote.$remote.fetch] ne {}} {
2157                                 foreach line $repo_config(remote.$remote.fetch) {
2158                                         if {[regexp {^([^:]+):} $line line rb]} {
2159                                                 lappend rb_list $rb
2160                                         }
2161                                 }
2162                         }
2163                 } else {
2164                         catch {
2165                                 set fd [open [gitdir remotes $remote] r]
2166                                 while {[gets $fd line] >= 0} {
2167                                         if {[regexp {^Pull:[ \t]*([^:]+):} $line line rb]} {
2168                                                 lappend rb_list $rb
2169                                         }
2170                                 }
2171                                 close $fd
2172                         }
2173                 }
2174
2175                 foreach rb $rb_list {
2176                         regsub ^refs/heads/ $rb {} rb_short
2177                         $m add command \
2178                                 -label "Branch $rb_short from $remote..." \
2179                                 -command [list pull_remote $remote $rb] \
2180                                 -font font_ui
2181                         lappend disable_on_lock \
2182                                 [list $m entryconf [$m index last] -state]
2183                 }
2184         }
2185 }
2186
2187 ######################################################################
2188 ##
2189 ## icons
2190
2191 set filemask {
2192 #define mask_width 14
2193 #define mask_height 15
2194 static unsigned char mask_bits[] = {
2195    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2196    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2197    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2198 }
2199
2200 image create bitmap file_plain -background white -foreground black -data {
2201 #define plain_width 14
2202 #define plain_height 15
2203 static unsigned char plain_bits[] = {
2204    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2205    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2206    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2207 } -maskdata $filemask
2208
2209 image create bitmap file_mod -background white -foreground blue -data {
2210 #define mod_width 14
2211 #define mod_height 15
2212 static unsigned char mod_bits[] = {
2213    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2214    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2215    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2216 } -maskdata $filemask
2217
2218 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2219 #define file_fulltick_width 14
2220 #define file_fulltick_height 15
2221 static unsigned char file_fulltick_bits[] = {
2222    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2223    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2224    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2225 } -maskdata $filemask
2226
2227 image create bitmap file_parttick -background white -foreground "#005050" -data {
2228 #define parttick_width 14
2229 #define parttick_height 15
2230 static unsigned char parttick_bits[] = {
2231    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2232    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
2233    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2234 } -maskdata $filemask
2235
2236 image create bitmap file_question -background white -foreground black -data {
2237 #define file_question_width 14
2238 #define file_question_height 15
2239 static unsigned char file_question_bits[] = {
2240    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2241    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2242    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2243 } -maskdata $filemask
2244
2245 image create bitmap file_removed -background white -foreground red -data {
2246 #define file_removed_width 14
2247 #define file_removed_height 15
2248 static unsigned char file_removed_bits[] = {
2249    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2250    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2251    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2252 } -maskdata $filemask
2253
2254 image create bitmap file_merge -background white -foreground blue -data {
2255 #define file_merge_width 14
2256 #define file_merge_height 15
2257 static unsigned char file_merge_bits[] = {
2258    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2259    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2260    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2261 } -maskdata $filemask
2262
2263 set ui_index .vpane.files.index.list
2264 set ui_workdir .vpane.files.workdir.list
2265
2266 set all_icons(_$ui_index)   file_plain
2267 set all_icons(A$ui_index)   file_fulltick
2268 set all_icons(M$ui_index)   file_fulltick
2269 set all_icons(D$ui_index)   file_removed
2270 set all_icons(U$ui_index)   file_merge
2271
2272 set all_icons(_$ui_workdir) file_plain
2273 set all_icons(M$ui_workdir) file_mod
2274 set all_icons(D$ui_workdir) file_question
2275 set all_icons(O$ui_workdir) file_plain
2276
2277 set max_status_desc 0
2278 foreach i {
2279                 {__ "Unmodified"}
2280
2281                 {_M "Modified, not staged"}
2282                 {M_ "Staged for commit"}
2283                 {MM "Portions staged for commit"}
2284                 {MD "Staged for commit, missing"}
2285
2286                 {_O "Untracked, not staged"}
2287                 {A_ "Staged for commit"}
2288                 {AM "Portions staged for commit"}
2289                 {AD "Staged for commit, missing"}
2290
2291                 {_D "Missing"}
2292                 {D_ "Staged for removal"}
2293                 {DO "Staged for removal, still present"}
2294
2295                 {U_ "Requires merge resolution"}
2296                 {UM "Requires merge resolution"}
2297                 {UD "Requires merge resolution"}
2298         } {
2299         if {$max_status_desc < [string length [lindex $i 1]]} {
2300                 set max_status_desc [string length [lindex $i 1]]
2301         }
2302         set all_descs([lindex $i 0]) [lindex $i 1]
2303 }
2304 unset i
2305
2306 ######################################################################
2307 ##
2308 ## util
2309
2310 proc is_MacOSX {} {
2311         global tcl_platform tk_library
2312         if {[tk windowingsystem] eq {aqua}} {
2313                 return 1
2314         }
2315         return 0
2316 }
2317
2318 proc is_Windows {} {
2319         global tcl_platform
2320         if {$tcl_platform(platform) eq {windows}} {
2321                 return 1
2322         }
2323         return 0
2324 }
2325
2326 proc bind_button3 {w cmd} {
2327         bind $w <Any-Button-3> $cmd
2328         if {[is_MacOSX]} {
2329                 bind $w <Control-Button-1> $cmd
2330         }
2331 }
2332
2333 proc incr_font_size {font {amt 1}} {
2334         set sz [font configure $font -size]
2335         incr sz $amt
2336         font configure $font -size $sz
2337         font configure ${font}bold -size $sz
2338 }
2339
2340 proc hook_failed_popup {hook msg} {
2341         set w .hookfail
2342         toplevel $w
2343
2344         frame $w.m
2345         label $w.m.l1 -text "$hook hook failed:" \
2346                 -anchor w \
2347                 -justify left \
2348                 -font font_uibold
2349         text $w.m.t \
2350                 -background white -borderwidth 1 \
2351                 -relief sunken \
2352                 -width 80 -height 10 \
2353                 -font font_diff \
2354                 -yscrollcommand [list $w.m.sby set]
2355         label $w.m.l2 \
2356                 -text {You must correct the above errors before committing.} \
2357                 -anchor w \
2358                 -justify left \
2359                 -font font_uibold
2360         scrollbar $w.m.sby -command [list $w.m.t yview]
2361         pack $w.m.l1 -side top -fill x
2362         pack $w.m.l2 -side bottom -fill x
2363         pack $w.m.sby -side right -fill y
2364         pack $w.m.t -side left -fill both -expand 1
2365         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2366
2367         $w.m.t insert 1.0 $msg
2368         $w.m.t conf -state disabled
2369
2370         button $w.ok -text OK \
2371                 -width 15 \
2372                 -font font_ui \
2373                 -command "destroy $w"
2374         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2375
2376         bind $w <Visibility> "grab $w; focus $w"
2377         bind $w <Key-Return> "destroy $w"
2378         wm title $w "[appname] ([reponame]): error"
2379         tkwait window $w
2380 }
2381
2382 set next_console_id 0
2383
2384 proc new_console {short_title long_title} {
2385         global next_console_id console_data
2386         set w .console[incr next_console_id]
2387         set console_data($w) [list $short_title $long_title]
2388         return [console_init $w]
2389 }
2390
2391 proc console_init {w} {
2392         global console_cr console_data M1B
2393
2394         set console_cr($w) 1.0
2395         toplevel $w
2396         frame $w.m
2397         label $w.m.l1 -text "[lindex $console_data($w) 1]:" \
2398                 -anchor w \
2399                 -justify left \
2400                 -font font_uibold
2401         text $w.m.t \
2402                 -background white -borderwidth 1 \
2403                 -relief sunken \
2404                 -width 80 -height 10 \
2405                 -font font_diff \
2406                 -state disabled \
2407                 -yscrollcommand [list $w.m.sby set]
2408         label $w.m.s -text {Working... please wait...} \
2409                 -anchor w \
2410                 -justify left \
2411                 -font font_uibold
2412         scrollbar $w.m.sby -command [list $w.m.t yview]
2413         pack $w.m.l1 -side top -fill x
2414         pack $w.m.s -side bottom -fill x
2415         pack $w.m.sby -side right -fill y
2416         pack $w.m.t -side left -fill both -expand 1
2417         pack $w.m -side top -fill both -expand 1 -padx 5 -pady 10
2418
2419         menu $w.ctxm -tearoff 0
2420         $w.ctxm add command -label "Copy" \
2421                 -font font_ui \
2422                 -command "tk_textCopy $w.m.t"
2423         $w.ctxm add command -label "Select All" \
2424                 -font font_ui \
2425                 -command "$w.m.t tag add sel 0.0 end"
2426         $w.ctxm add command -label "Copy All" \
2427                 -font font_ui \
2428                 -command "
2429                         $w.m.t tag add sel 0.0 end
2430                         tk_textCopy $w.m.t
2431                         $w.m.t tag remove sel 0.0 end
2432                 "
2433
2434         button $w.ok -text {Close} \
2435                 -font font_ui \
2436                 -state disabled \
2437                 -command "destroy $w"
2438         pack $w.ok -side bottom -anchor e -pady 10 -padx 10
2439
2440         bind_button3 $w.m.t "tk_popup $w.ctxm %X %Y"
2441         bind $w.m.t <$M1B-Key-a> "$w.m.t tag add sel 0.0 end;break"
2442         bind $w.m.t <$M1B-Key-A> "$w.m.t tag add sel 0.0 end;break"
2443         bind $w <Visibility> "focus $w"
2444         wm title $w "[appname] ([reponame]): [lindex $console_data($w) 0]"
2445         return $w
2446 }
2447
2448 proc console_exec {w cmd {after {}}} {
2449         # -- Windows tosses the enviroment when we exec our child.
2450         #    But most users need that so we have to relogin. :-(
2451         #
2452         if {[is_Windows]} {
2453                 set cmd [list sh --login -c "cd \"[pwd]\" && [join $cmd { }]"]
2454         }
2455
2456         # -- Tcl won't let us redirect both stdout and stderr to
2457         #    the same pipe.  So pass it through cat...
2458         #
2459         set cmd [concat | $cmd |& cat]
2460
2461         set fd_f [open $cmd r]
2462         fconfigure $fd_f -blocking 0 -translation binary
2463         fileevent $fd_f readable [list console_read $w $fd_f $after]
2464 }
2465
2466 proc console_read {w fd after} {
2467         global console_cr console_data
2468
2469         set buf [read $fd]
2470         if {$buf ne {}} {
2471                 if {![winfo exists $w]} {console_init $w}
2472                 $w.m.t conf -state normal
2473                 set c 0
2474                 set n [string length $buf]
2475                 while {$c < $n} {
2476                         set cr [string first "\r" $buf $c]
2477                         set lf [string first "\n" $buf $c]
2478                         if {$cr < 0} {set cr [expr {$n + 1}]}
2479                         if {$lf < 0} {set lf [expr {$n + 1}]}
2480
2481                         if {$lf < $cr} {
2482                                 $w.m.t insert end [string range $buf $c $lf]
2483                                 set console_cr($w) [$w.m.t index {end -1c}]
2484                                 set c $lf
2485                                 incr c
2486                         } else {
2487                                 $w.m.t delete $console_cr($w) end
2488                                 $w.m.t insert end "\n"
2489                                 $w.m.t insert end [string range $buf $c $cr]
2490                                 set c $cr
2491                                 incr c
2492                         }
2493                 }
2494                 $w.m.t conf -state disabled
2495                 $w.m.t see end
2496         }
2497
2498         fconfigure $fd -blocking 1
2499         if {[eof $fd]} {
2500                 if {[catch {close $fd}]} {
2501                         if {![winfo exists $w]} {console_init $w}
2502                         $w.m.s conf -background red -text {Error: Command Failed}
2503                         $w.ok conf -state normal
2504                         set ok 0
2505                 } elseif {[winfo exists $w]} {
2506                         $w.m.s conf -background green -text {Success}
2507                         $w.ok conf -state normal
2508                         set ok 1
2509                 }
2510                 array unset console_cr $w
2511                 array unset console_data $w
2512                 if {$after ne {}} {
2513                         uplevel #0 $after $ok
2514                 }
2515                 return
2516         }
2517         fconfigure $fd -blocking 0
2518 }
2519
2520 ######################################################################
2521 ##
2522 ## ui commands
2523
2524 set starting_gitk_msg {Starting gitk... please wait...}
2525
2526 proc do_gitk {revs} {
2527         global ui_status_value starting_gitk_msg
2528
2529         set cmd gitk
2530         if {$revs ne {}} {
2531                 append cmd { }
2532                 append cmd $revs
2533         }
2534         if {[is_Windows]} {
2535                 set cmd "sh -c \"exec $cmd\""
2536         }
2537         append cmd { &}
2538
2539         if {[catch {eval exec $cmd} err]} {
2540                 error_popup "Failed to start gitk:\n\n$err"
2541         } else {
2542                 set ui_status_value $starting_gitk_msg
2543                 after 10000 {
2544                         if {$ui_status_value eq $starting_gitk_msg} {
2545                                 set ui_status_value {Ready.}
2546                         }
2547                 }
2548         }
2549 }
2550
2551 proc do_gc {} {
2552         set w [new_console {gc} {Compressing the object database}]
2553         console_exec $w {git gc}
2554 }
2555
2556 proc do_fsck_objects {} {
2557         set w [new_console {fsck-objects} \
2558                 {Verifying the object database with fsck-objects}]
2559         set cmd [list git fsck-objects]
2560         lappend cmd --full
2561         lappend cmd --cache
2562         lappend cmd --strict
2563         console_exec $w $cmd
2564 }
2565
2566 set is_quitting 0
2567
2568 proc do_quit {} {
2569         global ui_comm is_quitting repo_config commit_type
2570
2571         if {$is_quitting} return
2572         set is_quitting 1
2573
2574         # -- Stash our current commit buffer.
2575         #
2576         set save [gitdir GITGUI_MSG]
2577         set msg [string trim [$ui_comm get 0.0 end]]
2578         if {![string match amend* $commit_type]
2579                 && [$ui_comm edit modified]
2580                 && $msg ne {}} {
2581                 catch {
2582                         set fd [open $save w]
2583                         puts $fd [string trim [$ui_comm get 0.0 end]]
2584                         close $fd
2585                 }
2586         } else {
2587                 catch {file delete $save}
2588         }
2589
2590         # -- Stash our current window geometry into this repository.
2591         #
2592         set cfg_geometry [list]
2593         lappend cfg_geometry [wm geometry .]
2594         lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
2595         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
2596         if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2597                 set rc_geometry {}
2598         }
2599         if {$cfg_geometry ne $rc_geometry} {
2600                 catch {exec git repo-config gui.geometry $cfg_geometry}
2601         }
2602
2603         destroy .
2604 }
2605
2606 proc do_rescan {} {
2607         rescan {set ui_status_value {Ready.}}
2608 }
2609
2610 proc unstage_helper {txt paths} {
2611         global file_states current_diff
2612
2613         if {![lock_index begin-update]} return
2614
2615         set pathList [list]
2616         set after {}
2617         foreach path $paths {
2618                 switch -glob -- [lindex $file_states($path) 0] {
2619                 A? -
2620                 M? -
2621                 D? {
2622                         lappend pathList $path
2623                         if {$path eq $current_diff} {
2624                                 set after {reshow_diff;}
2625                         }
2626                 }
2627                 }
2628         }
2629         if {$pathList eq {}} {
2630                 unlock_index
2631         } else {
2632                 update_indexinfo \
2633                         $txt \
2634                         $pathList \
2635                         [concat $after {set ui_status_value {Ready.}}]
2636         }
2637 }
2638
2639 proc do_unstage_selection {} {
2640         global current_diff selected_paths
2641
2642         if {[array size selected_paths] > 0} {
2643                 unstage_helper \
2644                         {Unstaging selected files from commit} \
2645                         [array names selected_paths]
2646         } elseif {$current_diff ne {}} {
2647                 unstage_helper \
2648                         "Unstaging [short_path $current_diff] from commit" \
2649                         [list $current_diff]
2650         }
2651 }
2652
2653 proc add_helper {txt paths} {
2654         global file_states current_diff
2655
2656         if {![lock_index begin-update]} return
2657
2658         set pathList [list]
2659         set after {}
2660         foreach path $paths {
2661                 switch -glob -- [lindex $file_states($path) 0] {
2662                 _O -
2663                 ?M -
2664                 ?D -
2665                 U? {
2666                         lappend pathList $path
2667                         if {$path eq $current_diff} {
2668                                 set after {reshow_diff;}
2669                         }
2670                 }
2671                 }
2672         }
2673         if {$pathList eq {}} {
2674                 unlock_index
2675         } else {
2676                 update_index \
2677                         $txt \
2678                         $pathList \
2679                         [concat $after {set ui_status_value {Ready to commit.}}]
2680         }
2681 }
2682
2683 proc do_add_selection {} {
2684         global current_diff selected_paths
2685
2686         if {[array size selected_paths] > 0} {
2687                 add_helper \
2688                         {Adding selected files} \
2689                         [array names selected_paths]
2690         } elseif {$current_diff ne {}} {
2691                 add_helper \
2692                         "Adding [short_path $current_diff]" \
2693                         [list $current_diff]
2694         }
2695 }
2696
2697 proc do_add_all {} {
2698         global file_states
2699
2700         set paths [list]
2701         foreach path [array names file_states] {
2702                 switch -glob -- [lindex $file_states($path) 0] {
2703                 U? {continue}
2704                 ?M -
2705                 ?D {lappend paths $path}
2706                 }
2707         }
2708         add_helper {Adding all changed files} $paths
2709 }
2710
2711 proc revert_helper {txt paths} {
2712         global file_states current_diff
2713
2714         if {![lock_index begin-update]} return
2715
2716         set pathList [list]
2717         set after {}
2718         foreach path $paths {
2719                 switch -glob -- [lindex $file_states($path) 0] {
2720                 U? {continue}
2721                 ?M -
2722                 ?D {
2723                         lappend pathList $path
2724                         if {$path eq $current_diff} {
2725                                 set after {reshow_diff;}
2726                         }
2727                 }
2728                 }
2729         }
2730
2731         set n [llength $pathList]
2732         if {$n == 0} {
2733                 unlock_index
2734                 return
2735         } elseif {$n == 1} {
2736                 set s "[short_path [lindex $pathList]]"
2737         } else {
2738                 set s "these $n files"
2739         }
2740
2741         set reply [tk_dialog \
2742                 .confirm_revert \
2743                 "[appname] ([reponame])" \
2744                 "Revert changes in $s?
2745
2746 Any unadded changes will be permanently lost by the revert." \
2747                 question \
2748                 1 \
2749                 {Do Nothing} \
2750                 {Revert Changes} \
2751                 ]
2752         if {$reply == 1} {
2753                 checkout_index \
2754                         $txt \
2755                         $pathList \
2756                         [concat $after {set ui_status_value {Ready.}}]
2757         } else {
2758                 unlock_index
2759         }
2760 }
2761
2762 proc do_revert_selection {} {
2763         global current_diff selected_paths
2764
2765         if {[array size selected_paths] > 0} {
2766                 revert_helper \
2767                         {Reverting selected files} \
2768                         [array names selected_paths]
2769         } elseif {$current_diff ne {}} {
2770                 revert_helper \
2771                         "Reverting [short_path $current_diff]" \
2772                         [list $current_diff]
2773         }
2774 }
2775
2776 proc do_signoff {} {
2777         global ui_comm
2778
2779         set me [committer_ident]
2780         if {$me eq {}} return
2781
2782         set sob "Signed-off-by: $me"
2783         set last [$ui_comm get {end -1c linestart} {end -1c}]
2784         if {$last ne $sob} {
2785                 $ui_comm edit separator
2786                 if {$last ne {}
2787                         && ![regexp {^[A-Z][A-Za-z]*-[A-Za-z-]+: *} $last]} {
2788                         $ui_comm insert end "\n"
2789                 }
2790                 $ui_comm insert end "\n$sob"
2791                 $ui_comm edit separator
2792                 $ui_comm see end
2793         }
2794 }
2795
2796 proc do_select_commit_type {} {
2797         global commit_type selected_commit_type
2798
2799         if {$selected_commit_type eq {new}
2800                 && [string match amend* $commit_type]} {
2801                 create_new_commit
2802         } elseif {$selected_commit_type eq {amend}
2803                 && ![string match amend* $commit_type]} {
2804                 load_last_commit
2805
2806                 # The amend request was rejected...
2807                 #
2808                 if {![string match amend* $commit_type]} {
2809                         set selected_commit_type new
2810                 }
2811         }
2812 }
2813
2814 proc do_commit {} {
2815         commit_tree
2816 }
2817
2818 proc do_about {} {
2819         global appvers copyright
2820         global tcl_patchLevel tk_patchLevel
2821
2822         set w .about_dialog
2823         toplevel $w
2824         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2825
2826         label $w.header -text "About [appname]" \
2827                 -font font_uibold
2828         pack $w.header -side top -fill x
2829
2830         frame $w.buttons
2831         button $w.buttons.close -text {Close} \
2832                 -font font_ui \
2833                 -command [list destroy $w]
2834         pack $w.buttons.close -side right
2835         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2836
2837         label $w.desc \
2838                 -text "[appname] - a commit creation tool for Git.
2839 $copyright" \
2840                 -padx 5 -pady 5 \
2841                 -justify left \
2842                 -anchor w \
2843                 -borderwidth 1 \
2844                 -relief solid \
2845                 -font font_ui
2846         pack $w.desc -side top -fill x -padx 5 -pady 5
2847
2848         set v {}
2849         append v "[appname] version $appvers\n"
2850         append v "[exec git version]\n"
2851         append v "\n"
2852         if {$tcl_patchLevel eq $tk_patchLevel} {
2853                 append v "Tcl/Tk version $tcl_patchLevel"
2854         } else {
2855                 append v "Tcl version $tcl_patchLevel"
2856                 append v ", Tk version $tk_patchLevel"
2857         }
2858
2859         label $w.vers \
2860                 -text $v \
2861                 -padx 5 -pady 5 \
2862                 -justify left \
2863                 -anchor w \
2864                 -borderwidth 1 \
2865                 -relief solid \
2866                 -font font_ui
2867         pack $w.vers -side top -fill x -padx 5 -pady 5
2868
2869         menu $w.ctxm -tearoff 0
2870         $w.ctxm add command \
2871                 -label {Copy} \
2872                 -font font_ui \
2873                 -command "
2874                 clipboard clear
2875                 clipboard append -format STRING -type STRING -- \[$w.vers cget -text\]
2876         "
2877
2878         bind $w <Visibility> "grab $w; focus $w"
2879         bind $w <Key-Escape> "destroy $w"
2880         bind_button3 $w.vers "tk_popup $w.ctxm %X %Y; grab $w; focus $w"
2881         wm title $w "About [appname]"
2882         tkwait window $w
2883 }
2884
2885 proc do_options {} {
2886         global repo_config global_config font_descs
2887         global repo_config_new global_config_new
2888
2889         array unset repo_config_new
2890         array unset global_config_new
2891         foreach name [array names repo_config] {
2892                 set repo_config_new($name) $repo_config($name)
2893         }
2894         load_config 1
2895         foreach name [array names repo_config] {
2896                 switch -- $name {
2897                 gui.diffcontext {continue}
2898                 }
2899                 set repo_config_new($name) $repo_config($name)
2900         }
2901         foreach name [array names global_config] {
2902                 set global_config_new($name) $global_config($name)
2903         }
2904
2905         set w .options_editor
2906         toplevel $w
2907         wm geometry $w "+[winfo rootx .]+[winfo rooty .]"
2908
2909         label $w.header -text "[appname] Options" \
2910                 -font font_uibold
2911         pack $w.header -side top -fill x
2912
2913         frame $w.buttons
2914         button $w.buttons.restore -text {Restore Defaults} \
2915                 -font font_ui \
2916                 -command do_restore_defaults
2917         pack $w.buttons.restore -side left
2918         button $w.buttons.save -text Save \
2919                 -font font_ui \
2920                 -command [list do_save_config $w]
2921         pack $w.buttons.save -side right
2922         button $w.buttons.cancel -text {Cancel} \
2923                 -font font_ui \
2924                 -command [list destroy $w]
2925         pack $w.buttons.cancel -side right -padx 5
2926         pack $w.buttons -side bottom -fill x -pady 10 -padx 10
2927
2928         labelframe $w.repo -text "[reponame] Repository" \
2929                 -font font_ui \
2930                 -relief raised -borderwidth 2
2931         labelframe $w.global -text {Global (All Repositories)} \
2932                 -font font_ui \
2933                 -relief raised -borderwidth 2
2934         pack $w.repo -side left -fill both -expand 1 -pady 5 -padx 5
2935         pack $w.global -side right -fill both -expand 1 -pady 5 -padx 5
2936
2937         foreach option {
2938                 {b partialinclude {Allow Partially Added Files}}
2939                 {b pullsummary {Show Pull Summary}}
2940                 {b trustmtime  {Trust File Modification Timestamps}}
2941                 {i diffcontext {Number of Diff Context Lines}}
2942                 } {
2943                 set type [lindex $option 0]
2944                 set name [lindex $option 1]
2945                 set text [lindex $option 2]
2946                 foreach f {repo global} {
2947                         switch $type {
2948                         b {
2949                                 checkbutton $w.$f.$name -text $text \
2950                                         -variable ${f}_config_new(gui.$name) \
2951                                         -onvalue true \
2952                                         -offvalue false \
2953                                         -font font_ui
2954                                 pack $w.$f.$name -side top -anchor w
2955                         }
2956                         i {
2957                                 frame $w.$f.$name
2958                                 label $w.$f.$name.l -text "$text:" -font font_ui
2959                                 pack $w.$f.$name.l -side left -anchor w -fill x
2960                                 spinbox $w.$f.$name.v \
2961                                         -textvariable ${f}_config_new(gui.$name) \
2962                                         -from 1 -to 99 -increment 1 \
2963                                         -width 3 \
2964                                         -font font_ui
2965                                 pack $w.$f.$name.v -side right -anchor e
2966                                 pack $w.$f.$name -side top -anchor w -fill x
2967                         }
2968                         }
2969                 }
2970         }
2971
2972         set all_fonts [lsort [font families]]
2973         foreach option $font_descs {
2974                 set name [lindex $option 0]
2975                 set font [lindex $option 1]
2976                 set text [lindex $option 2]
2977
2978                 set global_config_new(gui.$font^^family) \
2979                         [font configure $font -family]
2980                 set global_config_new(gui.$font^^size) \
2981                         [font configure $font -size]
2982
2983                 frame $w.global.$name
2984                 label $w.global.$name.l -text "$text:" -font font_ui
2985                 pack $w.global.$name.l -side left -anchor w -fill x
2986                 eval tk_optionMenu $w.global.$name.family \
2987                         global_config_new(gui.$font^^family) \
2988                         $all_fonts
2989                 spinbox $w.global.$name.size \
2990                         -textvariable global_config_new(gui.$font^^size) \
2991                         -from 2 -to 80 -increment 1 \
2992                         -width 3 \
2993                         -font font_ui
2994                 pack $w.global.$name.size -side right -anchor e
2995                 pack $w.global.$name.family -side right -anchor e
2996                 pack $w.global.$name -side top -anchor w -fill x
2997         }
2998
2999         bind $w <Visibility> "grab $w; focus $w"
3000         bind $w <Key-Escape> "destroy $w"
3001         wm title $w "[appname] ([reponame]): Options"
3002         tkwait window $w
3003 }
3004
3005 proc do_restore_defaults {} {
3006         global font_descs default_config repo_config
3007         global repo_config_new global_config_new
3008
3009         foreach name [array names default_config] {
3010                 set repo_config_new($name) $default_config($name)
3011                 set global_config_new($name) $default_config($name)
3012         }
3013
3014         foreach option $font_descs {
3015                 set name [lindex $option 0]
3016                 set repo_config(gui.$name) $default_config(gui.$name)
3017         }
3018         apply_config
3019
3020         foreach option $font_descs {
3021                 set name [lindex $option 0]
3022                 set font [lindex $option 1]
3023                 set global_config_new(gui.$font^^family) \
3024                         [font configure $font -family]
3025                 set global_config_new(gui.$font^^size) \
3026                         [font configure $font -size]
3027         }
3028 }
3029
3030 proc do_save_config {w} {
3031         if {[catch {save_config} err]} {
3032                 error_popup "Failed to completely save options:\n\n$err"
3033         }
3034         reshow_diff
3035         destroy $w
3036 }
3037
3038 proc do_windows_shortcut {} {
3039         global argv0
3040
3041         if {[catch {
3042                 set desktop [exec cygpath \
3043                         --windows \
3044                         --absolute \
3045                         --long-name \
3046                         --desktop]
3047                 }]} {
3048                         set desktop .
3049         }
3050         set fn [tk_getSaveFile \
3051                 -parent . \
3052                 -title "[appname] ([reponame]): Create Desktop Icon" \
3053                 -initialdir $desktop \
3054                 -initialfile "Git [reponame].bat"]
3055         if {$fn != {}} {
3056                 if {[catch {
3057                                 set fd [open $fn w]
3058                                 set sh [exec cygpath \
3059                                         --windows \
3060                                         --absolute \
3061                                         /bin/sh]
3062                                 set me [exec cygpath \
3063                                         --unix \
3064                                         --absolute \
3065                                         $argv0]
3066                                 set gd [exec cygpath \
3067                                         --unix \
3068                                         --absolute \
3069                                         [gitdir]]
3070                                 set gw [exec cygpath \
3071                                         --windows \
3072                                         --absolute \
3073                                         [file dirname [gitdir]]]
3074                                 regsub -all ' $me "'\\''" me
3075                                 regsub -all ' $gd "'\\''" gd
3076                                 puts $fd "@ECHO Entering $gw"
3077                                 puts $fd "@ECHO Starting git-gui... please wait..."
3078                                 puts -nonewline $fd "@\"$sh\" --login -c \""
3079                                 puts -nonewline $fd "GIT_DIR='$gd'"
3080                                 puts -nonewline $fd " '$me'"
3081                                 puts $fd "&\""
3082                                 close $fd
3083                         } err]} {
3084                         error_popup "Cannot write script:\n\n$err"
3085                 }
3086         }
3087 }
3088
3089 proc do_macosx_app {} {
3090         global argv0 env
3091
3092         set fn [tk_getSaveFile \
3093                 -parent . \
3094                 -title "[appname] ([reponame]): Create Desktop Icon" \
3095                 -initialdir [file join $env(HOME) Desktop] \
3096                 -initialfile "Git [reponame].app"]
3097         if {$fn != {}} {
3098                 if {[catch {
3099                                 set Contents [file join $fn Contents]
3100                                 set MacOS [file join $Contents MacOS]
3101                                 set exe [file join $MacOS git-gui]
3102
3103                                 file mkdir $MacOS
3104
3105                                 set fd [open [file join $Contents Info.plist] w]
3106                                 puts $fd {<?xml version="1.0" encoding="UTF-8"?>
3107 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
3108 <plist version="1.0">
3109 <dict>
3110         <key>CFBundleDevelopmentRegion</key>
3111         <string>English</string>
3112         <key>CFBundleExecutable</key>
3113         <string>git-gui</string>
3114         <key>CFBundleIdentifier</key>
3115         <string>org.spearce.git-gui</string>
3116         <key>CFBundleInfoDictionaryVersion</key>
3117         <string>6.0</string>
3118         <key>CFBundlePackageType</key>
3119         <string>APPL</string>
3120         <key>CFBundleSignature</key>
3121         <string>????</string>
3122         <key>CFBundleVersion</key>
3123         <string>1.0</string>
3124         <key>NSPrincipalClass</key>
3125         <string>NSApplication</string>
3126 </dict>
3127 </plist>}
3128                                 close $fd
3129
3130                                 set fd [open $exe w]
3131                                 set gd [file normalize [gitdir]]
3132                                 set ep [file normalize [exec git --exec-path]]
3133                                 regsub -all ' $gd "'\\''" gd
3134                                 regsub -all ' $ep "'\\''" ep
3135                                 puts $fd "#!/bin/sh"
3136                                 foreach name [array names env] {
3137                                         if {[string match GIT_* $name]} {
3138                                                 regsub -all ' $env($name) "'\\''" v
3139                                                 puts $fd "export $name='$v'"
3140                                         }
3141                                 }
3142                                 puts $fd "export PATH='$ep':\$PATH"
3143                                 puts $fd "export GIT_DIR='$gd'"
3144                                 puts $fd "exec [file normalize $argv0]"
3145                                 close $fd
3146
3147                                 file attributes $exe -permissions u+x,g+x,o+x
3148                         } err]} {
3149                         error_popup "Cannot write icon:\n\n$err"
3150                 }
3151         }
3152 }
3153
3154 proc toggle_or_diff {w x y} {
3155         global file_states file_lists current_diff ui_index ui_workdir
3156         global last_clicked selected_paths
3157
3158         set pos [split [$w index @$x,$y] .]
3159         set lno [lindex $pos 0]
3160         set col [lindex $pos 1]
3161         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3162         if {$path eq {}} {
3163                 set last_clicked {}
3164                 return
3165         }
3166
3167         set last_clicked [list $w $lno]
3168         array unset selected_paths
3169         $ui_index tag remove in_sel 0.0 end
3170         $ui_workdir tag remove in_sel 0.0 end
3171
3172         if {$col == 0} {
3173                 if {$current_diff eq $path} {
3174                         set after {reshow_diff;}
3175                 } else {
3176                         set after {}
3177                 }
3178                 if {$w eq $ui_index} {
3179                         update_indexinfo \
3180                                 "Unstaging [short_path $path] from commit" \
3181                                 [list $path] \
3182                                 [concat $after {set ui_status_value {Ready.}}]
3183                 } elseif {$w eq $ui_workdir} {
3184                         update_index \
3185                                 "Adding [short_path $path]" \
3186                                 [list $path] \
3187                                 [concat $after {set ui_status_value {Ready.}}]
3188                 }
3189         } else {
3190                 show_diff $path $w $lno
3191         }
3192 }
3193
3194 proc add_one_to_selection {w x y} {
3195         global file_lists last_clicked selected_paths
3196
3197         set lno [lindex [split [$w index @$x,$y] .] 0]
3198         set path [lindex $file_lists($w) [expr {$lno - 1}]]
3199         if {$path eq {}} {
3200                 set last_clicked {}
3201                 return
3202         }
3203
3204         if {$last_clicked ne {}
3205                 && [lindex $last_clicked 0] ne $w} {
3206                 array unset selected_paths
3207                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
3208         }
3209
3210         set last_clicked [list $w $lno]
3211         if {[catch {set in_sel $selected_paths($path)}]} {
3212                 set in_sel 0
3213         }
3214         if {$in_sel} {
3215                 unset selected_paths($path)
3216                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
3217         } else {
3218                 set selected_paths($path) 1
3219                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
3220         }
3221 }
3222
3223 proc add_range_to_selection {w x y} {
3224         global file_lists last_clicked selected_paths
3225
3226         if {[lindex $last_clicked 0] ne $w} {
3227                 toggle_or_diff $w $x $y
3228                 return
3229         }
3230
3231         set lno [lindex [split [$w index @$x,$y] .] 0]
3232         set lc [lindex $last_clicked 1]
3233         if {$lc < $lno} {
3234                 set begin $lc
3235                 set end $lno
3236         } else {
3237                 set begin $lno
3238                 set end $lc
3239         }
3240
3241         foreach path [lrange $file_lists($w) \
3242                 [expr {$begin - 1}] \
3243                 [expr {$end - 1}]] {
3244                 set selected_paths($path) 1
3245         }
3246         $w tag add in_sel $begin.0 [expr {$end + 1}].0
3247 }
3248
3249 ######################################################################
3250 ##
3251 ## config defaults
3252
3253 set cursor_ptr arrow
3254 font create font_diff -family Courier -size 10
3255 font create font_ui
3256 catch {
3257         label .dummy
3258         eval font configure font_ui [font actual [.dummy cget -font]]
3259         destroy .dummy
3260 }
3261
3262 font create font_uibold
3263 font create font_diffbold
3264
3265 if {[is_Windows]} {
3266         set M1B Control
3267         set M1T Ctrl
3268 } elseif {[is_MacOSX]} {
3269         set M1B M1
3270         set M1T Cmd
3271 } else {
3272         set M1B M1
3273         set M1T M1
3274 }
3275
3276 proc apply_config {} {
3277         global repo_config font_descs
3278
3279         foreach option $font_descs {
3280                 set name [lindex $option 0]
3281                 set font [lindex $option 1]
3282                 if {[catch {
3283                         foreach {cn cv} $repo_config(gui.$name) {
3284                                 font configure $font $cn $cv
3285                         }
3286                         } err]} {
3287                         error_popup "Invalid font specified in gui.$name:\n\n$err"
3288                 }
3289                 foreach {cn cv} [font configure $font] {
3290                         font configure ${font}bold $cn $cv
3291                 }
3292                 font configure ${font}bold -weight bold
3293         }
3294 }
3295
3296 set default_config(gui.trustmtime) false
3297 set default_config(gui.pullsummary) true
3298 set default_config(gui.partialinclude) false
3299 set default_config(gui.diffcontext) 5
3300 set default_config(gui.fontui) [font configure font_ui]
3301 set default_config(gui.fontdiff) [font configure font_diff]
3302 set font_descs {
3303         {fontui   font_ui   {Main Font}}
3304         {fontdiff font_diff {Diff/Console Font}}
3305 }
3306 load_config 0
3307 apply_config
3308
3309 ######################################################################
3310 ##
3311 ## ui construction
3312
3313 # -- Menu Bar
3314 #
3315 menu .mbar -tearoff 0
3316 .mbar add cascade -label Repository -menu .mbar.repository
3317 .mbar add cascade -label Edit -menu .mbar.edit
3318 if {!$single_commit} {
3319         .mbar add cascade -label Branch -menu .mbar.branch
3320 }
3321 .mbar add cascade -label Commit -menu .mbar.commit
3322 if {!$single_commit} {
3323         .mbar add cascade -label Fetch -menu .mbar.fetch
3324         .mbar add cascade -label Pull -menu .mbar.pull
3325         .mbar add cascade -label Push -menu .mbar.push
3326 }
3327 . configure -menu .mbar
3328
3329 # -- Repository Menu
3330 #
3331 menu .mbar.repository
3332 .mbar.repository add command \
3333         -label {Visualize Current Branch} \
3334         -command {do_gitk {}} \
3335         -font font_ui
3336 if {![is_MacOSX]} {
3337         .mbar.repository add command \
3338                 -label {Visualize All Branches} \
3339                 -command {do_gitk {--all}} \
3340                 -font font_ui
3341 }
3342 .mbar.repository add separator
3343
3344 if {!$single_commit} {
3345         .mbar.repository add command -label {Compress Database} \
3346                 -command do_gc \
3347                 -font font_ui
3348
3349         .mbar.repository add command -label {Verify Database} \
3350                 -command do_fsck_objects \
3351                 -font font_ui
3352
3353         .mbar.repository add separator
3354
3355         if {[is_Windows]} {
3356                 .mbar.repository add command \
3357                         -label {Create Desktop Icon} \
3358                         -command do_windows_shortcut \
3359                         -font font_ui
3360         } elseif {[is_MacOSX]} {
3361                 .mbar.repository add command \
3362                         -label {Create Desktop Icon} \
3363                         -command do_macosx_app \
3364                         -font font_ui
3365         }
3366 }
3367
3368 .mbar.repository add command -label Quit \
3369         -command do_quit \
3370         -accelerator $M1T-Q \
3371         -font font_ui
3372
3373 # -- Edit Menu
3374 #
3375 menu .mbar.edit
3376 .mbar.edit add command -label Undo \
3377         -command {catch {[focus] edit undo}} \
3378         -accelerator $M1T-Z \
3379         -font font_ui
3380 .mbar.edit add command -label Redo \
3381         -command {catch {[focus] edit redo}} \
3382         -accelerator $M1T-Y \
3383         -font font_ui
3384 .mbar.edit add separator
3385 .mbar.edit add command -label Cut \
3386         -command {catch {tk_textCut [focus]}} \
3387         -accelerator $M1T-X \
3388         -font font_ui
3389 .mbar.edit add command -label Copy \
3390         -command {catch {tk_textCopy [focus]}} \
3391         -accelerator $M1T-C \
3392         -font font_ui
3393 .mbar.edit add command -label Paste \
3394         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
3395         -accelerator $M1T-V \
3396         -font font_ui
3397 .mbar.edit add command -label Delete \
3398         -command {catch {[focus] delete sel.first sel.last}} \
3399         -accelerator Del \
3400         -font font_ui
3401 .mbar.edit add separator
3402 .mbar.edit add command -label {Select All} \
3403         -command {catch {[focus] tag add sel 0.0 end}} \
3404         -accelerator $M1T-A \
3405         -font font_ui
3406
3407 # -- Branch Menu
3408 #
3409 if {!$single_commit} {
3410         menu .mbar.branch
3411
3412         .mbar.branch add command -label {Create...} \
3413                 -command do_create_branch \
3414                 -accelerator $M1T-N \
3415                 -font font_ui
3416         lappend disable_on_lock [list .mbar.branch entryconf \
3417                 [.mbar.branch index last] -state]
3418
3419         .mbar.branch add command -label {Delete...} \
3420                 -command do_delete_branch \
3421                 -font font_ui
3422         lappend disable_on_lock [list .mbar.branch entryconf \
3423                 [.mbar.branch index last] -state]
3424 }
3425
3426 # -- Commit Menu
3427 #
3428 menu .mbar.commit
3429
3430 .mbar.commit add radiobutton \
3431         -label {New Commit} \
3432         -command do_select_commit_type \
3433         -variable selected_commit_type \
3434         -value new \
3435         -font font_ui
3436 lappend disable_on_lock \
3437         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3438
3439 .mbar.commit add radiobutton \
3440         -label {Amend Last Commit} \
3441         -command do_select_commit_type \
3442         -variable selected_commit_type \
3443         -value amend \
3444         -font font_ui
3445 lappend disable_on_lock \
3446         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3447
3448 .mbar.commit add separator
3449
3450 .mbar.commit add command -label Rescan \
3451         -command do_rescan \
3452         -accelerator F5 \
3453         -font font_ui
3454 lappend disable_on_lock \
3455         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3456
3457 .mbar.commit add command -label {Add To Commit} \
3458         -command do_add_selection \
3459         -font font_ui
3460 lappend disable_on_lock \
3461         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3462
3463 .mbar.commit add command -label {Add All To Commit} \
3464         -command do_add_all \
3465         -accelerator $M1T-I \
3466         -font font_ui
3467 lappend disable_on_lock \
3468         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3469
3470 .mbar.commit add command -label {Unstage From Commit} \
3471         -command do_unstage_selection \
3472         -font font_ui
3473 lappend disable_on_lock \
3474         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3475
3476 .mbar.commit add command -label {Revert Changes} \
3477         -command do_revert_selection \
3478         -font font_ui
3479 lappend disable_on_lock \
3480         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3481
3482 .mbar.commit add separator
3483
3484 .mbar.commit add command -label {Sign Off} \
3485         -command do_signoff \
3486         -accelerator $M1T-S \
3487         -font font_ui
3488
3489 .mbar.commit add command -label Commit \
3490         -command do_commit \
3491         -accelerator $M1T-Return \
3492         -font font_ui
3493 lappend disable_on_lock \
3494         [list .mbar.commit entryconf [.mbar.commit index last] -state]
3495
3496 # -- Transport menus
3497 #
3498 if {!$single_commit} {
3499         menu .mbar.fetch
3500         menu .mbar.pull
3501         menu .mbar.push
3502 }
3503
3504 if {[is_MacOSX]} {
3505         # -- Apple Menu (Mac OS X only)
3506         #
3507         .mbar add cascade -label Apple -menu .mbar.apple
3508         menu .mbar.apple
3509
3510         .mbar.apple add command -label "About [appname]" \
3511                 -command do_about \
3512                 -font font_ui
3513         .mbar.apple add command -label "[appname] Options..." \
3514                 -command do_options \
3515                 -font font_ui
3516 } else {
3517         # -- Edit Menu
3518         #
3519         .mbar.edit add separator
3520         .mbar.edit add command -label {Options...} \
3521                 -command do_options \
3522                 -font font_ui
3523
3524         # -- Tools Menu
3525         #
3526         if {[file exists /usr/local/miga/lib/gui-miga]
3527                 && [file exists .pvcsrc]} {
3528         proc do_miga {} {
3529                 global ui_status_value
3530                 if {![lock_index update]} return
3531                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
3532                 set miga_fd [open "|$cmd" r]
3533                 fconfigure $miga_fd -blocking 0
3534                 fileevent $miga_fd readable [list miga_done $miga_fd]
3535                 set ui_status_value {Running miga...}
3536         }
3537         proc miga_done {fd} {
3538                 read $fd 512
3539                 if {[eof $fd]} {
3540                         close $fd
3541                         unlock_index
3542                         rescan [list set ui_status_value {Ready.}]
3543                 }
3544         }
3545         .mbar add cascade -label Tools -menu .mbar.tools
3546         menu .mbar.tools
3547         .mbar.tools add command -label "Migrate" \
3548                 -command do_miga \
3549                 -font font_ui
3550         lappend disable_on_lock \
3551                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
3552         }
3553
3554         # -- Help Menu
3555         #
3556         .mbar add cascade -label Help -menu .mbar.help
3557         menu .mbar.help
3558
3559         .mbar.help add command -label "About [appname]" \
3560                 -command do_about \
3561                 -font font_ui
3562 }
3563
3564
3565 # -- Branch Control
3566 #
3567 frame .branch \
3568         -borderwidth 1 \
3569         -relief sunken
3570 label .branch.l1 \
3571         -text {Current Branch:} \
3572         -anchor w \
3573         -justify left \
3574         -font font_ui
3575 label .branch.cb \
3576         -textvariable current_branch \
3577         -anchor w \
3578         -justify left \
3579         -font font_ui
3580 pack .branch.l1 -side left
3581 pack .branch.cb -side left -fill x
3582 pack .branch -side top -fill x
3583
3584 # -- Main Window Layout
3585 #
3586 panedwindow .vpane -orient vertical
3587 panedwindow .vpane.files -orient horizontal
3588 .vpane add .vpane.files -sticky nsew -height 100 -width 400
3589 pack .vpane -anchor n -side top -fill both -expand 1
3590
3591 # -- Index File List
3592 #
3593 frame .vpane.files.index -height 100 -width 400
3594 label .vpane.files.index.title -text {Changes To Be Committed} \
3595         -background green \
3596         -font font_ui
3597 text $ui_index -background white -borderwidth 0 \
3598         -width 40 -height 10 \
3599         -font font_ui \
3600         -cursor $cursor_ptr \
3601         -yscrollcommand {.vpane.files.index.sb set} \
3602         -state disabled
3603 scrollbar .vpane.files.index.sb -command [list $ui_index yview]
3604 pack .vpane.files.index.title -side top -fill x
3605 pack .vpane.files.index.sb -side right -fill y
3606 pack $ui_index -side left -fill both -expand 1
3607 .vpane.files add .vpane.files.index -sticky nsew
3608
3609 # -- Working Directory File List
3610 #
3611 frame .vpane.files.workdir -height 100 -width 100
3612 label .vpane.files.workdir.title -text {Changed But Not Updated} \
3613         -background red \
3614         -font font_ui
3615 text $ui_workdir -background white -borderwidth 0 \
3616         -width 40 -height 10 \
3617         -font font_ui \
3618         -cursor $cursor_ptr \
3619         -yscrollcommand {.vpane.files.workdir.sb set} \
3620         -state disabled
3621 scrollbar .vpane.files.workdir.sb -command [list $ui_workdir yview]
3622 pack .vpane.files.workdir.title -side top -fill x
3623 pack .vpane.files.workdir.sb -side right -fill y
3624 pack $ui_workdir -side left -fill both -expand 1
3625 .vpane.files add .vpane.files.workdir -sticky nsew
3626
3627 foreach i [list $ui_index $ui_workdir] {
3628         $i tag conf in_diff -font font_uibold
3629         $i tag conf in_sel \
3630                 -background [$i cget -foreground] \
3631                 -foreground [$i cget -background]
3632 }
3633 unset i
3634
3635 # -- Diff and Commit Area
3636 #
3637 frame .vpane.lower -height 300 -width 400
3638 frame .vpane.lower.commarea
3639 frame .vpane.lower.diff -relief sunken -borderwidth 1
3640 pack .vpane.lower.commarea -side top -fill x
3641 pack .vpane.lower.diff -side bottom -fill both -expand 1
3642 .vpane add .vpane.lower -stick nsew
3643
3644 # -- Commit Area Buttons
3645 #
3646 frame .vpane.lower.commarea.buttons
3647 label .vpane.lower.commarea.buttons.l -text {} \
3648         -anchor w \
3649         -justify left \
3650         -font font_ui
3651 pack .vpane.lower.commarea.buttons.l -side top -fill x
3652 pack .vpane.lower.commarea.buttons -side left -fill y
3653
3654 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
3655         -command do_rescan \
3656         -font font_ui
3657 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3658 lappend disable_on_lock \
3659         {.vpane.lower.commarea.buttons.rescan conf -state}
3660
3661 button .vpane.lower.commarea.buttons.incall -text {Add All} \
3662         -command do_add_all \
3663         -font font_ui
3664 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3665 lappend disable_on_lock \
3666         {.vpane.lower.commarea.buttons.incall conf -state}
3667
3668 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
3669         -command do_signoff \
3670         -font font_ui
3671 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3672
3673 button .vpane.lower.commarea.buttons.commit -text {Commit} \
3674         -command do_commit \
3675         -font font_ui
3676 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3677 lappend disable_on_lock \
3678         {.vpane.lower.commarea.buttons.commit conf -state}
3679
3680 # -- Commit Message Buffer
3681 #
3682 frame .vpane.lower.commarea.buffer
3683 frame .vpane.lower.commarea.buffer.header
3684 set ui_comm .vpane.lower.commarea.buffer.t
3685 set ui_coml .vpane.lower.commarea.buffer.header.l
3686 radiobutton .vpane.lower.commarea.buffer.header.new \
3687         -text {New Commit} \
3688         -command do_select_commit_type \
3689         -variable selected_commit_type \
3690         -value new \
3691         -font font_ui
3692 lappend disable_on_lock \
3693         [list .vpane.lower.commarea.buffer.header.new conf -state]
3694 radiobutton .vpane.lower.commarea.buffer.header.amend \
3695         -text {Amend Last Commit} \
3696         -command do_select_commit_type \
3697         -variable selected_commit_type \
3698         -value amend \
3699         -font font_ui
3700 lappend disable_on_lock \
3701         [list .vpane.lower.commarea.buffer.header.amend conf -state]
3702 label $ui_coml \
3703         -anchor w \
3704         -justify left \
3705         -font font_ui
3706 proc trace_commit_type {varname args} {
3707         global ui_coml commit_type
3708         switch -glob -- $commit_type {
3709         initial       {set txt {Initial Commit Message:}}
3710         amend         {set txt {Amended Commit Message:}}
3711         amend-initial {set txt {Amended Initial Commit Message:}}
3712         amend-merge   {set txt {Amended Merge Commit Message:}}
3713         merge         {set txt {Merge Commit Message:}}
3714         *             {set txt {Commit Message:}}
3715         }
3716         $ui_coml conf -text $txt
3717 }
3718 trace add variable commit_type write trace_commit_type
3719 pack $ui_coml -side left -fill x
3720 pack .vpane.lower.commarea.buffer.header.amend -side right
3721 pack .vpane.lower.commarea.buffer.header.new -side right
3722
3723 text $ui_comm -background white -borderwidth 1 \
3724         -undo true \
3725         -maxundo 20 \
3726         -autoseparators true \
3727         -relief sunken \
3728         -width 75 -height 9 -wrap none \
3729         -font font_diff \
3730         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3731 scrollbar .vpane.lower.commarea.buffer.sby \
3732         -command [list $ui_comm yview]
3733 pack .vpane.lower.commarea.buffer.header -side top -fill x
3734 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3735 pack $ui_comm -side left -fill y
3736 pack .vpane.lower.commarea.buffer -side left -fill y
3737
3738 # -- Commit Message Buffer Context Menu
3739 #
3740 set ctxm .vpane.lower.commarea.buffer.ctxm
3741 menu $ctxm -tearoff 0
3742 $ctxm add command \
3743         -label {Cut} \
3744         -font font_ui \
3745         -command {tk_textCut $ui_comm}
3746 $ctxm add command \
3747         -label {Copy} \
3748         -font font_ui \
3749         -command {tk_textCopy $ui_comm}
3750 $ctxm add command \
3751         -label {Paste} \
3752         -font font_ui \
3753         -command {tk_textPaste $ui_comm}
3754 $ctxm add command \
3755         -label {Delete} \
3756         -font font_ui \
3757         -command {$ui_comm delete sel.first sel.last}
3758 $ctxm add separator
3759 $ctxm add command \
3760         -label {Select All} \
3761         -font font_ui \
3762         -command {$ui_comm tag add sel 0.0 end}
3763 $ctxm add command \
3764         -label {Copy All} \
3765         -font font_ui \
3766         -command {
3767                 $ui_comm tag add sel 0.0 end
3768                 tk_textCopy $ui_comm
3769                 $ui_comm tag remove sel 0.0 end
3770         }
3771 $ctxm add separator
3772 $ctxm add command \
3773         -label {Sign Off} \
3774         -font font_ui \
3775         -command do_signoff
3776 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
3777
3778 # -- Diff Header
3779 #
3780 set current_diff {}
3781 set diff_actions [list]
3782 proc trace_current_diff {varname args} {
3783         global current_diff diff_actions file_states
3784         if {$current_diff eq {}} {
3785                 set s {}
3786                 set f {}
3787                 set p {}
3788                 set o disabled
3789         } else {
3790                 set p $current_diff
3791                 set s [mapdesc [lindex $file_states($p) 0] $p]
3792                 set f {File:}
3793                 set p [escape_path $p]
3794                 set o normal
3795         }
3796
3797         .vpane.lower.diff.header.status configure -text $s
3798         .vpane.lower.diff.header.file configure -text $f
3799         .vpane.lower.diff.header.path configure -text $p
3800         foreach w $diff_actions {
3801                 uplevel #0 $w $o
3802         }
3803 }
3804 trace add variable current_diff write trace_current_diff
3805
3806 frame .vpane.lower.diff.header -background orange
3807 label .vpane.lower.diff.header.status \
3808         -background orange \
3809         -width $max_status_desc \
3810         -anchor w \
3811         -justify left \
3812         -font font_ui
3813 label .vpane.lower.diff.header.file \
3814         -background orange \
3815         -anchor w \
3816         -justify left \
3817         -font font_ui
3818 label .vpane.lower.diff.header.path \
3819         -background orange \
3820         -anchor w \
3821         -justify left \
3822         -font font_ui
3823 pack .vpane.lower.diff.header.status -side left
3824 pack .vpane.lower.diff.header.file -side left
3825 pack .vpane.lower.diff.header.path -fill x
3826 set ctxm .vpane.lower.diff.header.ctxm
3827 menu $ctxm -tearoff 0
3828 $ctxm add command \
3829         -label {Copy} \
3830         -font font_ui \
3831         -command {
3832                 clipboard clear
3833                 clipboard append \
3834                         -format STRING \
3835                         -type STRING \
3836                         -- $current_diff
3837         }
3838 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3839 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3840
3841 # -- Diff Body
3842 #
3843 frame .vpane.lower.diff.body
3844 set ui_diff .vpane.lower.diff.body.t
3845 text $ui_diff -background white -borderwidth 0 \
3846         -width 80 -height 15 -wrap none \
3847         -font font_diff \
3848         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3849         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3850         -state disabled
3851 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3852         -command [list $ui_diff xview]
3853 scrollbar .vpane.lower.diff.body.sby -orient vertical \
3854         -command [list $ui_diff yview]
3855 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3856 pack .vpane.lower.diff.body.sby -side right -fill y
3857 pack $ui_diff -side left -fill both -expand 1
3858 pack .vpane.lower.diff.header -side top -fill x
3859 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3860
3861 $ui_diff tag conf d_@ -font font_diffbold
3862 $ui_diff tag conf d_+  -foreground blue
3863 $ui_diff tag conf d_-  -foreground red
3864 $ui_diff tag conf d_++ -foreground {#00a000}
3865 $ui_diff tag conf d_-- -foreground {#a000a0}
3866 $ui_diff tag conf d_+- \
3867         -foreground red \
3868         -background {light goldenrod yellow}
3869 $ui_diff tag conf d_-+ \
3870         -foreground blue \
3871         -background azure2
3872
3873 # -- Diff Body Context Menu
3874 #
3875 set ctxm .vpane.lower.diff.body.ctxm
3876 menu $ctxm -tearoff 0
3877 $ctxm add command \
3878         -label {Copy} \
3879         -font font_ui \
3880         -command {tk_textCopy $ui_diff}
3881 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3882 $ctxm add command \
3883         -label {Select All} \
3884         -font font_ui \
3885         -command {$ui_diff tag add sel 0.0 end}
3886 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3887 $ctxm add command \
3888         -label {Copy All} \
3889         -font font_ui \
3890         -command {
3891                 $ui_diff tag add sel 0.0 end
3892                 tk_textCopy $ui_diff
3893                 $ui_diff tag remove sel 0.0 end
3894         }
3895 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3896 $ctxm add separator
3897 $ctxm add command \
3898         -label {Decrease Font Size} \
3899         -font font_ui \
3900         -command {incr_font_size font_diff -1}
3901 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3902 $ctxm add command \
3903         -label {Increase Font Size} \
3904         -font font_ui \
3905         -command {incr_font_size font_diff 1}
3906 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3907 $ctxm add separator
3908 $ctxm add command \
3909         -label {Show Less Context} \
3910         -font font_ui \
3911         -command {if {$repo_config(gui.diffcontext) >= 2} {
3912                 incr repo_config(gui.diffcontext) -1
3913                 reshow_diff
3914         }}
3915 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3916 $ctxm add command \
3917         -label {Show More Context} \
3918         -font font_ui \
3919         -command {
3920                 incr repo_config(gui.diffcontext)
3921                 reshow_diff
3922         }
3923 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3924 $ctxm add separator
3925 $ctxm add command -label {Options...} \
3926         -font font_ui \
3927         -command do_options
3928 bind_button3 $ui_diff "tk_popup $ctxm %X %Y"
3929
3930 # -- Status Bar
3931 #
3932 set ui_status_value {Initializing...}
3933 label .status -textvariable ui_status_value \
3934         -anchor w \
3935         -justify left \
3936         -borderwidth 1 \
3937         -relief sunken \
3938         -font font_ui
3939 pack .status -anchor w -side bottom -fill x
3940
3941 # -- Load geometry
3942 #
3943 catch {
3944 set gm $repo_config(gui.geometry)
3945 wm geometry . [lindex $gm 0]
3946 .vpane sash place 0 \
3947         [lindex [.vpane sash coord 0] 0] \
3948         [lindex $gm 1]
3949 .vpane.files sash place 0 \
3950         [lindex $gm 2] \
3951         [lindex [.vpane.files sash coord 0] 1]
3952 unset gm
3953 }
3954
3955 # -- Key Bindings
3956 #
3957 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3958 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3959 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3960 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3961 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3962 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3963 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3964 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3965 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3966 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3967 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3968
3969 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3970 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3971 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3972 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3973 bind $ui_diff <$M1B-Key-v> {break}
3974 bind $ui_diff <$M1B-Key-V> {break}
3975 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3976 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3977 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3978 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3979 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3980 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3981
3982 if {!$single_commit} {
3983         bind . <$M1B-Key-n> do_create_branch
3984         bind . <$M1B-Key-N> do_create_branch
3985 }
3986
3987 bind .   <Destroy> do_quit
3988 bind all <Key-F5> do_rescan
3989 bind all <$M1B-Key-r> do_rescan
3990 bind all <$M1B-Key-R> do_rescan
3991 bind .   <$M1B-Key-s> do_signoff
3992 bind .   <$M1B-Key-S> do_signoff
3993 bind .   <$M1B-Key-i> do_add_all
3994 bind .   <$M1B-Key-I> do_add_all
3995 bind .   <$M1B-Key-Return> do_commit
3996 bind all <$M1B-Key-q> do_quit
3997 bind all <$M1B-Key-Q> do_quit
3998 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3999 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
4000 foreach i [list $ui_index $ui_workdir] {
4001         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
4002         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
4003         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
4004 }
4005 unset i
4006
4007 set file_lists($ui_index) [list]
4008 set file_lists($ui_workdir) [list]
4009
4010 set HEAD {}
4011 set PARENT {}
4012 set MERGE_HEAD [list]
4013 set commit_type {}
4014 set empty_tree {}
4015 set current_branch {}
4016 set current_diff {}
4017 set selected_commit_type new
4018
4019 wm title . "[appname] ([file normalize [file dirname [gitdir]]])"
4020 focus -force $ui_comm
4021
4022 # -- Warn the user about environmental problems.  Cygwin's Tcl
4023 #    does *not* pass its env array onto any processes it spawns.
4024 #    This means that git processes get none of our environment.
4025 #
4026 if {[is_Windows]} {
4027         set ignored_env 0
4028         set suggest_user {}
4029         set msg "Possible environment issues exist.
4030
4031 The following environment variables are probably
4032 going to be ignored by any Git subprocess run
4033 by [appname]:
4034
4035 "
4036         foreach name [array names env] {
4037                 switch -regexp -- $name {
4038                 {^GIT_INDEX_FILE$} -
4039                 {^GIT_OBJECT_DIRECTORY$} -
4040                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
4041                 {^GIT_DIFF_OPTS$} -
4042                 {^GIT_EXTERNAL_DIFF$} -
4043                 {^GIT_PAGER$} -
4044                 {^GIT_TRACE$} -
4045                 {^GIT_CONFIG$} -
4046                 {^GIT_CONFIG_LOCAL$} -
4047                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
4048                         append msg " - $name\n"
4049                         incr ignored_env
4050                 }
4051                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
4052                         append msg " - $name\n"
4053                         incr ignored_env
4054                         set suggest_user $name
4055                 }
4056                 }
4057         }
4058         if {$ignored_env > 0} {
4059                 append msg "
4060 This is due to a known issue with the
4061 Tcl binary distributed by Cygwin."
4062
4063                 if {$suggest_user ne {}} {
4064                         append msg "
4065
4066 A good replacement for $suggest_user
4067 is placing values for the user.name and
4068 user.email settings into your personal
4069 ~/.gitconfig file.
4070 "
4071                 }
4072                 warn_popup $msg
4073         }
4074         unset ignored_env msg suggest_user name
4075 }
4076
4077 # -- Only initialize complex UI if we are going to stay running.
4078 #
4079 if {!$single_commit} {
4080         load_all_remotes
4081         load_all_heads
4082
4083         populate_branch_menu
4084         populate_fetch_menu .mbar.fetch
4085         populate_pull_menu .mbar.pull
4086         populate_push_menu .mbar.push
4087 }
4088
4089 # -- Only suggest a gc run if we are going to stay running.
4090 #
4091 if {!$single_commit} {
4092         set object_limit 2000
4093         if {[is_Windows]} {set object_limit 200}
4094         regexp {^([0-9]+) objects,} [exec git count-objects] _junk objects_current
4095         if {$objects_current >= $object_limit} {
4096                 if {[ask_popup \
4097                         "This repository currently has $objects_current loose objects.
4098
4099 To maintain optimal performance it is strongly
4100 recommended that you compress the database
4101 when more than $object_limit loose objects exist.
4102
4103 Compress the database now?"] eq yes} {
4104                         do_gc
4105                 }
4106         }
4107         unset object_limit _junk objects_current
4108 }
4109
4110 lock_index begin-read
4111 after 1 do_rescan