accessible/mac/mozActionElements.mm

   1 /* clang-format off */
   2 /* -*- Mode: Objective-C++; tab-width: 2; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
   3 /* clang-format on */
   4 /* This Source Code Form is subject to the terms of the Mozilla Public
   5  * License, v. 2.0. If a copy of the MPL was not distributed with this
   6  * file, You can obtain one at http://mozilla.org/MPL/2.0/. */
   7
   8 #import "mozActionElements.h"
   9
  10 #import "MacUtils.h"
  11 #include "LocalAccessible-inl.h"
  12 #include "DocAccessible.h"
  13 #include "XULTabAccessible.h"
  14 #include "HTMLFormControlAccessible.h"
  15
  16 #include "nsCocoaUtils.h"
  17 #include "mozilla/FloatingPoint.h"
  18
  19 using namespace mozilla::a11y;
  20
  21 @implementation mozButtonAccessible
  22
  23 - (NSNumber*)moxHasPopup {
  24   return @([self stateWithMask:states::HASPOPUP] != 0);
  25 }
  26
  27 - (NSString*)moxPopupValue {
  28   if ([self stateWithMask:states::HASPOPUP] != 0) {
  29     return utils::GetAccAttr(self, nsGkAtoms::aria_haspopup);
  30   }
  31
  32   return nil;
  33 }
  34
  35 @end
  36
  37 @implementation mozPopupButtonAccessible
  38
  39 - (NSString*)moxTitle {
  40   // Popup buttons don't have titles.
  41   return @"";
  42 }
  43
  44 - (BOOL)moxBlockSelector:(SEL)selector {
  45   if (selector == @selector(moxHasPopup)) {
  46     return YES;
  47   }
  48
  49   return [super moxBlockSelector:selector];
  50 }
  51
  52 - (NSArray*)moxChildren {
  53   if ([self stateWithMask:states::EXPANDED] == 0) {
  54     // If the popup button is collapsed don't return its children.
  55     return @[];
  56   }
  57
  58   return [super moxChildren];
  59 }
  60
  61 - (void)stateChanged:(uint64_t)state isEnabled:(BOOL)enabled {
  62   [super stateChanged:state isEnabled:enabled];
  63
  64   if (state == states::EXPANDED) {
  65     // If the EXPANDED state is updated, fire AXMenu events on the
  66     // popups child which is the actual menu.
  67     if (mozAccessible* popup = (mozAccessible*)[self childAt:0]) {
  68       [popup moxPostNotification:(enabled ? @"AXMenuOpened" : @"AXMenuClosed")];
  69     }
  70   }
  71 }
  72
  73 @end
  74
  75 @implementation mozRadioButtonAccessible
  76
  77 - (NSArray*)moxLinkedUIElements {
  78   return [[self getRelationsByType:RelationType::MEMBER_OF]
  79       arrayByAddingObjectsFromArray:[super moxLinkedUIElements]];
  80 }
  81
  82 @end
  83
  84 @implementation mozCheckboxAccessible
  85
  86 - (int)isChecked {
  87   // check if we're checked or in a mixed state
  88   uint64_t state =
  89       [self stateWithMask:(states::CHECKED | states::PRESSED | states::MIXED)];
  90   if (state & (states::CHECKED | states::PRESSED)) {
  91     return kChecked;
  92   }
  93
  94   if (state & states::MIXED) {
  95     return kMixed;
  96   }
  97
  98   return kUnchecked;
  99 }
 100
 101 - (id)moxValue {
 102   NS_OBJC_BEGIN_TRY_BLOCK_RETURN;
 103
 104   return [NSNumber numberWithInt:[self isChecked]];
 105
 106   NS_OBJC_END_TRY_BLOCK_RETURN(nil);
 107 }
 108
 109 - (void)stateChanged:(uint64_t)state isEnabled:(BOOL)enabled {
 110   [super stateChanged:state isEnabled:enabled];
 111
 112   if (state & (states::CHECKED | states::PRESSED | states::MIXED)) {
 113     [self moxPostNotification:NSAccessibilityValueChangedNotification];
 114   }
 115 }
 116
 117 @end
 118
 119 @implementation mozPaneAccessible
 120
 121 - (NSArray*)moxChildren {
 122   // By default, all tab panels are exposed in the a11y tree
 123   // even if the tab they represent isn't the active tab. To
 124   // prevent VoiceOver from navigating background tab content,
 125   // only expose the tab panel that is currently on screen.
 126   for (mozAccessible* child in [super moxChildren]) {
 127     if (!([child state] & states::OFFSCREEN)) {
 128       return [NSArray arrayWithObject:GetObjectOrRepresentedView(child)];
 129     }
 130   }
 131   MOZ_ASSERT_UNREACHABLE("We have no on screen tab content?");
 132   return @[];
 133 }
 134
 135 @end
 136
 137 @implementation mozRangeAccessible
 138
 139 - (id)moxValue {
 140   return [NSNumber numberWithDouble:mGeckoAccessible->CurValue()];
 141 }
 142
 143 - (id)moxMinValue {
 144   return [NSNumber numberWithDouble:mGeckoAccessible->MinValue()];
 145 }
 146
 147 - (id)moxMaxValue {
 148   return [NSNumber numberWithDouble:mGeckoAccessible->MaxValue()];
 149 }
 150
 151 - (NSString*)moxOrientation {
 152   RefPtr<AccAttributes> attributes = mGeckoAccessible->Attributes();
 153   if (attributes) {
 154     nsAutoString result;
 155     attributes->GetAttribute(nsGkAtoms::aria_orientation, result);
 156     if (result.Equals(u"horizontal"_ns)) {
 157       return NSAccessibilityHorizontalOrientationValue;
 158     } else if (result.Equals(u"vertical"_ns)) {
 159       return NSAccessibilityVerticalOrientationValue;
 160     }
 161   }
 162
 163   return NSAccessibilityUnknownOrientationValue;
 164 }
 165
 166 - (void)handleAccessibleEvent:(uint32_t)eventType {
 167   switch (eventType) {
 168     case nsIAccessibleEvent::EVENT_TEXT_VALUE_CHANGE:
 169     case nsIAccessibleEvent::EVENT_VALUE_CHANGE:
 170       [self moxPostNotification:NSAccessibilityValueChangedNotification];
 171       break;
 172     default:
 173       [super handleAccessibleEvent:eventType];
 174       break;
 175   }
 176 }
 177
 178 @end
 179
 180 @implementation mozMeterAccessible
 181
 182 - (NSString*)moxValueDescription {
 183   nsAutoString valueDesc;
 184   mGeckoAccessible->Value(valueDesc);
 185   if (mGeckoAccessible->TagName() != nsGkAtoms::meter) {
 186     // We're dealing with an aria meter, which shouldn't get
 187     // a value region.
 188     return nsCocoaUtils::ToNSString(valueDesc);
 189   }
 190
 191   if (!valueDesc.IsEmpty()) {
 192     // Append a comma to separate the existing value description
 193     // from the value region.
 194     valueDesc.Append(u", "_ns);
 195   }
 196   // We need to concat the given value description
 197   // with a description of the value as either optimal,
 198   // suboptimal, or critical.
 199   int32_t region;
 200   if (mGeckoAccessible->IsRemote()) {
 201     region = mGeckoAccessible->AsRemote()->ValueRegion();
 202   } else {
 203     HTMLMeterAccessible* localMeter =
 204         static_cast<HTMLMeterAccessible*>(mGeckoAccessible->AsLocal());
 205     region = localMeter->ValueRegion();
 206   }
 207
 208   if (region == 1) {
 209     valueDesc.Append(u"Optimal value"_ns);
 210   } else if (region == 0) {
 211     valueDesc.Append(u"Suboptimal value"_ns);
 212   } else {
 213     MOZ_ASSERT(region == -1);
 214     valueDesc.Append(u"Critical value"_ns);
 215   }
 216
 217   return nsCocoaUtils::ToNSString(valueDesc);
 218 }
 219
 220 @end
 221
 222 @implementation mozIncrementableAccessible
 223
 224 - (NSString*)moxValueDescription {
 225   nsAutoString valueDesc;
 226   mGeckoAccessible->Value(valueDesc);
 227   return nsCocoaUtils::ToNSString(valueDesc);
 228 }
 229
 230 - (void)moxSetValue:(id)value {
 231   [self setValue:([value doubleValue])];
 232 }
 233
 234 - (void)moxPerformIncrement {
 235   [self changeValueBySteps:1];
 236 }
 237
 238 - (void)moxPerformDecrement {
 239   [self changeValueBySteps:-1];
 240 }
 241
 242 /*
 243  * Updates the accessible's current value by factor and step.
 244  *
 245  * factor: A signed integer representing the number of times to
 246  *    apply step to the current value. A positive value will increment,
 247  *    while a negative one will decrement.
 248  * step: An unsigned integer specified by the webauthor and indicating the
 249  *    amount by which to increment/decrement the current value.
 250  */
 251 - (void)changeValueBySteps:(int)factor {
 252   MOZ_ASSERT(mGeckoAccessible, "mGeckoAccessible is null");
 253
 254   double newValue =
 255       mGeckoAccessible->CurValue() + (mGeckoAccessible->Step() * factor);
 256   [self setValue:(newValue)];
 257 }
 258
 259 /*
 260  * Updates the accessible's current value to the specified value
 261  */
 262 - (void)setValue:(double)value {
 263   MOZ_ASSERT(mGeckoAccessible, "mGeckoAccessible is null");
 264   mGeckoAccessible->SetCurValue(value);
 265 }
 266
 267 @end
 268
 269 @implementation mozDatePickerAccessible
 270
 271 - (NSString*)moxTitle {
 272   return utils::LocalizedString(u"dateField"_ns);
 273 }
 274
 275 @end