configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 m4_toupper($1)_PATH=$withval; \
  46                 AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  47                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  48         fi; \
  49 fi; \
  50 ]) # GIT_CONF_APPEND_PATH
  51 #
  52 # GIT_PARSE_WITH(PACKAGE)
  53 # -----------------------
  54 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  55 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  56 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  57 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  58 AC_DEFUN([GIT_PARSE_WITH],
  59 [PACKAGE=m4_toupper($1); \
  60 if test "$withval" = "no"; then \
  61         m4_toupper(NO_$1)=YesPlease; \
  62 elif test "$withval" = "yes"; then \
  63         m4_toupper(NO_$1)=; \
  64 else \
  65         m4_toupper(NO_$1)=; \
  66         m4_toupper($1)DIR=$withval; \
  67         AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  68         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  69 fi \
  70 ])# GIT_PARSE_WITH
  71
  72 dnl
  73 dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
  74 dnl -----------------------------------------
  75 dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
  76 dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
  77 dnl -Wall), it does not work.  By looking for function definition in
  78 dnl libraries, this problem can be worked around.
  79 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
  80   AC_SEARCH_LIBS([$1],,
  81   [$2],[$3])
  82 ],[$3])])
  83
  84 dnl
  85 dnl GIT_STASH_FLAGS(BASEPATH_VAR)
  86 dnl -----------------------------
  87 dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
  88 dnl tests that may want to take user settings into account.
  89 AC_DEFUN([GIT_STASH_FLAGS],[
  90 if test -n "$1"; then
  91    old_CPPFLAGS="$CPPFLAGS"
  92    old_LDFLAGS="$LDFLAGS"
  93    CPPFLAGS="-I$1/include $CPPFLAGS"
  94    LDFLAGS="-L$1/$lib $LDFLAGS"
  95 fi
  96 ])
  97
  98 dnl
  99 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 100 dnl -----------------------------
 101 dnl Restore the stashed *FLAGS values.
 102 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 103 if test -n "$1"; then
 104    CPPFLAGS="$old_CPPFLAGS"
 105    LDFLAGS="$old_LDFLAGS"
 106 fi
 107 ])
 108
 109 ## Site configuration related to programs (before tests)
 110 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 111 #
 112 # Set lib to alternative name of lib directory (e.g. lib64)
 113 AC_ARG_WITH([lib],
 114  [AS_HELP_STRING([--with-lib=ARG],
 115                  [ARG specifies alternative name for lib directory])],
 116  [if test "$withval" = "no" || test "$withval" = "yes"; then \
 117         AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 118 else \
 119         lib=$withval; \
 120         AC_MSG_NOTICE([Setting lib to '$lib']); \
 121         GIT_CONF_APPEND_LINE(lib=$withval); \
 122 fi; \
 123 ],[])
 124
 125 if test -z "$lib"; then
 126    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 127    lib=lib
 128 fi
 129
 130 AC_ARG_ENABLE([pthreads],
 131  [AS_HELP_STRING([--enable-pthreads=FLAGS],
 132   [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
 133   [The default if FLAGS is not specified is to try first -pthread]
 134   [and then -lpthread.]
 135   [--without-pthreads will disable threading.])],
 136 [
 137 if test "x$enableval" = "xyes"; then
 138    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
 139 elif test "x$enableval" != "xno"; then
 140    PTHREAD_CFLAGS=$enableval
 141    AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
 142 else
 143    AC_MSG_NOTICE([POSIX Threads will be disabled.])
 144    NO_PTHREADS=YesPlease
 145    USER_NOPTHREAD=1
 146 fi],
 147 [
 148    AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
 149 ])
 150
 151 ## Site configuration (override autodetection)
 152 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 153 AC_MSG_NOTICE([CHECKS for site configuration])
 154 #
 155 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 156 # tests.  These tests take up a significant amount of the total test time
 157 # but are not needed unless you plan to talk to SVN repos.
 158 #
 159 # Define MOZILLA_SHA1 environment variable when running make to make use of
 160 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 161 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 162 # choice) has very fast version optimized for i586.
 163 #
 164 # Define PPC_SHA1 environment variable when running make to make use of
 165 # a bundled SHA1 routine optimized for PowerPC.
 166 #
 167 # Define ARM_SHA1 environment variable when running make to make use of
 168 # a bundled SHA1 routine optimized for ARM.
 169 #
 170 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 171 # This also implies MOZILLA_SHA1.
 172 #
 173 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 174 # /foo/bar/include and /foo/bar/lib directories.
 175 AC_ARG_WITH(openssl,
 176 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 177 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 178 GIT_PARSE_WITH(openssl))
 179 #
 180 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 181 # git-http-push are not built, and you cannot use http:// and https://
 182 # transports.
 183 #
 184 # Define CURLDIR=/foo/bar if your curl header and library files are in
 185 # /foo/bar/include and /foo/bar/lib directories.
 186 AC_ARG_WITH(curl,
 187 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 188 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 189 GIT_PARSE_WITH(curl))
 190 #
 191 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 192 # not built, and you cannot push using http:// and https:// transports.
 193 #
 194 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 195 # /foo/bar/include and /foo/bar/lib directories.
 196 AC_ARG_WITH(expat,
 197 AS_HELP_STRING([--with-expat],
 198 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 199 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 200 GIT_PARSE_WITH(expat))
 201 #
 202 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 203 # installed in /sw, but don't want GIT to link against any libraries
 204 # installed there.  If defined you may specify your own (or Fink's)
 205 # include directories and library directories by defining CFLAGS
 206 # and LDFLAGS appropriately.
 207 #
 208 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 209 # have DarwinPorts installed in /opt/local, but don't want GIT to
 210 # link against any libraries installed there.  If defined you may
 211 # specify your own (or DarwinPort's) include directories and
 212 # library directories by defining CFLAGS and LDFLAGS appropriately.
 213 #
 214 # Define NO_MMAP if you want to avoid mmap.
 215 #
 216 # Define NO_ICONV if your libc does not properly support iconv.
 217 AC_ARG_WITH(iconv,
 218 AS_HELP_STRING([--without-iconv],
 219 [if your architecture doesn't properly support iconv])
 220 AS_HELP_STRING([--with-iconv=PATH],
 221 [PATH is prefix for libiconv library and headers])
 222 AS_HELP_STRING([],
 223 [used only if you need linking with libiconv]),
 224 GIT_PARSE_WITH(iconv))
 225
 226 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 227 #
 228 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 229 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 230 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 231 # randomly break unless your underlying filesystem supports those sub-second
 232 # times (my ext3 doesn't).
 233 #
 234 # Define USE_STDEV below if you want git to care about the underlying device
 235 # change being considered an inode change from the update-index perspective.
 236
 237 #
 238 # Define SHELL_PATH to provide path to shell.
 239 GIT_ARG_SET_PATH(shell)
 240 #
 241 # Define PERL_PATH to provide path to Perl.
 242 GIT_ARG_SET_PATH(perl)
 243 #
 244 # Define ZLIB_PATH to provide path to zlib.
 245 GIT_ARG_SET_PATH(zlib)
 246 #
 247 # Declare the with-tcltk/without-tcltk options.
 248 AC_ARG_WITH(tcltk,
 249 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 250 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 251 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 252 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 253 GIT_PARSE_WITH(tcltk))
 254 #
 255
 256
 257 ## Checks for programs.
 258 AC_MSG_NOTICE([CHECKS for programs])
 259 #
 260 AC_PROG_CC([cc gcc])
 261 # which switch to pass runtime path to dynamic libraries to the linker
 262 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 263    SAVE_LDFLAGS="${LDFLAGS}"
 264    LDFLAGS="${SAVE_LDFLAGS} -R /"
 265    AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 266    LDFLAGS="${SAVE_LDFLAGS}"
 267 ])
 268 if test "$git_cv_ld_dashr" = "yes"; then
 269    AC_SUBST(CC_LD_DYNPATH, [-R])
 270 else
 271    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 272       SAVE_LDFLAGS="${LDFLAGS}"
 273       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 274       AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 275       LDFLAGS="${SAVE_LDFLAGS}"
 276    ])
 277    if test "$git_cv_ld_wl_rpath" = "yes"; then
 278       AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 279    else
 280       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 281          SAVE_LDFLAGS="${LDFLAGS}"
 282          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 283          AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 284          LDFLAGS="${SAVE_LDFLAGS}"
 285       ])
 286       if test "$git_cv_ld_rpath" = "yes"; then
 287          AC_SUBST(CC_LD_DYNPATH, [-rpath])
 288       else
 289          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 290       fi
 291    fi
 292 fi
 293 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 294 AC_CHECK_TOOLS(AR, [gar ar], :)
 295 AC_CHECK_PROGS(TAR, [gtar tar])
 296 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 297 # or will be empty otherwise.
 298 if test -z "$NO_TCLTK"; then
 299   if test "$with_tcltk" = ""; then
 300   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 301     TCLTK_PATH=wish
 302     AC_SUBST(TCLTK_PATH)
 303   elif test "$with_tcltk" = "yes"; then
 304   # Tcl/Tk check requested.
 305     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 306   else
 307     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 308     TCLTK_PATH="$with_tcltk"
 309     AC_SUBST(TCLTK_PATH)
 310   fi
 311 fi
 312 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 313 if test -n "$ASCIIDOC"; then
 314         AC_MSG_CHECKING([for asciidoc version])
 315         asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
 316         case "${asciidoc_version}" in
 317         asciidoc' '8*)
 318                 ASCIIDOC8=YesPlease
 319                 AC_MSG_RESULT([${asciidoc_version} > 7])
 320                 ;;
 321         asciidoc' '7*)
 322                 ASCIIDOC8=
 323                 AC_MSG_RESULT([${asciidoc_version}])
 324                 ;;
 325         *)
 326                 ASCIIDOC8=
 327                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 328                 ;;
 329         esac
 330 fi
 331 AC_SUBST(ASCIIDOC8)
 332
 333
 334 ## Checks for libraries.
 335 AC_MSG_NOTICE([CHECKS for libraries])
 336 #
 337 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 338 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 339
 340 GIT_STASH_FLAGS($OPENSSLDIR)
 341
 342 AC_CHECK_LIB([crypto], [SHA1_Init],
 343 [NEEDS_SSL_WITH_CRYPTO=],
 344 [AC_CHECK_LIB([ssl], [SHA1_Init],
 345  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 346   NEEDS_SSL_WITH_CRYPTO=],
 347  [NO_OPENSSL=YesPlease])])
 348
 349 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 350
 351 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 352 AC_SUBST(NO_OPENSSL)
 353
 354 #
 355 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 356 # git-http-push are not built, and you cannot use http:// and https://
 357 # transports.
 358
 359 GIT_STASH_FLAGS($CURLDIR)
 360
 361 AC_CHECK_LIB([curl], [curl_global_init],
 362 [NO_CURL=],
 363 [NO_CURL=YesPlease])
 364
 365 GIT_UNSTASH_FLAGS($CURLDIR)
 366
 367 AC_SUBST(NO_CURL)
 368
 369 #
 370 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 371 # not built, and you cannot push using http:// and https:// transports.
 372
 373 GIT_STASH_FLAGS($EXPATDIR)
 374
 375 AC_CHECK_LIB([expat], [XML_ParserCreate],
 376 [NO_EXPAT=],
 377 [NO_EXPAT=YesPlease])
 378
 379 GIT_UNSTASH_FLAGS($EXPATDIR)
 380
 381 AC_SUBST(NO_EXPAT)
 382
 383 #
 384 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 385 # some Solaris installations).
 386 # Define NO_ICONV if neither libc nor libiconv support iconv.
 387
 388 GIT_STASH_FLAGS($ICONVDIR)
 389
 390 AC_DEFUN([ICONVTEST_SRC], [
 391 #include <iconv.h>
 392
 393 int main(void)
 394 {
 395         iconv_open("", "");
 396         return 0;
 397 }
 398 ])
 399
 400 if test -n "$ICONVDIR"; then
 401    lib_order="-liconv -lc"
 402 else
 403    lib_order="-lc -liconv"
 404 fi
 405
 406 NO_ICONV=YesPlease
 407
 408 for l in $lib_order; do
 409     if test "$l" = "-liconv"; then
 410        NEEDS_LIBICONV=YesPlease
 411     else
 412        NEEDS_LIBICONV=
 413     fi
 414
 415     old_LIBS="$LIBS"
 416     LIBS="$LIBS $l"
 417     AC_MSG_CHECKING([for iconv in $l])
 418     AC_LINK_IFELSE(ICONVTEST_SRC,
 419         [AC_MSG_RESULT([yes])
 420         NO_ICONV=
 421         break],
 422         [AC_MSG_RESULT([no])])
 423     LIBS="$old_LIBS"
 424 done
 425
 426 #in case of break
 427 LIBS="$old_LIBS"
 428
 429 GIT_UNSTASH_FLAGS($ICONVDIR)
 430
 431 AC_SUBST(NEEDS_LIBICONV)
 432 AC_SUBST(NO_ICONV)
 433
 434 #
 435 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 436
 437 GIT_STASH_FLAGS($ZLIB_PATH)
 438
 439 AC_DEFUN([ZLIBTEST_SRC], [
 440 #include <zlib.h>
 441
 442 int main(void)
 443 {
 444         deflateBound(0, 0);
 445         return 0;
 446 }
 447 ])
 448 AC_MSG_CHECKING([for deflateBound in -lz])
 449 old_LIBS="$LIBS"
 450 LIBS="$LIBS -lz"
 451 AC_LINK_IFELSE(ZLIBTEST_SRC,
 452         [AC_MSG_RESULT([yes])],
 453         [AC_MSG_RESULT([no])
 454         NO_DEFLATE_BOUND=yes])
 455 LIBS="$old_LIBS"
 456
 457 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 458
 459 AC_SUBST(NO_DEFLATE_BOUND)
 460
 461 #
 462 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 463 # Patrick Mauritz).
 464 AC_CHECK_LIB([c], [socket],
 465 [NEEDS_SOCKET=],
 466 [NEEDS_SOCKET=YesPlease])
 467 AC_SUBST(NEEDS_SOCKET)
 468 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 469
 470
 471 ## Checks for header files.
 472 AC_MSG_NOTICE([CHECKS for header files])
 473 #
 474 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 475 AC_CHECK_HEADER([sys/select.h],
 476 [NO_SYS_SELECT_H=],
 477 [NO_SYS_SELECT_H=UnfortunatelyYes])
 478 AC_SUBST(NO_SYS_SELECT_H)
 479 #
 480 # Define OLD_ICONV if your library has an old iconv(), where the second
 481 # (input buffer pointer) parameter is declared with type (const char **).
 482 AC_DEFUN([OLDICONVTEST_SRC], [[
 483 #include <iconv.h>
 484
 485 extern size_t iconv(iconv_t cd,
 486                     char **inbuf, size_t *inbytesleft,
 487                     char **outbuf, size_t *outbytesleft);
 488
 489 int main(void)
 490 {
 491         return 0;
 492 }
 493 ]])
 494
 495 GIT_STASH_FLAGS($ICONVDIR)
 496
 497 AC_MSG_CHECKING([for old iconv()])
 498 AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 499         [AC_MSG_RESULT([no])],
 500         [AC_MSG_RESULT([yes])
 501         OLD_ICONV=UnfortunatelyYes])
 502
 503 GIT_UNSTASH_FLAGS($ICONVDIR)
 504
 505 AC_SUBST(OLD_ICONV)
 506
 507 ## Checks for typedefs, structures, and compiler characteristics.
 508 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 509 #
 510 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 511 AC_CHECK_MEMBER(struct dirent.d_ino,
 512 [NO_D_INO_IN_DIRENT=],
 513 [NO_D_INO_IN_DIRENT=YesPlease],
 514 [#include <dirent.h>])
 515 AC_SUBST(NO_D_INO_IN_DIRENT)
 516 #
 517 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 518 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 519 AC_CHECK_MEMBER(struct dirent.d_type,
 520 [NO_D_TYPE_IN_DIRENT=],
 521 [NO_D_TYPE_IN_DIRENT=YesPlease],
 522 [#include <dirent.h>])
 523 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 524 #
 525 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 526 # sockaddr_storage.
 527 AC_CHECK_TYPE(struct sockaddr_storage,
 528 [NO_SOCKADDR_STORAGE=],
 529 [NO_SOCKADDR_STORAGE=YesPlease],[
 530 #include <sys/types.h>
 531 #include <sys/socket.h>
 532 ])
 533 AC_SUBST(NO_SOCKADDR_STORAGE)
 534 #
 535 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 536 AC_CHECK_TYPE([struct addrinfo],[
 537  GIT_CHECK_FUNC([getaddrinfo],
 538   [NO_IPV6=],
 539   [NO_IPV6=YesPlease])
 540 ],[NO_IPV6=YesPlease],[
 541 #include <sys/types.h>
 542 #include <sys/socket.h>
 543 #include <netdb.h>
 544 ])
 545 AC_SUBST(NO_IPV6)
 546 #
 547 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 548 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 549 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 550 # some C compilers supported these specifiers prior to C99 as an extension.
 551 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 552  [ac_cv_c_c99_format],
 553 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 554 AC_RUN_IFELSE(
 555         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 556                 [[char buf[64];
 557                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 558                   return 1;
 559                 else if (strcmp(buf, "12345"))
 560                   return 2;]])],
 561         [ac_cv_c_c99_format=yes],
 562         [ac_cv_c_c99_format=no])
 563 ])
 564 if test $ac_cv_c_c99_format = no; then
 565         NO_C99_FORMAT=YesPlease
 566 else
 567         NO_C99_FORMAT=
 568 fi
 569 AC_SUBST(NO_C99_FORMAT)
 570 #
 571 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 572 # when attempting to read from an fopen'ed directory.
 573 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 574  [ac_cv_fread_reads_directories],
 575 [
 576 AC_RUN_IFELSE(
 577         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 578                 [[char c;
 579                 FILE *f = fopen(".", "r");
 580                 return f && fread(&c, 1, 1, f)]])],
 581         [ac_cv_fread_reads_directories=no],
 582         [ac_cv_fread_reads_directories=yes])
 583 ])
 584 if test $ac_cv_fread_reads_directories = yes; then
 585         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 586 else
 587         FREAD_READS_DIRECTORIES=
 588 fi
 589 AC_SUBST(FREAD_READS_DIRECTORIES)
 590 #
 591 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 592 # or vsnprintf() return -1 instead of number of characters which would
 593 # have been written to the final string if enough space had been available.
 594 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 595  [ac_cv_snprintf_returns_bogus],
 596 [
 597 AC_RUN_IFELSE(
 598         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 599                 #include "stdarg.h"
 600
 601                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 602                 {
 603                   int ret;
 604                   va_list ap;
 605                   va_start(ap, format);
 606                   ret = vsnprintf(str, maxsize, format, ap);
 607                   va_end(ap);
 608                   return ret;
 609                 }],
 610                 [[char buf[6];
 611                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 612                       || strcmp(buf, "12")) return 1;
 613                   if (snprintf(buf, 3, "%s", "12345") != 5
 614                       || strcmp(buf, "12")) return 1]])],
 615         [ac_cv_snprintf_returns_bogus=no],
 616         [ac_cv_snprintf_returns_bogus=yes])
 617 ])
 618 if test $ac_cv_snprintf_returns_bogus = yes; then
 619         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 620 else
 621         SNPRINTF_RETURNS_BOGUS=
 622 fi
 623 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 624
 625
 626 ## Checks for library functions.
 627 ## (in default C library and libraries checked by AC_CHECK_LIB)
 628 AC_MSG_NOTICE([CHECKS for library functions])
 629 #
 630 # Define NO_STRCASESTR if you don't have strcasestr.
 631 GIT_CHECK_FUNC(strcasestr,
 632 [NO_STRCASESTR=],
 633 [NO_STRCASESTR=YesPlease])
 634 AC_SUBST(NO_STRCASESTR)
 635 #
 636 # Define NO_MEMMEM if you don't have memmem.
 637 GIT_CHECK_FUNC(memmem,
 638 [NO_MEMMEM=],
 639 [NO_MEMMEM=YesPlease])
 640 AC_SUBST(NO_MEMMEM)
 641 #
 642 # Define NO_STRLCPY if you don't have strlcpy.
 643 GIT_CHECK_FUNC(strlcpy,
 644 [NO_STRLCPY=],
 645 [NO_STRLCPY=YesPlease])
 646 AC_SUBST(NO_STRLCPY)
 647 #
 648 # Define NO_UINTMAX_T if your platform does not have uintmax_t
 649 AC_CHECK_TYPE(uintmax_t,
 650 [NO_UINTMAX_T=],
 651 [NO_UINTMAX_T=YesPlease],[
 652 #include <inttypes.h>
 653 ])
 654 AC_SUBST(NO_UINTMAX_T)
 655 #
 656 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 657 GIT_CHECK_FUNC(strtoumax,
 658 [NO_STRTOUMAX=],
 659 [NO_STRTOUMAX=YesPlease])
 660 AC_SUBST(NO_STRTOUMAX)
 661 #
 662 # Define NO_SETENV if you don't have setenv in the C library.
 663 GIT_CHECK_FUNC(setenv,
 664 [NO_SETENV=],
 665 [NO_SETENV=YesPlease])
 666 AC_SUBST(NO_SETENV)
 667 #
 668 # Define NO_UNSETENV if you don't have unsetenv in the C library.
 669 GIT_CHECK_FUNC(unsetenv,
 670 [NO_UNSETENV=],
 671 [NO_UNSETENV=YesPlease])
 672 AC_SUBST(NO_UNSETENV)
 673 #
 674 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 675 GIT_CHECK_FUNC(mkdtemp,
 676 [NO_MKDTEMP=],
 677 [NO_MKDTEMP=YesPlease])
 678 AC_SUBST(NO_MKDTEMP)
 679 #
 680 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
 681 GIT_CHECK_FUNC(mkstemps,
 682 [NO_MKSTEMPS=],
 683 [NO_MKSTEMPS=YesPlease])
 684 AC_SUBST(NO_MKSTEMPS)
 685 #
 686 #
 687 # Define NO_MMAP if you want to avoid mmap.
 688 #
 689 # Define NO_ICONV if your libc does not properly support iconv.
 690
 691
 692 ## Other checks.
 693 # Define USE_PIC if you need the main git objects to be built with -fPIC
 694 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 695 #
 696 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 697 # Enable it on Windows.  By default, symrefs are still used.
 698 #
 699 # Define NO_PTHREADS if we do not have pthreads
 700 #
 701 # Define PTHREAD_LIBS to the linker flag used for Pthread support and define
 702 # THREADED_DELTA_SEARCH if Pthreads are available.
 703 AC_DEFUN([PTHREADTEST_SRC], [
 704 #include <pthread.h>
 705
 706 int main(void)
 707 {
 708         pthread_mutex_t test_mutex;
 709         return (0);
 710 }
 711 ])
 712
 713 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 714 dnl   [[#include <pthread.h>]],
 715 dnl   [[pthread_mutex_t test_mutex;]]
 716 dnl )])
 717
 718 NO_PTHREADS=UnfortunatelyYes
 719 THREADED_DELTA_SEARCH=
 720 PTHREAD_LIBS=
 721
 722 if test -n "$USER_NOPTHREAD"; then
 723    AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
 724 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
 725 # -D_REENTRANT' or some such.
 726 elif test -z "$PTHREAD_CFLAGS"; then
 727   for opt in -pthread -lpthread; do
 728      old_CFLAGS="$CFLAGS"
 729      CFLAGS="$opt $CFLAGS"
 730      AC_MSG_CHECKING([Checking for POSIX Threads with '$opt'])
 731      AC_LINK_IFELSE(PTHREADTEST_SRC,
 732         [AC_MSG_RESULT([yes])
 733                 NO_PTHREADS=
 734                 PTHREAD_LIBS="$opt"
 735                 THREADED_DELTA_SEARCH=YesPlease
 736                 break
 737         ],
 738         [AC_MSG_RESULT([no])])
 739       CFLAGS="$old_CFLAGS"
 740   done
 741 else
 742   old_CFLAGS="$CFLAGS"
 743   CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
 744   AC_MSG_CHECKING([Checking for POSIX Threads with '$PTHREAD_CFLAGS'])
 745   AC_LINK_IFELSE(PTHREADTEST_SRC,
 746         [AC_MSG_RESULT([yes])
 747                 NO_PTHREADS=
 748                 PTHREAD_LIBS="$PTHREAD_CFLAGS"
 749                 THREADED_DELTA_SEARCH=YesPlease
 750         ],
 751         [AC_MSG_RESULT([no])])
 752
 753   CFLAGS="$old_CFLAGS"
 754 fi
 755
 756 CFLAGS="$old_CFLAGS"
 757
 758 AC_SUBST(PTHREAD_LIBS)
 759 AC_SUBST(NO_PTHREADS)
 760 AC_SUBST(THREADED_DELTA_SEARCH)
 761
 762 ## Output files
 763 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 764 AC_OUTPUT
 765
 766
 767 ## Cleanup
 768 rm -f "${config_append}"