Girocco/User.pm

   1 package Girocco::User;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Digest::MD5 qw(md5);
   7
   8 use Girocco::Config;
   9 use Girocco::CGI;
  10 use Girocco::Util;
  11 use Girocco::SSHUtil;
  12
  13 BEGIN {
  14         eval {
  15                 require Digest::SHA;
  16                 Digest::SHA->import(
  17                         qw(sha1_hex)
  18         );1} ||
  19         eval {
  20                 require Digest::SHA1;
  21                 Digest::SHA1->import(
  22                         qw(sha1_hex)
  23         );1} ||
  24         eval {
  25                 require Digest::SHA::PurePerl;
  26                 Digest::SHA::PurePerl->import(
  27                         qw(sha1_hex)
  28         );1} ||
  29         die "One of Digest::SHA or Digest::SHA1 or Digest::SHA::PurePerl "
  30         . "must be available\n";
  31 }
  32
  33 sub _gen_uuid {
  34         my $self = shift;
  35
  36         $self->{uuid} = '' unless $self->{uuid};
  37         my @md5;
  38         {
  39                 no warnings;
  40                 @md5 = unpack('C*', md5(time . $$ . rand() . join(':',%$self)));
  41         }
  42         $md5[6] = 0x40 | ($md5[6] & 0x0F); # Version 4 -- random
  43         $md5[8] = 0x80 | ($md5[8] & 0x3F); # RFC 4122 specification
  44         return sprintf(
  45                 '%02x%02x%02x%02x-%02x%02x-%02x%02x-%02x%02x-%02x%02x%02x%02x%02x%02x',
  46                 @md5);
  47 }
  48
  49 sub _remove_ssh_leftovers {
  50         my $self = shift;
  51         my @files;
  52         system('rm', '-f', "$Girocco::Config::chroot/etc/sshkeys/$self->{name}");
  53         @files = glob("'$Girocco::Config::chroot/etc/sshcerts/${Girocco::Config::nickname}_$self->{name}'_user_*.pem");
  54         system('rm', '-f', @files) if @files;
  55         system('rm', '-f', "$Girocco::Config::chroot/etc/sshactive/$self->{name}");
  56         @files = glob("'$Girocco::Config::chroot/etc/sshactive/$self->{name}',*");
  57         system('rm', '-f', @files) if @files;
  58 }
  59
  60 sub _passwd_add {
  61         use POSIX qw(strftime);
  62         my $self = shift;
  63         my (undef, undef, $gid) = getgrnam($Girocco::Config::owning_group||'');
  64         my $owngroupid = $gid ? $gid : 65534;
  65         Girocco::User->load($self->{name}) and die "User $self->{name} already exists";
  66         $self->{uuid} = $self->_gen_uuid;
  67         my ($S,$M,$H,$d,$m,$y) = gmtime(time());
  68         $self->{creationtime} = strftime("%Y%m%d_%H%M%S", $S, $M, $H, $d, $m, $y, -1, -1, -1);
  69         my $email_uuid_etc = join ',', $self->{email}, $self->{uuid}, $self->{creationtime};
  70         filedb_atomic_append(jailed_file('/etc/passwd'),
  71                 join(':', $self->{name}, 'x', '\i', $owngroupid, $email_uuid_etc, '/', '/bin/git-shell-verify'),
  72                 $self->{name});
  73         $self->_remove_ssh_leftovers;
  74 }
  75
  76 sub _passwd_update {
  77         my $self = shift;
  78         filedb_atomic_edit(jailed_file('/etc/passwd'),
  79                 sub {
  80                         $_ = $_[0];
  81                         chomp;
  82                         if ($self->{name} eq (split /:/)[0]) {
  83                                 # preserve all but login name and first 2 fields of comment field
  84                                 # creating a uuid (field 2 of comment field) if one is not already present
  85                                 my @fields=split(/:/, $_, -1);
  86                                 $fields[0] = $self->{name};
  87                                 my @subfields = split(',', $fields[4]||'', -1);
  88                                 $self->{uuid} = $subfields[1] || '';
  89                                 $self->{uuid} or $self->{uuid} = $self->_gen_uuid;
  90                                 $subfields[0] = $self->{email};
  91                                 $subfields[1] = $self->{uuid};
  92                                 $fields[4] = join(',', @subfields);
  93                                 return join(':', @fields)."\n";
  94                         } else {
  95                                 return "$_\n";
  96                         }
  97                 },
  98                 $self->{name}
  99         );
 100 }
 101
 102 sub _passwd_remove {
 103         my $self = shift;
 104         $self->_remove_ssh_leftovers;
 105         filedb_atomic_edit(jailed_file('/etc/passwd'),
 106                 sub {
 107                         $self->{name} ne (split /:/)[0] and return $_;
 108                 },
 109                 $self->{name}
 110         );
 111 }
 112
 113 sub _sshkey_path {
 114         my $self = shift;
 115         '/etc/sshkeys/'.$self->{name};
 116 }
 117
 118 sub _sshkey_load {
 119         my $self = shift;
 120         open my $fd, '<', jailed_file($self->_sshkey_path) or die "sshkey load failed: $!";
 121         my @keys = ();
 122         my $auth = '';
 123         my $authtype = '';
 124         while (<$fd>) {
 125                 chomp;
 126                 if (/^(?:no-pty )?(ssh-(?:dss|rsa) .*)$/) {
 127                         push @keys, $1;
 128                 } elsif (/^# ([A-Z]+)AUTH ([0-9a-f]+) (\d+)/) {
 129                         my $expire = $3;
 130                         $auth = $2 unless (time >= $expire);
 131                         $authtype = $1 if $auth;
 132                 }
 133         }
 134         close $fd;
 135         my $keys = join("\n", @keys); chomp $keys;
 136         ($keys, $auth, $authtype);
 137 }
 138
 139 sub _trimkeys {
 140         my $keys = shift;
 141         my @lines = ();
 142         foreach (split /\r\n|\r|\n/, $keys) {
 143                 next if /^[ \t]*$/ || /^[ \t]*#/;
 144                 push(@lines, $_);
 145         }
 146         return join("\n", @lines);
 147 }
 148
 149 sub _sshkey_save {
 150         my $self = shift;
 151         $self->{keys} = _trimkeys($self->{keys} || '');
 152         open my $fd, '>', jailed_file($self->_sshkey_path) or die "sshkey save failed: $!";
 153         if (defined($self->{auth}) && $self->{auth}) {
 154                 my $expire = time + 24 * 3600;
 155                 my $typestr = $self->{authtype} ? uc($self->{authtype}) : 'REPO';
 156                 print $fd "# ${typestr}AUTH $self->{auth} $expire\n";
 157         }
 158         print $fd map("no-pty $_\n", split(/\n/, $self->{keys}));
 159         close $fd;
 160         chmod 0664, jailed_file($self->_sshkey_path);
 161 }
 162
 163 # private constructor, do not use
 164 sub _new {
 165         my $class = shift;
 166         my ($name) = @_;
 167         Girocco::User::valid_name($name) or die "refusing to create user with invalid name ($name)!";
 168         my $proj = { name => $name };
 169
 170         bless $proj, $class;
 171 }
 172
 173 # public constructor #0
 174 # creates a virtual user not connected to disk record
 175 # you can conjure() it later to disk
 176 sub ghost {
 177         my $class = shift;
 178         my ($name) = @_;
 179         my $self = $class->_new($name);
 180         $self;
 181 }
 182
 183 # public constructor #1
 184 sub load {
 185         my $class = shift;
 186         my ($name) = @_;
 187
 188         open my $fd, '<', jailed_file("/etc/passwd") or die "user load failed: $!";
 189         my $r = qr/^\Q$name\E:/;
 190         foreach (grep /$r/, <$fd>) {
 191                 chomp;
 192
 193                 my (undef, undef, $uid, undef, $email_uuid_etc) = split /:/;
 194                 my $self = $class->_new($name);
 195                 $self->{uid} = $uid;
 196                 ($self->{keys}, $self->{auth}, $self->{authtype}) = $self->_sshkey_load;
 197                 ($self->{email}, $self->{uuid}, $self->{creationtime}) = split ',', $email_uuid_etc;
 198
 199                 close $fd;
 200                 $self->{uuid} or !valid_email($self->{email}) or $self->_passwd_update;
 201                 return $self;
 202         }
 203         close $fd;
 204         undef;
 205 }
 206
 207 # public constructor #2
 208 sub load_by_uid {
 209         my $class = shift;
 210         my ($uid) = @_;
 211
 212         open my $fd, '<', jailed_file("/etc/passwd") or die "user load failed: $!";
 213         my $r = qr/^[^:]+:[^:]*:\Q$uid\E:/;
 214         foreach (grep /$r/, <$fd>) {
 215                 chomp;
 216
 217                 my ($name, undef, undef, undef, $email_uuid_etc) = split /:/;
 218                 my $self = $class->_new($name);
 219                 $self->{uid} = $uid;
 220                 ($self->{keys}, $self->{auth}, $self->{authtype}) = $self->_sshkey_load;
 221                 ($self->{email}, $self->{uuid}, $self->{creationtime}) = split ',', $email_uuid_etc;
 222
 223                 close $fd;
 224                 $self->{uuid} or $self->_passwd_update;
 225                 return $self;
 226         }
 227         close $fd;
 228         undef;
 229 }
 230
 231 # $user may not be in sane state if this returns false!
 232 sub cgi_fill {
 233         my $self = shift;
 234         my ($gcgi) = @_;
 235         my $cgi = $gcgi->cgi;
 236
 237         $self->{name} = $gcgi->wparam('name');
 238         Girocco::User::valid_name($self->{name})
 239                 or $gcgi->err("Name contains invalid characters.");
 240
 241         length($self->{name}) <= 64
 242                 or $gcgi->err("Your user name is longer than 64 characters. Do you really need that much?");
 243
 244         $self->{email} = $gcgi->wparam('email');
 245         valid_email($self->{email})
 246                 or $gcgi->err("Your email sure looks weird...?");
 247         length($self->{email}) <= 96
 248                 or $gcgi->err("Your email is longer than 96 characters. Do you really need that much?");
 249
 250         $self->keys_fill($gcgi);
 251 }
 252
 253 sub update_email {
 254         my $self = shift;
 255         my $gcgi = shift;
 256         my $email = shift || '';
 257
 258         if (valid_email($email)) {
 259                 $self->{email} = $email;
 260                 $self->_passwd_update;
 261         } else {
 262                 $gcgi->err("Your email sure looks weird...?");
 263         }
 264
 265         not $gcgi->err_check;
 266 }
 267
 268 sub _checkkey {
 269         my $key = shift;
 270         my ($type, $bits, $fingerprint, $comment) = sshpub_validate($key);
 271         return $type ? 1 : 0;
 272 }
 273
 274 sub keys_fill {
 275         my $self = shift;
 276         my ($gcgi) = @_;
 277         my $cgi = $gcgi->cgi;
 278
 279         $self->{keys} = _trimkeys($cgi->param('keys'));
 280         length($self->{keys}) <= 4096
 281                 or $gcgi->err("The list of keys is more than 4kb. Do you really need that much?");
 282         foreach my $key (split /\r?\n/, $self->{keys}) {
 283                 my ($type, $bits, $fingerprint, $comment);
 284                 ($type, $bits, $fingerprint, $comment) = sshpub_validate($key)
 285                         if $key =~ /^ssh-(?:dss|rsa) [0-9A-Za-z+\/=]+ \S+@\S+$/;
 286                 if (!$type) {
 287                         my $keyval = CGI::escapeHTML($key);
 288                         my $dsablurb = '';
 289                         $dsablurb = ' or ssh-dss' unless $Girocco::Config::disable_dsa;
 290                         $gcgi->err(<<EOT);
 291 Your ssh key ("$keyval") appears to have an invalid format
 292 (does not start with ssh-rsa$dsablurb or does not end with <tt>\@</tt>-identifier) -
 293 maybe your browser has split a single key onto multiple lines?
 294 EOT
 295                 } elsif ($Girocco::Config::disable_dsa && $type eq 'ssh-dss') {
 296                         my $keyval = CGI::escapeHTML($key);
 297                         $gcgi->err(<<EOT);
 298 Your ssh key ("$keyval") appears to be of type dsa but only rsa keys are
 299 supported - please generate an rsa key (starts with ssh-rsa) and try again
 300 EOT
 301                 } elsif ($Girocco::Config::min_key_length && $bits < $Girocco::Config::min_key_length) {
 302                         my $keyval = CGI::escapeHTML($key);
 303                         $gcgi->err(<<EOT);
 304 Your ssh key ("$keyval") appears to have only $bits bit(s) but at least
 305 $Girocco::Config::min_key_length are required - please generate a longer key
 306 EOT
 307                 }
 308         }
 309
 310         not $gcgi->err_check;
 311 }
 312
 313 sub keys_save {
 314         my $self = shift;
 315
 316         $self->_sshkey_save;
 317 }
 318
 319 sub keys_html_list {
 320         my $self = shift;
 321         my @keys = split(/\r?\n/, $self->{keys});
 322         return '' if !@keys;
 323         my $html = "<ol>\n";
 324         my %types = ('ssh-dss' => 'DSA', 'ssh-rsa' => 'RSA');
 325         my $line = 0;
 326         foreach (@keys) {
 327                 ++$line;
 328                 my ($type, $bits, $fingerprint, $comment) = sshpub_validate($_);
 329                 next unless $type && $types{$type};
 330                 my $euser = CGI::escapeHTML(CGI::Util::escape($self->{name}));
 331                 $html .= "<li>$bits <tt>$fingerprint</tt> ($types{$type}) $comment";
 332                 $html .= "<br /><a target=\"_blank\" ".
 333                         "href=\"@{[url_path($Girocco::Config::webadmurl)]}/usercert.cgi/$euser/$line/".
 334                         $Girocco::Config::nickname."_${euser}_user_$line.pem\">".
 335                         "download https push user authentication certificate</a> <sup>".
 336                         "<a target=\"_blank\" href=\"@{[url_path($Girocco::Config::htmlurl)]}/httpspush.html\">".
 337                         "(learn more)</a></sup>"
 338                         if $type eq 'ssh-rsa' && $Girocco::Config::httpspushurl &&
 339                                 $Girocco::Config::clientcert &&
 340                                 $Girocco::Config::clientkey;
 341                 $html .= "</li>\n";
 342         }
 343         $html .= "</ol>\n";
 344         return $html;
 345 }
 346
 347 sub gen_auth {
 348         my $self = shift;
 349         my ($type) = @_;
 350         $type = 'REPO' unless $type && $type =~ /^[A-Z]+$/;
 351
 352         $self->{authtype} = $type;
 353         $self->{auth} = sha1_hex(time . $$ . rand() . $self->{keys});
 354         $self->_sshkey_save;
 355         $self->{auth};
 356 }
 357
 358 sub del_auth {
 359         my $self = shift;
 360
 361         delete $self->{auth};
 362         delete $self->{authtype};
 363 }
 364
 365 sub get_projects {
 366         my $self = shift;
 367
 368         return @{$self->{projects}} if defined($self->{projects});
 369         my @projects = filedb_atomic_grep(jailed_file('/etc/group'),
 370                 sub {
 371                         $_ = $_[0];
 372                         chomp;
 373                         my ($group, $users) = (split /:/)[0,3];
 374                         $group if $users && $users =~ /(^|,)\Q$self->{name}\E(,|$)/;
 375                 }
 376         );
 377         $self->{projects} = \@projects;
 378         @{$self->{projects}};
 379 }
 380
 381 sub conjure {
 382         my $self = shift;
 383
 384         $self->_passwd_add;
 385         $self->_sshkey_save;
 386 }
 387
 388 sub remove {
 389         my $self = shift;
 390
 391         require Girocco::Project;
 392         foreach ($self->get_projects) {
 393                 if (Girocco::Project::does_exist($_)) {
 394                         my $project = Girocco::Project->load($_);
 395                         $project->update if $project->remove_user($self->{name});
 396                 }
 397         }
 398
 399         $self->_passwd_remove;
 400 }
 401
 402 ### static methods
 403
 404 # Note that 'mob' and 'everyone' are NOT reserved names per se, but they are
 405 # names with special semantics and they should be allowed in project membership
 406 # lists so they are therefore NOT included in the reservedusernames list.
 407 # 'git' and 'lock' are reserved so that the personal mob names 'mob.git' and
 408 # 'mob.lock' are not needed as they would be invalid.
 409 our %reservedusernames = (
 410         root => 1,
 411         sshd => 1,
 412         _sshd => 1,
 413         nobody => 1,
 414         lc($Girocco::Config::cgi_user) => 1,
 415         lc($Girocco::Config::mirror_user) => 1,
 416         git => 1,
 417         lock => 1,
 418 );
 419
 420 sub valid_name {
 421         $_ = $_[0];
 422         /^[a-zA-Z0-9][a-zA-Z0-9+._-]*$/
 423         and (not m#\.\.#)
 424         and (not m#\.$#)
 425         and (not m#\.git$#i)
 426         and (not m#\.lock$#i)
 427         and (not m#^mob[._]#i)
 428         and !exists($reservedusernames{lc($_)});
 429 }
 430
 431 sub does_exist {
 432         my ($name) = @_;
 433         Girocco::User::valid_name($name) or die "tried to query for user with invalid name $name!";
 434         (-e jailed_file("/etc/sshkeys/$name"));
 435 }
 436
 437 sub resolve_uid {
 438         my ($name) = @_;
 439         $Girocco::Config::chrooted and undef; # TODO for ACLs within chroot
 440         scalar(getpwnam($name));
 441 }
 442
 443
 444 1;