configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(find/pred.c)
   3 AM_CONFIG_HEADER(config.h)
   4 AC_CANONICAL_HOST
   5 AC_CONFIG_MACRO_DIR(gnulib/m4)
   6
   7 dnl Set of available languages.
   8 ALL_LINGUAS="da de es et fr gl id it ko nl pl pt_BR ru sv tr"
   9
  10 AM_INIT_AUTOMAKE(findutils, 4.2.3)
  11
  12 AC_SUBST(INCLUDES)dnl
  13 AC_ARG_ENABLE(id-cache,
  14 [  --enable-id-cache       cache all UIDs & GIDs; avoid if using NIS or Hesiod],
  15   AC_DEFINE(CACHE_IDS, 1, [Define if you want find -nouser and -nogroup to make tables of
  16    used UIDs and GIDs at startup instead of using getpwuid or
  17    getgrgid when needed.  Speeds up -nouser and -nogroup unless you
  18    are running NIS or Hesiod, which make password and group calls
  19    very expensive.]))
  20
  21 dnl Checks for programs.
  22 AC_PROG_CC
  23 AC_PROG_CPP
  24
  25 AC_AIX
  26 AC_PROG_CC_STDC
  27
  28 dnl AC_MINIX
  29 dnl for gnulib
  30 gl_EARLY
  31 dnl gl_EARLY calls AC_GNU_SOURCE anyway.
  32
  33
  34 AC_ISC_POSIX
  35 AM_C_PROTOTYPES
  36
  37 AC_PROG_INSTALL
  38 AC_PROG_RANLIB
  39 dnl AC_PROG_LIBTOOL
  40 AC_PROG_MAKE_SET
  41 AC_SYS_LARGEFILE
  42
  43
  44 gl_INIT
  45
  46 dnl Try to get a POSIX.1 environment.
  47
  48 dnl Checks for libraries.
  49 AC_CHECK_LIB(sun, getpwnam)
  50
  51 dnl Checks for header files.
  52 AC_HEADER_STDC
  53 AC_CHECK_HEADERS(fcntl.h string.h limits.h unistd.h errno.h stdlib.h stddef.h)
  54 AC_CHECK_HEADERS(unistd.h inttypes.h fcntl.h locale.h stdint.h)
  55 AC_CHECK_HEADERS(sys/param.h)
  56 AC_HEADER_MAJOR
  57 AC_HEADER_DIRENT
  58 AC_HEADER_STAT
  59 AC_HEADER_SYS_WAIT
  60
  61 AC_MSG_CHECKING(how to get filesystem type)
  62 fstype=no
  63 # The order of these tests is important.
  64 AC_TRY_CPP([#include <sys/statvfs.h>
  65 #include <sys/fstyp.h>], AC_DEFINE(FSTYPE_STATVFS, 1, [Define to use SVR4 statvfs to get filesystem type.]) fstype=SVR4)
  66 if test $fstype = no; then
  67 AC_TRY_CPP([#include <sys/statfs.h>
  68 #include <sys/fstyp.h>], AC_DEFINE(FSTYPE_USG_STATFS, 1, [Define to use SVR3.2 statfs to get filesystem type.]) fstype=SVR3)
  69 fi
  70 if test $fstype = no; then
  71 AC_TRY_CPP([#include <sys/statfs.h>
  72 #include <sys/vmount.h>], AC_DEFINE(FSTYPE_AIX_STATFS, 1, [Define to use AIX3 statfs to get filesystem type.]) fstype=AIX)
  73 fi
  74 if test $fstype = no; then
  75 AC_EGREP_HEADER(f_type;, sys/mount.h, AC_DEFINE(FSTYPE_STATFS, 1, [Define to use 4.4BSD and OSF1 statfs to get filesystem type.]) fstype=4.4BSD/OSF1)
  76 fi
  77 if test $fstype = no; then
  78 AC_TRY_CPP([#include <mntent.h>], AC_DEFINE(FSTYPE_MNTENT, 1, [Define to use 4.3BSD getmntent to get filesystem type.]) fstype=4.3BSD)
  79 fi
  80 if test $fstype = no; then
  81 AC_TRY_CPP([#include <sys/mount.h>
  82 #include <sys/fs_types.h>], AC_DEFINE(FSTYPE_GETMNT, 1, [Define to use Ultrix getmnt to get filesystem type.]) fstype=Ultrix)
  83 fi
  84 AC_MSG_RESULT($fstype)
  85
  86 dnl Checks for typedefs, structures, and compiler characteristics.
  87
  88 AC_TYPE_UID_T
  89 AC_TYPE_SIZE_T
  90 AC_CHECK_TYPE(ssize_t, int)
  91 AC_TYPE_PID_T
  92 AC_CHECK_TYPE(ino_t, unsigned long)
  93 AC_CHECK_TYPE(dev_t, unsigned long)
  94 AC_TYPE_MODE_T
  95 AC_STRUCT_ST_BLOCKS
  96 AC_CHECK_MEMBERS([struct stat.st_rdev])
  97 AC_STRUCT_TM
  98 AC_STRUCT_TIMEZONE
  99
 100 dnl Checks for library functions that are provided by gnulib.
 101 AC_FUNC_STRFTIME
 102 AC_REPLACE_FUNCS(memcmp memset stpcpy strdup strstr strtol strtoul)
 103 AC_CHECK_FUNCS(fchdir getcwd strerror endgrent endpwent)
 104 AC_FUNC_VPRINTF
 105 AC_FUNC_ALLOCA
 106 AC_FUNC_GETMNTENT
 107 AC_FUNC_CLOSEDIR_VOID
 108
 109 dnl Checks for library functions that are provided by findlib.
 110 FINDLIB_REPLACE_FUNCS(waitpid strspn)
 111 FINDLIB_REPLACE_FUNCS(forcefindlib)
 112
 113 dnl gl_XALLOC
 114 gl_FUNC_ALLOCA
 115
 116
 117 AC_PREREQ(2.13)
 118
 119 # Define intmax_t to 'signed long' or 'signed long long'
 120 # if it is not already defined in <stdint.h> or <inttypes.h>.
 121 dnl Derived from gnulib's uintmax_t which was from Paul Eggert.
 122 AC_DEFUN([jy_AC_TYPE_INTMAX_T],
 123 [
 124   if test $ac_cv_header_inttypes_h = no && test $ac_cv_header_stdint_h = no; then
 125     AC_REQUIRE([jm_AC_TYPE_LONG_LONG])
 126     test $ac_cv_type_long_long = yes \
 127       && ac_type='long long' \
 128       || ac_type='long'
 129     AC_DEFINE_UNQUOTED(intmax_t, $ac_type,
 130       [Define to signed long or signed long long
 131        if <stdint.h> and <inttypes.h> don't define.])
 132   else
 133     AC_DEFINE(HAVE_INTMAX_T, 1,
 134       [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
 135   fi
 136 ])
 137
 138 jy_AC_TYPE_INTMAX_T
 139 echo ================================================
 140 sleep 1
 141 jy_SORTZ
 142 echo ================================================
 143 sleep 1
 144
 145 dnl internationalization macros
 146 AM_GNU_GETTEXT
 147
 148 # This is necessary so that .o files in LIBOBJS are also built via
 149 # the ANSI2KNR-filtering rules.
 150 #LIBOBJS=`echo $LIBOBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
 151 ##AC_CONFIG_SUBDIRS(gnulib)
 152 AC_CONFIG_FILES(gnulib/Makefile gnulib/lib/Makefile gnulib/m4/Makefile)
 153 AC_CONFIG_FILES(m4/Makefile)
 154 AC_OUTPUT(
 155         Makefile
 156         find/Makefile find/testsuite/Makefile
 157         xargs/Makefile xargs/testsuite/Makefile
 158         locate/Makefile locate/testsuite/Makefile
 159         intl/Makefile po/Makefile.in po/Makefile
 160         doc/Makefile lib/Makefile
 161         )