cgi/html.cgi

   1 #!/usr/bin/perl
   2 # (c) Petr Baudis <pasky@suse.cz>
   3 # Portions Copyright (c) Kyle J. McKay <mackyle@gmail.com>
   4 # GPLv2
   5
   6 use strict;
   7 use warnings;
   8
   9 use Digest::MD5 qw(md5_hex);
  10
  11 use lib ".";
  12 use Girocco::CGI;
  13 use Girocco::Config;
  14 use Girocco::Util;
  15
  16 BEGIN {
  17         eval {
  18                 require Digest::SHA;
  19                 Digest::SHA->import(
  20                         qw(sha1_hex)
  21         );1} ||
  22         eval {
  23                 require Digest::SHA1;
  24                 Digest::SHA1->import(
  25                         qw(sha1_hex)
  26         );1} ||
  27         eval {
  28                 require Digest::SHA::PurePerl;
  29                 Digest::SHA::PurePerl->import(
  30                         qw(sha1_hex)
  31         );1} ||
  32         die "One of Digest::SHA or Digest::SHA1 or Digest::SHA::PurePerl "
  33         . "must be available\n";
  34 }
  35
  36 # Ultra-trivial templating engine;
  37 # /^@section=SECTION
  38 # /^@heading=HEADING
  39 # /^@header                     produces HTML header based on @section and @heading
  40 # /@@gitweburl@@/               substitute for gitweburl configuration variable
  41 # /@@base(gitweburl)@@/         substitute for base portion of gitweburl variable
  42 # /@@path(gitweburl)@@/         substitute for path portion of gitweburl variable
  43 # /@@server(gitweburl)@@/       replace scheme://host:port portion of gitweburl variable
  44 # /@@md5(relpath)@@/            produces MD5 hex of file in DOCUMENT_ROOT at relpath
  45 # /@@sha1(relpath)@@/           produces SHA1 hex of file in DOCUMENT_ROOT at relpath
  46 # /@@ifmob@@...@@end@@/         remove unless mob defined
  47 # /@@ifssh@@...@@end@@/         remove unless pushurl defined
  48 # /@@ifhttps@@...@@end@@/       remove unless httpspushurl defined
  49
  50 my $pathinfo = $ENV{PATH_INFO} || '';
  51 my $docroot = $ENV{DOCUMENT_ROOT} || '';
  52 $pathinfo =~ s,^/,,;
  53 unless ($pathinfo) {
  54         my $gcgi = Girocco::CGI->new('HTML Templater');
  55         print "<p>Hi, this is your friendly HTML templater speaking. Pass me template name.</p>\n";
  56         exit;
  57 }
  58
  59 my $templatefd;
  60 unless ($pathinfo !~ m#\./# and open($templatefd, '<', "$Girocco::Config::basedir/html/$pathinfo")) {
  61         my $gcgi = Girocco::CGI->new('HTML Templater');
  62         print "<p>Invalid template name.</p>\n";
  63         exit;
  64 }
  65
  66 if ($pathinfo =~ /\.(png|jpe?g|gif|svgz?)$/) {
  67         my $kind = $1;
  68         $kind = 'jpeg' if $kind eq 'jpg';
  69         $kind = 'svg+xml' if $kind =~ /^svg/;
  70         print "Content-type: image/$kind\n\n";
  71         my $buf;
  72         while (read($templatefd, $buf, 32768)) {
  73                 print $buf;
  74         }
  75         exit;
  76 }
  77
  78 sub get_file_hash {
  79         my ($hash, $fn) = @_;
  80         return '' unless $docroot && $docroot ne '/' && -d $docroot;
  81         return '' if $hash ne 'md5' && $hash ne 'sha1';
  82         return '' if !$fn || $fn =~ m|^[./]| || $fn =~ m|[.]/| || $fn =~ m|/[.]|;
  83         return '' unless -f "$docroot/$fn";
  84         open(HASHFILE, '<', "$docroot/$fn") or return '';
  85         local $/;
  86         undef $/;
  87         my $contents = <HASHFILE>;
  88         close(HASHFILE);
  89         return $hash eq 'md5' ? md5_hex($contents) : sha1_hex($contents);
  90 }
  91
  92 my ($gcgi, $section, $heading);
  93
  94 my $template=join('', map(to_utf8($_, 1), <$templatefd>));
  95 close $templatefd;
  96 $template =~ s/@\@ifmob@\@(.*?)@\@end@\@/$Girocco::Config::mob?$1:''/ges;
  97 $template =~ s/@\@ifssh@\@(.*?)@\@end@\@/$Girocco::Config::pushurl?$1:''/ges;
  98 $template =~ s/@\@ifhttps@\@(.*?)@\@end@\@/$Girocco::Config::httpspushurl?$1:''/ges;
  99
 100 foreach (split(/\n/, $template)) {
 101         chomp;
 102         if (s/^\@section=//) {
 103                 $section = $_;
 104                 next;
 105         } elsif (s/^\@heading=//) {
 106                 $heading = $_;
 107                 next;
 108         } elsif (s/^\@header//) {
 109                 $gcgi = Girocco::CGI->new($heading, $section);
 110                 print "<div class=\"htmlcgi\">";
 111                 next;
 112         } else {
 113                 s/@@(\w+?)@@/${$Girocco::Config::{$1}}/ge;
 114                 s/@\@base\((\w+?)\)@@/url_base(${$Girocco::Config::{$1}})/ge;
 115                 s/@\@path\((\w+?)\)@@/url_path(${$Girocco::Config::{$1}})/ge;
 116                 s/@\@server\((\w+?)\)@@/url_server(${$Girocco::Config::{$1}})/ge;
 117                 s/@\@(md5|sha1)\(([^()]+?)\)@@/get_file_hash($1,$2)/ge;
 118                 print "$_\n";
 119         }
 120 }
 121 print "</div>";
 122 $gcgi and $gcgi->srcname("html/$pathinfo");