toolbox/check-perl-modules.pl

   1 #!/usr/bin/perl
   2
   3 # check-perl-modules.pl -- check for modules used by Girocco
   4 # Copyright (c) 2013 Kyle J. McKay.  All rights reserved.
   5 # License GPLv2+: GNU GPL version 2 or later.
   6 # www.gnu.org/licenses/gpl-2.0.html
   7 # This is free software: you are free to change and redistribute it.
   8 # There is NO WARRANTY, to the extent permitted by law.
   9
  10 # Attempt to require all the modules used by Perl anywhere in Girocco and
  11 # report the failures.  There is special handling for the SHA-1 functions
  12 # and some other optional modules.
  13
  14 # These ones are not errors
  15
  16 eval {require Proc::ProcessTable; 1} or
  17 print "Note: missing Perl module Proc::ProcessTable, deprecated ".
  18         "toolbox/kill-stale-daemons.pl will not function\n";
  19
  20 eval {require HTML::Entities; 1} or
  21 print "Warning: missing Perl module HTML::Entities, gitweb ".
  22         "email obfuscation will be partially disabled\n";
  23
  24 eval {require HTML::TagCloud; 1} or
  25 print "Warning: missing Perl module HTML::TagCloud, optional gitweb tag cloud ".
  26         "display will be all one size\n";
  27
  28 eval {require HTTP::Date; 1} ||
  29 eval {require Time::ParseDate; 1} or
  30 print "Warning: missing Perl module HTTP::Date and Time::ParseDate, gitweb ".
  31         "will always return true to if-modified-since feed requests\n";
  32
  33 # These ones are required
  34
  35 my $errors = 0;
  36
  37 # For SHA1, any of Digest::SHA, Digest::SHA1 or Digest::SHA::PurePerl will do
  38
  39 eval {require Digest::SHA; 1} ||
  40 eval {require Digest::SHA1; 1} ||
  41 eval {require Digest::SHA::PurePerl; 1} or
  42 ++$errors,
  43 print STDERR "One of the Perl modules Digest::SHA or Digest::SHA1 or "
  44 . "Digest::SHA::PurePerl must be available\n";
  45
  46 my @modules = qw(
  47         CGI
  48         CGI::Carp
  49         CGI::Util
  50         Digest::MD5
  51         Encode
  52         Errno
  53         Fcntl
  54         File::Basename
  55         File::Find
  56         File::Spec
  57         File::stat
  58         Getopt::Long
  59         IO::Handle
  60         IO::Socket
  61         IPC::Open2
  62         JSON
  63         LWP::UserAgent
  64         MIME::Base64
  65         Pod::Usage
  66         POSIX
  67         RPC::XML
  68         RPC::XML::Client
  69         Socket
  70         Storable
  71         Time::HiRes
  72         Time::Local
  73 );
  74
  75 my %imports = (
  76         Time::HiRes => [qw(gettimeofday tv_interval)],
  77 );
  78
  79 foreach my $module (@modules) {
  80         my $imports = '';
  81         $imports = " qw(".join(' ', @{$imports{$module}}).")"
  82                 if $imports{$module};
  83         eval "use $module$imports; 1" or
  84         ++$errors, print STDERR "Missing required Perl module $module$imports\n";
  85 }
  86
  87 eval {require JSON; 1} &&
  88 eval {require LWP::UserAgent; 1} &&
  89 eval {require RPC::XML; 1} &&
  90 eval {require RPC::XML::Client; 1} or
  91 print STDERR "Note: Perl modules JSON, LWP::UserAgent, RPC::XML and RPC::".
  92         "XML::Client are required by the ref-change notification mechanism\n";
  93
  94 my $fcgi_ok = 1;
  95 eval {require FCGI; 1} or $fcgi_ok = 0,
  96 print STDERR "Note: running gitweb.cgi in FastCGI mode requires ".
  97         "the missing Perl module FCGI\n";
  98 eval {require CGI::Fast; 1} or $fcgi_ok = 0,
  99 print STDERR "Note: running gitweb.cgi in FastCGI mode requires ".
 100         "the missing Perl module CGI::Fast\n";
 101 !$fcgi_ok || eval {require FCGI::ProcManager; 1} or
 102 print STDERR "Note: gitweb.cgi running in FastCGI mode requires ".
 103         "missing FCGI::ProcManager to support the --nproc option\n";
 104
 105 exit($errors ? 1 : 0);