git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  72     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  73     --[no-]suppress-from           * Send to self. Default off.
  74     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  75     --[no-]thread                  * Use In-Reply-To: field. Default on.
  76
  77   Administering:
  78     --confirm               <str>  * Confirm recipients before sending;
  79                                      auto, cc, compose, always, or never.
  80     --quiet                        * Output one line of info per email.
  81     --dry-run                      * Don't actually send the emails.
  82     --[no-]validate                * Perform patch sanity checks. Default on.
  83     --[no-]format-patch            * understand any non optional arguments as
  84                                      `git format-patch` ones.
  85
  86 EOT
  87         exit(1);
  88 }
  89
  90 # most mail servers generate the Date: header, but not all...
  91 sub format_2822_time {
  92         my ($time) = @_;
  93         my @localtm = localtime($time);
  94         my @gmttm = gmtime($time);
  95         my $localmin = $localtm[1] + $localtm[2] * 60;
  96         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  97         if ($localtm[0] != $gmttm[0]) {
  98                 die "local zone differs from GMT by a non-minute interval\n";
  99         }
 100         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 101                 $localmin += 1440;
 102         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 103                 $localmin -= 1440;
 104         } elsif ($gmttm[6] != $localtm[6]) {
 105                 die "local time offset greater than or equal to 24 hours\n";
 106         }
 107         my $offset = $localmin - $gmtmin;
 108         my $offhour = $offset / 60;
 109         my $offmin = abs($offset % 60);
 110         if (abs($offhour) >= 24) {
 111                 die ("local time offset greater than or equal to 24 hours\n");
 112         }
 113
 114         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 115                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 116                        $localtm[3],
 117                        qw(Jan Feb Mar Apr May Jun
 118                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 119                        $localtm[5]+1900,
 120                        $localtm[2],
 121                        $localtm[1],
 122                        $localtm[0],
 123                        ($offset >= 0) ? '+' : '-',
 124                        abs($offhour),
 125                        $offmin,
 126                        );
 127 }
 128
 129 my $have_email_valid = eval { require Email::Valid; 1 };
 130 my $have_mail_address = eval { require Mail::Address; 1 };
 131 my $smtp;
 132 my $auth;
 133
 134 sub unique_email_list(@);
 135 sub cleanup_compose_files();
 136
 137 # Variables we fill in automatically, or via prompting:
 138 my (@to,@cc,@initial_cc,@bcclist,@xh,
 139         $initial_reply_to,$initial_subject,@files,
 140         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 141
 142 my $envelope_sender;
 143
 144 # Example reply to:
 145 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 146
 147 my $repo = eval { Git->repository() };
 148 my @repo = $repo ? ($repo) : ();
 149 my $term = eval {
 150         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 151                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 152                 : new Term::ReadLine 'git-send-email';
 153 };
 154 if ($@) {
 155         $term = new FakeTerm "$@: going non-interactive";
 156 }
 157
 158 # Behavior modification variables
 159 my ($quiet, $dry_run) = (0, 0);
 160 my $format_patch;
 161 my $compose_filename;
 162
 163 # Handle interactive edition of files.
 164 my $multiedit;
 165 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 166 sub do_edit {
 167         if (defined($multiedit) && !$multiedit) {
 168                 map {
 169                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 170                         if (($? & 127) || ($? >> 8)) {
 171                                 die("the editor exited uncleanly, aborting everything");
 172                         }
 173                 } @_;
 174         } else {
 175                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 176                 if (($? & 127) || ($? >> 8)) {
 177                         die("the editor exited uncleanly, aborting everything");
 178                 }
 179         }
 180 }
 181
 182 # Variables with corresponding config settings
 183 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 184 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 185 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 186 my ($validate, $confirm);
 187 my (@suppress_cc);
 188
 189 my %config_bool_settings = (
 190     "thread" => [\$thread, 1],
 191     "chainreplyto" => [\$chain_reply_to, 1],
 192     "suppressfrom" => [\$suppress_from, undef],
 193     "signedoffbycc" => [\$signed_off_by_cc, undef],
 194     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 195     "validate" => [\$validate, 1],
 196 );
 197
 198 my %config_settings = (
 199     "smtpserver" => \$smtp_server,
 200     "smtpserverport" => \$smtp_server_port,
 201     "smtpuser" => \$smtp_authuser,
 202     "smtppass" => \$smtp_authpass,
 203     "to" => \@to,
 204     "cc" => \@initial_cc,
 205     "cccmd" => \$cc_cmd,
 206     "aliasfiletype" => \$aliasfiletype,
 207     "bcc" => \@bcclist,
 208     "aliasesfile" => \@alias_files,
 209     "suppresscc" => \@suppress_cc,
 210     "envelopesender" => \$envelope_sender,
 211     "multiedit" => \$multiedit,
 212     "confirm"   => \$confirm,
 213     "from" => \$sender,
 214 );
 215
 216 # Handle Uncouth Termination
 217 sub signal_handler {
 218
 219         # Make text normal
 220         print color("reset"), "\n";
 221
 222         # SMTP password masked
 223         system "stty echo";
 224
 225         # tmp files from --compose
 226         if (defined $compose_filename) {
 227                 if (-e $compose_filename) {
 228                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 229                 }
 230                 if (-e ($compose_filename . ".final")) {
 231                         print "'$compose_filename.final' contains the composed email.\n"
 232                 }
 233         }
 234
 235         exit;
 236 };
 237
 238 $SIG{TERM} = \&signal_handler;
 239 $SIG{INT}  = \&signal_handler;
 240
 241 # Begin by accumulating all the variables (defined above), that we will end up
 242 # needing, first, from the command line:
 243
 244 my $rc = GetOptions("sender|from=s" => \$sender,
 245                     "in-reply-to=s" => \$initial_reply_to,
 246                     "subject=s" => \$initial_subject,
 247                     "to=s" => \@to,
 248                     "cc=s" => \@initial_cc,
 249                     "bcc=s" => \@bcclist,
 250                     "chain-reply-to!" => \$chain_reply_to,
 251                     "smtp-server=s" => \$smtp_server,
 252                     "smtp-server-port=s" => \$smtp_server_port,
 253                     "smtp-user=s" => \$smtp_authuser,
 254                     "smtp-pass:s" => \$smtp_authpass,
 255                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 256                     "smtp-encryption=s" => \$smtp_encryption,
 257                     "identity=s" => \$identity,
 258                     "annotate" => \$annotate,
 259                     "compose" => \$compose,
 260                     "quiet" => \$quiet,
 261                     "cc-cmd=s" => \$cc_cmd,
 262                     "suppress-from!" => \$suppress_from,
 263                     "suppress-cc=s" => \@suppress_cc,
 264                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 265                     "confirm=s" => \$confirm,
 266                     "dry-run" => \$dry_run,
 267                     "envelope-sender=s" => \$envelope_sender,
 268                     "thread!" => \$thread,
 269                     "validate!" => \$validate,
 270                     "format-patch!" => \$format_patch,
 271          );
 272
 273 unless ($rc) {
 274     usage();
 275 }
 276
 277 die "Cannot run git format-patch from outside a repository\n"
 278         if $format_patch and not $repo;
 279
 280 # Now, let's fill any that aren't set in with defaults:
 281
 282 sub read_config {
 283         my ($prefix) = @_;
 284
 285         foreach my $setting (keys %config_bool_settings) {
 286                 my $target = $config_bool_settings{$setting}->[0];
 287                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 288         }
 289
 290         foreach my $setting (keys %config_settings) {
 291                 my $target = $config_settings{$setting};
 292                 if (ref($target) eq "ARRAY") {
 293                         unless (@$target) {
 294                                 my @values = Git::config(@repo, "$prefix.$setting");
 295                                 @$target = @values if (@values && defined $values[0]);
 296                         }
 297                 }
 298                 else {
 299                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 300                 }
 301         }
 302
 303         if (!defined $smtp_encryption) {
 304                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 305                 if (defined $enc) {
 306                         $smtp_encryption = $enc;
 307                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 308                         $smtp_encryption = 'ssl';
 309                 }
 310         }
 311 }
 312
 313 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 314 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 315 read_config("sendemail.$identity") if (defined $identity);
 316 read_config("sendemail");
 317
 318 # fall back on builtin bool defaults
 319 foreach my $setting (values %config_bool_settings) {
 320         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 321 }
 322
 323 # 'default' encryption is none -- this only prevents a warning
 324 $smtp_encryption = '' unless (defined $smtp_encryption);
 325
 326 # Set CC suppressions
 327 my(%suppress_cc);
 328 if (@suppress_cc) {
 329         foreach my $entry (@suppress_cc) {
 330                 die "Unknown --suppress-cc field: '$entry'\n"
 331                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 332                 $suppress_cc{$entry} = 1;
 333         }
 334 }
 335
 336 if ($suppress_cc{'all'}) {
 337         foreach my $entry (qw (ccmd cc author self sob body bodycc)) {
 338                 $suppress_cc{$entry} = 1;
 339         }
 340         delete $suppress_cc{'all'};
 341 }
 342
 343 # If explicit old-style ones are specified, they trump --suppress-cc.
 344 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 345 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 346
 347 if ($suppress_cc{'body'}) {
 348         foreach my $entry (qw (sob bodycc)) {
 349                 $suppress_cc{$entry} = 1;
 350         }
 351         delete $suppress_cc{'body'};
 352 }
 353
 354 # Set confirm's default value
 355 my $confirm_unconfigured = !defined $confirm;
 356 if ($confirm_unconfigured) {
 357         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 358 };
 359 die "Unknown --confirm setting: '$confirm'\n"
 360         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 361
 362 # Debugging, print out the suppressions.
 363 if (0) {
 364         print "suppressions:\n";
 365         foreach my $entry (keys %suppress_cc) {
 366                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 367         }
 368 }
 369
 370 my ($repoauthor, $repocommitter);
 371 ($repoauthor) = Git::ident_person(@repo, 'author');
 372 ($repocommitter) = Git::ident_person(@repo, 'committer');
 373
 374 # Verify the user input
 375
 376 foreach my $entry (@to) {
 377         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 378 }
 379
 380 foreach my $entry (@initial_cc) {
 381         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 382 }
 383
 384 foreach my $entry (@bcclist) {
 385         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 386 }
 387
 388 sub parse_address_line {
 389         if ($have_mail_address) {
 390                 return map { $_->format } Mail::Address->parse($_[0]);
 391         } else {
 392                 return split_addrs($_[0]);
 393         }
 394 }
 395
 396 sub split_addrs {
 397         return quotewords('\s*,\s*', 1, @_);
 398 }
 399
 400 my %aliases;
 401 my %parse_alias = (
 402         # multiline formats can be supported in the future
 403         mutt => sub { my $fh = shift; while (<$fh>) {
 404                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 405                         my ($alias, $addr) = ($1, $2);
 406                         $addr =~ s/#.*$//; # mutt allows # comments
 407                          # commas delimit multiple addresses
 408                         $aliases{$alias} = [ split_addrs($addr) ];
 409                 }}},
 410         mailrc => sub { my $fh = shift; while (<$fh>) {
 411                 if (/^alias\s+(\S+)\s+(.*)$/) {
 412                         # spaces delimit multiple addresses
 413                         $aliases{$1} = [ quotewords('\s+', 0, $2) ];
 414                 }}},
 415         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 416                 for (my $x = ''; defined($x); $x = $_) {
 417                         chomp $x;
 418                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 419                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 420                         $aliases{$1} = [ split_addrs($2) ];
 421                 }},
 422         elm => sub  { my $fh = shift;
 423                       while (<$fh>) {
 424                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 425                               my ($alias, $addr) = ($1, $2);
 426                                $aliases{$alias} = [ split_addrs($addr) ];
 427                           }
 428                       } },
 429
 430         gnus => sub { my $fh = shift; while (<$fh>) {
 431                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 432                         $aliases{$1} = [ $2 ];
 433                 }}}
 434 );
 435
 436 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 437         foreach my $file (@alias_files) {
 438                 open my $fh, '<', $file or die "opening $file: $!\n";
 439                 $parse_alias{$aliasfiletype}->($fh);
 440                 close $fh;
 441         }
 442 }
 443
 444 ($sender) = expand_aliases($sender) if defined $sender;
 445
 446 # returns 1 if the conflict must be solved using it as a format-patch argument
 447 sub check_file_rev_conflict($) {
 448         return unless $repo;
 449         my $f = shift;
 450         try {
 451                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 452                 if (defined($format_patch)) {
 453                         print "foo\n";
 454                         return $format_patch;
 455                 }
 456                 die(<<EOF);
 457 File '$f' exists but it could also be the range of commits
 458 to produce patches for.  Please disambiguate by...
 459
 460     * Saying "./$f" if you mean a file; or
 461     * Giving --format-patch option if you mean a range.
 462 EOF
 463         } catch Git::Error::Command with {
 464                 return 0;
 465         }
 466 }
 467
 468 # Now that all the defaults are set, process the rest of the command line
 469 # arguments and collect up the files that need to be processed.
 470 my @rev_list_opts;
 471 while (defined(my $f = shift @ARGV)) {
 472         if ($f eq "--") {
 473                 push @rev_list_opts, "--", @ARGV;
 474                 @ARGV = ();
 475         } elsif (-d $f and !check_file_rev_conflict($f)) {
 476                 opendir(DH,$f)
 477                         or die "Failed to opendir $f: $!";
 478
 479                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 480                                 sort readdir(DH);
 481                 closedir(DH);
 482         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 483                 push @files, $f;
 484         } else {
 485                 push @rev_list_opts, $f;
 486         }
 487 }
 488
 489 if (@rev_list_opts) {
 490         die "Cannot run git format-patch from outside a repository\n"
 491                 unless $repo;
 492         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 493 }
 494
 495 if ($validate) {
 496         foreach my $f (@files) {
 497                 unless (-p $f) {
 498                         my $error = validate_patch($f);
 499                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 500                 }
 501         }
 502 }
 503
 504 if (@files) {
 505         unless ($quiet) {
 506                 print $_,"\n" for (@files);
 507         }
 508 } else {
 509         print STDERR "\nNo patch files specified!\n\n";
 510         usage();
 511 }
 512
 513 sub get_patch_subject($) {
 514         my $fn = shift;
 515         open (my $fh, '<', $fn);
 516         while (my $line = <$fh>) {
 517                 next unless ($line =~ /^Subject: (.*)$/);
 518                 close $fh;
 519                 return "GIT: $1\n";
 520         }
 521         close $fh;
 522         die "No subject line in $fn ?";
 523 }
 524
 525 if ($compose) {
 526         # Note that this does not need to be secure, but we will make a small
 527         # effort to have it be unique
 528         $compose_filename = ($repo ?
 529                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 530                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 531         open(C,">",$compose_filename)
 532                 or die "Failed to open for writing $compose_filename: $!";
 533
 534
 535         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 536         my $tpl_subject = $initial_subject || '';
 537         my $tpl_reply_to = $initial_reply_to || '';
 538
 539         print C <<EOT;
 540 From $tpl_sender # This line is ignored.
 541 GIT: Lines beginning in "GIT: " will be removed.
 542 GIT: Consider including an overall diffstat or table of contents
 543 GIT: for the patch you are writing.
 544 GIT:
 545 GIT: Clear the body content if you don't wish to send a summary.
 546 From: $tpl_sender
 547 Subject: $tpl_subject
 548 In-Reply-To: $tpl_reply_to
 549
 550 EOT
 551         for my $f (@files) {
 552                 print C get_patch_subject($f);
 553         }
 554         close(C);
 555
 556         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 557
 558         if ($annotate) {
 559                 do_edit($compose_filename, @files);
 560         } else {
 561                 do_edit($compose_filename);
 562         }
 563
 564         open(C2,">",$compose_filename . ".final")
 565                 or die "Failed to open $compose_filename.final : " . $!;
 566
 567         open(C,"<",$compose_filename)
 568                 or die "Failed to open $compose_filename : " . $!;
 569
 570         my $need_8bit_cte = file_has_nonascii($compose_filename);
 571         my $in_body = 0;
 572         my $summary_empty = 1;
 573         while(<C>) {
 574                 next if m/^GIT: /;
 575                 if ($in_body) {
 576                         $summary_empty = 0 unless (/^\n$/);
 577                 } elsif (/^\n$/) {
 578                         $in_body = 1;
 579                         if ($need_8bit_cte) {
 580                                 print C2 "MIME-Version: 1.0\n",
 581                                          "Content-Type: text/plain; ",
 582                                            "charset=utf-8\n",
 583                                          "Content-Transfer-Encoding: 8bit\n";
 584                         }
 585                 } elsif (/^MIME-Version:/i) {
 586                         $need_8bit_cte = 0;
 587                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 588                         $initial_subject = $1;
 589                         my $subject = $initial_subject;
 590                         $_ = "Subject: " .
 591                                 ($subject =~ /[^[:ascii:]]/ ?
 592                                  quote_rfc2047($subject) :
 593                                  $subject) .
 594                                 "\n";
 595                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 596                         $initial_reply_to = $1;
 597                         next;
 598                 } elsif (/^From:\s*(.+)\s*$/i) {
 599                         $sender = $1;
 600                         next;
 601                 } elsif (/^(?:To|Cc|Bcc):/i) {
 602                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 603                         next;
 604                 }
 605                 print C2 $_;
 606         }
 607         close(C);
 608         close(C2);
 609
 610         if ($summary_empty) {
 611                 print "Summary email is empty, skipping it\n";
 612                 $compose = -1;
 613         }
 614 } elsif ($annotate) {
 615         do_edit(@files);
 616 }
 617
 618 sub ask {
 619         my ($prompt, %arg) = @_;
 620         my $valid_re = $arg{valid_re};
 621         my $default = $arg{default};
 622         my $resp;
 623         my $i = 0;
 624         return defined $default ? $default : undef
 625                 unless defined $term->IN and defined fileno($term->IN) and
 626                        defined $term->OUT and defined fileno($term->OUT);
 627         while ($i++ < 10) {
 628                 $resp = $term->readline($prompt);
 629                 if (!defined $resp) { # EOF
 630                         print "\n";
 631                         return defined $default ? $default : undef;
 632                 }
 633                 if ($resp eq '' and defined $default) {
 634                         return $default;
 635                 }
 636                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 637                         return $resp;
 638                 }
 639         }
 640         return undef;
 641 }
 642
 643 my $prompting = 0;
 644 if (!defined $sender) {
 645         $sender = $repoauthor || $repocommitter || '';
 646         $sender = ask("Who should the emails appear to be from? [$sender] ",
 647                       default => $sender);
 648         print "Emails will be sent from: ", $sender, "\n";
 649         $prompting++;
 650 }
 651
 652 if (!@to) {
 653         my $to = ask("Who should the emails be sent to? ");
 654         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 655         $prompting++;
 656 }
 657
 658 sub expand_aliases {
 659         my @cur = @_;
 660         my @last;
 661         do {
 662                 @last = @cur;
 663                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 664         } while (join(',',@cur) ne join(',',@last));
 665         return @cur;
 666 }
 667
 668 @to = expand_aliases(@to);
 669 @to = (map { sanitize_address($_) } @to);
 670 @initial_cc = expand_aliases(@initial_cc);
 671 @bcclist = expand_aliases(@bcclist);
 672
 673 if ($thread && !defined $initial_reply_to && $prompting) {
 674         $initial_reply_to = ask(
 675                 "Message-ID to be used as In-Reply-To for the first email? ");
 676 }
 677 if (defined $initial_reply_to) {
 678         $initial_reply_to =~ s/^\s*<?//;
 679         $initial_reply_to =~ s/>?\s*$//;
 680         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 681 }
 682
 683 if (!defined $smtp_server) {
 684         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 685                 if (-x $_) {
 686                         $smtp_server = $_;
 687                         last;
 688                 }
 689         }
 690         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 691 }
 692
 693 if ($compose && $compose > 0) {
 694         @files = ($compose_filename . ".final", @files);
 695 }
 696
 697 # Variables we set as part of the loop over files
 698 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 699         $needs_confirm, $message_num, $ask_default);
 700
 701 sub extract_valid_address {
 702         my $address = shift;
 703         my $local_part_regexp = '[^<>"\s@]+';
 704         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 705
 706         # check for a local address:
 707         return $address if ($address =~ /^($local_part_regexp)$/);
 708
 709         $address =~ s/^\s*<(.*)>\s*$/$1/;
 710         if ($have_email_valid) {
 711                 return scalar Email::Valid->address($address);
 712         } else {
 713                 # less robust/correct than the monster regexp in Email::Valid,
 714                 # but still does a 99% job, and one less dependency
 715                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 716                 return $1;
 717         }
 718 }
 719
 720 # Usually don't need to change anything below here.
 721
 722 # we make a "fake" message id by taking the current number
 723 # of seconds since the beginning of Unix time and tacking on
 724 # a random number to the end, in case we are called quicker than
 725 # 1 second since the last time we were called.
 726
 727 # We'll setup a template for the message id, using the "from" address:
 728
 729 my ($message_id_stamp, $message_id_serial);
 730 sub make_message_id
 731 {
 732         my $uniq;
 733         if (!defined $message_id_stamp) {
 734                 $message_id_stamp = sprintf("%s-%s", time, $$);
 735                 $message_id_serial = 0;
 736         }
 737         $message_id_serial++;
 738         $uniq = "$message_id_stamp-$message_id_serial";
 739
 740         my $du_part;
 741         for ($sender, $repocommitter, $repoauthor) {
 742                 $du_part = extract_valid_address(sanitize_address($_));
 743                 last if (defined $du_part and $du_part ne '');
 744         }
 745         if (not defined $du_part or $du_part eq '') {
 746                 use Sys::Hostname qw();
 747                 $du_part = 'user@' . Sys::Hostname::hostname();
 748         }
 749         my $message_id_template = "<%s-git-send-email-%s>";
 750         $message_id = sprintf($message_id_template, $uniq, $du_part);
 751         #print "new message id = $message_id\n"; # Was useful for debugging
 752 }
 753
 754
 755
 756 $time = time - scalar $#files;
 757
 758 sub unquote_rfc2047 {
 759         local ($_) = @_;
 760         my $encoding;
 761         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 762                 $encoding = $1;
 763                 s/_/ /g;
 764                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 765         }
 766         return wantarray ? ($_, $encoding) : $_;
 767 }
 768
 769 sub quote_rfc2047 {
 770         local $_ = shift;
 771         my $encoding = shift || 'utf-8';
 772         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 773         s/(.*)/=\?$encoding\?q\?$1\?=/;
 774         return $_;
 775 }
 776
 777 # use the simplest quoting being able to handle the recipient
 778 sub sanitize_address
 779 {
 780         my ($recipient) = @_;
 781         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 782
 783         if (not $recipient_name) {
 784                 return "$recipient";
 785         }
 786
 787         # if recipient_name is already quoted, do nothing
 788         if ($recipient_name =~ /^("[[:ascii:]]*"|=\?utf-8\?q\?.*\?=)$/) {
 789                 return $recipient;
 790         }
 791
 792         # rfc2047 is needed if a non-ascii char is included
 793         if ($recipient_name =~ /[^[:ascii:]]/) {
 794                 $recipient_name =~ s/^"(.*)"$/$1/;
 795                 $recipient_name = quote_rfc2047($recipient_name);
 796         }
 797
 798         # double quotes are needed if specials or CTLs are included
 799         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 800                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 801                 $recipient_name = "\"$recipient_name\"";
 802         }
 803
 804         return "$recipient_name $recipient_addr";
 805
 806 }
 807
 808 sub send_message
 809 {
 810         my @recipients = unique_email_list(@to);
 811         @cc = (grep { my $cc = extract_valid_address($_);
 812                       not grep { $cc eq $_ } @recipients
 813                     }
 814                map { sanitize_address($_) }
 815                @cc);
 816         my $to = join (",\n\t", @recipients);
 817         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 818         @recipients = (map { extract_valid_address($_) } @recipients);
 819         my $date = format_2822_time($time++);
 820         my $gitversion = '@@GIT_VERSION@@';
 821         if ($gitversion =~ m/..GIT_VERSION../) {
 822             $gitversion = Git::version();
 823         }
 824
 825         my $cc = join(", ", unique_email_list(@cc));
 826         my $ccline = "";
 827         if ($cc ne '') {
 828                 $ccline = "\nCc: $cc";
 829         }
 830         my $sanitized_sender = sanitize_address($sender);
 831         make_message_id() unless defined($message_id);
 832
 833         my $header = "From: $sanitized_sender
 834 To: $to${ccline}
 835 Subject: $subject
 836 Date: $date
 837 Message-Id: $message_id
 838 X-Mailer: git-send-email $gitversion
 839 ";
 840         if ($reply_to) {
 841
 842                 $header .= "In-Reply-To: $reply_to\n";
 843                 $header .= "References: $references\n";
 844         }
 845         if (@xh) {
 846                 $header .= join("\n", @xh) . "\n";
 847         }
 848
 849         my @sendmail_parameters = ('-i', @recipients);
 850         my $raw_from = $sanitized_sender;
 851         $raw_from = $envelope_sender if (defined $envelope_sender);
 852         $raw_from = extract_valid_address($raw_from);
 853         unshift (@sendmail_parameters,
 854                         '-f', $raw_from) if(defined $envelope_sender);
 855
 856         if ($needs_confirm && !$dry_run) {
 857                 print "\n$header\n";
 858                 if ($needs_confirm eq "inform") {
 859                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 860                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 861                         print "    The Cc list above has been expanded by additional\n";
 862                         print "    addresses found in the patch commit message. By default\n";
 863                         print "    send-email prompts before sending whenever this occurs.\n";
 864                         print "    This behavior is controlled by the sendemail.confirm\n";
 865                         print "    configuration setting.\n";
 866                         print "\n";
 867                         print "    For additional information, run 'git send-email --help'.\n";
 868                         print "    To retain the current behavior, but squelch this message,\n";
 869                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 870                 }
 871                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 872                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 873                          default => $ask_default);
 874                 die "Send this email reply required" unless defined $_;
 875                 if (/^n/i) {
 876                         return;
 877                 } elsif (/^q/i) {
 878                         cleanup_compose_files();
 879                         exit(0);
 880                 } elsif (/^a/i) {
 881                         $confirm = 'never';
 882                 }
 883         }
 884
 885         if ($dry_run) {
 886                 # We don't want to send the email.
 887         } elsif ($smtp_server =~ m#^/#) {
 888                 my $pid = open my $sm, '|-';
 889                 defined $pid or die $!;
 890                 if (!$pid) {
 891                         exec($smtp_server, @sendmail_parameters) or die $!;
 892                 }
 893                 print $sm "$header\n$message";
 894                 close $sm or die $?;
 895         } else {
 896
 897                 if (!defined $smtp_server) {
 898                         die "The required SMTP server is not properly defined."
 899                 }
 900
 901                 if ($smtp_encryption eq 'ssl') {
 902                         $smtp_server_port ||= 465; # ssmtp
 903                         require Net::SMTP::SSL;
 904                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 905                 }
 906                 else {
 907                         require Net::SMTP;
 908                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 909                                                  ? "$smtp_server:$smtp_server_port"
 910                                                  : $smtp_server);
 911                         if ($smtp_encryption eq 'tls') {
 912                                 require Net::SMTP::SSL;
 913                                 $smtp->command('STARTTLS');
 914                                 $smtp->response();
 915                                 if ($smtp->code == 220) {
 916                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 917                                                 or die "STARTTLS failed! ".$smtp->message;
 918                                         $smtp_encryption = '';
 919                                         # Send EHLO again to receive fresh
 920                                         # supported commands
 921                                         $smtp->hello();
 922                                 } else {
 923                                         die "Server does not support STARTTLS! ".$smtp->message;
 924                                 }
 925                         }
 926                 }
 927
 928                 if (!$smtp) {
 929                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 930                 }
 931
 932                 if (defined $smtp_authuser) {
 933
 934                         if (!defined $smtp_authpass) {
 935
 936                                 system "stty -echo";
 937
 938                                 do {
 939                                         print "Password: ";
 940                                         $_ = <STDIN>;
 941                                         print "\n";
 942                                 } while (!defined $_);
 943
 944                                 chomp($smtp_authpass = $_);
 945
 946                                 system "stty echo";
 947                         }
 948
 949                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 950                 }
 951
 952                 $smtp->mail( $raw_from ) or die $smtp->message;
 953                 $smtp->to( @recipients ) or die $smtp->message;
 954                 $smtp->data or die $smtp->message;
 955                 $smtp->datasend("$header\n$message") or die $smtp->message;
 956                 $smtp->dataend() or die $smtp->message;
 957                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 958         }
 959         if ($quiet) {
 960                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 961         } else {
 962                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 963                 if ($smtp_server !~ m#^/#) {
 964                         print "Server: $smtp_server\n";
 965                         print "MAIL FROM:<$raw_from>\n";
 966                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 967                 } else {
 968                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 969                 }
 970                 print $header, "\n";
 971                 if ($smtp) {
 972                         print "Result: ", $smtp->code, ' ',
 973                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 974                 } else {
 975                         print "Result: OK\n";
 976                 }
 977         }
 978 }
 979
 980 $reply_to = $initial_reply_to;
 981 $references = $initial_reply_to || '';
 982 $subject = $initial_subject;
 983 $message_num = 0;
 984
 985 foreach my $t (@files) {
 986         open(F,"<",$t) or die "can't open file $t";
 987
 988         my $author = undef;
 989         my $author_encoding;
 990         my $has_content_type;
 991         my $body_encoding;
 992         @cc = ();
 993         @xh = ();
 994         my $input_format = undef;
 995         my @header = ();
 996         $message = "";
 997         $message_num++;
 998         # First unfold multiline header fields
 999         while(<F>) {
1000                 last if /^\s*$/;
1001                 if (/^\s+\S/ and @header) {
1002                         chomp($header[$#header]);
1003                         s/^\s+/ /;
1004                         $header[$#header] .= $_;
1005             } else {
1006                         push(@header, $_);
1007                 }
1008         }
1009         # Now parse the header
1010         foreach(@header) {
1011                 if (/^From /) {
1012                         $input_format = 'mbox';
1013                         next;
1014                 }
1015                 chomp;
1016                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1017                         $input_format = 'mbox';
1018                 }
1019
1020                 if (defined $input_format && $input_format eq 'mbox') {
1021                         if (/^Subject:\s+(.*)$/) {
1022                                 $subject = $1;
1023                         }
1024                         elsif (/^From:\s+(.*)$/) {
1025                                 ($author, $author_encoding) = unquote_rfc2047($1);
1026                                 next if $suppress_cc{'author'};
1027                                 next if $suppress_cc{'self'} and $author eq $sender;
1028                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1029                                         $1, $_) unless $quiet;
1030                                 push @cc, $1;
1031                         }
1032                         elsif (/^Cc:\s+(.*)$/) {
1033                                 foreach my $addr (parse_address_line($1)) {
1034                                         if (unquote_rfc2047($addr) eq $sender) {
1035                                                 next if ($suppress_cc{'self'});
1036                                         } else {
1037                                                 next if ($suppress_cc{'cc'});
1038                                         }
1039                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1040                                                 $addr, $_) unless $quiet;
1041                                         push @cc, $addr;
1042                                 }
1043                         }
1044                         elsif (/^Content-type:/i) {
1045                                 $has_content_type = 1;
1046                                 if (/charset="?([^ "]+)/) {
1047                                         $body_encoding = $1;
1048                                 }
1049                                 push @xh, $_;
1050                         }
1051                         elsif (/^Message-Id: (.*)/i) {
1052                                 $message_id = $1;
1053                         }
1054                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1055                                 push @xh, $_;
1056                         }
1057
1058                 } else {
1059                         # In the traditional
1060                         # "send lots of email" format,
1061                         # line 1 = cc
1062                         # line 2 = subject
1063                         # So let's support that, too.
1064                         $input_format = 'lots';
1065                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1066                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1067                                         $_, $_) unless $quiet;
1068                                 push @cc, $_;
1069                         } elsif (!defined $subject) {
1070                                 $subject = $_;
1071                         }
1072                 }
1073         }
1074         # Now parse the message body
1075         while(<F>) {
1076                 $message .=  $_;
1077                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1078                         chomp;
1079                         my ($what, $c) = ($1, $2);
1080                         chomp $c;
1081                         if ($c eq $sender) {
1082                                 next if ($suppress_cc{'self'});
1083                         } else {
1084                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1085                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1086                         }
1087                         push @cc, $c;
1088                         printf("(body) Adding cc: %s from line '%s'\n",
1089                                 $c, $_) unless $quiet;
1090                 }
1091         }
1092         close F;
1093
1094         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1095                 open(F, "$cc_cmd $t |")
1096                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1097                 while(<F>) {
1098                         my $c = $_;
1099                         $c =~ s/^\s*//g;
1100                         $c =~ s/\n$//g;
1101                         next if ($c eq $sender and $suppress_from);
1102                         push @cc, $c;
1103                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1104                                 $c, $cc_cmd) unless $quiet;
1105                 }
1106                 close F
1107                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1108         }
1109
1110         if (defined $author and $author ne $sender) {
1111                 $message = "From: $author\n\n$message";
1112                 if (defined $author_encoding) {
1113                         if ($has_content_type) {
1114                                 if ($body_encoding eq $author_encoding) {
1115                                         # ok, we already have the right encoding
1116                                 }
1117                                 else {
1118                                         # uh oh, we should re-encode
1119                                 }
1120                         }
1121                         else {
1122                                 push @xh,
1123                                   'MIME-Version: 1.0',
1124                                   "Content-Type: text/plain; charset=$author_encoding",
1125                                   'Content-Transfer-Encoding: 8bit';
1126                         }
1127                 }
1128         }
1129
1130         $needs_confirm = (
1131                 $confirm eq "always" or
1132                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1133                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1134         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1135
1136         @cc = (@initial_cc, @cc);
1137
1138         send_message();
1139
1140         # set up for the next message
1141         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
1142                 $reply_to = $message_id;
1143                 if (length $references > 0) {
1144                         $references .= "\n $message_id";
1145                 } else {
1146                         $references = "$message_id";
1147                 }
1148         }
1149         $message_id = undef;
1150 }
1151
1152 cleanup_compose_files();
1153
1154 sub cleanup_compose_files() {
1155         unlink($compose_filename, $compose_filename . ".final") if $compose;
1156 }
1157
1158 $smtp->quit if $smtp;
1159
1160 sub unique_email_list(@) {
1161         my %seen;
1162         my @emails;
1163
1164         foreach my $entry (@_) {
1165                 if (my $clean = extract_valid_address($entry)) {
1166                         $seen{$clean} ||= 0;
1167                         next if $seen{$clean}++;
1168                         push @emails, $entry;
1169                 } else {
1170                         print STDERR "W: unable to extract a valid address",
1171                                         " from: $entry\n";
1172                 }
1173         }
1174         return @emails;
1175 }
1176
1177 sub validate_patch {
1178         my $fn = shift;
1179         open(my $fh, '<', $fn)
1180                 or die "unable to open $fn: $!\n";
1181         while (my $line = <$fh>) {
1182                 if (length($line) > 998) {
1183                         return "$.: patch contains a line longer than 998 characters";
1184                 }
1185         }
1186         return undef;
1187 }
1188
1189 sub file_has_nonascii {
1190         my $fn = shift;
1191         open(my $fh, '<', $fn)
1192                 or die "unable to open $fn: $!\n";
1193         while (my $line = <$fh>) {
1194                 return 1 if $line =~ /[^[:ascii:]]/;
1195         }
1196         return 0;
1197 }