git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Data::Dumper;
  24 use Term::ANSIColor;
  25 use Git;
  26
  27 $SIG{INT} = sub { print color("reset"), "\n"; exit };
  28
  29 package FakeTerm;
  30 sub new {
  31         my ($class, $reason) = @_;
  32         return bless \$reason, shift;
  33 }
  34 sub readline {
  35         my $self = shift;
  36         die "Cannot use readline on FakeTerm: $$self";
  37 }
  38 package main;
  39
  40
  41 sub usage {
  42         print <<EOT;
  43 git-send-email [options] <file | directory>...
  44 Options:
  45    --from         Specify the "From:" line of the email to be sent.
  46
  47    --to           Specify the primary "To:" line of the email.
  48
  49    --cc           Specify an initial "Cc:" list for the entire series
  50                   of emails.
  51
  52    --cc-cmd       Specify a command to execute per file which adds
  53                   per file specific cc address entries
  54
  55    --bcc          Specify a list of email addresses that should be Bcc:
  56                   on all the emails.
  57
  58    --compose      Use \$GIT_EDITOR, core.editor, \$EDITOR, or \$VISUAL to edit
  59                   an introductory message for the patch series.
  60
  61    --subject      Specify the initial "Subject:" line.
  62                   Only necessary if --compose is also set.  If --compose
  63                   is not set, this will be prompted for.
  64
  65    --in-reply-to  Specify the first "In-Reply-To:" header line.
  66                   Only used if --compose is also set.  If --compose is not
  67                   set, this will be prompted for.
  68
  69    --chain-reply-to If set, the replies will all be to the previous
  70                   email sent, rather than to the first email sent.
  71                   Defaults to on.
  72
  73    --signed-off-cc Automatically add email addresses that appear in
  74                  Signed-off-by: or Cc: lines to the cc: list. Defaults to on.
  75
  76    --identity     The configuration identity, a subsection to prioritise over
  77                   the default section.
  78
  79    --smtp-server  If set, specifies the outgoing SMTP server to use.
  80                   Defaults to localhost.  Port number can be specified here with
  81                   hostname:port format or by using --smtp-server-port option.
  82
  83    --smtp-server-port Specify a port on the outgoing SMTP server to connect to.
  84
  85    --smtp-user    The username for SMTP-AUTH.
  86
  87    --smtp-pass    The password for SMTP-AUTH.
  88
  89    --smtp-ssl     If set, connects to the SMTP server using SSL.
  90
  91    --suppress-from Suppress sending emails to yourself. Defaults to off.
  92
  93    --thread       Specify that the "In-Reply-To:" header should be set on all
  94                   emails. Defaults to on.
  95
  96    --quiet        Make git-send-email less verbose.  One line per email
  97                   should be all that is output.
  98
  99    --dry-run      Do everything except actually send the emails.
 100
 101    --envelope-sender    Specify the envelope sender used to send the emails.
 102
 103 EOT
 104         exit(1);
 105 }
 106
 107 # most mail servers generate the Date: header, but not all...
 108 sub format_2822_time {
 109         my ($time) = @_;
 110         my @localtm = localtime($time);
 111         my @gmttm = gmtime($time);
 112         my $localmin = $localtm[1] + $localtm[2] * 60;
 113         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
 114         if ($localtm[0] != $gmttm[0]) {
 115                 die "local zone differs from GMT by a non-minute interval\n";
 116         }
 117         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 118                 $localmin += 1440;
 119         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 120                 $localmin -= 1440;
 121         } elsif ($gmttm[6] != $localtm[6]) {
 122                 die "local time offset greater than or equal to 24 hours\n";
 123         }
 124         my $offset = $localmin - $gmtmin;
 125         my $offhour = $offset / 60;
 126         my $offmin = abs($offset % 60);
 127         if (abs($offhour) >= 24) {
 128                 die ("local time offset greater than or equal to 24 hours\n");
 129         }
 130
 131         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 132                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 133                        $localtm[3],
 134                        qw(Jan Feb Mar Apr May Jun
 135                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 136                        $localtm[5]+1900,
 137                        $localtm[2],
 138                        $localtm[1],
 139                        $localtm[0],
 140                        ($offset >= 0) ? '+' : '-',
 141                        abs($offhour),
 142                        $offmin,
 143                        );
 144 }
 145
 146 my $have_email_valid = eval { require Email::Valid; 1 };
 147 my $smtp;
 148 my $auth;
 149
 150 sub unique_email_list(@);
 151 sub cleanup_compose_files();
 152
 153 # Constants (essentially)
 154 my $compose_filename = ".msg.$$";
 155
 156 # Variables we fill in automatically, or via prompting:
 157 my (@to,@cc,@initial_cc,@bcclist,@xh,
 158         $initial_reply_to,$initial_subject,@files,$author,$sender,$compose,$time);
 159
 160 my $envelope_sender;
 161
 162 # Example reply to:
 163 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 164
 165 my $repo = Git->repository();
 166 my $term = eval {
 167         new Term::ReadLine 'git-send-email';
 168 };
 169 if ($@) {
 170         $term = new FakeTerm "$@: going non-interactive";
 171 }
 172
 173 # Behavior modification variables
 174 my ($quiet, $dry_run) = (0, 0);
 175
 176 # Variables with corresponding config settings
 177 my ($thread, $chain_reply_to, $suppress_from, $signed_off_cc, $cc_cmd);
 178 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_authpass, $smtp_ssl);
 179 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 180
 181 my %config_bool_settings = (
 182     "thread" => [\$thread, 1],
 183     "chainreplyto" => [\$chain_reply_to, 1],
 184     "suppressfrom" => [\$suppress_from, 0],
 185     "signedoffcc" => [\$signed_off_cc, 1],
 186     "smtpssl" => [\$smtp_ssl, 0],
 187 );
 188
 189 my %config_settings = (
 190     "smtpserver" => \$smtp_server,
 191     "smtpserverport" => \$smtp_server_port,
 192     "smtpuser" => \$smtp_authuser,
 193     "smtppass" => \$smtp_authpass,
 194     "to" => \@to,
 195     "cccmd" => \$cc_cmd,
 196     "aliasfiletype" => \$aliasfiletype,
 197     "bcc" => \@bcclist,
 198     "aliasesfile" => \@alias_files,
 199 );
 200
 201 # Begin by accumulating all the variables (defined above), that we will end up
 202 # needing, first, from the command line:
 203
 204 my $rc = GetOptions("sender|from=s" => \$sender,
 205                     "in-reply-to=s" => \$initial_reply_to,
 206                     "subject=s" => \$initial_subject,
 207                     "to=s" => \@to,
 208                     "cc=s" => \@initial_cc,
 209                     "bcc=s" => \@bcclist,
 210                     "chain-reply-to!" => \$chain_reply_to,
 211                     "smtp-server=s" => \$smtp_server,
 212                     "smtp-server-port=s" => \$smtp_server_port,
 213                     "smtp-user=s" => \$smtp_authuser,
 214                     "smtp-pass=s" => \$smtp_authpass,
 215                     "smtp-ssl!" => \$smtp_ssl,
 216                     "identity=s" => \$identity,
 217                     "compose" => \$compose,
 218                     "quiet" => \$quiet,
 219                     "cc-cmd=s" => \$cc_cmd,
 220                     "suppress-from!" => \$suppress_from,
 221                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_cc,
 222                     "dry-run" => \$dry_run,
 223                     "envelope-sender=s" => \$envelope_sender,
 224                     "thread!" => \$thread,
 225          );
 226
 227 unless ($rc) {
 228     usage();
 229 }
 230
 231 # Now, let's fill any that aren't set in with defaults:
 232
 233 sub read_config {
 234         my ($prefix) = @_;
 235
 236         foreach my $setting (keys %config_bool_settings) {
 237                 my $target = $config_bool_settings{$setting}->[0];
 238                 $$target = $repo->config_bool("$prefix.$setting") unless (defined $$target);
 239         }
 240
 241         foreach my $setting (keys %config_settings) {
 242                 my $target = $config_settings{$setting};
 243                 if (ref($target) eq "ARRAY") {
 244                         unless (@$target) {
 245                                 my @values = $repo->config("$prefix.$setting");
 246                                 @$target = @values if (@values && defined $values[0]);
 247                         }
 248                 }
 249                 else {
 250                         $$target = $repo->config("$prefix.$setting") unless (defined $$target);
 251                 }
 252         }
 253 }
 254
 255 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 256 $identity = $repo->config("sendemail.identity") unless (defined $identity);
 257 read_config("sendemail.$identity") if (defined $identity);
 258 read_config("sendemail");
 259
 260 # fall back on builtin bool defaults
 261 foreach my $setting (values %config_bool_settings) {
 262         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 263 }
 264
 265 my ($repoauthor) = $repo->ident_person('author');
 266 my ($repocommitter) = $repo->ident_person('committer');
 267
 268 # Verify the user input
 269
 270 foreach my $entry (@to) {
 271         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 272 }
 273
 274 foreach my $entry (@initial_cc) {
 275         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 276 }
 277
 278 foreach my $entry (@bcclist) {
 279         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 280 }
 281
 282 my %aliases;
 283 my %parse_alias = (
 284         # multiline formats can be supported in the future
 285         mutt => sub { my $fh = shift; while (<$fh>) {
 286                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 287                         my ($alias, $addr) = ($1, $2);
 288                         $addr =~ s/#.*$//; # mutt allows # comments
 289                          # commas delimit multiple addresses
 290                         $aliases{$alias} = [ split(/\s*,\s*/, $addr) ];
 291                 }}},
 292         mailrc => sub { my $fh = shift; while (<$fh>) {
 293                 if (/^alias\s+(\S+)\s+(.*)$/) {
 294                         # spaces delimit multiple addresses
 295                         $aliases{$1} = [ split(/\s+/, $2) ];
 296                 }}},
 297         pine => sub { my $fh = shift; while (<$fh>) {
 298                 if (/^(\S+)\t.*\t(.*)$/) {
 299                         $aliases{$1} = [ split(/\s*,\s*/, $2) ];
 300                 }}},
 301         gnus => sub { my $fh = shift; while (<$fh>) {
 302                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 303                         $aliases{$1} = [ $2 ];
 304                 }}}
 305 );
 306
 307 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 308         foreach my $file (@alias_files) {
 309                 open my $fh, '<', $file or die "opening $file: $!\n";
 310                 $parse_alias{$aliasfiletype}->($fh);
 311                 close $fh;
 312         }
 313 }
 314
 315 ($sender) = expand_aliases($sender) if defined $sender;
 316
 317 # Now that all the defaults are set, process the rest of the command line
 318 # arguments and collect up the files that need to be processed.
 319 for my $f (@ARGV) {
 320         if (-d $f) {
 321                 opendir(DH,$f)
 322                         or die "Failed to opendir $f: $!";
 323
 324                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 325                                 sort readdir(DH);
 326
 327         } elsif (-f $f) {
 328                 push @files, $f;
 329
 330         } else {
 331                 print STDERR "Skipping $f - not found.\n";
 332         }
 333 }
 334
 335 foreach my $f (@files) {
 336         my $error = validate_patch($f);
 337         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 338 }
 339
 340 if (@files) {
 341         unless ($quiet) {
 342                 print $_,"\n" for (@files);
 343         }
 344 } else {
 345         print STDERR "\nNo patch files specified!\n\n";
 346         usage();
 347 }
 348
 349 my $prompting = 0;
 350 if (!defined $sender) {
 351         $sender = $repoauthor || $repocommitter;
 352         do {
 353                 $_ = $term->readline("Who should the emails appear to be from? [$sender] ");
 354         } while (!defined $_);
 355
 356         $sender = $_ if ($_);
 357         print "Emails will be sent from: ", $sender, "\n";
 358         $prompting++;
 359 }
 360
 361 if (!@to) {
 362         do {
 363                 $_ = $term->readline("Who should the emails be sent to? ",
 364                                 "");
 365         } while (!defined $_);
 366         my $to = $_;
 367         push @to, split /,/, $to;
 368         $prompting++;
 369 }
 370
 371 sub expand_aliases {
 372         my @cur = @_;
 373         my @last;
 374         do {
 375                 @last = @cur;
 376                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 377         } while (join(',',@cur) ne join(',',@last));
 378         return @cur;
 379 }
 380
 381 @to = expand_aliases(@to);
 382 @to = (map { sanitize_address($_) } @to);
 383 @initial_cc = expand_aliases(@initial_cc);
 384 @bcclist = expand_aliases(@bcclist);
 385
 386 if (!defined $initial_subject && $compose) {
 387         do {
 388                 $_ = $term->readline("What subject should the initial email start with? ",
 389                         $initial_subject);
 390         } while (!defined $_);
 391         $initial_subject = $_;
 392         $prompting++;
 393 }
 394
 395 if ($thread && !defined $initial_reply_to && $prompting) {
 396         do {
 397                 $_= $term->readline("Message-ID to be used as In-Reply-To for the first email? ",
 398                         $initial_reply_to);
 399         } while (!defined $_);
 400
 401         $initial_reply_to = $_;
 402 }
 403 if (defined $initial_reply_to && $_ ne "") {
 404         $initial_reply_to =~ s/^\s*<?/</;
 405         $initial_reply_to =~ s/>?\s*$/>/;
 406 }
 407
 408 if (!defined $smtp_server) {
 409         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 410                 if (-x $_) {
 411                         $smtp_server = $_;
 412                         last;
 413                 }
 414         }
 415         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 416 }
 417
 418 if ($compose) {
 419         # Note that this does not need to be secure, but we will make a small
 420         # effort to have it be unique
 421         open(C,">",$compose_filename)
 422                 or die "Failed to open for writing $compose_filename: $!";
 423         print C "From $sender # This line is ignored.\n";
 424         printf C "Subject: %s\n\n", $initial_subject;
 425         printf C <<EOT;
 426 GIT: Please enter your email below.
 427 GIT: Lines beginning in "GIT: " will be removed.
 428 GIT: Consider including an overall diffstat or table of contents
 429 GIT: for the patch you are writing.
 430
 431 EOT
 432         close(C);
 433
 434         my $editor = $ENV{GIT_EDITOR} || $repo->config("core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 435         system('sh', '-c', '$0 $@', $editor, $compose_filename);
 436
 437         open(C2,">",$compose_filename . ".final")
 438                 or die "Failed to open $compose_filename.final : " . $!;
 439
 440         open(C,"<",$compose_filename)
 441                 or die "Failed to open $compose_filename : " . $!;
 442
 443         while(<C>) {
 444                 next if m/^GIT: /;
 445                 print C2 $_;
 446         }
 447         close(C);
 448         close(C2);
 449
 450         do {
 451                 $_ = $term->readline("Send this email? (y|n) ");
 452         } while (!defined $_);
 453
 454         if (uc substr($_,0,1) ne 'Y') {
 455                 cleanup_compose_files();
 456                 exit(0);
 457         }
 458
 459         @files = ($compose_filename . ".final");
 460 }
 461
 462 # Variables we set as part of the loop over files
 463 our ($message_id, %mail, $subject, $reply_to, $references, $message);
 464
 465 sub extract_valid_address {
 466         my $address = shift;
 467         my $local_part_regexp = '[^<>"\s@]+';
 468         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 469
 470         # check for a local address:
 471         return $address if ($address =~ /^($local_part_regexp)$/);
 472
 473         $address =~ s/^\s*<(.*)>\s*$/$1/;
 474         if ($have_email_valid) {
 475                 return scalar Email::Valid->address($address);
 476         } else {
 477                 # less robust/correct than the monster regexp in Email::Valid,
 478                 # but still does a 99% job, and one less dependency
 479                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 480                 return $1;
 481         }
 482 }
 483
 484 # Usually don't need to change anything below here.
 485
 486 # we make a "fake" message id by taking the current number
 487 # of seconds since the beginning of Unix time and tacking on
 488 # a random number to the end, in case we are called quicker than
 489 # 1 second since the last time we were called.
 490
 491 # We'll setup a template for the message id, using the "from" address:
 492
 493 my ($message_id_stamp, $message_id_serial);
 494 sub make_message_id
 495 {
 496         my $uniq;
 497         if (!defined $message_id_stamp) {
 498                 $message_id_stamp = sprintf("%s-%s", time, $$);
 499                 $message_id_serial = 0;
 500         }
 501         $message_id_serial++;
 502         $uniq = "$message_id_stamp-$message_id_serial";
 503
 504         my $du_part;
 505         for ($sender, $repocommitter, $repoauthor) {
 506                 $du_part = extract_valid_address(sanitize_address($_));
 507                 last if (defined $du_part and $du_part ne '');
 508         }
 509         if (not defined $du_part or $du_part eq '') {
 510                 use Sys::Hostname qw();
 511                 $du_part = 'user@' . Sys::Hostname::hostname();
 512         }
 513         my $message_id_template = "<%s-git-send-email-%s>";
 514         $message_id = sprintf($message_id_template, $uniq, $du_part);
 515         #print "new message id = $message_id\n"; # Was useful for debugging
 516 }
 517
 518
 519
 520 $time = time - scalar $#files;
 521
 522 sub unquote_rfc2047 {
 523         local ($_) = @_;
 524         my $encoding;
 525         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 526                 $encoding = $1;
 527                 s/_/ /g;
 528                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 529         }
 530         return wantarray ? ($_, $encoding) : $_;
 531 }
 532
 533 # use the simplest quoting being able to handle the recipient
 534 sub sanitize_address
 535 {
 536         my ($recipient) = @_;
 537         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 538
 539         if (not $recipient_name) {
 540                 return "$recipient";
 541         }
 542
 543         # if recipient_name is already quoted, do nothing
 544         if ($recipient_name =~ /^(".*"|=\?utf-8\?q\?.*\?=)$/) {
 545                 return $recipient;
 546         }
 547
 548         # rfc2047 is needed if a non-ascii char is included
 549         if ($recipient_name =~ /[^[:ascii:]]/) {
 550                 $recipient_name =~ s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 551                 $recipient_name =~ s/(.*)/=\?utf-8\?q\?$1\?=/;
 552         }
 553
 554         # double quotes are needed if specials or CTLs are included
 555         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 556                 $recipient_name =~ s/(["\\\r])/\\$1/;
 557                 $recipient_name = "\"$recipient_name\"";
 558         }
 559
 560         return "$recipient_name $recipient_addr";
 561
 562 }
 563
 564 sub send_message
 565 {
 566         my @recipients = unique_email_list(@to);
 567         @cc = (grep { my $cc = extract_valid_address($_);
 568                       not grep { $cc eq $_ } @recipients
 569                     }
 570                map { sanitize_address($_) }
 571                @cc);
 572         my $to = join (",\n\t", @recipients);
 573         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 574         @recipients = (map { extract_valid_address($_) } @recipients);
 575         my $date = format_2822_time($time++);
 576         my $gitversion = '@@GIT_VERSION@@';
 577         if ($gitversion =~ m/..GIT_VERSION../) {
 578             $gitversion = Git::version();
 579         }
 580
 581         my $cc = join(", ", unique_email_list(@cc));
 582         my $ccline = "";
 583         if ($cc ne '') {
 584                 $ccline = "\nCc: $cc";
 585         }
 586         my $sanitized_sender = sanitize_address($sender);
 587         make_message_id() unless defined($message_id);
 588
 589         my $header = "From: $sanitized_sender
 590 To: $to${ccline}
 591 Subject: $subject
 592 Date: $date
 593 Message-Id: $message_id
 594 X-Mailer: git-send-email $gitversion
 595 ";
 596         if ($thread && $reply_to) {
 597
 598                 $header .= "In-Reply-To: $reply_to\n";
 599                 $header .= "References: $references\n";
 600         }
 601         if (@xh) {
 602                 $header .= join("\n", @xh) . "\n";
 603         }
 604
 605         my @sendmail_parameters = ('-i', @recipients);
 606         my $raw_from = $sanitized_sender;
 607         $raw_from = $envelope_sender if (defined $envelope_sender);
 608         $raw_from = extract_valid_address($raw_from);
 609         unshift (@sendmail_parameters,
 610                         '-f', $raw_from) if(defined $envelope_sender);
 611
 612         if ($dry_run) {
 613                 # We don't want to send the email.
 614         } elsif ($smtp_server =~ m#^/#) {
 615                 my $pid = open my $sm, '|-';
 616                 defined $pid or die $!;
 617                 if (!$pid) {
 618                         exec($smtp_server, @sendmail_parameters) or die $!;
 619                 }
 620                 print $sm "$header\n$message";
 621                 close $sm or die $?;
 622         } else {
 623
 624                 if (!defined $smtp_server) {
 625                         die "The required SMTP server is not properly defined."
 626                 }
 627
 628                 if ($smtp_ssl) {
 629                         $smtp_server_port ||= 465; # ssmtp
 630                         require Net::SMTP::SSL;
 631                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 632                 }
 633                 else {
 634                         require Net::SMTP;
 635                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 636                                                  ? "$smtp_server:$smtp_server_port"
 637                                                  : $smtp_server);
 638                 }
 639
 640                 if (!$smtp) {
 641                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 642                 }
 643
 644                 if ((defined $smtp_authuser) && (defined $smtp_authpass)) {
 645                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 646                 }
 647                 $smtp->mail( $raw_from ) or die $smtp->message;
 648                 $smtp->to( @recipients ) or die $smtp->message;
 649                 $smtp->data or die $smtp->message;
 650                 $smtp->datasend("$header\n$message") or die $smtp->message;
 651                 $smtp->dataend() or die $smtp->message;
 652                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 653         }
 654         if ($quiet) {
 655                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 656         } else {
 657                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 658                 if ($smtp_server !~ m#^/#) {
 659                         print "Server: $smtp_server\n";
 660                         print "MAIL FROM:<$raw_from>\n";
 661                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 662                 } else {
 663                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 664                 }
 665                 print $header, "\n";
 666                 if ($smtp) {
 667                         print "Result: ", $smtp->code, ' ',
 668                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 669                 } else {
 670                         print "Result: OK\n";
 671                 }
 672         }
 673 }
 674
 675 $reply_to = $initial_reply_to;
 676 $references = $initial_reply_to || '';
 677 $subject = $initial_subject;
 678
 679 foreach my $t (@files) {
 680         open(F,"<",$t) or die "can't open file $t";
 681
 682         my $author = undef;
 683         my $author_encoding;
 684         my $has_content_type;
 685         my $body_encoding;
 686         @cc = @initial_cc;
 687         @xh = ();
 688         my $input_format = undef;
 689         my $header_done = 0;
 690         $message = "";
 691         while(<F>) {
 692                 if (!$header_done) {
 693                         if (/^From /) {
 694                                 $input_format = 'mbox';
 695                                 next;
 696                         }
 697                         chomp;
 698                         if (!defined $input_format && /^[-A-Za-z]+:\s/) {
 699                                 $input_format = 'mbox';
 700                         }
 701
 702                         if (defined $input_format && $input_format eq 'mbox') {
 703                                 if (/^Subject:\s+(.*)$/) {
 704                                         $subject = $1;
 705
 706                                 } elsif (/^(Cc|From):\s+(.*)$/) {
 707                                         if (unquote_rfc2047($2) eq $sender) {
 708                                                 next if ($suppress_from);
 709                                         }
 710                                         elsif ($1 eq 'From') {
 711                                                 ($author, $author_encoding)
 712                                                   = unquote_rfc2047($2);
 713                                         }
 714                                         printf("(mbox) Adding cc: %s from line '%s'\n",
 715                                                 $2, $_) unless $quiet;
 716                                         push @cc, $2;
 717                                 }
 718                                 elsif (/^Content-type:/i) {
 719                                         $has_content_type = 1;
 720                                         if (/charset="?[^ "]+/) {
 721                                                 $body_encoding = $1;
 722                                         }
 723                                         push @xh, $_;
 724                                 }
 725                                 elsif (/^Message-Id: (.*)/i) {
 726                                         $message_id = $1;
 727                                 }
 728                                 elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
 729                                         push @xh, $_;
 730                                 }
 731
 732                         } else {
 733                                 # In the traditional
 734                                 # "send lots of email" format,
 735                                 # line 1 = cc
 736                                 # line 2 = subject
 737                                 # So let's support that, too.
 738                                 $input_format = 'lots';
 739                                 if (@cc == 0) {
 740                                         printf("(non-mbox) Adding cc: %s from line '%s'\n",
 741                                                 $_, $_) unless $quiet;
 742
 743                                         push @cc, $_;
 744
 745                                 } elsif (!defined $subject) {
 746                                         $subject = $_;
 747                                 }
 748                         }
 749
 750                         # A whitespace line will terminate the headers
 751                         if (m/^\s*$/) {
 752                                 $header_done = 1;
 753                         }
 754                 } else {
 755                         $message .=  $_;
 756                         if (/^(Signed-off-by|Cc): (.*)$/i && $signed_off_cc) {
 757                                 my $c = $2;
 758                                 chomp $c;
 759                                 next if ($c eq $sender and $suppress_from);
 760                                 push @cc, $c;
 761                                 printf("(sob) Adding cc: %s from line '%s'\n",
 762                                         $c, $_) unless $quiet;
 763                         }
 764                 }
 765         }
 766         close F;
 767
 768         if (defined $cc_cmd) {
 769                 open(F, "$cc_cmd $t |")
 770                         or die "(cc-cmd) Could not execute '$cc_cmd'";
 771                 while(<F>) {
 772                         my $c = $_;
 773                         $c =~ s/^\s*//g;
 774                         $c =~ s/\n$//g;
 775                         next if ($c eq $sender and $suppress_from);
 776                         push @cc, $c;
 777                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
 778                                 $c, $cc_cmd) unless $quiet;
 779                 }
 780                 close F
 781                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
 782         }
 783
 784         if (defined $author) {
 785                 $message = "From: $author\n\n$message";
 786                 if (defined $author_encoding) {
 787                         if ($has_content_type) {
 788                                 if ($body_encoding eq $author_encoding) {
 789                                         # ok, we already have the right encoding
 790                                 }
 791                                 else {
 792                                         # uh oh, we should re-encode
 793                                 }
 794                         }
 795                         else {
 796                                 push @xh,
 797                                   'MIME-Version: 1.0',
 798                                   "Content-Type: text/plain; charset=$author_encoding",
 799                                   'Content-Transfer-Encoding: 8bit';
 800                         }
 801                 }
 802         }
 803
 804         send_message();
 805
 806         # set up for the next message
 807         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
 808                 $reply_to = $message_id;
 809                 if (length $references > 0) {
 810                         $references .= "\n $message_id";
 811                 } else {
 812                         $references = "$message_id";
 813                 }
 814         }
 815         $message_id = undef;
 816 }
 817
 818 if ($compose) {
 819         cleanup_compose_files();
 820 }
 821
 822 sub cleanup_compose_files() {
 823         unlink($compose_filename, $compose_filename . ".final");
 824
 825 }
 826
 827 $smtp->quit if $smtp;
 828
 829 sub unique_email_list(@) {
 830         my %seen;
 831         my @emails;
 832
 833         foreach my $entry (@_) {
 834                 if (my $clean = extract_valid_address($entry)) {
 835                         $seen{$clean} ||= 0;
 836                         next if $seen{$clean}++;
 837                         push @emails, $entry;
 838                 } else {
 839                         print STDERR "W: unable to extract a valid address",
 840                                         " from: $entry\n";
 841                 }
 842         }
 843         return @emails;
 844 }
 845
 846 sub validate_patch {
 847         my $fn = shift;
 848         open(my $fh, '<', $fn)
 849                 or die "unable to open $fn: $!\n";
 850         while (my $line = <$fh>) {
 851                 if (length($line) > 998) {
 852                         return "$.: patch contains a line longer than 998 characters";
 853                 }
 854         }
 855         return undef;
 856 }