gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  56         if ($path_info) {
  57                 # $path_info has already been URL-decoded by the web server, but
  58                 # $my_url and $my_uri have not. URL-decode them so we can properly
  59                 # strip $path_info.
  60                 $my_url = unescape($my_url);
  61                 $my_uri = unescape($my_uri);
  62                 if ($my_url =~ s,\Q$path_info\E$,, &&
  63                     $my_uri =~ s,\Q$path_info\E$,, &&
  64                     defined $ENV{'SCRIPT_NAME'}) {
  65                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  66                 }
  67         }
  68
  69         # target of the home link on top of all pages
  70         our $home_link = $my_uri || "/";
  71 }
  72
  73 # core git executable to use
  74 # this can just be "git" if your webserver has a sensible PATH
  75 our $GIT = "++GIT_BINDIR++/git";
  76
  77 # absolute fs-path which will be prepended to the project path
  78 #our $projectroot = "/pub/scm";
  79 our $projectroot = "++GITWEB_PROJECTROOT++";
  80
  81 # fs traversing limit for getting project list
  82 # the number is relative to the projectroot
  83 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  84
  85 # string of the home link on top of all pages
  86 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  87
  88 # name of your site or organization to appear in page titles
  89 # replace this with something more descriptive for clearer bookmarks
  90 our $site_name = "++GITWEB_SITENAME++"
  91                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  92
  93 # html snippet to include in the <head> section of each page
  94 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  95 # filename of html text to include at top of each page
  96 our $site_header = "++GITWEB_SITE_HEADER++";
  97 # html text to include at home page
  98 our $home_text = "++GITWEB_HOMETEXT++";
  99 # filename of html text to include at bottom of each page
 100 our $site_footer = "++GITWEB_SITE_FOOTER++";
 101
 102 # URI of stylesheets
 103 our @stylesheets = ("++GITWEB_CSS++");
 104 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 105 our $stylesheet = undef;
 106 # URI of GIT logo (72x27 size)
 107 our $logo = "++GITWEB_LOGO++";
 108 # URI of GIT favicon, assumed to be image/png type
 109 our $favicon = "++GITWEB_FAVICON++";
 110 # URI of gitweb.js (JavaScript code for gitweb)
 111 our $javascript = "++GITWEB_JS++";
 112
 113 # URI and label (title) of GIT logo link
 114 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 115 #our $logo_label = "git documentation";
 116 our $logo_url = "http://git-scm.com/";
 117 our $logo_label = "git homepage";
 118
 119 # source of projects list
 120 our $projects_list = "++GITWEB_LIST++";
 121
 122 # the width (in characters) of the projects list "Description" column
 123 our $projects_list_description_width = 25;
 124
 125 # group projects by category on the projects list
 126 # (enabled if this variable evaluates to true)
 127 our $projects_list_group_categories = 0;
 128
 129 # default category if none specified
 130 # (leave the empty string for no category)
 131 our $project_list_default_category = "";
 132
 133 # default order of projects list
 134 # valid values are none, project, descr, owner, and age
 135 our $default_projects_order = "project";
 136
 137 # show repository only if this file exists
 138 # (only effective if this variable evaluates to true)
 139 our $export_ok = "++GITWEB_EXPORT_OK++";
 140
 141 # don't generate age column on the projects list page
 142 our $omit_age_column = 0;
 143
 144 # don't generate information about owners of repositories
 145 our $omit_owner=0;
 146
 147 # show repository only if this subroutine returns true
 148 # when given the path to the project, for example:
 149 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 150 our $export_auth_hook = undef;
 151
 152 # only allow viewing of repositories also shown on the overview page
 153 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 154
 155 # list of git base URLs used for URL to where fetch project from,
 156 # i.e. full URL is "$git_base_url/$project"
 157 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 158
 159 # default blob_plain mimetype and default charset for text/plain blob
 160 our $default_blob_plain_mimetype = 'text/plain';
 161 our $default_text_plain_charset  = undef;
 162
 163 # file to use for guessing MIME types before trying /etc/mime.types
 164 # (relative to the current git repository)
 165 our $mimetypes_file = undef;
 166
 167 # assume this charset if line contains non-UTF-8 characters;
 168 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 169 # for which encoding all byte sequences are valid, for example
 170 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 171 # could be even 'utf-8' for the old behavior)
 172 our $fallback_encoding = 'latin1';
 173
 174 # rename detection options for git-diff and git-diff-tree
 175 # - default is '-M', with the cost proportional to
 176 #   (number of removed files) * (number of new files).
 177 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 178 #   (number of changed files + number of removed files) * (number of new files)
 179 # - even more costly is '-C', '--find-copies-harder' with cost
 180 #   (number of files in the original tree) * (number of new files)
 181 # - one might want to include '-B' option, e.g. '-B', '-M'
 182 our @diff_opts = ('-M'); # taken from git_commit
 183
 184 # Disables features that would allow repository owners to inject script into
 185 # the gitweb domain.
 186 our $prevent_xss = 0;
 187
 188 # Path to the highlight executable to use (must be the one from
 189 # http://www.andre-simon.de due to assumptions about parameters and output).
 190 # Useful if highlight is not installed on your webserver's PATH.
 191 # [Default: highlight]
 192 our $highlight_bin = "++HIGHLIGHT_BIN++";
 193
 194 # information about snapshot formats that gitweb is capable of serving
 195 our %known_snapshot_formats = (
 196         # name => {
 197         #       'display' => display name,
 198         #       'type' => mime type,
 199         #       'suffix' => filename suffix,
 200         #       'format' => --format for git-archive,
 201         #       'compressor' => [compressor command and arguments]
 202         #                       (array reference, optional)
 203         #       'disabled' => boolean (optional)}
 204         #
 205         'tgz' => {
 206                 'display' => 'tar.gz',
 207                 'type' => 'application/x-gzip',
 208                 'suffix' => '.tar.gz',
 209                 'format' => 'tar',
 210                 'compressor' => ['gzip', '-n']},
 211
 212         'tbz2' => {
 213                 'display' => 'tar.bz2',
 214                 'type' => 'application/x-bzip2',
 215                 'suffix' => '.tar.bz2',
 216                 'format' => 'tar',
 217                 'compressor' => ['bzip2']},
 218
 219         'txz' => {
 220                 'display' => 'tar.xz',
 221                 'type' => 'application/x-xz',
 222                 'suffix' => '.tar.xz',
 223                 'format' => 'tar',
 224                 'compressor' => ['xz'],
 225                 'disabled' => 1},
 226
 227         'zip' => {
 228                 'display' => 'zip',
 229                 'type' => 'application/x-zip',
 230                 'suffix' => '.zip',
 231                 'format' => 'zip'},
 232 );
 233
 234 # Aliases so we understand old gitweb.snapshot values in repository
 235 # configuration.
 236 our %known_snapshot_format_aliases = (
 237         'gzip'  => 'tgz',
 238         'bzip2' => 'tbz2',
 239         'xz'    => 'txz',
 240
 241         # backward compatibility: legacy gitweb config support
 242         'x-gzip' => undef, 'gz' => undef,
 243         'x-bzip2' => undef, 'bz2' => undef,
 244         'x-zip' => undef, '' => undef,
 245 );
 246
 247 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 248 # are changed, it may be appropriate to change these values too via
 249 # $GITWEB_CONFIG.
 250 our %avatar_size = (
 251         'default' => 16,
 252         'double'  => 32
 253 );
 254
 255 # Used to set the maximum load that we will still respond to gitweb queries.
 256 # If server load exceed this value then return "503 server busy" error.
 257 # If gitweb cannot determined server load, it is taken to be 0.
 258 # Leave it undefined (or set to 'undef') to turn off load checking.
 259 our $maxload = 300;
 260
 261 # configuration for 'highlight' (http://www.andre-simon.de/)
 262 # match by basename
 263 our %highlight_basename = (
 264         #'Program' => 'py',
 265         #'Library' => 'py',
 266         'SConstruct' => 'py', # SCons equivalent of Makefile
 267         'Makefile' => 'make',
 268 );
 269 # match by extension
 270 our %highlight_ext = (
 271         # main extensions, defining name of syntax;
 272         # see files in /usr/share/highlight/langDefs/ directory
 273         map { $_ => $_ }
 274                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 275         # alternate extensions, see /etc/highlight/filetypes.conf
 276         'h' => 'c',
 277         map { $_ => 'sh'  } qw(bash zsh ksh),
 278         map { $_ => 'cpp' } qw(cxx c++ cc),
 279         map { $_ => 'php' } qw(php3 php4 php5 phps),
 280         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 281         map { $_ => 'make'} qw(mak mk),
 282         map { $_ => 'xml' } qw(xhtml html htm),
 283 );
 284
 285 # You define site-wide feature defaults here; override them with
 286 # $GITWEB_CONFIG as necessary.
 287 our %feature = (
 288         # feature => {
 289         #       'sub' => feature-sub (subroutine),
 290         #       'override' => allow-override (boolean),
 291         #       'default' => [ default options...] (array reference)}
 292         #
 293         # if feature is overridable (it means that allow-override has true value),
 294         # then feature-sub will be called with default options as parameters;
 295         # return value of feature-sub indicates if to enable specified feature
 296         #
 297         # if there is no 'sub' key (no feature-sub), then feature cannot be
 298         # overridden
 299         #
 300         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 301         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 302         # is enabled
 303
 304         # Enable the 'blame' blob view, showing the last commit that modified
 305         # each line in the file. This can be very CPU-intensive.
 306
 307         # To enable system wide have in $GITWEB_CONFIG
 308         # $feature{'blame'}{'default'} = [1];
 309         # To have project specific config enable override in $GITWEB_CONFIG
 310         # $feature{'blame'}{'override'} = 1;
 311         # and in project config gitweb.blame = 0|1;
 312         'blame' => {
 313                 'sub' => sub { feature_bool('blame', @_) },
 314                 'override' => 0,
 315                 'default' => [0]},
 316
 317         # Enable the 'snapshot' link, providing a compressed archive of any
 318         # tree. This can potentially generate high traffic if you have large
 319         # project.
 320
 321         # Value is a list of formats defined in %known_snapshot_formats that
 322         # you wish to offer.
 323         # To disable system wide have in $GITWEB_CONFIG
 324         # $feature{'snapshot'}{'default'} = [];
 325         # To have project specific config enable override in $GITWEB_CONFIG
 326         # $feature{'snapshot'}{'override'} = 1;
 327         # and in project config, a comma-separated list of formats or "none"
 328         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 329         'snapshot' => {
 330                 'sub' => \&feature_snapshot,
 331                 'override' => 0,
 332                 'default' => ['tgz']},
 333
 334         # Enable text search, which will list the commits which match author,
 335         # committer or commit text to a given string.  Enabled by default.
 336         # Project specific override is not supported.
 337         #
 338         # Note that this controls all search features, which means that if
 339         # it is disabled, then 'grep' and 'pickaxe' search would also be
 340         # disabled.
 341         'search' => {
 342                 'override' => 0,
 343                 'default' => [1]},
 344
 345         # Enable grep search, which will list the files in currently selected
 346         # tree containing the given string. Enabled by default. This can be
 347         # potentially CPU-intensive, of course.
 348         # Note that you need to have 'search' feature enabled too.
 349
 350         # To enable system wide have in $GITWEB_CONFIG
 351         # $feature{'grep'}{'default'} = [1];
 352         # To have project specific config enable override in $GITWEB_CONFIG
 353         # $feature{'grep'}{'override'} = 1;
 354         # and in project config gitweb.grep = 0|1;
 355         'grep' => {
 356                 'sub' => sub { feature_bool('grep', @_) },
 357                 'override' => 0,
 358                 'default' => [1]},
 359
 360         # Enable the pickaxe search, which will list the commits that modified
 361         # a given string in a file. This can be practical and quite faster
 362         # alternative to 'blame', but still potentially CPU-intensive.
 363         # Note that you need to have 'search' feature enabled too.
 364
 365         # To enable system wide have in $GITWEB_CONFIG
 366         # $feature{'pickaxe'}{'default'} = [1];
 367         # To have project specific config enable override in $GITWEB_CONFIG
 368         # $feature{'pickaxe'}{'override'} = 1;
 369         # and in project config gitweb.pickaxe = 0|1;
 370         'pickaxe' => {
 371                 'sub' => sub { feature_bool('pickaxe', @_) },
 372                 'override' => 0,
 373                 'default' => [1]},
 374
 375         # Enable showing size of blobs in a 'tree' view, in a separate
 376         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 377
 378         # To disable system wide have in $GITWEB_CONFIG
 379         # $feature{'show-sizes'}{'default'} = [0];
 380         # To have project specific config enable override in $GITWEB_CONFIG
 381         # $feature{'show-sizes'}{'override'} = 1;
 382         # and in project config gitweb.showsizes = 0|1;
 383         'show-sizes' => {
 384                 'sub' => sub { feature_bool('showsizes', @_) },
 385                 'override' => 0,
 386                 'default' => [1]},
 387
 388         # Make gitweb use an alternative format of the URLs which can be
 389         # more readable and natural-looking: project name is embedded
 390         # directly in the path and the query string contains other
 391         # auxiliary information. All gitweb installations recognize
 392         # URL in either format; this configures in which formats gitweb
 393         # generates links.
 394
 395         # To enable system wide have in $GITWEB_CONFIG
 396         # $feature{'pathinfo'}{'default'} = [1];
 397         # Project specific override is not supported.
 398
 399         # Note that you will need to change the default location of CSS,
 400         # favicon, logo and possibly other files to an absolute URL. Also,
 401         # if gitweb.cgi serves as your indexfile, you will need to force
 402         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 403         'pathinfo' => {
 404                 'override' => 0,
 405                 'default' => [0]},
 406
 407         # Make gitweb consider projects in project root subdirectories
 408         # to be forks of existing projects. Given project $projname.git,
 409         # projects matching $projname/*.git will not be shown in the main
 410         # projects list, instead a '+' mark will be added to $projname
 411         # there and a 'forks' view will be enabled for the project, listing
 412         # all the forks. If project list is taken from a file, forks have
 413         # to be listed after the main project.
 414
 415         # To enable system wide have in $GITWEB_CONFIG
 416         # $feature{'forks'}{'default'} = [1];
 417         # Project specific override is not supported.
 418         'forks' => {
 419                 'override' => 0,
 420                 'default' => [0]},
 421
 422         # Insert custom links to the action bar of all project pages.
 423         # This enables you mainly to link to third-party scripts integrating
 424         # into gitweb; e.g. git-browser for graphical history representation
 425         # or custom web-based repository administration interface.
 426
 427         # The 'default' value consists of a list of triplets in the form
 428         # (label, link, position) where position is the label after which
 429         # to insert the link and link is a format string where %n expands
 430         # to the project name, %f to the project path within the filesystem,
 431         # %h to the current hash (h gitweb parameter) and %b to the current
 432         # hash base (hb gitweb parameter); %% expands to %.
 433
 434         # To enable system wide have in $GITWEB_CONFIG e.g.
 435         # $feature{'actions'}{'default'} = [('graphiclog',
 436         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 437         # Project specific override is not supported.
 438         'actions' => {
 439                 'override' => 0,
 440                 'default' => []},
 441
 442         # Allow gitweb scan project content tags of project repository,
 443         # and display the popular Web 2.0-ish "tag cloud" near the projects
 444         # list.  Note that this is something COMPLETELY different from the
 445         # normal Git tags.
 446
 447         # gitweb by itself can show existing tags, but it does not handle
 448         # tagging itself; you need to do it externally, outside gitweb.
 449         # The format is described in git_get_project_ctags() subroutine.
 450         # You may want to install the HTML::TagCloud Perl module to get
 451         # a pretty tag cloud instead of just a list of tags.
 452
 453         # To enable system wide have in $GITWEB_CONFIG
 454         # $feature{'ctags'}{'default'} = [1];
 455         # Project specific override is not supported.
 456
 457         # In the future whether ctags editing is enabled might depend
 458         # on the value, but using 1 should always mean no editing of ctags.
 459         'ctags' => {
 460                 'override' => 0,
 461                 'default' => [0]},
 462
 463         # The maximum number of patches in a patchset generated in patch
 464         # view. Set this to 0 or undef to disable patch view, or to a
 465         # negative number to remove any limit.
 466
 467         # To disable system wide have in $GITWEB_CONFIG
 468         # $feature{'patches'}{'default'} = [0];
 469         # To have project specific config enable override in $GITWEB_CONFIG
 470         # $feature{'patches'}{'override'} = 1;
 471         # and in project config gitweb.patches = 0|n;
 472         # where n is the maximum number of patches allowed in a patchset.
 473         'patches' => {
 474                 'sub' => \&feature_patches,
 475                 'override' => 0,
 476                 'default' => [16]},
 477
 478         # Avatar support. When this feature is enabled, views such as
 479         # shortlog or commit will display an avatar associated with
 480         # the email of the committer(s) and/or author(s).
 481
 482         # Currently available providers are gravatar and picon.
 483         # If an unknown provider is specified, the feature is disabled.
 484
 485         # Gravatar depends on Digest::MD5.
 486         # Picon currently relies on the indiana.edu database.
 487
 488         # To enable system wide have in $GITWEB_CONFIG
 489         # $feature{'avatar'}{'default'} = ['<provider>'];
 490         # where <provider> is either gravatar or picon.
 491         # To have project specific config enable override in $GITWEB_CONFIG
 492         # $feature{'avatar'}{'override'} = 1;
 493         # and in project config gitweb.avatar = <provider>;
 494         'avatar' => {
 495                 'sub' => \&feature_avatar,
 496                 'override' => 0,
 497                 'default' => ['']},
 498
 499         # Enable displaying how much time and how many git commands
 500         # it took to generate and display page.  Disabled by default.
 501         # Project specific override is not supported.
 502         'timed' => {
 503                 'override' => 0,
 504                 'default' => [0]},
 505
 506         # Enable turning some links into links to actions which require
 507         # JavaScript to run (like 'blame_incremental').  Not enabled by
 508         # default.  Project specific override is currently not supported.
 509         'javascript-actions' => {
 510                 'override' => 0,
 511                 'default' => [0]},
 512
 513         # Enable and configure ability to change common timezone for dates
 514         # in gitweb output via JavaScript.  Enabled by default.
 515         # Project specific override is not supported.
 516         'javascript-timezone' => {
 517                 'override' => 0,
 518                 'default' => [
 519                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 520                                      # or undef to turn off this feature
 521                         'gitweb_tz', # name of cookie where to store selected timezone
 522                         'datetime',  # CSS class used to mark up dates for manipulation
 523                 ]},
 524
 525         # Syntax highlighting support. This is based on Daniel Svensson's
 526         # and Sham Chukoury's work in gitweb-xmms2.git.
 527         # It requires the 'highlight' program present in $PATH,
 528         # and therefore is disabled by default.
 529
 530         # To enable system wide have in $GITWEB_CONFIG
 531         # $feature{'highlight'}{'default'} = [1];
 532
 533         'highlight' => {
 534                 'sub' => sub { feature_bool('highlight', @_) },
 535                 'override' => 0,
 536                 'default' => [0]},
 537
 538         # Enable displaying of remote heads in the heads list
 539
 540         # To enable system wide have in $GITWEB_CONFIG
 541         # $feature{'remote_heads'}{'default'} = [1];
 542         # To have project specific config enable override in $GITWEB_CONFIG
 543         # $feature{'remote_heads'}{'override'} = 1;
 544         # and in project config gitweb.remote_heads = 0|1;
 545         'remote_heads' => {
 546                 'sub' => sub { feature_bool('remote_heads', @_) },
 547                 'override' => 0,
 548                 'default' => [0]},
 549 );
 550
 551 sub gitweb_get_feature {
 552         my ($name) = @_;
 553         return unless exists $feature{$name};
 554         my ($sub, $override, @defaults) = (
 555                 $feature{$name}{'sub'},
 556                 $feature{$name}{'override'},
 557                 @{$feature{$name}{'default'}});
 558         # project specific override is possible only if we have project
 559         our $git_dir; # global variable, declared later
 560         if (!$override || !defined $git_dir) {
 561                 return @defaults;
 562         }
 563         if (!defined $sub) {
 564                 warn "feature $name is not overridable";
 565                 return @defaults;
 566         }
 567         return $sub->(@defaults);
 568 }
 569
 570 # A wrapper to check if a given feature is enabled.
 571 # With this, you can say
 572 #
 573 #   my $bool_feat = gitweb_check_feature('bool_feat');
 574 #   gitweb_check_feature('bool_feat') or somecode;
 575 #
 576 # instead of
 577 #
 578 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 579 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 580 #
 581 sub gitweb_check_feature {
 582         return (gitweb_get_feature(@_))[0];
 583 }
 584
 585
 586 sub feature_bool {
 587         my $key = shift;
 588         my ($val) = git_get_project_config($key, '--bool');
 589
 590         if (!defined $val) {
 591                 return ($_[0]);
 592         } elsif ($val eq 'true') {
 593                 return (1);
 594         } elsif ($val eq 'false') {
 595                 return (0);
 596         }
 597 }
 598
 599 sub feature_snapshot {
 600         my (@fmts) = @_;
 601
 602         my ($val) = git_get_project_config('snapshot');
 603
 604         if ($val) {
 605                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 606         }
 607
 608         return @fmts;
 609 }
 610
 611 sub feature_patches {
 612         my @val = (git_get_project_config('patches', '--int'));
 613
 614         if (@val) {
 615                 return @val;
 616         }
 617
 618         return ($_[0]);
 619 }
 620
 621 sub feature_avatar {
 622         my @val = (git_get_project_config('avatar'));
 623
 624         return @val ? @val : @_;
 625 }
 626
 627 # checking HEAD file with -e is fragile if the repository was
 628 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 629 # and then pruned.
 630 sub check_head_link {
 631         my ($dir) = @_;
 632         my $headfile = "$dir/HEAD";
 633         return ((-e $headfile) ||
 634                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 635 }
 636
 637 sub check_export_ok {
 638         my ($dir) = @_;
 639         return (check_head_link($dir) &&
 640                 (!$export_ok || -e "$dir/$export_ok") &&
 641                 (!$export_auth_hook || $export_auth_hook->($dir)));
 642 }
 643
 644 # process alternate names for backward compatibility
 645 # filter out unsupported (unknown) snapshot formats
 646 sub filter_snapshot_fmts {
 647         my @fmts = @_;
 648
 649         @fmts = map {
 650                 exists $known_snapshot_format_aliases{$_} ?
 651                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 652         @fmts = grep {
 653                 exists $known_snapshot_formats{$_} &&
 654                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 655 }
 656
 657 # If it is set to code reference, it is code that it is to be run once per
 658 # request, allowing updating configurations that change with each request,
 659 # while running other code in config file only once.
 660 #
 661 # Otherwise, if it is false then gitweb would process config file only once;
 662 # if it is true then gitweb config would be run for each request.
 663 our $per_request_config = 1;
 664
 665 # read and parse gitweb config file given by its parameter.
 666 # returns true on success, false on recoverable error, allowing
 667 # to chain this subroutine, using first file that exists.
 668 # dies on errors during parsing config file, as it is unrecoverable.
 669 sub read_config_file {
 670         my $filename = shift;
 671         return unless defined $filename;
 672         # die if there are errors parsing config file
 673         if (-e $filename) {
 674                 do $filename;
 675                 die $@ if $@;
 676                 return 1;
 677         }
 678         return;
 679 }
 680
 681 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 682 sub evaluate_gitweb_config {
 683         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 684         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 685         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 686
 687         # Protect agains duplications of file names, to not read config twice.
 688         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 689         # there possibility of duplication of filename there doesn't matter.
 690         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 691         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 692
 693         # Common system-wide settings for convenience.
 694         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 695         read_config_file($GITWEB_CONFIG_COMMON);
 696
 697         # Use first config file that exists.  This means use the per-instance
 698         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 699         read_config_file($GITWEB_CONFIG) and return;
 700         read_config_file($GITWEB_CONFIG_SYSTEM);
 701 }
 702
 703 # Get loadavg of system, to compare against $maxload.
 704 # Currently it requires '/proc/loadavg' present to get loadavg;
 705 # if it is not present it returns 0, which means no load checking.
 706 sub get_loadavg {
 707         if( -e '/proc/loadavg' ){
 708                 open my $fd, '<', '/proc/loadavg'
 709                         or return 0;
 710                 my @load = split(/\s+/, scalar <$fd>);
 711                 close $fd;
 712
 713                 # The first three columns measure CPU and IO utilization of the last one,
 714                 # five, and 10 minute periods.  The fourth column shows the number of
 715                 # currently running processes and the total number of processes in the m/n
 716                 # format.  The last column displays the last process ID used.
 717                 return $load[0] || 0;
 718         }
 719         # additional checks for load average should go here for things that don't export
 720         # /proc/loadavg
 721
 722         return 0;
 723 }
 724
 725 # version of the core git binary
 726 our $git_version;
 727 sub evaluate_git_version {
 728         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 729         $number_of_git_cmds++;
 730 }
 731
 732 sub check_loadavg {
 733         if (defined $maxload && get_loadavg() > $maxload) {
 734                 die_error(503, "The load average on the server is too high");
 735         }
 736 }
 737
 738 # ======================================================================
 739 # input validation and dispatch
 740
 741 # input parameters can be collected from a variety of sources (presently, CGI
 742 # and PATH_INFO), so we define an %input_params hash that collects them all
 743 # together during validation: this allows subsequent uses (e.g. href()) to be
 744 # agnostic of the parameter origin
 745
 746 our %input_params = ();
 747
 748 # input parameters are stored with the long parameter name as key. This will
 749 # also be used in the href subroutine to convert parameters to their CGI
 750 # equivalent, and since the href() usage is the most frequent one, we store
 751 # the name -> CGI key mapping here, instead of the reverse.
 752 #
 753 # XXX: Warning: If you touch this, check the search form for updating,
 754 # too.
 755
 756 our @cgi_param_mapping = (
 757         project => "p",
 758         action => "a",
 759         file_name => "f",
 760         file_parent => "fp",
 761         hash => "h",
 762         hash_parent => "hp",
 763         hash_base => "hb",
 764         hash_parent_base => "hpb",
 765         page => "pg",
 766         order => "o",
 767         searchtext => "s",
 768         searchtype => "st",
 769         snapshot_format => "sf",
 770         extra_options => "opt",
 771         search_use_regexp => "sr",
 772         ctag => "by_tag",
 773         diff_style => "ds",
 774         project_filter => "pf",
 775         # this must be last entry (for manipulation from JavaScript)
 776         javascript => "js"
 777 );
 778 our %cgi_param_mapping = @cgi_param_mapping;
 779
 780 # we will also need to know the possible actions, for validation
 781 our %actions = (
 782         "blame" => \&git_blame,
 783         "blame_incremental" => \&git_blame_incremental,
 784         "blame_data" => \&git_blame_data,
 785         "blobdiff" => \&git_blobdiff,
 786         "blobdiff_plain" => \&git_blobdiff_plain,
 787         "blob" => \&git_blob,
 788         "blob_plain" => \&git_blob_plain,
 789         "commitdiff" => \&git_commitdiff,
 790         "commitdiff_plain" => \&git_commitdiff_plain,
 791         "commit" => \&git_commit,
 792         "forks" => \&git_forks,
 793         "heads" => \&git_heads,
 794         "history" => \&git_history,
 795         "log" => \&git_log,
 796         "patch" => \&git_patch,
 797         "patches" => \&git_patches,
 798         "remotes" => \&git_remotes,
 799         "rss" => \&git_rss,
 800         "atom" => \&git_atom,
 801         "search" => \&git_search,
 802         "search_help" => \&git_search_help,
 803         "shortlog" => \&git_shortlog,
 804         "summary" => \&git_summary,
 805         "tag" => \&git_tag,
 806         "tags" => \&git_tags,
 807         "tree" => \&git_tree,
 808         "snapshot" => \&git_snapshot,
 809         "object" => \&git_object,
 810         # those below don't need $project
 811         "opml" => \&git_opml,
 812         "project_list" => \&git_project_list,
 813         "project_index" => \&git_project_index,
 814 );
 815
 816 # finally, we have the hash of allowed extra_options for the commands that
 817 # allow them
 818 our %allowed_options = (
 819         "--no-merges" => [ qw(rss atom log shortlog history) ],
 820 );
 821
 822 # fill %input_params with the CGI parameters. All values except for 'opt'
 823 # should be single values, but opt can be an array. We should probably
 824 # build an array of parameters that can be multi-valued, but since for the time
 825 # being it's only this one, we just single it out
 826 sub evaluate_query_params {
 827         our $cgi;
 828
 829         while (my ($name, $symbol) = each %cgi_param_mapping) {
 830                 if ($symbol eq 'opt') {
 831                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->param($symbol) ];
 832                 } else {
 833                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 834                 }
 835         }
 836 }
 837
 838 # now read PATH_INFO and update the parameter list for missing parameters
 839 sub evaluate_path_info {
 840         return if defined $input_params{'project'};
 841         return if !$path_info;
 842         $path_info =~ s,^/+,,;
 843         return if !$path_info;
 844
 845         # find which part of PATH_INFO is project
 846         my $project = $path_info;
 847         $project =~ s,/+$,,;
 848         while ($project && !check_head_link("$projectroot/$project")) {
 849                 $project =~ s,/*[^/]*$,,;
 850         }
 851         return unless $project;
 852         $input_params{'project'} = $project;
 853
 854         # do not change any parameters if an action is given using the query string
 855         return if $input_params{'action'};
 856         $path_info =~ s,^\Q$project\E/*,,;
 857
 858         # next, check if we have an action
 859         my $action = $path_info;
 860         $action =~ s,/.*$,,;
 861         if (exists $actions{$action}) {
 862                 $path_info =~ s,^$action/*,,;
 863                 $input_params{'action'} = $action;
 864         }
 865
 866         # list of actions that want hash_base instead of hash, but can have no
 867         # pathname (f) parameter
 868         my @wants_base = (
 869                 'tree',
 870                 'history',
 871         );
 872
 873         # we want to catch, among others
 874         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 875         my ($parentrefname, $parentpathname, $refname, $pathname) =
 876                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 877
 878         # first, analyze the 'current' part
 879         if (defined $pathname) {
 880                 # we got "branch:filename" or "branch:dir/"
 881                 # we could use git_get_type(branch:pathname), but:
 882                 # - it needs $git_dir
 883                 # - it does a git() call
 884                 # - the convention of terminating directories with a slash
 885                 #   makes it superfluous
 886                 # - embedding the action in the PATH_INFO would make it even
 887                 #   more superfluous
 888                 $pathname =~ s,^/+,,;
 889                 if (!$pathname || substr($pathname, -1) eq "/") {
 890                         $input_params{'action'} ||= "tree";
 891                         $pathname =~ s,/$,,;
 892                 } else {
 893                         # the default action depends on whether we had parent info
 894                         # or not
 895                         if ($parentrefname) {
 896                                 $input_params{'action'} ||= "blobdiff_plain";
 897                         } else {
 898                                 $input_params{'action'} ||= "blob_plain";
 899                         }
 900                 }
 901                 $input_params{'hash_base'} ||= $refname;
 902                 $input_params{'file_name'} ||= $pathname;
 903         } elsif (defined $refname) {
 904                 # we got "branch". In this case we have to choose if we have to
 905                 # set hash or hash_base.
 906                 #
 907                 # Most of the actions without a pathname only want hash to be
 908                 # set, except for the ones specified in @wants_base that want
 909                 # hash_base instead. It should also be noted that hand-crafted
 910                 # links having 'history' as an action and no pathname or hash
 911                 # set will fail, but that happens regardless of PATH_INFO.
 912                 if (defined $parentrefname) {
 913                         # if there is parent let the default be 'shortlog' action
 914                         # (for http://git.example.com/repo.git/A..B links); if there
 915                         # is no parent, dispatch will detect type of object and set
 916                         # action appropriately if required (if action is not set)
 917                         $input_params{'action'} ||= "shortlog";
 918                 }
 919                 if ($input_params{'action'} &&
 920                     grep { $_ eq $input_params{'action'} } @wants_base) {
 921                         $input_params{'hash_base'} ||= $refname;
 922                 } else {
 923                         $input_params{'hash'} ||= $refname;
 924                 }
 925         }
 926
 927         # next, handle the 'parent' part, if present
 928         if (defined $parentrefname) {
 929                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 930                 # someproject/blobdiff/oldrev..newrev:/filename
 931                 if ($parentpathname) {
 932                         $parentpathname =~ s,^/+,,;
 933                         $parentpathname =~ s,/$,,;
 934                         $input_params{'file_parent'} ||= $parentpathname;
 935                 } else {
 936                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 937                 }
 938                 # we assume that hash_parent_base is wanted if a path was specified,
 939                 # or if the action wants hash_base instead of hash
 940                 if (defined $input_params{'file_parent'} ||
 941                         grep { $_ eq $input_params{'action'} } @wants_base) {
 942                         $input_params{'hash_parent_base'} ||= $parentrefname;
 943                 } else {
 944                         $input_params{'hash_parent'} ||= $parentrefname;
 945                 }
 946         }
 947
 948         # for the snapshot action, we allow URLs in the form
 949         # $project/snapshot/$hash.ext
 950         # where .ext determines the snapshot and gets removed from the
 951         # passed $refname to provide the $hash.
 952         #
 953         # To be able to tell that $refname includes the format extension, we
 954         # require the following two conditions to be satisfied:
 955         # - the hash input parameter MUST have been set from the $refname part
 956         #   of the URL (i.e. they must be equal)
 957         # - the snapshot format MUST NOT have been defined already (e.g. from
 958         #   CGI parameter sf)
 959         # It's also useless to try any matching unless $refname has a dot,
 960         # so we check for that too
 961         if (defined $input_params{'action'} &&
 962                 $input_params{'action'} eq 'snapshot' &&
 963                 defined $refname && index($refname, '.') != -1 &&
 964                 $refname eq $input_params{'hash'} &&
 965                 !defined $input_params{'snapshot_format'}) {
 966                 # We loop over the known snapshot formats, checking for
 967                 # extensions. Allowed extensions are both the defined suffix
 968                 # (which includes the initial dot already) and the snapshot
 969                 # format key itself, with a prepended dot
 970                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 971                         my $hash = $refname;
 972                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 973                                 next;
 974                         }
 975                         my $sfx = $1;
 976                         # a valid suffix was found, so set the snapshot format
 977                         # and reset the hash parameter
 978                         $input_params{'snapshot_format'} = $fmt;
 979                         $input_params{'hash'} = $hash;
 980                         # we also set the format suffix to the one requested
 981                         # in the URL: this way a request for e.g. .tgz returns
 982                         # a .tgz instead of a .tar.gz
 983                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 984                         last;
 985                 }
 986         }
 987 }
 988
 989 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 990      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 991      $searchtext, $search_regexp, $project_filter);
 992 sub evaluate_and_validate_params {
 993         our $action = $input_params{'action'};
 994         if (defined $action) {
 995                 if (!validate_action($action)) {
 996                         die_error(400, "Invalid action parameter");
 997                 }
 998         }
 999
1000         # parameters which are pathnames
1001         our $project = $input_params{'project'};
1002         if (defined $project) {
1003                 if (!validate_project($project)) {
1004                         undef $project;
1005                         die_error(404, "No such project");
1006                 }
1007         }
1008
1009         our $project_filter = $input_params{'project_filter'};
1010         if (defined $project_filter) {
1011                 if (!validate_pathname($project_filter)) {
1012                         die_error(404, "Invalid project_filter parameter");
1013                 }
1014         }
1015
1016         our $file_name = $input_params{'file_name'};
1017         if (defined $file_name) {
1018                 if (!validate_pathname($file_name)) {
1019                         die_error(400, "Invalid file parameter");
1020                 }
1021         }
1022
1023         our $file_parent = $input_params{'file_parent'};
1024         if (defined $file_parent) {
1025                 if (!validate_pathname($file_parent)) {
1026                         die_error(400, "Invalid file parent parameter");
1027                 }
1028         }
1029
1030         # parameters which are refnames
1031         our $hash = $input_params{'hash'};
1032         if (defined $hash) {
1033                 if (!validate_refname($hash)) {
1034                         die_error(400, "Invalid hash parameter");
1035                 }
1036         }
1037
1038         our $hash_parent = $input_params{'hash_parent'};
1039         if (defined $hash_parent) {
1040                 if (!validate_refname($hash_parent)) {
1041                         die_error(400, "Invalid hash parent parameter");
1042                 }
1043         }
1044
1045         our $hash_base = $input_params{'hash_base'};
1046         if (defined $hash_base) {
1047                 if (!validate_refname($hash_base)) {
1048                         die_error(400, "Invalid hash base parameter");
1049                 }
1050         }
1051
1052         our @extra_options = @{$input_params{'extra_options'}};
1053         # @extra_options is always defined, since it can only be (currently) set from
1054         # CGI, and $cgi->param() returns the empty array in array context if the param
1055         # is not set
1056         foreach my $opt (@extra_options) {
1057                 if (not exists $allowed_options{$opt}) {
1058                         die_error(400, "Invalid option parameter");
1059                 }
1060                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1061                         die_error(400, "Invalid option parameter for this action");
1062                 }
1063         }
1064
1065         our $hash_parent_base = $input_params{'hash_parent_base'};
1066         if (defined $hash_parent_base) {
1067                 if (!validate_refname($hash_parent_base)) {
1068                         die_error(400, "Invalid hash parent base parameter");
1069                 }
1070         }
1071
1072         # other parameters
1073         our $page = $input_params{'page'};
1074         if (defined $page) {
1075                 if ($page =~ m/[^0-9]/) {
1076                         die_error(400, "Invalid page parameter");
1077                 }
1078         }
1079
1080         our $searchtype = $input_params{'searchtype'};
1081         if (defined $searchtype) {
1082                 if ($searchtype =~ m/[^a-z]/) {
1083                         die_error(400, "Invalid searchtype parameter");
1084                 }
1085         }
1086
1087         our $search_use_regexp = $input_params{'search_use_regexp'};
1088
1089         our $searchtext = $input_params{'searchtext'};
1090         our $search_regexp;
1091         if (defined $searchtext) {
1092                 if (length($searchtext) < 2) {
1093                         die_error(403, "At least two characters are required for search parameter");
1094                 }
1095                 if ($search_use_regexp) {
1096                         $search_regexp = $searchtext;
1097                         if (!eval { qr/$search_regexp/; 1; }) {
1098                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1099                                 die_error(400, "Invalid search regexp '$search_regexp'",
1100                                           esc_html($error));
1101                         }
1102                 } else {
1103                         $search_regexp = quotemeta $searchtext;
1104                 }
1105         }
1106 }
1107
1108 # path to the current git repository
1109 our $git_dir;
1110 sub evaluate_git_dir {
1111         our $git_dir = "$projectroot/$project" if $project;
1112 }
1113
1114 our (@snapshot_fmts, $git_avatar);
1115 sub configure_gitweb_features {
1116         # list of supported snapshot formats
1117         our @snapshot_fmts = gitweb_get_feature('snapshot');
1118         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1119
1120         # check that the avatar feature is set to a known provider name,
1121         # and for each provider check if the dependencies are satisfied.
1122         # if the provider name is invalid or the dependencies are not met,
1123         # reset $git_avatar to the empty string.
1124         our ($git_avatar) = gitweb_get_feature('avatar');
1125         if ($git_avatar eq 'gravatar') {
1126                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1127         } elsif ($git_avatar eq 'picon') {
1128                 # no dependencies
1129         } else {
1130                 $git_avatar = '';
1131         }
1132 }
1133
1134 # custom error handler: 'die <message>' is Internal Server Error
1135 sub handle_errors_html {
1136         my $msg = shift; # it is already HTML escaped
1137
1138         # to avoid infinite loop where error occurs in die_error,
1139         # change handler to default handler, disabling handle_errors_html
1140         set_message("Error occured when inside die_error:\n$msg");
1141
1142         # you cannot jump out of die_error when called as error handler;
1143         # the subroutine set via CGI::Carp::set_message is called _after_
1144         # HTTP headers are already written, so it cannot write them itself
1145         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1146 }
1147 set_message(\&handle_errors_html);
1148
1149 # dispatch
1150 sub dispatch {
1151         if (!defined $action) {
1152                 if (defined $hash) {
1153                         $action = git_get_type($hash);
1154                         $action or die_error(404, "Object does not exist");
1155                 } elsif (defined $hash_base && defined $file_name) {
1156                         $action = git_get_type("$hash_base:$file_name");
1157                         $action or die_error(404, "File or directory does not exist");
1158                 } elsif (defined $project) {
1159                         $action = 'summary';
1160                 } else {
1161                         $action = 'project_list';
1162                 }
1163         }
1164         if (!defined($actions{$action})) {
1165                 die_error(400, "Unknown action");
1166         }
1167         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1168             !$project) {
1169                 die_error(400, "Project needed");
1170         }
1171         $actions{$action}->();
1172 }
1173
1174 sub reset_timer {
1175         our $t0 = [ gettimeofday() ]
1176                 if defined $t0;
1177         our $number_of_git_cmds = 0;
1178 }
1179
1180 our $first_request = 1;
1181 sub run_request {
1182         reset_timer();
1183
1184         evaluate_uri();
1185         if ($first_request) {
1186                 evaluate_gitweb_config();
1187                 evaluate_git_version();
1188         }
1189         if ($per_request_config) {
1190                 if (ref($per_request_config) eq 'CODE') {
1191                         $per_request_config->();
1192                 } elsif (!$first_request) {
1193                         evaluate_gitweb_config();
1194                 }
1195         }
1196         check_loadavg();
1197
1198         # $projectroot and $projects_list might be set in gitweb config file
1199         $projects_list ||= $projectroot;
1200
1201         evaluate_query_params();
1202         evaluate_path_info();
1203         evaluate_and_validate_params();
1204         evaluate_git_dir();
1205
1206         configure_gitweb_features();
1207
1208         dispatch();
1209 }
1210
1211 our $is_last_request = sub { 1 };
1212 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1213 our $CGI = 'CGI';
1214 our $cgi;
1215 sub configure_as_fcgi {
1216         require CGI::Fast;
1217         our $CGI = 'CGI::Fast';
1218
1219         my $request_number = 0;
1220         # let each child service 100 requests
1221         our $is_last_request = sub { ++$request_number > 100 };
1222 }
1223 sub evaluate_argv {
1224         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1225         configure_as_fcgi()
1226                 if $script_name =~ /\.fcgi$/;
1227
1228         return unless (@ARGV);
1229
1230         require Getopt::Long;
1231         Getopt::Long::GetOptions(
1232                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1233                 'nproc|n=i' => sub {
1234                         my ($arg, $val) = @_;
1235                         return unless eval { require FCGI::ProcManager; 1; };
1236                         my $proc_manager = FCGI::ProcManager->new({
1237                                 n_processes => $val,
1238                         });
1239                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1240                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1241                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1242                 },
1243         );
1244 }
1245
1246 sub run {
1247         evaluate_argv();
1248
1249         $first_request = 1;
1250         $pre_listen_hook->()
1251                 if $pre_listen_hook;
1252
1253  REQUEST:
1254         while ($cgi = $CGI->new()) {
1255                 $pre_dispatch_hook->()
1256                         if $pre_dispatch_hook;
1257
1258                 run_request();
1259
1260                 $post_dispatch_hook->()
1261                         if $post_dispatch_hook;
1262                 $first_request = 0;
1263
1264                 last REQUEST if ($is_last_request->());
1265         }
1266
1267  DONE_GITWEB:
1268         1;
1269 }
1270
1271 run();
1272
1273 if (defined caller) {
1274         # wrapped in a subroutine processing requests,
1275         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1276         return;
1277 } else {
1278         # pure CGI script, serving single request
1279         exit;
1280 }
1281
1282 ## ======================================================================
1283 ## action links
1284
1285 # possible values of extra options
1286 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1287 # -replay => 1      - start from a current view (replay with modifications)
1288 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1289 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1290 sub href {
1291         my %params = @_;
1292         # default is to use -absolute url() i.e. $my_uri
1293         my $href = $params{-full} ? $my_url : $my_uri;
1294
1295         # implicit -replay, must be first of implicit params
1296         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1297
1298         $params{'project'} = $project unless exists $params{'project'};
1299
1300         if ($params{-replay}) {
1301                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1302                         if (!exists $params{$name}) {
1303                                 $params{$name} = $input_params{$name};
1304                         }
1305                 }
1306         }
1307
1308         my $use_pathinfo = gitweb_check_feature('pathinfo');
1309         if (defined $params{'project'} &&
1310             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1311                 # try to put as many parameters as possible in PATH_INFO:
1312                 #   - project name
1313                 #   - action
1314                 #   - hash_parent or hash_parent_base:/file_parent
1315                 #   - hash or hash_base:/filename
1316                 #   - the snapshot_format as an appropriate suffix
1317
1318                 # When the script is the root DirectoryIndex for the domain,
1319                 # $href here would be something like http://gitweb.example.com/
1320                 # Thus, we strip any trailing / from $href, to spare us double
1321                 # slashes in the final URL
1322                 $href =~ s,/$,,;
1323
1324                 # Then add the project name, if present
1325                 $href .= "/".esc_path_info($params{'project'});
1326                 delete $params{'project'};
1327
1328                 # since we destructively absorb parameters, we keep this
1329                 # boolean that remembers if we're handling a snapshot
1330                 my $is_snapshot = $params{'action'} eq 'snapshot';
1331
1332                 # Summary just uses the project path URL, any other action is
1333                 # added to the URL
1334                 if (defined $params{'action'}) {
1335                         $href .= "/".esc_path_info($params{'action'})
1336                                 unless $params{'action'} eq 'summary';
1337                         delete $params{'action'};
1338                 }
1339
1340                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1341                 # stripping nonexistent or useless pieces
1342                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1343                         || $params{'hash_parent'} || $params{'hash'});
1344                 if (defined $params{'hash_base'}) {
1345                         if (defined $params{'hash_parent_base'}) {
1346                                 $href .= esc_path_info($params{'hash_parent_base'});
1347                                 # skip the file_parent if it's the same as the file_name
1348                                 if (defined $params{'file_parent'}) {
1349                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1350                                                 delete $params{'file_parent'};
1351                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1352                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1353                                                 delete $params{'file_parent'};
1354                                         }
1355                                 }
1356                                 $href .= "..";
1357                                 delete $params{'hash_parent'};
1358                                 delete $params{'hash_parent_base'};
1359                         } elsif (defined $params{'hash_parent'}) {
1360                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1361                                 delete $params{'hash_parent'};
1362                         }
1363
1364                         $href .= esc_path_info($params{'hash_base'});
1365                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1366                                 $href .= ":/".esc_path_info($params{'file_name'});
1367                                 delete $params{'file_name'};
1368                         }
1369                         delete $params{'hash'};
1370                         delete $params{'hash_base'};
1371                 } elsif (defined $params{'hash'}) {
1372                         $href .= esc_path_info($params{'hash'});
1373                         delete $params{'hash'};
1374                 }
1375
1376                 # If the action was a snapshot, we can absorb the
1377                 # snapshot_format parameter too
1378                 if ($is_snapshot) {
1379                         my $fmt = $params{'snapshot_format'};
1380                         # snapshot_format should always be defined when href()
1381                         # is called, but just in case some code forgets, we
1382                         # fall back to the default
1383                         $fmt ||= $snapshot_fmts[0];
1384                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1385                         delete $params{'snapshot_format'};
1386                 }
1387         }
1388
1389         # now encode the parameters explicitly
1390         my @result = ();
1391         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1392                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1393                 if (defined $params{$name}) {
1394                         if (ref($params{$name}) eq "ARRAY") {
1395                                 foreach my $par (@{$params{$name}}) {
1396                                         push @result, $symbol . "=" . esc_param($par);
1397                                 }
1398                         } else {
1399                                 push @result, $symbol . "=" . esc_param($params{$name});
1400                         }
1401                 }
1402         }
1403         $href .= "?" . join(';', @result) if scalar @result;
1404
1405         # final transformation: trailing spaces must be escaped (URI-encoded)
1406         $href =~ s/(\s+)$/CGI::escape($1)/e;
1407
1408         if ($params{-anchor}) {
1409                 $href .= "#".esc_param($params{-anchor});
1410         }
1411
1412         return $href;
1413 }
1414
1415
1416 ## ======================================================================
1417 ## validation, quoting/unquoting and escaping
1418
1419 sub validate_action {
1420         my $input = shift || return undef;
1421         return undef unless exists $actions{$input};
1422         return $input;
1423 }
1424
1425 sub validate_project {
1426         my $input = shift || return undef;
1427         if (!validate_pathname($input) ||
1428                 !(-d "$projectroot/$input") ||
1429                 !check_export_ok("$projectroot/$input") ||
1430                 ($strict_export && !project_in_list($input))) {
1431                 return undef;
1432         } else {
1433                 return $input;
1434         }
1435 }
1436
1437 sub validate_pathname {
1438         my $input = shift || return undef;
1439
1440         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1441         # at the beginning, at the end, and between slashes.
1442         # also this catches doubled slashes
1443         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1444                 return undef;
1445         }
1446         # no null characters
1447         if ($input =~ m!\0!) {
1448                 return undef;
1449         }
1450         return $input;
1451 }
1452
1453 sub validate_refname {
1454         my $input = shift || return undef;
1455
1456         # textual hashes are O.K.
1457         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1458                 return $input;
1459         }
1460         # it must be correct pathname
1461         $input = validate_pathname($input)
1462                 or return undef;
1463         # restrictions on ref name according to git-check-ref-format
1464         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1465                 return undef;
1466         }
1467         return $input;
1468 }
1469
1470 # decode sequences of octets in utf8 into Perl's internal form,
1471 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1472 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1473 sub to_utf8 {
1474         my $str = shift;
1475         return undef unless defined $str;
1476
1477         if (utf8::is_utf8($str) || utf8::decode($str)) {
1478                 return $str;
1479         } else {
1480                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1481         }
1482 }
1483
1484 # quote unsafe chars, but keep the slash, even when it's not
1485 # correct, but quoted slashes look too horrible in bookmarks
1486 sub esc_param {
1487         my $str = shift;
1488         return undef unless defined $str;
1489         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1490         $str =~ s/ /\+/g;
1491         return $str;
1492 }
1493
1494 # the quoting rules for path_info fragment are slightly different
1495 sub esc_path_info {
1496         my $str = shift;
1497         return undef unless defined $str;
1498
1499         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1500         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1501
1502         return $str;
1503 }
1504
1505 # quote unsafe chars in whole URL, so some characters cannot be quoted
1506 sub esc_url {
1507         my $str = shift;
1508         return undef unless defined $str;
1509         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1510         $str =~ s/ /\+/g;
1511         return $str;
1512 }
1513
1514 # quote unsafe characters in HTML attributes
1515 sub esc_attr {
1516
1517         # for XHTML conformance escaping '"' to '&quot;' is not enough
1518         return esc_html(@_);
1519 }
1520
1521 # replace invalid utf8 character with SUBSTITUTION sequence
1522 sub esc_html {
1523         my $str = shift;
1524         my %opts = @_;
1525
1526         return undef unless defined $str;
1527
1528         $str = to_utf8($str);
1529         $str = $cgi->escapeHTML($str);
1530         if ($opts{'-nbsp'}) {
1531                 $str =~ s/ /&nbsp;/g;
1532         }
1533         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1534         return $str;
1535 }
1536
1537 # quote control characters and escape filename to HTML
1538 sub esc_path {
1539         my $str = shift;
1540         my %opts = @_;
1541
1542         return undef unless defined $str;
1543
1544         $str = to_utf8($str);
1545         $str = $cgi->escapeHTML($str);
1546         if ($opts{'-nbsp'}) {
1547                 $str =~ s/ /&nbsp;/g;
1548         }
1549         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1550         return $str;
1551 }
1552
1553 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1554 sub sanitize {
1555         my $str = shift;
1556
1557         return undef unless defined $str;
1558
1559         $str = to_utf8($str);
1560         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1561         return $str;
1562 }
1563
1564 # Make control characters "printable", using character escape codes (CEC)
1565 sub quot_cec {
1566         my $cntrl = shift;
1567         my %opts = @_;
1568         my %es = ( # character escape codes, aka escape sequences
1569                 "\t" => '\t',   # tab            (HT)
1570                 "\n" => '\n',   # line feed      (LF)
1571                 "\r" => '\r',   # carrige return (CR)
1572                 "\f" => '\f',   # form feed      (FF)
1573                 "\b" => '\b',   # backspace      (BS)
1574                 "\a" => '\a',   # alarm (bell)   (BEL)
1575                 "\e" => '\e',   # escape         (ESC)
1576                 "\013" => '\v', # vertical tab   (VT)
1577                 "\000" => '\0', # nul character  (NUL)
1578         );
1579         my $chr = ( (exists $es{$cntrl})
1580                     ? $es{$cntrl}
1581                     : sprintf('\%2x', ord($cntrl)) );
1582         if ($opts{-nohtml}) {
1583                 return $chr;
1584         } else {
1585                 return "<span class=\"cntrl\">$chr</span>";
1586         }
1587 }
1588
1589 # Alternatively use unicode control pictures codepoints,
1590 # Unicode "printable representation" (PR)
1591 sub quot_upr {
1592         my $cntrl = shift;
1593         my %opts = @_;
1594
1595         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1596         if ($opts{-nohtml}) {
1597                 return $chr;
1598         } else {
1599                 return "<span class=\"cntrl\">$chr</span>";
1600         }
1601 }
1602
1603 # git may return quoted and escaped filenames
1604 sub unquote {
1605         my $str = shift;
1606
1607         sub unq {
1608                 my $seq = shift;
1609                 my %es = ( # character escape codes, aka escape sequences
1610                         't' => "\t",   # tab            (HT, TAB)
1611                         'n' => "\n",   # newline        (NL)
1612                         'r' => "\r",   # return         (CR)
1613                         'f' => "\f",   # form feed      (FF)
1614                         'b' => "\b",   # backspace      (BS)
1615                         'a' => "\a",   # alarm (bell)   (BEL)
1616                         'e' => "\e",   # escape         (ESC)
1617                         'v' => "\013", # vertical tab   (VT)
1618                 );
1619
1620                 if ($seq =~ m/^[0-7]{1,3}$/) {
1621                         # octal char sequence
1622                         return chr(oct($seq));
1623                 } elsif (exists $es{$seq}) {
1624                         # C escape sequence, aka character escape code
1625                         return $es{$seq};
1626                 }
1627                 # quoted ordinary character
1628                 return $seq;
1629         }
1630
1631         if ($str =~ m/^"(.*)"$/) {
1632                 # needs unquoting
1633                 $str = $1;
1634                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1635         }
1636         return $str;
1637 }
1638
1639 # escape tabs (convert tabs to spaces)
1640 sub untabify {
1641         my $line = shift;
1642
1643         while ((my $pos = index($line, "\t")) != -1) {
1644                 if (my $count = (8 - ($pos % 8))) {
1645                         my $spaces = ' ' x $count;
1646                         $line =~ s/\t/$spaces/;
1647                 }
1648         }
1649
1650         return $line;
1651 }
1652
1653 sub project_in_list {
1654         my $project = shift;
1655         my @list = git_get_projects_list();
1656         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1657 }
1658
1659 ## ----------------------------------------------------------------------
1660 ## HTML aware string manipulation
1661
1662 # Try to chop given string on a word boundary between position
1663 # $len and $len+$add_len. If there is no word boundary there,
1664 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1665 # (marking chopped part) would be longer than given string.
1666 sub chop_str {
1667         my $str = shift;
1668         my $len = shift;
1669         my $add_len = shift || 10;
1670         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1671
1672         # Make sure perl knows it is utf8 encoded so we don't
1673         # cut in the middle of a utf8 multibyte char.
1674         $str = to_utf8($str);
1675
1676         # allow only $len chars, but don't cut a word if it would fit in $add_len
1677         # if it doesn't fit, cut it if it's still longer than the dots we would add
1678         # remove chopped character entities entirely
1679
1680         # when chopping in the middle, distribute $len into left and right part
1681         # return early if chopping wouldn't make string shorter
1682         if ($where eq 'center') {
1683                 return $str if ($len + 5 >= length($str)); # filler is length 5
1684                 $len = int($len/2);
1685         } else {
1686                 return $str if ($len + 4 >= length($str)); # filler is length 4
1687         }
1688
1689         # regexps: ending and beginning with word part up to $add_len
1690         my $endre = qr/.{$len}\w{0,$add_len}/;
1691         my $begre = qr/\w{0,$add_len}.{$len}/;
1692
1693         if ($where eq 'left') {
1694                 $str =~ m/^(.*?)($begre)$/;
1695                 my ($lead, $body) = ($1, $2);
1696                 if (length($lead) > 4) {
1697                         $lead = " ...";
1698                 }
1699                 return "$lead$body";
1700
1701         } elsif ($where eq 'center') {
1702                 $str =~ m/^($endre)(.*)$/;
1703                 my ($left, $str)  = ($1, $2);
1704                 $str =~ m/^(.*?)($begre)$/;
1705                 my ($mid, $right) = ($1, $2);
1706                 if (length($mid) > 5) {
1707                         $mid = " ... ";
1708                 }
1709                 return "$left$mid$right";
1710
1711         } else {
1712                 $str =~ m/^($endre)(.*)$/;
1713                 my $body = $1;
1714                 my $tail = $2;
1715                 if (length($tail) > 4) {
1716                         $tail = "... ";
1717                 }
1718                 return "$body$tail";
1719         }
1720 }
1721
1722 # takes the same arguments as chop_str, but also wraps a <span> around the
1723 # result with a title attribute if it does get chopped. Additionally, the
1724 # string is HTML-escaped.
1725 sub chop_and_escape_str {
1726         my ($str) = @_;
1727
1728         my $chopped = chop_str(@_);
1729         $str = to_utf8($str);
1730         if ($chopped eq $str) {
1731                 return esc_html($chopped);
1732         } else {
1733                 $str =~ s/[[:cntrl:]]/?/g;
1734                 return $cgi->span({-title=>$str}, esc_html($chopped));
1735         }
1736 }
1737
1738 # Highlight selected fragments of string, using given CSS class,
1739 # and escape HTML.  It is assumed that fragments do not overlap.
1740 # Regions are passed as list of pairs (array references).
1741 #
1742 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1743 # '<span class="mark">foo</span>bar'
1744 sub esc_html_hl_regions {
1745         my ($str, $css_class, @sel) = @_;
1746         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1747         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1748         return esc_html($str, %opts) unless @sel;
1749
1750         my $out = '';
1751         my $pos = 0;
1752
1753         for my $s (@sel) {
1754                 my ($begin, $end) = @$s;
1755
1756                 # Don't create empty <span> elements.
1757                 next if $end <= $begin;
1758
1759                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1760                                        %opts);
1761
1762                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1763                         if ($begin - $pos > 0);
1764                 $out .= $cgi->span({-class => $css_class}, $escaped);
1765
1766                 $pos = $end;
1767         }
1768         $out .= esc_html(substr($str, $pos), %opts)
1769                 if ($pos < length($str));
1770
1771         return $out;
1772 }
1773
1774 # return positions of beginning and end of each match
1775 sub matchpos_list {
1776         my ($str, $regexp) = @_;
1777         return unless (defined $str && defined $regexp);
1778
1779         my @matches;
1780         while ($str =~ /$regexp/g) {
1781                 push @matches, [$-[0], $+[0]];
1782         }
1783         return @matches;
1784 }
1785
1786 # highlight match (if any), and escape HTML
1787 sub esc_html_match_hl {
1788         my ($str, $regexp) = @_;
1789         return esc_html($str) unless defined $regexp;
1790
1791         my @matches = matchpos_list($str, $regexp);
1792         return esc_html($str) unless @matches;
1793
1794         return esc_html_hl_regions($str, 'match', @matches);
1795 }
1796
1797
1798 # highlight match (if any) of shortened string, and escape HTML
1799 sub esc_html_match_hl_chopped {
1800         my ($str, $chopped, $regexp) = @_;
1801         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1802
1803         my @matches = matchpos_list($str, $regexp);
1804         return esc_html($chopped) unless @matches;
1805
1806         # filter matches so that we mark chopped string
1807         my $tail = "... "; # see chop_str
1808         unless ($chopped =~ s/\Q$tail\E$//) {
1809                 $tail = '';
1810         }
1811         my $chop_len = length($chopped);
1812         my $tail_len = length($tail);
1813         my @filtered;
1814
1815         for my $m (@matches) {
1816                 if ($m->[0] > $chop_len) {
1817                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1818                         last;
1819                 } elsif ($m->[1] > $chop_len) {
1820                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1821                         last;
1822                 }
1823                 push @filtered, $m;
1824         }
1825
1826         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1827 }
1828
1829 ## ----------------------------------------------------------------------
1830 ## functions returning short strings
1831
1832 # CSS class for given age value (in seconds)
1833 sub age_class {
1834         my $age = shift;
1835
1836         if (!defined $age) {
1837                 return "noage";
1838         } elsif ($age < 60*60*2) {
1839                 return "age0";
1840         } elsif ($age < 60*60*24*2) {
1841                 return "age1";
1842         } else {
1843                 return "age2";
1844         }
1845 }
1846
1847 # convert age in seconds to "nn units ago" string
1848 sub age_string {
1849         my $age = shift;
1850         my $age_str;
1851
1852         if ($age > 60*60*24*365*2) {
1853                 $age_str = (int $age/60/60/24/365);
1854                 $age_str .= " years ago";
1855         } elsif ($age > 60*60*24*(365/12)*2) {
1856                 $age_str = int $age/60/60/24/(365/12);
1857                 $age_str .= " months ago";
1858         } elsif ($age > 60*60*24*7*2) {
1859                 $age_str = int $age/60/60/24/7;
1860                 $age_str .= " weeks ago";
1861         } elsif ($age > 60*60*24*2) {
1862                 $age_str = int $age/60/60/24;
1863                 $age_str .= " days ago";
1864         } elsif ($age > 60*60*2) {
1865                 $age_str = int $age/60/60;
1866                 $age_str .= " hours ago";
1867         } elsif ($age > 60*2) {
1868                 $age_str = int $age/60;
1869                 $age_str .= " min ago";
1870         } elsif ($age > 2) {
1871                 $age_str = int $age;
1872                 $age_str .= " sec ago";
1873         } else {
1874                 $age_str .= " right now";
1875         }
1876         return $age_str;
1877 }
1878
1879 use constant {
1880         S_IFINVALID => 0030000,
1881         S_IFGITLINK => 0160000,
1882 };
1883
1884 # submodule/subproject, a commit object reference
1885 sub S_ISGITLINK {
1886         my $mode = shift;
1887
1888         return (($mode & S_IFMT) == S_IFGITLINK)
1889 }
1890
1891 # convert file mode in octal to symbolic file mode string
1892 sub mode_str {
1893         my $mode = oct shift;
1894
1895         if (S_ISGITLINK($mode)) {
1896                 return 'm---------';
1897         } elsif (S_ISDIR($mode & S_IFMT)) {
1898                 return 'drwxr-xr-x';
1899         } elsif (S_ISLNK($mode)) {
1900                 return 'lrwxrwxrwx';
1901         } elsif (S_ISREG($mode)) {
1902                 # git cares only about the executable bit
1903                 if ($mode & S_IXUSR) {
1904                         return '-rwxr-xr-x';
1905                 } else {
1906                         return '-rw-r--r--';
1907                 };
1908         } else {
1909                 return '----------';
1910         }
1911 }
1912
1913 # convert file mode in octal to file type string
1914 sub file_type {
1915         my $mode = shift;
1916
1917         if ($mode !~ m/^[0-7]+$/) {
1918                 return $mode;
1919         } else {
1920                 $mode = oct $mode;
1921         }
1922
1923         if (S_ISGITLINK($mode)) {
1924                 return "submodule";
1925         } elsif (S_ISDIR($mode & S_IFMT)) {
1926                 return "directory";
1927         } elsif (S_ISLNK($mode)) {
1928                 return "symlink";
1929         } elsif (S_ISREG($mode)) {
1930                 return "file";
1931         } else {
1932                 return "unknown";
1933         }
1934 }
1935
1936 # convert file mode in octal to file type description string
1937 sub file_type_long {
1938         my $mode = shift;
1939
1940         if ($mode !~ m/^[0-7]+$/) {
1941                 return $mode;
1942         } else {
1943                 $mode = oct $mode;
1944         }
1945
1946         if (S_ISGITLINK($mode)) {
1947                 return "submodule";
1948         } elsif (S_ISDIR($mode & S_IFMT)) {
1949                 return "directory";
1950         } elsif (S_ISLNK($mode)) {
1951                 return "symlink";
1952         } elsif (S_ISREG($mode)) {
1953                 if ($mode & S_IXUSR) {
1954                         return "executable";
1955                 } else {
1956                         return "file";
1957                 };
1958         } else {
1959                 return "unknown";
1960         }
1961 }
1962
1963
1964 ## ----------------------------------------------------------------------
1965 ## functions returning short HTML fragments, or transforming HTML fragments
1966 ## which don't belong to other sections
1967
1968 # format line of commit message.
1969 sub format_log_line_html {
1970         my $line = shift;
1971
1972         $line = esc_html($line, -nbsp=>1);
1973         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1974                 $cgi->a({-href => href(action=>"object", hash=>$1),
1975                                         -class => "text"}, $1);
1976         }eg;
1977
1978         return $line;
1979 }
1980
1981 # format marker of refs pointing to given object
1982
1983 # the destination action is chosen based on object type and current context:
1984 # - for annotated tags, we choose the tag view unless it's the current view
1985 #   already, in which case we go to shortlog view
1986 # - for other refs, we keep the current view if we're in history, shortlog or
1987 #   log view, and select shortlog otherwise
1988 sub format_ref_marker {
1989         my ($refs, $id) = @_;
1990         my $markers = '';
1991
1992         if (defined $refs->{$id}) {
1993                 foreach my $ref (@{$refs->{$id}}) {
1994                         # this code exploits the fact that non-lightweight tags are the
1995                         # only indirect objects, and that they are the only objects for which
1996                         # we want to use tag instead of shortlog as action
1997                         my ($type, $name) = qw();
1998                         my $indirect = ($ref =~ s/\^\{\}$//);
1999                         # e.g. tags/v2.6.11 or heads/next
2000                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
2001                                 $type = $1;
2002                                 $name = $2;
2003                         } else {
2004                                 $type = "ref";
2005                                 $name = $ref;
2006                         }
2007
2008                         my $class = $type;
2009                         $class .= " indirect" if $indirect;
2010
2011                         my $dest_action = "shortlog";
2012
2013                         if ($indirect) {
2014                                 $dest_action = "tag" unless $action eq "tag";
2015                         } elsif ($action =~ /^(history|(short)?log)$/) {
2016                                 $dest_action = $action;
2017                         }
2018
2019                         my $dest = "";
2020                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2021                         $dest .= $ref;
2022
2023                         my $link = $cgi->a({
2024                                 -href => href(
2025                                         action=>$dest_action,
2026                                         hash=>$dest
2027                                 )}, $name);
2028
2029                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2030                                 $link . "</span>";
2031                 }
2032         }
2033
2034         if ($markers) {
2035                 return ' <span class="refs">'. $markers . '</span>';
2036         } else {
2037                 return "";
2038         }
2039 }
2040
2041 # format, perhaps shortened and with markers, title line
2042 sub format_subject_html {
2043         my ($long, $short, $href, $extra) = @_;
2044         $extra = '' unless defined($extra);
2045
2046         if (length($short) < length($long)) {
2047                 $long =~ s/[[:cntrl:]]/?/g;
2048                 return $cgi->a({-href => $href, -class => "list subject",
2049                                 -title => to_utf8($long)},
2050                        esc_html($short)) . $extra;
2051         } else {
2052                 return $cgi->a({-href => $href, -class => "list subject"},
2053                        esc_html($long)) . $extra;
2054         }
2055 }
2056
2057 # Rather than recomputing the url for an email multiple times, we cache it
2058 # after the first hit. This gives a visible benefit in views where the avatar
2059 # for the same email is used repeatedly (e.g. shortlog).
2060 # The cache is shared by all avatar engines (currently gravatar only), which
2061 # are free to use it as preferred. Since only one avatar engine is used for any
2062 # given page, there's no risk for cache conflicts.
2063 our %avatar_cache = ();
2064
2065 # Compute the picon url for a given email, by using the picon search service over at
2066 # http://www.cs.indiana.edu/picons/search.html
2067 sub picon_url {
2068         my $email = lc shift;
2069         if (!$avatar_cache{$email}) {
2070                 my ($user, $domain) = split('@', $email);
2071                 $avatar_cache{$email} =
2072                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2073                         "$domain/$user/" .
2074                         "users+domains+unknown/up/single";
2075         }
2076         return $avatar_cache{$email};
2077 }
2078
2079 # Compute the gravatar url for a given email, if it's not in the cache already.
2080 # Gravatar stores only the part of the URL before the size, since that's the
2081 # one computationally more expensive. This also allows reuse of the cache for
2082 # different sizes (for this particular engine).
2083 sub gravatar_url {
2084         my $email = lc shift;
2085         my $size = shift;
2086         $avatar_cache{$email} ||=
2087                 "http://www.gravatar.com/avatar/" .
2088                         Digest::MD5::md5_hex($email) . "?s=";
2089         return $avatar_cache{$email} . $size;
2090 }
2091
2092 # Insert an avatar for the given $email at the given $size if the feature
2093 # is enabled.
2094 sub git_get_avatar {
2095         my ($email, %opts) = @_;
2096         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2097         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2098         $opts{-size} ||= 'default';
2099         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2100         my $url = "";
2101         if ($git_avatar eq 'gravatar') {
2102                 $url = gravatar_url($email, $size);
2103         } elsif ($git_avatar eq 'picon') {
2104                 $url = picon_url($email);
2105         }
2106         # Other providers can be added by extending the if chain, defining $url
2107         # as needed. If no variant puts something in $url, we assume avatars
2108         # are completely disabled/unavailable.
2109         if ($url) {
2110                 return $pre_white .
2111                        "<img width=\"$size\" " .
2112                             "class=\"avatar\" " .
2113                             "src=\"".esc_url($url)."\" " .
2114                             "alt=\"\" " .
2115                        "/>" . $post_white;
2116         } else {
2117                 return "";
2118         }
2119 }
2120
2121 sub format_search_author {
2122         my ($author, $searchtype, $displaytext) = @_;
2123         my $have_search = gitweb_check_feature('search');
2124
2125         if ($have_search) {
2126                 my $performed = "";
2127                 if ($searchtype eq 'author') {
2128                         $performed = "authored";
2129                 } elsif ($searchtype eq 'committer') {
2130                         $performed = "committed";
2131                 }
2132
2133                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2134                                 searchtext=>$author,
2135                                 searchtype=>$searchtype), class=>"list",
2136                                 title=>"Search for commits $performed by $author"},
2137                                 $displaytext);
2138
2139         } else {
2140                 return $displaytext;
2141         }
2142 }
2143
2144 # format the author name of the given commit with the given tag
2145 # the author name is chopped and escaped according to the other
2146 # optional parameters (see chop_str).
2147 sub format_author_html {
2148         my $tag = shift;
2149         my $co = shift;
2150         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2151         return "<$tag class=\"author\">" .
2152                format_search_author($co->{'author_name'}, "author",
2153                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2154                        $author) .
2155                "</$tag>";
2156 }
2157
2158 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2159 sub format_git_diff_header_line {
2160         my $line = shift;
2161         my $diffinfo = shift;
2162         my ($from, $to) = @_;
2163
2164         if ($diffinfo->{'nparents'}) {
2165                 # combined diff
2166                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2167                 if ($to->{'href'}) {
2168                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2169                                          esc_path($to->{'file'}));
2170                 } else { # file was deleted (no href)
2171                         $line .= esc_path($to->{'file'});
2172                 }
2173         } else {
2174                 # "ordinary" diff
2175                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2176                 if ($from->{'href'}) {
2177                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2178                                          'a/' . esc_path($from->{'file'}));
2179                 } else { # file was added (no href)
2180                         $line .= 'a/' . esc_path($from->{'file'});
2181                 }
2182                 $line .= ' ';
2183                 if ($to->{'href'}) {
2184                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2185                                          'b/' . esc_path($to->{'file'}));
2186                 } else { # file was deleted
2187                         $line .= 'b/' . esc_path($to->{'file'});
2188                 }
2189         }
2190
2191         return "<div class=\"diff header\">$line</div>\n";
2192 }
2193
2194 # format extended diff header line, before patch itself
2195 sub format_extended_diff_header_line {
2196         my $line = shift;
2197         my $diffinfo = shift;
2198         my ($from, $to) = @_;
2199
2200         # match <path>
2201         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2202                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2203                                        esc_path($from->{'file'}));
2204         }
2205         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2206                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2207                                  esc_path($to->{'file'}));
2208         }
2209         # match single <mode>
2210         if ($line =~ m/\s(\d{6})$/) {
2211                 $line .= '<span class="info"> (' .
2212                          file_type_long($1) .
2213                          ')</span>';
2214         }
2215         # match <hash>
2216         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2217                 # can match only for combined diff
2218                 $line = 'index ';
2219                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2220                         if ($from->{'href'}[$i]) {
2221                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2222                                                   -class=>"hash"},
2223                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2224                         } else {
2225                                 $line .= '0' x 7;
2226                         }
2227                         # separator
2228                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2229                 }
2230                 $line .= '..';
2231                 if ($to->{'href'}) {
2232                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2233                                          substr($diffinfo->{'to_id'},0,7));
2234                 } else {
2235                         $line .= '0' x 7;
2236                 }
2237
2238         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2239                 # can match only for ordinary diff
2240                 my ($from_link, $to_link);
2241                 if ($from->{'href'}) {
2242                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2243                                              substr($diffinfo->{'from_id'},0,7));
2244                 } else {
2245                         $from_link = '0' x 7;
2246                 }
2247                 if ($to->{'href'}) {
2248                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2249                                            substr($diffinfo->{'to_id'},0,7));
2250                 } else {
2251                         $to_link = '0' x 7;
2252                 }
2253                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2254                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2255         }
2256
2257         return $line . "<br/>\n";
2258 }
2259
2260 # format from-file/to-file diff header
2261 sub format_diff_from_to_header {
2262         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2263         my $line;
2264         my $result = '';
2265
2266         $line = $from_line;
2267         #assert($line =~ m/^---/) if DEBUG;
2268         # no extra formatting for "^--- /dev/null"
2269         if (! $diffinfo->{'nparents'}) {
2270                 # ordinary (single parent) diff
2271                 if ($line =~ m!^--- "?a/!) {
2272                         if ($from->{'href'}) {
2273                                 $line = '--- a/' .
2274                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2275                                                 esc_path($from->{'file'}));
2276                         } else {
2277                                 $line = '--- a/' .
2278                                         esc_path($from->{'file'});
2279                         }
2280                 }
2281                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2282
2283         } else {
2284                 # combined diff (merge commit)
2285                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2286                         if ($from->{'href'}[$i]) {
2287                                 $line = '--- ' .
2288                                         $cgi->a({-href=>href(action=>"blobdiff",
2289                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2290                                                              hash_parent_base=>$parents[$i],
2291                                                              file_parent=>$from->{'file'}[$i],
2292                                                              hash=>$diffinfo->{'to_id'},
2293                                                              hash_base=>$hash,
2294                                                              file_name=>$to->{'file'}),
2295                                                  -class=>"path",
2296                                                  -title=>"diff" . ($i+1)},
2297                                                 $i+1) .
2298                                         '/' .
2299                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2300                                                 esc_path($from->{'file'}[$i]));
2301                         } else {
2302                                 $line = '--- /dev/null';
2303                         }
2304                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2305                 }
2306         }
2307
2308         $line = $to_line;
2309         #assert($line =~ m/^\+\+\+/) if DEBUG;
2310         # no extra formatting for "^+++ /dev/null"
2311         if ($line =~ m!^\+\+\+ "?b/!) {
2312                 if ($to->{'href'}) {
2313                         $line = '+++ b/' .
2314                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2315                                         esc_path($to->{'file'}));
2316                 } else {
2317                         $line = '+++ b/' .
2318                                 esc_path($to->{'file'});
2319                 }
2320         }
2321         $result .= qq!<div class="diff to_file">$line</div>\n!;
2322
2323         return $result;
2324 }
2325
2326 # create note for patch simplified by combined diff
2327 sub format_diff_cc_simplified {
2328         my ($diffinfo, @parents) = @_;
2329         my $result = '';
2330
2331         $result .= "<div class=\"diff header\">" .
2332                    "diff --cc ";
2333         if (!is_deleted($diffinfo)) {
2334                 $result .= $cgi->a({-href => href(action=>"blob",
2335                                                   hash_base=>$hash,
2336                                                   hash=>$diffinfo->{'to_id'},
2337                                                   file_name=>$diffinfo->{'to_file'}),
2338                                     -class => "path"},
2339                                    esc_path($diffinfo->{'to_file'}));
2340         } else {
2341                 $result .= esc_path($diffinfo->{'to_file'});
2342         }
2343         $result .= "</div>\n" . # class="diff header"
2344                    "<div class=\"diff nodifferences\">" .
2345                    "Simple merge" .
2346                    "</div>\n"; # class="diff nodifferences"
2347
2348         return $result;
2349 }
2350
2351 sub diff_line_class {
2352         my ($line, $from, $to) = @_;
2353
2354         # ordinary diff
2355         my $num_sign = 1;
2356         # combined diff
2357         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2358                 $num_sign = scalar @{$from->{'href'}};
2359         }
2360
2361         my @diff_line_classifier = (
2362                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2363                 { regexp => qr/^\\/,               class => "incomplete"  },
2364                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2365                 # classifier for context must come before classifier add/rem,
2366                 # or we would have to use more complicated regexp, for example
2367                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2368                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2369                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2370         );
2371         for my $clsfy (@diff_line_classifier) {
2372                 return $clsfy->{'class'}
2373                         if ($line =~ $clsfy->{'regexp'});
2374         }
2375
2376         # fallback
2377         return "";
2378 }
2379
2380 # assumes that $from and $to are defined and correctly filled,
2381 # and that $line holds a line of chunk header for unified diff
2382 sub format_unidiff_chunk_header {
2383         my ($line, $from, $to) = @_;
2384
2385         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2386                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2387
2388         $from_lines = 0 unless defined $from_lines;
2389         $to_lines   = 0 unless defined $to_lines;
2390
2391         if ($from->{'href'}) {
2392                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2393                                      -class=>"list"}, $from_text);
2394         }
2395         if ($to->{'href'}) {
2396                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2397                                      -class=>"list"}, $to_text);
2398         }
2399         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2400                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2401         return $line;
2402 }
2403
2404 # assumes that $from and $to are defined and correctly filled,
2405 # and that $line holds a line of chunk header for combined diff
2406 sub format_cc_diff_chunk_header {
2407         my ($line, $from, $to) = @_;
2408
2409         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2410         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2411
2412         @from_text = split(' ', $ranges);
2413         for (my $i = 0; $i < @from_text; ++$i) {
2414                 ($from_start[$i], $from_nlines[$i]) =
2415                         (split(',', substr($from_text[$i], 1)), 0);
2416         }
2417
2418         $to_text   = pop @from_text;
2419         $to_start  = pop @from_start;
2420         $to_nlines = pop @from_nlines;
2421
2422         $line = "<span class=\"chunk_info\">$prefix ";
2423         for (my $i = 0; $i < @from_text; ++$i) {
2424                 if ($from->{'href'}[$i]) {
2425                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2426                                           -class=>"list"}, $from_text[$i]);
2427                 } else {
2428                         $line .= $from_text[$i];
2429                 }
2430                 $line .= " ";
2431         }
2432         if ($to->{'href'}) {
2433                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2434                                   -class=>"list"}, $to_text);
2435         } else {
2436                 $line .= $to_text;
2437         }
2438         $line .= " $prefix</span>" .
2439                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2440         return $line;
2441 }
2442
2443 # process patch (diff) line (not to be used for diff headers),
2444 # returning HTML-formatted (but not wrapped) line.
2445 # If the line is passed as a reference, it is treated as HTML and not
2446 # esc_html()'ed.
2447 sub format_diff_line {
2448         my ($line, $diff_class, $from, $to) = @_;
2449
2450         if (ref($line)) {
2451                 $line = $$line;
2452         } else {
2453                 chomp $line;
2454                 $line = untabify($line);
2455
2456                 if ($from && $to && $line =~ m/^\@{2} /) {
2457                         $line = format_unidiff_chunk_header($line, $from, $to);
2458                 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2459                         $line = format_cc_diff_chunk_header($line, $from, $to);
2460                 } else {
2461                         $line = esc_html($line, -nbsp=>1);
2462                 }
2463         }
2464
2465         my $diff_classes = "diff";
2466         $diff_classes .= " $diff_class" if ($diff_class);
2467         $line = "<div class=\"$diff_classes\">$line</div>\n";
2468
2469         return $line;
2470 }
2471
2472 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2473 # linked.  Pass the hash of the tree/commit to snapshot.
2474 sub format_snapshot_links {
2475         my ($hash) = @_;
2476         my $num_fmts = @snapshot_fmts;
2477         if ($num_fmts > 1) {
2478                 # A parenthesized list of links bearing format names.
2479                 # e.g. "snapshot (_tar.gz_ _zip_)"
2480                 return "snapshot (" . join(' ', map
2481                         $cgi->a({
2482                                 -href => href(
2483                                         action=>"snapshot",
2484                                         hash=>$hash,
2485                                         snapshot_format=>$_
2486                                 )
2487                         }, $known_snapshot_formats{$_}{'display'})
2488                 , @snapshot_fmts) . ")";
2489         } elsif ($num_fmts == 1) {
2490                 # A single "snapshot" link whose tooltip bears the format name.
2491                 # i.e. "_snapshot_"
2492                 my ($fmt) = @snapshot_fmts;
2493                 return
2494                         $cgi->a({
2495                                 -href => href(
2496                                         action=>"snapshot",
2497                                         hash=>$hash,
2498                                         snapshot_format=>$fmt
2499                                 ),
2500                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2501                         }, "snapshot");
2502         } else { # $num_fmts == 0
2503                 return undef;
2504         }
2505 }
2506
2507 ## ......................................................................
2508 ## functions returning values to be passed, perhaps after some
2509 ## transformation, to other functions; e.g. returning arguments to href()
2510
2511 # returns hash to be passed to href to generate gitweb URL
2512 # in -title key it returns description of link
2513 sub get_feed_info {
2514         my $format = shift || 'Atom';
2515         my %res = (action => lc($format));
2516
2517         # feed links are possible only for project views
2518         return unless (defined $project);
2519         # some views should link to OPML, or to generic project feed,
2520         # or don't have specific feed yet (so they should use generic)
2521         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2522
2523         my $branch;
2524         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2525         # from tag links; this also makes possible to detect branch links
2526         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2527             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2528                 $branch = $1;
2529         }
2530         # find log type for feed description (title)
2531         my $type = 'log';
2532         if (defined $file_name) {
2533                 $type  = "history of $file_name";
2534                 $type .= "/" if ($action eq 'tree');
2535                 $type .= " on '$branch'" if (defined $branch);
2536         } else {
2537                 $type = "log of $branch" if (defined $branch);
2538         }
2539
2540         $res{-title} = $type;
2541         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2542         $res{'file_name'} = $file_name;
2543
2544         return %res;
2545 }
2546
2547 ## ----------------------------------------------------------------------
2548 ## git utility subroutines, invoking git commands
2549
2550 # returns path to the core git executable and the --git-dir parameter as list
2551 sub git_cmd {
2552         $number_of_git_cmds++;
2553         return $GIT, '--git-dir='.$git_dir;
2554 }
2555
2556 # quote the given arguments for passing them to the shell
2557 # quote_command("command", "arg 1", "arg with ' and ! characters")
2558 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2559 # Try to avoid using this function wherever possible.
2560 sub quote_command {
2561         return join(' ',
2562                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2563 }
2564
2565 # get HEAD ref of given project as hash
2566 sub git_get_head_hash {
2567         return git_get_full_hash(shift, 'HEAD');
2568 }
2569
2570 sub git_get_full_hash {
2571         return git_get_hash(@_);
2572 }
2573
2574 sub git_get_short_hash {
2575         return git_get_hash(@_, '--short=7');
2576 }
2577
2578 sub git_get_hash {
2579         my ($project, $hash, @options) = @_;
2580         my $o_git_dir = $git_dir;
2581         my $retval = undef;
2582         $git_dir = "$projectroot/$project";
2583         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2584             '--verify', '-q', @options, $hash) {
2585                 $retval = <$fd>;
2586                 chomp $retval if defined $retval;
2587                 close $fd;
2588         }
2589         if (defined $o_git_dir) {
2590                 $git_dir = $o_git_dir;
2591         }
2592         return $retval;
2593 }
2594
2595 # get type of given object
2596 sub git_get_type {
2597         my $hash = shift;
2598
2599         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2600         my $type = <$fd>;
2601         close $fd or return;
2602         chomp $type;
2603         return $type;
2604 }
2605
2606 # repository configuration
2607 our $config_file = '';
2608 our %config;
2609
2610 # store multiple values for single key as anonymous array reference
2611 # single values stored directly in the hash, not as [ <value> ]
2612 sub hash_set_multi {
2613         my ($hash, $key, $value) = @_;
2614
2615         if (!exists $hash->{$key}) {
2616                 $hash->{$key} = $value;
2617         } elsif (!ref $hash->{$key}) {
2618                 $hash->{$key} = [ $hash->{$key}, $value ];
2619         } else {
2620                 push @{$hash->{$key}}, $value;
2621         }
2622 }
2623
2624 # return hash of git project configuration
2625 # optionally limited to some section, e.g. 'gitweb'
2626 sub git_parse_project_config {
2627         my $section_regexp = shift;
2628         my %config;
2629
2630         local $/ = "\0";
2631
2632         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2633                 or return;
2634
2635         while (my $keyval = <$fh>) {
2636                 chomp $keyval;
2637                 my ($key, $value) = split(/\n/, $keyval, 2);
2638
2639                 hash_set_multi(\%config, $key, $value)
2640                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2641         }
2642         close $fh;
2643
2644         return %config;
2645 }
2646
2647 # convert config value to boolean: 'true' or 'false'
2648 # no value, number > 0, 'true' and 'yes' values are true
2649 # rest of values are treated as false (never as error)
2650 sub config_to_bool {
2651         my $val = shift;
2652
2653         return 1 if !defined $val;             # section.key
2654
2655         # strip leading and trailing whitespace
2656         $val =~ s/^\s+//;
2657         $val =~ s/\s+$//;
2658
2659         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2660                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2661 }
2662
2663 # convert config value to simple decimal number
2664 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2665 # to be multiplied by 1024, 1048576, or 1073741824
2666 sub config_to_int {
2667         my $val = shift;
2668
2669         # strip leading and trailing whitespace
2670         $val =~ s/^\s+//;
2671         $val =~ s/\s+$//;
2672
2673         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2674                 $unit = lc($unit);
2675                 # unknown unit is treated as 1
2676                 return $num * ($unit eq 'g' ? 1073741824 :
2677                                $unit eq 'm' ?    1048576 :
2678                                $unit eq 'k' ?       1024 : 1);
2679         }
2680         return $val;
2681 }
2682
2683 # convert config value to array reference, if needed
2684 sub config_to_multi {
2685         my $val = shift;
2686
2687         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2688 }
2689
2690 sub git_get_project_config {
2691         my ($key, $type) = @_;
2692
2693         return unless defined $git_dir;
2694
2695         # key sanity check
2696         return unless ($key);
2697         # only subsection, if exists, is case sensitive,
2698         # and not lowercased by 'git config -z -l'
2699         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2700                 $key = join(".", lc($hi), $mi, lc($lo));
2701         } else {
2702                 $key = lc($key);
2703         }
2704         $key =~ s/^gitweb\.//;
2705         return if ($key =~ m/\W/);
2706
2707         # type sanity check
2708         if (defined $type) {
2709                 $type =~ s/^--//;
2710                 $type = undef
2711                         unless ($type eq 'bool' || $type eq 'int');
2712         }
2713
2714         # get config
2715         if (!defined $config_file ||
2716             $config_file ne "$git_dir/config") {
2717                 %config = git_parse_project_config('gitweb');
2718                 $config_file = "$git_dir/config";
2719         }
2720
2721         # check if config variable (key) exists
2722         return unless exists $config{"gitweb.$key"};
2723
2724         # ensure given type
2725         if (!defined $type) {
2726                 return $config{"gitweb.$key"};
2727         } elsif ($type eq 'bool') {
2728                 # backward compatibility: 'git config --bool' returns true/false
2729                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2730         } elsif ($type eq 'int') {
2731                 return config_to_int($config{"gitweb.$key"});
2732         }
2733         return $config{"gitweb.$key"};
2734 }
2735
2736 # get hash of given path at given ref
2737 sub git_get_hash_by_path {
2738         my $base = shift;
2739         my $path = shift || return undef;
2740         my $type = shift;
2741
2742         $path =~ s,/+$,,;
2743
2744         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2745                 or die_error(500, "Open git-ls-tree failed");
2746         my $line = <$fd>;
2747         close $fd or return undef;
2748
2749         if (!defined $line) {
2750                 # there is no tree or hash given by $path at $base
2751                 return undef;
2752         }
2753
2754         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2755         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2756         if (defined $type && $type ne $2) {
2757                 # type doesn't match
2758                 return undef;
2759         }
2760         return $3;
2761 }
2762
2763 # get path of entry with given hash at given tree-ish (ref)
2764 # used to get 'from' filename for combined diff (merge commit) for renames
2765 sub git_get_path_by_hash {
2766         my $base = shift || return;
2767         my $hash = shift || return;
2768
2769         local $/ = "\0";
2770
2771         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2772                 or return undef;
2773         while (my $line = <$fd>) {
2774                 chomp $line;
2775
2776                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2777                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2778                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2779                         close $fd;
2780                         return $1;
2781                 }
2782         }
2783         close $fd;
2784         return undef;
2785 }
2786
2787 ## ......................................................................
2788 ## git utility functions, directly accessing git repository
2789
2790 # get the value of config variable either from file named as the variable
2791 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2792 # configuration variable in the repository config file.
2793 sub git_get_file_or_project_config {
2794         my ($path, $name) = @_;
2795
2796         $git_dir = "$projectroot/$path";
2797         open my $fd, '<', "$git_dir/$name"
2798                 or return git_get_project_config($name);
2799         my $conf = <$fd>;
2800         close $fd;
2801         if (defined $conf) {
2802                 chomp $conf;
2803         }
2804         return $conf;
2805 }
2806
2807 sub git_get_project_description {
2808         my $path = shift;
2809         return git_get_file_or_project_config($path, 'description');
2810 }
2811
2812 sub git_get_project_category {
2813         my $path = shift;
2814         return git_get_file_or_project_config($path, 'category');
2815 }
2816
2817
2818 # supported formats:
2819 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2820 #   - if its contents is a number, use it as tag weight,
2821 #   - otherwise add a tag with weight 1
2822 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2823 #   the same value multiple times increases tag weight
2824 # * `gitweb.ctag' multi-valued repo config variable
2825 sub git_get_project_ctags {
2826         my $project = shift;
2827         my $ctags = {};
2828
2829         $git_dir = "$projectroot/$project";
2830         if (opendir my $dh, "$git_dir/ctags") {
2831                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2832                 foreach my $tagfile (@files) {
2833                         open my $ct, '<', $tagfile
2834                                 or next;
2835                         my $val = <$ct>;
2836                         chomp $val if $val;
2837                         close $ct;
2838
2839                         (my $ctag = $tagfile) =~ s#.*/##;
2840                         if ($val =~ /^\d+$/) {
2841                                 $ctags->{$ctag} = $val;
2842                         } else {
2843                                 $ctags->{$ctag} = 1;
2844                         }
2845                 }
2846                 closedir $dh;
2847
2848         } elsif (open my $fh, '<', "$git_dir/ctags") {
2849                 while (my $line = <$fh>) {
2850                         chomp $line;
2851                         $ctags->{$line}++ if $line;
2852                 }
2853                 close $fh;
2854
2855         } else {
2856                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2857                 foreach my $tag (@$taglist) {
2858                         $ctags->{$tag}++;
2859                 }
2860         }
2861
2862         return $ctags;
2863 }
2864
2865 # return hash, where keys are content tags ('ctags'),
2866 # and values are sum of weights of given tag in every project
2867 sub git_gather_all_ctags {
2868         my $projects = shift;
2869         my $ctags = {};
2870
2871         foreach my $p (@$projects) {
2872                 foreach my $ct (keys %{$p->{'ctags'}}) {
2873                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2874                 }
2875         }
2876
2877         return $ctags;
2878 }
2879
2880 sub git_populate_project_tagcloud {
2881         my $ctags = shift;
2882
2883         # First, merge different-cased tags; tags vote on casing
2884         my %ctags_lc;
2885         foreach (keys %$ctags) {
2886                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2887                 if (not $ctags_lc{lc $_}->{topcount}
2888                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2889                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2890                         $ctags_lc{lc $_}->{topname} = $_;
2891                 }
2892         }
2893
2894         my $cloud;
2895         my $matched = $input_params{'ctag'};
2896         if (eval { require HTML::TagCloud; 1; }) {
2897                 $cloud = HTML::TagCloud->new;
2898                 foreach my $ctag (sort keys %ctags_lc) {
2899                         # Pad the title with spaces so that the cloud looks
2900                         # less crammed.
2901                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2902                         $title =~ s/ /&nbsp;/g;
2903                         $title =~ s/^/&nbsp;/g;
2904                         $title =~ s/$/&nbsp;/g;
2905                         if (defined $matched && $matched eq $ctag) {
2906                                 $title = qq(<span class="match">$title</span>);
2907                         }
2908                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2909                                     $ctags_lc{$ctag}->{count});
2910                 }
2911         } else {
2912                 $cloud = {};
2913                 foreach my $ctag (keys %ctags_lc) {
2914                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2915                         if (defined $matched && $matched eq $ctag) {
2916                                 $title = qq(<span class="match">$title</span>);
2917                         }
2918                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2919                         $cloud->{$ctag}{ctag} =
2920                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2921                 }
2922         }
2923         return $cloud;
2924 }
2925
2926 sub git_show_project_tagcloud {
2927         my ($cloud, $count) = @_;
2928         if (ref $cloud eq 'HTML::TagCloud') {
2929                 return $cloud->html_and_css($count);
2930         } else {
2931                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2932                 return
2933                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2934                         join (', ', map {
2935                                 $cloud->{$_}->{'ctag'}
2936                         } splice(@tags, 0, $count)) .
2937                         '</div>';
2938         }
2939 }
2940
2941 sub git_get_project_url_list {
2942         my $path = shift;
2943
2944         $git_dir = "$projectroot/$path";
2945         open my $fd, '<', "$git_dir/cloneurl"
2946                 or return wantarray ?
2947                 @{ config_to_multi(git_get_project_config('url')) } :
2948                    config_to_multi(git_get_project_config('url'));
2949         my @git_project_url_list = map { chomp; $_ } <$fd>;
2950         close $fd;
2951
2952         return wantarray ? @git_project_url_list : \@git_project_url_list;
2953 }
2954
2955 sub git_get_projects_list {
2956         my $filter = shift || '';
2957         my $paranoid = shift;
2958         my @list;
2959
2960         if (-d $projects_list) {
2961                 # search in directory
2962                 my $dir = $projects_list;
2963                 # remove the trailing "/"
2964                 $dir =~ s!/+$!!;
2965                 my $pfxlen = length("$dir");
2966                 my $pfxdepth = ($dir =~ tr!/!!);
2967                 # when filtering, search only given subdirectory
2968                 if ($filter && !$paranoid) {
2969                         $dir .= "/$filter";
2970                         $dir =~ s!/+$!!;
2971                 }
2972
2973                 File::Find::find({
2974                         follow_fast => 1, # follow symbolic links
2975                         follow_skip => 2, # ignore duplicates
2976                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2977                         wanted => sub {
2978                                 # global variables
2979                                 our $project_maxdepth;
2980                                 our $projectroot;
2981                                 # skip project-list toplevel, if we get it.
2982                                 return if (m!^[/.]$!);
2983                                 # only directories can be git repositories
2984                                 return unless (-d $_);
2985                                 # don't traverse too deep (Find is super slow on os x)
2986                                 # $project_maxdepth excludes depth of $projectroot
2987                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2988                                         $File::Find::prune = 1;
2989                                         return;
2990                                 }
2991
2992                                 my $path = substr($File::Find::name, $pfxlen + 1);
2993                                 # paranoidly only filter here
2994                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
2995                                         next;
2996                                 }
2997                                 # we check related file in $projectroot
2998                                 if (check_export_ok("$projectroot/$path")) {
2999                                         push @list, { path => $path };
3000                                         $File::Find::prune = 1;
3001                                 }
3002                         },
3003                 }, "$dir");
3004
3005         } elsif (-f $projects_list) {
3006                 # read from file(url-encoded):
3007                 # 'git%2Fgit.git Linus+Torvalds'
3008                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3009                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3010                 open my $fd, '<', $projects_list or return;
3011         PROJECT:
3012                 while (my $line = <$fd>) {
3013                         chomp $line;
3014                         my ($path, $owner) = split ' ', $line;
3015                         $path = unescape($path);
3016                         $owner = unescape($owner);
3017                         if (!defined $path) {
3018                                 next;
3019                         }
3020                         # if $filter is rpovided, check if $path begins with $filter
3021                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3022                                 next;
3023                         }
3024                         if (check_export_ok("$projectroot/$path")) {
3025                                 my $pr = {
3026                                         path => $path
3027                                 };
3028                                 if ($owner) {
3029                                         $pr->{'owner'} = to_utf8($owner);
3030                                 }
3031                                 push @list, $pr;
3032                         }
3033                 }
3034                 close $fd;
3035         }
3036         return @list;
3037 }
3038
3039 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3040 # as side effects it sets 'forks' field to list of forks for forked projects
3041 sub filter_forks_from_projects_list {
3042         my $projects = shift;
3043
3044         my %trie; # prefix tree of directories (path components)
3045         # generate trie out of those directories that might contain forks
3046         foreach my $pr (@$projects) {
3047                 my $path = $pr->{'path'};
3048                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3049                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3050                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3051                 next unless (-d "$projectroot/$path"); # containing directory exists
3052                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3053
3054                 # add to trie
3055                 my @dirs = split('/', $path);
3056                 # walk the trie, until either runs out of components or out of trie
3057                 my $ref = \%trie;
3058                 while (scalar @dirs &&
3059                        exists($ref->{$dirs[0]})) {
3060                         $ref = $ref->{shift @dirs};
3061                 }
3062                 # create rest of trie structure from rest of components
3063                 foreach my $dir (@dirs) {
3064                         $ref = $ref->{$dir} = {};
3065                 }
3066                 # create end marker, store $pr as a data
3067                 $ref->{''} = $pr if (!exists $ref->{''});
3068         }
3069
3070         # filter out forks, by finding shortest prefix match for paths
3071         my @filtered;
3072  PROJECT:
3073         foreach my $pr (@$projects) {
3074                 # trie lookup
3075                 my $ref = \%trie;
3076         DIR:
3077                 foreach my $dir (split('/', $pr->{'path'})) {
3078                         if (exists $ref->{''}) {
3079                                 # found [shortest] prefix, is a fork - skip it
3080                                 push @{$ref->{''}{'forks'}}, $pr;
3081                                 next PROJECT;
3082                         }
3083                         if (!exists $ref->{$dir}) {
3084                                 # not in trie, cannot have prefix, not a fork
3085                                 push @filtered, $pr;
3086                                 next PROJECT;
3087                         }
3088                         # If the dir is there, we just walk one step down the trie.
3089                         $ref = $ref->{$dir};
3090                 }
3091                 # we ran out of trie
3092                 # (shouldn't happen: it's either no match, or end marker)
3093                 push @filtered, $pr;
3094         }
3095
3096         return @filtered;
3097 }
3098
3099 # note: fill_project_list_info must be run first,
3100 # for 'descr_long' and 'ctags' to be filled
3101 sub search_projects_list {
3102         my ($projlist, %opts) = @_;
3103         my $tagfilter  = $opts{'tagfilter'};
3104         my $search_re = $opts{'search_regexp'};
3105
3106         return @$projlist
3107                 unless ($tagfilter || $search_re);
3108
3109         # searching projects require filling to be run before it;
3110         fill_project_list_info($projlist,
3111                                $tagfilter  ? 'ctags' : (),
3112                                $search_re ? ('path', 'descr') : ());
3113         my @projects;
3114  PROJECT:
3115         foreach my $pr (@$projlist) {
3116
3117                 if ($tagfilter) {
3118                         next unless ref($pr->{'ctags'}) eq 'HASH';
3119                         next unless
3120                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3121                 }
3122
3123                 if ($search_re) {
3124                         next unless
3125                                 $pr->{'path'} =~ /$search_re/ ||
3126                                 $pr->{'descr_long'} =~ /$search_re/;
3127                 }
3128
3129                 push @projects, $pr;
3130         }
3131
3132         return @projects;
3133 }
3134
3135 our $gitweb_project_owner = undef;
3136 sub git_get_project_list_from_file {
3137
3138         return if (defined $gitweb_project_owner);
3139
3140         $gitweb_project_owner = {};
3141         # read from file (url-encoded):
3142         # 'git%2Fgit.git Linus+Torvalds'
3143         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3144         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3145         if (-f $projects_list) {
3146                 open(my $fd, '<', $projects_list);
3147                 while (my $line = <$fd>) {
3148                         chomp $line;
3149                         my ($pr, $ow) = split ' ', $line;
3150                         $pr = unescape($pr);
3151                         $ow = unescape($ow);
3152                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3153                 }
3154                 close $fd;
3155         }
3156 }
3157
3158 sub git_get_project_owner {
3159         my $project = shift;
3160         my $owner;
3161
3162         return undef unless $project;
3163         $git_dir = "$projectroot/$project";
3164
3165         if (!defined $gitweb_project_owner) {
3166                 git_get_project_list_from_file();
3167         }
3168
3169         if (exists $gitweb_project_owner->{$project}) {
3170                 $owner = $gitweb_project_owner->{$project};
3171         }
3172         if (!defined $owner){
3173                 $owner = git_get_project_config('owner');
3174         }
3175         if (!defined $owner) {
3176                 $owner = get_file_owner("$git_dir");
3177         }
3178
3179         return $owner;
3180 }
3181
3182 sub git_get_last_activity {
3183         my ($path) = @_;
3184         my $fd;
3185
3186         $git_dir = "$projectroot/$path";
3187         open($fd, "-|", git_cmd(), 'for-each-ref',
3188              '--format=%(committer)',
3189              '--sort=-committerdate',
3190              '--count=1',
3191              'refs/heads') or return;
3192         my $most_recent = <$fd>;
3193         close $fd or return;
3194         if (defined $most_recent &&
3195             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3196                 my $timestamp = $1;
3197                 my $age = time - $timestamp;
3198                 return ($age, age_string($age));
3199         }
3200         return (undef, undef);
3201 }
3202
3203 # Implementation note: when a single remote is wanted, we cannot use 'git
3204 # remote show -n' because that command always work (assuming it's a remote URL
3205 # if it's not defined), and we cannot use 'git remote show' because that would
3206 # try to make a network roundtrip. So the only way to find if that particular
3207 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3208 # and when we find what we want.
3209 sub git_get_remotes_list {
3210         my $wanted = shift;
3211         my %remotes = ();
3212
3213         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3214         return unless $fd;
3215         while (my $remote = <$fd>) {
3216                 chomp $remote;
3217                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3218                 next if $wanted and not $remote eq $wanted;
3219                 my ($url, $key) = ($1, $2);
3220
3221                 $remotes{$remote} ||= { 'heads' => () };
3222                 $remotes{$remote}{$key} = $url;
3223         }
3224         close $fd or return;
3225         return wantarray ? %remotes : \%remotes;
3226 }
3227
3228 # Takes a hash of remotes as first parameter and fills it by adding the
3229 # available remote heads for each of the indicated remotes.
3230 sub fill_remote_heads {
3231         my $remotes = shift;
3232         my @heads = map { "remotes/$_" } keys %$remotes;
3233         my @remoteheads = git_get_heads_list(undef, @heads);
3234         foreach my $remote (keys %$remotes) {
3235                 $remotes->{$remote}{'heads'} = [ grep {
3236                         $_->{'name'} =~ s!^$remote/!!
3237                         } @remoteheads ];
3238         }
3239 }
3240
3241 sub git_get_references {
3242         my $type = shift || "";
3243         my %refs;
3244         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3245         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3246         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3247                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3248                 or return;
3249
3250         while (my $line = <$fd>) {
3251                 chomp $line;
3252                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3253                         if (defined $refs{$1}) {
3254                                 push @{$refs{$1}}, $2;
3255                         } else {
3256                                 $refs{$1} = [ $2 ];
3257                         }
3258                 }
3259         }
3260         close $fd or return;
3261         return \%refs;
3262 }
3263
3264 sub git_get_rev_name_tags {
3265         my $hash = shift || return undef;
3266
3267         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3268                 or return;
3269         my $name_rev = <$fd>;
3270         close $fd;
3271
3272         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3273                 return $1;
3274         } else {
3275                 # catches also '$hash undefined' output
3276                 return undef;
3277         }
3278 }
3279
3280 ## ----------------------------------------------------------------------
3281 ## parse to hash functions
3282
3283 sub parse_date {
3284         my $epoch = shift;
3285         my $tz = shift || "-0000";
3286
3287         my %date;
3288         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3289         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3290         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3291         $date{'hour'} = $hour;
3292         $date{'minute'} = $min;
3293         $date{'mday'} = $mday;
3294         $date{'day'} = $days[$wday];
3295         $date{'month'} = $months[$mon];
3296         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3297                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3298         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3299                              $mday, $months[$mon], $hour ,$min;
3300         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3301                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3302
3303         my ($tz_sign, $tz_hour, $tz_min) =
3304                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3305         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3306         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3307         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3308         $date{'hour_local'} = $hour;
3309         $date{'minute_local'} = $min;
3310         $date{'tz_local'} = $tz;
3311         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3312                                   1900+$year, $mon+1, $mday,
3313                                   $hour, $min, $sec, $tz);
3314         return %date;
3315 }
3316
3317 sub parse_tag {
3318         my $tag_id = shift;
3319         my %tag;
3320         my @comment;
3321
3322         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3323         $tag{'id'} = $tag_id;
3324         while (my $line = <$fd>) {
3325                 chomp $line;
3326                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3327                         $tag{'object'} = $1;
3328                 } elsif ($line =~ m/^type (.+)$/) {
3329                         $tag{'type'} = $1;
3330                 } elsif ($line =~ m/^tag (.+)$/) {
3331                         $tag{'name'} = $1;
3332                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3333                         $tag{'author'} = $1;
3334                         $tag{'author_epoch'} = $2;
3335                         $tag{'author_tz'} = $3;
3336                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3337                                 $tag{'author_name'}  = $1;
3338                                 $tag{'author_email'} = $2;
3339                         } else {
3340                                 $tag{'author_name'} = $tag{'author'};
3341                         }
3342                 } elsif ($line =~ m/--BEGIN/) {
3343                         push @comment, $line;
3344                         last;
3345                 } elsif ($line eq "") {
3346                         last;
3347                 }
3348         }
3349         push @comment, <$fd>;
3350         $tag{'comment'} = \@comment;
3351         close $fd or return;
3352         if (!defined $tag{'name'}) {
3353                 return
3354         };
3355         return %tag
3356 }
3357
3358 sub parse_commit_text {
3359         my ($commit_text, $withparents) = @_;
3360         my @commit_lines = split '\n', $commit_text;
3361         my %co;
3362
3363         pop @commit_lines; # Remove '\0'
3364
3365         if (! @commit_lines) {
3366                 return;
3367         }
3368
3369         my $header = shift @commit_lines;
3370         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3371                 return;
3372         }
3373         ($co{'id'}, my @parents) = split ' ', $header;
3374         while (my $line = shift @commit_lines) {
3375                 last if $line eq "\n";
3376                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3377                         $co{'tree'} = $1;
3378                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3379                         push @parents, $1;
3380                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3381                         $co{'author'} = to_utf8($1);
3382                         $co{'author_epoch'} = $2;
3383                         $co{'author_tz'} = $3;
3384                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3385                                 $co{'author_name'}  = $1;
3386                                 $co{'author_email'} = $2;
3387                         } else {
3388                                 $co{'author_name'} = $co{'author'};
3389                         }
3390                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3391                         $co{'committer'} = to_utf8($1);
3392                         $co{'committer_epoch'} = $2;
3393                         $co{'committer_tz'} = $3;
3394                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3395                                 $co{'committer_name'}  = $1;
3396                                 $co{'committer_email'} = $2;
3397                         } else {
3398                                 $co{'committer_name'} = $co{'committer'};
3399                         }
3400                 }
3401         }
3402         if (!defined $co{'tree'}) {
3403                 return;
3404         };
3405         $co{'parents'} = \@parents;
3406         $co{'parent'} = $parents[0];
3407
3408         foreach my $title (@commit_lines) {
3409                 $title =~ s/^    //;
3410                 if ($title ne "") {
3411                         $co{'title'} = chop_str($title, 80, 5);
3412                         # remove leading stuff of merges to make the interesting part visible
3413                         if (length($title) > 50) {
3414                                 $title =~ s/^Automatic //;
3415                                 $title =~ s/^merge (of|with) /Merge ... /i;
3416                                 if (length($title) > 50) {
3417                                         $title =~ s/(http|rsync):\/\///;
3418                                 }
3419                                 if (length($title) > 50) {
3420                                         $title =~ s/(master|www|rsync)\.//;
3421                                 }
3422                                 if (length($title) > 50) {
3423                                         $title =~ s/kernel.org:?//;
3424                                 }
3425                                 if (length($title) > 50) {
3426                                         $title =~ s/\/pub\/scm//;
3427                                 }
3428                         }
3429                         $co{'title_short'} = chop_str($title, 50, 5);
3430                         last;
3431                 }
3432         }
3433         if (! defined $co{'title'} || $co{'title'} eq "") {
3434                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3435         }
3436         # remove added spaces
3437         foreach my $line (@commit_lines) {
3438                 $line =~ s/^    //;
3439         }
3440         $co{'comment'} = \@commit_lines;
3441
3442         my $age = time - $co{'committer_epoch'};
3443         $co{'age'} = $age;
3444         $co{'age_string'} = age_string($age);
3445         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3446         if ($age > 60*60*24*7*2) {
3447                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3448                 $co{'age_string_age'} = $co{'age_string'};
3449         } else {
3450                 $co{'age_string_date'} = $co{'age_string'};
3451                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3452         }
3453         return %co;
3454 }
3455
3456 sub parse_commit {
3457         my ($commit_id) = @_;
3458         my %co;
3459
3460         local $/ = "\0";
3461
3462         open my $fd, "-|", git_cmd(), "rev-list",
3463                 "--parents",
3464                 "--header",
3465                 "--max-count=1",
3466                 $commit_id,
3467                 "--",
3468                 or die_error(500, "Open git-rev-list failed");
3469         %co = parse_commit_text(<$fd>, 1);
3470         close $fd;
3471
3472         return %co;
3473 }
3474
3475 sub parse_commits {
3476         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3477         my @cos;
3478
3479         $maxcount ||= 1;
3480         $skip ||= 0;
3481
3482         local $/ = "\0";
3483
3484         open my $fd, "-|", git_cmd(), "rev-list",
3485                 "--header",
3486                 @args,
3487                 ("--max-count=" . $maxcount),
3488                 ("--skip=" . $skip),
3489                 @extra_options,
3490                 $commit_id,
3491                 "--",
3492                 ($filename ? ($filename) : ())
3493                 or die_error(500, "Open git-rev-list failed");
3494         while (my $line = <$fd>) {
3495                 my %co = parse_commit_text($line);
3496                 push @cos, \%co;
3497         }
3498         close $fd;
3499
3500         return wantarray ? @cos : \@cos;
3501 }
3502
3503 # parse line of git-diff-tree "raw" output
3504 sub parse_difftree_raw_line {
3505         my $line = shift;
3506         my %res;
3507
3508         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3509         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3510         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3511                 $res{'from_mode'} = $1;
3512                 $res{'to_mode'} = $2;
3513                 $res{'from_id'} = $3;
3514                 $res{'to_id'} = $4;
3515                 $res{'status'} = $5;
3516                 $res{'similarity'} = $6;
3517                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3518                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3519                 } else {
3520                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3521                 }
3522         }
3523         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3524         # combined diff (for merge commit)
3525         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3526                 $res{'nparents'}  = length($1);
3527                 $res{'from_mode'} = [ split(' ', $2) ];
3528                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3529                 $res{'from_id'} = [ split(' ', $3) ];
3530                 $res{'to_id'} = pop @{$res{'from_id'}};
3531                 $res{'status'} = [ split('', $4) ];
3532                 $res{'to_file'} = unquote($5);
3533         }
3534         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3535         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3536                 $res{'commit'} = $1;
3537         }
3538
3539         return wantarray ? %res : \%res;
3540 }
3541
3542 # wrapper: return parsed line of git-diff-tree "raw" output
3543 # (the argument might be raw line, or parsed info)
3544 sub parsed_difftree_line {
3545         my $line_or_ref = shift;
3546
3547         if (ref($line_or_ref) eq "HASH") {
3548                 # pre-parsed (or generated by hand)
3549                 return $line_or_ref;
3550         } else {
3551                 return parse_difftree_raw_line($line_or_ref);
3552         }
3553 }
3554
3555 # parse line of git-ls-tree output
3556 sub parse_ls_tree_line {
3557         my $line = shift;
3558         my %opts = @_;
3559         my %res;
3560
3561         if ($opts{'-l'}) {
3562                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3563                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3564
3565                 $res{'mode'} = $1;
3566                 $res{'type'} = $2;
3567                 $res{'hash'} = $3;
3568                 $res{'size'} = $4;
3569                 if ($opts{'-z'}) {
3570                         $res{'name'} = $5;
3571                 } else {
3572                         $res{'name'} = unquote($5);
3573                 }
3574         } else {
3575                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3576                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3577
3578                 $res{'mode'} = $1;
3579                 $res{'type'} = $2;
3580                 $res{'hash'} = $3;
3581                 if ($opts{'-z'}) {
3582                         $res{'name'} = $4;
3583                 } else {
3584                         $res{'name'} = unquote($4);
3585                 }
3586         }
3587
3588         return wantarray ? %res : \%res;
3589 }
3590
3591 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3592 sub parse_from_to_diffinfo {
3593         my ($diffinfo, $from, $to, @parents) = @_;
3594
3595         if ($diffinfo->{'nparents'}) {
3596                 # combined diff
3597                 $from->{'file'} = [];
3598                 $from->{'href'} = [];
3599                 fill_from_file_info($diffinfo, @parents)
3600                         unless exists $diffinfo->{'from_file'};
3601                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3602                         $from->{'file'}[$i] =
3603                                 defined $diffinfo->{'from_file'}[$i] ?
3604                                         $diffinfo->{'from_file'}[$i] :
3605                                         $diffinfo->{'to_file'};
3606                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3607                                 $from->{'href'}[$i] = href(action=>"blob",
3608                                                            hash_base=>$parents[$i],
3609                                                            hash=>$diffinfo->{'from_id'}[$i],
3610                                                            file_name=>$from->{'file'}[$i]);
3611                         } else {
3612                                 $from->{'href'}[$i] = undef;
3613                         }
3614                 }
3615         } else {
3616                 # ordinary (not combined) diff
3617                 $from->{'file'} = $diffinfo->{'from_file'};
3618                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3619                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3620                                                hash=>$diffinfo->{'from_id'},
3621                                                file_name=>$from->{'file'});
3622                 } else {
3623                         delete $from->{'href'};
3624                 }
3625         }
3626
3627         $to->{'file'} = $diffinfo->{'to_file'};
3628         if (!is_deleted($diffinfo)) { # file exists in result
3629                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3630                                      hash=>$diffinfo->{'to_id'},
3631                                      file_name=>$to->{'file'});
3632         } else {
3633                 delete $to->{'href'};
3634         }
3635 }
3636
3637 ## ......................................................................
3638 ## parse to array of hashes functions
3639
3640 sub git_get_heads_list {
3641         my ($limit, @classes) = @_;
3642         @classes = ('heads') unless @classes;
3643         my @patterns = map { "refs/$_" } @classes;
3644         my @headslist;
3645
3646         open my $fd, '-|', git_cmd(), 'for-each-ref',
3647                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3648                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3649                 @patterns
3650                 or return;
3651         while (my $line = <$fd>) {
3652                 my %ref_item;
3653
3654                 chomp $line;
3655                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3656                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3657                 my ($committer, $epoch, $tz) =
3658                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3659                 $ref_item{'fullname'}  = $name;
3660                 $name =~ s!^refs/(?:head|remote)s/!!;
3661
3662                 $ref_item{'name'}  = $name;
3663                 $ref_item{'id'}    = $hash;
3664                 $ref_item{'title'} = $title || '(no commit message)';
3665                 $ref_item{'epoch'} = $epoch;
3666                 if ($epoch) {
3667                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3668                 } else {
3669                         $ref_item{'age'} = "unknown";
3670                 }
3671
3672                 push @headslist, \%ref_item;
3673         }
3674         close $fd;
3675
3676         return wantarray ? @headslist : \@headslist;
3677 }
3678
3679 sub git_get_tags_list {
3680         my $limit = shift;
3681         my @tagslist;
3682
3683         open my $fd, '-|', git_cmd(), 'for-each-ref',
3684                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3685                 '--format=%(objectname) %(objecttype) %(refname) '.
3686                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3687                 'refs/tags'
3688                 or return;
3689         while (my $line = <$fd>) {
3690                 my %ref_item;
3691
3692                 chomp $line;
3693                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3694                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3695                 my ($creator, $epoch, $tz) =
3696                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3697                 $ref_item{'fullname'} = $name;
3698                 $name =~ s!^refs/tags/!!;
3699
3700                 $ref_item{'type'} = $type;
3701                 $ref_item{'id'} = $id;
3702                 $ref_item{'name'} = $name;
3703                 if ($type eq "tag") {
3704                         $ref_item{'subject'} = $title;
3705                         $ref_item{'reftype'} = $reftype;
3706                         $ref_item{'refid'}   = $refid;
3707                 } else {
3708                         $ref_item{'reftype'} = $type;
3709                         $ref_item{'refid'}   = $id;
3710                 }
3711
3712                 if ($type eq "tag" || $type eq "commit") {
3713                         $ref_item{'epoch'} = $epoch;
3714                         if ($epoch) {
3715                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3716                         } else {
3717                                 $ref_item{'age'} = "unknown";
3718                         }
3719                 }
3720
3721                 push @tagslist, \%ref_item;
3722         }
3723         close $fd;
3724
3725         return wantarray ? @tagslist : \@tagslist;
3726 }
3727
3728 ## ----------------------------------------------------------------------
3729 ## filesystem-related functions
3730
3731 sub get_file_owner {
3732         my $path = shift;
3733
3734         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3735         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3736         if (!defined $gcos) {
3737                 return undef;
3738         }
3739         my $owner = $gcos;
3740         $owner =~ s/[,;].*$//;
3741         return to_utf8($owner);
3742 }
3743
3744 # assume that file exists
3745 sub insert_file {
3746         my $filename = shift;
3747
3748         open my $fd, '<', $filename;
3749         print map { to_utf8($_) } <$fd>;
3750         close $fd;
3751 }
3752
3753 ## ......................................................................
3754 ## mimetype related functions
3755
3756 sub mimetype_guess_file {
3757         my $filename = shift;
3758         my $mimemap = shift;
3759         -r $mimemap or return undef;
3760
3761         my %mimemap;
3762         open(my $mh, '<', $mimemap) or return undef;
3763         while (<$mh>) {
3764                 next if m/^#/; # skip comments
3765                 my ($mimetype, @exts) = split(/\s+/);
3766                 foreach my $ext (@exts) {
3767                         $mimemap{$ext} = $mimetype;
3768                 }
3769         }
3770         close($mh);
3771
3772         $filename =~ /\.([^.]*)$/;
3773         return $mimemap{$1};
3774 }
3775
3776 sub mimetype_guess {
3777         my $filename = shift;
3778         my $mime;
3779         $filename =~ /\./ or return undef;
3780
3781         if ($mimetypes_file) {
3782                 my $file = $mimetypes_file;
3783                 if ($file !~ m!^/!) { # if it is relative path
3784                         # it is relative to project
3785                         $file = "$projectroot/$project/$file";
3786                 }
3787                 $mime = mimetype_guess_file($filename, $file);
3788         }
3789         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3790         return $mime;
3791 }
3792
3793 sub blob_mimetype {
3794         my $fd = shift;
3795         my $filename = shift;
3796
3797         if ($filename) {
3798                 my $mime = mimetype_guess($filename);
3799                 $mime and return $mime;
3800         }
3801
3802         # just in case
3803         return $default_blob_plain_mimetype unless $fd;
3804
3805         if (-T $fd) {
3806                 return 'text/plain';
3807         } elsif (! $filename) {
3808                 return 'application/octet-stream';
3809         } elsif ($filename =~ m/\.png$/i) {
3810                 return 'image/png';
3811         } elsif ($filename =~ m/\.gif$/i) {
3812                 return 'image/gif';
3813         } elsif ($filename =~ m/\.jpe?g$/i) {
3814                 return 'image/jpeg';
3815         } else {
3816                 return 'application/octet-stream';
3817         }
3818 }
3819
3820 sub blob_contenttype {
3821         my ($fd, $file_name, $type) = @_;
3822
3823         $type ||= blob_mimetype($fd, $file_name);
3824         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3825                 $type .= "; charset=$default_text_plain_charset";
3826         }
3827
3828         return $type;
3829 }
3830
3831 # guess file syntax for syntax highlighting; return undef if no highlighting
3832 # the name of syntax can (in the future) depend on syntax highlighter used
3833 sub guess_file_syntax {
3834         my ($highlight, $mimetype, $file_name) = @_;
3835         return undef unless ($highlight && defined $file_name);
3836         my $basename = basename($file_name, '.in');
3837         return $highlight_basename{$basename}
3838                 if exists $highlight_basename{$basename};
3839
3840         $basename =~ /\.([^.]*)$/;
3841         my $ext = $1 or return undef;
3842         return $highlight_ext{$ext}
3843                 if exists $highlight_ext{$ext};
3844
3845         return undef;
3846 }
3847
3848 # run highlighter and return FD of its output,
3849 # or return original FD if no highlighting
3850 sub run_highlighter {
3851         my ($fd, $highlight, $syntax) = @_;
3852         return $fd unless ($highlight && defined $syntax);
3853
3854         close $fd;
3855         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3856                   quote_command($highlight_bin).
3857                   " --replace-tabs=8 --fragment --syntax $syntax |"
3858                 or die_error(500, "Couldn't open file or run syntax highlighter");
3859         return $fd;
3860 }
3861
3862 ## ======================================================================
3863 ## functions printing HTML: header, footer, error page
3864
3865 sub get_page_title {
3866         my $title = to_utf8($site_name);
3867
3868         unless (defined $project) {
3869                 if (defined $project_filter) {
3870                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3871                 }
3872                 return $title;
3873         }
3874         $title .= " - " . to_utf8($project);
3875
3876         return $title unless (defined $action);
3877         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3878
3879         return $title unless (defined $file_name);
3880         $title .= " - " . esc_path($file_name);
3881         if ($action eq "tree" && $file_name !~ m|/$|) {
3882                 $title .= "/";
3883         }
3884
3885         return $title;
3886 }
3887
3888 sub get_content_type_html {
3889         # require explicit support from the UA if we are to send the page as
3890         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3891         # we have to do this because MSIE sometimes globs '*/*', pretending to
3892         # support xhtml+xml but choking when it gets what it asked for.
3893         if (defined $cgi->http('HTTP_ACCEPT') &&
3894             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3895             $cgi->Accept('application/xhtml+xml') != 0) {
3896                 return 'application/xhtml+xml';
3897         } else {
3898                 return 'text/html';
3899         }
3900 }
3901
3902 sub print_feed_meta {
3903         if (defined $project) {
3904                 my %href_params = get_feed_info();
3905                 if (!exists $href_params{'-title'}) {
3906                         $href_params{'-title'} = 'log';
3907                 }
3908
3909                 foreach my $format (qw(RSS Atom)) {
3910                         my $type = lc($format);
3911                         my %link_attr = (
3912                                 '-rel' => 'alternate',
3913                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3914                                 '-type' => "application/$type+xml"
3915                         );
3916
3917                         $href_params{'extra_options'} = undef;
3918                         $href_params{'action'} = $type;
3919                         $link_attr{'-href'} = href(%href_params);
3920                         print "<link ".
3921                               "rel=\"$link_attr{'-rel'}\" ".
3922                               "title=\"$link_attr{'-title'}\" ".
3923                               "href=\"$link_attr{'-href'}\" ".
3924                               "type=\"$link_attr{'-type'}\" ".
3925                               "/>\n";
3926
3927                         $href_params{'extra_options'} = '--no-merges';
3928                         $link_attr{'-href'} = href(%href_params);
3929                         $link_attr{'-title'} .= ' (no merges)';
3930                         print "<link ".
3931                               "rel=\"$link_attr{'-rel'}\" ".
3932                               "title=\"$link_attr{'-title'}\" ".
3933                               "href=\"$link_attr{'-href'}\" ".
3934                               "type=\"$link_attr{'-type'}\" ".
3935                               "/>\n";
3936                 }
3937
3938         } else {
3939                 printf('<link rel="alternate" title="%s projects list" '.
3940                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3941                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3942                 printf('<link rel="alternate" title="%s projects feeds" '.
3943                        'href="%s" type="text/x-opml" />'."\n",
3944                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3945         }
3946 }
3947
3948 sub print_header_links {
3949         my $status = shift;
3950
3951         # print out each stylesheet that exist, providing backwards capability
3952         # for those people who defined $stylesheet in a config file
3953         if (defined $stylesheet) {
3954                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3955         } else {
3956                 foreach my $stylesheet (@stylesheets) {
3957                         next unless $stylesheet;
3958                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3959                 }
3960         }
3961         print_feed_meta()
3962                 if ($status eq '200 OK');
3963         if (defined $favicon) {
3964                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3965         }
3966 }
3967
3968 sub print_nav_breadcrumbs_path {
3969         my $dirprefix = undef;
3970         while (my $part = shift) {
3971                 $dirprefix .= "/" if defined $dirprefix;
3972                 $dirprefix .= $part;
3973                 print $cgi->a({-href => href(project => undef,
3974                                              project_filter => $dirprefix,
3975                                              action => "project_list")},
3976                               esc_html($part)) . " / ";
3977         }
3978 }
3979
3980 sub print_nav_breadcrumbs {
3981         my %opts = @_;
3982
3983         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3984         if (defined $project) {
3985                 my @dirname = split '/', $project;
3986                 my $projectbasename = pop @dirname;
3987                 print_nav_breadcrumbs_path(@dirname);
3988                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
3989                 if (defined $action) {
3990                         my $action_print = $action ;
3991                         if (defined $opts{-action_extra}) {
3992                                 $action_print = $cgi->a({-href => href(action=>$action)},
3993                                         $action);
3994                         }
3995                         print " / $action_print";
3996                 }
3997                 if (defined $opts{-action_extra}) {
3998                         print " / $opts{-action_extra}";
3999                 }
4000                 print "\n";
4001         } elsif (defined $project_filter) {
4002                 print_nav_breadcrumbs_path(split '/', $project_filter);
4003         }
4004 }
4005
4006 sub print_search_form {
4007         if (!defined $searchtext) {
4008                 $searchtext = "";
4009         }
4010         my $search_hash;
4011         if (defined $hash_base) {
4012                 $search_hash = $hash_base;
4013         } elsif (defined $hash) {
4014                 $search_hash = $hash;
4015         } else {
4016                 $search_hash = "HEAD";
4017         }
4018         my $action = $my_uri;
4019         my $use_pathinfo = gitweb_check_feature('pathinfo');
4020         if ($use_pathinfo) {
4021                 $action .= "/".esc_url($project);
4022         }
4023         print $cgi->startform(-method => "get", -action => $action) .
4024               "<div class=\"search\">\n" .
4025               (!$use_pathinfo &&
4026               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4027               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4028               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4029               $cgi->popup_menu(-name => 'st', -default => 'commit',
4030                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4031               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
4032               " search:\n",
4033               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4034               "<span title=\"Extended regular expression\">" .
4035               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4036                              -checked => $search_use_regexp) .
4037               "</span>" .
4038               "</div>" .
4039               $cgi->end_form() . "\n";
4040 }
4041
4042 sub git_header_html {
4043         my $status = shift || "200 OK";
4044         my $expires = shift;
4045         my %opts = @_;
4046
4047         my $title = get_page_title();
4048         my $content_type = get_content_type_html();
4049         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4050                            -status=> $status, -expires => $expires)
4051                 unless ($opts{'-no_http_header'});
4052         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4053         print <<EOF;
4054 <?xml version="1.0" encoding="utf-8"?>
4055 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4056 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4057 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4058 <!-- git core binaries version $git_version -->
4059 <head>
4060 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4061 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4062 <meta name="robots" content="index, nofollow"/>
4063 <title>$title</title>
4064 EOF
4065         # the stylesheet, favicon etc urls won't work correctly with path_info
4066         # unless we set the appropriate base URL
4067         if ($ENV{'PATH_INFO'}) {
4068                 print "<base href=\"".esc_url($base_url)."\" />\n";
4069         }
4070         print_header_links($status);
4071
4072         if (defined $site_html_head_string) {
4073                 print to_utf8($site_html_head_string);
4074         }
4075
4076         print "</head>\n" .
4077               "<body>\n";
4078
4079         if (defined $site_header && -f $site_header) {
4080                 insert_file($site_header);
4081         }
4082
4083         print "<div class=\"page_header\">\n";
4084         if (defined $logo) {
4085                 print $cgi->a({-href => esc_url($logo_url),
4086                                -title => $logo_label},
4087                               $cgi->img({-src => esc_url($logo),
4088                                          -width => 72, -height => 27,
4089                                          -alt => "git",
4090                                          -class => "logo"}));
4091         }
4092         print_nav_breadcrumbs(%opts);
4093         print "</div>\n";
4094
4095         my $have_search = gitweb_check_feature('search');
4096         if (defined $project && $have_search) {
4097                 print_search_form();
4098         }
4099 }
4100
4101 sub git_footer_html {
4102         my $feed_class = 'rss_logo';
4103
4104         print "<div class=\"page_footer\">\n";
4105         if (defined $project) {
4106                 my $descr = git_get_project_description($project);
4107                 if (defined $descr) {
4108                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4109                 }
4110
4111                 my %href_params = get_feed_info();
4112                 if (!%href_params) {
4113                         $feed_class .= ' generic';
4114                 }
4115                 $href_params{'-title'} ||= 'log';
4116
4117                 foreach my $format (qw(RSS Atom)) {
4118                         $href_params{'action'} = lc($format);
4119                         print $cgi->a({-href => href(%href_params),
4120                                       -title => "$href_params{'-title'} $format feed",
4121                                       -class => $feed_class}, $format)."\n";
4122                 }
4123
4124         } else {
4125                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4126                                              project_filter => $project_filter),
4127                               -class => $feed_class}, "OPML") . " ";
4128                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4129                                              project_filter => $project_filter),
4130                               -class => $feed_class}, "TXT") . "\n";
4131         }
4132         print "</div>\n"; # class="page_footer"
4133
4134         if (defined $t0 && gitweb_check_feature('timed')) {
4135                 print "<div id=\"generating_info\">\n";
4136                 print 'This page took '.
4137                       '<span id="generating_time" class="time_span">'.
4138                       tv_interval($t0, [ gettimeofday() ]).
4139                       ' seconds </span>'.
4140                       ' and '.
4141                       '<span id="generating_cmd">'.
4142                       $number_of_git_cmds.
4143                       '</span> git commands '.
4144                       " to generate.\n";
4145                 print "</div>\n"; # class="page_footer"
4146         }
4147
4148         if (defined $site_footer && -f $site_footer) {
4149                 insert_file($site_footer);
4150         }
4151
4152         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4153         if (defined $action &&
4154             $action eq 'blame_incremental') {
4155                 print qq!<script type="text/javascript">\n!.
4156                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4157                       qq!           "!. href() .qq!");\n!.
4158                       qq!</script>\n!;
4159         } else {
4160                 my ($jstimezone, $tz_cookie, $datetime_class) =
4161                         gitweb_get_feature('javascript-timezone');
4162
4163                 print qq!<script type="text/javascript">\n!.
4164                       qq!window.onload = function () {\n!;
4165                 if (gitweb_check_feature('javascript-actions')) {
4166                         print qq!       fixLinks();\n!;
4167                 }
4168                 if ($jstimezone && $tz_cookie && $datetime_class) {
4169                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4170                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4171                 }
4172                 print qq!};\n!.
4173                       qq!</script>\n!;
4174         }
4175
4176         print "</body>\n" .
4177               "</html>";
4178 }
4179
4180 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4181 # Example: die_error(404, 'Hash not found')
4182 # By convention, use the following status codes (as defined in RFC 2616):
4183 # 400: Invalid or missing CGI parameters, or
4184 #      requested object exists but has wrong type.
4185 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4186 #      this server or project.
4187 # 404: Requested object/revision/project doesn't exist.
4188 # 500: The server isn't configured properly, or
4189 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4190 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4191 # 503: The server is currently unavailable (because it is overloaded,
4192 #      or down for maintenance).  Generally, this is a temporary state.
4193 sub die_error {
4194         my $status = shift || 500;
4195         my $error = esc_html(shift) || "Internal Server Error";
4196         my $extra = shift;
4197         my %opts = @_;
4198
4199         my %http_responses = (
4200                 400 => '400 Bad Request',
4201                 403 => '403 Forbidden',
4202                 404 => '404 Not Found',
4203                 500 => '500 Internal Server Error',
4204                 503 => '503 Service Unavailable',
4205         );
4206         git_header_html($http_responses{$status}, undef, %opts);
4207         print <<EOF;
4208 <div class="page_body">
4209 <br /><br />
4210 $status - $error
4211 <br />
4212 EOF
4213         if (defined $extra) {
4214                 print "<hr />\n" .
4215                       "$extra\n";
4216         }
4217         print "</div>\n";
4218
4219         git_footer_html();
4220         goto DONE_GITWEB
4221                 unless ($opts{'-error_handler'});
4222 }
4223
4224 ## ----------------------------------------------------------------------
4225 ## functions printing or outputting HTML: navigation
4226
4227 sub git_print_page_nav {
4228         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4229         $extra = '' if !defined $extra; # pager or formats
4230
4231         my @navs = qw(summary shortlog log commit commitdiff tree);
4232         if ($suppress) {
4233                 @navs = grep { $_ ne $suppress } @navs;
4234         }
4235
4236         my %arg = map { $_ => {action=>$_} } @navs;
4237         if (defined $head) {
4238                 for (qw(commit commitdiff)) {
4239                         $arg{$_}{'hash'} = $head;
4240                 }
4241                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4242                         for (qw(shortlog log)) {
4243                                 $arg{$_}{'hash'} = $head;
4244                         }
4245                 }
4246         }
4247
4248         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4249         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4250
4251         my @actions = gitweb_get_feature('actions');
4252         my %repl = (
4253                 '%' => '%',
4254                 'n' => $project,         # project name
4255                 'f' => $git_dir,         # project path within filesystem
4256                 'h' => $treehead || '',  # current hash ('h' parameter)
4257                 'b' => $treebase || '',  # hash base ('hb' parameter)
4258         );
4259         while (@actions) {
4260                 my ($label, $link, $pos) = splice(@actions,0,3);
4261                 # insert
4262                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4263                 # munch munch
4264                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4265                 $arg{$label}{'_href'} = $link;
4266         }
4267
4268         print "<div class=\"page_nav\">\n" .
4269                 (join " | ",
4270                  map { $_ eq $current ?
4271                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4272                  } @navs);
4273         print "<br/>\n$extra<br/>\n" .
4274               "</div>\n";
4275 }
4276
4277 # returns a submenu for the nagivation of the refs views (tags, heads,
4278 # remotes) with the current view disabled and the remotes view only
4279 # available if the feature is enabled
4280 sub format_ref_views {
4281         my ($current) = @_;
4282         my @ref_views = qw{tags heads};
4283         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4284         return join " | ", map {
4285                 $_ eq $current ? $_ :
4286                 $cgi->a({-href => href(action=>$_)}, $_)
4287         } @ref_views
4288 }
4289
4290 sub format_paging_nav {
4291         my ($action, $page, $has_next_link) = @_;
4292         my $paging_nav;
4293
4294
4295         if ($page > 0) {
4296                 $paging_nav .=
4297                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4298                         " &sdot; " .
4299                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4300                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4301         } else {
4302                 $paging_nav .= "first &sdot; prev";
4303         }
4304
4305         if ($has_next_link) {
4306                 $paging_nav .= " &sdot; " .
4307                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4308                                  -accesskey => "n", -title => "Alt-n"}, "next");
4309         } else {
4310                 $paging_nav .= " &sdot; next";
4311         }
4312
4313         return $paging_nav;
4314 }
4315
4316 ## ......................................................................
4317 ## functions printing or outputting HTML: div
4318
4319 sub git_print_header_div {
4320         my ($action, $title, $hash, $hash_base) = @_;
4321         my %args = ();
4322
4323         $args{'action'} = $action;
4324         $args{'hash'} = $hash if $hash;
4325         $args{'hash_base'} = $hash_base if $hash_base;
4326
4327         print "<div class=\"header\">\n" .
4328               $cgi->a({-href => href(%args), -class => "title"},
4329               $title ? $title : $action) .
4330               "\n</div>\n";
4331 }
4332
4333 sub format_repo_url {
4334         my ($name, $url) = @_;
4335         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4336 }
4337
4338 # Group output by placing it in a DIV element and adding a header.
4339 # Options for start_div() can be provided by passing a hash reference as the
4340 # first parameter to the function.
4341 # Options to git_print_header_div() can be provided by passing an array
4342 # reference. This must follow the options to start_div if they are present.
4343 # The content can be a scalar, which is output as-is, a scalar reference, which
4344 # is output after html escaping, an IO handle passed either as *handle or
4345 # *handle{IO}, or a function reference. In the latter case all following
4346 # parameters will be taken as argument to the content function call.
4347 sub git_print_section {
4348         my ($div_args, $header_args, $content);
4349         my $arg = shift;
4350         if (ref($arg) eq 'HASH') {
4351                 $div_args = $arg;
4352                 $arg = shift;
4353         }
4354         if (ref($arg) eq 'ARRAY') {
4355                 $header_args = $arg;
4356                 $arg = shift;
4357         }
4358         $content = $arg;
4359
4360         print $cgi->start_div($div_args);
4361         git_print_header_div(@$header_args);
4362
4363         if (ref($content) eq 'CODE') {
4364                 $content->(@_);
4365         } elsif (ref($content) eq 'SCALAR') {
4366                 print esc_html($$content);
4367         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4368                 print <$content>;
4369         } elsif (!ref($content) && defined($content)) {
4370                 print $content;
4371         }
4372
4373         print $cgi->end_div;
4374 }
4375
4376 sub format_timestamp_html {
4377         my $date = shift;
4378         my $strtime = $date->{'rfc2822'};
4379
4380         my (undef, undef, $datetime_class) =
4381                 gitweb_get_feature('javascript-timezone');
4382         if ($datetime_class) {
4383                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4384         }
4385
4386         my $localtime_format = '(%02d:%02d %s)';
4387         if ($date->{'hour_local'} < 6) {
4388                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4389         }
4390         $strtime .= ' ' .
4391                     sprintf($localtime_format,
4392                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4393
4394         return $strtime;
4395 }
4396
4397 # Outputs the author name and date in long form
4398 sub git_print_authorship {
4399         my $co = shift;
4400         my %opts = @_;
4401         my $tag = $opts{-tag} || 'div';
4402         my $author = $co->{'author_name'};
4403
4404         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4405         print "<$tag class=\"author_date\">" .
4406               format_search_author($author, "author", esc_html($author)) .
4407               " [".format_timestamp_html(\%ad)."]".
4408               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4409               "</$tag>\n";
4410 }
4411
4412 # Outputs table rows containing the full author or committer information,
4413 # in the format expected for 'commit' view (& similar).
4414 # Parameters are a commit hash reference, followed by the list of people
4415 # to output information for. If the list is empty it defaults to both
4416 # author and committer.
4417 sub git_print_authorship_rows {
4418         my $co = shift;
4419         # too bad we can't use @people = @_ || ('author', 'committer')
4420         my @people = @_;
4421         @people = ('author', 'committer') unless @people;
4422         foreach my $who (@people) {
4423                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4424                 print "<tr><td>$who</td><td>" .
4425                       format_search_author($co->{"${who}_name"}, $who,
4426                                            esc_html($co->{"${who}_name"})) . " " .
4427                       format_search_author($co->{"${who}_email"}, $who,
4428                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4429                       "</td><td rowspan=\"2\">" .
4430                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4431                       "</td></tr>\n" .
4432                       "<tr>" .
4433                       "<td></td><td>" .
4434                       format_timestamp_html(\%wd) .
4435                       "</td>" .
4436                       "</tr>\n";
4437         }
4438 }
4439
4440 sub git_print_page_path {
4441         my $name = shift;
4442         my $type = shift;
4443         my $hb = shift;
4444
4445
4446         print "<div class=\"page_path\">";
4447         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4448                       -title => 'tree root'}, to_utf8("[$project]"));
4449         print " / ";
4450         if (defined $name) {
4451                 my @dirname = split '/', $name;
4452                 my $basename = pop @dirname;
4453                 my $fullname = '';
4454
4455                 foreach my $dir (@dirname) {
4456                         $fullname .= ($fullname ? '/' : '') . $dir;
4457                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4458                                                      hash_base=>$hb),
4459                                       -title => $fullname}, esc_path($dir));
4460                         print " / ";
4461                 }
4462                 if (defined $type && $type eq 'blob') {
4463                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4464                                                      hash_base=>$hb),
4465                                       -title => $name}, esc_path($basename));
4466                         print '&nbsp;&nbsp;&nbsp;&nbsp;
4467 <a id="lineNoToggle" href="#" onclick="toggleLineNumbers();"></a>
4468 <script>
4469 function toggleLineNumbers() {
4470         e = document.getElementById("lineNoStyle");
4471         e2 = document.getElementById("lineNoToggle");
4472         if (e2.innerHTML == "[Hide line numbers]") {
4473                 e.innerHTML = ".linenr { display:none; }";
4474                 e2.innerHTML = "[Show line numbers]";
4475         }
4476         else {
4477                 e.innerHTML = "";
4478                 e2.innerHTML = "[Hide line numbers]";
4479         }
4480 }
4481 var style = document.createElement("style");
4482 style.setAttribute("id", "lineNoStyle");
4483 document.getElementsByTagName("head")[0].appendChild(style);
4484 toggleLineNumbers();
4485 </script>
4486 ';
4487                 } elsif (defined $type && $type eq 'tree') {
4488                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4489                                                      hash_base=>$hb),
4490                                       -title => $name}, esc_path($basename));
4491                         print " / ";
4492                 } else {
4493                         print esc_path($basename);
4494                 }
4495         }
4496         print "<br/></div>\n";
4497 }
4498
4499 sub git_print_log {
4500         my $log = shift;
4501         my %opts = @_;
4502
4503         if ($opts{'-remove_title'}) {
4504                 # remove title, i.e. first line of log
4505                 shift @$log;
4506         }
4507         # remove leading empty lines
4508         while (defined $log->[0] && $log->[0] eq "") {
4509                 shift @$log;
4510         }
4511
4512         # print log
4513         my $skip_blank_line = 0;
4514         foreach my $line (@$log) {
4515                 if ($line =~ m/^\s*([A-Z][-A-Za-z]*-[Bb]y|C[Cc]): /) {
4516                         if (! $opts{'-remove_signoff'}) {
4517                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4518                                 $skip_blank_line = 1;
4519                         }
4520                         next;
4521                 }
4522
4523                 if ($line =~ m,\s*([a-z]*link): (https?://\S+),i) {
4524                         if (! $opts{'-remove_signoff'}) {
4525                                 print "<span class=\"signoff\">" . esc_html($1) . ": " .
4526                                         "<a href=\"" . esc_html($2) . "\">" . esc_html($2) . "</a>" .
4527                                         "</span><br/>\n";
4528                                 $skip_blank_line = 1;
4529                         }
4530                         next;
4531                 }
4532
4533                 # print only one empty line
4534                 # do not print empty line after signoff
4535                 if ($line eq "") {
4536                         next if ($skip_blank_line);
4537                         $skip_blank_line = 1;
4538                 } else {
4539                         $skip_blank_line = 0;
4540                 }
4541
4542                 print format_log_line_html($line) . "<br/>\n";
4543         }
4544
4545         if ($opts{'-final_empty_line'}) {
4546                 # end with single empty line
4547                 print "<br/>\n" unless $skip_blank_line;
4548         }
4549 }
4550
4551 # return link target (what link points to)
4552 sub git_get_link_target {
4553         my $hash = shift;
4554         my $link_target;
4555
4556         # read link
4557         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4558                 or return;
4559         {
4560                 local $/ = undef;
4561                 $link_target = <$fd>;
4562         }
4563         close $fd
4564                 or return;
4565
4566         return $link_target;
4567 }
4568
4569 # given link target, and the directory (basedir) the link is in,
4570 # return target of link relative to top directory (top tree);
4571 # return undef if it is not possible (including absolute links).
4572 sub normalize_link_target {
4573         my ($link_target, $basedir) = @_;
4574
4575         # absolute symlinks (beginning with '/') cannot be normalized
4576         return if (substr($link_target, 0, 1) eq '/');
4577
4578         # normalize link target to path from top (root) tree (dir)
4579         my $path;
4580         if ($basedir) {
4581                 $path = $basedir . '/' . $link_target;
4582         } else {
4583                 # we are in top (root) tree (dir)
4584                 $path = $link_target;
4585         }
4586
4587         # remove //, /./, and /../
4588         my @path_parts;
4589         foreach my $part (split('/', $path)) {
4590                 # discard '.' and ''
4591                 next if (!$part || $part eq '.');
4592                 # handle '..'
4593                 if ($part eq '..') {
4594                         if (@path_parts) {
4595                                 pop @path_parts;
4596                         } else {
4597                                 # link leads outside repository (outside top dir)
4598                                 return;
4599                         }
4600                 } else {
4601                         push @path_parts, $part;
4602                 }
4603         }
4604         $path = join('/', @path_parts);
4605
4606         return $path;
4607 }
4608
4609 # print tree entry (row of git_tree), but without encompassing <tr> element
4610 sub git_print_tree_entry {
4611         my ($t, $basedir, $hash_base, $have_blame) = @_;
4612
4613         my %base_key = ();
4614         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4615
4616         # The format of a table row is: mode list link.  Where mode is
4617         # the mode of the entry, list is the name of the entry, an href,
4618         # and link is the action links of the entry.
4619
4620         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4621         if (exists $t->{'size'}) {
4622                 print "<td class=\"size\">$t->{'size'}</td>\n";
4623         }
4624         if ($t->{'type'} eq "blob") {
4625                 print "<td class=\"list\">" .
4626                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4627                                                file_name=>"$basedir$t->{'name'}", %base_key),
4628                                 -class => "list"}, esc_path($t->{'name'}));
4629                 if (S_ISLNK(oct $t->{'mode'})) {
4630                         my $link_target = git_get_link_target($t->{'hash'});
4631                         if ($link_target) {
4632                                 my $norm_target = normalize_link_target($link_target, $basedir);
4633                                 if (defined $norm_target) {
4634                                         print " -> " .
4635                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4636                                                                      file_name=>$norm_target),
4637                                                        -title => $norm_target}, esc_path($link_target));
4638                                 } else {
4639                                         print " -> " . esc_path($link_target);
4640                                 }
4641                         }
4642                 }
4643                 print "</td>\n";
4644                 print "<td class=\"link\">";
4645                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4646                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4647                               "blob");
4648                 if ($have_blame) {
4649                         print " | " .
4650                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4651                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4652                                       "blame");
4653                 }
4654                 if (defined $hash_base) {
4655                         print " | " .
4656                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4657                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4658                                       "history");
4659                 }
4660                 print " | " .
4661                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4662                                                file_name=>"$basedir$t->{'name'}")},
4663                                 "raw");
4664                 print "</td>\n";
4665
4666         } elsif ($t->{'type'} eq "tree") {
4667                 print "<td class=\"list\">";
4668                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4669                                              file_name=>"$basedir$t->{'name'}",
4670                                              %base_key)},
4671                               esc_path($t->{'name'}));
4672                 print "</td>\n";
4673                 print "<td class=\"link\">";
4674                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4675                                              file_name=>"$basedir$t->{'name'}",
4676                                              %base_key)},
4677                               "tree");
4678                 if (defined $hash_base) {
4679                         print " | " .
4680                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4681                                                      file_name=>"$basedir$t->{'name'}")},
4682                                       "history");
4683                 }
4684                 print "</td>\n";
4685         } else {
4686                 # unknown object: we can only present history for it
4687                 # (this includes 'commit' object, i.e. submodule support)
4688                 print "<td class=\"list\">" .
4689                       esc_path($t->{'name'}) .
4690                       "</td>\n";
4691                 print "<td class=\"link\">";
4692                 if (defined $hash_base) {
4693                         print $cgi->a({-href => href(action=>"history",
4694                                                      hash_base=>$hash_base,
4695                                                      file_name=>"$basedir$t->{'name'}")},
4696                                       "history");
4697                 }
4698                 print "</td>\n";
4699         }
4700 }
4701
4702 ## ......................................................................
4703 ## functions printing large fragments of HTML
4704
4705 # get pre-image filenames for merge (combined) diff
4706 sub fill_from_file_info {
4707         my ($diff, @parents) = @_;
4708
4709         $diff->{'from_file'} = [ ];
4710         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4711         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4712                 if ($diff->{'status'}[$i] eq 'R' ||
4713                     $diff->{'status'}[$i] eq 'C') {
4714                         $diff->{'from_file'}[$i] =
4715                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4716                 }
4717         }
4718
4719         return $diff;
4720 }
4721
4722 # is current raw difftree line of file deletion
4723 sub is_deleted {
4724         my $diffinfo = shift;
4725
4726         return $diffinfo->{'to_id'} eq ('0' x 40);
4727 }
4728
4729 # does patch correspond to [previous] difftree raw line
4730 # $diffinfo  - hashref of parsed raw diff format
4731 # $patchinfo - hashref of parsed patch diff format
4732 #              (the same keys as in $diffinfo)
4733 sub is_patch_split {
4734         my ($diffinfo, $patchinfo) = @_;
4735
4736         return defined $diffinfo && defined $patchinfo
4737                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4738 }
4739
4740
4741 sub git_difftree_body {
4742         my ($difftree, $hash, @parents) = @_;
4743         my ($parent) = $parents[0];
4744         my $have_blame = gitweb_check_feature('blame');
4745         print "<div class=\"list_head\">\n";
4746         if ($#{$difftree} > 10) {
4747                 print(($#{$difftree} + 1) . " files changed:\n");
4748         }
4749         print "</div>\n";
4750
4751         print "<table class=\"" .
4752               (@parents > 1 ? "combined " : "") .
4753               "diff_tree\">\n";
4754
4755         # header only for combined diff in 'commitdiff' view
4756         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4757         if ($has_header) {
4758                 # table header
4759                 print "<thead><tr>\n" .
4760                        "<th></th><th></th>\n"; # filename, patchN link
4761                 for (my $i = 0; $i < @parents; $i++) {
4762                         my $par = $parents[$i];
4763                         print "<th>" .
4764                               $cgi->a({-href => href(action=>"commitdiff",
4765                                                      hash=>$hash, hash_parent=>$par),
4766                                        -title => 'commitdiff to parent number ' .
4767                                                   ($i+1) . ': ' . substr($par,0,7)},
4768                                       $i+1) .
4769                               "&nbsp;</th>\n";
4770                 }
4771                 print "</tr></thead>\n<tbody>\n";
4772         }
4773
4774         my $alternate = 1;
4775         my $patchno = 0;
4776         foreach my $line (@{$difftree}) {
4777                 my $diff = parsed_difftree_line($line);
4778
4779                 if ($alternate) {
4780                         print "<tr class=\"dark\">\n";
4781                 } else {
4782                         print "<tr class=\"light\">\n";
4783                 }
4784                 $alternate ^= 1;
4785
4786                 if (exists $diff->{'nparents'}) { # combined diff
4787
4788                         fill_from_file_info($diff, @parents)
4789                                 unless exists $diff->{'from_file'};
4790
4791                         if (!is_deleted($diff)) {
4792                                 # file exists in the result (child) commit
4793                                 print "<td>" .
4794                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4795                                                              file_name=>$diff->{'to_file'},
4796                                                              hash_base=>$hash),
4797                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4798                                       "</td>\n";
4799                         } else {
4800                                 print "<td>" .
4801                                       esc_path($diff->{'to_file'}) .
4802                                       "</td>\n";
4803                         }
4804
4805                         if ($action eq 'commitdiff') {
4806                                 # link to patch
4807                                 $patchno++;
4808                                 print "<td class=\"link\">" .
4809                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4810                                               "patch") .
4811                                       " | " .
4812                                       "</td>\n";
4813                         }
4814
4815                         my $has_history = 0;
4816                         my $not_deleted = 0;
4817                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4818                                 my $hash_parent = $parents[$i];
4819                                 my $from_hash = $diff->{'from_id'}[$i];
4820                                 my $from_path = $diff->{'from_file'}[$i];
4821                                 my $status = $diff->{'status'}[$i];
4822
4823                                 $has_history ||= ($status ne 'A');
4824                                 $not_deleted ||= ($status ne 'D');
4825
4826                                 if ($status eq 'A') {
4827                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4828                                 } elsif ($status eq 'D') {
4829                                         print "<td class=\"link\">" .
4830                                               $cgi->a({-href => href(action=>"blob",
4831                                                                      hash_base=>$hash,
4832                                                                      hash=>$from_hash,
4833                                                                      file_name=>$from_path)},
4834                                                       "blob" . ($i+1)) .
4835                                               " | </td>\n";
4836                                 } else {
4837                                         if ($diff->{'to_id'} eq $from_hash) {
4838                                                 print "<td class=\"link nochange\">";
4839                                         } else {
4840                                                 print "<td class=\"link\">";
4841                                         }
4842                                         print $cgi->a({-href => href(action=>"blobdiff",
4843                                                                      hash=>$diff->{'to_id'},
4844                                                                      hash_parent=>$from_hash,
4845                                                                      hash_base=>$hash,
4846                                                                      hash_parent_base=>$hash_parent,
4847                                                                      file_name=>$diff->{'to_file'},
4848                                                                      file_parent=>$from_path)},
4849                                                       "diff" . ($i+1)) .
4850                                               " | </td>\n";
4851                                 }
4852                         }
4853
4854                         print "<td class=\"link\">";
4855                         if ($not_deleted) {
4856                                 print $cgi->a({-href => href(action=>"blob",
4857                                                              hash=>$diff->{'to_id'},
4858                                                              file_name=>$diff->{'to_file'},
4859                                                              hash_base=>$hash)},
4860                                               "blob");
4861                                 print " | " if ($has_history);
4862                         }
4863                         if ($has_history) {
4864                                 print $cgi->a({-href => href(action=>"history",
4865                                                              file_name=>$diff->{'to_file'},
4866                                                              hash_base=>$hash)},
4867                                               "history");
4868                         }
4869                         print "</td>\n";
4870
4871                         print "</tr>\n";
4872                         next; # instead of 'else' clause, to avoid extra indent
4873                 }
4874                 # else ordinary diff
4875
4876                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4877                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4878                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4879                         $to_mode_oct = oct $diff->{'to_mode'};
4880                         if (S_ISREG($to_mode_oct)) { # only for regular file
4881                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4882                         }
4883                         $to_file_type = file_type($diff->{'to_mode'});
4884                 }
4885                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4886                         $from_mode_oct = oct $diff->{'from_mode'};
4887                         if (S_ISREG($from_mode_oct)) { # only for regular file
4888                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4889                         }
4890                         $from_file_type = file_type($diff->{'from_mode'});
4891                 }
4892
4893                 if ($diff->{'status'} eq "A") { # created
4894                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4895                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4896                         $mode_chng   .= "]</span>";
4897                         print "<td>";
4898                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4899                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4900                                       -class => "list"}, esc_path($diff->{'file'}));
4901                         print "</td>\n";
4902                         print "<td>$mode_chng</td>\n";
4903                         print "<td class=\"link\">";
4904                         if ($action eq 'commitdiff') {
4905                                 # link to patch
4906                                 $patchno++;
4907                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4908                                               "patch") .
4909                                       " | ";
4910                         }
4911                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4912                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4913                                       "blob");
4914                         print "</td>\n";
4915
4916                 } elsif ($diff->{'status'} eq "D") { # deleted
4917                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4918                         print "<td>";
4919                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4920                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4921                                        -class => "list"}, esc_path($diff->{'file'}));
4922                         print "</td>\n";
4923                         print "<td>$mode_chng</td>\n";
4924                         print "<td class=\"link\">";
4925                         if ($action eq 'commitdiff') {
4926                                 # link to patch
4927                                 $patchno++;
4928                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4929                                               "patch") .
4930                                       " | ";
4931                         }
4932                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4933                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4934                                       "blob") . " | ";
4935                         if ($have_blame) {
4936                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4937                                                              file_name=>$diff->{'file'})},
4938                                               "blame") . " | ";
4939                         }
4940                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4941                                                      file_name=>$diff->{'file'})},
4942                                       "history");
4943                         print "</td>\n";
4944
4945                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4946                         my $mode_chnge = "";
4947                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4948                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4949                                 if ($from_file_type ne $to_file_type) {
4950                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4951                                 }
4952                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4953                                         if ($from_mode_str && $to_mode_str) {
4954                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4955                                         } elsif ($to_mode_str) {
4956                                                 $mode_chnge .= " mode: $to_mode_str";
4957                                         }
4958                                 }
4959                                 $mode_chnge .= "]</span>\n";
4960                         }
4961                         print "<td>";
4962                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4963                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4964                                       -class => "list"}, esc_path($diff->{'file'}));
4965                         print "</td>\n";
4966                         print "<td>$mode_chnge</td>\n";
4967                         print "<td class=\"link\">";
4968                         if ($action eq 'commitdiff') {
4969                                 # link to patch
4970                                 $patchno++;
4971                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4972                                               "patch") .
4973                                       " | ";
4974                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4975                                 # "commit" view and modified file (not onlu mode changed)
4976                                 print $cgi->a({-href => href(action=>"blobdiff",
4977                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4978                                                              hash_base=>$hash, hash_parent_base=>$parent,
4979                                                              file_name=>$diff->{'file'})},
4980                                               "diff") .
4981                                       " | ";
4982                         }
4983                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4984                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4985                                        "blob") . " | ";
4986                         if ($have_blame) {
4987                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4988                                                              file_name=>$diff->{'file'})},
4989                                               "blame") . " | ";
4990                         }
4991                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4992                                                      file_name=>$diff->{'file'})},
4993                                       "history");
4994                         print "</td>\n";
4995
4996                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4997                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4998                         my $nstatus = $status_name{$diff->{'status'}};
4999                         my $mode_chng = "";
5000                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5001                                 # mode also for directories, so we cannot use $to_mode_str
5002                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
5003                         }
5004                         print "<td>" .
5005                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
5006                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
5007                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
5008                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
5009                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
5010                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
5011                                       -class => "list"}, esc_path($diff->{'from_file'})) .
5012                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
5013                               "<td class=\"link\">";
5014                         if ($action eq 'commitdiff') {
5015                                 # link to patch
5016                                 $patchno++;
5017                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5018                                               "patch") .
5019                                       " | ";
5020                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5021                                 # "commit" view and modified file (not only pure rename or copy)
5022                                 print $cgi->a({-href => href(action=>"blobdiff",
5023                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5024                                                              hash_base=>$hash, hash_parent_base=>$parent,
5025                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
5026                                               "diff") .
5027                                       " | ";
5028                         }
5029                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5030                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
5031                                       "blob") . " | ";
5032                         if ($have_blame) {
5033                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5034                                                              file_name=>$diff->{'to_file'})},
5035                                               "blame") . " | ";
5036                         }
5037                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5038                                                     file_name=>$diff->{'to_file'})},
5039                                       "history");
5040                         print "</td>\n";
5041
5042                 } # we should not encounter Unmerged (U) or Unknown (X) status
5043                 print "</tr>\n";
5044         }
5045         print "</tbody>" if $has_header;
5046         print "</table>\n";
5047 }
5048
5049 # Print context lines and then rem/add lines in a side-by-side manner.
5050 sub print_sidebyside_diff_lines {
5051         my ($ctx, $rem, $add) = @_;
5052
5053         # print context block before add/rem block
5054         if (@$ctx) {
5055                 print join '',
5056                         '<div class="chunk_block ctx">',
5057                                 '<div class="old">',
5058                                 @$ctx,
5059                                 '</div>',
5060                                 '<div class="new">',
5061                                 @$ctx,
5062                                 '</div>',
5063                         '</div>';
5064         }
5065
5066         if (!@$add) {
5067                 # pure removal
5068                 print join '',
5069                         '<div class="chunk_block rem">',
5070                                 '<div class="old">',
5071                                 @$rem,
5072                                 '</div>',
5073                         '</div>';
5074         } elsif (!@$rem) {
5075                 # pure addition
5076                 print join '',
5077                         '<div class="chunk_block add">',
5078                                 '<div class="new">',
5079                                 @$add,
5080                                 '</div>',
5081                         '</div>';
5082         } else {
5083                 print join '',
5084                         '<div class="chunk_block chg">',
5085                                 '<div class="old">',
5086                                 @$rem,
5087                                 '</div>',
5088                                 '<div class="new">',
5089                                 @$add,
5090                                 '</div>',
5091                         '</div>';
5092         }
5093 }
5094
5095 # Print context lines and then rem/add lines in inline manner.
5096 sub print_inline_diff_lines {
5097         my ($ctx, $rem, $add) = @_;
5098
5099         print @$ctx, @$rem, @$add;
5100 }
5101
5102 # Format removed and added line, mark changed part and HTML-format them.
5103 # Implementation is based on contrib/diff-highlight
5104 sub format_rem_add_lines_pair {
5105         my ($rem, $add, $num_parents) = @_;
5106
5107         # We need to untabify lines before split()'ing them;
5108         # otherwise offsets would be invalid.
5109         chomp $rem;
5110         chomp $add;
5111         $rem = untabify($rem);
5112         $add = untabify($add);
5113
5114         my @rem = split(//, $rem);
5115         my @add = split(//, $add);
5116         my ($esc_rem, $esc_add);
5117         # Ignore leading +/- characters for each parent.
5118         my ($prefix_len, $suffix_len) = ($num_parents, 0);
5119         my ($prefix_has_nonspace, $suffix_has_nonspace);
5120
5121         my $shorter = (@rem < @add) ? @rem : @add;
5122         while ($prefix_len < $shorter) {
5123                 last if ($rem[$prefix_len] ne $add[$prefix_len]);
5124
5125                 $prefix_has_nonspace = 1 if ($rem[$prefix_len] !~ /\s/);
5126                 $prefix_len++;
5127         }
5128
5129         while ($prefix_len + $suffix_len < $shorter) {
5130                 last if ($rem[-1 - $suffix_len] ne $add[-1 - $suffix_len]);
5131
5132                 $suffix_has_nonspace = 1 if ($rem[-1 - $suffix_len] !~ /\s/);
5133                 $suffix_len++;
5134         }
5135
5136         # Mark lines that are different from each other, but have some common
5137         # part that isn't whitespace.  If lines are completely different, don't
5138         # mark them because that would make output unreadable, especially if
5139         # diff consists of multiple lines.
5140         if ($prefix_has_nonspace || $suffix_has_nonspace) {
5141                 $esc_rem = esc_html_hl_regions($rem, 'marked',
5142                         [$prefix_len, @rem - $suffix_len], -nbsp=>1);
5143                 $esc_add = esc_html_hl_regions($add, 'marked',
5144                         [$prefix_len, @add - $suffix_len], -nbsp=>1);
5145         } else {
5146                 $esc_rem = esc_html($rem, -nbsp=>1);
5147                 $esc_add = esc_html($add, -nbsp=>1);
5148         }
5149
5150         return format_diff_line(\$esc_rem, 'rem'),
5151                format_diff_line(\$esc_add, 'add');
5152 }
5153
5154 # HTML-format diff context, removed and added lines.
5155 sub format_ctx_rem_add_lines {
5156         my ($ctx, $rem, $add, $num_parents) = @_;
5157         my (@new_ctx, @new_rem, @new_add);
5158         my $can_highlight = 0;
5159         my $is_combined = ($num_parents > 1);
5160
5161         # Highlight if every removed line has a corresponding added line.
5162         if (@$add > 0 && @$add == @$rem) {
5163                 $can_highlight = 1;
5164
5165                 # Highlight lines in combined diff only if the chunk contains
5166                 # diff between the same version, e.g.
5167                 #
5168                 #    - a
5169                 #   -  b
5170                 #    + c
5171                 #   +  d
5172                 #
5173                 # Otherwise the highlightling would be confusing.
5174                 if ($is_combined) {
5175                         for (my $i = 0; $i < @$add; $i++) {
5176                                 my $prefix_rem = substr($rem->[$i], 0, $num_parents);
5177                                 my $prefix_add = substr($add->[$i], 0, $num_parents);
5178
5179                                 $prefix_rem =~ s/-/+/g;
5180
5181                                 if ($prefix_rem ne $prefix_add) {
5182                                         $can_highlight = 0;
5183                                         last;
5184                                 }
5185                         }
5186                 }
5187         }
5188
5189         if ($can_highlight) {
5190                 for (my $i = 0; $i < @$add; $i++) {
5191                         my ($line_rem, $line_add) = format_rem_add_lines_pair(
5192                                 $rem->[$i], $add->[$i], $num_parents);
5193                         push @new_rem, $line_rem;
5194                         push @new_add, $line_add;
5195                 }
5196         } else {
5197                 @new_rem = map { format_diff_line($_, 'rem') } @$rem;
5198                 @new_add = map { format_diff_line($_, 'add') } @$add;
5199         }
5200
5201         @new_ctx = map { format_diff_line($_, 'ctx') } @$ctx;
5202
5203         return (\@new_ctx, \@new_rem, \@new_add);
5204 }
5205
5206 # Print context lines and then rem/add lines.
5207 sub print_diff_lines {
5208         my ($ctx, $rem, $add, $diff_style, $num_parents) = @_;
5209         my $is_combined = $num_parents > 1;
5210
5211         ($ctx, $rem, $add) = format_ctx_rem_add_lines($ctx, $rem, $add,
5212                 $num_parents);
5213
5214         if ($diff_style eq 'sidebyside' && !$is_combined) {
5215                 print_sidebyside_diff_lines($ctx, $rem, $add);
5216         } else {
5217                 # default 'inline' style and unknown styles
5218                 print_inline_diff_lines($ctx, $rem, $add);
5219         }
5220 }
5221
5222 sub print_diff_chunk {
5223         my ($diff_style, $num_parents, $from, $to, @chunk) = @_;
5224         my (@ctx, @rem, @add);
5225
5226         # The class of the previous line.
5227         my $prev_class = '';
5228
5229         return unless @chunk;
5230
5231         # incomplete last line might be among removed or added lines,
5232         # or both, or among context lines: find which
5233         for (my $i = 1; $i < @chunk; $i++) {
5234                 if ($chunk[$i][0] eq 'incomplete') {
5235                         $chunk[$i][0] = $chunk[$i-1][0];
5236                 }
5237         }
5238
5239         # guardian
5240         push @chunk, ["", ""];
5241
5242         foreach my $line_info (@chunk) {
5243                 my ($class, $line) = @$line_info;
5244
5245                 # print chunk headers
5246                 if ($class && $class eq 'chunk_header') {
5247                         print format_diff_line($line, $class, $from, $to);
5248                         next;
5249                 }
5250
5251                 ## print from accumulator when have some add/rem lines or end
5252                 # of chunk (flush context lines), or when have add and rem
5253                 # lines and new block is reached (otherwise add/rem lines could
5254                 # be reordered)
5255                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5256                     (@rem && @add && $class ne $prev_class)) {
5257                         print_diff_lines(\@ctx, \@rem, \@add,
5258                                          $diff_style, $num_parents);
5259                         @ctx = @rem = @add = ();
5260                 }
5261
5262                 ## adding lines to accumulator
5263                 # guardian value
5264                 last unless $line;
5265                 # rem, add or change
5266                 if ($class eq 'rem') {
5267                         push @rem, $line;
5268                 } elsif ($class eq 'add') {
5269                         push @add, $line;
5270                 }
5271                 # context line
5272                 if ($class eq 'ctx') {
5273                         push @ctx, $line;
5274                 }
5275
5276                 $prev_class = $class;
5277         }
5278 }
5279
5280 sub git_patchset_body {
5281         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5282         my ($hash_parent) = $hash_parents[0];
5283
5284         my $is_combined = (@hash_parents > 1);
5285         my $patch_idx = 0;
5286         my $patch_number = 0;
5287         my $patch_line;
5288         my $diffinfo;
5289         my $to_name;
5290         my (%from, %to);
5291         my @chunk; # for side-by-side diff
5292
5293         print "<div class=\"patchset\">\n";
5294
5295         # skip to first patch
5296         while ($patch_line = <$fd>) {
5297                 chomp $patch_line;
5298
5299                 last if ($patch_line =~ m/^diff /);
5300         }
5301
5302  PATCH:
5303         while ($patch_line) {
5304
5305                 # parse "git diff" header line
5306                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5307                         # $1 is from_name, which we do not use
5308                         $to_name = unquote($2);
5309                         $to_name =~ s!^b/!!;
5310                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5311                         # $1 is 'cc' or 'combined', which we do not use
5312                         $to_name = unquote($2);
5313                 } else {
5314                         $to_name = undef;
5315                 }
5316
5317                 # check if current patch belong to current raw line
5318                 # and parse raw git-diff line if needed
5319                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5320                         # this is continuation of a split patch
5321                         print "<div class=\"patch cont\">\n";
5322                 } else {
5323                         # advance raw git-diff output if needed
5324                         $patch_idx++ if defined $diffinfo;
5325
5326                         # read and prepare patch information
5327                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5328
5329                         # compact combined diff output can have some patches skipped
5330                         # find which patch (using pathname of result) we are at now;
5331                         if ($is_combined) {
5332                                 while ($to_name ne $diffinfo->{'to_file'}) {
5333                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5334                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5335                                               "</div>\n";  # class="patch"
5336
5337                                         $patch_idx++;
5338                                         $patch_number++;
5339
5340                                         last if $patch_idx > $#$difftree;
5341                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5342                                 }
5343                         }
5344
5345                         # modifies %from, %to hashes
5346                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5347
5348                         # this is first patch for raw difftree line with $patch_idx index
5349                         # we index @$difftree array from 0, but number patches from 1
5350                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5351                 }
5352
5353                 # git diff header
5354                 #assert($patch_line =~ m/^diff /) if DEBUG;
5355                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5356                 $patch_number++;
5357                 # print "git diff" header
5358                 print format_git_diff_header_line($patch_line, $diffinfo,
5359                                                   \%from, \%to);
5360
5361                 # print extended diff header
5362                 print "<div class=\"diff extended_header\">\n";
5363         EXTENDED_HEADER:
5364                 while ($patch_line = <$fd>) {
5365                         chomp $patch_line;
5366
5367                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5368
5369                         print format_extended_diff_header_line($patch_line, $diffinfo,
5370                                                                \%from, \%to);
5371                 }
5372                 print "</div>\n"; # class="diff extended_header"
5373
5374                 # from-file/to-file diff header
5375                 if (! $patch_line) {
5376                         print "</div>\n"; # class="patch"
5377                         last PATCH;
5378                 }
5379                 next PATCH if ($patch_line =~ m/^diff /);
5380                 #assert($patch_line =~ m/^---/) if DEBUG;
5381
5382                 my $last_patch_line = $patch_line;
5383                 $patch_line = <$fd>;
5384                 chomp $patch_line;
5385                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5386
5387                 print format_diff_from_to_header($last_patch_line, $patch_line,
5388                                                  $diffinfo, \%from, \%to,
5389                                                  @hash_parents);
5390
5391                 # the patch itself
5392         LINE:
5393                 while ($patch_line = <$fd>) {
5394                         chomp $patch_line;
5395
5396                         next PATCH if ($patch_line =~ m/^diff /);
5397
5398                         my $class = diff_line_class($patch_line, \%from, \%to);
5399
5400                         if ($class eq 'chunk_header') {
5401                                 print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5402                                 @chunk = ();
5403                         }
5404
5405                         push @chunk, [ $class, $patch_line ];
5406                 }
5407
5408         } continue {
5409                 if (@chunk) {
5410                         print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5411                         @chunk = ();
5412                 }
5413                 print "</div>\n"; # class="patch"
5414         }
5415
5416         # for compact combined (--cc) format, with chunk and patch simplification
5417         # the patchset might be empty, but there might be unprocessed raw lines
5418         for (++$patch_idx if $patch_number > 0;
5419              $patch_idx < @$difftree;
5420              ++$patch_idx) {
5421                 # read and prepare patch information
5422                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5423
5424                 # generate anchor for "patch" links in difftree / whatchanged part
5425                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5426                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5427                       "</div>\n";  # class="patch"
5428
5429                 $patch_number++;
5430         }
5431
5432         if ($patch_number == 0) {
5433                 if (@hash_parents > 1) {
5434                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5435                 } else {
5436                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5437                 }
5438         }
5439
5440         print "</div>\n"; # class="patchset"
5441 }
5442
5443 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5444
5445 sub git_project_search_form {
5446         my ($searchtext, $search_use_regexp) = @_;
5447
5448         my $limit = '';
5449         if ($project_filter) {
5450                 $limit = " in '$project_filter/'";
5451         }
5452
5453         print "<div class=\"projsearch\">\n";
5454         print $cgi->startform(-method => 'get', -action => $my_uri) .
5455               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5456         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5457                 if (defined $project_filter);
5458         print $cgi->textfield(-name => 's', -value => $searchtext,
5459                               -title => "Search project by name and description$limit",
5460                               -size => 60) . "\n" .
5461               "<span title=\"Extended regular expression\">" .
5462               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5463                              -checked => $search_use_regexp) .
5464               "</span>\n" .
5465               $cgi->submit(-name => 'btnS', -value => 'Search') .
5466               $cgi->end_form() . "\n" .
5467               $cgi->a({-href => href(project => undef, searchtext => undef,
5468                                      project_filter => $project_filter)},
5469                       esc_html("List all projects$limit")) . "<br />\n";
5470         print "</div>\n";
5471 }
5472
5473 # entry for given @keys needs filling if at least one of keys in list
5474 # is not present in %$project_info
5475 sub project_info_needs_filling {
5476         my ($project_info, @keys) = @_;
5477
5478         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5479         foreach my $key (@keys) {
5480                 if (!exists $project_info->{$key}) {
5481                         return 1;
5482                 }
5483         }
5484         return;
5485 }
5486
5487 # fills project list info (age, description, owner, category, forks, etc.)
5488 # for each project in the list, removing invalid projects from
5489 # returned list, or fill only specified info.
5490 #
5491 # Invalid projects are removed from the returned list if and only if you
5492 # ask 'age' or 'age_string' to be filled, because they are the only fields
5493 # that run unconditionally git command that requires repository, and
5494 # therefore do always check if project repository is invalid.
5495 #
5496 # USAGE:
5497 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5498 #   ensures that 'descr_long' and 'ctags' fields are filled
5499 # * @project_list = fill_project_list_info(\@project_list)
5500 #   ensures that all fields are filled (and invalid projects removed)
5501 #
5502 # NOTE: modifies $projlist, but does not remove entries from it
5503 sub fill_project_list_info {
5504         my ($projlist, @wanted_keys) = @_;
5505         my @projects;
5506         my $filter_set = sub { return @_; };
5507         if (@wanted_keys) {
5508                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5509                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5510         }
5511
5512         my $show_ctags = gitweb_check_feature('ctags');
5513  PROJECT:
5514         foreach my $pr (@$projlist) {
5515                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5516                         my (@activity) = git_get_last_activity($pr->{'path'});
5517                         unless (@activity) {
5518                                 next PROJECT;
5519                         }
5520                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5521                 }
5522                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5523                         my $descr = git_get_project_description($pr->{'path'}) || "";
5524                         $descr = to_utf8($descr);
5525                         $pr->{'descr_long'} = $descr;
5526                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5527                 }
5528                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5529                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5530                 }
5531                 if ($show_ctags &&
5532                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5533                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5534                 }
5535                 if ($projects_list_group_categories &&
5536                     project_info_needs_filling($pr, $filter_set->('category'))) {
5537                         my $cat = git_get_project_category($pr->{'path'}) ||
5538                                                            $project_list_default_category;
5539                         $pr->{'category'} = to_utf8($cat);
5540                 }
5541
5542                 push @projects, $pr;
5543         }
5544
5545         return @projects;
5546 }
5547
5548 sub sort_projects_list {
5549         my ($projlist, $order) = @_;
5550         my @projects;
5551
5552         my %order_info = (
5553                 project => { key => 'path', type => 'str' },
5554                 descr => { key => 'descr_long', type => 'str' },
5555                 owner => { key => 'owner', type => 'str' },
5556                 age => { key => 'age', type => 'num' }
5557         );
5558         my $oi = $order_info{$order};
5559         return @$projlist unless defined $oi;
5560         if ($oi->{'type'} eq 'str') {
5561                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5562         } else {
5563                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5564         }
5565
5566         return @projects;
5567 }
5568
5569 # returns a hash of categories, containing the list of project
5570 # belonging to each category
5571 sub build_projlist_by_category {
5572         my ($projlist, $from, $to) = @_;
5573         my %categories;
5574
5575         $from = 0 unless defined $from;
5576         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5577
5578         for (my $i = $from; $i <= $to; $i++) {
5579                 my $pr = $projlist->[$i];
5580                 push @{$categories{ $pr->{'category'} }}, $pr;
5581         }
5582
5583         return wantarray ? %categories : \%categories;
5584 }
5585
5586 # print 'sort by' <th> element, generating 'sort by $name' replay link
5587 # if that order is not selected
5588 sub print_sort_th {
5589         print format_sort_th(@_);
5590 }
5591
5592 sub format_sort_th {
5593         my ($name, $order, $header) = @_;
5594         my $sort_th = "";
5595         $header ||= ucfirst($name);
5596
5597         if ($order eq $name) {
5598                 $sort_th .= "<th>$header</th>\n";
5599         } else {
5600                 $sort_th .= "<th>" .
5601                             $cgi->a({-href => href(-replay=>1, order=>$name),
5602                                      -class => "header"}, $header) .
5603                             "</th>\n";
5604         }
5605
5606         return $sort_th;
5607 }
5608
5609 sub git_project_list_rows {
5610         my ($projlist, $from, $to, $check_forks) = @_;
5611
5612         $from = 0 unless defined $from;
5613         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5614
5615         my $alternate = 1;
5616         for (my $i = $from; $i <= $to; $i++) {
5617                 my $pr = $projlist->[$i];
5618
5619                 if ($alternate) {
5620                         print "<tr class=\"dark\">\n";
5621                 } else {
5622                         print "<tr class=\"light\">\n";
5623                 }
5624                 $alternate ^= 1;
5625
5626                 if ($check_forks) {
5627                         print "<td>";
5628                         if ($pr->{'forks'}) {
5629                                 my $nforks = scalar @{$pr->{'forks'}};
5630                                 if ($nforks > 0) {
5631                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5632                                                        -title => "$nforks forks"}, "+");
5633                                 } else {
5634                                         print $cgi->span({-title => "$nforks forks"}, "+");
5635                                 }
5636                         }
5637                         print "</td>\n";
5638                 }
5639                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5640                                         -class => "list"},
5641                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5642                       "</td>\n" .
5643                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5644                                         -class => "list",
5645                                         -title => $pr->{'descr_long'}},
5646                                         $search_regexp
5647                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5648                                                                     $pr->{'descr'}, $search_regexp)
5649                                         : esc_html($pr->{'descr'})) .
5650                       "</td>\n";
5651                 unless ($omit_owner) {
5652                         print "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5653                 }
5654                 unless ($omit_age_column) {
5655                         print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5656                             (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n";
5657                 }
5658                 print"<td class=\"link\">" .
5659                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5660                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5661                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5662                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5663                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5664                       "</td>\n" .
5665                       "</tr>\n";
5666         }
5667 }
5668
5669 sub git_project_list_body {
5670         # actually uses global variable $project
5671         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5672         my @projects = @$projlist;
5673
5674         my $check_forks = gitweb_check_feature('forks');
5675         my $show_ctags  = gitweb_check_feature('ctags');
5676         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5677         $check_forks = undef
5678                 if ($tagfilter || $search_regexp);
5679
5680         # filtering out forks before filling info allows to do less work
5681         @projects = filter_forks_from_projects_list(\@projects)
5682                 if ($check_forks);
5683         # search_projects_list pre-fills required info
5684         @projects = search_projects_list(\@projects,
5685                                          'search_regexp' => $search_regexp,
5686                                          'tagfilter'  => $tagfilter)
5687                 if ($tagfilter || $search_regexp);
5688         # fill the rest
5689         my @all_fields = ('descr', 'descr_long', 'ctags', 'category');
5690         push @all_fields, ('age', 'age_string') unless($omit_age_column);
5691         push @all_fields, 'owner' unless($omit_owner);
5692         @projects = fill_project_list_info(\@projects, @all_fields);
5693
5694         $order ||= $default_projects_order;
5695         $from = 0 unless defined $from;
5696         $to = $#projects if (!defined $to || $#projects < $to);
5697
5698         # short circuit
5699         if ($from > $to) {
5700                 print "<center>\n".
5701                       "<b>No such projects found</b><br />\n".
5702                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5703                       "</center>\n<br />\n";
5704                 return;
5705         }
5706
5707         @projects = sort_projects_list(\@projects, $order);
5708
5709         if ($show_ctags) {
5710                 my $ctags = git_gather_all_ctags(\@projects);
5711                 my $cloud = git_populate_project_tagcloud($ctags);
5712                 print git_show_project_tagcloud($cloud, 64);
5713         }
5714
5715         print "<table class=\"project_list\">\n";
5716         unless ($no_header) {
5717                 print "<tr>\n";
5718                 if ($check_forks) {
5719                         print "<th></th>\n";
5720                 }
5721                 print_sort_th('project', $order, 'Project');
5722                 print_sort_th('descr', $order, 'Description');
5723                 print_sort_th('owner', $order, 'Owner') unless $omit_owner;
5724                 print_sort_th('age', $order, 'Last Change') unless $omit_age_column;
5725                 print "<th></th>\n" . # for links
5726                       "</tr>\n";
5727         }
5728
5729         if ($projects_list_group_categories) {
5730                 # only display categories with projects in the $from-$to window
5731                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5732                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5733                 foreach my $cat (sort keys %categories) {
5734                         unless ($cat eq "") {
5735                                 print "<tr>\n";
5736                                 if ($check_forks) {
5737                                         print "<td></td>\n";
5738                                 }
5739                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5740                                 print "</tr>\n";
5741                         }
5742
5743                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5744                 }
5745         } else {
5746                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5747         }
5748
5749         if (defined $extra) {
5750                 print "<tr>\n";
5751                 if ($check_forks) {
5752                         print "<td></td>\n";
5753                 }
5754                 print "<td colspan=\"5\">$extra</td>\n" .
5755                       "</tr>\n";
5756         }
5757         print "</table>\n";
5758 }
5759
5760 sub git_log_body {
5761         # uses global variable $project
5762         my ($commitlist, $from, $to, $refs, $extra) = @_;
5763
5764         $from = 0 unless defined $from;
5765         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5766
5767         for (my $i = 0; $i <= $to; $i++) {
5768                 my %co = %{$commitlist->[$i]};
5769                 next if !%co;
5770                 my $commit = $co{'id'};
5771                 my $ref = format_ref_marker($refs, $commit);
5772                 git_print_header_div('commit',
5773                                "<span class=\"age\">$co{'age_string'}</span>" .
5774                                esc_html($co{'title'}) . $ref,
5775                                $commit);
5776                 print "<div class=\"title_text\">\n" .
5777                       "<div class=\"log_link\">\n" .
5778                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5779                       " | " .
5780                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5781                       " | " .
5782                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5783                       "<br/>\n" .
5784                       "</div>\n";
5785                       git_print_authorship(\%co, -tag => 'span');
5786                       print "<br/>\n</div>\n";
5787
5788                 print "<div class=\"log_body\">\n";
5789                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5790                 print "</div>\n";
5791         }
5792         if ($extra) {
5793                 print "<div class=\"page_nav\">\n";
5794                 print "$extra\n";
5795                 print "</div>\n";
5796         }
5797 }
5798
5799 sub git_shortlog_body {
5800         # uses global variable $project
5801         my ($commitlist, $from, $to, $refs, $extra) = @_;
5802
5803         $from = 0 unless defined $from;
5804         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5805
5806         print "<table class=\"shortlog\">\n";
5807         my $alternate = 1;
5808         for (my $i = $from; $i <= $to; $i++) {
5809                 my %co = %{$commitlist->[$i]};
5810                 my $commit = $co{'id'};
5811                 my $ref = format_ref_marker($refs, $commit);
5812                 if ($alternate) {
5813                         print "<tr class=\"dark\">\n";
5814                 } else {
5815                         print "<tr class=\"light\">\n";
5816                 }
5817                 $alternate ^= 1;
5818                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5819                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5820                       format_author_html('td', \%co, 10) . "<td>";
5821                 print format_subject_html($co{'title'}, $co{'title_short'},
5822                                           href(action=>"commit", hash=>$commit), $ref);
5823                 print "</td>\n" .
5824                       "<td class=\"link\">" .
5825                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5826                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5827                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5828                 my $snapshot_links = format_snapshot_links($commit);
5829                 if (defined $snapshot_links) {
5830                         print " | " . $snapshot_links;
5831                 }
5832                 print "</td>\n" .
5833                       "</tr>\n";
5834         }
5835         if (defined $extra) {
5836                 print "<tr>\n" .
5837                       "<td colspan=\"4\">$extra</td>\n" .
5838                       "</tr>\n";
5839         }
5840         print "</table>\n";
5841 }
5842
5843 sub git_history_body {
5844         # Warning: assumes constant type (blob or tree) during history
5845         my ($commitlist, $from, $to, $refs, $extra,
5846             $file_name, $file_hash, $ftype) = @_;
5847
5848         $from = 0 unless defined $from;
5849         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5850
5851         print "<table class=\"history\">\n";
5852         my $alternate = 1;
5853         for (my $i = $from; $i <= $to; $i++) {
5854                 my %co = %{$commitlist->[$i]};
5855                 if (!%co) {
5856                         next;
5857                 }
5858                 my $commit = $co{'id'};
5859
5860                 my $ref = format_ref_marker($refs, $commit);
5861
5862                 if ($alternate) {
5863                         print "<tr class=\"dark\">\n";
5864                 } else {
5865                         print "<tr class=\"light\">\n";
5866                 }
5867                 $alternate ^= 1;
5868                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5869         # shortlog:   format_author_html('td', \%co, 10)
5870                       format_author_html('td', \%co, 15, 3) . "<td>";
5871                 # originally git_history used chop_str($co{'title'}, 50)
5872                 print format_subject_html($co{'title'}, $co{'title_short'},
5873                                           href(action=>"commit", hash=>$commit), $ref);
5874                 print "</td>\n" .
5875                       "<td class=\"link\">" .
5876                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5877                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5878
5879                 if ($ftype eq 'blob') {
5880                         my $blob_current = $file_hash;
5881                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5882                         if (defined $blob_current && defined $blob_parent &&
5883                                         $blob_current ne $blob_parent) {
5884                                 print " | " .
5885                                         $cgi->a({-href => href(action=>"blobdiff",
5886                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5887                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5888                                                                file_name=>$file_name)},
5889                                                 "diff to current");
5890                         }
5891                 }
5892                 print "</td>\n" .
5893                       "</tr>\n";
5894         }
5895         if (defined $extra) {
5896                 print "<tr>\n" .
5897                       "<td colspan=\"4\">$extra</td>\n" .
5898                       "</tr>\n";
5899         }
5900         print "</table>\n";
5901 }
5902
5903 sub git_tags_body {
5904         # uses global variable $project
5905         my ($taglist, $from, $to, $extra) = @_;
5906         $from = 0 unless defined $from;
5907         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5908
5909         print "<table class=\"tags\">\n";
5910         my $alternate = 1;
5911         for (my $i = $from; $i <= $to; $i++) {
5912                 my $entry = $taglist->[$i];
5913                 my %tag = %$entry;
5914                 my $comment = $tag{'subject'};
5915                 my $comment_short;
5916                 if (defined $comment) {
5917                         $comment_short = chop_str($comment, 30, 5);
5918                 }
5919                 if ($alternate) {
5920                         print "<tr class=\"dark\">\n";
5921                 } else {
5922                         print "<tr class=\"light\">\n";
5923                 }
5924                 $alternate ^= 1;
5925                 if (defined $tag{'age'}) {
5926                         print "<td><i>$tag{'age'}</i></td>\n";
5927                 } else {
5928                         print "<td></td>\n";
5929                 }
5930                 print "<td>" .
5931                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5932                                -class => "list name"}, esc_html($tag{'name'})) .
5933                       "</td>\n" .
5934                       "<td>";
5935                 if (defined $comment) {
5936                         print format_subject_html($comment, $comment_short,
5937                                                   href(action=>"tag", hash=>$tag{'id'}));
5938                 }
5939                 print "</td>\n" .
5940                       "<td class=\"selflink\">";
5941                 if ($tag{'type'} eq "tag") {
5942                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5943                 } else {
5944                         print "&nbsp;";
5945                 }
5946                 print "</td>\n" .
5947                       "<td class=\"link\">" . " | " .
5948                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5949                 if ($tag{'reftype'} eq "commit") {
5950                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5951                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5952                 } elsif ($tag{'reftype'} eq "blob") {
5953                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5954                 }
5955                 print "</td>\n" .
5956                       "</tr>";
5957         }
5958         if (defined $extra) {
5959                 print "<tr>\n" .
5960                       "<td colspan=\"5\">$extra</td>\n" .
5961                       "</tr>\n";
5962         }
5963         print "</table>\n";
5964 }
5965
5966 sub git_heads_body {
5967         # uses global variable $project
5968         my ($headlist, $head_at, $from, $to, $extra) = @_;
5969         $from = 0 unless defined $from;
5970         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5971
5972         print "<table class=\"heads\">\n";
5973         my $alternate = 1;
5974         for (my $i = $from; $i <= $to; $i++) {
5975                 my $entry = $headlist->[$i];
5976                 my %ref = %$entry;
5977                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
5978                 if ($alternate) {
5979                         print "<tr class=\"dark\">\n";
5980                 } else {
5981                         print "<tr class=\"light\">\n";
5982                 }
5983                 $alternate ^= 1;
5984                 print "<td><i>$ref{'age'}</i></td>\n" .
5985                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5986                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5987                                -class => "list name"},esc_html($ref{'name'})) .
5988                       "</td>\n" .
5989                       "<td class=\"link\">" .
5990                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5991                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5992                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5993                       "</td>\n" .
5994                       "</tr>";
5995         }
5996         if (defined $extra) {
5997                 print "<tr>\n" .
5998                       "<td colspan=\"3\">$extra</td>\n" .
5999                       "</tr>\n";
6000         }
6001         print "</table>\n";
6002 }
6003
6004 # Display a single remote block
6005 sub git_remote_block {
6006         my ($remote, $rdata, $limit, $head) = @_;
6007
6008         my $heads = $rdata->{'heads'};
6009         my $fetch = $rdata->{'fetch'};
6010         my $push = $rdata->{'push'};
6011
6012         my $urls_table = "<table class=\"projects_list\">\n" ;
6013
6014         if (defined $fetch) {
6015                 if ($fetch eq $push) {
6016                         $urls_table .= format_repo_url("URL", $fetch);
6017                 } else {
6018                         $urls_table .= format_repo_url("Fetch URL", $fetch);
6019                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
6020                 }
6021         } elsif (defined $push) {
6022                 $urls_table .= format_repo_url("Push URL", $push);
6023         } else {
6024                 $urls_table .= format_repo_url("", "No remote URL");
6025         }
6026
6027         $urls_table .= "</table>\n";
6028
6029         my $dots;
6030         if (defined $limit && $limit < @$heads) {
6031                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
6032         }
6033
6034         print $urls_table;
6035         git_heads_body($heads, $head, 0, $limit, $dots);
6036 }
6037
6038 # Display a list of remote names with the respective fetch and push URLs
6039 sub git_remotes_list {
6040         my ($remotedata, $limit) = @_;
6041         print "<table class=\"heads\">\n";
6042         my $alternate = 1;
6043         my @remotes = sort keys %$remotedata;
6044
6045         my $limited = $limit && $limit < @remotes;
6046
6047         $#remotes = $limit - 1 if $limited;
6048
6049         while (my $remote = shift @remotes) {
6050                 my $rdata = $remotedata->{$remote};
6051                 my $fetch = $rdata->{'fetch'};
6052                 my $push = $rdata->{'push'};
6053                 if ($alternate) {
6054                         print "<tr class=\"dark\">\n";
6055                 } else {
6056                         print "<tr class=\"light\">\n";
6057                 }
6058                 $alternate ^= 1;
6059                 print "<td>" .
6060                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
6061                                -class=> "list name"},esc_html($remote)) .
6062                       "</td>";
6063                 print "<td class=\"link\">" .
6064                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
6065                       " | " .
6066                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
6067                       "</td>";
6068
6069                 print "</tr>\n";
6070         }
6071
6072         if ($limited) {
6073                 print "<tr>\n" .
6074                       "<td colspan=\"3\">" .
6075                       $cgi->a({-href => href(action=>"remotes")}, "...") .
6076                       "</td>\n" . "</tr>\n";
6077         }
6078
6079         print "</table>";
6080 }
6081
6082 # Display remote heads grouped by remote, unless there are too many
6083 # remotes, in which case we only display the remote names
6084 sub git_remotes_body {
6085         my ($remotedata, $limit, $head) = @_;
6086         if ($limit and $limit < keys %$remotedata) {
6087                 git_remotes_list($remotedata, $limit);
6088         } else {
6089                 fill_remote_heads($remotedata);
6090                 while (my ($remote, $rdata) = each %$remotedata) {
6091                         git_print_section({-class=>"remote", -id=>$remote},
6092                                 ["remotes", $remote, $remote], sub {
6093                                         git_remote_block($remote, $rdata, $limit, $head);
6094                                 });
6095                 }
6096         }
6097 }
6098
6099 sub git_search_message {
6100         my %co = @_;
6101
6102         my $greptype;
6103         if ($searchtype eq 'commit') {
6104                 $greptype = "--grep=";
6105         } elsif ($searchtype eq 'author') {
6106                 $greptype = "--author=";
6107         } elsif ($searchtype eq 'committer') {
6108                 $greptype = "--committer=";
6109         }
6110         $greptype .= $searchtext;
6111         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6112                                        $greptype, '--regexp-ignore-case',
6113                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6114
6115         my $paging_nav = '';
6116         if ($page > 0) {
6117                 $paging_nav .=
6118                         $cgi->a({-href => href(-replay=>1, page=>undef)},
6119                                 "first") .
6120                         " &sdot; " .
6121                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
6122                                  -accesskey => "p", -title => "Alt-p"}, "prev");
6123         } else {
6124                 $paging_nav .= "first &sdot; prev";
6125         }
6126         my $next_link = '';
6127         if ($#commitlist >= 100) {
6128                 $next_link =
6129                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6130                                  -accesskey => "n", -title => "Alt-n"}, "next");
6131                 $paging_nav .= " &sdot; $next_link";
6132         } else {
6133                 $paging_nav .= " &sdot; next";
6134         }
6135
6136         git_header_html();
6137
6138         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6139         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6140         if ($page == 0 && !@commitlist) {
6141                 print "<p>No match.</p>\n";
6142         } else {
6143                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6144         }
6145
6146         git_footer_html();
6147 }
6148
6149 sub git_search_changes {
6150         my %co = @_;
6151
6152         local $/ = "\n";
6153         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6154                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6155                 ($search_use_regexp ? '--pickaxe-regex' : ())
6156                         or die_error(500, "Open git-log failed");
6157
6158         git_header_html();
6159
6160         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6161         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6162
6163         print "<table class=\"pickaxe search\">\n";
6164         my $alternate = 1;
6165         undef %co;
6166         my @files;
6167         while (my $line = <$fd>) {
6168                 chomp $line;
6169                 next unless $line;
6170
6171                 my %set = parse_difftree_raw_line($line);
6172                 if (defined $set{'commit'}) {
6173                         # finish previous commit
6174                         if (%co) {
6175                                 print "</td>\n" .
6176                                       "<td class=\"link\">" .
6177                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6178                                               "commit") .
6179                                       " | " .
6180                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6181                                                              hash_base=>$co{'id'})},
6182                                               "tree") .
6183                                       "</td>\n" .
6184                                       "</tr>\n";
6185                         }
6186
6187                         if ($alternate) {
6188                                 print "<tr class=\"dark\">\n";
6189                         } else {
6190                                 print "<tr class=\"light\">\n";
6191                         }
6192                         $alternate ^= 1;
6193                         %co = parse_commit($set{'commit'});
6194                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6195                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6196                               "<td><i>$author</i></td>\n" .
6197                               "<td>" .
6198                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6199                                       -class => "list subject"},
6200                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6201                 } elsif (defined $set{'to_id'}) {
6202                         next if ($set{'to_id'} =~ m/^0{40}$/);
6203
6204                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6205                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6206                                       -class => "list"},
6207                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6208                               "<br/>\n";
6209                 }
6210         }
6211         close $fd;
6212
6213         # finish last commit (warning: repetition!)
6214         if (%co) {
6215                 print "</td>\n" .
6216                       "<td class=\"link\">" .
6217                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6218                               "commit") .
6219                       " | " .
6220                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6221                                              hash_base=>$co{'id'})},
6222                               "tree") .
6223                       "</td>\n" .
6224                       "</tr>\n";
6225         }
6226
6227         print "</table>\n";
6228
6229         git_footer_html();
6230 }
6231
6232 sub git_search_files {
6233         my %co = @_;
6234
6235         local $/ = "\n";
6236         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6237                 $search_use_regexp ? ('-E', '-i') : '-F',
6238                 $searchtext, $co{'tree'}
6239                         or die_error(500, "Open git-grep failed");
6240
6241         git_header_html();
6242
6243         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6244         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6245
6246         print "<table class=\"grep_search\">\n";
6247         my $alternate = 1;
6248         my $matches = 0;
6249         my $lastfile = '';
6250         my $file_href;
6251         while (my $line = <$fd>) {
6252                 chomp $line;
6253                 my ($file, $lno, $ltext, $binary);
6254                 last if ($matches++ > 1000);
6255                 if ($line =~ /^Binary file (.+) matches$/) {
6256                         $file = $1;
6257                         $binary = 1;
6258                 } else {
6259                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6260                         $file =~ s/^$co{'tree'}://;
6261                 }
6262                 if ($file ne $lastfile) {
6263                         $lastfile and print "</td></tr>\n";
6264                         if ($alternate++) {
6265                                 print "<tr class=\"dark\">\n";
6266                         } else {
6267                                 print "<tr class=\"light\">\n";
6268                         }
6269                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6270                                           file_name=>$file);
6271                         print "<td class=\"list\">".
6272                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6273                         print "</td><td>\n";
6274                         $lastfile = $file;
6275                 }
6276                 if ($binary) {
6277                         print "<div class=\"binary\">Binary file</div>\n";
6278                 } else {
6279                         $ltext = untabify($ltext);
6280                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6281                                 $ltext = esc_html($1, -nbsp=>1);
6282                                 $ltext .= '<span class="match">';
6283                                 $ltext .= esc_html($2, -nbsp=>1);
6284                                 $ltext .= '</span>';
6285                                 $ltext .= esc_html($3, -nbsp=>1);
6286                         } else {
6287                                 $ltext = esc_html($ltext, -nbsp=>1);
6288                         }
6289                         print "<div class=\"pre\">" .
6290                                 $cgi->a({-href => $file_href.'#l'.$lno,
6291                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6292                                 ' ' .  $ltext . "</div>\n";
6293                 }
6294         }
6295         if ($lastfile) {
6296                 print "</td></tr>\n";
6297                 if ($matches > 1000) {
6298                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6299                 }
6300         } else {
6301                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6302         }
6303         close $fd;
6304
6305         print "</table>\n";
6306
6307         git_footer_html();
6308 }
6309
6310 sub git_search_grep_body {
6311         my ($commitlist, $from, $to, $extra) = @_;
6312         $from = 0 unless defined $from;
6313         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6314
6315         print "<table class=\"commit_search\">\n";
6316         my $alternate = 1;
6317         for (my $i = $from; $i <= $to; $i++) {
6318                 my %co = %{$commitlist->[$i]};
6319                 if (!%co) {
6320                         next;
6321                 }
6322                 my $commit = $co{'id'};
6323                 if ($alternate) {
6324                         print "<tr class=\"dark\">\n";
6325                 } else {
6326                         print "<tr class=\"light\">\n";
6327                 }
6328                 $alternate ^= 1;
6329                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6330                       format_author_html('td', \%co, 15, 5) .
6331                       "<td>" .
6332                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6333                                -class => "list subject"},
6334                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6335                 my $comment = $co{'comment'};
6336                 foreach my $line (@$comment) {
6337                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6338                                 my ($lead, $match, $trail) = ($1, $2, $3);
6339                                 $match = chop_str($match, 70, 5, 'center');
6340                                 my $contextlen = int((80 - length($match))/2);
6341                                 $contextlen = 30 if ($contextlen > 30);
6342                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6343                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6344
6345                                 $lead  = esc_html($lead);
6346                                 $match = esc_html($match);
6347                                 $trail = esc_html($trail);
6348
6349                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6350                         }
6351                 }
6352                 print "</td>\n" .
6353                       "<td class=\"link\">" .
6354                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6355                       " | " .
6356                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6357                       " | " .
6358                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6359                 print "</td>\n" .
6360                       "</tr>\n";
6361         }
6362         if (defined $extra) {
6363                 print "<tr>\n" .
6364                       "<td colspan=\"3\">$extra</td>\n" .
6365                       "</tr>\n";
6366         }
6367         print "</table>\n";
6368 }
6369
6370 ## ======================================================================
6371 ## ======================================================================
6372 ## actions
6373
6374 sub git_project_list {
6375         my $order = $input_params{'order'};
6376         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6377                 die_error(400, "Unknown order parameter");
6378         }
6379
6380         my @list = git_get_projects_list($project_filter, $strict_export);
6381         if (!@list) {
6382                 die_error(404, "No projects found");
6383         }
6384
6385         git_header_html();
6386         if (defined $home_text && -f $home_text) {
6387                 print "<div class=\"index_include\">\n";
6388                 insert_file($home_text);
6389                 print "</div>\n";
6390         }
6391
6392         git_project_search_form($searchtext, $search_use_regexp);
6393         git_project_list_body(\@list, $order);
6394         git_footer_html();
6395 }
6396
6397 sub git_forks {
6398         my $order = $input_params{'order'};
6399         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6400                 die_error(400, "Unknown order parameter");
6401         }
6402
6403         my $filter = $project;
6404         $filter =~ s/\.git$//;
6405         my @list = git_get_projects_list($filter);
6406         if (!@list) {
6407                 die_error(404, "No forks found");
6408         }
6409
6410         git_header_html();
6411         git_print_page_nav('','');
6412         git_print_header_div('summary', "$project forks");
6413         git_project_list_body(\@list, $order);
6414         git_footer_html();
6415 }
6416
6417 sub git_project_index {
6418         my @projects = git_get_projects_list($project_filter, $strict_export);
6419         if (!@projects) {
6420                 die_error(404, "No projects found");
6421         }
6422
6423         print $cgi->header(
6424                 -type => 'text/plain',
6425                 -charset => 'utf-8',
6426                 -content_disposition => 'inline; filename="index.aux"');
6427
6428         foreach my $pr (@projects) {
6429                 if (!exists $pr->{'owner'}) {
6430                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6431                 }
6432
6433                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6434                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6435                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6436                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6437                 $path  =~ s/ /\+/g;
6438                 $owner =~ s/ /\+/g;
6439
6440                 print "$path $owner\n";
6441         }
6442 }
6443
6444 sub git_summary {
6445         my $descr = git_get_project_description($project) || "none";
6446         my %co = parse_commit("HEAD");
6447         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6448         my $head = $co{'id'};
6449         my $remote_heads = gitweb_check_feature('remote_heads');
6450
6451         my $owner = git_get_project_owner($project);
6452
6453         my $refs = git_get_references();
6454         # These get_*_list functions return one more to allow us to see if
6455         # there are more ...
6456         my @taglist  = git_get_tags_list(16);
6457         my @headlist = git_get_heads_list(16);
6458         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6459         my @forklist;
6460         my $check_forks = gitweb_check_feature('forks');
6461
6462         if ($check_forks) {
6463                 # find forks of a project
6464                 my $filter = $project;
6465                 $filter =~ s/\.git$//;
6466                 @forklist = git_get_projects_list($filter);
6467                 # filter out forks of forks
6468                 @forklist = filter_forks_from_projects_list(\@forklist)
6469                         if (@forklist);
6470         }
6471
6472         git_header_html();
6473         git_print_page_nav('summary','', $head);
6474
6475         print "<div class=\"title\">&nbsp;</div>\n";
6476         print "<table class=\"projects_list\">\n" .
6477               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n";
6478         unless ($omit_owner) {
6479                 print  "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6480         }
6481         if (defined $cd{'rfc2822'}) {
6482                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6483                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6484         }
6485
6486         # use per project git URL list in $projectroot/$project/cloneurl
6487         # or make project git URL from git base URL and project name
6488         my $url_tag = "URL";
6489         my @url_list = git_get_project_url_list($project);
6490         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6491         foreach my $git_url (@url_list) {
6492                 next unless $git_url;
6493                 print format_repo_url($url_tag, $git_url);
6494                 $url_tag = "";
6495         }
6496
6497         # Tag cloud
6498         my $show_ctags = gitweb_check_feature('ctags');
6499         if ($show_ctags) {
6500                 my $ctags = git_get_project_ctags($project);
6501                 if (%$ctags) {
6502                         # without ability to add tags, don't show if there are none
6503                         my $cloud = git_populate_project_tagcloud($ctags);
6504                         print "<tr id=\"metadata_ctags\">" .
6505                               "<td>content tags</td>" .
6506                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6507                               "</tr>\n";
6508                 }
6509         }
6510
6511         print "</table>\n";
6512
6513         # If XSS prevention is on, we don't include README.html.
6514         # TODO: Allow a readme in some safe format.
6515         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6516                 print "<div class=\"title\">readme</div>\n" .
6517                       "<div class=\"readme\">\n";
6518                 insert_file("$projectroot/$project/README.html");
6519                 print "\n</div>\n"; # class="readme"
6520         }
6521
6522         # we need to request one more than 16 (0..15) to check if
6523         # those 16 are all
6524         my @commitlist = $head ? parse_commits($head, 17) : ();
6525         if (@commitlist) {
6526                 git_print_header_div('shortlog');
6527                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6528                                   $#commitlist <=  15 ? undef :
6529                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6530         }
6531
6532         if (@taglist) {
6533                 git_print_header_div('tags');
6534                 git_tags_body(\@taglist, 0, 15,
6535                               $#taglist <=  15 ? undef :
6536                               $cgi->a({-href => href(action=>"tags")}, "..."));
6537         }
6538
6539         if (@headlist) {
6540                 git_print_header_div('heads');
6541                 git_heads_body(\@headlist, $head, 0, 15,
6542                                $#headlist <= 15 ? undef :
6543                                $cgi->a({-href => href(action=>"heads")}, "..."));
6544         }
6545
6546         if (%remotedata) {
6547                 git_print_header_div('remotes');
6548                 git_remotes_body(\%remotedata, 15, $head);
6549         }
6550
6551         if (@forklist) {
6552                 git_print_header_div('forks');
6553                 git_project_list_body(\@forklist, 'age', 0, 15,
6554                                       $#forklist <= 15 ? undef :
6555                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6556                                       'no_header');
6557         }
6558
6559         git_footer_html();
6560 }
6561
6562 sub git_tag {
6563         my %tag = parse_tag($hash);
6564
6565         if (! %tag) {
6566                 die_error(404, "Unknown tag object");
6567         }
6568
6569         my $head = git_get_head_hash($project);
6570         git_header_html();
6571         git_print_page_nav('','', $head,undef,$head);
6572         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6573         print "<div class=\"title_text\">\n" .
6574               "<table class=\"object_header\">\n" .
6575               "<tr>\n" .
6576               "<td>object</td>\n" .
6577               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6578                                $tag{'object'}) . "</td>\n" .
6579               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6580                                               $tag{'type'}) . "</td>\n" .
6581               "</tr>\n";
6582         if (defined($tag{'author'})) {
6583                 git_print_authorship_rows(\%tag, 'author');
6584         }
6585         print "</table>\n\n" .
6586               "</div>\n";
6587         print "<div class=\"page_body\">";
6588         my $comment = $tag{'comment'};
6589         foreach my $line (@$comment) {
6590                 chomp $line;
6591                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6592         }
6593         print "</div>\n";
6594         git_footer_html();
6595 }
6596
6597 sub git_blame_common {
6598         my $format = shift || 'porcelain';
6599         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6600                 $format = 'incremental';
6601                 $action = 'blame_incremental'; # for page title etc
6602         }
6603
6604         # permissions
6605         gitweb_check_feature('blame')
6606                 or die_error(403, "Blame view not allowed");
6607
6608         # error checking
6609         die_error(400, "No file name given") unless $file_name;
6610         $hash_base ||= git_get_head_hash($project);
6611         die_error(404, "Couldn't find base commit") unless $hash_base;
6612         my %co = parse_commit($hash_base)
6613                 or die_error(404, "Commit not found");
6614         my $ftype = "blob";
6615         if (!defined $hash) {
6616                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6617                         or die_error(404, "Error looking up file");
6618         } else {
6619                 $ftype = git_get_type($hash);
6620                 if ($ftype !~ "blob") {
6621                         die_error(400, "Object is not a blob");
6622                 }
6623         }
6624
6625         my $fd;
6626         if ($format eq 'incremental') {
6627                 # get file contents (as base)
6628                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6629                         or die_error(500, "Open git-cat-file failed");
6630         } elsif ($format eq 'data') {
6631                 # run git-blame --incremental
6632                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6633                         $hash_base, "--", $file_name
6634                         or die_error(500, "Open git-blame --incremental failed");
6635         } else {
6636                 # run git-blame --porcelain
6637                 open $fd, "-|", git_cmd(), "blame", '-p',
6638                         $hash_base, '--', $file_name
6639                         or die_error(500, "Open git-blame --porcelain failed");
6640         }
6641
6642         # incremental blame data returns early
6643         if ($format eq 'data') {
6644                 print $cgi->header(
6645                         -type=>"text/plain", -charset => "utf-8",
6646                         -status=> "200 OK");
6647                 local $| = 1; # output autoflush
6648                 while (my $line = <$fd>) {
6649                         print to_utf8($line);
6650                 }
6651                 close $fd
6652                         or print "ERROR $!\n";
6653
6654                 print 'END';
6655                 if (defined $t0 && gitweb_check_feature('timed')) {
6656                         print ' '.
6657                               tv_interval($t0, [ gettimeofday() ]).
6658                               ' '.$number_of_git_cmds;
6659                 }
6660                 print "\n";
6661
6662                 return;
6663         }
6664
6665         # page header
6666         git_header_html();
6667         my $formats_nav =
6668                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6669                         "blob") .
6670                 " | ";
6671         if ($format eq 'incremental') {
6672                 $formats_nav .=
6673                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6674                                 "blame") . " (non-incremental)";
6675         } else {
6676                 $formats_nav .=
6677                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6678                                 "blame") . " (incremental)";
6679         }
6680         $formats_nav .=
6681                 " | " .
6682                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6683                         "history") .
6684                 " | " .
6685                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6686                         "HEAD");
6687         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6688         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6689         git_print_page_path($file_name, $ftype, $hash_base);
6690
6691         # page body
6692         if ($format eq 'incremental') {
6693                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6694                       "This page requires JavaScript to run.\n Use ".
6695                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6696                               'this page').
6697                       " instead.\n".
6698                       "</b></center></div>\n</noscript>\n";
6699
6700                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6701         }
6702
6703         print qq!<div class="page_body">\n!;
6704         print qq!<div id="progress_info">... / ...</div>\n!
6705                 if ($format eq 'incremental');
6706         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6707               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6708               qq!<thead>\n!.
6709               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6710               qq!</thead>\n!.
6711               qq!<tbody>\n!;
6712
6713         my @rev_color = qw(light dark);
6714         my $num_colors = scalar(@rev_color);
6715         my $current_color = 0;
6716
6717         if ($format eq 'incremental') {
6718                 my $color_class = $rev_color[$current_color];
6719
6720                 #contents of a file
6721                 my $linenr = 0;
6722         LINE:
6723                 while (my $line = <$fd>) {
6724                         chomp $line;
6725                         $linenr++;
6726
6727                         print qq!<tr id="l$linenr" class="$color_class">!.
6728                               qq!<td class="sha1"><a href=""> </a></td>!.
6729                               qq!<td class="linenr">!.
6730                               qq!<a class="linenr" href="">$linenr</a></td>!;
6731                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6732                         print qq!</tr>\n!;
6733                 }
6734
6735         } else { # porcelain, i.e. ordinary blame
6736                 my %metainfo = (); # saves information about commits
6737
6738                 # blame data
6739         LINE:
6740                 while (my $line = <$fd>) {
6741                         chomp $line;
6742                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6743                         # no <lines in group> for subsequent lines in group of lines
6744                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6745                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6746                         if (!exists $metainfo{$full_rev}) {
6747                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6748                         }
6749                         my $meta = $metainfo{$full_rev};
6750                         my $data;
6751                         while ($data = <$fd>) {
6752                                 chomp $data;
6753                                 last if ($data =~ s/^\t//); # contents of line
6754                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6755                                         $meta->{$1} = $2 unless exists $meta->{$1};
6756                                 }
6757                                 if ($data =~ /^previous /) {
6758                                         $meta->{'nprevious'}++;
6759                                 }
6760                         }
6761                         my $short_rev = substr($full_rev, 0, 8);
6762                         my $author = $meta->{'author'};
6763                         my %date =
6764                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6765                         my $date = $date{'iso-tz'};
6766                         if ($group_size) {
6767                                 $current_color = ($current_color + 1) % $num_colors;
6768                         }
6769                         my $tr_class = $rev_color[$current_color];
6770                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6771                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6772                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6773                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6774                         if ($group_size) {
6775                                 print "<td class=\"sha1\"";
6776                                 print " title=\"". esc_html($author) . ", $date\"";
6777                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6778                                 print ">";
6779                                 print $cgi->a({-href => href(action=>"commit",
6780                                                              hash=>$full_rev,
6781                                                              file_name=>$file_name)},
6782                                               esc_html($short_rev));
6783                                 if ($group_size >= 2) {
6784                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6785                                         if (@author_initials) {
6786                                                 print "<br />" .
6787                                                       esc_html(join('', @author_initials));
6788                                                 #           or join('.', ...)
6789                                         }
6790                                 }
6791                                 print "</td>\n";
6792                         }
6793                         # 'previous' <sha1 of parent commit> <filename at commit>
6794                         if (exists $meta->{'previous'} &&
6795                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6796                                 $meta->{'parent'} = $1;
6797                                 $meta->{'file_parent'} = unquote($2);
6798                         }
6799                         my $linenr_commit =
6800                                 exists($meta->{'parent'}) ?
6801                                 $meta->{'parent'} : $full_rev;
6802                         my $linenr_filename =
6803                                 exists($meta->{'file_parent'}) ?
6804                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6805                         my $blamed = href(action => 'blame',
6806                                           file_name => $linenr_filename,
6807                                           hash_base => $linenr_commit);
6808                         print "<td class=\"linenr\">";
6809                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6810                                         -class => "linenr" },
6811                                       esc_html($lineno));
6812                         print "</td>";
6813                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6814                         print "</tr>\n";
6815                 } # end while
6816
6817         }
6818
6819         # footer
6820         print "</tbody>\n".
6821               "</table>\n"; # class="blame"
6822         print "</div>\n";   # class="blame_body"
6823         close $fd
6824                 or print "Reading blob failed\n";
6825
6826         git_footer_html();
6827 }
6828
6829 sub git_blame {
6830         git_blame_common();
6831 }
6832
6833 sub git_blame_incremental {
6834         git_blame_common('incremental');
6835 }
6836
6837 sub git_blame_data {
6838         git_blame_common('data');
6839 }
6840
6841 sub git_tags {
6842         my $head = git_get_head_hash($project);
6843         git_header_html();
6844         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6845         git_print_header_div('summary', $project);
6846
6847         my @tagslist = git_get_tags_list();
6848         if (@tagslist) {
6849                 git_tags_body(\@tagslist);
6850         }
6851         git_footer_html();
6852 }
6853
6854 sub git_heads {
6855         my $head = git_get_head_hash($project);
6856         git_header_html();
6857         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6858         git_print_header_div('summary', $project);
6859
6860         my @headslist = git_get_heads_list();
6861         if (@headslist) {
6862                 git_heads_body(\@headslist, $head);
6863         }
6864         git_footer_html();
6865 }
6866
6867 # used both for single remote view and for list of all the remotes
6868 sub git_remotes {
6869         gitweb_check_feature('remote_heads')
6870                 or die_error(403, "Remote heads view is disabled");
6871
6872         my $head = git_get_head_hash($project);
6873         my $remote = $input_params{'hash'};
6874
6875         my $remotedata = git_get_remotes_list($remote);
6876         die_error(500, "Unable to get remote information") unless defined $remotedata;
6877
6878         unless (%$remotedata) {
6879                 die_error(404, defined $remote ?
6880                         "Remote $remote not found" :
6881                         "No remotes found");
6882         }
6883
6884         git_header_html(undef, undef, -action_extra => $remote);
6885         git_print_page_nav('', '',  $head, undef, $head,
6886                 format_ref_views($remote ? '' : 'remotes'));
6887
6888         fill_remote_heads($remotedata);
6889         if (defined $remote) {
6890                 git_print_header_div('remotes', "$remote remote for $project");
6891                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6892         } else {
6893                 git_print_header_div('summary', "$project remotes");
6894                 git_remotes_body($remotedata, undef, $head);
6895         }
6896
6897         git_footer_html();
6898 }
6899
6900 sub git_blob_plain {
6901         my $type = shift;
6902         my $expires;
6903
6904         if (!defined $hash) {
6905                 if (defined $file_name) {
6906                         my $base = $hash_base || git_get_head_hash($project);
6907                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6908                                 or die_error(404, "Cannot find file");
6909                 } else {
6910                         die_error(400, "No file name defined");
6911                 }
6912         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6913                 # blobs defined by non-textual hash id's can be cached
6914                 $expires = "+1d";
6915         }
6916
6917         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6918                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6919
6920         # content-type (can include charset)
6921         $type = blob_contenttype($fd, $file_name, $type);
6922
6923         # "save as" filename, even when no $file_name is given
6924         my $save_as = "$hash";
6925         if (defined $file_name) {
6926                 $save_as = $file_name;
6927         } elsif ($type =~ m/^text\//) {
6928                 $save_as .= '.txt';
6929         }
6930
6931         # With XSS prevention on, blobs of all types except a few known safe
6932         # ones are served with "Content-Disposition: attachment" to make sure
6933         # they don't run in our security domain.  For certain image types,
6934         # blob view writes an <img> tag referring to blob_plain view, and we
6935         # want to be sure not to break that by serving the image as an
6936         # attachment (though Firefox 3 doesn't seem to care).
6937         my $sandbox = $prevent_xss &&
6938                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6939
6940         # serve text/* as text/plain
6941         if ($prevent_xss &&
6942             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6943              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6944                 my $rest = $1;
6945                 $rest = defined $rest ? $rest : '';
6946                 $type = "text/plain$rest";
6947         }
6948
6949         print $cgi->header(
6950                 -type => $type,
6951                 -expires => $expires,
6952                 -content_disposition =>
6953                         ($sandbox ? 'attachment' : 'inline')
6954                         . '; filename="' . $save_as . '"');
6955         local $/ = undef;
6956         binmode STDOUT, ':raw';
6957         print <$fd>;
6958         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6959         close $fd;
6960 }
6961
6962 sub git_blob {
6963         my $expires;
6964
6965         if (!defined $hash) {
6966                 if (defined $file_name) {
6967                         my $base = $hash_base || git_get_head_hash($project);
6968                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6969                                 or die_error(404, "Cannot find file");
6970                 } else {
6971                         die_error(400, "No file name defined");
6972                 }
6973         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6974                 # blobs defined by non-textual hash id's can be cached
6975                 $expires = "+1d";
6976         }
6977
6978         my $have_blame = gitweb_check_feature('blame');
6979         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6980                 or die_error(500, "Couldn't cat $file_name, $hash");
6981         my $mimetype = blob_mimetype($fd, $file_name);
6982         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6983         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6984                 close $fd;
6985                 return git_blob_plain($mimetype);
6986         }
6987         # we can have blame only for text/* mimetype
6988         $have_blame &&= ($mimetype =~ m!^text/!);
6989
6990         my $highlight_js = gitweb_check_feature('syntaxhighlighter_js');
6991         if ($highlight_js) {
6992                 push @stylesheets, $highlight_js->{url} . '/styles/shCore'
6993                         . $highlight_js->{style} . '.css';
6994                 push @stylesheets, $highlight_js->{url} . '/styles/shTheme'
6995                         . $highlight_js->{theme} . '.css';
6996         }
6997
6998         my $highlight = gitweb_check_feature('highlight');
6999         if ($highlight_js && $highlight) {
7000                 die_error(500, 'The highlight and syntaxhighlighter_js are'
7001                         . 'mutually exclusive');
7002         }
7003         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
7004         $fd = run_highlighter($fd, $highlight, $syntax)
7005                 if $syntax;
7006
7007         git_header_html(undef, $expires);
7008         my $formats_nav = '';
7009         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7010                 if (defined $file_name) {
7011                         if ($have_blame) {
7012                                 $formats_nav .=
7013                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
7014                                                 "blame") .
7015                                         " | ";
7016                         }
7017                         $formats_nav .=
7018                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7019                                         "history") .
7020                                 " | " .
7021                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7022                                         "raw") .
7023                                 " | " .
7024                                 $cgi->a({-href => href(action=>"blob",
7025                                                        hash_base=>"HEAD", file_name=>$file_name)},
7026                                         "HEAD");
7027                 } else {
7028                         $formats_nav .=
7029                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7030                                         "raw");
7031                 }
7032                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7033                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7034         } else {
7035                 print "<div class=\"page_nav\">\n" .
7036                       "<br/><br/></div>\n" .
7037                       "<div class=\"title\">".esc_html($hash)."</div>\n";
7038         }
7039         git_print_page_path($file_name, "blob", $hash_base);
7040         print "<div class=\"page_body\">\n";
7041         if ($mimetype =~ m!^image/!) {
7042                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
7043                 if ($file_name) {
7044                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
7045                 }
7046                 print qq! src="! .
7047                       href(action=>"blob_plain", hash=>$hash,
7048                            hash_base=>$hash_base, file_name=>$file_name) .
7049                       qq!" />\n!;
7050         } elsif ($highlight_js) {
7051                 my $ext = $file_name;
7052                 $ext =~ s/.*\.//;
7053                 print qq!<pre class="brush:!.$ext.qq!">!;
7054                 while (my $line = <$fd>) {
7055                         $line =~ s!&!\&#38;!g;
7056                         $line =~ s!<!\&#60;!g;
7057                         print $line;
7058                 }
7059                 print qq!</pre>!;
7060                 foreach my $name ('Core', 'Autoloader') {
7061                         print qq!<script src="!.$highlight_js->{url}
7062                                 .qq!/scripts/sh!.$name
7063                                 .qq!.js" type="text/javascript"></script>!;
7064                 }
7065                 print qq!<script type="text/javascript">!;
7066                 print qq!SyntaxHighlighter.defaults["pad-line-numbers"] = 3;!;
7067                 print qq!SyntaxHighlighter.defaults["toolbar"] = false;!;
7068                 # for XHTML compliance
7069                 print qq!SyntaxHighlighter.config["space"] = '&#160;';!;
7070                 print qq!SyntaxHighlighter.autoloader(!;
7071                 my $brush_prefix = $highlight_js->{url} . '/scripts/shBrush';
7072                 foreach my $language ('applescript AppleScript',
7073                                 'actionscript3 as3 AS3',
7074                                 'bash shell Bash',
7075                                 'clj Clojure',
7076                                 'coldfusion cf ColdFusion',
7077                                 'cpp c Cpp',
7078                                 'c# c-sharp csharp CSharp',
7079                                 'css Css',
7080                                 'delphi pascal Delphi',
7081                                 'diff patch pas Diff',
7082                                 'erl erlang Erlang',
7083                                 'groovy Groovy',
7084                                 'java Java',
7085                                 'jfx javafx JavaFX',
7086                                 'js jscript javascript JScript',
7087                                 'perl pl Perl',
7088                                 'php Php',
7089                                 'text plain Plain',
7090                                 'py python Python',
7091                                 'ruby rails ror rb Ruby',
7092                                 'scala Scala',
7093                                 'scm Scheme',
7094                                 'sql Sql',
7095                                 'vb vbnet Vb',
7096                                 'xml xhtml xslt html Xml') {
7097                         my $lang = $language;
7098                         $lang =~ s! (\S+)$! $brush_prefix$1!;
7099                         print "'".$lang.qq!.js',!;
7100                 }
7101                 print qq!''); SyntaxHighlighter.all();</script>!;
7102         } else {
7103                 my $nr;
7104                 while (my $line = <$fd>) {
7105                         chomp $line;
7106                         $nr++;
7107                         $line = untabify($line);
7108                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
7109                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
7110                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
7111                 }
7112         }
7113         close $fd
7114                 or print "Reading blob failed.\n";
7115         print "</div>";
7116         git_footer_html();
7117 }
7118
7119 sub git_tree {
7120         if (!defined $hash_base) {
7121                 $hash_base = "HEAD";
7122         }
7123         if (!defined $hash) {
7124                 if (defined $file_name) {
7125                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
7126                 } else {
7127                         $hash = $hash_base;
7128                 }
7129         }
7130         die_error(404, "No such tree") unless defined($hash);
7131
7132         my $show_sizes = gitweb_check_feature('show-sizes');
7133         my $have_blame = gitweb_check_feature('blame');
7134
7135         my @entries = ();
7136         {
7137                 local $/ = "\0";
7138                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
7139                         ($show_sizes ? '-l' : ()), @extra_options, $hash
7140                         or die_error(500, "Open git-ls-tree failed");
7141                 @entries = map { chomp; $_ } <$fd>;
7142                 close $fd
7143                         or die_error(404, "Reading tree failed");
7144         }
7145
7146         my $refs = git_get_references();
7147         my $ref = format_ref_marker($refs, $hash_base);
7148         git_header_html();
7149         my $basedir = '';
7150         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7151                 my @views_nav = ();
7152                 if (defined $file_name) {
7153                         push @views_nav,
7154                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7155                                         "history"),
7156                                 $cgi->a({-href => href(action=>"tree",
7157                                                        hash_base=>"HEAD", file_name=>$file_name)},
7158                                         "HEAD"),
7159                 }
7160                 my $snapshot_links = format_snapshot_links($hash);
7161                 if (defined $snapshot_links) {
7162                         # FIXME: Should be available when we have no hash base as well.
7163                         push @views_nav, $snapshot_links;
7164                 }
7165                 git_print_page_nav('tree','', $hash_base, undef, undef,
7166                                    join(' | ', @views_nav));
7167                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
7168         } else {
7169                 undef $hash_base;
7170                 print "<div class=\"page_nav\">\n";
7171                 print "<br/><br/></div>\n";
7172                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
7173         }
7174         if (defined $file_name) {
7175                 $basedir = $file_name;
7176                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
7177                         $basedir .= '/';
7178                 }
7179                 git_print_page_path($file_name, 'tree', $hash_base);
7180         }
7181         print "<div class=\"page_body\">\n";
7182         print "<table class=\"tree\">\n";
7183         my $alternate = 1;
7184         # '..' (top directory) link if possible
7185         if (defined $hash_base &&
7186             defined $file_name && $file_name =~ m![^/]+$!) {
7187                 if ($alternate) {
7188                         print "<tr class=\"dark\">\n";
7189                 } else {
7190                         print "<tr class=\"light\">\n";
7191                 }
7192                 $alternate ^= 1;
7193
7194                 my $up = $file_name;
7195                 $up =~ s!/?[^/]+$!!;
7196                 undef $up unless $up;
7197                 # based on git_print_tree_entry
7198                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
7199                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
7200                 print '<td class="list">';
7201                 print $cgi->a({-href => href(action=>"tree",
7202                                              hash_base=>$hash_base,
7203                                              file_name=>$up)},
7204                               "..");
7205                 print "</td>\n";
7206                 print "<td class=\"link\"></td>\n";
7207
7208                 print "</tr>\n";
7209         }
7210         foreach my $line (@entries) {
7211                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
7212
7213                 if ($alternate) {
7214                         print "<tr class=\"dark\">\n";
7215                 } else {
7216                         print "<tr class=\"light\">\n";
7217                 }
7218                 $alternate ^= 1;
7219
7220                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7221
7222                 print "</tr>\n";
7223         }
7224         print "</table>\n" .
7225               "</div>";
7226         git_footer_html();
7227 }
7228
7229 sub snapshot_name {
7230         my ($project, $hash) = @_;
7231
7232         # path/to/project.git  -> project
7233         # path/to/project/.git -> project
7234         my $name = to_utf8($project);
7235         $name =~ s,([^/])/*\.git$,$1,;
7236         $name = basename($name);
7237         # sanitize name
7238         $name =~ s/[[:cntrl:]]/?/g;
7239
7240         my $ver = $hash;
7241         if ($hash =~ /^[0-9a-fA-F]+$/) {
7242                 # shorten SHA-1 hash
7243                 my $full_hash = git_get_full_hash($project, $hash);
7244                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7245                         $ver = git_get_short_hash($project, $hash);
7246                 }
7247         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7248                 # tags don't need shortened SHA-1 hash
7249                 $ver = $1;
7250         } else {
7251                 # branches and other need shortened SHA-1 hash
7252                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
7253                         $ver = $1;
7254                 }
7255                 $ver .= '-' . git_get_short_hash($project, $hash);
7256         }
7257         # in case of hierarchical branch names
7258         $ver =~ s!/!.!g;
7259
7260         # name = project-version_string
7261         $name = "$name-$ver";
7262
7263         return wantarray ? ($name, $name) : $name;
7264 }
7265
7266 sub exit_if_unmodified_since {
7267         my ($latest_epoch) = @_;
7268         our $cgi;
7269
7270         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7271         if (defined $if_modified) {
7272                 my $since;
7273                 if (eval { require HTTP::Date; 1; }) {
7274                         $since = HTTP::Date::str2time($if_modified);
7275                 } elsif (eval { require Time::ParseDate; 1; }) {
7276                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7277                 }
7278                 if (defined $since && $latest_epoch <= $since) {
7279                         my %latest_date = parse_date($latest_epoch);
7280                         print $cgi->header(
7281                                 -last_modified => $latest_date{'rfc2822'},
7282                                 -status => '304 Not Modified');
7283                         goto DONE_GITWEB;
7284                 }
7285         }
7286 }
7287
7288 sub git_snapshot {
7289         my $format = $input_params{'snapshot_format'};
7290         if (!@snapshot_fmts) {
7291                 die_error(403, "Snapshots not allowed");
7292         }
7293         # default to first supported snapshot format
7294         $format ||= $snapshot_fmts[0];
7295         if ($format !~ m/^[a-z0-9]+$/) {
7296                 die_error(400, "Invalid snapshot format parameter");
7297         } elsif (!exists($known_snapshot_formats{$format})) {
7298                 die_error(400, "Unknown snapshot format");
7299         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7300                 die_error(403, "Snapshot format not allowed");
7301         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7302                 die_error(403, "Unsupported snapshot format");
7303         }
7304
7305         my $type = git_get_type("$hash^{}");
7306         if (!$type) {
7307                 die_error(404, 'Object does not exist');
7308         }  elsif ($type eq 'blob') {
7309                 die_error(400, 'Object is not a tree-ish');
7310         }
7311
7312         my ($name, $prefix) = snapshot_name($project, $hash);
7313         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7314
7315         my %co = parse_commit($hash);
7316         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7317
7318         my $cmd = quote_command(
7319                 git_cmd(), 'archive',
7320                 "--format=$known_snapshot_formats{$format}{'format'}",
7321                 "--prefix=$prefix/", $hash);
7322         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7323                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7324         }
7325
7326         $filename =~ s/(["\\])/\\$1/g;
7327         my %latest_date;
7328         if (%co) {
7329                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7330         }
7331
7332         print $cgi->header(
7333                 -type => $known_snapshot_formats{$format}{'type'},
7334                 -content_disposition => 'inline; filename="' . $filename . '"',
7335                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7336                 -status => '200 OK');
7337
7338         open my $fd, "-|", $cmd
7339                 or die_error(500, "Execute git-archive failed");
7340         binmode STDOUT, ':raw';
7341         print <$fd>;
7342         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7343         close $fd;
7344 }
7345
7346 sub git_log_generic {
7347         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7348
7349         my $head = git_get_head_hash($project);
7350         if (!defined $base) {
7351                 $base = $head;
7352         }
7353         if (!defined $page) {
7354                 $page = 0;
7355         }
7356         my $refs = git_get_references();
7357
7358         my $commit_hash = $base;
7359         if (defined $parent) {
7360                 $commit_hash = "$parent..$base";
7361         }
7362         my @commitlist =
7363                 parse_commits($commit_hash, 101, (100 * $page),
7364                               defined $file_name ? ($file_name, "--full-history") : ());
7365
7366         my $ftype;
7367         if (!defined $file_hash && defined $file_name) {
7368                 # some commits could have deleted file in question,
7369                 # and not have it in tree, but one of them has to have it
7370                 for (my $i = 0; $i < @commitlist; $i++) {
7371                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7372                         last if defined $file_hash;
7373                 }
7374         }
7375         if (defined $file_hash) {
7376                 $ftype = git_get_type($file_hash);
7377         }
7378         if (defined $file_name && !defined $ftype) {
7379                 die_error(500, "Unknown type of object");
7380         }
7381         my %co;
7382         if (defined $file_name) {
7383                 %co = parse_commit($base)
7384                         or die_error(404, "Unknown commit object");
7385         }
7386
7387
7388         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7389         my $next_link = '';
7390         if ($#commitlist >= 100) {
7391                 $next_link =
7392                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7393                                  -accesskey => "n", -title => "Alt-n"}, "next");
7394         }
7395         my $patch_max = gitweb_get_feature('patches');
7396         if ($patch_max && !defined $file_name) {
7397                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7398                         $paging_nav .= " &sdot; " .
7399                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7400                                         "patches");
7401                 }
7402         }
7403
7404         git_header_html();
7405         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7406         if (defined $file_name) {
7407                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7408         } else {
7409                 git_print_header_div('summary', $project)
7410         }
7411         git_print_page_path($file_name, $ftype, $hash_base)
7412                 if (defined $file_name);
7413
7414         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7415                      $file_name, $file_hash, $ftype);
7416
7417         git_footer_html();
7418 }
7419
7420 sub git_log {
7421         git_log_generic('log', \&git_log_body,
7422                         $hash, $hash_parent);
7423 }
7424
7425 sub git_commit {
7426         $hash ||= $hash_base || "HEAD";
7427         my %co = parse_commit($hash)
7428             or die_error(404, "Unknown commit object");
7429
7430         my $parent  = $co{'parent'};
7431         my $parents = $co{'parents'}; # listref
7432
7433         # we need to prepare $formats_nav before any parameter munging
7434         my $formats_nav;
7435         if (!defined $parent) {
7436                 # --root commitdiff
7437                 $formats_nav .= '(initial)';
7438         } elsif (@$parents == 1) {
7439                 # single parent commit
7440                 $formats_nav .=
7441                         '(parent: ' .
7442                         $cgi->a({-href => href(action=>"commit",
7443                                                hash=>$parent)},
7444                                 esc_html(substr($parent, 0, 7))) .
7445                         ')';
7446         } else {
7447                 # merge commit
7448                 $formats_nav .=
7449                         '(merge: ' .
7450                         join(' ', map {
7451                                 $cgi->a({-href => href(action=>"commit",
7452                                                        hash=>$_)},
7453                                         esc_html(substr($_, 0, 7)));
7454                         } @$parents ) .
7455                         ')';
7456         }
7457         if (gitweb_check_feature('patches') && @$parents <= 1) {
7458                 $formats_nav .= " | " .
7459                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7460                                 "patch");
7461         }
7462
7463         if (!defined $parent) {
7464                 $parent = "--root";
7465         }
7466         my @difftree;
7467         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7468                 @diff_opts,
7469                 (@$parents <= 1 ? $parent : '-c'),
7470                 $hash, "--"
7471                 or die_error(500, "Open git-diff-tree failed");
7472         @difftree = map { chomp; $_ } <$fd>;
7473         close $fd or die_error(404, "Reading git-diff-tree failed");
7474
7475         # non-textual hash id's can be cached
7476         my $expires;
7477         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7478                 $expires = "+1d";
7479         }
7480         my $refs = git_get_references();
7481         my $ref = format_ref_marker($refs, $co{'id'});
7482
7483         git_header_html(undef, $expires);
7484         git_print_page_nav('commit', '',
7485                            $hash, $co{'tree'}, $hash,
7486                            $formats_nav);
7487
7488         if (defined $co{'parent'}) {
7489                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7490         } else {
7491                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7492         }
7493         print "<div class=\"title_text\">\n" .
7494               "<table class=\"object_header\">\n";
7495         git_print_authorship_rows(\%co);
7496         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7497         print "<tr>" .
7498               "<td>tree</td>" .
7499               "<td class=\"sha1\">" .
7500               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7501                        class => "list"}, $co{'tree'}) .
7502               "</td>" .
7503               "<td class=\"link\">" .
7504               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7505                       "tree");
7506         my $snapshot_links = format_snapshot_links($hash);
7507         if (defined $snapshot_links) {
7508                 print " | " . $snapshot_links;
7509         }
7510         print "</td>" .
7511               "</tr>\n";
7512
7513         foreach my $par (@$parents) {
7514                 print "<tr>" .
7515                       "<td>parent</td>" .
7516                       "<td class=\"sha1\">" .
7517                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7518                                class => "list"}, $par) .
7519                       "</td>" .
7520                       "<td class=\"link\">" .
7521                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7522                       " | " .
7523                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7524                       "</td>" .
7525                       "</tr>\n";
7526         }
7527         print "</table>".
7528               "</div>\n";
7529
7530         print "<div class=\"page_body\">\n";
7531         git_print_log($co{'comment'});
7532         print "</div>\n";
7533
7534         git_difftree_body(\@difftree, $hash, @$parents);
7535
7536         git_footer_html();
7537 }
7538
7539 sub git_object {
7540         # object is defined by:
7541         # - hash or hash_base alone
7542         # - hash_base and file_name
7543         my $type;
7544
7545         # - hash or hash_base alone
7546         if ($hash || ($hash_base && !defined $file_name)) {
7547                 my $object_id = $hash || $hash_base;
7548
7549                 open my $fd, "-|", quote_command(
7550                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7551                         or die_error(404, "Object does not exist");
7552                 $type = <$fd>;
7553                 chomp $type;
7554                 close $fd
7555                         or die_error(404, "Object does not exist");
7556
7557         # - hash_base and file_name
7558         } elsif ($hash_base && defined $file_name) {
7559                 $file_name =~ s,/+$,,;
7560
7561                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7562                         or die_error(404, "Base object does not exist");
7563
7564                 # here errors should not hapen
7565                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7566                         or die_error(500, "Open git-ls-tree failed");
7567                 my $line = <$fd>;
7568                 close $fd;
7569
7570                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7571                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7572                         die_error(404, "File or directory for given base does not exist");
7573                 }
7574                 $type = $2;
7575                 $hash = $3;
7576         } else {
7577                 die_error(400, "Not enough information to find object");
7578         }
7579
7580         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7581                                           hash=>$hash, hash_base=>$hash_base,
7582                                           file_name=>$file_name),
7583                              -status => '302 Found');
7584 }
7585
7586 sub git_blobdiff {
7587         my $format = shift || 'html';
7588         my $diff_style = $input_params{'diff_style'} || 'inline';
7589
7590         my $fd;
7591         my @difftree;
7592         my %diffinfo;
7593         my $expires;
7594
7595         # preparing $fd and %diffinfo for git_patchset_body
7596         # new style URI
7597         if (defined $hash_base && defined $hash_parent_base) {
7598                 if (defined $file_name) {
7599                         # read raw output
7600                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7601                                 $hash_parent_base, $hash_base,
7602                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7603                                 or die_error(500, "Open git-diff-tree failed");
7604                         @difftree = map { chomp; $_ } <$fd>;
7605                         close $fd
7606                                 or die_error(404, "Reading git-diff-tree failed");
7607                         @difftree
7608                                 or die_error(404, "Blob diff not found");
7609
7610                 } elsif (defined $hash &&
7611                          $hash =~ /[0-9a-fA-F]{40}/) {
7612                         # try to find filename from $hash
7613
7614                         # read filtered raw output
7615                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7616                                 $hash_parent_base, $hash_base, "--"
7617                                 or die_error(500, "Open git-diff-tree failed");
7618                         @difftree =
7619                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7620                                 # $hash == to_id
7621                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7622                                 map { chomp; $_ } <$fd>;
7623                         close $fd
7624                                 or die_error(404, "Reading git-diff-tree failed");
7625                         @difftree
7626                                 or die_error(404, "Blob diff not found");
7627
7628                 } else {
7629                         die_error(400, "Missing one of the blob diff parameters");
7630                 }
7631
7632                 if (@difftree > 1) {
7633                         die_error(400, "Ambiguous blob diff specification");
7634                 }
7635
7636                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7637                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7638                 $file_name   ||= $diffinfo{'to_file'};
7639
7640                 $hash_parent ||= $diffinfo{'from_id'};
7641                 $hash        ||= $diffinfo{'to_id'};
7642
7643                 # non-textual hash id's can be cached
7644                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7645                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7646                         $expires = '+1d';
7647                 }
7648
7649                 # open patch output
7650                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7651                         '-p', ($format eq 'html' ? "--full-index" : ()),
7652                         $hash_parent_base, $hash_base,
7653                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7654                         or die_error(500, "Open git-diff-tree failed");
7655         }
7656
7657         # old/legacy style URI -- not generated anymore since 1.4.3.
7658         if (!%diffinfo) {
7659                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7660         }
7661
7662         # header
7663         if ($format eq 'html') {
7664                 my $formats_nav =
7665                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7666                                 "raw");
7667                 $formats_nav .= diff_style_nav($diff_style);
7668                 git_header_html(undef, $expires);
7669                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7670                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7671                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7672                 } else {
7673                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7674                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7675                 }
7676                 if (defined $file_name) {
7677                         git_print_page_path($file_name, "blob", $hash_base);
7678                 } else {
7679                         print "<div class=\"page_path\"></div>\n";
7680                 }
7681
7682         } elsif ($format eq 'plain') {
7683                 print $cgi->header(
7684                         -type => 'text/plain',
7685                         -charset => 'utf-8',
7686                         -expires => $expires,
7687                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7688
7689                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7690
7691         } else {
7692                 die_error(400, "Unknown blobdiff format");
7693         }
7694
7695         # patch
7696         if ($format eq 'html') {
7697                 print "<div class=\"page_body\">\n";
7698
7699                 git_patchset_body($fd, $diff_style,
7700                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7701                 close $fd;
7702
7703                 print "</div>\n"; # class="page_body"
7704                 git_footer_html();
7705
7706         } else {
7707                 while (my $line = <$fd>) {
7708                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7709                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7710
7711                         print $line;
7712
7713                         last if $line =~ m!^\+\+\+!;
7714                 }
7715                 local $/ = undef;
7716                 print <$fd>;
7717                 close $fd;
7718         }
7719 }
7720
7721 sub git_blobdiff_plain {
7722         git_blobdiff('plain');
7723 }
7724
7725 # assumes that it is added as later part of already existing navigation,
7726 # so it returns "| foo | bar" rather than just "foo | bar"
7727 sub diff_style_nav {
7728         my ($diff_style, $is_combined) = @_;
7729         $diff_style ||= 'inline';
7730
7731         return "" if ($is_combined);
7732
7733         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7734         my %styles = @styles;
7735         @styles =
7736                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7737
7738         return join '',
7739                 map { " | ".$_ }
7740                 map {
7741                         $_ eq $diff_style ? $styles{$_} :
7742                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7743                 } @styles;
7744 }
7745
7746 sub git_commitdiff {
7747         my %params = @_;
7748         my $format = $params{-format} || 'html';
7749         my $diff_style = $input_params{'diff_style'} || 'inline';
7750
7751         my ($patch_max) = gitweb_get_feature('patches');
7752         if ($format eq 'patch') {
7753                 die_error(403, "Patch view not allowed") unless $patch_max;
7754         }
7755
7756         $hash ||= $hash_base || "HEAD";
7757         my %co = parse_commit($hash)
7758             or die_error(404, "Unknown commit object");
7759
7760         # choose format for commitdiff for merge
7761         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7762                 $hash_parent = '--cc';
7763         }
7764         # we need to prepare $formats_nav before almost any parameter munging
7765         my $formats_nav;
7766         if ($format eq 'html') {
7767                 $formats_nav =
7768                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7769                                 "raw");
7770                 if ($patch_max && @{$co{'parents'}} <= 1) {
7771                         $formats_nav .= " | " .
7772                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7773                                         "patch");
7774                 }
7775                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7776
7777                 if (defined $hash_parent &&
7778                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7779                         # commitdiff with two commits given
7780                         my $hash_parent_short = $hash_parent;
7781                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7782                                 $hash_parent_short = substr($hash_parent, 0, 7);
7783                         }
7784                         $formats_nav .=
7785                                 ' (from';
7786                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7787                                 if ($co{'parents'}[$i] eq $hash_parent) {
7788                                         $formats_nav .= ' parent ' . ($i+1);
7789                                         last;
7790                                 }
7791                         }
7792                         $formats_nav .= ': ' .
7793                                 $cgi->a({-href => href(-replay=>1,
7794                                                        hash=>$hash_parent, hash_base=>undef)},
7795                                         esc_html($hash_parent_short)) .
7796                                 ')';
7797                 } elsif (!$co{'parent'}) {
7798                         # --root commitdiff
7799                         $formats_nav .= ' (initial)';
7800                 } elsif (scalar @{$co{'parents'}} == 1) {
7801                         # single parent commit
7802                         $formats_nav .=
7803                                 ' (parent: ' .
7804                                 $cgi->a({-href => href(-replay=>1,
7805                                                        hash=>$co{'parent'}, hash_base=>undef)},
7806                                         esc_html(substr($co{'parent'}, 0, 7))) .
7807                                 ')';
7808                 } else {
7809                         # merge commit
7810                         if ($hash_parent eq '--cc') {
7811                                 $formats_nav .= ' | ' .
7812                                         $cgi->a({-href => href(-replay=>1,
7813                                                                hash=>$hash, hash_parent=>'-c')},
7814                                                 'combined');
7815                         } else { # $hash_parent eq '-c'
7816                                 $formats_nav .= ' | ' .
7817                                         $cgi->a({-href => href(-replay=>1,
7818                                                                hash=>$hash, hash_parent=>'--cc')},
7819                                                 'compact');
7820                         }
7821                         $formats_nav .=
7822                                 ' (merge: ' .
7823                                 join(' ', map {
7824                                         $cgi->a({-href => href(-replay=>1,
7825                                                                hash=>$_, hash_base=>undef)},
7826                                                 esc_html(substr($_, 0, 7)));
7827                                 } @{$co{'parents'}} ) .
7828                                 ')';
7829                 }
7830         }
7831
7832         my $hash_parent_param = $hash_parent;
7833         if (!defined $hash_parent_param) {
7834                 # --cc for multiple parents, --root for parentless
7835                 $hash_parent_param =
7836                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7837         }
7838
7839         # read commitdiff
7840         my $fd;
7841         my @difftree;
7842         if ($format eq 'html') {
7843                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7844                         "--no-commit-id", "--patch-with-raw", "--full-index",
7845                         $hash_parent_param, $hash, "--"
7846                         or die_error(500, "Open git-diff-tree failed");
7847
7848                 while (my $line = <$fd>) {
7849                         chomp $line;
7850                         # empty line ends raw part of diff-tree output
7851                         last unless $line;
7852                         push @difftree, scalar parse_difftree_raw_line($line);
7853                 }
7854
7855         } elsif ($format eq 'plain') {
7856                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7857                         '-p', $hash_parent_param, $hash, "--"
7858                         or die_error(500, "Open git-diff-tree failed");
7859         } elsif ($format eq 'patch') {
7860                 # For commit ranges, we limit the output to the number of
7861                 # patches specified in the 'patches' feature.
7862                 # For single commits, we limit the output to a single patch,
7863                 # diverging from the git-format-patch default.
7864                 my @commit_spec = ();
7865                 if ($hash_parent) {
7866                         if ($patch_max > 0) {
7867                                 push @commit_spec, "-$patch_max";
7868                         }
7869                         push @commit_spec, '-n', "$hash_parent..$hash";
7870                 } else {
7871                         if ($params{-single}) {
7872                                 push @commit_spec, '-1';
7873                         } else {
7874                                 if ($patch_max > 0) {
7875                                         push @commit_spec, "-$patch_max";
7876                                 }
7877                                 push @commit_spec, "-n";
7878                         }
7879                         push @commit_spec, '--root', $hash;
7880                 }
7881                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7882                         '--encoding=utf8', '--stdout', @commit_spec
7883                         or die_error(500, "Open git-format-patch failed");
7884         } else {
7885                 die_error(400, "Unknown commitdiff format");
7886         }
7887
7888         # non-textual hash id's can be cached
7889         my $expires;
7890         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7891                 $expires = "+1d";
7892         }
7893
7894         # write commit message
7895         if ($format eq 'html') {
7896                 my $refs = git_get_references();
7897                 my $ref = format_ref_marker($refs, $co{'id'});
7898
7899                 git_header_html(undef, $expires);
7900                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7901                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7902                 print "<div class=\"title_text\">\n" .
7903                       "<table class=\"object_header\">\n";
7904                 git_print_authorship_rows(\%co);
7905                 print "</table>".
7906                       "</div>\n";
7907                 print "<div class=\"page_body\">\n";
7908                 if (@{$co{'comment'}} > 1) {
7909                         print "<div class=\"log\">\n";
7910                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7911                         print "</div>\n"; # class="log"
7912                 }
7913
7914         } elsif ($format eq 'plain') {
7915                 my $refs = git_get_references("tags");
7916                 my $tagname = git_get_rev_name_tags($hash);
7917                 my $filename = basename($project) . "-$hash.patch";
7918
7919                 print $cgi->header(
7920                         -type => 'text/plain',
7921                         -charset => 'utf-8',
7922                         -expires => $expires,
7923                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7924                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7925                 print "From: " . to_utf8($co{'author'}) . "\n";
7926                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7927                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7928
7929                 print "X-Git-Tag: $tagname\n" if $tagname;
7930                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7931
7932                 foreach my $line (@{$co{'comment'}}) {
7933                         print to_utf8($line) . "\n";
7934                 }
7935                 print "---\n\n";
7936         } elsif ($format eq 'patch') {
7937                 my $filename = basename($project) . "-$hash.patch";
7938
7939                 print $cgi->header(
7940                         -type => 'text/plain',
7941                         -charset => 'utf-8',
7942                         -expires => $expires,
7943                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7944         }
7945
7946         # write patch
7947         if ($format eq 'html') {
7948                 my $use_parents = !defined $hash_parent ||
7949                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7950                 git_difftree_body(\@difftree, $hash,
7951                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7952                 print "<br/>\n";
7953
7954                 git_patchset_body($fd, $diff_style,
7955                                   \@difftree, $hash,
7956                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7957                 close $fd;
7958                 print "</div>\n"; # class="page_body"
7959                 git_footer_html();
7960
7961         } elsif ($format eq 'plain') {
7962                 local $/ = undef;
7963                 print <$fd>;
7964                 close $fd
7965                         or print "Reading git-diff-tree failed\n";
7966         } elsif ($format eq 'patch') {
7967                 local $/ = undef;
7968                 print <$fd>;
7969                 close $fd
7970                         or print "Reading git-format-patch failed\n";
7971         }
7972 }
7973
7974 sub git_commitdiff_plain {
7975         git_commitdiff(-format => 'plain');
7976 }
7977
7978 # format-patch-style patches
7979 sub git_patch {
7980         git_commitdiff(-format => 'patch', -single => 1);
7981 }
7982
7983 sub git_patches {
7984         git_commitdiff(-format => 'patch');
7985 }
7986
7987 sub git_history {
7988         git_log_generic('history', \&git_history_body,
7989                         $hash_base, $hash_parent_base,
7990                         $file_name, $hash);
7991 }
7992
7993 sub git_search {
7994         $searchtype ||= 'commit';
7995
7996         # check if appropriate features are enabled
7997         gitweb_check_feature('search')
7998                 or die_error(403, "Search is disabled");
7999         if ($searchtype eq 'pickaxe') {
8000                 # pickaxe may take all resources of your box and run for several minutes
8001                 # with every query - so decide by yourself how public you make this feature
8002                 gitweb_check_feature('pickaxe')
8003                         or die_error(403, "Pickaxe search is disabled");
8004         }
8005         if ($searchtype eq 'grep') {
8006                 # grep search might be potentially CPU-intensive, too
8007                 gitweb_check_feature('grep')
8008                         or die_error(403, "Grep search is disabled");
8009         }
8010
8011         if (!defined $searchtext) {
8012                 die_error(400, "Text field is empty");
8013         }
8014         if (!defined $hash) {
8015                 $hash = git_get_head_hash($project);
8016         }
8017         my %co = parse_commit($hash);
8018         if (!%co) {
8019                 die_error(404, "Unknown commit object");
8020         }
8021         if (!defined $page) {
8022                 $page = 0;
8023         }
8024
8025         if ($searchtype eq 'commit' ||
8026             $searchtype eq 'author' ||
8027             $searchtype eq 'committer') {
8028                 git_search_message(%co);
8029         } elsif ($searchtype eq 'pickaxe') {
8030                 git_search_changes(%co);
8031         } elsif ($searchtype eq 'grep') {
8032                 git_search_files(%co);
8033         } else {
8034                 die_error(400, "Unknown search type");
8035         }
8036 }
8037
8038 sub git_search_help {
8039         git_header_html();
8040         git_print_page_nav('','', $hash,$hash,$hash);
8041         print <<EOT;
8042 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
8043 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
8044 the pattern entered is recognized as the POSIX extended
8045 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
8046 insensitive).</p>
8047 <dl>
8048 <dt><b>commit</b></dt>
8049 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
8050 EOT
8051         my $have_grep = gitweb_check_feature('grep');
8052         if ($have_grep) {
8053                 print <<EOT;
8054 <dt><b>grep</b></dt>
8055 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
8056     a different one) are searched for the given pattern. On large trees, this search can take
8057 a while and put some strain on the server, so please use it with some consideration. Note that
8058 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
8059 case-sensitive.</dd>
8060 EOT
8061         }
8062         print <<EOT;
8063 <dt><b>author</b></dt>
8064 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
8065 <dt><b>committer</b></dt>
8066 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
8067 EOT
8068         my $have_pickaxe = gitweb_check_feature('pickaxe');
8069         if ($have_pickaxe) {
8070                 print <<EOT;
8071 <dt><b>pickaxe</b></dt>
8072 <dd>All commits that caused the string to appear or disappear from any file (changes that
8073 added, removed or "modified" the string) will be listed. This search can take a while and
8074 takes a lot of strain on the server, so please use it wisely. Note that since you may be
8075 interested even in changes just changing the case as well, this search is case sensitive.</dd>
8076 EOT
8077         }
8078         print "</dl>\n";
8079         git_footer_html();
8080 }
8081
8082 sub git_shortlog {
8083         git_log_generic('shortlog', \&git_shortlog_body,
8084                         $hash, $hash_parent);
8085 }
8086
8087 ## ......................................................................
8088 ## feeds (RSS, Atom; OPML)
8089
8090 sub git_feed {
8091         my $format = shift || 'atom';
8092         my $have_blame = gitweb_check_feature('blame');
8093
8094         # Atom: http://www.atomenabled.org/developers/syndication/
8095         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
8096         if ($format ne 'rss' && $format ne 'atom') {
8097                 die_error(400, "Unknown web feed format");
8098         }
8099
8100         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
8101         my $head = $hash || 'HEAD';
8102         my @commitlist = parse_commits($head, 150, 0, $file_name);
8103
8104         my %latest_commit;
8105         my %latest_date;
8106         my $content_type = "application/$format+xml";
8107         if (defined $cgi->http('HTTP_ACCEPT') &&
8108                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
8109                 # browser (feed reader) prefers text/xml
8110                 $content_type = 'text/xml';
8111         }
8112         if (defined($commitlist[0])) {
8113                 %latest_commit = %{$commitlist[0]};
8114                 my $latest_epoch = $latest_commit{'committer_epoch'};
8115                 exit_if_unmodified_since($latest_epoch);
8116                 %latest_date = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
8117         }
8118         print $cgi->header(
8119                 -type => $content_type,
8120                 -charset => 'utf-8',
8121                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
8122                 -status => '200 OK');
8123
8124         # Optimization: skip generating the body if client asks only
8125         # for Last-Modified date.
8126         return if ($cgi->request_method() eq 'HEAD');
8127
8128         # header variables
8129         my $title = "$site_name - $project/$action";
8130         my $feed_type = 'log';
8131         if (defined $hash) {
8132                 $title .= " - '$hash'";
8133                 $feed_type = 'branch log';
8134                 if (defined $file_name) {
8135                         $title .= " :: $file_name";
8136                         $feed_type = 'history';
8137                 }
8138         } elsif (defined $file_name) {
8139                 $title .= " - $file_name";
8140                 $feed_type = 'history';
8141         }
8142         $title .= " $feed_type";
8143         my $descr = git_get_project_description($project);
8144         if (defined $descr) {
8145                 $descr = esc_html($descr);
8146         } else {
8147                 $descr = "$project " .
8148                          ($format eq 'rss' ? 'RSS' : 'Atom') .
8149                          " feed";
8150         }
8151         my $owner = git_get_project_owner($project);
8152         $owner = esc_html($owner);
8153
8154         #header
8155         my $alt_url;
8156         if (defined $file_name) {
8157                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
8158         } elsif (defined $hash) {
8159                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
8160         } else {
8161                 $alt_url = href(-full=>1, action=>"summary");
8162         }
8163         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
8164         if ($format eq 'rss') {
8165                 print <<XML;
8166 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
8167 <channel>
8168 XML
8169                 print "<title>$title</title>\n" .
8170                       "<link>$alt_url</link>\n" .
8171                       "<description>$descr</description>\n" .
8172                       "<language>en</language>\n" .
8173                       # project owner is responsible for 'editorial' content
8174                       "<managingEditor>$owner</managingEditor>\n";
8175                 if (defined $logo || defined $favicon) {
8176                         # prefer the logo to the favicon, since RSS
8177                         # doesn't allow both
8178                         my $img = esc_url($logo || $favicon);
8179                         print "<image>\n" .
8180                               "<url>$img</url>\n" .
8181                               "<title>$title</title>\n" .
8182                               "<link>$alt_url</link>\n" .
8183                               "</image>\n";
8184                 }
8185                 if (%latest_date) {
8186                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
8187                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
8188                 }
8189                 print "<generator>gitweb v.$version/$git_version</generator>\n";
8190         } elsif ($format eq 'atom') {
8191                 print <<XML;
8192 <feed xmlns="http://www.w3.org/2005/Atom">
8193 XML
8194                 print "<title>$title</title>\n" .
8195                       "<subtitle>$descr</subtitle>\n" .
8196                       '<link rel="alternate" type="text/html" href="' .
8197                       $alt_url . '" />' . "\n" .
8198                       '<link rel="self" type="' . $content_type . '" href="' .
8199                       $cgi->self_url() . '" />' . "\n" .
8200                       "<id>" . href(-full=>1) . "</id>\n" .
8201                       # use project owner for feed author
8202                       "<author><name>$owner</name></author>\n";
8203                 if (defined $favicon) {
8204                         print "<icon>" . esc_url($favicon) . "</icon>\n";
8205                 }
8206                 if (defined $logo) {
8207                         # not twice as wide as tall: 72 x 27 pixels
8208                         print "<logo>" . esc_url($logo) . "</logo>\n";
8209                 }
8210                 if (! %latest_date) {
8211                         # dummy date to keep the feed valid until commits trickle in:
8212                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
8213                 } else {
8214                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
8215                 }
8216                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
8217         }
8218
8219         # contents
8220         for (my $i = 0; $i <= $#commitlist; $i++) {
8221                 my %co = %{$commitlist[$i]};
8222                 my $commit = $co{'id'};
8223                 # we read 150, we always show 30 and the ones more recent than 48 hours
8224                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
8225                         last;
8226                 }
8227                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
8228
8229                 # get list of changed files
8230                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8231                         $co{'parent'} || "--root",
8232                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8233                         or next;
8234                 my @difftree = map { chomp; $_ } <$fd>;
8235                 close $fd
8236                         or next;
8237
8238                 # print element (entry, item)
8239                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8240                 if ($format eq 'rss') {
8241                         print "<item>\n" .
8242                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8243                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8244                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8245                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8246                               "<link>$co_url</link>\n" .
8247                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8248                               "<content:encoded>" .
8249                               "<![CDATA[\n";
8250                 } elsif ($format eq 'atom') {
8251                         print "<entry>\n" .
8252                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8253                               "<updated>$cd{'iso-8601'}</updated>\n" .
8254                               "<author>\n" .
8255                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8256                         if ($co{'author_email'}) {
8257                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8258                         }
8259                         print "</author>\n" .
8260                               # use committer for contributor
8261                               "<contributor>\n" .
8262                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8263                         if ($co{'committer_email'}) {
8264                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8265                         }
8266                         print "</contributor>\n" .
8267                               "<published>$cd{'iso-8601'}</published>\n" .
8268                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
8269                               "<id>$co_url</id>\n" .
8270                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8271                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8272                 }
8273                 my $comment = $co{'comment'};
8274                 print "<pre>\n";
8275                 foreach my $line (@$comment) {
8276                         $line = esc_html($line);
8277                         print "$line\n";
8278                 }
8279                 print "</pre><ul>\n";
8280                 foreach my $difftree_line (@difftree) {
8281                         my %difftree = parse_difftree_raw_line($difftree_line);
8282                         next if !$difftree{'from_id'};
8283
8284                         my $file = $difftree{'file'} || $difftree{'to_file'};
8285
8286                         print "<li>" .
8287                               "[" .
8288                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8289                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8290                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8291                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8292                                       -title => "diff"}, 'D');
8293                         if ($have_blame) {
8294                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8295                                                              file_name=>$file, hash_base=>$commit),
8296                                               -title => "blame"}, 'B');
8297                         }
8298                         # if this is not a feed of a file history
8299                         if (!defined $file_name || $file_name ne $file) {
8300                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8301                                                              file_name=>$file, hash=>$commit),
8302                                               -title => "history"}, 'H');
8303                         }
8304                         $file = esc_path($file);
8305                         print "] ".
8306                               "$file</li>\n";
8307                 }
8308                 if ($format eq 'rss') {
8309                         print "</ul>]]>\n" .
8310                               "</content:encoded>\n" .
8311                               "</item>\n";
8312                 } elsif ($format eq 'atom') {
8313                         print "</ul>\n</div>\n" .
8314                               "</content>\n" .
8315                               "</entry>\n";
8316                 }
8317         }
8318
8319         # end of feed
8320         if ($format eq 'rss') {
8321                 print "</channel>\n</rss>\n";
8322         } elsif ($format eq 'atom') {
8323                 print "</feed>\n";
8324         }
8325 }
8326
8327 sub git_rss {
8328         git_feed('rss');
8329 }
8330
8331 sub git_atom {
8332         git_feed('atom');
8333 }
8334
8335 sub git_opml {
8336         my @list = git_get_projects_list($project_filter, $strict_export);
8337         if (!@list) {
8338                 die_error(404, "No projects found");
8339         }
8340
8341         print $cgi->header(
8342                 -type => 'text/xml',
8343                 -charset => 'utf-8',
8344                 -content_disposition => 'inline; filename="opml.xml"');
8345
8346         my $title = esc_html($site_name);
8347         my $filter = " within subdirectory ";
8348         if (defined $project_filter) {
8349                 $filter .= esc_html($project_filter);
8350         } else {
8351                 $filter = "";
8352         }
8353         print <<XML;
8354 <?xml version="1.0" encoding="utf-8"?>
8355 <opml version="1.0">
8356 <head>
8357   <title>$title OPML Export$filter</title>
8358 </head>
8359 <body>
8360 <outline text="git RSS feeds">
8361 XML
8362
8363         foreach my $pr (@list) {
8364                 my %proj = %$pr;
8365                 my $head = git_get_head_hash($proj{'path'});
8366                 if (!defined $head) {
8367                         next;
8368                 }
8369                 $git_dir = "$projectroot/$proj{'path'}";
8370                 my %co = parse_commit($head);
8371                 if (!%co) {
8372                         next;
8373                 }
8374
8375                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8376                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8377                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8378                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8379         }
8380         print <<XML;
8381 </outline>
8382 </body>
8383 </opml>
8384 XML
8385 }