toolbox/update-all-config.pl

   1 #!/usr/bin/perl
   2
   3 # update-all-config.pl - Update all out-of-date config
   4
   5 use strict;
   6 use warnings;
   7 use vars qw($VERSION);
   8 BEGIN {*VERSION = \'2.0'}
   9 use File::Basename;
  10 use File::Spec;
  11 use Cwd qw(realpath);
  12 use POSIX qw();
  13 use Getopt::Long;
  14 use Pod::Usage;
  15 use lib "__BASEDIR__";
  16 use Girocco::Config;
  17 use Girocco::Util;
  18 use Girocco::CLIUtil;
  19 use Girocco::Project;
  20
  21 my $shbin;
  22 BEGIN {
  23     $shbin = $Girocco::Config::posix_sh_bin;
  24     defined($shbin) && $shbin ne "" or $shbin = "/bin/sh";
  25 }
  26
  27 exit(&main(@ARGV)||0);
  28
  29 my ($dryrun, $force, $quiet);
  30
  31 sub die_usage {
  32         pod2usage(-exitval => 2);
  33 }
  34
  35 sub do_help {
  36         pod2usage(-verbose => 2, -exitval => 0);
  37 }
  38
  39 sub do_version {
  40         print basename($0), " version ", $VERSION, "\n";
  41         exit 0;
  42 }
  43
  44 my ($dmode, $dperm, $drwxmode, $fmode, $fmodeoct, $fperm, $wall);
  45 BEGIN {
  46         $dmode=02775;
  47         $dperm='drwxrwsr-x';
  48         $drwxmode='ug+rwx,o+rx';
  49         $fmode=0664;
  50         $fmodeoct='0664';
  51         $fperm='-rw-rw-r--';
  52         $wall=0;
  53 }
  54
  55 my $owning_group_id;
  56
  57 sub main {
  58         local *ARGV = \@_;
  59         my ($help, $version);
  60
  61         umask 002;
  62         close(DATA) if fileno(DATA);
  63         Getopt::Long::Configure('bundling');
  64         GetOptions(
  65                 'help|h'        => sub {do_help},
  66                 'version|V'     => sub {do_version},
  67                 'dry-run|n'     => \$dryrun,
  68                 'quiet|q'       => \$quiet,
  69                 'force|f'       => \$force,
  70         ) or die_usage;
  71         $dryrun and $quiet = 0;
  72
  73         -f jailed_file("/etc/group") or
  74                 die "Girocco group file not found: " . jailed_file("/etc/group") . "\n";
  75
  76         if (!defined($Girocco::Config::owning_group) || $Girocco::Config::owning_group eq "") {
  77                 die "\$Girocco::Config::owning_group unset, refusing to run without --force\n" unless $force;
  78                 $dmode=02777;
  79                 $dperm='drwxrwsrwx';
  80                 $drwxmode='a+rwx';
  81                 $fmode=0666;
  82                 $fmodeoct='0666';
  83                 $fperm='-rw-rw-rw-';
  84                 $wall=1;
  85                 warn "Mode 666 in effect\n" unless $quiet;
  86         } elsif (($owning_group_id = scalar(getgrnam($Girocco::Config::owning_group))) !~ /^\d+$/) {
  87                 die "\$Girocco::Config::owning_group invalid ($Girocco::Config::owning_group), refusing to run\n";
  88         }
  89
  90         my @allprojs = Girocco::Project::get_full_list;
  91         my @projects = ();
  92
  93         my $root = $Girocco::Config::reporoot;
  94         $root or die "\$Girocco::Config::reporoot is invalid\n";
  95         $root =~ s,/+$,,;
  96         $root ne "" or $root = "/";
  97         $root = realpath($root);
  98         if (@ARGV) {
  99                 my %projnames = map {($_ => 1)} @allprojs;
 100                 foreach (@ARGV) {
 101                         s,/+$,,;
 102                         $_ or $_ = "/";
 103                         -d $_ and $_ = realpath($_);
 104                         s,^\Q$root\E/,,;
 105                         s,\.git$,,;
 106                         if (!exists($projnames{$_})) {
 107                                 warn "$_: unknown to Girocco (not in etc/group)\n"
 108                                         unless $quiet;
 109                                 next;
 110                         }
 111                         push(@projects, $_);
 112                 }
 113         } else {
 114                 @projects = sort {lc($a) cmp lc($b)} @allprojs;
 115         }
 116
 117         my $bad = 0;
 118         foreach (@projects) {
 119                 my $projdir = "$root/$_.git";
 120                 if (! -d $projdir) {
 121                         warn "$_: does not exist -- skipping\n" unless $quiet;
 122                         next;
 123                 }
 124                 if (!is_git_dir($projdir)) {
 125                         warn "$_: is not a .git directory -- skipping\n" unless $quiet;
 126                         next;
 127                 }
 128                 if (-e "$projdir/.noconfig") {
 129                         warn "$_: found .noconfig -- skipping\n" unless $quiet;
 130                         next;
 131                 }
 132                 if (!chdir($projdir)) {
 133                         warn "$_: chdir to project directory failed: $!\n" unless $quiet;
 134                         next;
 135                 }
 136                 process_one_project($_) or $bad = 1;
 137         }
 138
 139         return $bad ? 1 : 0;
 140 }
 141
 142 my (@mkdirs, @mkfiles);
 143 my (@fixdpermsdirs, @fixdpermsrwx, @fixfpermsfiles, @fixfpermsdirs);
 144 BEGIN {
 145         @mkdirs = qw(refs info hooks ctags htmlcache bundles reflogs objects objects/info);
 146         @mkfiles = qw(config info/lastactivity);
 147         @fixdpermsdirs = qw(. refs info ctags htmlcache bundles reflogs objects objects/info);
 148         @fixdpermsrwx = qw(refs objects);
 149         @fixfpermsfiles = qw(HEAD config description packed-refs README.html info/lastactivity
 150                 info/alternates info/http-alternates info/packs);
 151         @fixfpermsdirs = qw(ctags);
 152 }
 153
 154 my (@boolvars, @falsevars, @false0vars, @truevars);
 155 BEGIN {
 156         @boolvars = qw(gitweb.statusupdates);
 157         @falsevars = qw(core.ignorecase receive.denynonfastforwards);
 158         @false0vars = qw(gc.auto receive.autogc);
 159         @truevars = qw(receive.updateserverinfo repack.writebitmaps transfer.fsckobjects);
 160 }
 161
 162 my $hdr;
 163
 164 sub defval($$) {
 165         return defined($_[0]) ? $_[0] : $_[1];
 166 }
 167
 168 sub openfind_ {
 169         my $noe = shift;
 170         my $duperr;
 171         if ($noe) {{
 172                 open $duperr, '>&2' or last;
 173                 my $errfd = POSIX::open(File::Spec->devnull, &POSIX::O_RDWR);
 174                 defined($errfd) or close($duperr), $duperr = undef, last;
 175                 POSIX::dup2($errfd, 2) or close($duperr), $duperr = undef;
 176                 POSIX::close($errfd);
 177         }}
 178         my $fd;
 179         my $ans = open $fd, '-|', "find", @_;
 180         if ($noe && defined($duperr) && defined(fileno($duperr))) {
 181                 POSIX::dup2(fileno($duperr), 2);
 182                 close($duperr);
 183         }
 184         $ans or die "find failed: $!\n";
 185         return $fd;
 186 }
 187
 188 sub openfind { return openfind_(0, @_); }
 189 sub openfindne { return openfind_(1, @_); }
 190
 191 sub process_one_project
 192 {
 193         my ($proj) = @_;
 194         my $bad = 0;
 195         my $reallybad = 0;
 196         $hdr = 0;
 197         do {
 198                 if (! -d $_) {
 199                         if (-e $_) {
 200                                 warn "$proj: bypassing project, exists but not directory: $_\n" unless $quiet;
 201                                 $reallybad = $bad = 1;
 202                                 last;
 203                         } else {
 204                                 do_mkdir($proj, $_) or $bad = 1, last;
 205                         }
 206                 }
 207         } foreach (@mkdirs);
 208         return 0 if $reallybad;
 209
 210         -d $_ && check_dperm($proj, $_) or $bad = 1 foreach (@fixdpermsdirs);
 211         my $fp = openfindne(@fixdpermsrwx, qw(-xdev -type d ( ! -path objects/?? -o -prune ) ! -perm), "-$drwxmode", "-print");
 212         while (<$fp>) {
 213                 chomp;
 214                 change_dpermrwx($proj, $_) or $bad = 1;
 215         }
 216         close($fp) or $bad = 1;
 217         $fp = openfind(qw(. -xdev -type d ( ! -path ./objects/?? -o -prune ) ! -perm -a+rx -print));
 218         while (<$fp>) {
 219                 chomp;
 220                 change_dpermrx($proj, $_) or $bad = 1;
 221         }
 222         close($fp) or $bad = 1;
 223
 224         do {
 225                 if (-e $_) {
 226                         if (! -f $_) {
 227                                 warn "$proj: bypassing project, exists but not file: $_\n" unless $quiet;
 228                                 $reallybad = $bad = 1;
 229                                 last;
 230                         }
 231                 } else {
 232                         my $result = "(dryrun)";
 233                         if (!$dryrun) {
 234                                 $result = "";
 235                                 my $tf;
 236                                 open($tf, '>', $_) && close ($tf) or $result = "FAILED", $bad = 1;
 237                         }
 238                         pmsg($proj, "$_: created", $result) unless $quiet;
 239                 }
 240         } foreach(@mkfiles);
 241         return 0 if $reallybad;
 242
 243         $dryrun || check_fperm($proj, "config") or $bad = 1;
 244         my $config = read_config_file_hash("config", !$quiet);
 245         if (!defined($config)) {
 246                 warn "$proj: could not read config file -- skipping\n" unless $quiet;
 247                 return 0;
 248         }
 249
 250         my $do_config = sub {
 251                 my ($item, $val) = @_;
 252                 my $oldval = defval($config->{$item},"");
 253                 my $result = "(dryrun)";
 254                 if (!$dryrun) {
 255                         $result = "";
 256                         system($Girocco::Config::git_bin, "config", "--file", "config", "--replace-all", $item, $val) == 0 or
 257                                 $result = "FAILED", $bad = 1;
 258                 }
 259                 if (!exists($config->{$item})) {
 260                         pmsg($proj, "config $item: created \"$val\"", $result) unless $quiet;
 261                 } else {
 262                         pmsg($proj, "config $item: \"$oldval\" -> \"$val\"", $result) unless $quiet;
 263                 }
 264         };
 265         my $do_config_unset = sub {
 266                 my ($item, $msg) = @_;
 267                 defined($msg) or $msg = "";
 268                 $msg eq "" or $msg = " " . $msg;
 269                 my $oldval = defval($config->{$item},"");
 270                 my $result = "(dryrun)";
 271                 if (!$dryrun) {
 272                         $result = "";
 273                         system($Girocco::Config::git_bin, "config", "--file", "config", "--unset-all", $item) == 0 or
 274                                 $result = "FAILED", $bad = 1;
 275                 }
 276                 pmsg($proj, "config $item: removed$msg \"$oldval\"", $result) unless $quiet;
 277         };
 278
 279         my $repovers = $config->{'core.repositoryformatversion'};
 280         if (!defined($repovers)) {
 281                 $repovers = "";
 282         } elsif ($repovers =~ /^[2345]$/) {
 283                 pmsg($proj, "WARNING: unknown core.repositoryformatversion value left unchanged: \"$repovers\"");
 284         } elsif ($repovers !~ /^[01]$/) {
 285                 pmsg($proj, "WARNING: replacing invalid core.repositoryformatversion value: \"$repovers\"") unless $quiet;
 286                 $repovers = "";
 287         }
 288         &$do_config('core.repositoryformatversion', 0) if $repovers eq "";
 289         my $cmplvl = defval($config->{'core.compression'},"");
 290         if ($cmplvl !~ /^-?\d+$/ || $cmplvl < -1 || $cmplvl > 9 || "" . (0 + $cmplvl) ne "" . $cmplvl) {
 291                 pmsg($proj, "WARNING: replacing invalid core.compression value: \"$cmplvl\"") unless $cmplvl eq "" || $quiet;
 292                 $cmplvl = "";
 293         } elsif ($cmplvl != 5) {
 294                 pmsg($proj, "WARNING: suboptimal core.compression value left unchanged: \"$cmplvl\"") unless $quiet;
 295         }
 296         $cmplvl ne "" or &$do_config('core.compression', 5);
 297         my $grpshr = defval($config->{'core.sharedrepository'},"");
 298         if ($grpshr eq "" || (valid_bool($grpshr) && !git_bool($grpshr))) {
 299                 &$do_config('core.sharedrepository', 1);
 300         } elsif (!(valid_bool($grpshr) && git_bool($grpshr))) {
 301                 pmsg($proj, "WARNING: odd core.sharedrepository value left unchanged: \"$grpshr\"");
 302         }
 303         if (git_bool($config->{'core.bare'})) {
 304                 my $setlaru = 1;
 305                 my $laru = $config->{'core.logallrefupdates'};
 306                 if (defined($laru)) {
 307                         if (valid_bool($laru)) {
 308                                 $setlaru = 0;
 309                                 if (git_bool($laru)) {
 310                                         pmsg($proj, "WARNING: core.logallrefupdates is true (left unchanged)") unless $quiet;
 311                                 }
 312                         } else {
 313                                 pmsg($proj, "WARNING: replacing non-boolean core.logallrefupdates value") unless $quiet;
 314                         }
 315                 }
 316                 !$setlaru or &$do_config('core.logallrefupdates', 'false');
 317         } else {
 318                 pmsg($proj, "WARNING: core.bare is not true (left unchanged)") unless $quiet;
 319         }
 320         defval($config->{'transfer.unpacklimit'},"") eq "1" or &$do_config('transfer.unpacklimit', 1);
 321         lc(defval($config->{'receive.denydeletecurrent'},"")) eq "warn" or &$do_config('receive.denydeletecurrent', 'warn');
 322         do {
 323                 !exists($config->{$_}) || valid_bool(defval($config->{$_},"")) or &$do_config_unset($_, "(not a boolean)");
 324         } foreach (@boolvars);
 325         do {
 326                 (valid_bool(defval($config->{$_},"")) && !git_bool($config->{$_})) or &$do_config($_, "false");
 327         } foreach (@falsevars);
 328         do {
 329                 (valid_bool(defval($config->{$_},"")) && !git_bool($config->{$_})) or &$do_config($_, 0);
 330         } foreach (@false0vars);
 331         do {
 332                 (valid_bool(defval($config->{$_},"")) && git_bool($config->{$_})) or &$do_config($_, "true");
 333         } foreach (@truevars);
 334
 335         if (defined($Girocco::Config::owning_group) && $Girocco::Config::owning_group ne "") {
 336                 $fp = openfind(qw(. -xdev ( -type d -o -type f ) ! -group), $Girocco::Config::owning_group, "-print");
 337                 while (<$fp>) {
 338                         chomp;
 339                         change_group($proj, $_) or $bad = 1;
 340                 }
 341                 close($fp) or $bad = 1;
 342         }
 343         foreach (@fixfpermsfiles) {
 344                 if (-e $_) {
 345                         if (! -f $_) {
 346                                 warn "$proj: bypassing project, exists but not file: $_\n" unless $quiet;
 347                                 $reallybad = $bad = 1;
 348                                 last;
 349                         }
 350                         check_fperm($proj, $_) or $bad = 1;
 351                 }
 352         }
 353         return 0 if $reallybad;
 354
 355         $fp = openfindne(@fixfpermsdirs, qw(-xdev -type f ! -perm), $fmodeoct, "-print");
 356         while (<$fp>) {
 357                 chomp;
 358                 check_fperm($proj, $_) or $bad = 1;
 359         }
 360         close($fp) or $bad = 1;
 361         $fp = openfind(qw(. -xdev -type f ! -perm -a+r -print));
 362         while (<$fp>) {
 363                 chomp;
 364                 check_fpermr($proj, $_) or $bad = 1;
 365         }
 366         close($fp) or $bad = 1;
 367         $fp = openfind(qw(. -xdev -type d ( -path ./hooks -o -path ./mob/hooks ) -prune -o -type f -perm +a+x -print));
 368         while (<$fp>) {
 369                 chomp;
 370                 check_fpermnox($proj, $_) or $bad = 1;
 371         }
 372         close($fp) or $bad = 1;
 373
 374         my $bu = defval($config->{'gitweb.baseurl'},"");
 375         if (-e ".nofetch") {
 376                 $bu eq "" or pmsg($proj, "WARNING: .nofetch exists but gitweb.baseurl is not empty ($bu)") unless $quiet;
 377         } else {
 378                 $bu ne "" or pmsg($proj, "WARNING: gitweb.baseurl is empty and .nofetch does not exist") unless $quiet;
 379         }
 380
 381         return !$bad;
 382 }
 383
 384 sub do_mkdir
 385 {
 386         my ($proj, $subdir) = @_;
 387         my $result = "";
 388         if (!$dryrun) {
 389                 mkdir("$subdir") && -d "$subdir" or $result = "FAILED";
 390         } else {
 391                 $result = "(dryrun)";
 392         }
 393         pmsg($proj, "$subdir/: created", $result);
 394         return $result ne "FAILED";
 395 }
 396
 397 sub check_dperm {
 398         my ($proj, $subdir) = @_;
 399         my $oldmode = (stat($subdir))[2];
 400         if (!defined($oldmode) || $oldmode eq "") {
 401                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 402                 return 0;
 403         }
 404         my $newmode = ($oldmode & ~07777) | $dmode;
 405         $newmode == $oldmode and return 1;
 406         my $result = "";
 407         if (!$dryrun) {
 408                 if (!chmod($newmode & 07777, $subdir)) {
 409                         $result = "FAILED";
 410                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 411                 }
 412         } else {
 413                 $result = "(dryrun)";
 414         }
 415         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 416         return $result ne "FAILED";
 417 }
 418
 419 sub change_dpermrwx {
 420         my ($proj, $subdir) = @_;
 421         my $oldmode = (stat($subdir))[2];
 422         if (!defined($oldmode) || $oldmode eq "") {
 423                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 424                 return 0;
 425         }
 426         my $newmode = $oldmode | ($wall ? 0777 : 0775);
 427         $newmode == $oldmode and return 1;
 428         my $result = "";
 429         if (!$dryrun) {
 430                 if (!chmod($newmode & 07777, $subdir)) {
 431                         $result = "FAILED";
 432                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 433                 }
 434         } else {
 435                 $result = "(dryrun)";
 436         }
 437         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 438         return $result ne "FAILED";
 439 }
 440
 441 sub change_dpermrx {
 442         my ($proj, $subdir) = @_;
 443         $subdir =~ s,^\./,,;
 444         my $oldmode = (stat($subdir))[2];
 445         if (!defined($oldmode) || $oldmode eq "") {
 446                 warn "chmod: ($proj) $subdir: No such file or directory\n" unless $quiet;
 447                 return 0;
 448         }
 449         my $newmode = $oldmode | 0555;
 450         $newmode == $oldmode and return 1;
 451         my $result = "";
 452         if (!$dryrun) {
 453                 if (!chmod($newmode & 07777, $subdir)) {
 454                         $result = "FAILED";
 455                         warn "chmod: ($proj) $subdir: $!\n" unless $quiet;
 456                 }
 457         } else {
 458                 $result = "(dryrun)";
 459         }
 460         pmsg($proj, "$subdir/:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 461         return $result ne "FAILED";
 462 }
 463
 464 sub check_fperm {
 465         my ($proj, $file) = @_;
 466         my $oldmode = (stat($file))[2];
 467         if (!defined($oldmode) || $oldmode eq "") {
 468                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 469                 return 0;
 470         }
 471         my $newmode = ($oldmode & ~07777) | $fmode;
 472         $newmode == $oldmode and return 1;
 473         my $result = "";
 474         if (!$dryrun) {
 475                 if (!chmod($newmode & 07777, $file)) {
 476                         $result = "FAILED";
 477                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 478                 }
 479         } else {
 480                 $result = "(dryrun)";
 481         }
 482         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 483         return $result ne "FAILED";
 484 }
 485
 486 sub check_fpermr {
 487         my ($proj, $file) = @_;
 488         $file =~ s,^\./,,;
 489         my $oldmode = (stat($file))[2];
 490         if (!defined($oldmode) || $oldmode eq "") {
 491                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 492                 return 0;
 493         }
 494         my $newmode = $oldmode | 0444;
 495         $newmode == $oldmode and return 1;
 496         my $result = "";
 497         if (!$dryrun) {
 498                 if (!chmod($newmode & 07777, $file)) {
 499                         $result = "FAILED";
 500                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 501                 }
 502         } else {
 503                 $result = "(dryrun)";
 504         }
 505         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 506         return $result ne "FAILED";
 507 }
 508
 509 sub check_fpermnox {
 510         my ($proj, $file) = @_;
 511         $file =~ s,^\./,,;
 512         my $oldmode = (stat($file))[2];
 513         if (!defined($oldmode) || $oldmode eq "") {
 514                 warn "chmod: ($proj) $file: No such file or directory\n" unless $quiet;
 515                 return 0;
 516         }
 517         my $newmode = $oldmode & ~0111;
 518         $newmode == $oldmode and return 1;
 519         my $result = "";
 520         if (!$dryrun) {
 521                 if (!chmod($newmode & 07777, $file)) {
 522                         $result = "FAILED";
 523                         warn "chmod: ($proj) $file: $!\n" unless $quiet;
 524                 }
 525         } else {
 526                 $result = "(dryrun)";
 527         }
 528         pmsg($proj, "$file:", get_mode_perm($oldmode), '->', get_mode_perm($newmode), $result);
 529         return $result ne "FAILED";
 530 }
 531
 532 sub change_group {
 533         my ($proj, $item) = @_;
 534         $item =~ s,^\./,,;
 535         my @info = stat($item);
 536         if (@info < 6 || $info[2] eq "" || $info[4] eq "" || $info[5] eq "") {
 537                 warn "chgrp: ($proj) $item: No such file or directory\n" unless $quiet;
 538                 return 0;
 539         }
 540         $info[5] == $owning_group_id and return 1;
 541         my $result = "";
 542         if (!$dryrun) {
 543                 if (!chown($info[4], $owning_group_id, $item)) {
 544                         $result = "FAILED";
 545                         warn "chgrp: ($proj) $item: $!\n" unless $quiet;
 546                 } elsif (!chmod($info[2] & 07777, $item)) {
 547                         $result = "FAILED";
 548                         warn "chmod: ($proj) $item: $!\n" unless $quiet;
 549                 }
 550         } else {
 551                 $result = "(dryrun)";
 552         }
 553         my $isdir = ((($info[2] >> 12) & 017) == 004) ? '/' : '';
 554         pmsg($proj, "$item$isdir: group", get_grp_nam($info[5]), '->', $Girocco::Config::owning_group, $result);
 555         return $result ne "FAILED";
 556 }
 557
 558 my $wrote; BEGIN {$wrote = ""}
 559 sub pmsg {
 560         my $proj = shift;
 561         my $msg = join(" ", @_);
 562         $msg =~ s/\s+$//;
 563         my $prefix = "";
 564         if (!$hdr) {
 565                 $prefix = $wrote . $proj . ":\n";
 566                 $hdr = 1;
 567         }
 568         print $prefix, "  ", join(' ', @_), "\n";
 569         $wrote = "\n";
 570 }
 571
 572 my %ftypes;
 573 BEGIN {%ftypes = (
 574         000 => '?',
 575         001 => 'p',
 576         002 => 'c',
 577         003 => '?',
 578         004 => 'd',
 579         005 => '?',
 580         006 => 'b',
 581         007 => '?',
 582         010 => '-',
 583         011 => '?',
 584         012 => 'l',
 585         013 => '?',
 586         014 => 's',
 587         015 => '?',
 588         016 => 'w',
 589         017 => '?'
 590 )}
 591 my %fperms;
 592 BEGIN {%fperms = (
 593         0 => '---',
 594         1 => '--x',
 595         2 => '-w-',
 596         3 => '-wx',
 597         4 => 'r--',
 598         5 => 'r-x',
 599         6 => 'rw-',
 600         7 => 'rwx'
 601 )}
 602
 603 sub get_mode_perm {
 604         my $mode = $_[0];
 605         my $str = $ftypes{($mode >> 12) & 017} .
 606                 $fperms{($mode >> 6) & 7} .
 607                 $fperms{($mode >> 3) & 7} .
 608                 $fperms{$mode & 7};
 609         substr($str,3,1) = ($mode & 0100) ? 's' : 'S' if $mode & 04000;
 610         substr($str,6,1) = ($mode & 0010) ? 's' : 'S' if $mode & 02000;
 611         substr($str,9,1) = ($mode & 0001) ? 't' : 'T' if $mode & 01000;
 612         return $str;
 613 }
 614
 615 sub get_perm {
 616         my $mode = (stat($_[0]))[2];
 617         defined($mode) or return '??????????';
 618         return get_mode_perm($mode);
 619 }
 620
 621 sub get_grp_nam {
 622         my $grpid = $_[0];
 623         defined($grpid) or return '?';
 624         my $grpnm = scalar(getgrgid($grpid));
 625         return defined($grpnm) && $grpnm ne "" ? $grpnm : $grpid;
 626 }
 627
 628 sub get_grp {
 629         my $grp = (stat($_[0]))[5];
 630         defined($grp) or return '?';
 631         return get_grp_nam($grp);
 632 }
 633
 634 __END__
 635
 636 =head1 NAME
 637
 638 update-all-config.pl - Update all projects' config settings
 639
 640 =head1 SYNOPSIS
 641
 642 update-all-config.pl [<options>] [<projname>]...
 643
 644  Options:
 645    -h | --help                  detailed instructions
 646    -V | --version               show version
 647    -n | --dry-run               show what would be done but don't do it
 648    -f | --force                 run without a Config.pm owning_group
 649    -q | --quiet                 suppress change messages
 650
 651  <projname>                     if given, only operate on these projects
 652
 653 =head1 OPTIONS
 654
 655 =over 8
 656
 657 =item B<-h>, B<--help>
 658
 659 Print the full description of update-all-config.pl's options.
 660
 661 =item B<-V>, B<--version>
 662
 663 Print the version of update-all-config.pl.
 664
 665 =item B<-n>, B<--dry-run>
 666
 667 Do not actually make any changes, just show what would be done without
 668 actually doing it.
 669
 670 =item B<-q>, B<--quiet>
 671
 672 Suppress the messages about what's actually being changed.  This option
 673 is ignored if B<--dry-run> is in effect.
 674
 675 The warnings about missing and unknown-to-Girocco projects are also
 676 suppressed by this option.
 677
 678 =item B<-f>, B<--force>
 679
 680 Allow running without a $Girocco::Config::owning_group set.  This is not
 681 recommended as it results in world-writable items being used (instead of
 682 just world-readable).
 683
 684 =item B<<projname>>
 685
 686 If no project names are specified then I<all> projects are processed.
 687
 688 If one or more project names are specified then only those projects are
 689 processed.  Specifying non-existent projects produces a warning for them,
 690 but the rest of the projects specified will still be processed.
 691
 692 Each B<projname> may be either a full absolute path starting with
 693 $Girocco::Config::reporoot or just the project name part with or without
 694 a trailing C<.git>.
 695
 696 Any explicitly specified projects that do exist but are not known to
 697 Girocco will be skipped (with a warning).
 698
 699 =back
 700
 701 =head1 DESCRIPTION
 702
 703 Inspect the C<config> files of Girocco projects (i.e. $GIT_DIR/config) and
 704 look for anomalies and out-of-date settings.
 705
 706 Additionally check the existence and permissions on various files and
 707 directories in the project.
 708
 709 If an explicity specified project is located under $Girocco::Config::reporoot
 710 but is not actually known to Girocco (i.e. it's not in the etc/group file)
 711 then it will be skipped.
 712
 713 By default, any anomalies or out-of-date settings will be corrected with a
 714 message to that effect.  However using B<--dry-run> will only show the
 715 correction(s) which would be made without making them and B<--quiet> will make
 716 the correction(s) without any messages.
 717
 718 Any projects that have a C<$GIT_DIR/.noconfig> file are always skipped (with a
 719 message unless B<--quiet> is used).
 720
 721 =cut