configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49
  50
  51 ## Site configuration
  52 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  53 #
  54 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
  55 # tests.  These tests take up a significant amount of the total test time
  56 # but are not needed unless you plan to talk to SVN repos.
  57 #
  58 # Define MOZILLA_SHA1 environment variable when running make to make use of
  59 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
  60 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
  61 # choice) has very fast version optimized for i586.
  62 #
  63 # Define PPC_SHA1 environment variable when running make to make use of
  64 # a bundled SHA1 routine optimized for PowerPC.
  65 #
  66 # Define ARM_SHA1 environment variable when running make to make use of
  67 # a bundled SHA1 routine optimized for ARM.
  68 #
  69 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
  70 # This also implies MOZILLA_SHA1.
  71 #
  72 # Define NO_CURL if you do not have curl installed.  git-http-pull and
  73 # git-http-push are not built, and you cannot use http:// and https://
  74 # transports.
  75 #
  76 # Define CURLDIR=/foo/bar if your curl header and library files are in
  77 # /foo/bar/include and /foo/bar/lib directories.
  78 #
  79 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
  80 # not built, and you cannot push using http:// and https:// transports.
  81 #
  82 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
  83 # installed in /sw, but don't want GIT to link against any libraries
  84 # installed there.  If defined you may specify your own (or Fink's)
  85 # include directories and library directories by defining CFLAGS
  86 # and LDFLAGS appropriately.
  87 #
  88 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
  89 # have DarwinPorts installed in /opt/local, but don't want GIT to
  90 # link against any libraries installed there.  If defined you may
  91 # specify your own (or DarwinPort's) include directories and
  92 # library directories by defining CFLAGS and LDFLAGS appropriately.
  93 #
  94 # Define NO_MMAP if you want to avoid mmap.
  95 #
  96 # Define SHELL_PATH to provide path to shell.
  97 GIT_ARG_SET_PATH(shell)
  98 #
  99 # Define PERL_PATH to provide path to Perl.
 100 GIT_ARG_SET_PATH(perl)
 101 #
 102 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 103 # Define PYTHON_PATH to provide path to Python.
 104 AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
 105 AS_HELP_STRING([--without-python], [don't use python scripts])],
 106  [if test "$withval" = "no"; then \
 107     NO_PYTHON=YesPlease; \
 108   elif test "$withval" = "yes"; then \
 109     NO_PYTHON=; \
 110   else \
 111     NO_PYTHON=; \
 112     PYTHON_PATH=$withval; \
 113   fi; \
 114  ])
 115 AC_SUBST(NO_PYTHON)
 116 AC_SUBST(PYTHON_PATH)
 117 #
 118 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 119 # Define COLLISION_CHECK below if you believe that SHA1's
 120 # 1461501637330902918203684832716283019655932542976 hashes do not give you
 121 # sufficient guarantee that no collisions between objects will ever happen.
 122 #
 123 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 124 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 125 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 126 # randomly break unless your underlying filesystem supports those sub-second
 127 # times (my ext3 doesn't).
 128 #
 129 # Define USE_STDEV below if you want git to care about the underlying device
 130 # change being considered an inode change from the update-cache perspective.
 131
 132
 133 ## Checks for programs.
 134 AC_MSG_NOTICE([CHECKS for programs])
 135 #
 136 AC_PROG_CC
 137 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 138 AC_CHECK_TOOL(AR, ar, :)
 139 AC_CHECK_PROGS(TAR, [gtar tar])
 140 #
 141 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 142 # Define PYTHON_PATH to provide path to Python.
 143 if test -z "$NO_PYTHON"; then
 144         if test -z "$PYTHON_PATH"; then
 145                 AC_PATH_PROGS(PYTHON_PATH, [python python2.4 python2.3 python2])
 146         fi
 147         if test -n "$PYTHON_PATH"; then
 148                 GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
 149                 NO_PYTHON=""
 150         fi
 151 fi
 152
 153
 154 ## Checks for libraries.
 155 AC_MSG_NOTICE([CHECKS for libraries])
 156 #
 157 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 158 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 159 AC_CHECK_LIB([crypto], [SHA1_Init],
 160 [NEEDS_SSL_WITH_CRYPTO=],
 161 [AC_CHECK_LIB([ssl], [SHA1_Init],
 162  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 163   NEEDS_SSL_WITH_CRYPTO=],
 164  [NO_OPENSSL=YesPlease])])
 165 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 166 AC_SUBST(NO_OPENSSL)
 167 #
 168 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 169 # git-http-push are not built, and you cannot use http:// and https://
 170 # transports.
 171 AC_CHECK_LIB([curl], [curl_global_init],
 172 [NO_CURL=],
 173 [NO_CURL=YesPlease])
 174 AC_SUBST(NO_CURL)
 175 #
 176 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 177 # not built, and you cannot push using http:// and https:// transports.
 178 AC_CHECK_LIB([expat], [XML_ParserCreate],
 179 [NO_EXPAT=],
 180 [NO_EXPAT=YesPlease])
 181 AC_SUBST(NO_EXPAT)
 182 #
 183 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 184 AC_CHECK_LIB([c], [iconv],
 185 [NEEDS_LIBICONV=],
 186 [NEEDS_LIBICONV=YesPlease])
 187 AC_SUBST(NEEDS_LIBICONV)
 188 #
 189 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 190 # Patrick Mauritz).
 191 AC_CHECK_LIB([c], [socket],
 192 [NEEDS_SOCKET=],
 193 [NEEDS_SOCKET=YesPlease])
 194 AC_SUBST(NEEDS_SOCKET)
 195
 196
 197 ## Checks for header files.
 198
 199
 200 ## Checks for typedefs, structures, and compiler characteristics.
 201 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 202 #
 203 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 204 AC_CHECK_MEMBER(struct dirent.d_ino,
 205 [NO_D_INO_IN_DIRENT=],
 206 [NO_D_INO_IN_DIRENT=YesPlease],
 207 [#include <dirent.h>])
 208 AC_SUBST(NO_D_INO_IN_DIRENT)
 209 #
 210 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 211 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 212 AC_CHECK_MEMBER(struct dirent.d_type,
 213 [NO_D_TYPE_IN_DIRENT=],
 214 [NO_D_TYPE_IN_DIRENT=YesPlease],
 215 [#include <dirent.h>])
 216 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 217 #
 218 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 219 # sockaddr_storage.
 220 AC_CHECK_TYPE(struct sockaddr_storage,
 221 [NO_SOCKADDR_STORAGE=],
 222 [NO_SOCKADDR_STORAGE=YesPlease],
 223 [#include <netinet/in.h>])
 224 AC_SUBST(NO_SOCKADDR_STORAGE)
 225 #
 226 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 227 AC_CHECK_TYPE([struct addrinfo],[
 228  AC_CHECK_FUNC([getaddrinfo],
 229   [NO_IPV6=],
 230   [NO_IPV6=YesPlease])
 231 ],[NO_IPV6=YesPlease],[
 232 #include <sys/types.h>
 233 #include <sys/socket.h>
 234 #include <netdb.h>
 235 ])
 236 AC_SUBST(NO_IPV6)
 237 #
 238 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 239 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 240 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 241 # some C compilers supported these specifiers prior to C99 as an extension.
 242 AC_CACHE_CHECK(whether formatted IO functions support C99 size specifiers,
 243  ac_cv_c_c99_format,
 244 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 245 AC_RUN_IFELSE(
 246         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 247                 [[char buf[64];
 248                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 249                   exit(1);
 250                 else if (strcmp(buf, "12345"))
 251                   exit(2);]])],
 252         [ac_cv_c_c99_format=yes],
 253         [ac_cv_c_c99_format=no])
 254 ])
 255 if test $ac_cv_c_c99_format = no; then
 256         NO_C99_FORMAT=YesPlease
 257 else
 258         NO_C99_FORMAT=
 259 fi
 260 AC_SUBST(NO_C99_FORMAT)
 261
 262 ## Checks for library functions.
 263 ## (in default C library and libraries checked by AC_CHECK_LIB)
 264 AC_MSG_NOTICE([CHECKS for library functions])
 265 #
 266 # Define NO_STRCASESTR if you don't have strcasestr.
 267 AC_CHECK_FUNC(strcasestr,
 268 [NO_STRCASESTR=],
 269 [NO_STRCASESTR=YesPlease])
 270 AC_SUBST(NO_STRCASESTR)
 271 #
 272 # Define NO_STRLCPY if you don't have strlcpy.
 273 AC_CHECK_FUNC(strlcpy,
 274 [NO_STRLCPY=],
 275 [NO_STRLCPY=YesPlease])
 276 AC_SUBST(NO_STRLCPY)
 277 #
 278 # Define NO_SETENV if you don't have setenv in the C library.
 279 AC_CHECK_FUNC(setenv,
 280 [NO_SETENV=],
 281 [NO_SETENV=YesPlease])
 282 AC_SUBST(NO_SETENV)
 283 #
 284 # Define NO_MMAP if you want to avoid mmap.
 285 #
 286 # Define NO_ICONV if your libc does not properly support iconv.
 287
 288
 289 ## Other checks.
 290 # Define USE_PIC if you need the main git objects to be built with -fPIC
 291 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 292 #
 293 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 294 # Enable it on Windows.  By default, symrefs are still used.
 295 #
 296 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 297 #
 298 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 299 # a missing newline at the end of the file.
 300
 301
 302 ## Output files
 303 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 304 AC_OUTPUT
 305
 306
 307 ## Cleanup
 308 rm -f "${config_append}"