toolbox/update-all-config.pl

   1 #!/usr/bin/perl
   2
   3 # update-all-config.pl - Update all out-of-date config
   4
   5 use strict;
   6 use warnings;
   7 use vars qw($VERSION);
   8 BEGIN {*VERSION = \'2.0'}
   9 use File::Basename;
  10 use File::Spec;
  11 use Cwd qw(realpath);
  12 use POSIX qw();
  13 use Getopt::Long;
  14 use Pod::Usage;
  15 use lib "__BASEDIR__";
  16 use Girocco::Config;
  17 use Girocco::Util;
  18 use Girocco::CLIUtil;
  19 use Girocco::Project;
  20
  21 my $shbin;
  22 BEGIN {
  23     $shbin = $Girocco::Config::posix_sh_bin;
  24     defined($shbin) && $shbin ne "" or $shbin = "/bin/sh";
  25 }
  26
  27 exit(&main(@ARGV)||0);
  28
  29 my ($dryrun, $force, $quiet);
  30
  31 sub die_usage {
  32         pod2usage(-exitval => 2);
  33 }
  34
  35 sub do_help {
  36         pod2usage(-verbose => 2, -exitval => 0);
  37 }
  38
  39 sub do_version {
  40         print basename($0), " version ", $VERSION, "\n";
  41         exit 0;
  42 }
  43
  44 my ($dmode, $dperm, $drwxmode, $fmode, $fmodeoct, $fperm, $wall);
  45 BEGIN {
  46         $dmode=02775;
  47         $dperm='drwxrwsr-x';
  48         $drwxmode='ug+rwx,o+rx';
  49         $fmode=0664;
  50         $fmodeoct='0664';
  51         $fperm='-rw-rw-r--';
  52         $wall=0;
  53 }
  54
  55 my $owning_group_id;
  56 my $htmlcache_owning_group_id;
  57 my $ctags_owning_group_id;
  58
  59 sub main {
  60         local *ARGV = \@_;
  61         my ($help, $version);
  62
  63         umask 002;
  64         close(DATA) if fileno(DATA);
  65         Getopt::Long::Configure('bundling');
  66         GetOptions(
  67                 'help|h'        => sub {do_help},
  68                 'version|V'     => sub {do_version},
  69                 'dry-run|n'     => \$dryrun,
  70                 'quiet|q'       => \$quiet,
  71                 'force|f'       => \$force,
  72         ) or die_usage;
  73         $dryrun and $quiet = 0;
  74
  75         -f jailed_file("/etc/group") or
  76                 die "Girocco group file not found: " . jailed_file("/etc/group") . "\n";
  77
  78         if (!defined($Girocco::Config::owning_group) || $Girocco::Config::owning_group eq "") {
  79                 die "\$Girocco::Config::owning_group unset, refusing to run without --force\n" unless $force;
  80                 $dmode=02777;
  81                 $dperm='drwxrwsrwx';
  82                 $drwxmode='a+rwx';
  83                 $fmode=0666;
  84                 $fmodeoct='0666';
  85                 $fperm='-rw-rw-rw-';
  86                 $wall=1;
  87                 warn "Mode 666 in effect\n" unless $quiet;
  88         } elsif (($owning_group_id = scalar(getgrnam($Girocco::Config::owning_group))) !~ /^\d+$/) {
  89                 die "\$Girocco::Config::owning_group invalid ($Girocco::Config::owning_group), refusing to run\n";
  90         }
  91         if (defined($owning_group_id) && $Girocco::Config::htmlcache_owning_group) {
  92                 die "\$Girocco::Config::htmlcache_owning_group invalid ($Girocco::Config::htmlcache_owning_group), refusing to run\n"
  93                 unless ($htmlcache_owning_group_id = scalar(getgrnam($Girocco::Config::htmlcache_owning_group))) =~ /^\d+$/;
  94         }
  95         if (defined($owning_group_id) && $Girocco::Config::ctags_owning_group) {
  96                 die "\$Girocco::Config::ctags_owning_group invalid ($Girocco::Config::ctags_owning_group), refusing to run\n"
  97                 unless ($ctags_owning_group_id = scalar(getgrnam($Girocco::Config::ctags_owning_group))) =~ /^\d+$/;
  98         }
  99
 100         my @allprojs = Girocco::Project::get_full_list;
 101         my @projects = ();
 102
 103         my $root = $Girocco::Config::reporoot;
 104         $root or die "\$Girocco::Config::reporoot is invalid\n";
 105         $root =~ s,/+$,,;
 106         $root ne "" or $root = "/";
 107         $root = realpath($root);
 108         if (@ARGV) {
 109                 my %projnames = map {($_ => 1)} @allprojs;
 110                 foreach (@ARGV) {
 111                         s,/+$,,;
 112                         $_ or $_ = "/";
 113                         -d $_ and $_ = realpath($_);
 114                         s,^\Q$root\E/,,;
 115                         s,\.git$,,;
 116                         if (!exists($projnames{$_})) {
 117                                 warn "$_: unknown to Girocco (not in etc/group)\n"
 118                                         unless $quiet;
 119                                 next;
 120                         }
 121                         push(@projects, $_);
 122                 }
 123         } else {
 124                 @projects = sort {lc($a) cmp lc($b)} @allprojs;
 125         }
 126
 127         nice_me(18);
 128         my $bad = 0;
 129         foreach (@projects) {
 130                 my $projdir = "$root/$_.git";
 131                 if (! -d $projdir) {
 132                         warn "$_: does not exist -- skipping\n" unless $quiet;
 133                         next;
 134                 }
 135                 if (!is_git_dir($projdir)) {
 136                         warn "$_: is not a .git directory -- skipping\n" unless $quiet;
 137                         next;
 138                 }
 139                 if (-e "$projdir/.noconfig") {
 140                         warn "$_: found .noconfig -- skipping\n" unless $quiet;
 141                         next;
 142                 }
 143                 if (!chdir($projdir)) {
 144                         warn "$_: chdir to project directory failed: $!\n" unless $quiet;
 145                         next;
 146                 }
 147                 process_one_project($_) or $bad = 1;
 148         }
 149
 150         return $bad ? 1 : 0;
 151 }
 152
 153 my (@mkdirs, @mkfiles);
 154 my (@fixdpermsdirs, @fixdpermsrwx, @fixfpermsfiles, @fixfpermsdirs);
 155 BEGIN {
 156         @mkdirs = qw(refs info hooks ctags htmlcache bundles reflogs objects objects/info);
 157         @mkfiles = qw(config info/lastactivity);
 158         @fixdpermsdirs = qw(. refs info ctags htmlcache bundles reflogs objects objects/info);
 159         @fixdpermsrwx = qw(refs objects);
 160         @fixfpermsfiles = qw(HEAD config description packed-refs README.html info/lastactivity
 161                 info/alternates info/http-alternates info/packs);
 162         @fixfpermsdirs = qw(ctags);
 163 }
 164
 165 my (@boolvars, @falsevars, @false0vars, @truevars);
 166 BEGIN {
 167         @boolvars = qw(gitweb.statusupdates);
 168         @falsevars = qw(core.ignorecase receive.denynonfastforwards);
 169         @false0vars = qw(gc.auto receive.autogc);
 170         @truevars = qw(receive.updateserverinfo repack.writebitmaps transfer.fsckobjects);
 171 }
 172
 173 my $hdr;
 174
 175 sub defval($$) {
 176         return defined($_[0]) ? $_[0] : $_[1];
 177 }
 178
 179 sub openfind_ {
 180         my $noe = shift;
 181         my $duperr;
 182         if ($noe) {{
 183                 open $duperr, '>&2' or last;
 184                 my $errfd = POSIX::open(File::Spec->devnull, &POSIX::O_RDWR);
 185                 defined($errfd) or close($duperr), $duperr = undef, last;
 186                 POSIX::dup2($errfd, 2) or close($duperr), $duperr = undef;
 187                 POSIX::close($errfd);
 188         }}
 189         my $fd;
 190         my $ans = open $fd, '-|', "find", @_;
 191         if ($noe && defined($duperr) && defined(fileno($duperr))) {
 192                 POSIX::dup2(fileno($duperr), 2);
 193                 close($duperr);
 194         }
 195         $ans or die "find failed: $!\n";
 196         return $fd;
 197 }
 198
 199 sub openfind { return openfind_(0, @_); }
 200 sub openfindne { return openfind_(1, @_); }
 201
 202 sub all_remotes
 203 {
 204         my $config = shift;
 205         return map({
 206                 my ($i,$r) = (index($_,"."),rindex($_,"."));
 207                 substr($_,$i+1,$r-$i-1);
 208         } grep(/^remote\.[^.].*\.url$/i, keys(%$config)));
 209 }
 210
 211 sub has_default_fetch_spec
 212 {
 213         my $config = shift;
 214         my $default = $config->{'remotes.default'};
 215         my @remotes = defined($default) ? split(' ', $default) : all_remotes($config);
 216         foreach (@remotes) {
 217                 defval($config->{"remote.$_.url"},"") ne "" or next;
 218                 !defined($default) && git_bool($config->{"remote.$_.skipdefaultupdate"}) and next;
 219                 defval($config->{"remote.$_.fetch"},"") ne "" and return 1;
 220         }
 221         return 0;
 222 }
 223
 224 sub is_native_git_mirror_url
 225 {
 226         my $bu = shift;
 227         defined($bu) && $bu ne "" or return 0;
 228         # All current or former natively supported by Git URLs return true:
 229         #  1. rsync: (removed in 2.8.0, also recognize rsync+ and rsync::)
 230         #  2. ftp:/ftps: (strongly discouraged)
 231         #  3. git:
 232         #  4. http:/https: (smart and non-smart)
 233         #  5. ssh:
 234         #  6. scp-like ssh syntax [user@]host:[^:/]
 235         return $bu =~ /^(?:
 236                 rsync[:+]       |
 237                 ftps?:          |
 238                 git:            |
 239                 https?:         |
 240                 ssh:            |
 241                 (?:[^\s:\@]+\@)?[^\s:\@+]+:(?!\/\/)[^\s:\\]
 242         )/xi;
 243 }
 244
 245 sub process_one_project
 246 {
 247         my ($proj) = @_;
 248         my $bad = 0;
 249         my $reallybad = 0;
 250         $hdr = 0;
 251         do {
 252                 if (! -d $_) {
 253                         if (-e $_) {
 254                                 warn "$proj: bypassing project, exists but not directory: $_\n" unless $quiet;
 255                                 $reallybad = $bad = 1;
 256                                 last;
 257                         } else {
 258                                 my $grpid = $owning_group_id;
 259                                 $grpid = $htmlcache_owning_group_id
 260                                         if $htmlcache_owning_group_id && $_ eq "htmlcache";
 261                                 $grpid = $ctags_owning_group_id
 262                                         if $ctags_owning_group_id && $_ eq "ctags";
 263                                 do_mkdir($proj, $_, $grpid) or $bad = 1, last;
 264                         }
 265                 }
 266         } foreach (@mkdirs);
 267         return 0 if $reallybad;
 268
 269         -d $_ && check_dperm($proj, $_) or $bad = 1 foreach (@fixdpermsdirs);
 270         my $fp = openfindne(@fixdpermsrwx, qw(-xdev -type d ( ! -path objects/?? -o -prune ) ! -perm), "-$drwxmode", "-print");
 271         while (<$fp>) {
 272                 chomp;
 273                 change_dpermrwx($proj, $_) or $bad = 1;
 274         }
 275         close($fp) or $bad = 1;
 276         $fp = openfind(qw(. -xdev -type d ( ! -path ./objects/?? -o -prune ) ! -perm -a+rx -print));
 277         while (<$fp>) {
 278                 chomp;
 279                 change_dpermrx($proj, $_) or $bad = 1;
 280         }
 281         close($fp) or $bad = 1;
 282
 283         do {
 284                 if (-e $_) {
 285                         if (! -f $_) {
 286                                 warn "$proj: bypassing project, exists but not file: $_\n" unless $quiet;
 287                                 $reallybad = $bad = 1;
 288                                 last;
 289                         }
 290                 } else {
 291                         my $result = "(dryrun)";
 292                         if (!$dryrun) {
 293                                 $result = "";
 294                                 my $tf;
 295                                 open($tf, '>', $_) && close ($tf) or $result = "FAILED", $bad = 1;
 296                         }
 297                         pmsg($proj, "$_: created", $result) unless $quiet;
 298                 }
 299         } foreach(@mkfiles);
 300         return 0 if $reallybad;
 301
 302         $dryrun || check_fperm($proj, "config") or $bad = 1;
 303         my $config = read_config_file_hash("config", !$quiet);
 304         if (!defined($config)) {
 305                 warn "$proj: could not read config file -- skipping\n" unless $quiet;
 306                 return 0;
 307         }
 308
 309         my $do_config = sub {
 310                 my ($item, $val) = @_;
 311                 my $oldval = defval($config->{$item},"");
 312                 my $result = "(dryrun)";
 313                 if (!$dryrun) {
 314                         $result = "";
 315                         system($Girocco::Config::git_bin, "config", "--file", "config", "--replace-all", $item, $val) == 0 or
 316                                 $result = "FAILED", $bad = 1;
 317                 }
 318                 if (!exists($config->{$item})) {
 319                         pmsg($proj, "config $item: created \"$val\"", $result) unless $quiet;
 320                 } else {
 321                         pmsg($proj, "config $item: \"$oldval\" -> \"$val\"", $result) unless $quiet;
 322                 }
 323         };
 324         my $do_config_unset = sub {
 325                 my ($item, $msg) = @_;
 326                 defined($msg) or $msg = "";
 327                 $msg eq "" or $msg = " " . $msg;
 328                 my $oldval = defval($config->{$item},"");
 329                 my $result = "(dryrun)";
 330                 if (!$dryrun) {
 331                         $result = "";
 332                         system($Girocco::Config::git_bin, "config", "--file", "config", "--unset-all", $item) == 0 or
 333                                 $result = "FAILED", $bad = 1;
 334                 }
 335                 pmsg($proj, "config $item: removed$msg \"$oldval\"", $result) unless $quiet;
 336         };
 337
 338         my $repovers = $config->{'core.repositoryformatversion'};
 339         if (!defined($repovers)) {
 340                 $repovers = "";
 341         } elsif ($repovers =~ /^[2345]$/) {
 342                 pmsg($proj, "WARNING: unknown core.repositoryformatversion value left unchanged: \"$repovers\"");
 343         } elsif ($repovers !~ /^[01]$/) {
 344                 pmsg($proj, "WARNING: replacing invalid core.repositoryformatversion value: \"$repovers\"") unless $quiet;
 345                 $repovers = "";
 346         }
 347         &$do_config('core.repositoryformatversion', 0) if $repovers eq "";
 348         my $hookspath = $Girocco::Config::reporoot . "/_global/hooks";
 349         defval($config->{'core.hookspath'},"") eq $hookspath or &$do_config('core.hookspath', $hookspath);
 350         my $cmplvl = defval($config->{'core.compression'},"");
 351         if ($cmplvl !~ /^-?\d+$/ || $cmplvl < -1 || $cmplvl > 9 || "" . (0 + $cmplvl) ne "" . $cmplvl) {
 352                 pmsg($proj, "WARNING: replacing invalid core.compression value: \"$cmplvl\"") unless $cmplvl eq "" || $quiet;
 353                 $cmplvl = "";
 354         } elsif ($cmplvl != 5) {
 355                 pmsg($proj, "WARNING: suboptimal core.compression value left unchanged: \"$cmplvl\"") unless $quiet;
 356         }
 357         $cmplvl ne "" or &$do_config('core.compression', 5);
 358         my $grpshr = defval($config->{'core.sharedrepository'},"");
 359         if ($grpshr eq "" || (valid_bool($grpshr) && !git_bool($grpshr))) {
 360                 &$do_config('core.sharedrepository', 1);
 361         } elsif (!(valid_bool($grpshr) && git_bool($grpshr))) {
 362                 pmsg($proj, "WARNING: odd core.sharedrepository value left unchanged: \"$grpshr\"");
 363         }
 364         if (git_bool($config->{'core.bare'})) {
 365                 my $setlaru = 1;
 366                 my $laru = $config->{'core.logallrefupdates'};
 367                 if (defined($laru)) {
 368                         if (valid_bool($laru)) {
 369                                 $setlaru = 0;
 370                                 if (git_bool($laru)) {
 371                                         pmsg($proj, "WARNING: core.logallrefupdates is true (left unchanged)") unless $quiet;
 372                                 }
 373                         } else {
 374                                 pmsg($proj, "WARNING: replacing non-boolean core.logallrefupdates value") unless $quiet;
 375                         }
 376                 }
 377                 !$setlaru or &$do_config('core.logallrefupdates', 'false');
 378         } else {
 379                 pmsg($proj, "WARNING: core.bare is not true (left unchanged)") unless $quiet;
 380         }
 381         my $precious = defval($config->{'extensions.preciousobjects'},"");
 382         valid_bool($precious) && git_bool($precious) or &$do_config('extensions.preciousobjects', 'true');
 383         defval($config->{'transfer.unpacklimit'},"") eq "1" or &$do_config('transfer.unpacklimit', 1);
 384         lc(defval($config->{'receive.denydeletecurrent'},"")) eq "warn" or &$do_config('receive.denydeletecurrent', 'warn');
 385         do {
 386                 !exists($config->{$_}) || valid_bool(defval($config->{$_},"")) or &$do_config_unset($_, "(not a boolean)");
 387         } foreach (@boolvars);
 388         do {
 389                 (valid_bool(defval($config->{$_},"")) && !git_bool($config->{$_})) or &$do_config($_, "false");
 390         } foreach (@falsevars);
 391         do {
 392                 (valid_bool(defval($config->{$_},"")) && !git_bool($config->{$_})) or &$do_config($_, 0);
 393         } foreach (@false0vars);
 394         do {
 395                 (valid_bool(defval($config->{$_},"")) && git_bool($config->{$_})) or &$do_config($_, "true");
 396         } foreach (@truevars);
 397
 398         if (defined($Girocco::Config::owning_group) && $Girocco::Config::owning_group ne "") {
 399                 $fp = openfind(qw(. -xdev ( -type d -o -type f ) ! -group), $Girocco::Config::owning_group, "-print");
 400                 while (<$fp>) {
 401                         chomp;
 402                         my $grpid = $owning_group_id;
 403                         $grpid = $htmlcache_owning_group_id if $htmlcache_owning_group_id && m{^\./htmlcache(?:/|$)}i;
 404                         $grpid = $ctags_owning_group_id if $ctags_owning_group_id && m{^\./ctags(?:/|$)}i;
 405                         change_group($proj, $_, $grpid) or $bad = 1;
 406                 }
 407                 close($fp) or $bad = 1;
 408         }
 409         foreach (@fixfpermsfiles) {
 410                 if (-e $_) {
 411                         if (! -f $_) {
 412                                 warn "$proj: bypassing project, exists but not file: $_\n" unless $quiet;
 413                                 $reallybad = $bad = 1;
 414                                 last;
 415                         }
 416                         check_fperm($proj, $_) or $bad = 1;
 417                 }
 418         }
 419         return 0 if $reallybad;
 420
 421         $fp = openfindne(@fixfpermsdirs, qw(-xdev -type f ! -perm), $fmodeoct, "-print");
 422         while (<$fp>) {
 423                 chomp;
 424                 check_fperm($proj, $_) or $bad = 1;
 425         }
 426         close($fp) or $bad = 1;
 427         $fp = openfind(qw(. -xdev -type f ! -perm -a+r -print));
 428         while (<$fp>) {
 429                 chomp;
 430                 check_fpermr($proj, $_) or $bad = 1;
 431         }
 432         close($fp) or $bad = 1;
 433         $fp = openfind(qw(. -xdev -type d ( -path ./hooks -o -path ./mob/hooks ) -prune -o -type f -perm +a+x -print));
 434         while (<$fp>) {
 435                 chomp;
 436                 check_fpermnox($proj, $_) or $bad = 1;
 437         }
 438         close($fp) or $bad = 1;
 439
 440         my $bu = defval($config->{'gitweb.baseurl'},"");
 441         if (-e ".nofetch") {
 442                 $bu eq "" or pmsg($proj, "WARNING: .nofetch exists but gitweb.baseurl is not empty ($bu)") unless $quiet;
 443         } else {
 444                 if ($bu eq "") {
 445                         if (has_default_fetch_spec($config)) {
 446                                 pmsg($proj, "WARNING: gitweb.baseurl is empty and .nofetch does not exist but fetch spec does") unless $quiet;
 447                         } else {
 448                                 pmsg($proj, "WARNING: gitweb.baseurl is empty and .nofetch does not exist") unless $quiet;
 449                         }
 450                 } elsif (is_native_git_mirror_url($bu) && !has_default_fetch_spec($config)) {
 451                         pmsg($proj, "WARNING: gitweb.baseurl is not empty but fetch spec is") unless $quiet;
 452                 }
 453         }
 454
 455         return !$bad;
 456 }
 457
 458 sub do_mkdir
 459 {
 460         my ($proj, $subdir, $grpid) = @_;
 461         my $result = "";
 462         if (!$dryrun) {
 463                 mkdir($subdir) && -d "$subdir" or $result = "FAILED";
 464                 if ($grpid && $grpid != $owning_group_id) {
 465                         my @info = stat($subdir);
 466                         if (@info < 6 || $info[2] eq "" || $info[4] eq "" || $info[5] eq "") {
 467                                 $result = "FAILED";
 468                         } elsif ($info[5] != $grpid) {
 469                                 if (!chown($info[4], $grpid, $subdir)) {
 470                                         $result = "FAILED";
 471                                         warn "chgrp: ($proj) $subdir: $!\n" unless $quiet;
 472                                 } elsif (!chmod($info[2] & 07777, $subdir)) {
 473                                         $result = "FAILED";
 474                                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 475                                 }
 476                         }
 477                 }
 478         } else {
 479                 $result = "(dryrun)";
 480         }
 481         pmsg($proj, "$subdir/: created", $result);
 482         return $result ne "FAILED";
 483 }
 484
 485 sub check_dperm {
 486         my ($proj, $subdir) = @_;
 487         my $oldmode = (stat($subdir))[2];
 488         if (!defined($oldmode) || $oldmode eq "") {
 489                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 490                 return 0;
 491         }
 492         my $newmode = ($oldmode & ~07777) | $dmode;
 493         $newmode == $oldmode and return 1;
 494         my $result = "";
 495         if (!$dryrun) {
 496                 if (!chmod($newmode & 07777, $subdir)) {
 497                         $result = "FAILED";
 498                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 499                 }
 500         } else {
 501                 $result = "(dryrun)";
 502         }
 503         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 504         return $result ne "FAILED";
 505 }
 506
 507 sub change_dpermrwx {
 508         my ($proj, $subdir) = @_;
 509         my $oldmode = (stat($subdir))[2];
 510         if (!defined($oldmode) || $oldmode eq "") {
 511                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 512                 return 0;
 513         }
 514         my $newmode = $oldmode | ($wall ? 0777 : 0775);
 515         $newmode == $oldmode and return 1;
 516         my $result = "";
 517         if (!$dryrun) {
 518                 if (!chmod($newmode & 07777, $subdir)) {
 519                         $result = "FAILED";
 520                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 521                 }
 522         } else {
 523                 $result = "(dryrun)";
 524         }
 525         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 526         return $result ne "FAILED";
 527 }
 528
 529 sub change_dpermrx {
 530         my ($proj, $subdir) = @_;
 531         $subdir =~ s,^\./,,;
 532         my $oldmode = (stat($subdir))[2];
 533         if (!defined($oldmode) || $oldmode eq "") {
 534                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 535                 return 0;
 536         }
 537         my $newmode = $oldmode | 0555;
 538         $newmode == $oldmode and return 1;
 539         my $result = "";
 540         if (!$dryrun) {
 541                 if (!chmod($newmode & 07777, $subdir)) {
 542                         $result = "FAILED";
 543                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 544                 }
 545         } else {
 546                 $result = "(dryrun)";
 547         }
 548         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 549         return $result ne "FAILED";
 550 }
 551
 552 sub check_fperm {
 553         my ($proj, $file) = @_;
 554         my $oldmode = (stat($file))[2];
 555         if (!defined($oldmode) || $oldmode eq "") {
 556                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 557                 return 0;
 558         }
 559         my $newmode = ($oldmode & ~07777) | $fmode;
 560         $newmode == $oldmode and return 1;
 561         my $result = "";
 562         if (!$dryrun) {
 563                 if (!chmod($newmode & 07777, $file)) {
 564                         $result = "FAILED";
 565                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 566                 }
 567         } else {
 568                 $result = "(dryrun)";
 569         }
 570         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 571         return $result ne "FAILED";
 572 }
 573
 574 sub check_fpermr {
 575         my ($proj, $file) = @_;
 576         $file =~ s,^\./,,;
 577         my $oldmode = (stat($file))[2];
 578         if (!defined($oldmode) || $oldmode eq "") {
 579                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 580                 return 0;
 581         }
 582         my $newmode = $oldmode | 0444;
 583         $newmode == $oldmode and return 1;
 584         my $result = "";
 585         if (!$dryrun) {
 586                 if (!chmod($newmode & 07777, $file)) {
 587                         $result = "FAILED";
 588                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 589                 }
 590         } else {
 591                 $result = "(dryrun)";
 592         }
 593         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 594         return $result ne "FAILED";
 595 }
 596
 597 sub check_fpermnox {
 598         my ($proj, $file) = @_;
 599         $file =~ s,^\./,,;
 600         my $oldmode = (stat($file))[2];
 601         if (!defined($oldmode) || $oldmode eq "") {
 602                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 603                 return 0;
 604         }
 605         my $newmode = $oldmode & ~0111;
 606         $newmode == $oldmode and return 1;
 607         my $result = "";
 608         if (!$dryrun) {
 609                 if (!chmod($newmode & 07777, $file)) {
 610                         $result = "FAILED";
 611                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 612                 }
 613         } else {
 614                 $result = "(dryrun)";
 615         }
 616         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 617         return $result ne "FAILED";
 618 }
 619
 620 sub change_group {
 621         my ($proj, $item, $grpid) = @_;
 622         $item =~ s,^\./,,;
 623         my @info = stat($item);
 624         if (@info < 6 || $info[2] eq "" || $info[4] eq "" || $info[5] eq "") {
 625                 warn "chgrp: ($proj) $item: No such file or directory\n" unless $quiet;
 626                 return 0;
 627         }
 628         $info[5] == $grpid and return 1;
 629         my $result = "";
 630         if (!$dryrun) {
 631                 if (!chown($info[4], $grpid, $item)) {
 632                         $result = "FAILED";
 633                         warn "chgrp: ($proj) $item: $!\n" unless $quiet;
 634                 } elsif (!chmod($info[2] & 07777, $item)) {
 635                         $result = "FAILED";
 636                         warn "chmod: ($proj) $item: $!\n" unless $quiet;
 637                 }
 638         } else {
 639                 $result = "(dryrun)";
 640         }
 641         my $isdir = ((($info[2] >> 12) & 017) == 004) ? '/' : '';
 642         pmsg($proj, "$item$isdir: group", get_grp_nam($info[5]), '->', get_grp_nam($grpid), $result);
 643         return $result ne "FAILED";
 644 }
 645
 646 my $wrote; BEGIN {$wrote = ""}
 647 sub pmsg {
 648         my $proj = shift;
 649         my $msg = join(" ", @_);
 650         $msg =~ s/\s+$//;
 651         my $prefix = "";
 652         if (!$hdr) {
 653                 $prefix = $wrote . $proj . ":\n";
 654                 $hdr = 1;
 655         }
 656         print $prefix, "  ", join(' ', @_), "\n";
 657         $wrote = "\n";
 658 }
 659
 660 my %ftypes;
 661 BEGIN {%ftypes = (
 662         000 => '?',
 663         001 => 'p',
 664         002 => 'c',
 665         003 => '?',
 666         004 => 'd',
 667         005 => '?',
 668         006 => 'b',
 669         007 => '?',
 670         010 => '-',
 671         011 => '?',
 672         012 => 'l',
 673         013 => '?',
 674         014 => 's',
 675         015 => '?',
 676         016 => 'w',
 677         017 => '?'
 678 )}
 679 my %fperms;
 680 BEGIN {%fperms = (
 681         0 => '---',
 682         1 => '--x',
 683         2 => '-w-',
 684         3 => '-wx',
 685         4 => 'r--',
 686         5 => 'r-x',
 687         6 => 'rw-',
 688         7 => 'rwx'
 689 )}
 690
 691 sub get_mode_perm {
 692         my $mode = $_[0];
 693         my $str = $ftypes{($mode >> 12) & 017} .
 694                 $fperms{($mode >> 6) & 7} .
 695                 $fperms{($mode >> 3) & 7} .
 696                 $fperms{$mode & 7};
 697         substr($str,3,1) = ($mode & 0100) ? 's' : 'S' if $mode & 04000;
 698         substr($str,6,1) = ($mode & 0010) ? 's' : 'S' if $mode & 02000;
 699         substr($str,9,1) = ($mode & 0001) ? 't' : 'T' if $mode & 01000;
 700         return $str;
 701 }
 702
 703 sub get_perm {
 704         my $mode = (stat($_[0]))[2];
 705         defined($mode) or return '??????????';
 706         return get_mode_perm($mode);
 707 }
 708
 709 sub get_grp_nam {
 710         my $grpid = $_[0];
 711         defined($grpid) or return '?';
 712         my $grpnm = scalar(getgrgid($grpid));
 713         return defined($grpnm) && $grpnm ne "" ? $grpnm : $grpid;
 714 }
 715
 716 sub get_grp {
 717         my $grp = (stat($_[0]))[5];
 718         defined($grp) or return '?';
 719         return get_grp_nam($grp);
 720 }
 721
 722 __END__
 723
 724 =head1 NAME
 725
 726 update-all-config.pl - Update all projects' config settings
 727
 728 =head1 SYNOPSIS
 729
 730 update-all-config.pl [<options>] [<projname>]...
 731
 732  Options:
 733    -h | --help                  detailed instructions
 734    -V | --version               show version
 735    -n | --dry-run               show what would be done but don't do it
 736    -f | --force                 run without a Config.pm owning_group
 737    -q | --quiet                 suppress change messages
 738
 739  <projname>                     if given, only operate on these projects
 740
 741 =head1 OPTIONS
 742
 743 =over 8
 744
 745 =item B<-h>, B<--help>
 746
 747 Print the full description of update-all-config.pl's options.
 748
 749 =item B<-V>, B<--version>
 750
 751 Print the version of update-all-config.pl.
 752
 753 =item B<-n>, B<--dry-run>
 754
 755 Do not actually make any changes, just show what would be done without
 756 actually doing it.
 757
 758 =item B<-q>, B<--quiet>
 759
 760 Suppress the messages about what's actually being changed.  This option
 761 is ignored if B<--dry-run> is in effect.
 762
 763 The warnings about missing and unknown-to-Girocco projects are also
 764 suppressed by this option.
 765
 766 =item B<-f>, B<--force>
 767
 768 Allow running without a $Girocco::Config::owning_group set.  This is not
 769 recommended as it results in world-writable items being used (instead of
 770 just world-readable).
 771
 772 =item B<<projname>>
 773
 774 If no project names are specified then I<all> projects are processed.
 775
 776 If one or more project names are specified then only those projects are
 777 processed.  Specifying non-existent projects produces a warning for them,
 778 but the rest of the projects specified will still be processed.
 779
 780 Each B<projname> may be either a full absolute path starting with
 781 $Girocco::Config::reporoot or just the project name part with or without
 782 a trailing C<.git>.
 783
 784 Any explicitly specified projects that do exist but are not known to
 785 Girocco will be skipped (with a warning).
 786
 787 =back
 788
 789 =head1 DESCRIPTION
 790
 791 Inspect the C<config> files of Girocco projects (i.e. $GIT_DIR/config) and
 792 look for anomalies and out-of-date settings.
 793
 794 Additionally check the existence and permissions on various files and
 795 directories in the project.
 796
 797 If an explicity specified project is located under $Girocco::Config::reporoot
 798 but is not actually known to Girocco (i.e. it's not in the etc/group file)
 799 then it will be skipped.
 800
 801 By default, any anomalies or out-of-date settings will be corrected with a
 802 message to that effect.  However using B<--dry-run> will only show the
 803 correction(s) which would be made without making them and B<--quiet> will make
 804 the correction(s) without any messages.
 805
 806 Any projects that have a C<$GIT_DIR/.noconfig> file are always skipped (with a
 807 message unless B<--quiet> is used).
 808
 809 =cut