toolbox/update-all-config.pl

   1 #!/usr/bin/perl
   2
   3 # update-all-config.pl - Update all out-of-date config
   4
   5 use strict;
   6 use warnings;
   7 use vars qw($VERSION);
   8 BEGIN {*VERSION = \'2.0'}
   9 use File::Basename;
  10 use File::Spec;
  11 use Cwd qw(realpath);
  12 use POSIX qw();
  13 use Getopt::Long;
  14 use Pod::Usage;
  15 use lib "__BASEDIR__";
  16 use Girocco::Config;
  17 use Girocco::Util;
  18 use Girocco::CLIUtil;
  19 use Girocco::Project;
  20
  21 my $shbin;
  22 BEGIN {
  23     $shbin = $Girocco::Config::posix_sh_bin;
  24     defined($shbin) && $shbin ne "" or $shbin = "/bin/sh";
  25 }
  26
  27 exit(&main(@ARGV)||0);
  28
  29 my ($dryrun, $force, $quiet);
  30
  31 sub die_usage {
  32         pod2usage(-exitval => 2);
  33 }
  34
  35 sub do_help {
  36         pod2usage(-verbose => 2, -exitval => 0);
  37 }
  38
  39 sub do_version {
  40         print basename($0), " version ", $VERSION, "\n";
  41         exit 0;
  42 }
  43
  44 my ($dmode, $dperm, $drwxmode, $fmode, $fmodeoct, $fperm, $wall);
  45 BEGIN {
  46         $dmode=02775;
  47         $dperm='drwxrwsr-x';
  48         $drwxmode='ug+rwx,o+rx';
  49         $fmode=0664;
  50         $fmodeoct='0664';
  51         $fperm='-rw-rw-r--';
  52         $wall=0;
  53 }
  54
  55 my $owning_group_id;
  56
  57 sub main {
  58         local *ARGV = \@_;
  59         my ($help, $version);
  60
  61         umask 002;
  62         close(DATA) if fileno(DATA);
  63         Getopt::Long::Configure('bundling');
  64         GetOptions(
  65                 'help|h'        => sub {do_help},
  66                 'version|V'     => sub {do_version},
  67                 'dry-run|n'     => \$dryrun,
  68                 'quiet|q'       => \$quiet,
  69                 'force|f'       => \$force,
  70         ) or die_usage;
  71         $dryrun and $quiet = 0;
  72
  73         -f jailed_file("/etc/group") or
  74                 die "Girocco group file not found: " . jailed_file("/etc/group") . "\n";
  75
  76         if (!defined($Girocco::Config::owning_group) || $Girocco::Config::owning_group eq "") {
  77                 die "\$Girocco::Config::owning_group unset, refusing to run without --force\n" unless $force;
  78                 $dmode=02777;
  79                 $dperm='drwxrwsrwx';
  80                 $drwxmode='a+rwx';
  81                 $fmode=0666;
  82                 $fmodeoct='0666';
  83                 $fperm='-rw-rw-rw-';
  84                 $wall=1;
  85                 warn "Mode 666 in effect\n" unless $quiet;
  86         } elsif (($owning_group_id = scalar(getgrnam($Girocco::Config::owning_group))) !~ /^\d+$/) {
  87                 die "\$Girocco::Config::owning_group invalid ($Girocco::Config::owning_group), refusing to run\n";
  88         }
  89
  90         my @allprojs = Girocco::Project::get_full_list;
  91         my @projects = ();
  92
  93         my $root = $Girocco::Config::reporoot;
  94         $root or die "\$Girocco::Config::reporoot is invalid\n";
  95         $root =~ s,/+$,,;
  96         $root ne "" or $root = "/";
  97         $root = realpath($root);
  98         if (@ARGV) {
  99                 my %projnames = map {($_ => 1)} @allprojs;
 100                 foreach (@ARGV) {
 101                         s,/+$,,;
 102                         $_ or $_ = "/";
 103                         -d $_ and $_ = realpath($_);
 104                         s,^\Q$root\E/,,;
 105                         s,\.git$,,;
 106                         if (!exists($projnames{$_})) {
 107                                 warn "$_: unknown to Girocco (not in etc/group)\n"
 108                                         unless $quiet;
 109                                 next;
 110                         }
 111                         push(@projects, $_);
 112                 }
 113         } else {
 114                 @projects = sort {lc($a) cmp lc($b)} @allprojs;
 115         }
 116
 117         my $bad = 0;
 118         foreach (@projects) {
 119                 my $projdir = "$root/$_.git";
 120                 if (! -d $projdir) {
 121                         warn "$_: does not exist -- skipping\n" unless $quiet;
 122                         next;
 123                 }
 124                 if (!is_git_dir($projdir)) {
 125                         warn "$_: is not a .git directory -- skipping\n" unless $quiet;
 126                         next;
 127                 }
 128                 if (-e "$projdir/.noconfig") {
 129                         warn "$_: found .noconfig -- skipping\n" unless $quiet;
 130                         next;
 131                 }
 132                 if (!chdir($projdir)) {
 133                         warn "$_: chdir to project directory failed: $!\n" unless $quiet;
 134                         next;
 135                 }
 136                 process_one_project($_) or $bad = 1;
 137         }
 138
 139         return $bad ? 1 : 0;
 140 }
 141
 142 my (@mkdirs, @mkfiles);
 143 my (@fixdpermsdirs, @fixdpermsrwx, @fixfpermsfiles, @fixfpermsdirs);
 144 BEGIN {
 145         @mkdirs = qw(refs info hooks ctags htmlcache bundles reflogs objects objects/info);
 146         @mkfiles = qw(config info/lastactivity);
 147         @fixdpermsdirs = qw(. refs info ctags htmlcache bundles reflogs objects objects/info);
 148         @fixdpermsrwx = qw(refs objects);
 149         @fixfpermsfiles = qw(HEAD config description packed-refs README.html info/lastactivity
 150                 info/alternates info/http-alternates info/packs);
 151         @fixfpermsdirs = qw(ctags);
 152 }
 153
 154 my (@boolvars, @falsevars, @false0vars, @truevars);
 155 BEGIN {
 156         @boolvars = qw(gitweb.statusupdates);
 157         @falsevars = qw(core.ignorecase receive.denynonfastforwards);
 158         @false0vars = qw(gc.auto receive.autogc);
 159         @truevars = qw(receive.updateserverinfo repack.writebitmaps transfer.fsckobjects);
 160 }
 161
 162 my $hdr;
 163
 164 sub defval($$) {
 165         return defined($_[0]) ? $_[0] : $_[1];
 166 }
 167
 168 sub openfind_ {
 169         my $noe = shift;
 170         my $duperr;
 171         if ($noe) {{
 172                 open $duperr, '>&2' or last;
 173                 my $errfd = POSIX::open(File::Spec->devnull, &POSIX::O_RDWR);
 174                 defined($errfd) or close($duperr), $duperr = undef, last;
 175                 POSIX::dup2($errfd, 2) or close($duperr), $duperr = undef;
 176                 POSIX::close($errfd);
 177         }}
 178         my $fd;
 179         my $ans = open $fd, '-|', "find", @_;
 180         if ($noe && defined($duperr) && defined(fileno($duperr))) {
 181                 POSIX::dup2(fileno($duperr), 2);
 182                 close($duperr);
 183         }
 184         $ans or die "find failed: $!\n";
 185         return $fd;
 186 }
 187
 188 sub openfind { return openfind_(0, @_); }
 189 sub openfindne { return openfind_(1, @_); }
 190
 191 sub process_one_project
 192 {
 193         my ($proj) = @_;
 194         my $bad = 0;
 195         my $reallybad = 0;
 196         $hdr = 0;
 197         do {
 198                 if (! -d $_) {
 199                         if (-e $_) {
 200                                 warn "$proj: bypassing project, exists but not directory: $_\n" unless $quiet;
 201                                 $reallybad = $bad = 1;
 202                                 last;
 203                         } else {
 204                                 do_mkdir($proj, $_) or $bad = 1, last;
 205                         }
 206                 }
 207         } foreach (@mkdirs);
 208         return 0 if $reallybad;
 209
 210         -d $_ && check_dperm($proj, $_) or $bad = 1 foreach (@fixdpermsdirs);
 211         my $fp = openfindne(@fixdpermsrwx, qw(-xdev -type d ( ! -path objects/?? -o -prune ) ! -perm), "-$drwxmode", "-print");
 212         while (<$fp>) {
 213                 chomp;
 214                 change_dpermrwx($proj, $_) or $bad = 1;
 215         }
 216         close($fp) or $bad = 1;
 217         $fp = openfind(qw(. -xdev -type d ( ! -path ./objects/?? -o -prune ) ! -perm -a+rx -print));
 218         while (<$fp>) {
 219                 chomp;
 220                 change_dpermrx($proj, $_) or $bad = 1;
 221         }
 222         close($fp) or $bad = 1;
 223
 224         do {
 225                 if (-e $_) {
 226                         if (! -f $_) {
 227                                 warn "$proj: bypassing project, exists but not file: $_\n" unless $quiet;
 228                                 $reallybad = $bad = 1;
 229                                 last;
 230                         }
 231                 } else {
 232                         my $result = "(dryrun)";
 233                         if (!$dryrun) {
 234                                 $result = "";
 235                                 my $tf;
 236                                 open($tf, '>', $_) && close ($tf) or $result = "FAILED", $bad = 1;
 237                         }
 238                         pmsg($proj, "$_: created", $result) unless $quiet;
 239                 }
 240         } foreach(@mkfiles);
 241         return 0 if $reallybad;
 242
 243         $dryrun || check_fperm($proj, "config") or $bad = 1;
 244         my $config = read_config_file_hash("config", !$quiet);
 245         if (!defined($config)) {
 246                 warn "$proj: could not read config file -- skipping\n" unless $quiet;
 247                 return 0;
 248         }
 249
 250         my $do_config = sub {
 251                 my ($item, $val) = @_;
 252                 my $oldval = defval($config->{$item},"");
 253                 my $result = "(dryrun)";
 254                 if (!$dryrun) {
 255                         $result = "";
 256                         system($Girocco::Config::git_bin, "config", "--file", "config", "--replace-all", $item, $val) == 0 or
 257                                 $result = "FAILED", $bad = 1;
 258                 }
 259                 if (!exists($config->{$item})) {
 260                         pmsg($proj, "config $item: created \"$val\"", $result) unless $quiet;
 261                 } else {
 262                         pmsg($proj, "config $item: \"$oldval\" -> \"$val\"", $result) unless $quiet;
 263                 }
 264         };
 265         my $do_config_unset = sub {
 266                 my ($item, $msg) = @_;
 267                 defined($msg) or $msg = "";
 268                 $msg eq "" or $msg = " " . $msg;
 269                 my $oldval = defval($config->{$item},"");
 270                 my $result = "(dryrun)";
 271                 if (!$dryrun) {
 272                         $result = "";
 273                         system($Girocco::Config::git_bin, "config", "--file", "config", "--unset-all", $item) == 0 or
 274                                 $result = "FAILED", $bad = 1;
 275                 }
 276                 pmsg($proj, "config $item: removed$msg \"$oldval\"", $result) unless $quiet;
 277         };
 278
 279         my $cmplvl = defval($config->{'core.compression'},"");
 280         if ($cmplvl !~ /^-?\d+$/ || $cmplvl < -1 || $cmplvl > 9 || "" . (0 + $cmplvl) ne "" . $cmplvl) {
 281                 pmsg($proj, "WARNING: replacing invalid core.compression value: \"$cmplvl\"") unless $cmplvl eq "" || $quiet;
 282                 $cmplvl = "";
 283         } elsif ($cmplvl != 5) {
 284                 pmsg($proj, "WARNING: suboptimal core.compression value left unchanged: \"$cmplvl\"") unless $quiet;
 285         }
 286         $cmplvl ne "" or &$do_config('core.compression', 5);
 287         my $grpshr = defval($config->{'core.sharedrepository'},"");
 288         if ($grpshr eq "" || (valid_bool($grpshr) && !git_bool($grpshr))) {
 289                 &$do_config('core.sharedrepository', 1);
 290         } elsif (!(valid_bool($grpshr) && git_bool($grpshr))) {
 291                 pmsg($proj, "WARNING: odd core.sharedrepository value left unchanged: \"$grpshr\"");
 292         }
 293         if (git_bool($config->{'core.bare'})) {
 294                 my $setlaru = 1;
 295                 my $laru = $config->{'core.logallrefupdates'};
 296                 if (defined($laru)) {
 297                         if (valid_bool($laru)) {
 298                                 $setlaru = 0;
 299                                 if (git_bool($laru)) {
 300                                         pmsg($proj, "WARNING: core.logallrefupdates is true (left unchanged)") unless $quiet;
 301                                 }
 302                         } else {
 303                                 pmsg($proj, "WARNING: replacing non-boolean core.logallrefupdates value") unless $quiet;
 304                         }
 305                 }
 306                 !$setlaru or &$do_config('core.logallrefupdates', 'false');
 307         } else {
 308                 pmsg($proj, "WARNING: core.bare is not true (left unchanged)") unless $quiet;
 309         }
 310         defval($config->{'transfer.unpacklimit'},"") eq "1" or &$do_config('transfer.unpacklimit', 1);
 311         lc(defval($config->{'receive.denydeletecurrent'},"")) eq "warn" or &$do_config('receive.denydeletecurrent', 'warn');
 312         do {
 313                 !exists($config->{$_}) || valid_bool(defval($config->{$_},"")) or &$do_config_unset($_, "(not a boolean)");
 314         } foreach (@boolvars);
 315         do {
 316                 (valid_bool(defval($config->{$_},"")) && !git_bool($config->{$_})) or &$do_config($_, "false");
 317         } foreach (@falsevars);
 318         do {
 319                 (valid_bool(defval($config->{$_},"")) && !git_bool($config->{$_})) or &$do_config($_, 0);
 320         } foreach (@false0vars);
 321         do {
 322                 (valid_bool(defval($config->{$_},"")) && git_bool($config->{$_})) or &$do_config($_, "true");
 323         } foreach (@truevars);
 324
 325         if (defined($Girocco::Config::owning_group) && $Girocco::Config::owning_group ne "") {
 326                 $fp = openfind(qw(. -xdev ( -type d -o -type f ) ! -group), $Girocco::Config::owning_group, "-print");
 327                 while (<$fp>) {
 328                         chomp;
 329                         change_group($proj, $_) or $bad = 1;
 330                 }
 331                 close($fp) or $bad = 1;
 332         }
 333         foreach (@fixfpermsfiles) {
 334                 if (-e $_) {
 335                         if (! -f $_) {
 336                                 warn "$proj: bypassing project, exists but not file: $_\n" unless $quiet;
 337                                 $reallybad = $bad = 1;
 338                                 last;
 339                         }
 340                         check_fperm($proj, $_) or $bad = 1;
 341                 }
 342         }
 343         return 0 if $reallybad;
 344
 345         $fp = openfindne(@fixfpermsdirs, qw(-xdev -type f ! -perm), $fmodeoct, "-print");
 346         while (<$fp>) {
 347                 chomp;
 348                 check_fperm($proj, $_) or $bad = 1;
 349         }
 350         close($fp) or $bad = 1;
 351         $fp = openfind(qw(. -xdev -type f ! -perm -a+r -print));
 352         while (<$fp>) {
 353                 chomp;
 354                 check_fpermr($proj, $_) or $bad = 1;
 355         }
 356         close($fp) or $bad = 1;
 357         $fp = openfind(qw(. -xdev -type d ( -path ./hooks -o -path ./mob/hooks ) -prune -o -type f -perm +a+x -print));
 358         while (<$fp>) {
 359                 chomp;
 360                 check_fpermnox($proj, $_) or $bad = 1;
 361         }
 362         close($fp) or $bad = 1;
 363
 364         my $bu = defval($config->{'gitweb.baseurl'},"");
 365         if (-e ".nofetch") {
 366                 $bu eq "" or pmsg($proj, "WARNING: .nofetch exists but gitweb.baseurl is not empty ($bu)") unless $quiet;
 367         } else {
 368                 $bu ne "" or pmsg($proj, "WARNING: gitweb.baseurl is empty and .nofetch does not exist") unless $quiet;
 369         }
 370
 371         return !$bad;
 372 }
 373
 374 sub do_mkdir
 375 {
 376         my ($proj, $subdir) = @_;
 377         my $result = "";
 378         if (!$dryrun) {
 379                 mkdir("$subdir") && -d "$subdir" or $result = "FAILED";
 380         } else {
 381                 $result = "(dryrun)";
 382         }
 383         pmsg($proj, "$subdir/: created", $result);
 384         return $result ne "FAILED";
 385 }
 386
 387 sub check_dperm {
 388         my ($proj, $subdir) = @_;
 389         my $oldmode = (stat($subdir))[2];
 390         if (!defined($oldmode) || $oldmode eq "") {
 391                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 392                 return 0;
 393         }
 394         my $newmode = ($oldmode & ~07777) | $dmode;
 395         $newmode == $oldmode and return 1;
 396         my $result = "";
 397         if (!$dryrun) {
 398                 if (!chmod($newmode & 07777, $subdir)) {
 399                         $result = "FAILED";
 400                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 401                 }
 402         } else {
 403                 $result = "(dryrun)";
 404         }
 405         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 406         return $result ne "FAILED";
 407 }
 408
 409 sub change_dpermrwx {
 410         my ($proj, $subdir) = @_;
 411         my $oldmode = (stat($subdir))[2];
 412         if (!defined($oldmode) || $oldmode eq "") {
 413                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 414                 return 0;
 415         }
 416         my $newmode = $oldmode | ($wall ? 0777 : 0775);
 417         $newmode == $oldmode and return 1;
 418         my $result = "";
 419         if (!$dryrun) {
 420                 if (!chmod($newmode & 07777, $subdir)) {
 421                         $result = "FAILED";
 422                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 423                 }
 424         } else {
 425                 $result = "(dryrun)";
 426         }
 427         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 428         return $result ne "FAILED";
 429 }
 430
 431 sub change_dpermrx {
 432         my ($proj, $subdir) = @_;
 433         $subdir =~ s,^\./,,;
 434         my $oldmode = (stat($subdir))[2];
 435         if (!defined($oldmode) || $oldmode eq "") {
 436                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 437                 return 0;
 438         }
 439         my $newmode = $oldmode | 0555;
 440         $newmode == $oldmode and return 1;
 441         my $result = "";
 442         if (!$dryrun) {
 443                 if (!chmod($newmode & 07777, $subdir)) {
 444                         $result = "FAILED";
 445                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 446                 }
 447         } else {
 448                 $result = "(dryrun)";
 449         }
 450         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 451         return $result ne "FAILED";
 452 }
 453
 454 sub check_fperm {
 455         my ($proj, $file) = @_;
 456         my $oldmode = (stat($file))[2];
 457         if (!defined($oldmode) || $oldmode eq "") {
 458                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 459                 return 0;
 460         }
 461         my $newmode = ($oldmode & ~07777) | $fmode;
 462         $newmode == $oldmode and return 1;
 463         my $result = "";
 464         if (!$dryrun) {
 465                 if (!chmod($newmode & 07777, $file)) {
 466                         $result = "FAILED";
 467                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 468                 }
 469         } else {
 470                 $result = "(dryrun)";
 471         }
 472         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 473         return $result ne "FAILED";
 474 }
 475
 476 sub check_fpermr {
 477         my ($proj, $file) = @_;
 478         $file =~ s,^\./,,;
 479         my $oldmode = (stat($file))[2];
 480         if (!defined($oldmode) || $oldmode eq "") {
 481                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 482                 return 0;
 483         }
 484         my $newmode = $oldmode | 0444;
 485         $newmode == $oldmode and return 1;
 486         my $result = "";
 487         if (!$dryrun) {
 488                 if (!chmod($newmode & 07777, $file)) {
 489                         $result = "FAILED";
 490                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 491                 }
 492         } else {
 493                 $result = "(dryrun)";
 494         }
 495         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 496         return $result ne "FAILED";
 497 }
 498
 499 sub check_fpermnox {
 500         my ($proj, $file) = @_;
 501         $file =~ s,^\./,,;
 502         my $oldmode = (stat($file))[2];
 503         if (!defined($oldmode) || $oldmode eq "") {
 504                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 505                 return 0;
 506         }
 507         my $newmode = $oldmode & ~0111;
 508         $newmode == $oldmode and return 1;
 509         my $result = "";
 510         if (!$dryrun) {
 511                 if (!chmod($newmode & 07777, $file)) {
 512                         $result = "FAILED";
 513                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 514                 }
 515         } else {
 516                 $result = "(dryrun)";
 517         }
 518         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 519         return $result ne "FAILED";
 520 }
 521
 522 sub change_group {
 523         my ($proj, $item) = @_;
 524         $item =~ s,^\./,,;
 525         my @info = stat($item);
 526         if (@info < 6 || $info[2] eq "" || $info[4] eq "" || $info[5] eq "") {
 527                 warn "chgrp: ($proj) $item: No such file or directory\n" unless $quiet;
 528                 return 0;
 529         }
 530         $info[5] == $owning_group_id and return 1;
 531         my $result = "";
 532         if (!$dryrun) {
 533                 if (!chown($info[4], $owning_group_id, $item)) {
 534                         $result = "FAILED";
 535                         warn "chgrp: ($proj) $item: $!\n" unless $quiet;
 536                 } elsif (!chmod($info[2] & 07777, $item)) {
 537                         $result = "FAILED";
 538                         warn "chmod: ($proj) $item: $!\n" unless $quiet;
 539                 }
 540         } else {
 541                 $result = "(dryrun)";
 542         }
 543         my $isdir = ((($info[2] >> 12) & 017) == 004) ? '/' : '';
 544         pmsg($proj, "$item$isdir: group", get_grp_nam($info[5]), '->', $Girocco::Config::owning_group, $result);
 545         return $result ne "FAILED";
 546 }
 547
 548 my $wrote; BEGIN {$wrote = ""}
 549 sub pmsg {
 550         my $proj = shift;
 551         my $msg = join(" ", @_);
 552         $msg =~ s/\s+$//;
 553         my $prefix = "";
 554         if (!$hdr) {
 555                 $prefix = $wrote . $proj . ":\n";
 556                 $hdr = 1;
 557         }
 558         print $prefix, "  ", join(' ', @_), "\n";
 559         $wrote = "\n";
 560 }
 561
 562 my %ftypes;
 563 BEGIN {%ftypes = (
 564         000 => '?',
 565         001 => 'p',
 566         002 => 'c',
 567         003 => '?',
 568         004 => 'd',
 569         005 => '?',
 570         006 => 'b',
 571         007 => '?',
 572         010 => '-',
 573         011 => '?',
 574         012 => 'l',
 575         013 => '?',
 576         014 => 's',
 577         015 => '?',
 578         016 => 'w',
 579         017 => '?'
 580 )}
 581 my %fperms;
 582 BEGIN {%fperms = (
 583         0 => '---',
 584         1 => '--x',
 585         2 => '-w-',
 586         3 => '-wx',
 587         4 => 'r--',
 588         5 => 'r-x',
 589         6 => 'rw-',
 590         7 => 'rwx'
 591 )}
 592
 593 sub get_mode_perm {
 594         my $mode = $_[0];
 595         my $str = $ftypes{($mode >> 12) & 017} .
 596                 $fperms{($mode >> 6) & 7} .
 597                 $fperms{($mode >> 3) & 7} .
 598                 $fperms{$mode & 7};
 599         substr($str,3,1) = ($mode & 0100) ? 's' : 'S' if $mode & 04000;
 600         substr($str,6,1) = ($mode & 0010) ? 's' : 'S' if $mode & 02000;
 601         substr($str,9,1) = ($mode & 0001) ? 't' : 'T' if $mode & 01000;
 602         return $str;
 603 }
 604
 605 sub get_perm {
 606         my $mode = (stat($_[0]))[2];
 607         defined($mode) or return '??????????';
 608         return get_mode_perm($mode);
 609 }
 610
 611 sub get_grp_nam {
 612         my $grpid = $_[0];
 613         defined($grpid) or return '?';
 614         my $grpnm = scalar(getgrgid($grpid));
 615         return defined($grpnm) && $grpnm ne "" ? $grpnm : $grpid;
 616 }
 617
 618 sub get_grp {
 619         my $grp = (stat($_[0]))[5];
 620         defined($grp) or return '?';
 621         return get_grp_nam($grp);
 622 }
 623
 624 __END__
 625
 626 =head1 NAME
 627
 628 update-all-config.pl - Update all projects' config settings
 629
 630 =head1 SYNOPSIS
 631
 632 update-all-config.pl [<options>] [<projname>]...
 633
 634  Options:
 635    -h | --help                  detailed instructions
 636    -V | --version               show version
 637    -n | --dry-run               show what would be done but don't do it
 638    -f | --force                 run without a Config.pm owning_group
 639    -q | --quiet                 suppress change messages
 640
 641  <projname>                     if given, only operate on these projects
 642
 643 =head1 OPTIONS
 644
 645 =over 8
 646
 647 =item B<-h>, B<--help>
 648
 649 Print the full description of update-all-config.pl's options.
 650
 651 =item B<-V>, B<--version>
 652
 653 Print the version of update-all-config.pl.
 654
 655 =item B<-n>, B<--dry-run>
 656
 657 Do not actually make any changes, just show what would be done without
 658 actually doing it.
 659
 660 =item B<-q>, B<--quiet>
 661
 662 Suppress the messages about what's actually being changed.  This option
 663 is ignored if B<--dry-run> is in effect.
 664
 665 The warnings about missing and unknown-to-Girocco projects are also
 666 suppressed by this option.
 667
 668 =item B<-f>, B<--force>
 669
 670 Allow running without a $Girocco::Config::owning_group set.  This is not
 671 recommended as it results in world-writable items being used (instead of
 672 just world-readable).
 673
 674 =item B<<projname>>
 675
 676 If no project names are specified then I<all> projects are processed.
 677
 678 If one or more project names are specified then only those projects are
 679 processed.  Specifying non-existent projects produces a warning for them,
 680 but the rest of the projects specified will still be processed.
 681
 682 Each B<projname> may be either a full absolute path starting with
 683 $Girocco::Config::reporoot or just the project name part with or without
 684 a trailing C<.git>.
 685
 686 Any explicitly specified projects that do exist but are not known to
 687 Girocco will be skipped (with a warning).
 688
 689 =back
 690
 691 =head1 DESCRIPTION
 692
 693 Inspect the C<config> files of Girocco projects (i.e. $GIT_DIR/config) and
 694 look for anomalies and out-of-date settings.
 695
 696 Additionally check the existence and permissions on various files and
 697 directories in the project.
 698
 699 If an explicity specified project is located under $Girocco::Config::reporoot
 700 but is not actually known to Girocco (i.e. it's not in the etc/group file)
 701 then it will be skipped.
 702
 703 By default, any anomalies or out-of-date settings will be corrected with a
 704 message to that effect.  However using B<--dry-run> will only show the
 705 correction(s) which would be made without making them and B<--quiet> will make
 706 the correction(s) without any messages.
 707
 708 Any projects that have a C<$GIT_DIR/.noconfig> file are always skipped (with a
 709 message unless B<--quiet> is used).
 710
 711 =cut