git-gui/git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [encoding convertfrom utf-8 {
  14 Copyright © 2006, 2007 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title [mc "git-gui: fatal error"] \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86 }
  87
  88 ######################################################################
  89 ##
  90 ## Internationalization (i18n) through msgcat and gettext. See
  91 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  92
  93 package require msgcat
  94
  95 proc _mc_trim {fmt} {
  96         set cmk [string first @@ $fmt]
  97         if {$cmk > 0} {
  98                 return [string range $fmt 0 [expr {$cmk - 1}]]
  99         }
 100         return $fmt
 101 }
 102
 103 proc mc {en_fmt args} {
 104         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 105         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 106                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 107         }
 108         return $msg
 109 }
 110
 111 proc strcat {args} {
 112         return [join $args {}]
 113 }
 114
 115 ::msgcat::mcload $oguimsg
 116 unset oguimsg
 117
 118 ######################################################################
 119 ##
 120 ## read only globals
 121
 122 set _appname {Git Gui}
 123 set _gitdir {}
 124 set _gitworktree {}
 125 set _isbare {}
 126 set _gitexec {}
 127 set _githtmldir {}
 128 set _reponame {}
 129 set _iscygwin {}
 130 set _search_path {}
 131
 132 set _trace [lsearch -exact $argv --trace]
 133 if {$_trace >= 0} {
 134         set argv [lreplace $argv $_trace $_trace]
 135         set _trace 1
 136 } else {
 137         set _trace 0
 138 }
 139
 140 proc appname {} {
 141         global _appname
 142         return $_appname
 143 }
 144
 145 proc gitdir {args} {
 146         global _gitdir
 147         if {$args eq {}} {
 148                 return $_gitdir
 149         }
 150         return [eval [list file join $_gitdir] $args]
 151 }
 152
 153 proc gitexec {args} {
 154         global _gitexec
 155         if {$_gitexec eq {}} {
 156                 if {[catch {set _gitexec [git --exec-path]} err]} {
 157                         error "Git not installed?\n\n$err"
 158                 }
 159                 if {[is_Cygwin]} {
 160                         set _gitexec [exec cygpath \
 161                                 --windows \
 162                                 --absolute \
 163                                 $_gitexec]
 164                 } else {
 165                         set _gitexec [file normalize $_gitexec]
 166                 }
 167         }
 168         if {$args eq {}} {
 169                 return $_gitexec
 170         }
 171         return [eval [list file join $_gitexec] $args]
 172 }
 173
 174 proc githtmldir {args} {
 175         global _githtmldir
 176         if {$_githtmldir eq {}} {
 177                 if {[catch {set _githtmldir [git --html-path]}]} {
 178                         # Git not installed or option not yet supported
 179                         return {}
 180                 }
 181                 if {[is_Cygwin]} {
 182                         set _githtmldir [exec cygpath \
 183                                 --windows \
 184                                 --absolute \
 185                                 $_githtmldir]
 186                 } else {
 187                         set _githtmldir [file normalize $_githtmldir]
 188                 }
 189         }
 190         if {$args eq {}} {
 191                 return $_githtmldir
 192         }
 193         return [eval [list file join $_githtmldir] $args]
 194 }
 195
 196 proc reponame {} {
 197         return $::_reponame
 198 }
 199
 200 proc is_MacOSX {} {
 201         if {[tk windowingsystem] eq {aqua}} {
 202                 return 1
 203         }
 204         return 0
 205 }
 206
 207 proc is_Windows {} {
 208         if {$::tcl_platform(platform) eq {windows}} {
 209                 return 1
 210         }
 211         return 0
 212 }
 213
 214 proc is_Cygwin {} {
 215         global _iscygwin
 216         if {$_iscygwin eq {}} {
 217                 if {$::tcl_platform(platform) eq {windows}} {
 218                         if {[catch {set p [exec cygpath --windir]} err]} {
 219                                 set _iscygwin 0
 220                         } else {
 221                                 set _iscygwin 1
 222                         }
 223                 } else {
 224                         set _iscygwin 0
 225                 }
 226         }
 227         return $_iscygwin
 228 }
 229
 230 proc is_enabled {option} {
 231         global enabled_options
 232         if {[catch {set on $enabled_options($option)}]} {return 0}
 233         return $on
 234 }
 235
 236 proc enable_option {option} {
 237         global enabled_options
 238         set enabled_options($option) 1
 239 }
 240
 241 proc disable_option {option} {
 242         global enabled_options
 243         set enabled_options($option) 0
 244 }
 245
 246 ######################################################################
 247 ##
 248 ## config
 249
 250 proc is_many_config {name} {
 251         switch -glob -- $name {
 252         gui.recentrepo -
 253         remote.*.fetch -
 254         remote.*.push
 255                 {return 1}
 256         *
 257                 {return 0}
 258         }
 259 }
 260
 261 proc is_config_true {name} {
 262         global repo_config
 263         if {[catch {set v $repo_config($name)}]} {
 264                 return 0
 265         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 266                 return 1
 267         } else {
 268                 return 0
 269         }
 270 }
 271
 272 proc get_config {name} {
 273         global repo_config
 274         if {[catch {set v $repo_config($name)}]} {
 275                 return {}
 276         } else {
 277                 return $v
 278         }
 279 }
 280
 281 proc is_bare {} {
 282         global _isbare
 283         global _gitdir
 284         global _gitworktree
 285
 286         if {$_isbare eq {}} {
 287                 if {[catch {
 288                         set _bare [git rev-parse --is-bare-repository]
 289                         switch  -- $_bare {
 290                         true { set _isbare 1 }
 291                         false { set _isbare 0}
 292                         default { throw }
 293                         }
 294                 }]} {
 295                         if {[is_config_true core.bare]
 296                                 || ($_gitworktree eq {}
 297                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 298                                 set _isbare 1
 299                         } else {
 300                                 set _isbare 0
 301                         }
 302                 }
 303         }
 304         return $_isbare
 305 }
 306
 307 ######################################################################
 308 ##
 309 ## handy utils
 310
 311 proc _trace_exec {cmd} {
 312         if {!$::_trace} return
 313         set d {}
 314         foreach v $cmd {
 315                 if {$d ne {}} {
 316                         append d { }
 317                 }
 318                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 319                         set v [sq $v]
 320                 }
 321                 append d $v
 322         }
 323         puts stderr $d
 324 }
 325
 326 proc _git_cmd {name} {
 327         global _git_cmd_path
 328
 329         if {[catch {set v $_git_cmd_path($name)}]} {
 330                 switch -- $name {
 331                   version   -
 332                 --version   -
 333                 --exec-path { return [list $::_git $name] }
 334                 }
 335
 336                 set p [gitexec git-$name$::_search_exe]
 337                 if {[file exists $p]} {
 338                         set v [list $p]
 339                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 340                         # Try to determine what sort of magic will make
 341                         # git-$name go and do its thing, because native
 342                         # Tcl on Windows doesn't know it.
 343                         #
 344                         set p [gitexec git-$name]
 345                         set f [open $p r]
 346                         set s [gets $f]
 347                         close $f
 348
 349                         switch -glob -- [lindex $s 0] {
 350                         #!*sh     { set i sh     }
 351                         #!*perl   { set i perl   }
 352                         #!*python { set i python }
 353                         default   { error "git-$name is not supported: $s" }
 354                         }
 355
 356                         upvar #0 _$i interp
 357                         if {![info exists interp]} {
 358                                 set interp [_which $i]
 359                         }
 360                         if {$interp eq {}} {
 361                                 error "git-$name requires $i (not in PATH)"
 362                         }
 363                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 364                 } else {
 365                         # Assume it is builtin to git somehow and we
 366                         # aren't actually able to see a file for it.
 367                         #
 368                         set v [list $::_git $name]
 369                 }
 370                 set _git_cmd_path($name) $v
 371         }
 372         return $v
 373 }
 374
 375 proc _which {what args} {
 376         global env _search_exe _search_path
 377
 378         if {$_search_path eq {}} {
 379                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 380                         set _search_path [split [exec cygpath \
 381                                 --windows \
 382                                 --path \
 383                                 --absolute \
 384                                 $env(PATH)] {;}]
 385                         set _search_exe .exe
 386                 } elseif {[is_Windows]} {
 387                         set gitguidir [file dirname [info script]]
 388                         regsub -all ";" $gitguidir "\\;" gitguidir
 389                         set env(PATH) "$gitguidir;$env(PATH)"
 390                         set _search_path [split $env(PATH) {;}]
 391                         set _search_exe .exe
 392                 } else {
 393                         set _search_path [split $env(PATH) :]
 394                         set _search_exe {}
 395                 }
 396         }
 397
 398         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 399                 set suffix {}
 400         } else {
 401                 set suffix $_search_exe
 402         }
 403
 404         foreach p $_search_path {
 405                 set p [file join $p $what$suffix]
 406                 if {[file exists $p]} {
 407                         return [file normalize $p]
 408                 }
 409         }
 410         return {}
 411 }
 412
 413 proc _lappend_nice {cmd_var} {
 414         global _nice
 415         upvar $cmd_var cmd
 416
 417         if {![info exists _nice]} {
 418                 set _nice [_which nice]
 419         }
 420         if {$_nice ne {}} {
 421                 lappend cmd $_nice
 422         }
 423 }
 424
 425 proc git {args} {
 426         set opt [list]
 427
 428         while {1} {
 429                 switch -- [lindex $args 0] {
 430                 --nice {
 431                         _lappend_nice opt
 432                 }
 433
 434                 default {
 435                         break
 436                 }
 437
 438                 }
 439
 440                 set args [lrange $args 1 end]
 441         }
 442
 443         set cmdp [_git_cmd [lindex $args 0]]
 444         set args [lrange $args 1 end]
 445
 446         _trace_exec [concat $opt $cmdp $args]
 447         set result [eval exec $opt $cmdp $args]
 448         if {$::_trace} {
 449                 puts stderr "< $result"
 450         }
 451         return $result
 452 }
 453
 454 proc _open_stdout_stderr {cmd} {
 455         _trace_exec $cmd
 456         if {[catch {
 457                         set fd [open [concat [list | ] $cmd] r]
 458                 } err]} {
 459                 if {   [lindex $cmd end] eq {2>@1}
 460                     && $err eq {can not find channel named "1"}
 461                         } {
 462                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 463                         # redirect operator.  Fallback to |& cat for those.
 464                         # The command was not actually started, so its safe
 465                         # to try to start it a second time.
 466                         #
 467                         set fd [open [concat \
 468                                 [list | ] \
 469                                 [lrange $cmd 0 end-1] \
 470                                 [list |& cat] \
 471                                 ] r]
 472                 } else {
 473                         error $err
 474                 }
 475         }
 476         fconfigure $fd -eofchar {}
 477         return $fd
 478 }
 479
 480 proc git_read {args} {
 481         set opt [list]
 482
 483         while {1} {
 484                 switch -- [lindex $args 0] {
 485                 --nice {
 486                         _lappend_nice opt
 487                 }
 488
 489                 --stderr {
 490                         lappend args 2>@1
 491                 }
 492
 493                 default {
 494                         break
 495                 }
 496
 497                 }
 498
 499                 set args [lrange $args 1 end]
 500         }
 501
 502         set cmdp [_git_cmd [lindex $args 0]]
 503         set args [lrange $args 1 end]
 504
 505         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 506 }
 507
 508 proc git_write {args} {
 509         set opt [list]
 510
 511         while {1} {
 512                 switch -- [lindex $args 0] {
 513                 --nice {
 514                         _lappend_nice opt
 515                 }
 516
 517                 default {
 518                         break
 519                 }
 520
 521                 }
 522
 523                 set args [lrange $args 1 end]
 524         }
 525
 526         set cmdp [_git_cmd [lindex $args 0]]
 527         set args [lrange $args 1 end]
 528
 529         _trace_exec [concat $opt $cmdp $args]
 530         return [open [concat [list | ] $opt $cmdp $args] w]
 531 }
 532
 533 proc githook_read {hook_name args} {
 534         set pchook [gitdir hooks $hook_name]
 535         lappend args 2>@1
 536
 537         # On Windows [file executable] might lie so we need to ask
 538         # the shell if the hook is executable.  Yes that's annoying.
 539         #
 540         if {[is_Windows]} {
 541                 upvar #0 _sh interp
 542                 if {![info exists interp]} {
 543                         set interp [_which sh]
 544                 }
 545                 if {$interp eq {}} {
 546                         error "hook execution requires sh (not in PATH)"
 547                 }
 548
 549                 set scr {if test -x "$1";then exec "$@";fi}
 550                 set sh_c [list $interp -c $scr $interp $pchook]
 551                 return [_open_stdout_stderr [concat $sh_c $args]]
 552         }
 553
 554         if {[file executable $pchook]} {
 555                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 556         }
 557
 558         return {}
 559 }
 560
 561 proc kill_file_process {fd} {
 562         set process [pid $fd]
 563
 564         catch {
 565                 if {[is_Windows]} {
 566                         # Use a Cygwin-specific flag to allow killing
 567                         # native Windows processes
 568                         exec kill -f $process
 569                 } else {
 570                         exec kill $process
 571                 }
 572         }
 573 }
 574
 575 proc gitattr {path attr default} {
 576         if {[catch {set r [git check-attr $attr -- $path]}]} {
 577                 set r unspecified
 578         } else {
 579                 set r [join [lrange [split $r :] 2 end] :]
 580                 regsub {^ } $r {} r
 581         }
 582         if {$r eq {unspecified}} {
 583                 return $default
 584         }
 585         return $r
 586 }
 587
 588 proc sq {value} {
 589         regsub -all ' $value "'\\''" value
 590         return "'$value'"
 591 }
 592
 593 proc load_current_branch {} {
 594         global current_branch is_detached
 595
 596         set fd [open [gitdir HEAD] r]
 597         if {[gets $fd ref] < 1} {
 598                 set ref {}
 599         }
 600         close $fd
 601
 602         set pfx {ref: refs/heads/}
 603         set len [string length $pfx]
 604         if {[string equal -length $len $pfx $ref]} {
 605                 # We're on a branch.  It might not exist.  But
 606                 # HEAD looks good enough to be a branch.
 607                 #
 608                 set current_branch [string range $ref $len end]
 609                 set is_detached 0
 610         } else {
 611                 # Assume this is a detached head.
 612                 #
 613                 set current_branch HEAD
 614                 set is_detached 1
 615         }
 616 }
 617
 618 auto_load tk_optionMenu
 619 rename tk_optionMenu real__tkOptionMenu
 620 proc tk_optionMenu {w varName args} {
 621         set m [eval real__tkOptionMenu $w $varName $args]
 622         $m configure -font font_ui
 623         $w configure -font font_ui
 624         return $m
 625 }
 626
 627 proc rmsel_tag {text} {
 628         $text tag conf sel \
 629                 -background [$text cget -background] \
 630                 -foreground [$text cget -foreground] \
 631                 -borderwidth 0
 632         $text tag conf in_sel -background lightgray
 633         bind $text <Motion> break
 634         return $text
 635 }
 636
 637 set root_exists 0
 638 bind . <Visibility> {
 639         bind . <Visibility> {}
 640         set root_exists 1
 641 }
 642
 643 if {[is_Windows]} {
 644         wm iconbitmap . -default $oguilib/git-gui.ico
 645         set ::tk::AlwaysShowSelection 1
 646
 647         # Spoof an X11 display for SSH
 648         if {![info exists env(DISPLAY)]} {
 649                 set env(DISPLAY) :9999
 650         }
 651 } else {
 652         catch {
 653                 image create photo gitlogo -width 16 -height 16
 654
 655                 gitlogo put #33CC33 -to  7  0  9  2
 656                 gitlogo put #33CC33 -to  4  2 12  4
 657                 gitlogo put #33CC33 -to  7  4  9  6
 658                 gitlogo put #CC3333 -to  4  6 12  8
 659                 gitlogo put gray26  -to  4  9  6 10
 660                 gitlogo put gray26  -to  3 10  6 12
 661                 gitlogo put gray26  -to  8  9 13 11
 662                 gitlogo put gray26  -to  8 11 10 12
 663                 gitlogo put gray26  -to 11 11 13 14
 664                 gitlogo put gray26  -to  3 12  5 14
 665                 gitlogo put gray26  -to  5 13
 666                 gitlogo put gray26  -to 10 13
 667                 gitlogo put gray26  -to  4 14 12 15
 668                 gitlogo put gray26  -to  5 15 11 16
 669                 gitlogo redither
 670
 671                 wm iconphoto . -default gitlogo
 672         }
 673 }
 674
 675 ######################################################################
 676 ##
 677 ## config defaults
 678
 679 set cursor_ptr arrow
 680 font create font_ui
 681 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 682         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 683         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 684 } else {
 685         font create font_diff -family Courier -size 10
 686         catch {
 687                 label .dummy
 688                 eval font configure font_ui [font actual [.dummy cget -font]]
 689                 destroy .dummy
 690         }
 691 }
 692
 693 font create font_uiitalic
 694 font create font_uibold
 695 font create font_diffbold
 696 font create font_diffitalic
 697
 698 foreach class {Button Checkbutton Entry Label
 699                 Labelframe Listbox Message
 700                 Radiobutton Spinbox Text} {
 701         option add *$class.font font_ui
 702 }
 703 if {![is_MacOSX]} {
 704         option add *Menu.font font_ui
 705         option add *Entry.borderWidth 1 startupFile
 706         option add *Entry.relief sunken startupFile
 707         option add *RadioButton.anchor w startupFile
 708 }
 709 unset class
 710
 711 if {[is_Windows] || [is_MacOSX]} {
 712         option add *Menu.tearOff 0
 713 }
 714
 715 if {[is_MacOSX]} {
 716         set M1B M1
 717         set M1T Cmd
 718 } else {
 719         set M1B Control
 720         set M1T Ctrl
 721 }
 722
 723 proc bind_button3 {w cmd} {
 724         bind $w <Any-Button-3> $cmd
 725         if {[is_MacOSX]} {
 726                 # Mac OS X sends Button-2 on right click through three-button mouse,
 727                 # or through trackpad right-clicking (two-finger touch + click).
 728                 bind $w <Any-Button-2> $cmd
 729                 bind $w <Control-Button-1> $cmd
 730         }
 731 }
 732
 733 proc apply_config {} {
 734         global repo_config font_descs
 735
 736         foreach option $font_descs {
 737                 set name [lindex $option 0]
 738                 set font [lindex $option 1]
 739                 if {[catch {
 740                         set need_weight 1
 741                         foreach {cn cv} $repo_config(gui.$name) {
 742                                 if {$cn eq {-weight}} {
 743                                         set need_weight 0
 744                                 }
 745                                 font configure $font $cn $cv
 746                         }
 747                         if {$need_weight} {
 748                                 font configure $font -weight normal
 749                         }
 750                         } err]} {
 751                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 752                 }
 753                 foreach {cn cv} [font configure $font] {
 754                         font configure ${font}bold $cn $cv
 755                         font configure ${font}italic $cn $cv
 756                 }
 757                 font configure ${font}bold -weight bold
 758                 font configure ${font}italic -slant italic
 759         }
 760
 761         global use_ttk NS
 762         set use_ttk 0
 763         set NS {}
 764         if {$repo_config(gui.usettk)} {
 765                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 766                 if {$use_ttk} {
 767                         set NS ttk
 768                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 769                         pave_toplevel .
 770                 }
 771         }
 772 }
 773
 774 set default_config(branch.autosetupmerge) true
 775 set default_config(merge.tool) {}
 776 set default_config(mergetool.keepbackup) true
 777 set default_config(merge.diffstat) true
 778 set default_config(merge.summary) false
 779 set default_config(merge.verbosity) 2
 780 set default_config(user.name) {}
 781 set default_config(user.email) {}
 782
 783 set default_config(gui.encoding) [encoding system]
 784 set default_config(gui.matchtrackingbranch) false
 785 set default_config(gui.pruneduringfetch) false
 786 set default_config(gui.trustmtime) false
 787 set default_config(gui.fastcopyblame) false
 788 set default_config(gui.copyblamethreshold) 40
 789 set default_config(gui.blamehistoryctx) 7
 790 set default_config(gui.diffcontext) 5
 791 set default_config(gui.commitmsgwidth) 75
 792 set default_config(gui.newbranchtemplate) {}
 793 set default_config(gui.spellingdictionary) {}
 794 set default_config(gui.fontui) [font configure font_ui]
 795 set default_config(gui.fontdiff) [font configure font_diff]
 796 # TODO: this option should be added to the git-config documentation
 797 set default_config(gui.maxfilesdisplayed) 5000
 798 set default_config(gui.usettk) 1
 799 set font_descs {
 800         {fontui   font_ui   {mc "Main Font"}}
 801         {fontdiff font_diff {mc "Diff/Console Font"}}
 802 }
 803
 804 ######################################################################
 805 ##
 806 ## find git
 807
 808 set _git  [_which git]
 809 if {$_git eq {}} {
 810         catch {wm withdraw .}
 811         tk_messageBox \
 812                 -icon error \
 813                 -type ok \
 814                 -title [mc "git-gui: fatal error"] \
 815                 -message [mc "Cannot find git in PATH."]
 816         exit 1
 817 }
 818
 819 ######################################################################
 820 ##
 821 ## version check
 822
 823 if {[catch {set _git_version [git --version]} err]} {
 824         catch {wm withdraw .}
 825         tk_messageBox \
 826                 -icon error \
 827                 -type ok \
 828                 -title [mc "git-gui: fatal error"] \
 829                 -message "Cannot determine Git version:
 830
 831 $err
 832
 833 [appname] requires Git 1.5.0 or later."
 834         exit 1
 835 }
 836 if {![regsub {^git version } $_git_version {} _git_version]} {
 837         catch {wm withdraw .}
 838         tk_messageBox \
 839                 -icon error \
 840                 -type ok \
 841                 -title [mc "git-gui: fatal error"] \
 842                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 843         exit 1
 844 }
 845
 846 set _real_git_version $_git_version
 847 regsub -- {[\-\.]dirty$} $_git_version {} _git_version
 848 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 849 regsub {\.[a-zA-Z]+\.?[0-9]+$} $_git_version {} _git_version
 850 regsub {\.GIT$} $_git_version {} _git_version
 851 regsub {\.[a-zA-Z]+\.?[0-9]+$} $_git_version {} _git_version
 852
 853 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 854         catch {wm withdraw .}
 855         if {[tk_messageBox \
 856                 -icon warning \
 857                 -type yesno \
 858                 -default no \
 859                 -title "[appname]: warning" \
 860                  -message [mc "Git version cannot be determined.
 861
 862 %s claims it is version '%s'.
 863
 864 %s requires at least Git 1.5.0 or later.
 865
 866 Assume '%s' is version 1.5.0?
 867 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 868                 set _git_version 1.5.0
 869         } else {
 870                 exit 1
 871         }
 872 }
 873 unset _real_git_version
 874
 875 proc git-version {args} {
 876         global _git_version
 877
 878         switch [llength $args] {
 879         0 {
 880                 return $_git_version
 881         }
 882
 883         2 {
 884                 set op [lindex $args 0]
 885                 set vr [lindex $args 1]
 886                 set cm [package vcompare $_git_version $vr]
 887                 return [expr $cm $op 0]
 888         }
 889
 890         4 {
 891                 set type [lindex $args 0]
 892                 set name [lindex $args 1]
 893                 set parm [lindex $args 2]
 894                 set body [lindex $args 3]
 895
 896                 if {($type ne {proc} && $type ne {method})} {
 897                         error "Invalid arguments to git-version"
 898                 }
 899                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 900                         error "Last arm of $type $name must be default"
 901                 }
 902
 903                 foreach {op vr cb} [lrange $body 0 end-2] {
 904                         if {[git-version $op $vr]} {
 905                                 return [uplevel [list $type $name $parm $cb]]
 906                         }
 907                 }
 908
 909                 return [uplevel [list $type $name $parm [lindex $body end]]]
 910         }
 911
 912         default {
 913                 error "git-version >= x"
 914         }
 915
 916         }
 917 }
 918
 919 if {[git-version < 1.5]} {
 920         catch {wm withdraw .}
 921         tk_messageBox \
 922                 -icon error \
 923                 -type ok \
 924                 -title [mc "git-gui: fatal error"] \
 925                 -message "[appname] requires Git 1.5.0 or later.
 926
 927 You are using [git-version]:
 928
 929 [git --version]"
 930         exit 1
 931 }
 932
 933 ######################################################################
 934 ##
 935 ## configure our library
 936
 937 set idx [file join $oguilib tclIndex]
 938 if {[catch {set fd [open $idx r]} err]} {
 939         catch {wm withdraw .}
 940         tk_messageBox \
 941                 -icon error \
 942                 -type ok \
 943                 -title [mc "git-gui: fatal error"] \
 944                 -message $err
 945         exit 1
 946 }
 947 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 948         set idx [list]
 949         while {[gets $fd n] >= 0} {
 950                 if {$n ne {} && ![string match #* $n]} {
 951                         lappend idx $n
 952                 }
 953         }
 954 } else {
 955         set idx {}
 956 }
 957 close $fd
 958
 959 if {$idx ne {}} {
 960         set loaded [list]
 961         foreach p $idx {
 962                 if {[lsearch -exact $loaded $p] >= 0} continue
 963                 source [file join $oguilib $p]
 964                 lappend loaded $p
 965         }
 966         unset loaded p
 967 } else {
 968         set auto_path [concat [list $oguilib] $auto_path]
 969 }
 970 unset -nocomplain idx fd
 971
 972 ######################################################################
 973 ##
 974 ## config file parsing
 975
 976 git-version proc _parse_config {arr_name args} {
 977         >= 1.5.3 {
 978                 upvar $arr_name arr
 979                 array unset arr
 980                 set buf {}
 981                 catch {
 982                         set fd_rc [eval \
 983                                 [list git_read config] \
 984                                 $args \
 985                                 [list --null --list]]
 986                         fconfigure $fd_rc -translation binary
 987                         set buf [read $fd_rc]
 988                         close $fd_rc
 989                 }
 990                 foreach line [split $buf "\0"] {
 991                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
 992                                 if {[is_many_config $name]} {
 993                                         lappend arr($name) $value
 994                                 } else {
 995                                         set arr($name) $value
 996                                 }
 997                         }
 998                 }
 999         }
1000         default {
1001                 upvar $arr_name arr
1002                 array unset arr
1003                 catch {
1004                         set fd_rc [eval [list git_read config --list] $args]
1005                         while {[gets $fd_rc line] >= 0} {
1006                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1007                                         if {[is_many_config $name]} {
1008                                                 lappend arr($name) $value
1009                                         } else {
1010                                                 set arr($name) $value
1011                                         }
1012                                 }
1013                         }
1014                         close $fd_rc
1015                 }
1016         }
1017 }
1018
1019 proc load_config {include_global} {
1020         global repo_config global_config system_config default_config
1021
1022         if {$include_global} {
1023                 _parse_config system_config --system
1024                 _parse_config global_config --global
1025         }
1026         _parse_config repo_config
1027
1028         foreach name [array names default_config] {
1029                 if {[catch {set v $system_config($name)}]} {
1030                         set system_config($name) $default_config($name)
1031                 }
1032         }
1033         foreach name [array names system_config] {
1034                 if {[catch {set v $global_config($name)}]} {
1035                         set global_config($name) $system_config($name)
1036                 }
1037                 if {[catch {set v $repo_config($name)}]} {
1038                         set repo_config($name) $system_config($name)
1039                 }
1040         }
1041 }
1042
1043 ######################################################################
1044 ##
1045 ## feature option selection
1046
1047 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1048         unset _junk
1049 } else {
1050         set subcommand gui
1051 }
1052 if {$subcommand eq {gui.sh}} {
1053         set subcommand gui
1054 }
1055 if {$subcommand eq {gui} && [llength $argv] > 0} {
1056         set subcommand [lindex $argv 0]
1057         set argv [lrange $argv 1 end]
1058 }
1059
1060 enable_option multicommit
1061 enable_option branch
1062 enable_option transport
1063 disable_option bare
1064
1065 switch -- $subcommand {
1066 browser -
1067 blame {
1068         enable_option bare
1069
1070         disable_option multicommit
1071         disable_option branch
1072         disable_option transport
1073 }
1074 citool {
1075         enable_option singlecommit
1076         enable_option retcode
1077
1078         disable_option multicommit
1079         disable_option branch
1080         disable_option transport
1081
1082         while {[llength $argv] > 0} {
1083                 set a [lindex $argv 0]
1084                 switch -- $a {
1085                 --amend {
1086                         enable_option initialamend
1087                 }
1088                 --nocommit {
1089                         enable_option nocommit
1090                         enable_option nocommitmsg
1091                 }
1092                 --commitmsg {
1093                         disable_option nocommitmsg
1094                 }
1095                 default {
1096                         break
1097                 }
1098                 }
1099
1100                 set argv [lrange $argv 1 end]
1101         }
1102 }
1103 }
1104
1105 ######################################################################
1106 ##
1107 ## execution environment
1108
1109 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1110
1111 # Suggest our implementation of askpass, if none is set
1112 if {![info exists env(SSH_ASKPASS)]} {
1113         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1114 }
1115
1116 ######################################################################
1117 ##
1118 ## repository setup
1119
1120 set picked 0
1121 if {[catch {
1122                 set _gitdir $env(GIT_DIR)
1123                 set _prefix {}
1124                 }]
1125         && [catch {
1126                 # beware that from the .git dir this sets _gitdir to .
1127                 # and _prefix to the empty string
1128                 set _gitdir [git rev-parse --git-dir]
1129                 set _prefix [git rev-parse --show-prefix]
1130         } err]} {
1131         load_config 1
1132         apply_config
1133         choose_repository::pick
1134         set picked 1
1135 }
1136
1137 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1138 # run from the .git dir itself) lest the routines to find the worktree
1139 # get confused
1140 if {$_gitdir eq "."} {
1141         set _gitdir [pwd]
1142 }
1143
1144 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1145         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1146 }
1147 if {![file isdirectory $_gitdir]} {
1148         catch {wm withdraw .}
1149         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1150         exit 1
1151 }
1152 # _gitdir exists, so try loading the config
1153 load_config 0
1154 apply_config
1155 # try to set work tree from environment, falling back to core.worktree
1156 if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1157         set _gitworktree [get_config core.worktree]
1158 }
1159 if {$_prefix ne {}} {
1160         if {$_gitworktree eq {}} {
1161                 regsub -all {[^/]+/} $_prefix ../ cdup
1162         } else {
1163                 set cdup $_gitworktree
1164         }
1165         if {[catch {cd $cdup} err]} {
1166                 catch {wm withdraw .}
1167                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1168                 exit 1
1169         }
1170         set _gitworktree [pwd]
1171         unset cdup
1172 } elseif {![is_enabled bare]} {
1173         if {[is_bare]} {
1174                 catch {wm withdraw .}
1175                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1176                 exit 1
1177         }
1178         if {$_gitworktree eq {}} {
1179                 set _gitworktree [file dirname $_gitdir]
1180         }
1181         if {[catch {cd $_gitworktree} err]} {
1182                 catch {wm withdraw .}
1183                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1184                 exit 1
1185         }
1186         set _gitworktree [pwd]
1187 }
1188 set _reponame [file split [file normalize $_gitdir]]
1189 if {[lindex $_reponame end] eq {.git}} {
1190         set _reponame [lindex $_reponame end-1]
1191 } else {
1192         set _reponame [lindex $_reponame end]
1193 }
1194
1195 set env(GIT_DIR) $_gitdir
1196 set env(GIT_WORK_TREE) $_gitworktree
1197
1198 ######################################################################
1199 ##
1200 ## global init
1201
1202 set current_diff_path {}
1203 set current_diff_side {}
1204 set diff_actions [list]
1205
1206 set HEAD {}
1207 set PARENT {}
1208 set MERGE_HEAD [list]
1209 set commit_type {}
1210 set empty_tree {}
1211 set current_branch {}
1212 set is_detached 0
1213 set current_diff_path {}
1214 set is_3way_diff 0
1215 set is_submodule_diff 0
1216 set is_conflict_diff 0
1217 set selected_commit_type new
1218 set diff_empty_count 0
1219
1220 set nullid "0000000000000000000000000000000000000000"
1221 set nullid2 "0000000000000000000000000000000000000001"
1222
1223 ######################################################################
1224 ##
1225 ## task management
1226
1227 set rescan_active 0
1228 set diff_active 0
1229 set last_clicked {}
1230
1231 set disable_on_lock [list]
1232 set index_lock_type none
1233
1234 proc lock_index {type} {
1235         global index_lock_type disable_on_lock
1236
1237         if {$index_lock_type eq {none}} {
1238                 set index_lock_type $type
1239                 foreach w $disable_on_lock {
1240                         uplevel #0 $w disabled
1241                 }
1242                 return 1
1243         } elseif {$index_lock_type eq "begin-$type"} {
1244                 set index_lock_type $type
1245                 return 1
1246         }
1247         return 0
1248 }
1249
1250 proc unlock_index {} {
1251         global index_lock_type disable_on_lock
1252
1253         set index_lock_type none
1254         foreach w $disable_on_lock {
1255                 uplevel #0 $w normal
1256         }
1257 }
1258
1259 ######################################################################
1260 ##
1261 ## status
1262
1263 proc repository_state {ctvar hdvar mhvar} {
1264         global current_branch
1265         upvar $ctvar ct $hdvar hd $mhvar mh
1266
1267         set mh [list]
1268
1269         load_current_branch
1270         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1271                 set hd {}
1272                 set ct initial
1273                 return
1274         }
1275
1276         set merge_head [gitdir MERGE_HEAD]
1277         if {[file exists $merge_head]} {
1278                 set ct merge
1279                 set fd_mh [open $merge_head r]
1280                 while {[gets $fd_mh line] >= 0} {
1281                         lappend mh $line
1282                 }
1283                 close $fd_mh
1284                 return
1285         }
1286
1287         set ct normal
1288 }
1289
1290 proc PARENT {} {
1291         global PARENT empty_tree
1292
1293         set p [lindex $PARENT 0]
1294         if {$p ne {}} {
1295                 return $p
1296         }
1297         if {$empty_tree eq {}} {
1298                 set empty_tree [git mktree << {}]
1299         }
1300         return $empty_tree
1301 }
1302
1303 proc force_amend {} {
1304         global selected_commit_type
1305         global HEAD PARENT MERGE_HEAD commit_type
1306
1307         repository_state newType newHEAD newMERGE_HEAD
1308         set HEAD $newHEAD
1309         set PARENT $newHEAD
1310         set MERGE_HEAD $newMERGE_HEAD
1311         set commit_type $newType
1312
1313         set selected_commit_type amend
1314         do_select_commit_type
1315 }
1316
1317 proc rescan {after {honor_trustmtime 1}} {
1318         global HEAD PARENT MERGE_HEAD commit_type
1319         global ui_index ui_workdir ui_comm
1320         global rescan_active file_states
1321         global repo_config
1322
1323         if {$rescan_active > 0 || ![lock_index read]} return
1324
1325         repository_state newType newHEAD newMERGE_HEAD
1326         if {[string match amend* $commit_type]
1327                 && $newType eq {normal}
1328                 && $newHEAD eq $HEAD} {
1329         } else {
1330                 set HEAD $newHEAD
1331                 set PARENT $newHEAD
1332                 set MERGE_HEAD $newMERGE_HEAD
1333                 set commit_type $newType
1334         }
1335
1336         array unset file_states
1337
1338         if {!$::GITGUI_BCK_exists &&
1339                 (![$ui_comm edit modified]
1340                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1341                 if {[string match amend* $commit_type]} {
1342                 } elseif {[load_message GITGUI_MSG]} {
1343                 } elseif {[run_prepare_commit_msg_hook]} {
1344                 } elseif {[load_message MERGE_MSG]} {
1345                 } elseif {[load_message SQUASH_MSG]} {
1346                 }
1347                 $ui_comm edit reset
1348                 $ui_comm edit modified false
1349         }
1350
1351         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1352                 rescan_stage2 {} $after
1353         } else {
1354                 set rescan_active 1
1355                 ui_status [mc "Refreshing file status..."]
1356                 set fd_rf [git_read update-index \
1357                         -q \
1358                         --unmerged \
1359                         --ignore-missing \
1360                         --refresh \
1361                         ]
1362                 fconfigure $fd_rf -blocking 0 -translation binary
1363                 fileevent $fd_rf readable \
1364                         [list rescan_stage2 $fd_rf $after]
1365         }
1366 }
1367
1368 if {[is_Cygwin]} {
1369         set is_git_info_exclude {}
1370         proc have_info_exclude {} {
1371                 global is_git_info_exclude
1372
1373                 if {$is_git_info_exclude eq {}} {
1374                         if {[catch {exec test -f [gitdir info exclude]}]} {
1375                                 set is_git_info_exclude 0
1376                         } else {
1377                                 set is_git_info_exclude 1
1378                         }
1379                 }
1380                 return $is_git_info_exclude
1381         }
1382 } else {
1383         proc have_info_exclude {} {
1384                 return [file readable [gitdir info exclude]]
1385         }
1386 }
1387
1388 proc rescan_stage2 {fd after} {
1389         global rescan_active buf_rdi buf_rdf buf_rlo
1390
1391         if {$fd ne {}} {
1392                 read $fd
1393                 if {![eof $fd]} return
1394                 close $fd
1395         }
1396
1397         set ls_others [list --exclude-per-directory=.gitignore]
1398         if {[have_info_exclude]} {
1399                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1400         }
1401         set user_exclude [get_config core.excludesfile]
1402         if {$user_exclude ne {} && [file readable $user_exclude]} {
1403                 lappend ls_others "--exclude-from=$user_exclude"
1404         }
1405
1406         set buf_rdi {}
1407         set buf_rdf {}
1408         set buf_rlo {}
1409
1410         set rescan_active 3
1411         ui_status [mc "Scanning for modified files ..."]
1412         set fd_di [git_read diff-index --cached -z [PARENT]]
1413         set fd_df [git_read diff-files -z]
1414         set fd_lo [eval git_read ls-files --others -z $ls_others]
1415
1416         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1417         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1418         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1419         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1420         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1421         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1422 }
1423
1424 proc load_message {file} {
1425         global ui_comm
1426
1427         set f [gitdir $file]
1428         if {[file isfile $f]} {
1429                 if {[catch {set fd [open $f r]}]} {
1430                         return 0
1431                 }
1432                 fconfigure $fd -eofchar {}
1433                 set content [string trim [read $fd]]
1434                 close $fd
1435                 regsub -all -line {[ \r\t]+$} $content {} content
1436                 $ui_comm delete 0.0 end
1437                 $ui_comm insert end $content
1438                 return 1
1439         }
1440         return 0
1441 }
1442
1443 proc run_prepare_commit_msg_hook {} {
1444         global pch_error
1445
1446         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1447         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1448         # empty file but existant file.
1449
1450         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1451
1452         if {[file isfile [gitdir MERGE_MSG]]} {
1453                 set pcm_source "merge"
1454                 set fd_mm [open [gitdir MERGE_MSG] r]
1455                 puts -nonewline $fd_pcm [read $fd_mm]
1456                 close $fd_mm
1457         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1458                 set pcm_source "squash"
1459                 set fd_sm [open [gitdir SQUASH_MSG] r]
1460                 puts -nonewline $fd_pcm [read $fd_sm]
1461                 close $fd_sm
1462         } else {
1463                 set pcm_source ""
1464         }
1465
1466         close $fd_pcm
1467
1468         set fd_ph [githook_read prepare-commit-msg \
1469                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1470         if {$fd_ph eq {}} {
1471                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1472                 return 0;
1473         }
1474
1475         ui_status [mc "Calling prepare-commit-msg hook..."]
1476         set pch_error {}
1477
1478         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1479         fileevent $fd_ph readable \
1480                 [list prepare_commit_msg_hook_wait $fd_ph]
1481
1482         return 1;
1483 }
1484
1485 proc prepare_commit_msg_hook_wait {fd_ph} {
1486         global pch_error
1487
1488         append pch_error [read $fd_ph]
1489         fconfigure $fd_ph -blocking 1
1490         if {[eof $fd_ph]} {
1491                 if {[catch {close $fd_ph}]} {
1492                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1493                         hook_failed_popup prepare-commit-msg $pch_error
1494                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1495                         exit 1
1496                 } else {
1497                         load_message PREPARE_COMMIT_MSG
1498                 }
1499                 set pch_error {}
1500                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1501                 return
1502         }
1503         fconfigure $fd_ph -blocking 0
1504         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1505 }
1506
1507 proc read_diff_index {fd after} {
1508         global buf_rdi
1509
1510         append buf_rdi [read $fd]
1511         set c 0
1512         set n [string length $buf_rdi]
1513         while {$c < $n} {
1514                 set z1 [string first "\0" $buf_rdi $c]
1515                 if {$z1 == -1} break
1516                 incr z1
1517                 set z2 [string first "\0" $buf_rdi $z1]
1518                 if {$z2 == -1} break
1519
1520                 incr c
1521                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1522                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1523                 merge_state \
1524                         [encoding convertfrom $p] \
1525                         [lindex $i 4]? \
1526                         [list [lindex $i 0] [lindex $i 2]] \
1527                         [list]
1528                 set c $z2
1529                 incr c
1530         }
1531         if {$c < $n} {
1532                 set buf_rdi [string range $buf_rdi $c end]
1533         } else {
1534                 set buf_rdi {}
1535         }
1536
1537         rescan_done $fd buf_rdi $after
1538 }
1539
1540 proc read_diff_files {fd after} {
1541         global buf_rdf
1542
1543         append buf_rdf [read $fd]
1544         set c 0
1545         set n [string length $buf_rdf]
1546         while {$c < $n} {
1547                 set z1 [string first "\0" $buf_rdf $c]
1548                 if {$z1 == -1} break
1549                 incr z1
1550                 set z2 [string first "\0" $buf_rdf $z1]
1551                 if {$z2 == -1} break
1552
1553                 incr c
1554                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1555                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1556                 merge_state \
1557                         [encoding convertfrom $p] \
1558                         ?[lindex $i 4] \
1559                         [list] \
1560                         [list [lindex $i 0] [lindex $i 2]]
1561                 set c $z2
1562                 incr c
1563         }
1564         if {$c < $n} {
1565                 set buf_rdf [string range $buf_rdf $c end]
1566         } else {
1567                 set buf_rdf {}
1568         }
1569
1570         rescan_done $fd buf_rdf $after
1571 }
1572
1573 proc read_ls_others {fd after} {
1574         global buf_rlo
1575
1576         append buf_rlo [read $fd]
1577         set pck [split $buf_rlo "\0"]
1578         set buf_rlo [lindex $pck end]
1579         foreach p [lrange $pck 0 end-1] {
1580                 set p [encoding convertfrom $p]
1581                 if {[string index $p end] eq {/}} {
1582                         set p [string range $p 0 end-1]
1583                 }
1584                 merge_state $p ?O
1585         }
1586         rescan_done $fd buf_rlo $after
1587 }
1588
1589 proc rescan_done {fd buf after} {
1590         global rescan_active current_diff_path
1591         global file_states repo_config
1592         upvar $buf to_clear
1593
1594         if {![eof $fd]} return
1595         set to_clear {}
1596         close $fd
1597         if {[incr rescan_active -1] > 0} return
1598
1599         prune_selection
1600         unlock_index
1601         display_all_files
1602         if {$current_diff_path ne {}} { reshow_diff $after }
1603         if {$current_diff_path eq {}} { select_first_diff $after }
1604 }
1605
1606 proc prune_selection {} {
1607         global file_states selected_paths
1608
1609         foreach path [array names selected_paths] {
1610                 if {[catch {set still_here $file_states($path)}]} {
1611                         unset selected_paths($path)
1612                 }
1613         }
1614 }
1615
1616 ######################################################################
1617 ##
1618 ## ui helpers
1619
1620 proc mapicon {w state path} {
1621         global all_icons
1622
1623         if {[catch {set r $all_icons($state$w)}]} {
1624                 puts "error: no icon for $w state={$state} $path"
1625                 return file_plain
1626         }
1627         return $r
1628 }
1629
1630 proc mapdesc {state path} {
1631         global all_descs
1632
1633         if {[catch {set r $all_descs($state)}]} {
1634                 puts "error: no desc for state={$state} $path"
1635                 return $state
1636         }
1637         return $r
1638 }
1639
1640 proc ui_status {msg} {
1641         global main_status
1642         if {[info exists main_status]} {
1643                 $main_status show $msg
1644         }
1645 }
1646
1647 proc ui_ready {{test {}}} {
1648         global main_status
1649         if {[info exists main_status]} {
1650                 $main_status show [mc "Ready."] $test
1651         }
1652 }
1653
1654 proc escape_path {path} {
1655         regsub -all {\\} $path "\\\\" path
1656         regsub -all "\n" $path "\\n" path
1657         return $path
1658 }
1659
1660 proc short_path {path} {
1661         return [escape_path [lindex [file split $path] end]]
1662 }
1663
1664 set next_icon_id 0
1665 set null_sha1 [string repeat 0 40]
1666
1667 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1668         global file_states next_icon_id null_sha1
1669
1670         set s0 [string index $new_state 0]
1671         set s1 [string index $new_state 1]
1672
1673         if {[catch {set info $file_states($path)}]} {
1674                 set state __
1675                 set icon n[incr next_icon_id]
1676         } else {
1677                 set state [lindex $info 0]
1678                 set icon [lindex $info 1]
1679                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1680                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1681         }
1682
1683         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1684         elseif {$s0 eq {_}} {set s0 _}
1685
1686         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1687         elseif {$s1 eq {_}} {set s1 _}
1688
1689         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1690                 set head_info [list 0 $null_sha1]
1691         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1692                 && $head_info eq {}} {
1693                 set head_info $index_info
1694         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1695                 set index_info $head_info
1696                 set head_info {}
1697         }
1698
1699         set file_states($path) [list $s0$s1 $icon \
1700                 $head_info $index_info \
1701                 ]
1702         return $state
1703 }
1704
1705 proc display_file_helper {w path icon_name old_m new_m} {
1706         global file_lists
1707
1708         if {$new_m eq {_}} {
1709                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1710                 if {$lno >= 0} {
1711                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1712                         incr lno
1713                         $w conf -state normal
1714                         $w delete $lno.0 [expr {$lno + 1}].0
1715                         $w conf -state disabled
1716                 }
1717         } elseif {$old_m eq {_} && $new_m ne {_}} {
1718                 lappend file_lists($w) $path
1719                 set file_lists($w) [lsort -unique $file_lists($w)]
1720                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1721                 incr lno
1722                 $w conf -state normal
1723                 $w image create $lno.0 \
1724                         -align center -padx 5 -pady 1 \
1725                         -name $icon_name \
1726                         -image [mapicon $w $new_m $path]
1727                 $w insert $lno.1 "[escape_path $path]\n"
1728                 $w conf -state disabled
1729         } elseif {$old_m ne $new_m} {
1730                 $w conf -state normal
1731                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1732                 $w conf -state disabled
1733         }
1734 }
1735
1736 proc display_file {path state} {
1737         global file_states selected_paths
1738         global ui_index ui_workdir
1739
1740         set old_m [merge_state $path $state]
1741         set s $file_states($path)
1742         set new_m [lindex $s 0]
1743         set icon_name [lindex $s 1]
1744
1745         set o [string index $old_m 0]
1746         set n [string index $new_m 0]
1747         if {$o eq {U}} {
1748                 set o _
1749         }
1750         if {$n eq {U}} {
1751                 set n _
1752         }
1753         display_file_helper     $ui_index $path $icon_name $o $n
1754
1755         if {[string index $old_m 0] eq {U}} {
1756                 set o U
1757         } else {
1758                 set o [string index $old_m 1]
1759         }
1760         if {[string index $new_m 0] eq {U}} {
1761                 set n U
1762         } else {
1763                 set n [string index $new_m 1]
1764         }
1765         display_file_helper     $ui_workdir $path $icon_name $o $n
1766
1767         if {$new_m eq {__}} {
1768                 unset file_states($path)
1769                 catch {unset selected_paths($path)}
1770         }
1771 }
1772
1773 proc display_all_files_helper {w path icon_name m} {
1774         global file_lists
1775
1776         lappend file_lists($w) $path
1777         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1778         $w image create end \
1779                 -align center -padx 5 -pady 1 \
1780                 -name $icon_name \
1781                 -image [mapicon $w $m $path]
1782         $w insert end "[escape_path $path]\n"
1783 }
1784
1785 set files_warning 0
1786 proc display_all_files {} {
1787         global ui_index ui_workdir
1788         global file_states file_lists
1789         global last_clicked
1790         global files_warning
1791
1792         $ui_index conf -state normal
1793         $ui_workdir conf -state normal
1794
1795         $ui_index delete 0.0 end
1796         $ui_workdir delete 0.0 end
1797         set last_clicked {}
1798
1799         set file_lists($ui_index) [list]
1800         set file_lists($ui_workdir) [list]
1801
1802         set to_display [lsort [array names file_states]]
1803         set display_limit [get_config gui.maxfilesdisplayed]
1804         if {[llength $to_display] > $display_limit} {
1805                 if {!$files_warning} {
1806                         # do not repeatedly warn:
1807                         set files_warning 1
1808                         info_popup [mc "Displaying only %s of %s files." \
1809                                 $display_limit [llength $to_display]]
1810                 }
1811                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1812         }
1813         foreach path $to_display {
1814                 set s $file_states($path)
1815                 set m [lindex $s 0]
1816                 set icon_name [lindex $s 1]
1817
1818                 set s [string index $m 0]
1819                 if {$s ne {U} && $s ne {_}} {
1820                         display_all_files_helper $ui_index $path \
1821                                 $icon_name $s
1822                 }
1823
1824                 if {[string index $m 0] eq {U}} {
1825                         set s U
1826                 } else {
1827                         set s [string index $m 1]
1828                 }
1829                 if {$s ne {_}} {
1830                         display_all_files_helper $ui_workdir $path \
1831                                 $icon_name $s
1832                 }
1833         }
1834
1835         $ui_index conf -state disabled
1836         $ui_workdir conf -state disabled
1837 }
1838
1839 ######################################################################
1840 ##
1841 ## icons
1842
1843 set filemask {
1844 #define mask_width 14
1845 #define mask_height 15
1846 static unsigned char mask_bits[] = {
1847    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1848    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1849    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1850 }
1851
1852 image create bitmap file_plain -background white -foreground black -data {
1853 #define plain_width 14
1854 #define plain_height 15
1855 static unsigned char plain_bits[] = {
1856    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1857    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1858    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1859 } -maskdata $filemask
1860
1861 image create bitmap file_mod -background white -foreground blue -data {
1862 #define mod_width 14
1863 #define mod_height 15
1864 static unsigned char mod_bits[] = {
1865    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1866    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1867    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1868 } -maskdata $filemask
1869
1870 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1871 #define file_fulltick_width 14
1872 #define file_fulltick_height 15
1873 static unsigned char file_fulltick_bits[] = {
1874    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1875    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1876    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1877 } -maskdata $filemask
1878
1879 image create bitmap file_question -background white -foreground black -data {
1880 #define file_question_width 14
1881 #define file_question_height 15
1882 static unsigned char file_question_bits[] = {
1883    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1884    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1885    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1886 } -maskdata $filemask
1887
1888 image create bitmap file_removed -background white -foreground red -data {
1889 #define file_removed_width 14
1890 #define file_removed_height 15
1891 static unsigned char file_removed_bits[] = {
1892    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1893    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1894    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1895 } -maskdata $filemask
1896
1897 image create bitmap file_merge -background white -foreground blue -data {
1898 #define file_merge_width 14
1899 #define file_merge_height 15
1900 static unsigned char file_merge_bits[] = {
1901    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1902    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1903    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1904 } -maskdata $filemask
1905
1906 image create bitmap file_statechange -background white -foreground green -data {
1907 #define file_merge_width 14
1908 #define file_merge_height 15
1909 static unsigned char file_statechange_bits[] = {
1910    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1911    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1912    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1913 } -maskdata $filemask
1914
1915 set ui_index .vpane.files.index.list
1916 set ui_workdir .vpane.files.workdir.list
1917
1918 set all_icons(_$ui_index)   file_plain
1919 set all_icons(A$ui_index)   file_plain
1920 set all_icons(M$ui_index)   file_fulltick
1921 set all_icons(D$ui_index)   file_removed
1922 set all_icons(U$ui_index)   file_merge
1923 set all_icons(T$ui_index)   file_statechange
1924
1925 set all_icons(_$ui_workdir) file_plain
1926 set all_icons(M$ui_workdir) file_mod
1927 set all_icons(D$ui_workdir) file_question
1928 set all_icons(U$ui_workdir) file_merge
1929 set all_icons(O$ui_workdir) file_plain
1930 set all_icons(T$ui_workdir) file_statechange
1931
1932 set max_status_desc 0
1933 foreach i {
1934                 {__ {mc "Unmodified"}}
1935
1936                 {_M {mc "Modified, not staged"}}
1937                 {M_ {mc "Staged for commit"}}
1938                 {MM {mc "Portions staged for commit"}}
1939                 {MD {mc "Staged for commit, missing"}}
1940
1941                 {_T {mc "File type changed, not staged"}}
1942                 {T_ {mc "File type changed, staged"}}
1943
1944                 {_O {mc "Untracked, not staged"}}
1945                 {A_ {mc "Staged for commit"}}
1946                 {AM {mc "Portions staged for commit"}}
1947                 {AD {mc "Staged for commit, missing"}}
1948
1949                 {_D {mc "Missing"}}
1950                 {D_ {mc "Staged for removal"}}
1951                 {DO {mc "Staged for removal, still present"}}
1952
1953                 {_U {mc "Requires merge resolution"}}
1954                 {U_ {mc "Requires merge resolution"}}
1955                 {UU {mc "Requires merge resolution"}}
1956                 {UM {mc "Requires merge resolution"}}
1957                 {UD {mc "Requires merge resolution"}}
1958                 {UT {mc "Requires merge resolution"}}
1959         } {
1960         set text [eval [lindex $i 1]]
1961         if {$max_status_desc < [string length $text]} {
1962                 set max_status_desc [string length $text]
1963         }
1964         set all_descs([lindex $i 0]) $text
1965 }
1966 unset i
1967
1968 ######################################################################
1969 ##
1970 ## util
1971
1972 proc scrollbar2many {list mode args} {
1973         foreach w $list {eval $w $mode $args}
1974 }
1975
1976 proc many2scrollbar {list mode sb top bottom} {
1977         $sb set $top $bottom
1978         foreach w $list {$w $mode moveto $top}
1979 }
1980
1981 proc incr_font_size {font {amt 1}} {
1982         set sz [font configure $font -size]
1983         incr sz $amt
1984         font configure $font -size $sz
1985         font configure ${font}bold -size $sz
1986         font configure ${font}italic -size $sz
1987 }
1988
1989 ######################################################################
1990 ##
1991 ## ui commands
1992
1993 set starting_gitk_msg [mc "Starting gitk... please wait..."]
1994
1995 proc do_gitk {revs {is_submodule false}} {
1996         global current_diff_path file_states current_diff_side ui_index
1997         global _gitdir _gitworktree
1998
1999         # -- Always start gitk through whatever we were loaded with.  This
2000         #    lets us bypass using shell process on Windows systems.
2001         #
2002         set exe [_which gitk -script]
2003         set cmd [list [info nameofexecutable] $exe]
2004         if {$exe eq {}} {
2005                 error_popup [mc "Couldn't find gitk in PATH"]
2006         } else {
2007                 global env
2008
2009                 set pwd [pwd]
2010
2011                 if {!$is_submodule} {
2012                         if {![is_bare]} {
2013                                 cd $_gitworktree
2014                         }
2015                 } else {
2016                         cd $current_diff_path
2017                         if {$revs eq {--}} {
2018                                 set s $file_states($current_diff_path)
2019                                 set old_sha1 {}
2020                                 set new_sha1 {}
2021                                 switch -glob -- [lindex $s 0] {
2022                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2023                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2024                                 MM {
2025                                         if {$current_diff_side eq $ui_index} {
2026                                                 set old_sha1 [lindex [lindex $s 2] 1]
2027                                                 set new_sha1 [lindex [lindex $s 3] 1]
2028                                         } else {
2029                                                 set old_sha1 [lindex [lindex $s 3] 1]
2030                                         }
2031                                 }
2032                                 }
2033                                 set revs $old_sha1...$new_sha1
2034                         }
2035                         # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2036                         # we've been using for the main repository, so unset them.
2037                         # TODO we could make life easier (start up faster?) for gitk
2038                         # by setting these to the appropriate values to allow gitk
2039                         # to skip the heuristics to find their proper value
2040                         unset env(GIT_DIR)
2041                         unset env(GIT_WORK_TREE)
2042                 }
2043                 eval exec $cmd $revs "--" "--" &
2044
2045                 set env(GIT_DIR) $_gitdir
2046                 set env(GIT_WORK_TREE) $_gitworktree
2047                 cd $pwd
2048
2049                 ui_status $::starting_gitk_msg
2050                 after 10000 {
2051                         ui_ready $starting_gitk_msg
2052                 }
2053         }
2054 }
2055
2056 proc do_git_gui {} {
2057         global current_diff_path
2058
2059         # -- Always start git gui through whatever we were loaded with.  This
2060         #    lets us bypass using shell process on Windows systems.
2061         #
2062         set exe [list [_which git]]
2063         if {$exe eq {}} {
2064                 error_popup [mc "Couldn't find git gui in PATH"]
2065         } else {
2066                 global env
2067                 global _gitdir _gitworktree
2068
2069                 # see note in do_gitk about unsetting these vars when
2070                 # running tools in a submodule
2071                 unset env(GIT_DIR)
2072                 unset env(GIT_WORK_TREE)
2073
2074                 set pwd [pwd]
2075                 cd $current_diff_path
2076
2077                 eval exec $exe gui &
2078
2079                 set env(GIT_DIR) $_gitdir
2080                 set env(GIT_WORK_TREE) $_gitworktree
2081                 cd $pwd
2082
2083                 ui_status $::starting_gitk_msg
2084                 after 10000 {
2085                         ui_ready $starting_gitk_msg
2086                 }
2087         }
2088 }
2089
2090 proc do_explore {} {
2091         global _gitworktree
2092         set explorer {}
2093         if {[is_Cygwin] || [is_Windows]} {
2094                 set explorer "explorer.exe"
2095         } elseif {[is_MacOSX]} {
2096                 set explorer "open"
2097         } else {
2098                 # freedesktop.org-conforming system is our best shot
2099                 set explorer "xdg-open"
2100         }
2101         eval exec $explorer $_gitworktree &
2102 }
2103
2104 set is_quitting 0
2105 set ret_code    1
2106
2107 proc terminate_me {win} {
2108         global ret_code
2109         if {$win ne {.}} return
2110         exit $ret_code
2111 }
2112
2113 proc do_quit {{rc {1}}} {
2114         global ui_comm is_quitting repo_config commit_type
2115         global GITGUI_BCK_exists GITGUI_BCK_i
2116         global ui_comm_spell
2117         global ret_code use_ttk
2118
2119         if {$is_quitting} return
2120         set is_quitting 1
2121
2122         if {[winfo exists $ui_comm]} {
2123                 # -- Stash our current commit buffer.
2124                 #
2125                 set save [gitdir GITGUI_MSG]
2126                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2127                         file rename -force [gitdir GITGUI_BCK] $save
2128                         set GITGUI_BCK_exists 0
2129                 } else {
2130                         set msg [string trim [$ui_comm get 0.0 end]]
2131                         regsub -all -line {[ \r\t]+$} $msg {} msg
2132                         if {(![string match amend* $commit_type]
2133                                 || [$ui_comm edit modified])
2134                                 && $msg ne {}} {
2135                                 catch {
2136                                         set fd [open $save w]
2137                                         puts -nonewline $fd $msg
2138                                         close $fd
2139                                 }
2140                         } else {
2141                                 catch {file delete $save}
2142                         }
2143                 }
2144
2145                 # -- Cancel our spellchecker if its running.
2146                 #
2147                 if {[info exists ui_comm_spell]} {
2148                         $ui_comm_spell stop
2149                 }
2150
2151                 # -- Remove our editor backup, its not needed.
2152                 #
2153                 after cancel $GITGUI_BCK_i
2154                 if {$GITGUI_BCK_exists} {
2155                         catch {file delete [gitdir GITGUI_BCK]}
2156                 }
2157
2158                 # -- Stash our current window geometry into this repository.
2159                 #
2160                 set cfg_wmstate [wm state .]
2161                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2162                         set rc_wmstate {}
2163                 }
2164                 if {$cfg_wmstate ne $rc_wmstate} {
2165                         catch {git config gui.wmstate $cfg_wmstate}
2166                 }
2167                 if {$cfg_wmstate eq {zoomed}} {
2168                         # on Windows wm geometry will lie about window
2169                         # position (but not size) when window is zoomed
2170                         # restore the window before querying wm geometry
2171                         wm state . normal
2172                 }
2173                 set cfg_geometry [list]
2174                 lappend cfg_geometry [wm geometry .]
2175                 if {$use_ttk} {
2176                         lappend cfg_geometry [.vpane sashpos 0]
2177                         lappend cfg_geometry [.vpane.files sashpos 0]
2178                 } else {
2179                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2180                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2181                 }
2182                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2183                         set rc_geometry {}
2184                 }
2185                 if {$cfg_geometry ne $rc_geometry} {
2186                         catch {git config gui.geometry $cfg_geometry}
2187                 }
2188         }
2189
2190         set ret_code $rc
2191
2192         # Briefly enable send again, working around Tk bug
2193         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2194         tk appname [appname]
2195
2196         destroy .
2197 }
2198
2199 proc do_rescan {} {
2200         rescan ui_ready
2201 }
2202
2203 proc ui_do_rescan {} {
2204         rescan {force_first_diff ui_ready}
2205 }
2206
2207 proc do_commit {} {
2208         commit_tree
2209 }
2210
2211 proc next_diff {{after {}}} {
2212         global next_diff_p next_diff_w next_diff_i
2213         show_diff $next_diff_p $next_diff_w {} {} $after
2214 }
2215
2216 proc find_anchor_pos {lst name} {
2217         set lid [lsearch -sorted -exact $lst $name]
2218
2219         if {$lid == -1} {
2220                 set lid 0
2221                 foreach lname $lst {
2222                         if {$lname >= $name} break
2223                         incr lid
2224                 }
2225         }
2226
2227         return $lid
2228 }
2229
2230 proc find_file_from {flist idx delta path mmask} {
2231         global file_states
2232
2233         set len [llength $flist]
2234         while {$idx >= 0 && $idx < $len} {
2235                 set name [lindex $flist $idx]
2236
2237                 if {$name ne $path && [info exists file_states($name)]} {
2238                         set state [lindex $file_states($name) 0]
2239
2240                         if {$mmask eq {} || [regexp $mmask $state]} {
2241                                 return $idx
2242                         }
2243                 }
2244
2245                 incr idx $delta
2246         }
2247
2248         return {}
2249 }
2250
2251 proc find_next_diff {w path {lno {}} {mmask {}}} {
2252         global next_diff_p next_diff_w next_diff_i
2253         global file_lists ui_index ui_workdir
2254
2255         set flist $file_lists($w)
2256         if {$lno eq {}} {
2257                 set lno [find_anchor_pos $flist $path]
2258         } else {
2259                 incr lno -1
2260         }
2261
2262         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2263                 if {$w eq $ui_index} {
2264                         set mmask "^$mmask"
2265                 } else {
2266                         set mmask "$mmask\$"
2267                 }
2268         }
2269
2270         set idx [find_file_from $flist $lno 1 $path $mmask]
2271         if {$idx eq {}} {
2272                 incr lno -1
2273                 set idx [find_file_from $flist $lno -1 $path $mmask]
2274         }
2275
2276         if {$idx ne {}} {
2277                 set next_diff_w $w
2278                 set next_diff_p [lindex $flist $idx]
2279                 set next_diff_i [expr {$idx+1}]
2280                 return 1
2281         } else {
2282                 return 0
2283         }
2284 }
2285
2286 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2287         global current_diff_path
2288
2289         if {$path ne $current_diff_path} {
2290                 return {}
2291         } elseif {[find_next_diff $w $path $lno $mmask]} {
2292                 return {next_diff;}
2293         } else {
2294                 return {reshow_diff;}
2295         }
2296 }
2297
2298 proc select_first_diff {after} {
2299         global ui_workdir
2300
2301         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2302             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2303                 next_diff $after
2304         } else {
2305                 uplevel #0 $after
2306         }
2307 }
2308
2309 proc force_first_diff {after} {
2310         global ui_workdir current_diff_path file_states
2311
2312         if {[info exists file_states($current_diff_path)]} {
2313                 set state [lindex $file_states($current_diff_path) 0]
2314         } else {
2315                 set state {OO}
2316         }
2317
2318         set reselect 0
2319         if {[string first {U} $state] >= 0} {
2320                 # Already a conflict, do nothing
2321         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2322                 set reselect 1
2323         } elseif {[string index $state 1] ne {O}} {
2324                 # Already a diff & no conflicts, do nothing
2325         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2326                 set reselect 1
2327         }
2328
2329         if {$reselect} {
2330                 next_diff $after
2331         } else {
2332                 uplevel #0 $after
2333         }
2334 }
2335
2336 proc toggle_or_diff {w x y} {
2337         global file_states file_lists current_diff_path ui_index ui_workdir
2338         global last_clicked selected_paths
2339
2340         set pos [split [$w index @$x,$y] .]
2341         set lno [lindex $pos 0]
2342         set col [lindex $pos 1]
2343         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2344         if {$path eq {}} {
2345                 set last_clicked {}
2346                 return
2347         }
2348
2349         set last_clicked [list $w $lno]
2350         array unset selected_paths
2351         $ui_index tag remove in_sel 0.0 end
2352         $ui_workdir tag remove in_sel 0.0 end
2353
2354         # Determine the state of the file
2355         if {[info exists file_states($path)]} {
2356                 set state [lindex $file_states($path) 0]
2357         } else {
2358                 set state {__}
2359         }
2360
2361         # Restage the file, or simply show the diff
2362         if {$col == 0 && $y > 1} {
2363                 # Conflicts need special handling
2364                 if {[string first {U} $state] >= 0} {
2365                         # $w must always be $ui_workdir, but...
2366                         if {$w ne $ui_workdir} { set lno {} }
2367                         merge_stage_workdir $path $lno
2368                         return
2369                 }
2370
2371                 if {[string index $state 1] eq {O}} {
2372                         set mmask {}
2373                 } else {
2374                         set mmask {[^O]}
2375                 }
2376
2377                 set after [next_diff_after_action $w $path $lno $mmask]
2378
2379                 if {$w eq $ui_index} {
2380                         update_indexinfo \
2381                                 "Unstaging [short_path $path] from commit" \
2382                                 [list $path] \
2383                                 [concat $after [list ui_ready]]
2384                 } elseif {$w eq $ui_workdir} {
2385                         update_index \
2386                                 "Adding [short_path $path]" \
2387                                 [list $path] \
2388                                 [concat $after [list ui_ready]]
2389                 }
2390         } else {
2391                 show_diff $path $w $lno
2392         }
2393 }
2394
2395 proc add_one_to_selection {w x y} {
2396         global file_lists last_clicked selected_paths
2397
2398         set lno [lindex [split [$w index @$x,$y] .] 0]
2399         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2400         if {$path eq {}} {
2401                 set last_clicked {}
2402                 return
2403         }
2404
2405         if {$last_clicked ne {}
2406                 && [lindex $last_clicked 0] ne $w} {
2407                 array unset selected_paths
2408                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2409         }
2410
2411         set last_clicked [list $w $lno]
2412         if {[catch {set in_sel $selected_paths($path)}]} {
2413                 set in_sel 0
2414         }
2415         if {$in_sel} {
2416                 unset selected_paths($path)
2417                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2418         } else {
2419                 set selected_paths($path) 1
2420                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2421         }
2422 }
2423
2424 proc add_range_to_selection {w x y} {
2425         global file_lists last_clicked selected_paths
2426
2427         if {[lindex $last_clicked 0] ne $w} {
2428                 toggle_or_diff $w $x $y
2429                 return
2430         }
2431
2432         set lno [lindex [split [$w index @$x,$y] .] 0]
2433         set lc [lindex $last_clicked 1]
2434         if {$lc < $lno} {
2435                 set begin $lc
2436                 set end $lno
2437         } else {
2438                 set begin $lno
2439                 set end $lc
2440         }
2441
2442         foreach path [lrange $file_lists($w) \
2443                 [expr {$begin - 1}] \
2444                 [expr {$end - 1}]] {
2445                 set selected_paths($path) 1
2446         }
2447         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2448 }
2449
2450 proc show_more_context {} {
2451         global repo_config
2452         if {$repo_config(gui.diffcontext) < 99} {
2453                 incr repo_config(gui.diffcontext)
2454                 reshow_diff
2455         }
2456 }
2457
2458 proc show_less_context {} {
2459         global repo_config
2460         if {$repo_config(gui.diffcontext) > 1} {
2461                 incr repo_config(gui.diffcontext) -1
2462                 reshow_diff
2463         }
2464 }
2465
2466 ######################################################################
2467 ##
2468 ## ui construction
2469
2470 set ui_comm {}
2471
2472 # -- Menu Bar
2473 #
2474 menu .mbar -tearoff 0
2475 if {[is_MacOSX]} {
2476         # -- Apple Menu (Mac OS X only)
2477         #
2478         .mbar add cascade -label Apple -menu .mbar.apple
2479         menu .mbar.apple
2480 }
2481 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2482 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2483 if {[is_enabled branch]} {
2484         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2485 }
2486 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2487         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2488 }
2489 if {[is_enabled transport]} {
2490         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2491         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2492 }
2493 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2494         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2495 }
2496
2497 # -- Repository Menu
2498 #
2499 menu .mbar.repository
2500
2501 if {![is_bare]} {
2502         .mbar.repository add command \
2503                 -label [mc "Explore Working Copy"] \
2504                 -command {do_explore}
2505         .mbar.repository add separator
2506 }
2507
2508 .mbar.repository add command \
2509         -label [mc "Browse Current Branch's Files"] \
2510         -command {browser::new $current_branch}
2511 set ui_browse_current [.mbar.repository index last]
2512 .mbar.repository add command \
2513         -label [mc "Browse Branch Files..."] \
2514         -command browser_open::dialog
2515 .mbar.repository add separator
2516
2517 .mbar.repository add command \
2518         -label [mc "Visualize Current Branch's History"] \
2519         -command {do_gitk $current_branch}
2520 set ui_visualize_current [.mbar.repository index last]
2521 .mbar.repository add command \
2522         -label [mc "Visualize All Branch History"] \
2523         -command {do_gitk --all}
2524 .mbar.repository add separator
2525
2526 proc current_branch_write {args} {
2527         global current_branch
2528         .mbar.repository entryconf $::ui_browse_current \
2529                 -label [mc "Browse %s's Files" $current_branch]
2530         .mbar.repository entryconf $::ui_visualize_current \
2531                 -label [mc "Visualize %s's History" $current_branch]
2532 }
2533 trace add variable current_branch write current_branch_write
2534
2535 if {[is_enabled multicommit]} {
2536         .mbar.repository add command -label [mc "Database Statistics"] \
2537                 -command do_stats
2538
2539         .mbar.repository add command -label [mc "Compress Database"] \
2540                 -command do_gc
2541
2542         .mbar.repository add command -label [mc "Verify Database"] \
2543                 -command do_fsck_objects
2544
2545         .mbar.repository add separator
2546
2547         if {[is_Cygwin]} {
2548                 .mbar.repository add command \
2549                         -label [mc "Create Desktop Icon"] \
2550                         -command do_cygwin_shortcut
2551         } elseif {[is_Windows]} {
2552                 .mbar.repository add command \
2553                         -label [mc "Create Desktop Icon"] \
2554                         -command do_windows_shortcut
2555         } elseif {[is_MacOSX]} {
2556                 .mbar.repository add command \
2557                         -label [mc "Create Desktop Icon"] \
2558                         -command do_macosx_app
2559         }
2560 }
2561
2562 if {[is_MacOSX]} {
2563         proc ::tk::mac::Quit {args} { do_quit }
2564 } else {
2565         .mbar.repository add command -label [mc Quit] \
2566                 -command do_quit \
2567                 -accelerator $M1T-Q
2568 }
2569
2570 # -- Edit Menu
2571 #
2572 menu .mbar.edit
2573 .mbar.edit add command -label [mc Undo] \
2574         -command {catch {[focus] edit undo}} \
2575         -accelerator $M1T-Z
2576 .mbar.edit add command -label [mc Redo] \
2577         -command {catch {[focus] edit redo}} \
2578         -accelerator $M1T-Y
2579 .mbar.edit add separator
2580 .mbar.edit add command -label [mc Cut] \
2581         -command {catch {tk_textCut [focus]}} \
2582         -accelerator $M1T-X
2583 .mbar.edit add command -label [mc Copy] \
2584         -command {catch {tk_textCopy [focus]}} \
2585         -accelerator $M1T-C
2586 .mbar.edit add command -label [mc Paste] \
2587         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2588         -accelerator $M1T-V
2589 .mbar.edit add command -label [mc Delete] \
2590         -command {catch {[focus] delete sel.first sel.last}} \
2591         -accelerator Del
2592 .mbar.edit add separator
2593 .mbar.edit add command -label [mc "Select All"] \
2594         -command {catch {[focus] tag add sel 0.0 end}} \
2595         -accelerator $M1T-A
2596
2597 # -- Branch Menu
2598 #
2599 if {[is_enabled branch]} {
2600         menu .mbar.branch
2601
2602         .mbar.branch add command -label [mc "Create..."] \
2603                 -command branch_create::dialog \
2604                 -accelerator $M1T-N
2605         lappend disable_on_lock [list .mbar.branch entryconf \
2606                 [.mbar.branch index last] -state]
2607
2608         .mbar.branch add command -label [mc "Checkout..."] \
2609                 -command branch_checkout::dialog \
2610                 -accelerator $M1T-O
2611         lappend disable_on_lock [list .mbar.branch entryconf \
2612                 [.mbar.branch index last] -state]
2613
2614         .mbar.branch add command -label [mc "Rename..."] \
2615                 -command branch_rename::dialog
2616         lappend disable_on_lock [list .mbar.branch entryconf \
2617                 [.mbar.branch index last] -state]
2618
2619         .mbar.branch add command -label [mc "Delete..."] \
2620                 -command branch_delete::dialog
2621         lappend disable_on_lock [list .mbar.branch entryconf \
2622                 [.mbar.branch index last] -state]
2623
2624         .mbar.branch add command -label [mc "Reset..."] \
2625                 -command merge::reset_hard
2626         lappend disable_on_lock [list .mbar.branch entryconf \
2627                 [.mbar.branch index last] -state]
2628 }
2629
2630 # -- Commit Menu
2631 #
2632 proc commit_btn_caption {} {
2633         if {[is_enabled nocommit]} {
2634                 return [mc "Done"]
2635         } else {
2636                 return [mc Commit@@verb]
2637         }
2638 }
2639
2640 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2641         menu .mbar.commit
2642
2643         if {![is_enabled nocommit]} {
2644                 .mbar.commit add radiobutton \
2645                         -label [mc "New Commit"] \
2646                         -command do_select_commit_type \
2647                         -variable selected_commit_type \
2648                         -value new
2649                 lappend disable_on_lock \
2650                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2651
2652                 .mbar.commit add radiobutton \
2653                         -label [mc "Amend Last Commit"] \
2654                         -command do_select_commit_type \
2655                         -variable selected_commit_type \
2656                         -value amend
2657                 lappend disable_on_lock \
2658                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2659
2660                 .mbar.commit add separator
2661         }
2662
2663         .mbar.commit add command -label [mc Rescan] \
2664                 -command ui_do_rescan \
2665                 -accelerator F5
2666         lappend disable_on_lock \
2667                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2668
2669         .mbar.commit add command -label [mc "Stage To Commit"] \
2670                 -command do_add_selection \
2671                 -accelerator $M1T-T
2672         lappend disable_on_lock \
2673                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2674
2675         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2676                 -command do_add_all \
2677                 -accelerator $M1T-I
2678         lappend disable_on_lock \
2679                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2680
2681         .mbar.commit add command -label [mc "Unstage From Commit"] \
2682                 -command do_unstage_selection \
2683                 -accelerator $M1T-U
2684         lappend disable_on_lock \
2685                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2686
2687         .mbar.commit add command -label [mc "Revert Changes"] \
2688                 -command do_revert_selection \
2689                 -accelerator $M1T-J
2690         lappend disable_on_lock \
2691                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2692
2693         .mbar.commit add separator
2694
2695         .mbar.commit add command -label [mc "Show Less Context"] \
2696                 -command show_less_context \
2697                 -accelerator $M1T-\-
2698
2699         .mbar.commit add command -label [mc "Show More Context"] \
2700                 -command show_more_context \
2701                 -accelerator $M1T-=
2702
2703         .mbar.commit add separator
2704
2705         if {![is_enabled nocommitmsg]} {
2706                 .mbar.commit add command -label [mc "Sign Off"] \
2707                         -command do_signoff \
2708                         -accelerator $M1T-S
2709         }
2710
2711         .mbar.commit add command -label [commit_btn_caption] \
2712                 -command do_commit \
2713                 -accelerator $M1T-Return
2714         lappend disable_on_lock \
2715                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2716 }
2717
2718 # -- Merge Menu
2719 #
2720 if {[is_enabled branch]} {
2721         menu .mbar.merge
2722         .mbar.merge add command -label [mc "Local Merge..."] \
2723                 -command merge::dialog \
2724                 -accelerator $M1T-M
2725         lappend disable_on_lock \
2726                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2727         .mbar.merge add command -label [mc "Abort Merge..."] \
2728                 -command merge::reset_hard
2729         lappend disable_on_lock \
2730                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2731 }
2732
2733 # -- Transport Menu
2734 #
2735 if {[is_enabled transport]} {
2736         menu .mbar.remote
2737
2738         .mbar.remote add command \
2739                 -label [mc "Add..."] \
2740                 -command remote_add::dialog \
2741                 -accelerator $M1T-A
2742         .mbar.remote add command \
2743                 -label [mc "Push..."] \
2744                 -command do_push_anywhere \
2745                 -accelerator $M1T-P
2746         .mbar.remote add command \
2747                 -label [mc "Delete Branch..."] \
2748                 -command remote_branch_delete::dialog
2749 }
2750
2751 if {[is_MacOSX]} {
2752         proc ::tk::mac::ShowPreferences {} {do_options}
2753 } else {
2754         # -- Edit Menu
2755         #
2756         .mbar.edit add separator
2757         .mbar.edit add command -label [mc "Options..."] \
2758                 -command do_options
2759 }
2760
2761 # -- Tools Menu
2762 #
2763 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2764         set tools_menubar .mbar.tools
2765         menu $tools_menubar
2766         $tools_menubar add separator
2767         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2768         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2769         set tools_tailcnt 3
2770         if {[array names repo_config guitool.*.cmd] ne {}} {
2771                 tools_populate_all
2772         }
2773 }
2774
2775 # -- Help Menu
2776 #
2777 .mbar add cascade -label [mc Help] -menu .mbar.help
2778 menu .mbar.help
2779
2780 if {[is_MacOSX]} {
2781         .mbar.apple add command -label [mc "About %s" [appname]] \
2782                 -command do_about
2783         .mbar.apple add separator
2784 } else {
2785         .mbar.help add command -label [mc "About %s" [appname]] \
2786                 -command do_about
2787 }
2788 . configure -menu .mbar
2789
2790 set doc_path [githtmldir]
2791 if {$doc_path ne {}} {
2792         set doc_path [file join $doc_path index.html]
2793
2794         if {[is_Cygwin]} {
2795                 set doc_path [exec cygpath --mixed $doc_path]
2796         }
2797 }
2798
2799 if {[file isfile $doc_path]} {
2800         set doc_url "file:$doc_path"
2801 } else {
2802         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2803 }
2804
2805 proc start_browser {url} {
2806         git "web--browse" $url
2807 }
2808
2809 .mbar.help add command -label [mc "Online Documentation"] \
2810         -command [list start_browser $doc_url]
2811
2812 .mbar.help add command -label [mc "Show SSH Key"] \
2813         -command do_ssh_key
2814
2815 unset doc_path doc_url
2816
2817 # -- Standard bindings
2818 #
2819 wm protocol . WM_DELETE_WINDOW do_quit
2820 bind all <$M1B-Key-q> do_quit
2821 bind all <$M1B-Key-Q> do_quit
2822 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2823 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2824
2825 set subcommand_args {}
2826 proc usage {} {
2827         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
2828         exit 1
2829 }
2830
2831 proc normalize_relpath {path} {
2832         set elements {}
2833         foreach item [file split $path] {
2834                 if {$item eq {.}} continue
2835                 if {$item eq {..} && [llength $elements] > 0
2836                     && [lindex $elements end] ne {..}} {
2837                         set elements [lrange $elements 0 end-1]
2838                         continue
2839                 }
2840                 lappend elements $item
2841         }
2842         return [eval file join $elements]
2843 }
2844
2845 # -- Not a normal commit type invocation?  Do that instead!
2846 #
2847 switch -- $subcommand {
2848 browser -
2849 blame {
2850         if {$subcommand eq "blame"} {
2851                 set subcommand_args {[--line=<num>] rev? path}
2852         } else {
2853                 set subcommand_args {rev? path}
2854         }
2855         if {$argv eq {}} usage
2856         set head {}
2857         set path {}
2858         set jump_spec {}
2859         set is_path 0
2860         foreach a $argv {
2861                 if {$is_path || [file exists $_prefix$a]} {
2862                         if {$path ne {}} usage
2863                         set path [normalize_relpath $_prefix$a]
2864                         break
2865                 } elseif {$a eq {--}} {
2866                         if {$path ne {}} {
2867                                 if {$head ne {}} usage
2868                                 set head $path
2869                                 set path {}
2870                         }
2871                         set is_path 1
2872                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2873                         if {$jump_spec ne {} || $head ne {}} usage
2874                         set jump_spec [list $lnum]
2875                 } elseif {$head eq {}} {
2876                         if {$head ne {}} usage
2877                         set head $a
2878                         set is_path 1
2879                 } else {
2880                         usage
2881                 }
2882         }
2883         unset is_path
2884
2885         if {$head ne {} && $path eq {}} {
2886                 set path [normalize_relpath $_prefix$head]
2887                 set head {}
2888         }
2889
2890         if {$head eq {}} {
2891                 load_current_branch
2892         } else {
2893                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2894                         if {[catch {
2895                                         set head [git rev-parse --verify $head]
2896                                 } err]} {
2897                                 puts stderr $err
2898                                 exit 1
2899                         }
2900                 }
2901                 set current_branch $head
2902         }
2903
2904         switch -- $subcommand {
2905         browser {
2906                 if {$jump_spec ne {}} usage
2907                 if {$head eq {}} {
2908                         if {$path ne {} && [file isdirectory $path]} {
2909                                 set head $current_branch
2910                         } else {
2911                                 set head $path
2912                                 set path {}
2913                         }
2914                 }
2915                 browser::new $head $path
2916         }
2917         blame   {
2918                 if {$head eq {} && ![file exists $path]} {
2919                         puts stderr [mc "fatal: cannot stat path %s: No such file or directory" $path]
2920                         exit 1
2921                 }
2922                 blame::new $head $path $jump_spec
2923         }
2924         }
2925         return
2926 }
2927 citool -
2928 gui {
2929         if {[llength $argv] != 0} {
2930                 puts -nonewline stderr "usage: $argv0"
2931                 if {$subcommand ne {gui}
2932                         && [file tail $argv0] ne "git-$subcommand"} {
2933                         puts -nonewline stderr " $subcommand"
2934                 }
2935                 puts stderr {}
2936                 exit 1
2937         }
2938         # fall through to setup UI for commits
2939 }
2940 default {
2941         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
2942         exit 1
2943 }
2944 }
2945
2946 # -- Branch Control
2947 #
2948 ${NS}::frame .branch
2949 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
2950 ${NS}::label .branch.l1 \
2951         -text [mc "Current Branch:"] \
2952         -anchor w \
2953         -justify left
2954 ${NS}::label .branch.cb \
2955         -textvariable current_branch \
2956         -anchor w \
2957         -justify left
2958 pack .branch.l1 -side left
2959 pack .branch.cb -side left -fill x
2960 pack .branch -side top -fill x
2961
2962 # -- Main Window Layout
2963 #
2964 ${NS}::panedwindow .vpane -orient horizontal
2965 ${NS}::panedwindow .vpane.files -orient vertical
2966 if {$use_ttk} {
2967         .vpane add .vpane.files
2968 } else {
2969         .vpane add .vpane.files -sticky nsew -height 100 -width 200
2970 }
2971 pack .vpane -anchor n -side top -fill both -expand 1
2972
2973 # -- Index File List
2974 #
2975 ${NS}::frame .vpane.files.index -height 100 -width 200
2976 tlabel .vpane.files.index.title \
2977         -text [mc "Staged Changes (Will Commit)"] \
2978         -background lightgreen -foreground black
2979 text $ui_index -background white -foreground black \
2980         -borderwidth 0 \
2981         -width 20 -height 10 \
2982         -wrap none \
2983         -cursor $cursor_ptr \
2984         -xscrollcommand {.vpane.files.index.sx set} \
2985         -yscrollcommand {.vpane.files.index.sy set} \
2986         -state disabled
2987 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
2988 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
2989 pack .vpane.files.index.title -side top -fill x
2990 pack .vpane.files.index.sx -side bottom -fill x
2991 pack .vpane.files.index.sy -side right -fill y
2992 pack $ui_index -side left -fill both -expand 1
2993
2994 # -- Working Directory File List
2995 #
2996 ${NS}::frame .vpane.files.workdir -height 100 -width 200
2997 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
2998         -background lightsalmon -foreground black
2999 text $ui_workdir -background white -foreground black \
3000         -borderwidth 0 \
3001         -width 20 -height 10 \
3002         -wrap none \
3003         -cursor $cursor_ptr \
3004         -xscrollcommand {.vpane.files.workdir.sx set} \
3005         -yscrollcommand {.vpane.files.workdir.sy set} \
3006         -state disabled
3007 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3008 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3009 pack .vpane.files.workdir.title -side top -fill x
3010 pack .vpane.files.workdir.sx -side bottom -fill x
3011 pack .vpane.files.workdir.sy -side right -fill y
3012 pack $ui_workdir -side left -fill both -expand 1
3013
3014 .vpane.files add .vpane.files.workdir
3015 .vpane.files add .vpane.files.index
3016 if {!$use_ttk} {
3017         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3018         .vpane.files paneconfigure .vpane.files.index -sticky news
3019 }
3020
3021 foreach i [list $ui_index $ui_workdir] {
3022         rmsel_tag $i
3023         $i tag conf in_diff -background [$i tag cget in_sel -background]
3024 }
3025 unset i
3026
3027 # -- Diff and Commit Area
3028 #
3029 ${NS}::frame .vpane.lower -height 300 -width 400
3030 ${NS}::frame .vpane.lower.commarea
3031 ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1
3032 pack .vpane.lower.diff -fill both -expand 1
3033 pack .vpane.lower.commarea -side bottom -fill x
3034 .vpane add .vpane.lower
3035 if {!$use_ttk} {.vpane paneconfigure .vpane.lower -sticky nsew}
3036
3037 # -- Commit Area Buttons
3038 #
3039 ${NS}::frame .vpane.lower.commarea.buttons
3040 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3041         -anchor w \
3042         -justify left
3043 pack .vpane.lower.commarea.buttons.l -side top -fill x
3044 pack .vpane.lower.commarea.buttons -side left -fill y
3045
3046 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3047         -command ui_do_rescan
3048 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3049 lappend disable_on_lock \
3050         {.vpane.lower.commarea.buttons.rescan conf -state}
3051
3052 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3053         -command do_add_all
3054 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3055 lappend disable_on_lock \
3056         {.vpane.lower.commarea.buttons.incall conf -state}
3057
3058 if {![is_enabled nocommitmsg]} {
3059         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3060                 -command do_signoff
3061         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3062 }
3063
3064 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3065         -command do_commit
3066 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3067 lappend disable_on_lock \
3068         {.vpane.lower.commarea.buttons.commit conf -state}
3069
3070 if {![is_enabled nocommit]} {
3071         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3072                 -command do_push_anywhere
3073         pack .vpane.lower.commarea.buttons.push -side top -fill x
3074 }
3075
3076 # -- Commit Message Buffer
3077 #
3078 ${NS}::frame .vpane.lower.commarea.buffer
3079 ${NS}::frame .vpane.lower.commarea.buffer.header
3080 set ui_comm .vpane.lower.commarea.buffer.t
3081 set ui_coml .vpane.lower.commarea.buffer.header.l
3082
3083 if {![is_enabled nocommit]} {
3084         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3085                 -text [mc "New Commit"] \
3086                 -command do_select_commit_type \
3087                 -variable selected_commit_type \
3088                 -value new
3089         lappend disable_on_lock \
3090                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3091         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3092                 -text [mc "Amend Last Commit"] \
3093                 -command do_select_commit_type \
3094                 -variable selected_commit_type \
3095                 -value amend
3096         lappend disable_on_lock \
3097                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3098 }
3099
3100 ${NS}::label $ui_coml \
3101         -anchor w \
3102         -justify left
3103 proc trace_commit_type {varname args} {
3104         global ui_coml commit_type
3105         switch -glob -- $commit_type {
3106         initial       {set txt [mc "Initial Commit Message:"]}
3107         amend         {set txt [mc "Amended Commit Message:"]}
3108         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3109         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3110         merge         {set txt [mc "Merge Commit Message:"]}
3111         *             {set txt [mc "Commit Message:"]}
3112         }
3113         $ui_coml conf -text $txt
3114 }
3115 trace add variable commit_type write trace_commit_type
3116 pack $ui_coml -side left -fill x
3117
3118 if {![is_enabled nocommit]} {
3119         pack .vpane.lower.commarea.buffer.header.amend -side right
3120         pack .vpane.lower.commarea.buffer.header.new -side right
3121 }
3122
3123 text $ui_comm -background white -foreground black \
3124         -borderwidth 1 \
3125         -undo true \
3126         -maxundo 20 \
3127         -autoseparators true \
3128         -relief sunken \
3129         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3130         -font font_diff \
3131         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3132 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3133         -command [list $ui_comm yview]
3134 pack .vpane.lower.commarea.buffer.header -side top -fill x
3135 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3136 pack $ui_comm -side left -fill y
3137 pack .vpane.lower.commarea.buffer -side left -fill y
3138
3139 # -- Commit Message Buffer Context Menu
3140 #
3141 set ctxm .vpane.lower.commarea.buffer.ctxm
3142 menu $ctxm -tearoff 0
3143 $ctxm add command \
3144         -label [mc Cut] \
3145         -command {tk_textCut $ui_comm}
3146 $ctxm add command \
3147         -label [mc Copy] \
3148         -command {tk_textCopy $ui_comm}
3149 $ctxm add command \
3150         -label [mc Paste] \
3151         -command {tk_textPaste $ui_comm}
3152 $ctxm add command \
3153         -label [mc Delete] \
3154         -command {catch {$ui_comm delete sel.first sel.last}}
3155 $ctxm add separator
3156 $ctxm add command \
3157         -label [mc "Select All"] \
3158         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3159 $ctxm add command \
3160         -label [mc "Copy All"] \
3161         -command {
3162                 $ui_comm tag add sel 0.0 end
3163                 tk_textCopy $ui_comm
3164                 $ui_comm tag remove sel 0.0 end
3165         }
3166 $ctxm add separator
3167 $ctxm add command \
3168         -label [mc "Sign Off"] \
3169         -command do_signoff
3170 set ui_comm_ctxm $ctxm
3171
3172 # -- Diff Header
3173 #
3174 proc trace_current_diff_path {varname args} {
3175         global current_diff_path diff_actions file_states
3176         if {$current_diff_path eq {}} {
3177                 set s {}
3178                 set f {}
3179                 set p {}
3180                 set o disabled
3181         } else {
3182                 set p $current_diff_path
3183                 set s [mapdesc [lindex $file_states($p) 0] $p]
3184                 set f [mc "File:"]
3185                 set p [escape_path $p]
3186                 set o normal
3187         }
3188
3189         .vpane.lower.diff.header.status configure -text $s
3190         .vpane.lower.diff.header.file configure -text $f
3191         .vpane.lower.diff.header.path configure -text $p
3192         foreach w $diff_actions {
3193                 uplevel #0 $w $o
3194         }
3195 }
3196 trace add variable current_diff_path write trace_current_diff_path
3197
3198 gold_frame .vpane.lower.diff.header
3199 tlabel .vpane.lower.diff.header.status \
3200         -background gold \
3201         -foreground black \
3202         -width $max_status_desc \
3203         -anchor w \
3204         -justify left
3205 tlabel .vpane.lower.diff.header.file \
3206         -background gold \
3207         -foreground black \
3208         -anchor w \
3209         -justify left
3210 tlabel .vpane.lower.diff.header.path \
3211         -background gold \
3212         -foreground black \
3213         -anchor w \
3214         -justify left
3215 pack .vpane.lower.diff.header.status -side left
3216 pack .vpane.lower.diff.header.file -side left
3217 pack .vpane.lower.diff.header.path -fill x
3218 set ctxm .vpane.lower.diff.header.ctxm
3219 menu $ctxm -tearoff 0
3220 $ctxm add command \
3221         -label [mc Copy] \
3222         -command {
3223                 clipboard clear
3224                 clipboard append \
3225                         -format STRING \
3226                         -type STRING \
3227                         -- $current_diff_path
3228         }
3229 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3230 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3231
3232 # -- Diff Body
3233 #
3234 ${NS}::frame .vpane.lower.diff.body
3235 set ui_diff .vpane.lower.diff.body.t
3236 text $ui_diff -background white -foreground black \
3237         -borderwidth 0 \
3238         -width 80 -height 5 -wrap none \
3239         -font font_diff \
3240         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3241         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3242         -state disabled
3243 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3244         -command [list $ui_diff xview]
3245 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3246         -command [list $ui_diff yview]
3247 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3248 pack .vpane.lower.diff.body.sby -side right -fill y
3249 pack $ui_diff -side left -fill both -expand 1
3250 pack .vpane.lower.diff.header -side top -fill x
3251 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3252
3253 $ui_diff tag conf d_cr -elide true
3254 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
3255 $ui_diff tag conf d_+ -foreground {#00a000}
3256 $ui_diff tag conf d_- -foreground red
3257
3258 $ui_diff tag conf d_++ -foreground {#00a000}
3259 $ui_diff tag conf d_-- -foreground red
3260 $ui_diff tag conf d_+s \
3261         -foreground {#00a000} \
3262         -background {#e2effa}
3263 $ui_diff tag conf d_-s \
3264         -foreground red \
3265         -background {#e2effa}
3266 $ui_diff tag conf d_s+ \
3267         -foreground {#00a000} \
3268         -background ivory1
3269 $ui_diff tag conf d_s- \
3270         -foreground red \
3271         -background ivory1
3272
3273 $ui_diff tag conf d<<<<<<< \
3274         -foreground orange \
3275         -font font_diffbold
3276 $ui_diff tag conf d======= \
3277         -foreground orange \
3278         -font font_diffbold
3279 $ui_diff tag conf d>>>>>>> \
3280         -foreground orange \
3281         -font font_diffbold
3282
3283 $ui_diff tag raise sel
3284
3285 # -- Diff Body Context Menu
3286 #
3287
3288 proc create_common_diff_popup {ctxm} {
3289         $ctxm add command \
3290                 -label [mc Refresh] \
3291                 -command reshow_diff
3292         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3293         $ctxm add command \
3294                 -label [mc Copy] \
3295                 -command {tk_textCopy $ui_diff}
3296         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3297         $ctxm add command \
3298                 -label [mc "Select All"] \
3299                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3300         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3301         $ctxm add command \
3302                 -label [mc "Copy All"] \
3303                 -command {
3304                         $ui_diff tag add sel 0.0 end
3305                         tk_textCopy $ui_diff
3306                         $ui_diff tag remove sel 0.0 end
3307                 }
3308         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3309         $ctxm add separator
3310         $ctxm add command \
3311                 -label [mc "Decrease Font Size"] \
3312                 -command {incr_font_size font_diff -1}
3313         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3314         $ctxm add command \
3315                 -label [mc "Increase Font Size"] \
3316                 -command {incr_font_size font_diff 1}
3317         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3318         $ctxm add separator
3319         set emenu $ctxm.enc
3320         menu $emenu
3321         build_encoding_menu $emenu [list force_diff_encoding]
3322         $ctxm add cascade \
3323                 -label [mc "Encoding"] \
3324                 -menu $emenu
3325         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3326         $ctxm add separator
3327         $ctxm add command -label [mc "Options..."] \
3328                 -command do_options
3329 }
3330
3331 set ctxm .vpane.lower.diff.body.ctxm
3332 menu $ctxm -tearoff 0
3333 $ctxm add command \
3334         -label [mc "Apply/Reverse Hunk"] \
3335         -command {apply_hunk $cursorX $cursorY}
3336 set ui_diff_applyhunk [$ctxm index last]
3337 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3338 $ctxm add command \
3339         -label [mc "Apply/Reverse Line"] \
3340         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3341 set ui_diff_applyline [$ctxm index last]
3342 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3343 $ctxm add separator
3344 $ctxm add command \
3345         -label [mc "Show Less Context"] \
3346         -command show_less_context
3347 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3348 $ctxm add command \
3349         -label [mc "Show More Context"] \
3350         -command show_more_context
3351 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3352 $ctxm add separator
3353 create_common_diff_popup $ctxm
3354
3355 set ctxmmg .vpane.lower.diff.body.ctxmmg
3356 menu $ctxmmg -tearoff 0
3357 $ctxmmg add command \
3358         -label [mc "Run Merge Tool"] \
3359         -command {merge_resolve_tool}
3360 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3361 $ctxmmg add separator
3362 $ctxmmg add command \
3363         -label [mc "Use Remote Version"] \
3364         -command {merge_resolve_one 3}
3365 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3366 $ctxmmg add command \
3367         -label [mc "Use Local Version"] \
3368         -command {merge_resolve_one 2}
3369 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3370 $ctxmmg add command \
3371         -label [mc "Revert To Base"] \
3372         -command {merge_resolve_one 1}
3373 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3374 $ctxmmg add separator
3375 $ctxmmg add command \
3376         -label [mc "Show Less Context"] \
3377         -command show_less_context
3378 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3379 $ctxmmg add command \
3380         -label [mc "Show More Context"] \
3381         -command show_more_context
3382 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3383 $ctxmmg add separator
3384 create_common_diff_popup $ctxmmg
3385
3386 set ctxmsm .vpane.lower.diff.body.ctxmsm
3387 menu $ctxmsm -tearoff 0
3388 $ctxmsm add command \
3389         -label [mc "Visualize These Changes In The Submodule"] \
3390         -command {do_gitk -- true}
3391 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3392 $ctxmsm add command \
3393         -label [mc "Visualize Current Branch History In The Submodule"] \
3394         -command {do_gitk {} true}
3395 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3396 $ctxmsm add command \
3397         -label [mc "Visualize All Branch History In The Submodule"] \
3398         -command {do_gitk --all true}
3399 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3400 $ctxmsm add separator
3401 $ctxmsm add command \
3402         -label [mc "Start git gui In The Submodule"] \
3403         -command {do_git_gui}
3404 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3405 $ctxmsm add separator
3406 create_common_diff_popup $ctxmsm
3407
3408 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3409         global current_diff_path file_states
3410         set ::cursorX $x
3411         set ::cursorY $y
3412         if {[info exists file_states($current_diff_path)]} {
3413                 set state [lindex $file_states($current_diff_path) 0]
3414         } else {
3415                 set state {__}
3416         }
3417         if {[string first {U} $state] >= 0} {
3418                 tk_popup $ctxmmg $X $Y
3419         } elseif {$::is_submodule_diff} {
3420                 tk_popup $ctxmsm $X $Y
3421         } else {
3422                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3423                 if {$::ui_index eq $::current_diff_side} {
3424                         set l [mc "Unstage Hunk From Commit"]
3425                         if {$has_range} {
3426                                 set t [mc "Unstage Lines From Commit"]
3427                         } else {
3428                                 set t [mc "Unstage Line From Commit"]
3429                         }
3430                 } else {
3431                         set l [mc "Stage Hunk For Commit"]
3432                         if {$has_range} {
3433                                 set t [mc "Stage Lines For Commit"]
3434                         } else {
3435                                 set t [mc "Stage Line For Commit"]
3436                         }
3437                 }
3438                 if {$::is_3way_diff
3439                         || $current_diff_path eq {}
3440                         || {__} eq $state
3441                         || {_O} eq $state
3442                         || {_T} eq $state
3443                         || {T_} eq $state} {
3444                         set s disabled
3445                 } else {
3446                         set s normal
3447                 }
3448                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3449                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3450                 tk_popup $ctxm $X $Y
3451         }
3452 }
3453 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3454
3455 # -- Status Bar
3456 #
3457 set main_status [::status_bar::new .status]
3458 pack .status -anchor w -side bottom -fill x
3459 $main_status show [mc "Initializing..."]
3460
3461 # -- Load geometry
3462 #
3463 catch {
3464 set gm $repo_config(gui.geometry)
3465 wm geometry . [lindex $gm 0]
3466 if {$use_ttk} {
3467         .vpane sashpos 0 [lindex $gm 1]
3468         .vpane.files sashpos 0 [lindex $gm 2]
3469 } else {
3470         .vpane sash place 0 \
3471                 [lindex $gm 1] \
3472                 [lindex [.vpane sash coord 0] 1]
3473         .vpane.files sash place 0 \
3474                 [lindex [.vpane.files sash coord 0] 0] \
3475                 [lindex $gm 2]
3476 }
3477 unset gm
3478 }
3479
3480 # -- Load window state
3481 #
3482 catch {
3483 set gws $repo_config(gui.wmstate)
3484 wm state . $gws
3485 unset gws
3486 }
3487
3488 # -- Key Bindings
3489 #
3490 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3491 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3492 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3493 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3494 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3495 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3496 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3497 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3498 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3499 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3500 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3501 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3502 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3503 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3504 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3505 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3506 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3507 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3508 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3509 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3510 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3511 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3512
3513 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3514 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3515 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3516 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3517 bind $ui_diff <$M1B-Key-v> {break}
3518 bind $ui_diff <$M1B-Key-V> {break}
3519 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3520 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3521 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3522 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3523 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3524 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3525 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3526 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3527 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3528 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3529 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3530 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3531 bind $ui_diff <Button-1>   {focus %W}
3532
3533 if {[is_enabled branch]} {
3534         bind . <$M1B-Key-n> branch_create::dialog
3535         bind . <$M1B-Key-N> branch_create::dialog
3536         bind . <$M1B-Key-o> branch_checkout::dialog
3537         bind . <$M1B-Key-O> branch_checkout::dialog
3538         bind . <$M1B-Key-m> merge::dialog
3539         bind . <$M1B-Key-M> merge::dialog
3540 }
3541 if {[is_enabled transport]} {
3542         bind . <$M1B-Key-p> do_push_anywhere
3543         bind . <$M1B-Key-P> do_push_anywhere
3544 }
3545
3546 bind .   <Key-F5>     ui_do_rescan
3547 bind .   <$M1B-Key-r> ui_do_rescan
3548 bind .   <$M1B-Key-R> ui_do_rescan
3549 bind .   <$M1B-Key-s> do_signoff
3550 bind .   <$M1B-Key-S> do_signoff
3551 bind .   <$M1B-Key-t> do_add_selection
3552 bind .   <$M1B-Key-T> do_add_selection
3553 bind .   <$M1B-Key-j> do_revert_selection
3554 bind .   <$M1B-Key-J> do_revert_selection
3555 bind .   <$M1B-Key-i> do_add_all
3556 bind .   <$M1B-Key-I> do_add_all
3557 bind .   <$M1B-Key-minus> {show_less_context;break}
3558 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3559 bind .   <$M1B-Key-equal> {show_more_context;break}
3560 bind .   <$M1B-Key-plus> {show_more_context;break}
3561 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3562 bind .   <$M1B-Key-Return> do_commit
3563 foreach i [list $ui_index $ui_workdir] {
3564         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3565         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3566         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3567 }
3568 unset i
3569
3570 set file_lists($ui_index) [list]
3571 set file_lists($ui_workdir) [list]
3572
3573 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3574 focus -force $ui_comm
3575
3576 # -- Warn the user about environmental problems.  Cygwin's Tcl
3577 #    does *not* pass its env array onto any processes it spawns.
3578 #    This means that git processes get none of our environment.
3579 #
3580 if {[is_Cygwin]} {
3581         set ignored_env 0
3582         set suggest_user {}
3583         set msg [mc "Possible environment issues exist.
3584
3585 The following environment variables are probably
3586 going to be ignored by any Git subprocess run
3587 by %s:
3588
3589 " [appname]]
3590         foreach name [array names env] {
3591                 switch -regexp -- $name {
3592                 {^GIT_INDEX_FILE$} -
3593                 {^GIT_OBJECT_DIRECTORY$} -
3594                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3595                 {^GIT_DIFF_OPTS$} -
3596                 {^GIT_EXTERNAL_DIFF$} -
3597                 {^GIT_PAGER$} -
3598                 {^GIT_TRACE$} -
3599                 {^GIT_CONFIG$} -
3600                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3601                         append msg " - $name\n"
3602                         incr ignored_env
3603                 }
3604                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3605                         append msg " - $name\n"
3606                         incr ignored_env
3607                         set suggest_user $name
3608                 }
3609                 }
3610         }
3611         if {$ignored_env > 0} {
3612                 append msg [mc "
3613 This is due to a known issue with the
3614 Tcl binary distributed by Cygwin."]
3615
3616                 if {$suggest_user ne {}} {
3617                         append msg [mc "
3618
3619 A good replacement for %s
3620 is placing values for the user.name and
3621 user.email settings into your personal
3622 ~/.gitconfig file.
3623 " $suggest_user]
3624                 }
3625                 warn_popup $msg
3626         }
3627         unset ignored_env msg suggest_user name
3628 }
3629
3630 # -- Only initialize complex UI if we are going to stay running.
3631 #
3632 if {[is_enabled transport]} {
3633         load_all_remotes
3634
3635         set n [.mbar.remote index end]
3636         populate_remotes_menu
3637         set n [expr {[.mbar.remote index end] - $n}]
3638         if {$n > 0} {
3639                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3640                 .mbar.remote insert $n separator
3641         }
3642         unset n
3643 }
3644
3645 if {[winfo exists $ui_comm]} {
3646         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3647
3648         # -- If both our backup and message files exist use the
3649         #    newer of the two files to initialize the buffer.
3650         #
3651         if {$GITGUI_BCK_exists} {
3652                 set m [gitdir GITGUI_MSG]
3653                 if {[file isfile $m]} {
3654                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3655                                 catch {file delete [gitdir GITGUI_MSG]}
3656                         } else {
3657                                 $ui_comm delete 0.0 end
3658                                 $ui_comm edit reset
3659                                 $ui_comm edit modified false
3660                                 catch {file delete [gitdir GITGUI_BCK]}
3661                                 set GITGUI_BCK_exists 0
3662                         }
3663                 }
3664                 unset m
3665         }
3666
3667         proc backup_commit_buffer {} {
3668                 global ui_comm GITGUI_BCK_exists
3669
3670                 set m [$ui_comm edit modified]
3671                 if {$m || $GITGUI_BCK_exists} {
3672                         set msg [string trim [$ui_comm get 0.0 end]]
3673                         regsub -all -line {[ \r\t]+$} $msg {} msg
3674
3675                         if {$msg eq {}} {
3676                                 if {$GITGUI_BCK_exists} {
3677                                         catch {file delete [gitdir GITGUI_BCK]}
3678                                         set GITGUI_BCK_exists 0
3679                                 }
3680                         } elseif {$m} {
3681                                 catch {
3682                                         set fd [open [gitdir GITGUI_BCK] w]
3683                                         puts -nonewline $fd $msg
3684                                         close $fd
3685                                         set GITGUI_BCK_exists 1
3686                                 }
3687                         }
3688
3689                         $ui_comm edit modified false
3690                 }
3691
3692                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3693         }
3694
3695         backup_commit_buffer
3696
3697         # -- If the user has aspell available we can drive it
3698         #    in pipe mode to spellcheck the commit message.
3699         #
3700         set spell_cmd [list |]
3701         set spell_dict [get_config gui.spellingdictionary]
3702         lappend spell_cmd aspell
3703         if {$spell_dict ne {}} {
3704                 lappend spell_cmd --master=$spell_dict
3705         }
3706         lappend spell_cmd --mode=none
3707         lappend spell_cmd --encoding=utf-8
3708         lappend spell_cmd pipe
3709         if {$spell_dict eq {none}
3710          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3711                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3712         } else {
3713                 set ui_comm_spell [spellcheck::init \
3714                         $spell_fd \
3715                         $ui_comm \
3716                         $ui_comm_ctxm \
3717                 ]
3718         }
3719         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3720 }
3721
3722 lock_index begin-read
3723 if {![winfo ismapped .]} {
3724         wm deiconify .
3725 }
3726 after 1 {
3727         if {[is_enabled initialamend]} {
3728                 force_amend
3729         } else {
3730                 do_rescan
3731         }
3732
3733         if {[is_enabled nocommitmsg]} {
3734                 $ui_comm configure -state disabled -background gray
3735         }
3736 }
3737 if {[is_enabled multicommit]} {
3738         after 1000 hint_gc
3739 }
3740 if {[is_enabled retcode]} {
3741         bind . <Destroy> {+terminate_me %W}
3742 }
3743 if {$picked && [is_config_true gui.autoexplore]} {
3744         do_explore
3745 }
3746
3747 # Local variables:
3748 # mode: tcl
3749 # indent-tabs-mode: t
3750 # tab-width: 4
3751 # End: