lib/mergetool.tcl

   1 # git-gui merge conflict resolution
   2 # parts based on git-mergetool (c) 2006 Theodore Y. Ts'o
   3
   4 proc merge_resolve_one {stage} {
   5         global current_diff_path
   6
   7         switch -- $stage {
   8                 1 { set target [mc "the base version"] }
   9                 2 { set target [mc "this branch"] }
  10                 3 { set target [mc "the other branch"] }
  11         }
  12
  13         set op_question [mc "Force resolution to %s?
  14 Note that the diff shows only conflicting changes.
  15
  16 %s will be overwritten.
  17
  18 This operation can be undone only by restarting the merge." \
  19                 $target [short_path $current_diff_path]]
  20
  21         if {[ask_popup $op_question] eq {yes}} {
  22                 merge_load_stages $current_diff_path [list merge_force_stage $stage]
  23         }
  24 }
  25
  26 proc merge_add_resolution {path} {
  27         global current_diff_path
  28
  29         if {$path eq $current_diff_path} {
  30                 set after {reshow_diff;}
  31         } else {
  32                 set after {}
  33         }
  34
  35         update_index \
  36                 [mc "Adding resolution for %s" [short_path $path]] \
  37                 [list $path] \
  38                 [concat $after [list ui_ready]]
  39 }
  40
  41 proc merge_force_stage {stage} {
  42         global current_diff_path merge_stages
  43
  44         if {$merge_stages($stage) ne {}} {
  45                 git checkout-index -f --stage=$stage -- $current_diff_path
  46         } else {
  47                 file delete -- $current_diff_path
  48         }
  49
  50         merge_add_resolution $current_diff_path
  51 }
  52
  53 proc merge_load_stages {path cont} {
  54         global merge_stages_fd merge_stages merge_stages_buf
  55
  56         if {[info exists merge_stages_fd]} {
  57                 catch { kill_file_process $merge_stages_fd }
  58                 catch { close $merge_stages_fd }
  59         }
  60
  61         set merge_stages(0) {}
  62         set merge_stages(1) {}
  63         set merge_stages(2) {}
  64         set merge_stages(3) {}
  65         set merge_stages_buf {}
  66
  67         set merge_stages_fd [eval git_read ls-files -u -z -- $path]
  68
  69         fconfigure $merge_stages_fd -blocking 0 -translation binary -encoding binary
  70         fileevent $merge_stages_fd readable [list read_merge_stages $merge_stages_fd $cont]
  71 }
  72
  73 proc read_merge_stages {fd cont} {
  74         global merge_stages_buf merge_stages_fd merge_stages
  75
  76         append merge_stages_buf [read $fd]
  77         set pck [split $merge_stages_buf "\0"]
  78         set merge_stages_buf [lindex $pck end]
  79
  80         if {[eof $fd] && $merge_stages_buf ne {}} {
  81                 lappend pck {}
  82                 set merge_stages_buf {}
  83         }
  84
  85         foreach p [lrange $pck 0 end-1] {
  86                 set fcols [split $p "\t"]
  87                 set cols  [split [lindex $fcols 0] " "]
  88                 set stage [lindex $cols 2]
  89
  90                 set merge_stages($stage) [lrange $cols 0 1]
  91         }
  92
  93         if {[eof $fd]} {
  94                 close $fd
  95                 unset merge_stages_fd
  96                 eval $cont
  97         }
  98 }
  99
 100 proc merge_resolve_tool {} {
 101         global current_diff_path
 102
 103         merge_load_stages $current_diff_path [list merge_resolve_tool2]
 104 }
 105
 106 proc merge_resolve_tool2 {} {
 107         global current_diff_path merge_stages
 108
 109         # Validate the stages
 110         if {$merge_stages(2) eq {} ||
 111             [lindex $merge_stages(2) 0] eq {120000} ||
 112             [lindex $merge_stages(2) 0] eq {160000} ||
 113             $merge_stages(3) eq {} ||
 114             [lindex $merge_stages(3) 0] eq {120000} ||
 115             [lindex $merge_stages(3) 0] eq {160000}
 116         } {
 117                 error_popup [mc "Cannot resolve deletion or link conflicts using a tool"]
 118                 return
 119         }
 120
 121         if {![file exists $current_diff_path]} {
 122                 error_popup [mc "Conflict file does not exist"]
 123                 return
 124         }
 125
 126         # Determine the tool to use
 127         set tool [get_config merge.tool]
 128         if {$tool eq {}} { set tool meld }
 129
 130         set merge_tool_path [get_config "mergetool.$tool.path"]
 131         if {$merge_tool_path eq {}} {
 132                 switch -- $tool {
 133                 emerge { set merge_tool_path "emacs" }
 134                 araxis { set merge_tool_path "compare" }
 135                 default { set merge_tool_path $tool }
 136                 }
 137         }
 138
 139         # Make file names
 140         set filebase [file rootname $current_diff_path]
 141         set fileext  [file extension $current_diff_path]
 142         set basename [lindex [file split $current_diff_path] end]
 143
 144         set MERGED   $current_diff_path
 145         set BASE     "./$MERGED.BASE$fileext"
 146         set LOCAL    "./$MERGED.LOCAL$fileext"
 147         set REMOTE   "./$MERGED.REMOTE$fileext"
 148         set BACKUP   "./$MERGED.BACKUP$fileext"
 149
 150         set base_stage $merge_stages(1)
 151
 152         # Build the command line
 153         switch -- $tool {
 154         kdiff3 {
 155                 if {$base_stage ne {}} {
 156                         set cmdline [list "$merge_tool_path" --auto --L1 "$MERGED (Base)" \
 157                                 --L2 "$MERGED (Local)" --L3 "$MERGED (Remote)" -o "$MERGED" "$BASE" "$LOCAL" "$REMOTE"]
 158                 } else {
 159                         set cmdline [list "$merge_tool_path" --auto --L1 "$MERGED (Local)" \
 160                                 --L2 "$MERGED (Remote)" -o "$MERGED" "$LOCAL" "$REMOTE"]
 161                 }
 162         }
 163         tkdiff {
 164                 if {$base_stage ne {}} {
 165                         set cmdline [list "$merge_tool_path" -a "$BASE" -o "$MERGED" "$LOCAL" "$REMOTE"]
 166                 } else {
 167                         set cmdline [list "$merge_tool_path" -o "$MERGED" "$LOCAL" "$REMOTE"]
 168                 }
 169         }
 170         meld {
 171                 set cmdline [list "$merge_tool_path" "$LOCAL" "$MERGED" "$REMOTE"]
 172         }
 173         gvimdiff {
 174                 set cmdline [list "$merge_tool_path" -f "$LOCAL" "$MERGED" "$REMOTE"]
 175         }
 176         xxdiff {
 177                 if {$base_stage ne {}} {
 178                         set cmdline [list "$merge_tool_path" -X --show-merged-pane \
 179                                             -R {Accel.SaveAsMerged: "Ctrl-S"} \
 180                                             -R {Accel.Search: "Ctrl+F"} \
 181                                             -R {Accel.SearchForward: "Ctrl-G"} \
 182                                             --merged-file "$MERGED" "$LOCAL" "$BASE" "$REMOTE"]
 183                 } else {
 184                         set cmdline [list "$merge_tool_path" -X --show-merged-pane \
 185                                             -R {Accel.SaveAsMerged: "Ctrl-S"} \
 186                                             -R {Accel.Search: "Ctrl+F"} \
 187                                             -R {Accel.SearchForward: "Ctrl-G"} \
 188                                             --merged-file "$MERGED" "$LOCAL" "$REMOTE"]
 189                 }
 190         }
 191         opendiff {
 192                 if {$base_stage ne {}} {
 193                         set cmdline [list "$merge_tool_path" "$LOCAL" "$REMOTE" -ancestor "$BASE" -merge "$MERGED"]
 194                 } else {
 195                         set cmdline [list "$merge_tool_path" "$LOCAL" "$REMOTE" -merge "$MERGED"]
 196                 }
 197         }
 198         ecmerge {
 199                 if {$base_stage ne {}} {
 200                         set cmdline [list "$merge_tool_path" "$BASE" "$LOCAL" "$REMOTE" --default --mode=merge3 --to="$MERGED"]
 201                 } else {
 202                         set cmdline [list "$merge_tool_path" "$LOCAL" "$REMOTE" --default --mode=merge2 --to="$MERGED"]
 203                 }
 204         }
 205         emerge {
 206                 if {$base_stage ne {}} {
 207                         set cmdline [list "$merge_tool_path" -f emerge-files-with-ancestor-command \
 208                                         "$LOCAL" "$REMOTE" "$BASE" "$basename"]
 209                 } else {
 210                         set cmdline [list "$merge_tool_path" -f emerge-files-command \
 211                                         "$LOCAL" "$REMOTE" "$basename"]
 212                 }
 213         }
 214         winmerge {
 215                 if {$base_stage ne {}} {
 216                         # This tool does not support 3-way merges.
 217                         # Use the 'conflict file' resolution feature instead.
 218                         set cmdline [list "$merge_tool_path" -e -ub "$MERGED"]
 219                 } else {
 220                         set cmdline [list "$merge_tool_path" -e -ub -wl \
 221                                 -dl "Theirs File" -dr "Mine File" "$REMOTE" "$LOCAL" "$MERGED"]
 222                 }
 223         }
 224         araxis {
 225                 if {$base_stage ne {}} {
 226                         set cmdline [list "$merge_tool_path" -wait -merge -3 -a1 \
 227                                 -title1:"'$MERGED (Base)'" -title2:"'$MERGED (Local)'" \
 228                                 -title3:"'$MERGED (Remote)'" \
 229                                 "$BASE" "$LOCAL" "$REMOTE" "$MERGED"]
 230                 } else {
 231                         set cmdline [list "$merge_tool_path" -wait -2 \
 232                                  -title1:"'$MERGED (Local)'" -title2:"'$MERGED (Remote)'" \
 233                                  "$LOCAL" "$REMOTE" "$MERGED"]
 234                 }
 235         }
 236         p4merge {
 237                 set cmdline [list "$merge_tool_path" "$BASE" "$REMOTE" "$LOCAL" "$MERGED"]
 238         }
 239         vimdiff {
 240                 error_popup [mc "Not a GUI merge tool: '%s'" $tool]
 241                 return
 242         }
 243         default {
 244                 error_popup [mc "Unsupported merge tool '%s'" $tool]
 245                 return
 246         }
 247         }
 248
 249         merge_tool_start $cmdline $MERGED $BACKUP [list $BASE $LOCAL $REMOTE]
 250 }
 251
 252 proc delete_temp_files {files} {
 253         foreach fname $files {
 254                 file delete $fname
 255         }
 256 }
 257
 258 proc merge_tool_get_stages {target stages} {
 259         global merge_stages
 260
 261         set i 1
 262         foreach fname $stages {
 263                 if {$merge_stages($i) eq {}} {
 264                         file delete $fname
 265                         catch { close [open $fname w] }
 266                 } else {
 267                         # A hack to support autocrlf properly
 268                         git checkout-index -f --stage=$i -- $target
 269                         file rename -force -- $target $fname
 270                 }
 271                 incr i
 272         }
 273 }
 274
 275 proc merge_tool_start {cmdline target backup stages} {
 276         global merge_stages mtool_target mtool_tmpfiles mtool_fd mtool_mtime
 277
 278         if {[info exists mtool_fd]} {
 279                 if {[ask_popup [mc "Merge tool is already running, terminate it?"]] eq {yes}} {
 280                         catch { kill_file_process $mtool_fd }
 281                         catch { close $mtool_fd }
 282                         unset mtool_fd
 283
 284                         set old_backup [lindex $mtool_tmpfiles end]
 285                         file rename -force -- $old_backup $mtool_target
 286                         delete_temp_files $mtool_tmpfiles
 287                 } else {
 288                         return
 289                 }
 290         }
 291
 292         # Save the original file
 293         file rename -force -- $target $backup
 294
 295         # Get the blobs; it destroys $target
 296         if {[catch {merge_tool_get_stages $target $stages} err]} {
 297                 file rename -force -- $backup $target
 298                 delete_temp_files $stages
 299                 error_popup [mc "Error retrieving versions:\n%s" $err]
 300                 return
 301         }
 302
 303         # Restore the conflict file
 304         file copy -force -- $backup $target
 305
 306         # Initialize global state
 307         set mtool_target $target
 308         set mtool_mtime [file mtime $target]
 309         set mtool_tmpfiles $stages
 310
 311         lappend mtool_tmpfiles $backup
 312
 313         # Force redirection to avoid interpreting output on stderr
 314         # as an error, and launch the tool
 315         lappend cmdline {2>@1}
 316
 317         if {[catch { set mtool_fd [_open_stdout_stderr $cmdline] } err]} {
 318                 delete_temp_files $mtool_tmpfiles
 319                 error_popup [mc "Could not start the merge tool:\n\n%s" $err]
 320                 return
 321         }
 322
 323         ui_status [mc "Running merge tool..."]
 324
 325         fconfigure $mtool_fd -blocking 0 -translation binary -encoding binary
 326         fileevent $mtool_fd readable [list read_mtool_output $mtool_fd]
 327 }
 328
 329 proc read_mtool_output {fd} {
 330         global mtool_fd mtool_tmpfiles
 331
 332         read $fd
 333         if {[eof $fd]} {
 334                 unset mtool_fd
 335
 336                 fconfigure $fd -blocking 1
 337                 merge_tool_finish $fd
 338         }
 339 }
 340
 341 proc merge_tool_finish {fd} {
 342         global mtool_tmpfiles mtool_target mtool_mtime
 343
 344         set backup [lindex $mtool_tmpfiles end]
 345         set failed 0
 346
 347         # Check the return code
 348         if {[catch {close $fd} err]} {
 349                 set failed 1
 350                 if {$err ne {child process exited abnormally}} {
 351                         error_popup [strcat [mc "Merge tool failed."] "\n\n$err"]
 352                 }
 353         }
 354
 355         # Check the modification time of the target file
 356         if {!$failed && [file mtime $mtool_target] eq $mtool_mtime} {
 357                 if {[ask_popup [mc "File %s unchanged, still accept as resolved?" \
 358                                 [short_path $mtool_target]]] ne {yes}} {
 359                         set failed 1
 360                 }
 361         }
 362
 363         # Finish
 364         if {$failed} {
 365                 file rename -force -- $backup $mtool_target
 366                 delete_temp_files $mtool_tmpfiles
 367                 ui_status [mc "Merge tool failed."]
 368         } else {
 369                 if {[is_config_true merge.keepbackup]} {
 370                         file rename -force -- $backup "$mtool_target.orig"
 371                 }
 372
 373                 delete_temp_files $mtool_tmpfiles
 374
 375                 merge_add_resolution $mtool_target
 376         }
 377 }