configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [1.4.1], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_WARN([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  46         fi; \
  47 fi; \
  48 ]) # GIT_CONF_APPEND_PATH
  49
  50
  51 ## Site configuration
  52 ## --with-PACKAGE[=ARG] and --without-PACKAGE
  53 #
  54 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interopability
  55 # tests.  These tests take up a significant amount of the total test time
  56 # but are not needed unless you plan to talk to SVN repos.
  57 #
  58 # Define MOZILLA_SHA1 environment variable when running make to make use of
  59 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
  60 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
  61 # choice) has very fast version optimized for i586.
  62 #
  63 # Define PPC_SHA1 environment variable when running make to make use of
  64 # a bundled SHA1 routine optimized for PowerPC.
  65 #
  66 # Define ARM_SHA1 environment variable when running make to make use of
  67 # a bundled SHA1 routine optimized for ARM.
  68 #
  69 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
  70 # This also implies MOZILLA_SHA1.
  71 #
  72 # Define NO_CURL if you do not have curl installed.  git-http-pull and
  73 # git-http-push are not built, and you cannot use http:// and https://
  74 # transports.
  75 #
  76 # Define CURLDIR=/foo/bar if your curl header and library files are in
  77 # /foo/bar/include and /foo/bar/lib directories.
  78 #
  79 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
  80 # not built, and you cannot push using http:// and https:// transports.
  81 #
  82 # Define NO_MMAP if you want to avoid mmap.
  83 #
  84 # Define NO_PYTHON if you want to loose all benefits of the recursive merge.
  85 #
  86 ## --enable-FEATURE[=ARG] and --disable-FEATURE
  87 # Define COLLISION_CHECK below if you believe that SHA1's
  88 # 1461501637330902918203684832716283019655932542976 hashes do not give you
  89 # sufficient guarantee that no collisions between objects will ever happen.
  90 #
  91 # Define USE_NSEC below if you want git to care about sub-second file mtimes
  92 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
  93 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
  94 # randomly break unless your underlying filesystem supports those sub-second
  95 # times (my ext3 doesn't).
  96 #
  97 # Define USE_STDEV below if you want git to care about the underlying device
  98 # change being considered an inode change from the update-cache perspective.
  99
 100
 101 ## Checks for programs.
 102 AC_MSG_NOTICE([CHECKS for programs])
 103 #
 104 GIT_ARG_SET_PATH(shell)
 105 GIT_ARG_SET_PATH(perl)
 106 AC_ARG_WITH(python,[AS_HELP_STRING([--with-python=PATH], [provide PATH to python])
 107 AS_HELP_STRING([--no-python], [don't use python scripts])],
 108  [if test "$withval" = "no"; then \
 109     NO_PYTHON=YesPlease; \
 110   elif test "$withval" != "yes"; then \
 111     PYTHON_PATH=$withval; \
 112   fi; \
 113  ])
 114 AC_SUBST(NO_PYTHON)
 115 AC_SUBST(PYTHON_PATH)
 116
 117
 118 #
 119 # Define NO_PYTHON if you want to lose all benefits of the recursive merge.
 120 # Define PYTHON_PATH to provide path to Python.
 121 AC_PROG_CC
 122 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 123 AC_CHECK_TOOL(AR, ar, :)
 124 AC_CHECK_PROGS(TAR, [gtar tar])
 125 if test -z "$NO_PYTHON"; then
 126         AC_PATH_PROGS(PYTHON_PATH, [python2.4 python2.3 python2 python])
 127         if test -n "$PYTHON_PATH"; then
 128                 GIT_CONF_APPEND_LINE([PYTHON_PATH=@PYTHON_PATH@])
 129         else
 130                 GIT_CONF_APPEND_LINE([NO_PYTHON=@NO_PYTHON@])
 131         fi
 132 else
 133         GIT_CONF_APPEND_LINE([NO_PYTHON=@NO_PYTHON@])
 134 fi
 135
 136
 137 ## Checks for libraries.
 138 AC_MSG_NOTICE([CHECKS for libraries])
 139 #
 140 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 141 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 142 AC_CHECK_LIB([ssl], [SHA1_Init],[],
 143 [AC_CHECK_LIB([crypto], [SHA1_INIT],
 144  [GIT_CONF_APPEND_LINE(NEEDS_SSL_WITH_CRYPTO=YesPlease)],
 145  [GIT_CONF_APPEND_LINE(NO_OPENSSL=YesPlease)])])
 146 #
 147 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 148 # git-http-push are not built, and you cannot use http:// and https://
 149 # transports.
 150 AC_CHECK_LIB([curl], [curl_global_init],[],
 151 [GIT_CONF_APPEND_LINE(NO_CURL=YesPlease)])
 152 #
 153 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 154 # not built, and you cannot push using http:// and https:// transports.
 155 AC_CHECK_LIB([expat], [XML_ParserCreate],[],
 156 [GIT_CONF_APPEND_LINE(NO_EXPAT=YesPlease)])
 157 #
 158 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin).
 159 AC_CHECK_LIB([c], [iconv],[],
 160 [AC_CHECK_LIB([iconv],[iconv],
 161  [GIT_CONF_APPEND_LINE(NEEDS_LIBICONV=YesPlease)],[])])
 162 #
 163 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 164 # Patrick Mauritz).
 165 AC_CHECK_LIB([c], [socket],[],
 166 [AC_CHECK_LIB([socket],[socket],
 167  [GIT_CONF_APPEND_LINE(NEEDS_SOCKET=YesPlease)],[])])
 168
 169
 170 ## Checks for header files.
 171
 172
 173 ## Checks for typedefs, structures, and compiler characteristics.
 174 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 175 #
 176 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 177 AC_CHECK_MEMBER(struct dirent.d_ino,[],
 178 [GIT_CONF_APPEND_LINE(NO_D_INO_IN_DIRENT=YesPlease)],
 179 [#include <dirent.h>])
 180 #
 181 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 182 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 183 AC_CHECK_MEMBER(struct dirent.d_type,[],
 184 [GIT_CONF_APPEND_LINE(NO_D_TYPE_IN_DIRENT=YesPlease)],
 185 [#include <dirent.h>])
 186 #
 187 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 188 # sockaddr_storage.
 189 AC_CHECK_TYPE(struct sockaddr_storage,[],
 190 [GIT_CONF_APPEND_LINE(NO_SOCKADDR_STORAGE=YesPlease)],
 191 [#include <netinet/in.h>])
 192 #
 193 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 194 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 195 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 196 # some C compilers supported these specifiers prior to C99 as an extension.
 197 AC_CACHE_CHECK(whether IO functions support %ll %hh %j %z %t size specifiers,
 198  ac_cv_c_c99_format,
 199 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 200 AC_RUN_IFELSE(
 201         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 202                 [[char buf[64];
 203                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 204                   exit(1);
 205                 else if (strcmp(buf, "12345"))
 206                   exit(2);]])],
 207         [ac_cv_c_c99_format=yes],
 208         [ac_cv_c_c99_format=no])
 209 ])
 210 if test $ac_cv_c_c99_format = no; then
 211         GIT_CONF_APPEND_LINE(NO_C99_FORMAT=YesPlease)
 212 fi
 213
 214
 215 ## Checks for library functions.
 216 ## (in default C library and libraries checked by AC_CHECK_LIB)
 217 AC_MSG_NOTICE([CHECKS for library functions])
 218 #
 219 # Define NO_STRCASESTR if you don't have strcasestr.
 220 AC_CHECK_FUNC(strcasestr,[],
 221 [GIT_CONF_APPEND_LINE(NO_STRCASESTR=YesPlease)])
 222 #
 223 # Define NO_STRLCPY if you don't have strlcpy.
 224 AC_CHECK_FUNC(strlcpy,[],
 225 [GIT_CONF_APPEND_LINE(NO_STRLCPY=YesPlease)])
 226 #
 227 # Define NO_SETENV if you don't have setenv in the C library.
 228 AC_CHECK_FUNC(setenv,[],
 229 [GIT_CONF_APPEND_LINE(NO_SETENV=YesPlease)])
 230 #
 231 # Define NO_MMAP if you want to avoid mmap.
 232 #
 233 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 234 #
 235 # Define NO_ICONV if your libc does not properly support iconv.
 236
 237
 238 ## Other checks.
 239 # Define USE_PIC if you need the main git objects to be built with -fPIC
 240 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 241 #
 242 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 243 # Enable it on Windows.  By default, symrefs are still used.
 244 #
 245 # Define WITH_OWN_SUBPROCESS_PY if you want to use with python 2.3.
 246 #
 247 # Define NO_ACCURATE_DIFF if your diff program at least sometimes misses
 248 # a missing newline at the end of the file.
 249
 250
 251 ## Output files
 252 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 253 AC_OUTPUT
 254
 255
 256 ## Cleanup
 257 rm -f "${config_append}"