git-gui/git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title "git-gui: fatal error" \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86         if {[tk windowingsystem] eq "win32"} { console show }
  87 }
  88
  89 ######################################################################
  90 ##
  91 ## Internationalization (i18n) through msgcat and gettext. See
  92 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  93
  94 package require msgcat
  95
  96 proc _mc_trim {fmt} {
  97         set cmk [string first @@ $fmt]
  98         if {$cmk > 0} {
  99                 return [string range $fmt 0 [expr {$cmk - 1}]]
 100         }
 101         return $fmt
 102 }
 103
 104 proc mc {en_fmt args} {
 105         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 106         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 107                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 108         }
 109         return $msg
 110 }
 111
 112 proc strcat {args} {
 113         return [join $args {}]
 114 }
 115
 116 ::msgcat::mcload $oguimsg
 117 unset oguimsg
 118
 119 ######################################################################
 120 ##
 121 ## read only globals
 122
 123 set _appname {Git Gui}
 124 set _gitdir {}
 125 set _gitworktree {}
 126 set _isbare {}
 127 set _gitexec {}
 128 set _githtmldir {}
 129 set _reponame {}
 130 set _iscygwin {}
 131 set _search_path {}
 132 set _shellpath {@@SHELL_PATH@@}
 133
 134 set _trace [lsearch -exact $argv --trace]
 135 if {$_trace >= 0} {
 136         set argv [lreplace $argv $_trace $_trace]
 137         set _trace 1
 138 } else {
 139         set _trace 0
 140 }
 141
 142 proc shellpath {} {
 143         global _shellpath env
 144         if {[string match @@* $_shellpath]} {
 145                 if {[info exists env(SHELL)]} {
 146                         return $env(SHELL)
 147                 } else {
 148                         return /bin/sh
 149                 }
 150         }
 151         return $_shellpath
 152 }
 153
 154 proc appname {} {
 155         global _appname
 156         return $_appname
 157 }
 158
 159 proc gitdir {args} {
 160         global _gitdir
 161         if {$args eq {}} {
 162                 return $_gitdir
 163         }
 164         return [eval [list file join $_gitdir] $args]
 165 }
 166
 167 proc gitexec {args} {
 168         global _gitexec
 169         if {$_gitexec eq {}} {
 170                 if {[catch {set _gitexec [git --exec-path]} err]} {
 171                         error "Git not installed?\n\n$err"
 172                 }
 173                 if {[is_Cygwin]} {
 174                         set _gitexec [exec cygpath \
 175                                 --windows \
 176                                 --absolute \
 177                                 $_gitexec]
 178                 } else {
 179                         set _gitexec [file normalize $_gitexec]
 180                 }
 181         }
 182         if {$args eq {}} {
 183                 return $_gitexec
 184         }
 185         return [eval [list file join $_gitexec] $args]
 186 }
 187
 188 proc githtmldir {args} {
 189         global _githtmldir
 190         if {$_githtmldir eq {}} {
 191                 if {[catch {set _githtmldir [git --html-path]}]} {
 192                         # Git not installed or option not yet supported
 193                         return {}
 194                 }
 195                 if {[is_Cygwin]} {
 196                         set _githtmldir [exec cygpath \
 197                                 --windows \
 198                                 --absolute \
 199                                 $_githtmldir]
 200                 } else {
 201                         set _githtmldir [file normalize $_githtmldir]
 202                 }
 203         }
 204         if {$args eq {}} {
 205                 return $_githtmldir
 206         }
 207         return [eval [list file join $_githtmldir] $args]
 208 }
 209
 210 proc reponame {} {
 211         return $::_reponame
 212 }
 213
 214 proc is_MacOSX {} {
 215         if {[tk windowingsystem] eq {aqua}} {
 216                 return 1
 217         }
 218         return 0
 219 }
 220
 221 proc is_Windows {} {
 222         if {$::tcl_platform(platform) eq {windows}} {
 223                 return 1
 224         }
 225         return 0
 226 }
 227
 228 proc is_Cygwin {} {
 229         global _iscygwin
 230         if {$_iscygwin eq {}} {
 231                 if {$::tcl_platform(platform) eq {windows}} {
 232                         if {[catch {set p [exec cygpath --windir]} err]} {
 233                                 set _iscygwin 0
 234                         } else {
 235                                 set _iscygwin 1
 236                         }
 237                 } else {
 238                         set _iscygwin 0
 239                 }
 240         }
 241         return $_iscygwin
 242 }
 243
 244 proc is_enabled {option} {
 245         global enabled_options
 246         if {[catch {set on $enabled_options($option)}]} {return 0}
 247         return $on
 248 }
 249
 250 proc enable_option {option} {
 251         global enabled_options
 252         set enabled_options($option) 1
 253 }
 254
 255 proc disable_option {option} {
 256         global enabled_options
 257         set enabled_options($option) 0
 258 }
 259
 260 ######################################################################
 261 ##
 262 ## config
 263
 264 proc is_many_config {name} {
 265         switch -glob -- $name {
 266         gui.recentrepo -
 267         remote.*.fetch -
 268         remote.*.push
 269                 {return 1}
 270         *
 271                 {return 0}
 272         }
 273 }
 274
 275 proc is_config_true {name} {
 276         global repo_config
 277         if {[catch {set v $repo_config($name)}]} {
 278                 return 0
 279         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 280                 return 1
 281         } else {
 282                 return 0
 283         }
 284 }
 285
 286 proc is_config_false {name} {
 287         global repo_config
 288         if {[catch {set v $repo_config($name)}]} {
 289                 return 0
 290         } elseif {$v eq {false} || $v eq {0} || $v eq {no}} {
 291                 return 1
 292         } else {
 293                 return 0
 294         }
 295 }
 296
 297 proc get_config {name} {
 298         global repo_config
 299         if {[catch {set v $repo_config($name)}]} {
 300                 return {}
 301         } else {
 302                 return $v
 303         }
 304 }
 305
 306 proc is_bare {} {
 307         global _isbare
 308         global _gitdir
 309         global _gitworktree
 310
 311         if {$_isbare eq {}} {
 312                 if {[catch {
 313                         set _bare [git rev-parse --is-bare-repository]
 314                         switch  -- $_bare {
 315                         true { set _isbare 1 }
 316                         false { set _isbare 0}
 317                         default { throw }
 318                         }
 319                 }]} {
 320                         if {[is_config_true core.bare]
 321                                 || ($_gitworktree eq {}
 322                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 323                                 set _isbare 1
 324                         } else {
 325                                 set _isbare 0
 326                         }
 327                 }
 328         }
 329         return $_isbare
 330 }
 331
 332 ######################################################################
 333 ##
 334 ## handy utils
 335
 336 proc _trace_exec {cmd} {
 337         if {!$::_trace} return
 338         set d {}
 339         foreach v $cmd {
 340                 if {$d ne {}} {
 341                         append d { }
 342                 }
 343                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 344                         set v [sq $v]
 345                 }
 346                 append d $v
 347         }
 348         puts stderr $d
 349 }
 350
 351 #'"  fix poor old emacs font-lock mode
 352
 353 proc _git_cmd {name} {
 354         global _git_cmd_path
 355
 356         if {[catch {set v $_git_cmd_path($name)}]} {
 357                 switch -- $name {
 358                   version   -
 359                 --version   -
 360                 --exec-path { return [list $::_git $name] }
 361                 }
 362
 363                 set p [gitexec git-$name$::_search_exe]
 364                 if {[file exists $p]} {
 365                         set v [list $p]
 366                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 367                         # Try to determine what sort of magic will make
 368                         # git-$name go and do its thing, because native
 369                         # Tcl on Windows doesn't know it.
 370                         #
 371                         set p [gitexec git-$name]
 372                         set f [open $p r]
 373                         set s [gets $f]
 374                         close $f
 375
 376                         switch -glob -- [lindex $s 0] {
 377                         #!*sh     { set i sh     }
 378                         #!*perl   { set i perl   }
 379                         #!*python { set i python }
 380                         default   { error "git-$name is not supported: $s" }
 381                         }
 382
 383                         upvar #0 _$i interp
 384                         if {![info exists interp]} {
 385                                 set interp [_which $i]
 386                         }
 387                         if {$interp eq {}} {
 388                                 error "git-$name requires $i (not in PATH)"
 389                         }
 390                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 391                 } else {
 392                         # Assume it is builtin to git somehow and we
 393                         # aren't actually able to see a file for it.
 394                         #
 395                         set v [list $::_git $name]
 396                 }
 397                 set _git_cmd_path($name) $v
 398         }
 399         return $v
 400 }
 401
 402 proc _which {what args} {
 403         global env _search_exe _search_path
 404
 405         if {$_search_path eq {}} {
 406                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 407                         set _search_path [split [exec cygpath \
 408                                 --windows \
 409                                 --path \
 410                                 --absolute \
 411                                 $env(PATH)] {;}]
 412                         set _search_exe .exe
 413                 } elseif {[is_Windows]} {
 414                         set gitguidir [file dirname [info script]]
 415                         regsub -all ";" $gitguidir "\\;" gitguidir
 416                         set env(PATH) "$gitguidir;$env(PATH)"
 417                         set _search_path [split $env(PATH) {;}]
 418                         set _search_exe .exe
 419                 } else {
 420                         set _search_path [split $env(PATH) :]
 421                         set _search_exe {}
 422                 }
 423         }
 424
 425         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 426                 set suffix {}
 427         } else {
 428                 set suffix $_search_exe
 429         }
 430
 431         foreach p $_search_path {
 432                 set p [file join $p $what$suffix]
 433                 if {[file exists $p]} {
 434                         return [file normalize $p]
 435                 }
 436         }
 437         return {}
 438 }
 439
 440 proc _lappend_nice {cmd_var} {
 441         global _nice
 442         upvar $cmd_var cmd
 443
 444         if {![info exists _nice]} {
 445                 set _nice [_which nice]
 446                 if {[catch {exec $_nice git version}]} {
 447                         set _nice {}
 448                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 449                         set _nice {}
 450                 }
 451         }
 452         if {$_nice ne {}} {
 453                 lappend cmd $_nice
 454         }
 455 }
 456
 457 proc git {args} {
 458         set opt [list]
 459
 460         while {1} {
 461                 switch -- [lindex $args 0] {
 462                 --nice {
 463                         _lappend_nice opt
 464                 }
 465
 466                 default {
 467                         break
 468                 }
 469
 470                 }
 471
 472                 set args [lrange $args 1 end]
 473         }
 474
 475         set cmdp [_git_cmd [lindex $args 0]]
 476         set args [lrange $args 1 end]
 477
 478         _trace_exec [concat $opt $cmdp $args]
 479         set result [eval exec $opt $cmdp $args]
 480         if {$::_trace} {
 481                 puts stderr "< $result"
 482         }
 483         return $result
 484 }
 485
 486 proc _open_stdout_stderr {cmd} {
 487         _trace_exec $cmd
 488         if {[catch {
 489                         set fd [open [concat [list | ] $cmd] r]
 490                 } err]} {
 491                 if {   [lindex $cmd end] eq {2>@1}
 492                     && $err eq {can not find channel named "1"}
 493                         } {
 494                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 495                         # redirect operator.  Fallback to |& cat for those.
 496                         # The command was not actually started, so its safe
 497                         # to try to start it a second time.
 498                         #
 499                         set fd [open [concat \
 500                                 [list | ] \
 501                                 [lrange $cmd 0 end-1] \
 502                                 [list |& cat] \
 503                                 ] r]
 504                 } else {
 505                         error $err
 506                 }
 507         }
 508         fconfigure $fd -eofchar {}
 509         return $fd
 510 }
 511
 512 proc git_read {args} {
 513         set opt [list]
 514
 515         while {1} {
 516                 switch -- [lindex $args 0] {
 517                 --nice {
 518                         _lappend_nice opt
 519                 }
 520
 521                 --stderr {
 522                         lappend args 2>@1
 523                 }
 524
 525                 default {
 526                         break
 527                 }
 528
 529                 }
 530
 531                 set args [lrange $args 1 end]
 532         }
 533
 534         set cmdp [_git_cmd [lindex $args 0]]
 535         set args [lrange $args 1 end]
 536
 537         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 538 }
 539
 540 proc git_write {args} {
 541         set opt [list]
 542
 543         while {1} {
 544                 switch -- [lindex $args 0] {
 545                 --nice {
 546                         _lappend_nice opt
 547                 }
 548
 549                 default {
 550                         break
 551                 }
 552
 553                 }
 554
 555                 set args [lrange $args 1 end]
 556         }
 557
 558         set cmdp [_git_cmd [lindex $args 0]]
 559         set args [lrange $args 1 end]
 560
 561         _trace_exec [concat $opt $cmdp $args]
 562         return [open [concat [list | ] $opt $cmdp $args] w]
 563 }
 564
 565 proc githook_read {hook_name args} {
 566         set pchook [gitdir hooks $hook_name]
 567         lappend args 2>@1
 568
 569         # On Windows [file executable] might lie so we need to ask
 570         # the shell if the hook is executable.  Yes that's annoying.
 571         #
 572         if {[is_Windows]} {
 573                 upvar #0 _sh interp
 574                 if {![info exists interp]} {
 575                         set interp [_which sh]
 576                 }
 577                 if {$interp eq {}} {
 578                         error "hook execution requires sh (not in PATH)"
 579                 }
 580
 581                 set scr {if test -x "$1";then exec "$@";fi}
 582                 set sh_c [list $interp -c $scr $interp $pchook]
 583                 return [_open_stdout_stderr [concat $sh_c $args]]
 584         }
 585
 586         if {[file executable $pchook]} {
 587                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 588         }
 589
 590         return {}
 591 }
 592
 593 proc kill_file_process {fd} {
 594         set process [pid $fd]
 595
 596         catch {
 597                 if {[is_Windows]} {
 598                         # Use a Cygwin-specific flag to allow killing
 599                         # native Windows processes
 600                         exec kill -f $process
 601                 } else {
 602                         exec kill $process
 603                 }
 604         }
 605 }
 606
 607 proc gitattr {path attr default} {
 608         if {[catch {set r [git check-attr $attr -- $path]}]} {
 609                 set r unspecified
 610         } else {
 611                 set r [join [lrange [split $r :] 2 end] :]
 612                 regsub {^ } $r {} r
 613         }
 614         if {$r eq {unspecified}} {
 615                 return $default
 616         }
 617         return $r
 618 }
 619
 620 proc sq {value} {
 621         regsub -all ' $value "'\\''" value
 622         return "'$value'"
 623 }
 624
 625 proc load_current_branch {} {
 626         global current_branch is_detached
 627
 628         set fd [open [gitdir HEAD] r]
 629         if {[gets $fd ref] < 1} {
 630                 set ref {}
 631         }
 632         close $fd
 633
 634         set pfx {ref: refs/heads/}
 635         set len [string length $pfx]
 636         if {[string equal -length $len $pfx $ref]} {
 637                 # We're on a branch.  It might not exist.  But
 638                 # HEAD looks good enough to be a branch.
 639                 #
 640                 set current_branch [string range $ref $len end]
 641                 set is_detached 0
 642         } else {
 643                 # Assume this is a detached head.
 644                 #
 645                 set current_branch HEAD
 646                 set is_detached 1
 647         }
 648 }
 649
 650 auto_load tk_optionMenu
 651 rename tk_optionMenu real__tkOptionMenu
 652 proc tk_optionMenu {w varName args} {
 653         set m [eval real__tkOptionMenu $w $varName $args]
 654         $m configure -font font_ui
 655         $w configure -font font_ui
 656         return $m
 657 }
 658
 659 proc rmsel_tag {text} {
 660         $text tag conf sel \
 661                 -background [$text cget -background] \
 662                 -foreground [$text cget -foreground] \
 663                 -borderwidth 0
 664         $text tag conf in_sel -background lightgray
 665         bind $text <Motion> break
 666         return $text
 667 }
 668
 669 wm withdraw .
 670 set root_exists 0
 671 bind . <Visibility> {
 672         bind . <Visibility> {}
 673         set root_exists 1
 674 }
 675
 676 if {[is_Windows]} {
 677         wm iconbitmap . -default $oguilib/git-gui.ico
 678         set ::tk::AlwaysShowSelection 1
 679         bind . <Control-F2> {console show}
 680
 681         # Spoof an X11 display for SSH
 682         if {![info exists env(DISPLAY)]} {
 683                 set env(DISPLAY) :9999
 684         }
 685 } else {
 686         catch {
 687                 image create photo gitlogo -width 16 -height 16
 688
 689                 gitlogo put #33CC33 -to  7  0  9  2
 690                 gitlogo put #33CC33 -to  4  2 12  4
 691                 gitlogo put #33CC33 -to  7  4  9  6
 692                 gitlogo put #CC3333 -to  4  6 12  8
 693                 gitlogo put gray26  -to  4  9  6 10
 694                 gitlogo put gray26  -to  3 10  6 12
 695                 gitlogo put gray26  -to  8  9 13 11
 696                 gitlogo put gray26  -to  8 11 10 12
 697                 gitlogo put gray26  -to 11 11 13 14
 698                 gitlogo put gray26  -to  3 12  5 14
 699                 gitlogo put gray26  -to  5 13
 700                 gitlogo put gray26  -to 10 13
 701                 gitlogo put gray26  -to  4 14 12 15
 702                 gitlogo put gray26  -to  5 15 11 16
 703                 gitlogo redither
 704
 705                 wm iconphoto . -default gitlogo
 706         }
 707 }
 708
 709 ######################################################################
 710 ##
 711 ## config defaults
 712
 713 set cursor_ptr arrow
 714 font create font_ui
 715 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 716         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 717         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 718 } else {
 719         font create font_diff -family Courier -size 10
 720         catch {
 721                 label .dummy
 722                 eval font configure font_ui [font actual [.dummy cget -font]]
 723                 destroy .dummy
 724         }
 725 }
 726
 727 font create font_uiitalic
 728 font create font_uibold
 729 font create font_diffbold
 730 font create font_diffitalic
 731
 732 foreach class {Button Checkbutton Entry Label
 733                 Labelframe Listbox Message
 734                 Radiobutton Spinbox Text} {
 735         option add *$class.font font_ui
 736 }
 737 if {![is_MacOSX]} {
 738         option add *Menu.font font_ui
 739         option add *Entry.borderWidth 1 startupFile
 740         option add *Entry.relief sunken startupFile
 741         option add *RadioButton.anchor w startupFile
 742 }
 743 unset class
 744
 745 if {[is_Windows] || [is_MacOSX]} {
 746         option add *Menu.tearOff 0
 747 }
 748
 749 if {[is_MacOSX]} {
 750         set M1B M1
 751         set M1T Cmd
 752 } else {
 753         set M1B Control
 754         set M1T Ctrl
 755 }
 756
 757 proc bind_button3 {w cmd} {
 758         bind $w <Any-Button-3> $cmd
 759         if {[is_MacOSX]} {
 760                 # Mac OS X sends Button-2 on right click through three-button mouse,
 761                 # or through trackpad right-clicking (two-finger touch + click).
 762                 bind $w <Any-Button-2> $cmd
 763                 bind $w <Control-Button-1> $cmd
 764         }
 765 }
 766
 767 proc apply_config {} {
 768         global repo_config font_descs
 769
 770         foreach option $font_descs {
 771                 set name [lindex $option 0]
 772                 set font [lindex $option 1]
 773                 if {[catch {
 774                         set need_weight 1
 775                         foreach {cn cv} $repo_config(gui.$name) {
 776                                 if {$cn eq {-weight}} {
 777                                         set need_weight 0
 778                                 }
 779                                 font configure $font $cn $cv
 780                         }
 781                         if {$need_weight} {
 782                                 font configure $font -weight normal
 783                         }
 784                         } err]} {
 785                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 786                 }
 787                 foreach {cn cv} [font configure $font] {
 788                         font configure ${font}bold $cn $cv
 789                         font configure ${font}italic $cn $cv
 790                 }
 791                 font configure ${font}bold -weight bold
 792                 font configure ${font}italic -slant italic
 793         }
 794
 795         global use_ttk NS
 796         set use_ttk 0
 797         set NS {}
 798         if {$repo_config(gui.usettk)} {
 799                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 800                 if {$use_ttk} {
 801                         set NS ttk
 802                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 803                         pave_toplevel .
 804                 }
 805         }
 806 }
 807
 808 set default_config(branch.autosetupmerge) true
 809 set default_config(merge.tool) {}
 810 set default_config(mergetool.keepbackup) true
 811 set default_config(merge.diffstat) true
 812 set default_config(merge.summary) false
 813 set default_config(merge.verbosity) 2
 814 set default_config(user.name) {}
 815 set default_config(user.email) {}
 816
 817 set default_config(gui.encoding) [encoding system]
 818 set default_config(gui.matchtrackingbranch) false
 819 set default_config(gui.textconv) true
 820 set default_config(gui.pruneduringfetch) false
 821 set default_config(gui.trustmtime) false
 822 set default_config(gui.fastcopyblame) false
 823 set default_config(gui.copyblamethreshold) 40
 824 set default_config(gui.blamehistoryctx) 7
 825 set default_config(gui.diffcontext) 5
 826 set default_config(gui.commitmsgwidth) 75
 827 set default_config(gui.newbranchtemplate) {}
 828 set default_config(gui.spellingdictionary) {}
 829 set default_config(gui.fontui) [font configure font_ui]
 830 set default_config(gui.fontdiff) [font configure font_diff]
 831 # TODO: this option should be added to the git-config documentation
 832 set default_config(gui.maxfilesdisplayed) 5000
 833 set default_config(gui.usettk) 1
 834 set font_descs {
 835         {fontui   font_ui   {mc "Main Font"}}
 836         {fontdiff font_diff {mc "Diff/Console Font"}}
 837 }
 838
 839 ######################################################################
 840 ##
 841 ## find git
 842
 843 set _git  [_which git]
 844 if {$_git eq {}} {
 845         catch {wm withdraw .}
 846         tk_messageBox \
 847                 -icon error \
 848                 -type ok \
 849                 -title [mc "git-gui: fatal error"] \
 850                 -message [mc "Cannot find git in PATH."]
 851         exit 1
 852 }
 853
 854 ######################################################################
 855 ##
 856 ## version check
 857
 858 if {[catch {set _git_version [git --version]} err]} {
 859         catch {wm withdraw .}
 860         tk_messageBox \
 861                 -icon error \
 862                 -type ok \
 863                 -title [mc "git-gui: fatal error"] \
 864                 -message "Cannot determine Git version:
 865
 866 $err
 867
 868 [appname] requires Git 1.5.0 or later."
 869         exit 1
 870 }
 871 if {![regsub {^git version } $_git_version {} _git_version]} {
 872         catch {wm withdraw .}
 873         tk_messageBox \
 874                 -icon error \
 875                 -type ok \
 876                 -title [mc "git-gui: fatal error"] \
 877                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 878         exit 1
 879 }
 880
 881 proc get_trimmed_version {s} {
 882     set r {}
 883     foreach x [split $s -._] {
 884         if {[string is integer -strict $x]} {
 885             lappend r $x
 886         } else {
 887             break
 888         }
 889     }
 890     return [join $r .]
 891 }
 892 set _real_git_version $_git_version
 893 set _git_version [get_trimmed_version $_git_version]
 894
 895 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 896         catch {wm withdraw .}
 897         if {[tk_messageBox \
 898                 -icon warning \
 899                 -type yesno \
 900                 -default no \
 901                 -title "[appname]: warning" \
 902                  -message [mc "Git version cannot be determined.
 903
 904 %s claims it is version '%s'.
 905
 906 %s requires at least Git 1.5.0 or later.
 907
 908 Assume '%s' is version 1.5.0?
 909 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 910                 set _git_version 1.5.0
 911         } else {
 912                 exit 1
 913         }
 914 }
 915 unset _real_git_version
 916
 917 proc git-version {args} {
 918         global _git_version
 919
 920         switch [llength $args] {
 921         0 {
 922                 return $_git_version
 923         }
 924
 925         2 {
 926                 set op [lindex $args 0]
 927                 set vr [lindex $args 1]
 928                 set cm [package vcompare $_git_version $vr]
 929                 return [expr $cm $op 0]
 930         }
 931
 932         4 {
 933                 set type [lindex $args 0]
 934                 set name [lindex $args 1]
 935                 set parm [lindex $args 2]
 936                 set body [lindex $args 3]
 937
 938                 if {($type ne {proc} && $type ne {method})} {
 939                         error "Invalid arguments to git-version"
 940                 }
 941                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 942                         error "Last arm of $type $name must be default"
 943                 }
 944
 945                 foreach {op vr cb} [lrange $body 0 end-2] {
 946                         if {[git-version $op $vr]} {
 947                                 return [uplevel [list $type $name $parm $cb]]
 948                         }
 949                 }
 950
 951                 return [uplevel [list $type $name $parm [lindex $body end]]]
 952         }
 953
 954         default {
 955                 error "git-version >= x"
 956         }
 957
 958         }
 959 }
 960
 961 if {[git-version < 1.5]} {
 962         catch {wm withdraw .}
 963         tk_messageBox \
 964                 -icon error \
 965                 -type ok \
 966                 -title [mc "git-gui: fatal error"] \
 967                 -message "[appname] requires Git 1.5.0 or later.
 968
 969 You are using [git-version]:
 970
 971 [git --version]"
 972         exit 1
 973 }
 974
 975 ######################################################################
 976 ##
 977 ## configure our library
 978
 979 set idx [file join $oguilib tclIndex]
 980 if {[catch {set fd [open $idx r]} err]} {
 981         catch {wm withdraw .}
 982         tk_messageBox \
 983                 -icon error \
 984                 -type ok \
 985                 -title [mc "git-gui: fatal error"] \
 986                 -message $err
 987         exit 1
 988 }
 989 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
 990         set idx [list]
 991         while {[gets $fd n] >= 0} {
 992                 if {$n ne {} && ![string match #* $n]} {
 993                         lappend idx $n
 994                 }
 995         }
 996 } else {
 997         set idx {}
 998 }
 999 close $fd
1000
1001 if {$idx ne {}} {
1002         set loaded [list]
1003         foreach p $idx {
1004                 if {[lsearch -exact $loaded $p] >= 0} continue
1005                 source [file join $oguilib $p]
1006                 lappend loaded $p
1007         }
1008         unset loaded p
1009 } else {
1010         set auto_path [concat [list $oguilib] $auto_path]
1011 }
1012 unset -nocomplain idx fd
1013
1014 ######################################################################
1015 ##
1016 ## config file parsing
1017
1018 git-version proc _parse_config {arr_name args} {
1019         >= 1.5.3 {
1020                 upvar $arr_name arr
1021                 array unset arr
1022                 set buf {}
1023                 catch {
1024                         set fd_rc [eval \
1025                                 [list git_read config] \
1026                                 $args \
1027                                 [list --null --list]]
1028                         fconfigure $fd_rc -translation binary
1029                         set buf [read $fd_rc]
1030                         close $fd_rc
1031                 }
1032                 foreach line [split $buf "\0"] {
1033                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1034                                 if {[is_many_config $name]} {
1035                                         lappend arr($name) $value
1036                                 } else {
1037                                         set arr($name) $value
1038                                 }
1039                         }
1040                 }
1041         }
1042         default {
1043                 upvar $arr_name arr
1044                 array unset arr
1045                 catch {
1046                         set fd_rc [eval [list git_read config --list] $args]
1047                         while {[gets $fd_rc line] >= 0} {
1048                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1049                                         if {[is_many_config $name]} {
1050                                                 lappend arr($name) $value
1051                                         } else {
1052                                                 set arr($name) $value
1053                                         }
1054                                 }
1055                         }
1056                         close $fd_rc
1057                 }
1058         }
1059 }
1060
1061 proc load_config {include_global} {
1062         global repo_config global_config system_config default_config
1063
1064         if {$include_global} {
1065                 _parse_config system_config --system
1066                 _parse_config global_config --global
1067         }
1068         _parse_config repo_config
1069
1070         foreach name [array names default_config] {
1071                 if {[catch {set v $system_config($name)}]} {
1072                         set system_config($name) $default_config($name)
1073                 }
1074         }
1075         foreach name [array names system_config] {
1076                 if {[catch {set v $global_config($name)}]} {
1077                         set global_config($name) $system_config($name)
1078                 }
1079                 if {[catch {set v $repo_config($name)}]} {
1080                         set repo_config($name) $system_config($name)
1081                 }
1082         }
1083 }
1084
1085 ######################################################################
1086 ##
1087 ## feature option selection
1088
1089 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1090         unset _junk
1091 } else {
1092         set subcommand gui
1093 }
1094 if {$subcommand eq {gui.sh}} {
1095         set subcommand gui
1096 }
1097 if {$subcommand eq {gui} && [llength $argv] > 0} {
1098         set subcommand [lindex $argv 0]
1099         set argv [lrange $argv 1 end]
1100 }
1101
1102 enable_option multicommit
1103 enable_option branch
1104 enable_option transport
1105 disable_option bare
1106
1107 switch -- $subcommand {
1108 browser -
1109 blame {
1110         enable_option bare
1111
1112         disable_option multicommit
1113         disable_option branch
1114         disable_option transport
1115 }
1116 citool {
1117         enable_option singlecommit
1118         enable_option retcode
1119
1120         disable_option multicommit
1121         disable_option branch
1122         disable_option transport
1123
1124         while {[llength $argv] > 0} {
1125                 set a [lindex $argv 0]
1126                 switch -- $a {
1127                 --amend {
1128                         enable_option initialamend
1129                 }
1130                 --nocommit {
1131                         enable_option nocommit
1132                         enable_option nocommitmsg
1133                 }
1134                 --commitmsg {
1135                         disable_option nocommitmsg
1136                 }
1137                 default {
1138                         break
1139                 }
1140                 }
1141
1142                 set argv [lrange $argv 1 end]
1143         }
1144 }
1145 }
1146
1147 ######################################################################
1148 ##
1149 ## execution environment
1150
1151 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1152
1153 # Suggest our implementation of askpass, if none is set
1154 if {![info exists env(SSH_ASKPASS)]} {
1155         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1156 }
1157
1158 ######################################################################
1159 ##
1160 ## repository setup
1161
1162 set picked 0
1163 if {[catch {
1164                 set _gitdir $env(GIT_DIR)
1165                 set _prefix {}
1166                 }]
1167         && [catch {
1168                 # beware that from the .git dir this sets _gitdir to .
1169                 # and _prefix to the empty string
1170                 set _gitdir [git rev-parse --git-dir]
1171                 set _prefix [git rev-parse --show-prefix]
1172         } err]} {
1173         load_config 1
1174         apply_config
1175         choose_repository::pick
1176         set picked 1
1177 }
1178
1179 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1180 # run from the .git dir itself) lest the routines to find the worktree
1181 # get confused
1182 if {$_gitdir eq "."} {
1183         set _gitdir [pwd]
1184 }
1185
1186 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1187         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1188 }
1189 if {![file isdirectory $_gitdir]} {
1190         catch {wm withdraw .}
1191         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1192         exit 1
1193 }
1194 # _gitdir exists, so try loading the config
1195 load_config 0
1196 apply_config
1197
1198 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1199 if {[package vsatisfies $_git_version 1.7.0]} {
1200         set _gitworktree [git rev-parse --show-toplevel]
1201 } else {
1202         # try to set work tree from environment, core.worktree or use
1203         # cdup to obtain a relative path to the top of the worktree. If
1204         # run from the top, the ./ prefix ensures normalize expands pwd.
1205         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1206                 set _gitworktree [get_config core.worktree]
1207                 if {$_gitworktree eq ""} {
1208                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1209                 }
1210         }
1211 }
1212
1213 if {$_prefix ne {}} {
1214         if {$_gitworktree eq {}} {
1215                 regsub -all {[^/]+/} $_prefix ../ cdup
1216         } else {
1217                 set cdup $_gitworktree
1218         }
1219         if {[catch {cd $cdup} err]} {
1220                 catch {wm withdraw .}
1221                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1222                 exit 1
1223         }
1224         set _gitworktree [pwd]
1225         unset cdup
1226 } elseif {![is_enabled bare]} {
1227         if {[is_bare]} {
1228                 catch {wm withdraw .}
1229                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1230                 exit 1
1231         }
1232         if {$_gitworktree eq {}} {
1233                 set _gitworktree [file dirname $_gitdir]
1234         }
1235         if {[catch {cd $_gitworktree} err]} {
1236                 catch {wm withdraw .}
1237                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1238                 exit 1
1239         }
1240         set _gitworktree [pwd]
1241 }
1242 set _reponame [file split [file normalize $_gitdir]]
1243 if {[lindex $_reponame end] eq {.git}} {
1244         set _reponame [lindex $_reponame end-1]
1245 } else {
1246         set _reponame [lindex $_reponame end]
1247 }
1248
1249 ######################################################################
1250 ##
1251 ## global init
1252
1253 set current_diff_path {}
1254 set current_diff_side {}
1255 set diff_actions [list]
1256
1257 set HEAD {}
1258 set PARENT {}
1259 set MERGE_HEAD [list]
1260 set commit_type {}
1261 set empty_tree {}
1262 set current_branch {}
1263 set is_detached 0
1264 set current_diff_path {}
1265 set is_3way_diff 0
1266 set is_submodule_diff 0
1267 set is_conflict_diff 0
1268 set selected_commit_type new
1269 set diff_empty_count 0
1270
1271 set nullid "0000000000000000000000000000000000000000"
1272 set nullid2 "0000000000000000000000000000000000000001"
1273
1274 ######################################################################
1275 ##
1276 ## task management
1277
1278 set rescan_active 0
1279 set diff_active 0
1280 set last_clicked {}
1281
1282 set disable_on_lock [list]
1283 set index_lock_type none
1284
1285 proc lock_index {type} {
1286         global index_lock_type disable_on_lock
1287
1288         if {$index_lock_type eq {none}} {
1289                 set index_lock_type $type
1290                 foreach w $disable_on_lock {
1291                         uplevel #0 $w disabled
1292                 }
1293                 return 1
1294         } elseif {$index_lock_type eq "begin-$type"} {
1295                 set index_lock_type $type
1296                 return 1
1297         }
1298         return 0
1299 }
1300
1301 proc unlock_index {} {
1302         global index_lock_type disable_on_lock
1303
1304         set index_lock_type none
1305         foreach w $disable_on_lock {
1306                 uplevel #0 $w normal
1307         }
1308 }
1309
1310 ######################################################################
1311 ##
1312 ## status
1313
1314 proc repository_state {ctvar hdvar mhvar} {
1315         global current_branch
1316         upvar $ctvar ct $hdvar hd $mhvar mh
1317
1318         set mh [list]
1319
1320         load_current_branch
1321         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1322                 set hd {}
1323                 set ct initial
1324                 return
1325         }
1326
1327         set merge_head [gitdir MERGE_HEAD]
1328         if {[file exists $merge_head]} {
1329                 set ct merge
1330                 set fd_mh [open $merge_head r]
1331                 while {[gets $fd_mh line] >= 0} {
1332                         lappend mh $line
1333                 }
1334                 close $fd_mh
1335                 return
1336         }
1337
1338         set ct normal
1339 }
1340
1341 proc PARENT {} {
1342         global PARENT empty_tree
1343
1344         set p [lindex $PARENT 0]
1345         if {$p ne {}} {
1346                 return $p
1347         }
1348         if {$empty_tree eq {}} {
1349                 set empty_tree [git mktree << {}]
1350         }
1351         return $empty_tree
1352 }
1353
1354 proc force_amend {} {
1355         global selected_commit_type
1356         global HEAD PARENT MERGE_HEAD commit_type
1357
1358         repository_state newType newHEAD newMERGE_HEAD
1359         set HEAD $newHEAD
1360         set PARENT $newHEAD
1361         set MERGE_HEAD $newMERGE_HEAD
1362         set commit_type $newType
1363
1364         set selected_commit_type amend
1365         do_select_commit_type
1366 }
1367
1368 proc rescan {after {honor_trustmtime 1}} {
1369         global HEAD PARENT MERGE_HEAD commit_type
1370         global ui_index ui_workdir ui_comm
1371         global rescan_active file_states
1372         global repo_config
1373
1374         if {$rescan_active > 0 || ![lock_index read]} return
1375
1376         repository_state newType newHEAD newMERGE_HEAD
1377         if {[string match amend* $commit_type]
1378                 && $newType eq {normal}
1379                 && $newHEAD eq $HEAD} {
1380         } else {
1381                 set HEAD $newHEAD
1382                 set PARENT $newHEAD
1383                 set MERGE_HEAD $newMERGE_HEAD
1384                 set commit_type $newType
1385         }
1386
1387         array unset file_states
1388
1389         if {!$::GITGUI_BCK_exists &&
1390                 (![$ui_comm edit modified]
1391                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1392                 if {[string match amend* $commit_type]} {
1393                 } elseif {[load_message GITGUI_MSG]} {
1394                 } elseif {[run_prepare_commit_msg_hook]} {
1395                 } elseif {[load_message MERGE_MSG]} {
1396                 } elseif {[load_message SQUASH_MSG]} {
1397                 }
1398                 $ui_comm edit reset
1399                 $ui_comm edit modified false
1400         }
1401
1402         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1403                 rescan_stage2 {} $after
1404         } else {
1405                 set rescan_active 1
1406                 ui_status [mc "Refreshing file status..."]
1407                 set fd_rf [git_read update-index \
1408                         -q \
1409                         --unmerged \
1410                         --ignore-missing \
1411                         --refresh \
1412                         ]
1413                 fconfigure $fd_rf -blocking 0 -translation binary
1414                 fileevent $fd_rf readable \
1415                         [list rescan_stage2 $fd_rf $after]
1416         }
1417 }
1418
1419 if {[is_Cygwin]} {
1420         set is_git_info_exclude {}
1421         proc have_info_exclude {} {
1422                 global is_git_info_exclude
1423
1424                 if {$is_git_info_exclude eq {}} {
1425                         if {[catch {exec test -f [gitdir info exclude]}]} {
1426                                 set is_git_info_exclude 0
1427                         } else {
1428                                 set is_git_info_exclude 1
1429                         }
1430                 }
1431                 return $is_git_info_exclude
1432         }
1433 } else {
1434         proc have_info_exclude {} {
1435                 return [file readable [gitdir info exclude]]
1436         }
1437 }
1438
1439 proc rescan_stage2 {fd after} {
1440         global rescan_active buf_rdi buf_rdf buf_rlo
1441
1442         if {$fd ne {}} {
1443                 read $fd
1444                 if {![eof $fd]} return
1445                 close $fd
1446         }
1447
1448         set ls_others [list --exclude-per-directory=.gitignore]
1449         if {[have_info_exclude]} {
1450                 lappend ls_others "--exclude-from=[gitdir info exclude]"
1451         }
1452         set user_exclude [get_config core.excludesfile]
1453         if {$user_exclude ne {} && [file readable $user_exclude]} {
1454                 lappend ls_others "--exclude-from=$user_exclude"
1455         }
1456
1457         set buf_rdi {}
1458         set buf_rdf {}
1459         set buf_rlo {}
1460
1461         set rescan_active 3
1462         ui_status [mc "Scanning for modified files ..."]
1463         set fd_di [git_read diff-index --cached -z [PARENT]]
1464         set fd_df [git_read diff-files -z]
1465         set fd_lo [eval git_read ls-files --others -z $ls_others]
1466
1467         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1468         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1469         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1470         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1471         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1472         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1473 }
1474
1475 proc load_message {file} {
1476         global ui_comm
1477
1478         set f [gitdir $file]
1479         if {[file isfile $f]} {
1480                 if {[catch {set fd [open $f r]}]} {
1481                         return 0
1482                 }
1483                 fconfigure $fd -eofchar {}
1484                 set content [string trim [read $fd]]
1485                 close $fd
1486                 regsub -all -line {[ \r\t]+$} $content {} content
1487                 $ui_comm delete 0.0 end
1488                 $ui_comm insert end $content
1489                 return 1
1490         }
1491         return 0
1492 }
1493
1494 proc run_prepare_commit_msg_hook {} {
1495         global pch_error
1496
1497         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1498         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1499         # empty file but existant file.
1500
1501         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1502
1503         if {[file isfile [gitdir MERGE_MSG]]} {
1504                 set pcm_source "merge"
1505                 set fd_mm [open [gitdir MERGE_MSG] r]
1506                 puts -nonewline $fd_pcm [read $fd_mm]
1507                 close $fd_mm
1508         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1509                 set pcm_source "squash"
1510                 set fd_sm [open [gitdir SQUASH_MSG] r]
1511                 puts -nonewline $fd_pcm [read $fd_sm]
1512                 close $fd_sm
1513         } else {
1514                 set pcm_source ""
1515         }
1516
1517         close $fd_pcm
1518
1519         set fd_ph [githook_read prepare-commit-msg \
1520                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1521         if {$fd_ph eq {}} {
1522                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1523                 return 0;
1524         }
1525
1526         ui_status [mc "Calling prepare-commit-msg hook..."]
1527         set pch_error {}
1528
1529         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1530         fileevent $fd_ph readable \
1531                 [list prepare_commit_msg_hook_wait $fd_ph]
1532
1533         return 1;
1534 }
1535
1536 proc prepare_commit_msg_hook_wait {fd_ph} {
1537         global pch_error
1538
1539         append pch_error [read $fd_ph]
1540         fconfigure $fd_ph -blocking 1
1541         if {[eof $fd_ph]} {
1542                 if {[catch {close $fd_ph}]} {
1543                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1544                         hook_failed_popup prepare-commit-msg $pch_error
1545                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1546                         exit 1
1547                 } else {
1548                         load_message PREPARE_COMMIT_MSG
1549                 }
1550                 set pch_error {}
1551                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1552                 return
1553         }
1554         fconfigure $fd_ph -blocking 0
1555         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1556 }
1557
1558 proc read_diff_index {fd after} {
1559         global buf_rdi
1560
1561         append buf_rdi [read $fd]
1562         set c 0
1563         set n [string length $buf_rdi]
1564         while {$c < $n} {
1565                 set z1 [string first "\0" $buf_rdi $c]
1566                 if {$z1 == -1} break
1567                 incr z1
1568                 set z2 [string first "\0" $buf_rdi $z1]
1569                 if {$z2 == -1} break
1570
1571                 incr c
1572                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1573                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1574                 merge_state \
1575                         [encoding convertfrom $p] \
1576                         [lindex $i 4]? \
1577                         [list [lindex $i 0] [lindex $i 2]] \
1578                         [list]
1579                 set c $z2
1580                 incr c
1581         }
1582         if {$c < $n} {
1583                 set buf_rdi [string range $buf_rdi $c end]
1584         } else {
1585                 set buf_rdi {}
1586         }
1587
1588         rescan_done $fd buf_rdi $after
1589 }
1590
1591 proc read_diff_files {fd after} {
1592         global buf_rdf
1593
1594         append buf_rdf [read $fd]
1595         set c 0
1596         set n [string length $buf_rdf]
1597         while {$c < $n} {
1598                 set z1 [string first "\0" $buf_rdf $c]
1599                 if {$z1 == -1} break
1600                 incr z1
1601                 set z2 [string first "\0" $buf_rdf $z1]
1602                 if {$z2 == -1} break
1603
1604                 incr c
1605                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1606                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1607                 merge_state \
1608                         [encoding convertfrom $p] \
1609                         ?[lindex $i 4] \
1610                         [list] \
1611                         [list [lindex $i 0] [lindex $i 2]]
1612                 set c $z2
1613                 incr c
1614         }
1615         if {$c < $n} {
1616                 set buf_rdf [string range $buf_rdf $c end]
1617         } else {
1618                 set buf_rdf {}
1619         }
1620
1621         rescan_done $fd buf_rdf $after
1622 }
1623
1624 proc read_ls_others {fd after} {
1625         global buf_rlo
1626
1627         append buf_rlo [read $fd]
1628         set pck [split $buf_rlo "\0"]
1629         set buf_rlo [lindex $pck end]
1630         foreach p [lrange $pck 0 end-1] {
1631                 set p [encoding convertfrom $p]
1632                 if {[string index $p end] eq {/}} {
1633                         set p [string range $p 0 end-1]
1634                 }
1635                 merge_state $p ?O
1636         }
1637         rescan_done $fd buf_rlo $after
1638 }
1639
1640 proc rescan_done {fd buf after} {
1641         global rescan_active current_diff_path
1642         global file_states repo_config
1643         upvar $buf to_clear
1644
1645         if {![eof $fd]} return
1646         set to_clear {}
1647         close $fd
1648         if {[incr rescan_active -1] > 0} return
1649
1650         prune_selection
1651         unlock_index
1652         display_all_files
1653         if {$current_diff_path ne {}} { reshow_diff $after }
1654         if {$current_diff_path eq {}} { select_first_diff $after }
1655 }
1656
1657 proc prune_selection {} {
1658         global file_states selected_paths
1659
1660         foreach path [array names selected_paths] {
1661                 if {[catch {set still_here $file_states($path)}]} {
1662                         unset selected_paths($path)
1663                 }
1664         }
1665 }
1666
1667 ######################################################################
1668 ##
1669 ## ui helpers
1670
1671 proc mapicon {w state path} {
1672         global all_icons
1673
1674         if {[catch {set r $all_icons($state$w)}]} {
1675                 puts "error: no icon for $w state={$state} $path"
1676                 return file_plain
1677         }
1678         return $r
1679 }
1680
1681 proc mapdesc {state path} {
1682         global all_descs
1683
1684         if {[catch {set r $all_descs($state)}]} {
1685                 puts "error: no desc for state={$state} $path"
1686                 return $state
1687         }
1688         return $r
1689 }
1690
1691 proc ui_status {msg} {
1692         global main_status
1693         if {[info exists main_status]} {
1694                 $main_status show $msg
1695         }
1696 }
1697
1698 proc ui_ready {{test {}}} {
1699         global main_status
1700         if {[info exists main_status]} {
1701                 $main_status show [mc "Ready."] $test
1702         }
1703 }
1704
1705 proc escape_path {path} {
1706         regsub -all {\\} $path "\\\\" path
1707         regsub -all "\n" $path "\\n" path
1708         return $path
1709 }
1710
1711 proc short_path {path} {
1712         return [escape_path [lindex [file split $path] end]]
1713 }
1714
1715 set next_icon_id 0
1716 set null_sha1 [string repeat 0 40]
1717
1718 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1719         global file_states next_icon_id null_sha1
1720
1721         set s0 [string index $new_state 0]
1722         set s1 [string index $new_state 1]
1723
1724         if {[catch {set info $file_states($path)}]} {
1725                 set state __
1726                 set icon n[incr next_icon_id]
1727         } else {
1728                 set state [lindex $info 0]
1729                 set icon [lindex $info 1]
1730                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1731                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1732         }
1733
1734         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1735         elseif {$s0 eq {_}} {set s0 _}
1736
1737         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1738         elseif {$s1 eq {_}} {set s1 _}
1739
1740         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1741                 set head_info [list 0 $null_sha1]
1742         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1743                 && $head_info eq {}} {
1744                 set head_info $index_info
1745         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1746                 set index_info $head_info
1747                 set head_info {}
1748         }
1749
1750         set file_states($path) [list $s0$s1 $icon \
1751                 $head_info $index_info \
1752                 ]
1753         return $state
1754 }
1755
1756 proc display_file_helper {w path icon_name old_m new_m} {
1757         global file_lists
1758
1759         if {$new_m eq {_}} {
1760                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1761                 if {$lno >= 0} {
1762                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1763                         incr lno
1764                         $w conf -state normal
1765                         $w delete $lno.0 [expr {$lno + 1}].0
1766                         $w conf -state disabled
1767                 }
1768         } elseif {$old_m eq {_} && $new_m ne {_}} {
1769                 lappend file_lists($w) $path
1770                 set file_lists($w) [lsort -unique $file_lists($w)]
1771                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1772                 incr lno
1773                 $w conf -state normal
1774                 $w image create $lno.0 \
1775                         -align center -padx 5 -pady 1 \
1776                         -name $icon_name \
1777                         -image [mapicon $w $new_m $path]
1778                 $w insert $lno.1 "[escape_path $path]\n"
1779                 $w conf -state disabled
1780         } elseif {$old_m ne $new_m} {
1781                 $w conf -state normal
1782                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1783                 $w conf -state disabled
1784         }
1785 }
1786
1787 proc display_file {path state} {
1788         global file_states selected_paths
1789         global ui_index ui_workdir
1790
1791         set old_m [merge_state $path $state]
1792         set s $file_states($path)
1793         set new_m [lindex $s 0]
1794         set icon_name [lindex $s 1]
1795
1796         set o [string index $old_m 0]
1797         set n [string index $new_m 0]
1798         if {$o eq {U}} {
1799                 set o _
1800         }
1801         if {$n eq {U}} {
1802                 set n _
1803         }
1804         display_file_helper     $ui_index $path $icon_name $o $n
1805
1806         if {[string index $old_m 0] eq {U}} {
1807                 set o U
1808         } else {
1809                 set o [string index $old_m 1]
1810         }
1811         if {[string index $new_m 0] eq {U}} {
1812                 set n U
1813         } else {
1814                 set n [string index $new_m 1]
1815         }
1816         display_file_helper     $ui_workdir $path $icon_name $o $n
1817
1818         if {$new_m eq {__}} {
1819                 unset file_states($path)
1820                 catch {unset selected_paths($path)}
1821         }
1822 }
1823
1824 proc display_all_files_helper {w path icon_name m} {
1825         global file_lists
1826
1827         lappend file_lists($w) $path
1828         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1829         $w image create end \
1830                 -align center -padx 5 -pady 1 \
1831                 -name $icon_name \
1832                 -image [mapicon $w $m $path]
1833         $w insert end "[escape_path $path]\n"
1834 }
1835
1836 set files_warning 0
1837 proc display_all_files {} {
1838         global ui_index ui_workdir
1839         global file_states file_lists
1840         global last_clicked
1841         global files_warning
1842
1843         $ui_index conf -state normal
1844         $ui_workdir conf -state normal
1845
1846         $ui_index delete 0.0 end
1847         $ui_workdir delete 0.0 end
1848         set last_clicked {}
1849
1850         set file_lists($ui_index) [list]
1851         set file_lists($ui_workdir) [list]
1852
1853         set to_display [lsort [array names file_states]]
1854         set display_limit [get_config gui.maxfilesdisplayed]
1855         if {[llength $to_display] > $display_limit} {
1856                 if {!$files_warning} {
1857                         # do not repeatedly warn:
1858                         set files_warning 1
1859                         info_popup [mc "Displaying only %s of %s files." \
1860                                 $display_limit [llength $to_display]]
1861                 }
1862                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1863         }
1864         foreach path $to_display {
1865                 set s $file_states($path)
1866                 set m [lindex $s 0]
1867                 set icon_name [lindex $s 1]
1868
1869                 set s [string index $m 0]
1870                 if {$s ne {U} && $s ne {_}} {
1871                         display_all_files_helper $ui_index $path \
1872                                 $icon_name $s
1873                 }
1874
1875                 if {[string index $m 0] eq {U}} {
1876                         set s U
1877                 } else {
1878                         set s [string index $m 1]
1879                 }
1880                 if {$s ne {_}} {
1881                         display_all_files_helper $ui_workdir $path \
1882                                 $icon_name $s
1883                 }
1884         }
1885
1886         $ui_index conf -state disabled
1887         $ui_workdir conf -state disabled
1888 }
1889
1890 ######################################################################
1891 ##
1892 ## icons
1893
1894 set filemask {
1895 #define mask_width 14
1896 #define mask_height 15
1897 static unsigned char mask_bits[] = {
1898    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1899    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
1900    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
1901 }
1902
1903 image create bitmap file_plain -background white -foreground black -data {
1904 #define plain_width 14
1905 #define plain_height 15
1906 static unsigned char plain_bits[] = {
1907    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1908    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
1909    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1910 } -maskdata $filemask
1911
1912 image create bitmap file_mod -background white -foreground blue -data {
1913 #define mod_width 14
1914 #define mod_height 15
1915 static unsigned char mod_bits[] = {
1916    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
1917    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1918    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1919 } -maskdata $filemask
1920
1921 image create bitmap file_fulltick -background white -foreground "#007000" -data {
1922 #define file_fulltick_width 14
1923 #define file_fulltick_height 15
1924 static unsigned char file_fulltick_bits[] = {
1925    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
1926    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
1927    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1928 } -maskdata $filemask
1929
1930 image create bitmap file_question -background white -foreground black -data {
1931 #define file_question_width 14
1932 #define file_question_height 15
1933 static unsigned char file_question_bits[] = {
1934    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
1935    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
1936    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1937 } -maskdata $filemask
1938
1939 image create bitmap file_removed -background white -foreground red -data {
1940 #define file_removed_width 14
1941 #define file_removed_height 15
1942 static unsigned char file_removed_bits[] = {
1943    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1944    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1945    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1946 } -maskdata $filemask
1947
1948 image create bitmap file_merge -background white -foreground blue -data {
1949 #define file_merge_width 14
1950 #define file_merge_height 15
1951 static unsigned char file_merge_bits[] = {
1952    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1953    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1954    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1955 } -maskdata $filemask
1956
1957 image create bitmap file_statechange -background white -foreground green -data {
1958 #define file_merge_width 14
1959 #define file_merge_height 15
1960 static unsigned char file_statechange_bits[] = {
1961    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
1962    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
1963    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
1964 } -maskdata $filemask
1965
1966 set ui_index .vpane.files.index.list
1967 set ui_workdir .vpane.files.workdir.list
1968
1969 set all_icons(_$ui_index)   file_plain
1970 set all_icons(A$ui_index)   file_plain
1971 set all_icons(M$ui_index)   file_fulltick
1972 set all_icons(D$ui_index)   file_removed
1973 set all_icons(U$ui_index)   file_merge
1974 set all_icons(T$ui_index)   file_statechange
1975
1976 set all_icons(_$ui_workdir) file_plain
1977 set all_icons(M$ui_workdir) file_mod
1978 set all_icons(D$ui_workdir) file_question
1979 set all_icons(U$ui_workdir) file_merge
1980 set all_icons(O$ui_workdir) file_plain
1981 set all_icons(T$ui_workdir) file_statechange
1982
1983 set max_status_desc 0
1984 foreach i {
1985                 {__ {mc "Unmodified"}}
1986
1987                 {_M {mc "Modified, not staged"}}
1988                 {M_ {mc "Staged for commit"}}
1989                 {MM {mc "Portions staged for commit"}}
1990                 {MD {mc "Staged for commit, missing"}}
1991
1992                 {_T {mc "File type changed, not staged"}}
1993                 {T_ {mc "File type changed, staged"}}
1994
1995                 {_O {mc "Untracked, not staged"}}
1996                 {A_ {mc "Staged for commit"}}
1997                 {AM {mc "Portions staged for commit"}}
1998                 {AD {mc "Staged for commit, missing"}}
1999
2000                 {_D {mc "Missing"}}
2001                 {D_ {mc "Staged for removal"}}
2002                 {DO {mc "Staged for removal, still present"}}
2003
2004                 {_U {mc "Requires merge resolution"}}
2005                 {U_ {mc "Requires merge resolution"}}
2006                 {UU {mc "Requires merge resolution"}}
2007                 {UM {mc "Requires merge resolution"}}
2008                 {UD {mc "Requires merge resolution"}}
2009                 {UT {mc "Requires merge resolution"}}
2010         } {
2011         set text [eval [lindex $i 1]]
2012         if {$max_status_desc < [string length $text]} {
2013                 set max_status_desc [string length $text]
2014         }
2015         set all_descs([lindex $i 0]) $text
2016 }
2017 unset i
2018
2019 ######################################################################
2020 ##
2021 ## util
2022
2023 proc scrollbar2many {list mode args} {
2024         foreach w $list {eval $w $mode $args}
2025 }
2026
2027 proc many2scrollbar {list mode sb top bottom} {
2028         $sb set $top $bottom
2029         foreach w $list {$w $mode moveto $top}
2030 }
2031
2032 proc incr_font_size {font {amt 1}} {
2033         set sz [font configure $font -size]
2034         incr sz $amt
2035         font configure $font -size $sz
2036         font configure ${font}bold -size $sz
2037         font configure ${font}italic -size $sz
2038 }
2039
2040 ######################################################################
2041 ##
2042 ## ui commands
2043
2044 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2045
2046 proc do_gitk {revs {is_submodule false}} {
2047         global current_diff_path file_states current_diff_side ui_index
2048         global _gitworktree
2049
2050         # -- Always start gitk through whatever we were loaded with.  This
2051         #    lets us bypass using shell process on Windows systems.
2052         #
2053         set exe [_which gitk -script]
2054         set cmd [list [info nameofexecutable] $exe]
2055         if {$exe eq {}} {
2056                 error_popup [mc "Couldn't find gitk in PATH"]
2057         } else {
2058                 global env
2059
2060                 if {[info exists env(GIT_DIR)]} {
2061                         set old_GIT_DIR $env(GIT_DIR)
2062                 } else {
2063                         set old_GIT_DIR {}
2064                 }
2065
2066                 set pwd [pwd]
2067
2068                 if {!$is_submodule} {
2069                         if {![is_bare]} {
2070                                 cd $_gitworktree
2071                         }
2072                         set env(GIT_DIR) [file normalize [gitdir]]
2073                 } else {
2074                         cd $current_diff_path
2075                         if {$revs eq {--}} {
2076                                 set s $file_states($current_diff_path)
2077                                 set old_sha1 {}
2078                                 set new_sha1 {}
2079                                 switch -glob -- [lindex $s 0] {
2080                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2081                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2082                                 MM {
2083                                         if {$current_diff_side eq $ui_index} {
2084                                                 set old_sha1 [lindex [lindex $s 2] 1]
2085                                                 set new_sha1 [lindex [lindex $s 3] 1]
2086                                         } else {
2087                                                 set old_sha1 [lindex [lindex $s 3] 1]
2088                                         }
2089                                 }
2090                                 }
2091                                 set revs $old_sha1...$new_sha1
2092                         }
2093                         if {[info exists env(GIT_DIR)]} {
2094                                 unset env(GIT_DIR)
2095                         }
2096                 }
2097                 eval exec $cmd $revs "--" "--" &
2098
2099                 if {$old_GIT_DIR ne {}} {
2100                         set env(GIT_DIR) $old_GIT_DIR
2101                 }
2102                 cd $pwd
2103
2104                 ui_status $::starting_gitk_msg
2105                 after 10000 {
2106                         ui_ready $starting_gitk_msg
2107                 }
2108         }
2109 }
2110
2111 proc do_git_gui {} {
2112         global current_diff_path
2113
2114         # -- Always start git gui through whatever we were loaded with.  This
2115         #    lets us bypass using shell process on Windows systems.
2116         #
2117         set exe [list [_which git]]
2118         if {$exe eq {}} {
2119                 error_popup [mc "Couldn't find git gui in PATH"]
2120         } else {
2121                 global env
2122
2123                 if {[info exists env(GIT_DIR)]} {
2124                         set old_GIT_DIR $env(GIT_DIR)
2125                         unset env(GIT_DIR)
2126                 } else {
2127                         set old_GIT_DIR {}
2128                 }
2129
2130                 set pwd [pwd]
2131                 cd $current_diff_path
2132
2133                 eval exec $exe gui &
2134
2135                 if {$old_GIT_DIR ne {}} {
2136                         set env(GIT_DIR) $old_GIT_DIR
2137                 }
2138                 cd $pwd
2139
2140                 ui_status $::starting_gitk_msg
2141                 after 10000 {
2142                         ui_ready $starting_gitk_msg
2143                 }
2144         }
2145 }
2146
2147 proc do_explore {} {
2148         global _gitworktree
2149         set explorer {}
2150         if {[is_Cygwin] || [is_Windows]} {
2151                 set explorer "explorer.exe"
2152         } elseif {[is_MacOSX]} {
2153                 set explorer "open"
2154         } else {
2155                 # freedesktop.org-conforming system is our best shot
2156                 set explorer "xdg-open"
2157         }
2158         eval exec $explorer [list [file nativename $_gitworktree]] &
2159 }
2160
2161 set is_quitting 0
2162 set ret_code    1
2163
2164 proc terminate_me {win} {
2165         global ret_code
2166         if {$win ne {.}} return
2167         exit $ret_code
2168 }
2169
2170 proc do_quit {{rc {1}}} {
2171         global ui_comm is_quitting repo_config commit_type
2172         global GITGUI_BCK_exists GITGUI_BCK_i
2173         global ui_comm_spell
2174         global ret_code use_ttk
2175
2176         if {$is_quitting} return
2177         set is_quitting 1
2178
2179         if {[winfo exists $ui_comm]} {
2180                 # -- Stash our current commit buffer.
2181                 #
2182                 set save [gitdir GITGUI_MSG]
2183                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2184                         file rename -force [gitdir GITGUI_BCK] $save
2185                         set GITGUI_BCK_exists 0
2186                 } else {
2187                         set msg [string trim [$ui_comm get 0.0 end]]
2188                         regsub -all -line {[ \r\t]+$} $msg {} msg
2189                         if {(![string match amend* $commit_type]
2190                                 || [$ui_comm edit modified])
2191                                 && $msg ne {}} {
2192                                 catch {
2193                                         set fd [open $save w]
2194                                         puts -nonewline $fd $msg
2195                                         close $fd
2196                                 }
2197                         } else {
2198                                 catch {file delete $save}
2199                         }
2200                 }
2201
2202                 # -- Cancel our spellchecker if its running.
2203                 #
2204                 if {[info exists ui_comm_spell]} {
2205                         $ui_comm_spell stop
2206                 }
2207
2208                 # -- Remove our editor backup, its not needed.
2209                 #
2210                 after cancel $GITGUI_BCK_i
2211                 if {$GITGUI_BCK_exists} {
2212                         catch {file delete [gitdir GITGUI_BCK]}
2213                 }
2214
2215                 # -- Stash our current window geometry into this repository.
2216                 #
2217                 set cfg_wmstate [wm state .]
2218                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2219                         set rc_wmstate {}
2220                 }
2221                 if {$cfg_wmstate ne $rc_wmstate} {
2222                         catch {git config gui.wmstate $cfg_wmstate}
2223                 }
2224                 if {$cfg_wmstate eq {zoomed}} {
2225                         # on Windows wm geometry will lie about window
2226                         # position (but not size) when window is zoomed
2227                         # restore the window before querying wm geometry
2228                         wm state . normal
2229                 }
2230                 set cfg_geometry [list]
2231                 lappend cfg_geometry [wm geometry .]
2232                 if {$use_ttk} {
2233                         lappend cfg_geometry [.vpane sashpos 0]
2234                         lappend cfg_geometry [.vpane.files sashpos 0]
2235                 } else {
2236                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2237                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2238                 }
2239                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2240                         set rc_geometry {}
2241                 }
2242                 if {$cfg_geometry ne $rc_geometry} {
2243                         catch {git config gui.geometry $cfg_geometry}
2244                 }
2245         }
2246
2247         set ret_code $rc
2248
2249         # Briefly enable send again, working around Tk bug
2250         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2251         tk appname [appname]
2252
2253         destroy .
2254 }
2255
2256 proc do_rescan {} {
2257         rescan ui_ready
2258 }
2259
2260 proc ui_do_rescan {} {
2261         rescan {force_first_diff ui_ready}
2262 }
2263
2264 proc do_commit {} {
2265         commit_tree
2266 }
2267
2268 proc next_diff {{after {}}} {
2269         global next_diff_p next_diff_w next_diff_i
2270         show_diff $next_diff_p $next_diff_w {} {} $after
2271 }
2272
2273 proc find_anchor_pos {lst name} {
2274         set lid [lsearch -sorted -exact $lst $name]
2275
2276         if {$lid == -1} {
2277                 set lid 0
2278                 foreach lname $lst {
2279                         if {$lname >= $name} break
2280                         incr lid
2281                 }
2282         }
2283
2284         return $lid
2285 }
2286
2287 proc find_file_from {flist idx delta path mmask} {
2288         global file_states
2289
2290         set len [llength $flist]
2291         while {$idx >= 0 && $idx < $len} {
2292                 set name [lindex $flist $idx]
2293
2294                 if {$name ne $path && [info exists file_states($name)]} {
2295                         set state [lindex $file_states($name) 0]
2296
2297                         if {$mmask eq {} || [regexp $mmask $state]} {
2298                                 return $idx
2299                         }
2300                 }
2301
2302                 incr idx $delta
2303         }
2304
2305         return {}
2306 }
2307
2308 proc find_next_diff {w path {lno {}} {mmask {}}} {
2309         global next_diff_p next_diff_w next_diff_i
2310         global file_lists ui_index ui_workdir
2311
2312         set flist $file_lists($w)
2313         if {$lno eq {}} {
2314                 set lno [find_anchor_pos $flist $path]
2315         } else {
2316                 incr lno -1
2317         }
2318
2319         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2320                 if {$w eq $ui_index} {
2321                         set mmask "^$mmask"
2322                 } else {
2323                         set mmask "$mmask\$"
2324                 }
2325         }
2326
2327         set idx [find_file_from $flist $lno 1 $path $mmask]
2328         if {$idx eq {}} {
2329                 incr lno -1
2330                 set idx [find_file_from $flist $lno -1 $path $mmask]
2331         }
2332
2333         if {$idx ne {}} {
2334                 set next_diff_w $w
2335                 set next_diff_p [lindex $flist $idx]
2336                 set next_diff_i [expr {$idx+1}]
2337                 return 1
2338         } else {
2339                 return 0
2340         }
2341 }
2342
2343 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2344         global current_diff_path
2345
2346         if {$path ne $current_diff_path} {
2347                 return {}
2348         } elseif {[find_next_diff $w $path $lno $mmask]} {
2349                 return {next_diff;}
2350         } else {
2351                 return {reshow_diff;}
2352         }
2353 }
2354
2355 proc select_first_diff {after} {
2356         global ui_workdir
2357
2358         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2359             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2360                 next_diff $after
2361         } else {
2362                 uplevel #0 $after
2363         }
2364 }
2365
2366 proc force_first_diff {after} {
2367         global ui_workdir current_diff_path file_states
2368
2369         if {[info exists file_states($current_diff_path)]} {
2370                 set state [lindex $file_states($current_diff_path) 0]
2371         } else {
2372                 set state {OO}
2373         }
2374
2375         set reselect 0
2376         if {[string first {U} $state] >= 0} {
2377                 # Already a conflict, do nothing
2378         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2379                 set reselect 1
2380         } elseif {[string index $state 1] ne {O}} {
2381                 # Already a diff & no conflicts, do nothing
2382         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2383                 set reselect 1
2384         }
2385
2386         if {$reselect} {
2387                 next_diff $after
2388         } else {
2389                 uplevel #0 $after
2390         }
2391 }
2392
2393 proc toggle_or_diff {w x y} {
2394         global file_states file_lists current_diff_path ui_index ui_workdir
2395         global last_clicked selected_paths
2396
2397         set pos [split [$w index @$x,$y] .]
2398         set lno [lindex $pos 0]
2399         set col [lindex $pos 1]
2400         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2401         if {$path eq {}} {
2402                 set last_clicked {}
2403                 return
2404         }
2405
2406         set last_clicked [list $w $lno]
2407         array unset selected_paths
2408         $ui_index tag remove in_sel 0.0 end
2409         $ui_workdir tag remove in_sel 0.0 end
2410
2411         # Determine the state of the file
2412         if {[info exists file_states($path)]} {
2413                 set state [lindex $file_states($path) 0]
2414         } else {
2415                 set state {__}
2416         }
2417
2418         # Restage the file, or simply show the diff
2419         if {$col == 0 && $y > 1} {
2420                 # Conflicts need special handling
2421                 if {[string first {U} $state] >= 0} {
2422                         # $w must always be $ui_workdir, but...
2423                         if {$w ne $ui_workdir} { set lno {} }
2424                         merge_stage_workdir $path $lno
2425                         return
2426                 }
2427
2428                 if {[string index $state 1] eq {O}} {
2429                         set mmask {}
2430                 } else {
2431                         set mmask {[^O]}
2432                 }
2433
2434                 set after [next_diff_after_action $w $path $lno $mmask]
2435
2436                 if {$w eq $ui_index} {
2437                         update_indexinfo \
2438                                 "Unstaging [short_path $path] from commit" \
2439                                 [list $path] \
2440                                 [concat $after [list ui_ready]]
2441                 } elseif {$w eq $ui_workdir} {
2442                         update_index \
2443                                 "Adding [short_path $path]" \
2444                                 [list $path] \
2445                                 [concat $after [list ui_ready]]
2446                 }
2447         } else {
2448                 show_diff $path $w $lno
2449         }
2450 }
2451
2452 proc add_one_to_selection {w x y} {
2453         global file_lists last_clicked selected_paths
2454
2455         set lno [lindex [split [$w index @$x,$y] .] 0]
2456         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2457         if {$path eq {}} {
2458                 set last_clicked {}
2459                 return
2460         }
2461
2462         if {$last_clicked ne {}
2463                 && [lindex $last_clicked 0] ne $w} {
2464                 array unset selected_paths
2465                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2466         }
2467
2468         set last_clicked [list $w $lno]
2469         if {[catch {set in_sel $selected_paths($path)}]} {
2470                 set in_sel 0
2471         }
2472         if {$in_sel} {
2473                 unset selected_paths($path)
2474                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2475         } else {
2476                 set selected_paths($path) 1
2477                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2478         }
2479 }
2480
2481 proc add_range_to_selection {w x y} {
2482         global file_lists last_clicked selected_paths
2483
2484         if {[lindex $last_clicked 0] ne $w} {
2485                 toggle_or_diff $w $x $y
2486                 return
2487         }
2488
2489         set lno [lindex [split [$w index @$x,$y] .] 0]
2490         set lc [lindex $last_clicked 1]
2491         if {$lc < $lno} {
2492                 set begin $lc
2493                 set end $lno
2494         } else {
2495                 set begin $lno
2496                 set end $lc
2497         }
2498
2499         foreach path [lrange $file_lists($w) \
2500                 [expr {$begin - 1}] \
2501                 [expr {$end - 1}]] {
2502                 set selected_paths($path) 1
2503         }
2504         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2505 }
2506
2507 proc show_more_context {} {
2508         global repo_config
2509         if {$repo_config(gui.diffcontext) < 99} {
2510                 incr repo_config(gui.diffcontext)
2511                 reshow_diff
2512         }
2513 }
2514
2515 proc show_less_context {} {
2516         global repo_config
2517         if {$repo_config(gui.diffcontext) > 1} {
2518                 incr repo_config(gui.diffcontext) -1
2519                 reshow_diff
2520         }
2521 }
2522
2523 ######################################################################
2524 ##
2525 ## ui construction
2526
2527 set ui_comm {}
2528
2529 # -- Menu Bar
2530 #
2531 menu .mbar -tearoff 0
2532 if {[is_MacOSX]} {
2533         # -- Apple Menu (Mac OS X only)
2534         #
2535         .mbar add cascade -label Apple -menu .mbar.apple
2536         menu .mbar.apple
2537 }
2538 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2539 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2540 if {[is_enabled branch]} {
2541         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2542 }
2543 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2544         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2545 }
2546 if {[is_enabled transport]} {
2547         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2548         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2549 }
2550 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2551         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2552 }
2553
2554 # -- Repository Menu
2555 #
2556 menu .mbar.repository
2557
2558 if {![is_bare]} {
2559         .mbar.repository add command \
2560                 -label [mc "Explore Working Copy"] \
2561                 -command {do_explore}
2562         .mbar.repository add separator
2563 }
2564
2565 .mbar.repository add command \
2566         -label [mc "Browse Current Branch's Files"] \
2567         -command {browser::new $current_branch}
2568 set ui_browse_current [.mbar.repository index last]
2569 .mbar.repository add command \
2570         -label [mc "Browse Branch Files..."] \
2571         -command browser_open::dialog
2572 .mbar.repository add separator
2573
2574 .mbar.repository add command \
2575         -label [mc "Visualize Current Branch's History"] \
2576         -command {do_gitk $current_branch}
2577 set ui_visualize_current [.mbar.repository index last]
2578 .mbar.repository add command \
2579         -label [mc "Visualize All Branch History"] \
2580         -command {do_gitk --all}
2581 .mbar.repository add separator
2582
2583 proc current_branch_write {args} {
2584         global current_branch
2585         .mbar.repository entryconf $::ui_browse_current \
2586                 -label [mc "Browse %s's Files" $current_branch]
2587         .mbar.repository entryconf $::ui_visualize_current \
2588                 -label [mc "Visualize %s's History" $current_branch]
2589 }
2590 trace add variable current_branch write current_branch_write
2591
2592 if {[is_enabled multicommit]} {
2593         .mbar.repository add command -label [mc "Database Statistics"] \
2594                 -command do_stats
2595
2596         .mbar.repository add command -label [mc "Compress Database"] \
2597                 -command do_gc
2598
2599         .mbar.repository add command -label [mc "Verify Database"] \
2600                 -command do_fsck_objects
2601
2602         .mbar.repository add separator
2603
2604         if {[is_Cygwin]} {
2605                 .mbar.repository add command \
2606                         -label [mc "Create Desktop Icon"] \
2607                         -command do_cygwin_shortcut
2608         } elseif {[is_Windows]} {
2609                 .mbar.repository add command \
2610                         -label [mc "Create Desktop Icon"] \
2611                         -command do_windows_shortcut
2612         } elseif {[is_MacOSX]} {
2613                 .mbar.repository add command \
2614                         -label [mc "Create Desktop Icon"] \
2615                         -command do_macosx_app
2616         }
2617 }
2618
2619 if {[is_MacOSX]} {
2620         proc ::tk::mac::Quit {args} { do_quit }
2621 } else {
2622         .mbar.repository add command -label [mc Quit] \
2623                 -command do_quit \
2624                 -accelerator $M1T-Q
2625 }
2626
2627 # -- Edit Menu
2628 #
2629 menu .mbar.edit
2630 .mbar.edit add command -label [mc Undo] \
2631         -command {catch {[focus] edit undo}} \
2632         -accelerator $M1T-Z
2633 .mbar.edit add command -label [mc Redo] \
2634         -command {catch {[focus] edit redo}} \
2635         -accelerator $M1T-Y
2636 .mbar.edit add separator
2637 .mbar.edit add command -label [mc Cut] \
2638         -command {catch {tk_textCut [focus]}} \
2639         -accelerator $M1T-X
2640 .mbar.edit add command -label [mc Copy] \
2641         -command {catch {tk_textCopy [focus]}} \
2642         -accelerator $M1T-C
2643 .mbar.edit add command -label [mc Paste] \
2644         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2645         -accelerator $M1T-V
2646 .mbar.edit add command -label [mc Delete] \
2647         -command {catch {[focus] delete sel.first sel.last}} \
2648         -accelerator Del
2649 .mbar.edit add separator
2650 .mbar.edit add command -label [mc "Select All"] \
2651         -command {catch {[focus] tag add sel 0.0 end}} \
2652         -accelerator $M1T-A
2653
2654 # -- Branch Menu
2655 #
2656 if {[is_enabled branch]} {
2657         menu .mbar.branch
2658
2659         .mbar.branch add command -label [mc "Create..."] \
2660                 -command branch_create::dialog \
2661                 -accelerator $M1T-N
2662         lappend disable_on_lock [list .mbar.branch entryconf \
2663                 [.mbar.branch index last] -state]
2664
2665         .mbar.branch add command -label [mc "Checkout..."] \
2666                 -command branch_checkout::dialog \
2667                 -accelerator $M1T-O
2668         lappend disable_on_lock [list .mbar.branch entryconf \
2669                 [.mbar.branch index last] -state]
2670
2671         .mbar.branch add command -label [mc "Rename..."] \
2672                 -command branch_rename::dialog
2673         lappend disable_on_lock [list .mbar.branch entryconf \
2674                 [.mbar.branch index last] -state]
2675
2676         .mbar.branch add command -label [mc "Delete..."] \
2677                 -command branch_delete::dialog
2678         lappend disable_on_lock [list .mbar.branch entryconf \
2679                 [.mbar.branch index last] -state]
2680
2681         .mbar.branch add command -label [mc "Reset..."] \
2682                 -command merge::reset_hard
2683         lappend disable_on_lock [list .mbar.branch entryconf \
2684                 [.mbar.branch index last] -state]
2685 }
2686
2687 # -- Commit Menu
2688 #
2689 proc commit_btn_caption {} {
2690         if {[is_enabled nocommit]} {
2691                 return [mc "Done"]
2692         } else {
2693                 return [mc Commit@@verb]
2694         }
2695 }
2696
2697 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2698         menu .mbar.commit
2699
2700         if {![is_enabled nocommit]} {
2701                 .mbar.commit add radiobutton \
2702                         -label [mc "New Commit"] \
2703                         -command do_select_commit_type \
2704                         -variable selected_commit_type \
2705                         -value new
2706                 lappend disable_on_lock \
2707                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2708
2709                 .mbar.commit add radiobutton \
2710                         -label [mc "Amend Last Commit"] \
2711                         -command do_select_commit_type \
2712                         -variable selected_commit_type \
2713                         -value amend
2714                 lappend disable_on_lock \
2715                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2716
2717                 .mbar.commit add separator
2718         }
2719
2720         .mbar.commit add command -label [mc Rescan] \
2721                 -command ui_do_rescan \
2722                 -accelerator F5
2723         lappend disable_on_lock \
2724                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2725
2726         .mbar.commit add command -label [mc "Stage To Commit"] \
2727                 -command do_add_selection \
2728                 -accelerator $M1T-T
2729         lappend disable_on_lock \
2730                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2731
2732         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2733                 -command do_add_all \
2734                 -accelerator $M1T-I
2735         lappend disable_on_lock \
2736                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2737
2738         .mbar.commit add command -label [mc "Unstage From Commit"] \
2739                 -command do_unstage_selection \
2740                 -accelerator $M1T-U
2741         lappend disable_on_lock \
2742                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2743
2744         .mbar.commit add command -label [mc "Revert Changes"] \
2745                 -command do_revert_selection \
2746                 -accelerator $M1T-J
2747         lappend disable_on_lock \
2748                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2749
2750         .mbar.commit add separator
2751
2752         .mbar.commit add command -label [mc "Show Less Context"] \
2753                 -command show_less_context \
2754                 -accelerator $M1T-\-
2755
2756         .mbar.commit add command -label [mc "Show More Context"] \
2757                 -command show_more_context \
2758                 -accelerator $M1T-=
2759
2760         .mbar.commit add separator
2761
2762         if {![is_enabled nocommitmsg]} {
2763                 .mbar.commit add command -label [mc "Sign Off"] \
2764                         -command do_signoff \
2765                         -accelerator $M1T-S
2766         }
2767
2768         .mbar.commit add command -label [commit_btn_caption] \
2769                 -command do_commit \
2770                 -accelerator $M1T-Return
2771         lappend disable_on_lock \
2772                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2773 }
2774
2775 # -- Merge Menu
2776 #
2777 if {[is_enabled branch]} {
2778         menu .mbar.merge
2779         .mbar.merge add command -label [mc "Local Merge..."] \
2780                 -command merge::dialog \
2781                 -accelerator $M1T-M
2782         lappend disable_on_lock \
2783                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2784         .mbar.merge add command -label [mc "Abort Merge..."] \
2785                 -command merge::reset_hard
2786         lappend disable_on_lock \
2787                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2788 }
2789
2790 # -- Transport Menu
2791 #
2792 if {[is_enabled transport]} {
2793         menu .mbar.remote
2794
2795         .mbar.remote add command \
2796                 -label [mc "Add..."] \
2797                 -command remote_add::dialog \
2798                 -accelerator $M1T-A
2799         .mbar.remote add command \
2800                 -label [mc "Push..."] \
2801                 -command do_push_anywhere \
2802                 -accelerator $M1T-P
2803         .mbar.remote add command \
2804                 -label [mc "Delete Branch..."] \
2805                 -command remote_branch_delete::dialog
2806 }
2807
2808 if {[is_MacOSX]} {
2809         proc ::tk::mac::ShowPreferences {} {do_options}
2810 } else {
2811         # -- Edit Menu
2812         #
2813         .mbar.edit add separator
2814         .mbar.edit add command -label [mc "Options..."] \
2815                 -command do_options
2816 }
2817
2818 # -- Tools Menu
2819 #
2820 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2821         set tools_menubar .mbar.tools
2822         menu $tools_menubar
2823         $tools_menubar add separator
2824         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2825         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2826         set tools_tailcnt 3
2827         if {[array names repo_config guitool.*.cmd] ne {}} {
2828                 tools_populate_all
2829         }
2830 }
2831
2832 # -- Help Menu
2833 #
2834 .mbar add cascade -label [mc Help] -menu .mbar.help
2835 menu .mbar.help
2836
2837 if {[is_MacOSX]} {
2838         .mbar.apple add command -label [mc "About %s" [appname]] \
2839                 -command do_about
2840         .mbar.apple add separator
2841 } else {
2842         .mbar.help add command -label [mc "About %s" [appname]] \
2843                 -command do_about
2844 }
2845 . configure -menu .mbar
2846
2847 set doc_path [githtmldir]
2848 if {$doc_path ne {}} {
2849         set doc_path [file join $doc_path index.html]
2850
2851         if {[is_Cygwin]} {
2852                 set doc_path [exec cygpath --mixed $doc_path]
2853         }
2854 }
2855
2856 if {[file isfile $doc_path]} {
2857         set doc_url "file:$doc_path"
2858 } else {
2859         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2860 }
2861
2862 proc start_browser {url} {
2863         git "web--browse" $url
2864 }
2865
2866 .mbar.help add command -label [mc "Online Documentation"] \
2867         -command [list start_browser $doc_url]
2868
2869 .mbar.help add command -label [mc "Show SSH Key"] \
2870         -command do_ssh_key
2871
2872 unset doc_path doc_url
2873
2874 # -- Standard bindings
2875 #
2876 wm protocol . WM_DELETE_WINDOW do_quit
2877 bind all <$M1B-Key-q> do_quit
2878 bind all <$M1B-Key-Q> do_quit
2879 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
2880 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
2881
2882 set subcommand_args {}
2883 proc usage {} {
2884         set s "usage: $::argv0 $::subcommand $::subcommand_args"
2885         if {[tk windowingsystem] eq "win32"} {
2886                 wm withdraw .
2887                 tk_messageBox -icon info -message $s \
2888                         -title [mc "Usage"]
2889         } else {
2890                 puts stderr $s
2891         }
2892         exit 1
2893 }
2894
2895 proc normalize_relpath {path} {
2896         set elements {}
2897         foreach item [file split $path] {
2898                 if {$item eq {.}} continue
2899                 if {$item eq {..} && [llength $elements] > 0
2900                     && [lindex $elements end] ne {..}} {
2901                         set elements [lrange $elements 0 end-1]
2902                         continue
2903                 }
2904                 lappend elements $item
2905         }
2906         return [eval file join $elements]
2907 }
2908
2909 # -- Not a normal commit type invocation?  Do that instead!
2910 #
2911 switch -- $subcommand {
2912 browser -
2913 blame {
2914         if {$subcommand eq "blame"} {
2915                 set subcommand_args {[--line=<num>] rev? path}
2916         } else {
2917                 set subcommand_args {rev? path}
2918         }
2919         if {$argv eq {}} usage
2920         set head {}
2921         set path {}
2922         set jump_spec {}
2923         set is_path 0
2924         foreach a $argv {
2925                 if {$is_path || [file exists $_prefix$a]} {
2926                         if {$path ne {}} usage
2927                         set path [normalize_relpath $_prefix$a]
2928                         break
2929                 } elseif {$a eq {--}} {
2930                         if {$path ne {}} {
2931                                 if {$head ne {}} usage
2932                                 set head $path
2933                                 set path {}
2934                         }
2935                         set is_path 1
2936                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
2937                         if {$jump_spec ne {} || $head ne {}} usage
2938                         set jump_spec [list $lnum]
2939                 } elseif {$head eq {}} {
2940                         if {$head ne {}} usage
2941                         set head $a
2942                         set is_path 1
2943                 } else {
2944                         usage
2945                 }
2946         }
2947         unset is_path
2948
2949         if {$head ne {} && $path eq {}} {
2950                 set path [normalize_relpath $_prefix$head]
2951                 set head {}
2952         }
2953
2954         if {$head eq {}} {
2955                 load_current_branch
2956         } else {
2957                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
2958                         if {[catch {
2959                                         set head [git rev-parse --verify $head]
2960                                 } err]} {
2961                                 if {[tk windowingsystem] eq "win32"} {
2962                                         tk_messageBox -icon error -title [mc Error] -message $err
2963                                 } else {
2964                                         puts stderr $err
2965                                 }
2966                                 exit 1
2967                         }
2968                 }
2969                 set current_branch $head
2970         }
2971
2972         wm deiconify .
2973         switch -- $subcommand {
2974         browser {
2975                 if {$jump_spec ne {}} usage
2976                 if {$head eq {}} {
2977                         if {$path ne {} && [file isdirectory $path]} {
2978                                 set head $current_branch
2979                         } else {
2980                                 set head $path
2981                                 set path {}
2982                         }
2983                 }
2984                 browser::new $head $path
2985         }
2986         blame   {
2987                 if {$head eq {} && ![file exists $path]} {
2988                         catch {wm withdraw .}
2989                         tk_messageBox \
2990                                 -icon error \
2991                                 -type ok \
2992                                 -title [mc "git-gui: fatal error"] \
2993                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
2994                         exit 1
2995                 }
2996                 blame::new $head $path $jump_spec
2997         }
2998         }
2999         return
3000 }
3001 citool -
3002 gui {
3003         if {[llength $argv] != 0} {
3004                 usage
3005         }
3006         # fall through to setup UI for commits
3007 }
3008 default {
3009         set err "usage: $argv0 \[{blame|browser|citool}\]"
3010         if {[tk windowingsystem] eq "win32"} {
3011                 wm withdraw .
3012                 tk_messageBox -icon error -message $err \
3013                         -title [mc "Usage"]
3014         } else {
3015                 puts stderr $err
3016         }
3017         exit 1
3018 }
3019 }
3020
3021 # -- Branch Control
3022 #
3023 ${NS}::frame .branch
3024 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3025 ${NS}::label .branch.l1 \
3026         -text [mc "Current Branch:"] \
3027         -anchor w \
3028         -justify left
3029 ${NS}::label .branch.cb \
3030         -textvariable current_branch \
3031         -anchor w \
3032         -justify left
3033 pack .branch.l1 -side left
3034 pack .branch.cb -side left -fill x
3035 pack .branch -side top -fill x
3036
3037 # -- Main Window Layout
3038 #
3039 ${NS}::panedwindow .vpane -orient horizontal
3040 ${NS}::panedwindow .vpane.files -orient vertical
3041 if {$use_ttk} {
3042         .vpane add .vpane.files
3043 } else {
3044         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3045 }
3046 pack .vpane -anchor n -side top -fill both -expand 1
3047
3048 # -- Index File List
3049 #
3050 ${NS}::frame .vpane.files.index -height 100 -width 200
3051 tlabel .vpane.files.index.title \
3052         -text [mc "Staged Changes (Will Commit)"] \
3053         -background lightgreen -foreground black
3054 text $ui_index -background white -foreground black \
3055         -borderwidth 0 \
3056         -width 20 -height 10 \
3057         -wrap none \
3058         -cursor $cursor_ptr \
3059         -xscrollcommand {.vpane.files.index.sx set} \
3060         -yscrollcommand {.vpane.files.index.sy set} \
3061         -state disabled
3062 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3063 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3064 pack .vpane.files.index.title -side top -fill x
3065 pack .vpane.files.index.sx -side bottom -fill x
3066 pack .vpane.files.index.sy -side right -fill y
3067 pack $ui_index -side left -fill both -expand 1
3068
3069 # -- Working Directory File List
3070 #
3071 ${NS}::frame .vpane.files.workdir -height 100 -width 200
3072 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3073         -background lightsalmon -foreground black
3074 text $ui_workdir -background white -foreground black \
3075         -borderwidth 0 \
3076         -width 20 -height 10 \
3077         -wrap none \
3078         -cursor $cursor_ptr \
3079         -xscrollcommand {.vpane.files.workdir.sx set} \
3080         -yscrollcommand {.vpane.files.workdir.sy set} \
3081         -state disabled
3082 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3083 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3084 pack .vpane.files.workdir.title -side top -fill x
3085 pack .vpane.files.workdir.sx -side bottom -fill x
3086 pack .vpane.files.workdir.sy -side right -fill y
3087 pack $ui_workdir -side left -fill both -expand 1
3088
3089 .vpane.files add .vpane.files.workdir
3090 .vpane.files add .vpane.files.index
3091 if {!$use_ttk} {
3092         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3093         .vpane.files paneconfigure .vpane.files.index -sticky news
3094 }
3095
3096 foreach i [list $ui_index $ui_workdir] {
3097         rmsel_tag $i
3098         $i tag conf in_diff -background [$i tag cget in_sel -background]
3099 }
3100 unset i
3101
3102 # -- Diff and Commit Area
3103 #
3104 ${NS}::frame .vpane.lower -height 300 -width 400
3105 ${NS}::frame .vpane.lower.commarea
3106 ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1
3107 pack .vpane.lower.diff -fill both -expand 1
3108 pack .vpane.lower.commarea -side bottom -fill x
3109 .vpane add .vpane.lower
3110 if {!$use_ttk} {.vpane paneconfigure .vpane.lower -sticky nsew}
3111
3112 # -- Commit Area Buttons
3113 #
3114 ${NS}::frame .vpane.lower.commarea.buttons
3115 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3116         -anchor w \
3117         -justify left
3118 pack .vpane.lower.commarea.buttons.l -side top -fill x
3119 pack .vpane.lower.commarea.buttons -side left -fill y
3120
3121 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3122         -command ui_do_rescan
3123 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3124 lappend disable_on_lock \
3125         {.vpane.lower.commarea.buttons.rescan conf -state}
3126
3127 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3128         -command do_add_all
3129 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3130 lappend disable_on_lock \
3131         {.vpane.lower.commarea.buttons.incall conf -state}
3132
3133 if {![is_enabled nocommitmsg]} {
3134         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3135                 -command do_signoff
3136         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3137 }
3138
3139 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3140         -command do_commit
3141 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3142 lappend disable_on_lock \
3143         {.vpane.lower.commarea.buttons.commit conf -state}
3144
3145 if {![is_enabled nocommit]} {
3146         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3147                 -command do_push_anywhere
3148         pack .vpane.lower.commarea.buttons.push -side top -fill x
3149 }
3150
3151 # -- Commit Message Buffer
3152 #
3153 ${NS}::frame .vpane.lower.commarea.buffer
3154 ${NS}::frame .vpane.lower.commarea.buffer.header
3155 set ui_comm .vpane.lower.commarea.buffer.t
3156 set ui_coml .vpane.lower.commarea.buffer.header.l
3157
3158 if {![is_enabled nocommit]} {
3159         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3160                 -text [mc "New Commit"] \
3161                 -command do_select_commit_type \
3162                 -variable selected_commit_type \
3163                 -value new
3164         lappend disable_on_lock \
3165                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3166         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3167                 -text [mc "Amend Last Commit"] \
3168                 -command do_select_commit_type \
3169                 -variable selected_commit_type \
3170                 -value amend
3171         lappend disable_on_lock \
3172                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3173 }
3174
3175 ${NS}::label $ui_coml \
3176         -anchor w \
3177         -justify left
3178 proc trace_commit_type {varname args} {
3179         global ui_coml commit_type
3180         switch -glob -- $commit_type {
3181         initial       {set txt [mc "Initial Commit Message:"]}
3182         amend         {set txt [mc "Amended Commit Message:"]}
3183         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3184         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3185         merge         {set txt [mc "Merge Commit Message:"]}
3186         *             {set txt [mc "Commit Message:"]}
3187         }
3188         $ui_coml conf -text $txt
3189 }
3190 trace add variable commit_type write trace_commit_type
3191 pack $ui_coml -side left -fill x
3192
3193 if {![is_enabled nocommit]} {
3194         pack .vpane.lower.commarea.buffer.header.amend -side right
3195         pack .vpane.lower.commarea.buffer.header.new -side right
3196 }
3197
3198 text $ui_comm -background white -foreground black \
3199         -borderwidth 1 \
3200         -undo true \
3201         -maxundo 20 \
3202         -autoseparators true \
3203         -relief sunken \
3204         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3205         -font font_diff \
3206         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3207 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3208         -command [list $ui_comm yview]
3209 pack .vpane.lower.commarea.buffer.header -side top -fill x
3210 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3211 pack $ui_comm -side left -fill y
3212 pack .vpane.lower.commarea.buffer -side left -fill y
3213
3214 # -- Commit Message Buffer Context Menu
3215 #
3216 set ctxm .vpane.lower.commarea.buffer.ctxm
3217 menu $ctxm -tearoff 0
3218 $ctxm add command \
3219         -label [mc Cut] \
3220         -command {tk_textCut $ui_comm}
3221 $ctxm add command \
3222         -label [mc Copy] \
3223         -command {tk_textCopy $ui_comm}
3224 $ctxm add command \
3225         -label [mc Paste] \
3226         -command {tk_textPaste $ui_comm}
3227 $ctxm add command \
3228         -label [mc Delete] \
3229         -command {catch {$ui_comm delete sel.first sel.last}}
3230 $ctxm add separator
3231 $ctxm add command \
3232         -label [mc "Select All"] \
3233         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3234 $ctxm add command \
3235         -label [mc "Copy All"] \
3236         -command {
3237                 $ui_comm tag add sel 0.0 end
3238                 tk_textCopy $ui_comm
3239                 $ui_comm tag remove sel 0.0 end
3240         }
3241 $ctxm add separator
3242 $ctxm add command \
3243         -label [mc "Sign Off"] \
3244         -command do_signoff
3245 set ui_comm_ctxm $ctxm
3246
3247 # -- Diff Header
3248 #
3249 proc trace_current_diff_path {varname args} {
3250         global current_diff_path diff_actions file_states
3251         if {$current_diff_path eq {}} {
3252                 set s {}
3253                 set f {}
3254                 set p {}
3255                 set o disabled
3256         } else {
3257                 set p $current_diff_path
3258                 set s [mapdesc [lindex $file_states($p) 0] $p]
3259                 set f [mc "File:"]
3260                 set p [escape_path $p]
3261                 set o normal
3262         }
3263
3264         .vpane.lower.diff.header.status configure -text $s
3265         .vpane.lower.diff.header.file configure -text $f
3266         .vpane.lower.diff.header.path configure -text $p
3267         foreach w $diff_actions {
3268                 uplevel #0 $w $o
3269         }
3270 }
3271 trace add variable current_diff_path write trace_current_diff_path
3272
3273 gold_frame .vpane.lower.diff.header
3274 tlabel .vpane.lower.diff.header.status \
3275         -background gold \
3276         -foreground black \
3277         -width $max_status_desc \
3278         -anchor w \
3279         -justify left
3280 tlabel .vpane.lower.diff.header.file \
3281         -background gold \
3282         -foreground black \
3283         -anchor w \
3284         -justify left
3285 tlabel .vpane.lower.diff.header.path \
3286         -background gold \
3287         -foreground black \
3288         -anchor w \
3289         -justify left
3290 pack .vpane.lower.diff.header.status -side left
3291 pack .vpane.lower.diff.header.file -side left
3292 pack .vpane.lower.diff.header.path -fill x
3293 set ctxm .vpane.lower.diff.header.ctxm
3294 menu $ctxm -tearoff 0
3295 $ctxm add command \
3296         -label [mc Copy] \
3297         -command {
3298                 clipboard clear
3299                 clipboard append \
3300                         -format STRING \
3301                         -type STRING \
3302                         -- $current_diff_path
3303         }
3304 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3305 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3306
3307 # -- Diff Body
3308 #
3309 ${NS}::frame .vpane.lower.diff.body
3310 set ui_diff .vpane.lower.diff.body.t
3311 text $ui_diff -background white -foreground black \
3312         -borderwidth 0 \
3313         -width 80 -height 5 -wrap none \
3314         -font font_diff \
3315         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3316         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3317         -state disabled
3318 catch {$ui_diff configure -tabstyle wordprocessor}
3319 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3320         -command [list $ui_diff xview]
3321 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3322         -command [list $ui_diff yview]
3323 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3324 pack .vpane.lower.diff.body.sby -side right -fill y
3325 pack $ui_diff -side left -fill both -expand 1
3326 pack .vpane.lower.diff.header -side top -fill x
3327 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3328
3329 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3330         $ui_diff tag configure clr4$n -background $c
3331         $ui_diff tag configure clri4$n -foreground $c
3332         $ui_diff tag configure clr3$n -foreground $c
3333         $ui_diff tag configure clri3$n -background $c
3334 }
3335 $ui_diff tag configure clr1 -font font_diffbold
3336
3337 $ui_diff tag conf d_cr -elide true
3338 $ui_diff tag conf d_@ -font font_diffbold
3339 $ui_diff tag conf d_+ -foreground {#00a000}
3340 $ui_diff tag conf d_- -foreground red
3341
3342 $ui_diff tag conf d_++ -foreground {#00a000}
3343 $ui_diff tag conf d_-- -foreground red
3344 $ui_diff tag conf d_+s \
3345         -foreground {#00a000} \
3346         -background {#e2effa}
3347 $ui_diff tag conf d_-s \
3348         -foreground red \
3349         -background {#e2effa}
3350 $ui_diff tag conf d_s+ \
3351         -foreground {#00a000} \
3352         -background ivory1
3353 $ui_diff tag conf d_s- \
3354         -foreground red \
3355         -background ivory1
3356
3357 $ui_diff tag conf d<<<<<<< \
3358         -foreground orange \
3359         -font font_diffbold
3360 $ui_diff tag conf d======= \
3361         -foreground orange \
3362         -font font_diffbold
3363 $ui_diff tag conf d>>>>>>> \
3364         -foreground orange \
3365         -font font_diffbold
3366
3367 $ui_diff tag raise sel
3368
3369 # -- Diff Body Context Menu
3370 #
3371
3372 proc create_common_diff_popup {ctxm} {
3373         $ctxm add command \
3374                 -label [mc Refresh] \
3375                 -command reshow_diff
3376         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3377         $ctxm add command \
3378                 -label [mc Copy] \
3379                 -command {tk_textCopy $ui_diff}
3380         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3381         $ctxm add command \
3382                 -label [mc "Select All"] \
3383                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3384         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3385         $ctxm add command \
3386                 -label [mc "Copy All"] \
3387                 -command {
3388                         $ui_diff tag add sel 0.0 end
3389                         tk_textCopy $ui_diff
3390                         $ui_diff tag remove sel 0.0 end
3391                 }
3392         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3393         $ctxm add separator
3394         $ctxm add command \
3395                 -label [mc "Decrease Font Size"] \
3396                 -command {incr_font_size font_diff -1}
3397         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3398         $ctxm add command \
3399                 -label [mc "Increase Font Size"] \
3400                 -command {incr_font_size font_diff 1}
3401         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3402         $ctxm add separator
3403         set emenu $ctxm.enc
3404         menu $emenu
3405         build_encoding_menu $emenu [list force_diff_encoding]
3406         $ctxm add cascade \
3407                 -label [mc "Encoding"] \
3408                 -menu $emenu
3409         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3410         $ctxm add separator
3411         $ctxm add command -label [mc "Options..."] \
3412                 -command do_options
3413 }
3414
3415 set ctxm .vpane.lower.diff.body.ctxm
3416 menu $ctxm -tearoff 0
3417 $ctxm add command \
3418         -label [mc "Apply/Reverse Hunk"] \
3419         -command {apply_hunk $cursorX $cursorY}
3420 set ui_diff_applyhunk [$ctxm index last]
3421 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3422 $ctxm add command \
3423         -label [mc "Apply/Reverse Line"] \
3424         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3425 set ui_diff_applyline [$ctxm index last]
3426 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3427 $ctxm add separator
3428 $ctxm add command \
3429         -label [mc "Show Less Context"] \
3430         -command show_less_context
3431 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3432 $ctxm add command \
3433         -label [mc "Show More Context"] \
3434         -command show_more_context
3435 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3436 $ctxm add separator
3437 create_common_diff_popup $ctxm
3438
3439 set ctxmmg .vpane.lower.diff.body.ctxmmg
3440 menu $ctxmmg -tearoff 0
3441 $ctxmmg add command \
3442         -label [mc "Run Merge Tool"] \
3443         -command {merge_resolve_tool}
3444 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3445 $ctxmmg add separator
3446 $ctxmmg add command \
3447         -label [mc "Use Remote Version"] \
3448         -command {merge_resolve_one 3}
3449 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3450 $ctxmmg add command \
3451         -label [mc "Use Local Version"] \
3452         -command {merge_resolve_one 2}
3453 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3454 $ctxmmg add command \
3455         -label [mc "Revert To Base"] \
3456         -command {merge_resolve_one 1}
3457 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3458 $ctxmmg add separator
3459 $ctxmmg add command \
3460         -label [mc "Show Less Context"] \
3461         -command show_less_context
3462 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3463 $ctxmmg add command \
3464         -label [mc "Show More Context"] \
3465         -command show_more_context
3466 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3467 $ctxmmg add separator
3468 create_common_diff_popup $ctxmmg
3469
3470 set ctxmsm .vpane.lower.diff.body.ctxmsm
3471 menu $ctxmsm -tearoff 0
3472 $ctxmsm add command \
3473         -label [mc "Visualize These Changes In The Submodule"] \
3474         -command {do_gitk -- true}
3475 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3476 $ctxmsm add command \
3477         -label [mc "Visualize Current Branch History In The Submodule"] \
3478         -command {do_gitk {} true}
3479 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3480 $ctxmsm add command \
3481         -label [mc "Visualize All Branch History In The Submodule"] \
3482         -command {do_gitk --all true}
3483 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3484 $ctxmsm add separator
3485 $ctxmsm add command \
3486         -label [mc "Start git gui In The Submodule"] \
3487         -command {do_git_gui}
3488 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3489 $ctxmsm add separator
3490 create_common_diff_popup $ctxmsm
3491
3492 proc has_textconv {path} {
3493         if {[is_config_false gui.textconv]} {
3494                 return 0
3495         }
3496         set filter [gitattr $path diff set]
3497         set textconv [get_config [join [list diff $filter textconv] .]]
3498         if {$filter ne {set} && $textconv ne {}} {
3499                 return 1
3500         } else {
3501                 return 0
3502         }
3503 }
3504
3505 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3506         global current_diff_path file_states
3507         set ::cursorX $x
3508         set ::cursorY $y
3509         if {[info exists file_states($current_diff_path)]} {
3510                 set state [lindex $file_states($current_diff_path) 0]
3511         } else {
3512                 set state {__}
3513         }
3514         if {[string first {U} $state] >= 0} {
3515                 tk_popup $ctxmmg $X $Y
3516         } elseif {$::is_submodule_diff} {
3517                 tk_popup $ctxmsm $X $Y
3518         } else {
3519                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3520                 if {$::ui_index eq $::current_diff_side} {
3521                         set l [mc "Unstage Hunk From Commit"]
3522                         if {$has_range} {
3523                                 set t [mc "Unstage Lines From Commit"]
3524                         } else {
3525                                 set t [mc "Unstage Line From Commit"]
3526                         }
3527                 } else {
3528                         set l [mc "Stage Hunk For Commit"]
3529                         if {$has_range} {
3530                                 set t [mc "Stage Lines For Commit"]
3531                         } else {
3532                                 set t [mc "Stage Line For Commit"]
3533                         }
3534                 }
3535                 if {$::is_3way_diff
3536                         || $current_diff_path eq {}
3537                         || {__} eq $state
3538                         || {_O} eq $state
3539                         || {_T} eq $state
3540                         || {T_} eq $state
3541                         || [has_textconv $current_diff_path]} {
3542                         set s disabled
3543                 } else {
3544                         set s normal
3545                 }
3546                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3547                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3548                 tk_popup $ctxm $X $Y
3549         }
3550 }
3551 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3552
3553 # -- Status Bar
3554 #
3555 set main_status [::status_bar::new .status]
3556 pack .status -anchor w -side bottom -fill x
3557 $main_status show [mc "Initializing..."]
3558
3559 # -- Load geometry
3560 #
3561 proc on_ttk_pane_mapped {w pane pos} {
3562         bind $w <Map> {}
3563         after 0 [list after idle [list $w sashpos $pane $pos]]
3564 }
3565 proc on_tk_pane_mapped {w pane x y} {
3566         bind $w <Map> {}
3567         after 0 [list after idle [list $w sash place $pane $x $y]]
3568 }
3569 proc on_application_mapped {} {
3570         global repo_config use_ttk
3571         bind . <Map> {}
3572         set gm $repo_config(gui.geometry)
3573         if {$use_ttk} {
3574                 bind .vpane <Map> \
3575                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3576                 bind .vpane.files <Map> \
3577                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3578         } else {
3579                 bind .vpane <Map> \
3580                     [list on_tk_pane_mapped %W 0 \
3581                          [lindex $gm 1] \
3582                          [lindex [.vpane sash coord 0] 1]]
3583                 bind .vpane.files <Map> \
3584                     [list on_tk_pane_mapped %W 0 \
3585                          [lindex [.vpane.files sash coord 0] 0] \
3586                          [lindex $gm 2]]
3587         }
3588         wm geometry . [lindex $gm 0]
3589 }
3590 if {[info exists repo_config(gui.geometry)]} {
3591         bind . <Map> [list on_application_mapped]
3592         wm geometry . [lindex $repo_config(gui.geometry) 0]
3593 }
3594
3595 # -- Load window state
3596 #
3597 if {[info exists repo_config(gui.wmstate)]} {
3598         catch {wm state . $repo_config(gui.wmstate)}
3599 }
3600
3601 # -- Key Bindings
3602 #
3603 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3604 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3605 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3606 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3607 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3608 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3609 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3610 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3611 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3612 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3613 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3614 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3615 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3616 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3617 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3618 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3619 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3620 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3621 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3622 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3623 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3624 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3625
3626 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3627 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3628 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3629 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3630 bind $ui_diff <$M1B-Key-v> {break}
3631 bind $ui_diff <$M1B-Key-V> {break}
3632 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3633 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3634 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3635 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3636 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3637 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3638 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3639 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3640 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3641 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3642 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3643 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3644 bind $ui_diff <Button-1>   {focus %W}
3645
3646 if {[is_enabled branch]} {
3647         bind . <$M1B-Key-n> branch_create::dialog
3648         bind . <$M1B-Key-N> branch_create::dialog
3649         bind . <$M1B-Key-o> branch_checkout::dialog
3650         bind . <$M1B-Key-O> branch_checkout::dialog
3651         bind . <$M1B-Key-m> merge::dialog
3652         bind . <$M1B-Key-M> merge::dialog
3653 }
3654 if {[is_enabled transport]} {
3655         bind . <$M1B-Key-p> do_push_anywhere
3656         bind . <$M1B-Key-P> do_push_anywhere
3657 }
3658
3659 bind .   <Key-F5>     ui_do_rescan
3660 bind .   <$M1B-Key-r> ui_do_rescan
3661 bind .   <$M1B-Key-R> ui_do_rescan
3662 bind .   <$M1B-Key-s> do_signoff
3663 bind .   <$M1B-Key-S> do_signoff
3664 bind .   <$M1B-Key-t> do_add_selection
3665 bind .   <$M1B-Key-T> do_add_selection
3666 bind .   <$M1B-Key-j> do_revert_selection
3667 bind .   <$M1B-Key-J> do_revert_selection
3668 bind .   <$M1B-Key-i> do_add_all
3669 bind .   <$M1B-Key-I> do_add_all
3670 bind .   <$M1B-Key-minus> {show_less_context;break}
3671 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3672 bind .   <$M1B-Key-equal> {show_more_context;break}
3673 bind .   <$M1B-Key-plus> {show_more_context;break}
3674 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3675 bind .   <$M1B-Key-Return> do_commit
3676 foreach i [list $ui_index $ui_workdir] {
3677         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3678         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3679         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3680 }
3681 unset i
3682
3683 set file_lists($ui_index) [list]
3684 set file_lists($ui_workdir) [list]
3685
3686 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3687 focus -force $ui_comm
3688
3689 # -- Warn the user about environmental problems.  Cygwin's Tcl
3690 #    does *not* pass its env array onto any processes it spawns.
3691 #    This means that git processes get none of our environment.
3692 #
3693 if {[is_Cygwin]} {
3694         set ignored_env 0
3695         set suggest_user {}
3696         set msg [mc "Possible environment issues exist.
3697
3698 The following environment variables are probably
3699 going to be ignored by any Git subprocess run
3700 by %s:
3701
3702 " [appname]]
3703         foreach name [array names env] {
3704                 switch -regexp -- $name {
3705                 {^GIT_INDEX_FILE$} -
3706                 {^GIT_OBJECT_DIRECTORY$} -
3707                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3708                 {^GIT_DIFF_OPTS$} -
3709                 {^GIT_EXTERNAL_DIFF$} -
3710                 {^GIT_PAGER$} -
3711                 {^GIT_TRACE$} -
3712                 {^GIT_CONFIG$} -
3713                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3714                         append msg " - $name\n"
3715                         incr ignored_env
3716                 }
3717                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3718                         append msg " - $name\n"
3719                         incr ignored_env
3720                         set suggest_user $name
3721                 }
3722                 }
3723         }
3724         if {$ignored_env > 0} {
3725                 append msg [mc "
3726 This is due to a known issue with the
3727 Tcl binary distributed by Cygwin."]
3728
3729                 if {$suggest_user ne {}} {
3730                         append msg [mc "
3731
3732 A good replacement for %s
3733 is placing values for the user.name and
3734 user.email settings into your personal
3735 ~/.gitconfig file.
3736 " $suggest_user]
3737                 }
3738                 warn_popup $msg
3739         }
3740         unset ignored_env msg suggest_user name
3741 }
3742
3743 # -- Only initialize complex UI if we are going to stay running.
3744 #
3745 if {[is_enabled transport]} {
3746         load_all_remotes
3747
3748         set n [.mbar.remote index end]
3749         populate_remotes_menu
3750         set n [expr {[.mbar.remote index end] - $n}]
3751         if {$n > 0} {
3752                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3753                 .mbar.remote insert $n separator
3754         }
3755         unset n
3756 }
3757
3758 if {[winfo exists $ui_comm]} {
3759         set GITGUI_BCK_exists [load_message GITGUI_BCK]
3760
3761         # -- If both our backup and message files exist use the
3762         #    newer of the two files to initialize the buffer.
3763         #
3764         if {$GITGUI_BCK_exists} {
3765                 set m [gitdir GITGUI_MSG]
3766                 if {[file isfile $m]} {
3767                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3768                                 catch {file delete [gitdir GITGUI_MSG]}
3769                         } else {
3770                                 $ui_comm delete 0.0 end
3771                                 $ui_comm edit reset
3772                                 $ui_comm edit modified false
3773                                 catch {file delete [gitdir GITGUI_BCK]}
3774                                 set GITGUI_BCK_exists 0
3775                         }
3776                 }
3777                 unset m
3778         }
3779
3780         proc backup_commit_buffer {} {
3781                 global ui_comm GITGUI_BCK_exists
3782
3783                 set m [$ui_comm edit modified]
3784                 if {$m || $GITGUI_BCK_exists} {
3785                         set msg [string trim [$ui_comm get 0.0 end]]
3786                         regsub -all -line {[ \r\t]+$} $msg {} msg
3787
3788                         if {$msg eq {}} {
3789                                 if {$GITGUI_BCK_exists} {
3790                                         catch {file delete [gitdir GITGUI_BCK]}
3791                                         set GITGUI_BCK_exists 0
3792                                 }
3793                         } elseif {$m} {
3794                                 catch {
3795                                         set fd [open [gitdir GITGUI_BCK] w]
3796                                         puts -nonewline $fd $msg
3797                                         close $fd
3798                                         set GITGUI_BCK_exists 1
3799                                 }
3800                         }
3801
3802                         $ui_comm edit modified false
3803                 }
3804
3805                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3806         }
3807
3808         backup_commit_buffer
3809
3810         # -- If the user has aspell available we can drive it
3811         #    in pipe mode to spellcheck the commit message.
3812         #
3813         set spell_cmd [list |]
3814         set spell_dict [get_config gui.spellingdictionary]
3815         lappend spell_cmd aspell
3816         if {$spell_dict ne {}} {
3817                 lappend spell_cmd --master=$spell_dict
3818         }
3819         lappend spell_cmd --mode=none
3820         lappend spell_cmd --encoding=utf-8
3821         lappend spell_cmd pipe
3822         if {$spell_dict eq {none}
3823          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3824                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3825         } else {
3826                 set ui_comm_spell [spellcheck::init \
3827                         $spell_fd \
3828                         $ui_comm \
3829                         $ui_comm_ctxm \
3830                 ]
3831         }
3832         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3833 }
3834
3835 lock_index begin-read
3836 if {![winfo ismapped .]} {
3837         wm deiconify .
3838 }
3839 after 1 {
3840         if {[is_enabled initialamend]} {
3841                 force_amend
3842         } else {
3843                 do_rescan
3844         }
3845
3846         if {[is_enabled nocommitmsg]} {
3847                 $ui_comm configure -state disabled -background gray
3848         }
3849 }
3850 if {[is_enabled multicommit]} {
3851         after 1000 hint_gc
3852 }
3853 if {[is_enabled retcode]} {
3854         bind . <Destroy> {+terminate_me %W}
3855 }
3856 if {$picked && [is_config_true gui.autoexplore]} {
3857         do_explore
3858 }
3859
3860 # Local variables:
3861 # mode: tcl
3862 # indent-tabs-mode: t
3863 # tab-width: 4
3864 # End: