accessible/mac/mozActionElements.mm

   1 /* clang-format off */
   2 /* -*- Mode: Objective-C++; tab-width: 2; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
   3 /* clang-format on */
   4 /* This Source Code Form is subject to the terms of the Mozilla Public
   5  * License, v. 2.0. If a copy of the MPL was not distributed with this
   6  * file, You can obtain one at http://mozilla.org/MPL/2.0/. */
   7
   8 #import "mozActionElements.h"
   9
  10 #import "MacUtils.h"
  11 #include "LocalAccessible-inl.h"
  12 #include "DocAccessible.h"
  13 #include "XULTabAccessible.h"
  14 #include "HTMLFormControlAccessible.h"
  15
  16 #include "nsCocoaUtils.h"
  17 #include "mozilla/FloatingPoint.h"
  18
  19 using namespace mozilla::a11y;
  20
  21 @implementation mozButtonAccessible
  22
  23 - (NSNumber*)moxHasPopup {
  24   return @([self stateWithMask:states::HASPOPUP] != 0);
  25 }
  26
  27 - (NSString*)moxPopupValue {
  28   if ([self stateWithMask:states::HASPOPUP] != 0) {
  29     return utils::GetAccAttr(self, nsGkAtoms::aria_haspopup);
  30   }
  31
  32   return nil;
  33 }
  34
  35 @end
  36
  37 @implementation mozPopupButtonAccessible
  38
  39 - (NSString*)moxTitle {
  40   // Popup buttons don't have titles.
  41   return @"";
  42 }
  43
  44 - (BOOL)moxBlockSelector:(SEL)selector {
  45   if (selector == @selector(moxHasPopup)) {
  46     return YES;
  47   }
  48
  49   return [super moxBlockSelector:selector];
  50 }
  51
  52 - (NSArray*)moxChildren {
  53   if ([self stateWithMask:states::EXPANDED] == 0) {
  54     // If the popup button is collapsed don't return its children.
  55     return @[];
  56   }
  57
  58   return [super moxChildren];
  59 }
  60
  61 - (void)stateChanged:(uint64_t)state isEnabled:(BOOL)enabled {
  62   [super stateChanged:state isEnabled:enabled];
  63
  64   if (state == states::EXPANDED) {
  65     // If the EXPANDED state is updated, fire AXMenu events on the
  66     // popups child which is the actual menu.
  67     if (mozAccessible* popup = (mozAccessible*)[self childAt:0]) {
  68       [popup moxPostNotification:(enabled ? @"AXMenuOpened" : @"AXMenuClosed")];
  69     }
  70   }
  71 }
  72
  73 @end
  74
  75 @implementation mozRadioButtonAccessible
  76
  77 - (NSArray*)moxLinkedUIElements {
  78   return [[self getRelationsByType:RelationType::MEMBER_OF]
  79       arrayByAddingObjectsFromArray:[super moxLinkedUIElements]];
  80 }
  81
  82 @end
  83
  84 @implementation mozCheckboxAccessible
  85
  86 - (int)isChecked {
  87   // check if we're checked or in a mixed state
  88   uint64_t state =
  89       [self stateWithMask:(states::CHECKED | states::PRESSED | states::MIXED)];
  90   if (state & (states::CHECKED | states::PRESSED)) {
  91     return kChecked;
  92   }
  93
  94   if (state & states::MIXED) {
  95     return kMixed;
  96   }
  97
  98   return kUnchecked;
  99 }
 100
 101 - (id)moxValue {
 102   NS_OBJC_BEGIN_TRY_BLOCK_RETURN;
 103
 104   return [NSNumber numberWithInt:[self isChecked]];
 105
 106   NS_OBJC_END_TRY_BLOCK_RETURN(nil);
 107 }
 108
 109 - (void)stateChanged:(uint64_t)state isEnabled:(BOOL)enabled {
 110   [super stateChanged:state isEnabled:enabled];
 111
 112   if (state & (states::CHECKED | states::PRESSED | states::MIXED)) {
 113     [self moxPostNotification:NSAccessibilityValueChangedNotification];
 114   }
 115 }
 116
 117 @end
 118
 119 @implementation mozPaneAccessible
 120
 121 - (NSArray*)moxChildren {
 122   // By default, all tab panels are exposed in the a11y tree
 123   // even if the tab they represent isn't the active tab. To
 124   // prevent VoiceOver from navigating background tab content,
 125   // only expose the tab panel that is currently on screen.
 126   for (mozAccessible* child in [super moxChildren]) {
 127     if (!([child state] & states::OFFSCREEN)) {
 128       return [NSArray arrayWithObject:GetObjectOrRepresentedView(child)];
 129     }
 130   }
 131   MOZ_ASSERT_UNREACHABLE("We have no on screen tab content?");
 132   return @[];
 133 }
 134
 135 @end
 136
 137 @implementation mozIncrementableAccessible
 138
 139 - (id)moxValue {
 140   return [NSNumber numberWithDouble:mGeckoAccessible->CurValue()];
 141 }
 142
 143 - (NSString*)moxValueDescription {
 144   nsAutoString valueDesc;
 145   mGeckoAccessible->Value(valueDesc);
 146   return nsCocoaUtils::ToNSString(valueDesc);
 147 }
 148 - (id)moxMinValue {
 149   return [NSNumber numberWithDouble:mGeckoAccessible->MinValue()];
 150 }
 151
 152 - (id)moxMaxValue {
 153   return [NSNumber numberWithDouble:mGeckoAccessible->MaxValue()];
 154 }
 155
 156 - (void)moxSetValue:(id)value {
 157   [self setValue:([value doubleValue])];
 158 }
 159
 160 - (void)moxPerformIncrement {
 161   [self changeValueBySteps:1];
 162 }
 163
 164 - (void)moxPerformDecrement {
 165   [self changeValueBySteps:-1];
 166 }
 167
 168 - (NSString*)moxOrientation {
 169   RefPtr<AccAttributes> attributes = mGeckoAccessible->Attributes();
 170   if (attributes) {
 171     nsAutoString result;
 172     attributes->GetAttribute(nsGkAtoms::aria_orientation, result);
 173     if (result.Equals(u"horizontal"_ns)) {
 174       return NSAccessibilityHorizontalOrientationValue;
 175     } else if (result.Equals(u"vertical"_ns)) {
 176       return NSAccessibilityVerticalOrientationValue;
 177     }
 178   }
 179
 180   return NSAccessibilityUnknownOrientationValue;
 181 }
 182
 183 - (void)handleAccessibleEvent:(uint32_t)eventType {
 184   switch (eventType) {
 185     case nsIAccessibleEvent::EVENT_TEXT_VALUE_CHANGE:
 186     case nsIAccessibleEvent::EVENT_VALUE_CHANGE:
 187       [self moxPostNotification:NSAccessibilityValueChangedNotification];
 188       break;
 189     default:
 190       [super handleAccessibleEvent:eventType];
 191       break;
 192   }
 193 }
 194
 195 /*
 196  * Updates the accessible's current value by factor and step.
 197  *
 198  * factor: A signed integer representing the number of times to
 199  *    apply step to the current value. A positive value will increment,
 200  *    while a negative one will decrement.
 201  * step: An unsigned integer specified by the webauthor and indicating the
 202  *    amount by which to increment/decrement the current value.
 203  */
 204 - (void)changeValueBySteps:(int)factor {
 205   MOZ_ASSERT(mGeckoAccessible, "mGeckoAccessible is null");
 206
 207   double newValue =
 208       mGeckoAccessible->CurValue() + (mGeckoAccessible->Step() * factor);
 209   [self setValue:(newValue)];
 210 }
 211
 212 /*
 213  * Updates the accessible's current value to the specified value
 214  */
 215 - (void)setValue:(double)value {
 216   MOZ_ASSERT(mGeckoAccessible, "mGeckoAccessible is null");
 217   mGeckoAccessible->SetCurValue(value);
 218 }
 219
 220 @end
 221
 222 @implementation mozDatePickerAccessible
 223
 224 - (NSString*)moxTitle {
 225   return utils::LocalizedString(u"dateField"_ns);
 226 }
 227
 228 @end