configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT([GNU findutils], 4.3.6, [bug-findutils@gnu.org])
   3 AC_CONFIG_AUX_DIR(build-aux)
   4 AM_INIT_AUTOMAKE
   5
   6 AC_CONFIG_SRCDIR([find/pred.c])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CANONICAL_HOST
   9 AC_CONFIG_MACRO_DIR(gnulib/m4)
  10
  11 dnl Set of available languages.
  12 ALL_LINGUAS="be bg ca da de el eo es et fi fr ga gl hr hu id it ja ko lg ms nl pl pt pt_BR ro ru rw sk sl sr sv tr uk vi zh_CN zh_TW"
  13
  14 AC_SUBST(INCLUDES)dnl
  15 AC_SUBST(AUXDIR,$ac_aux_dir)
  16 dnl check for --with-fts
  17 FIND_WITH_FTS
  18
  19 AC_ARG_ENABLE(id-cache,
  20 [  --enable-id-cache       cache all UIDs & GIDs; avoid if using NIS or Hesiod],
  21   AC_DEFINE(CACHE_IDS, 1, [Define if you want find -nouser and -nogroup to make tables of
  22    used UIDs and GIDs at startup instead of using getpwuid or
  23    getgrgid when needed.  Speeds up -nouser and -nogroup unless you
  24    are running NIS or Hesiod, which make password and group calls
  25    very expensive.]))
  26
  27 AC_ARG_ENABLE(debug,
  28         AS_HELP_STRING(--enable-debug,Enable debugging output which is likely to be interesting to people debugging findutils),
  29         [ac_cv_debug=$enableval],[ac_cv_debug=no])
  30
  31 AC_ARG_ENABLE(leaf-optimisation,
  32         AS_HELP_STRING(--enable-leaf-optimisation,Enable an optimisation which saves lstat calls to identify subdirectories on filesystems having traditional Unix semantics),
  33         [ac_cv_leaf_optimisation=$enableval],[ac_cv_leaf_optimisation=yes])
  34
  35 AC_ARG_ENABLE(d_type-optimization,
  36         AS_HELP_STRING(--enable-d_type-optimization,Make use of the file type data returned in struct dirent.d_type by readdir()),
  37         [ac_cv_d_type=$enableval],[ac_cv_d_type=yes])
  38
  39 dnl This one has no default, because otherwise we would have to say
  40 dnl both --enable-d_type-optimisation=no and --enable-d_type-optimization=no
  41 dnl to turn it off.
  42 AC_ARG_ENABLE(d_type-optimisation,
  43         AS_HELP_STRING(--enable-d_type-optimisation,Synonym for --enable-d_type-optimization),
  44         [ac_cv_d_type=$enableval],[])
  45
  46
  47 AC_MSG_CHECKING([whether debug output should be produced])
  48 if test x$ac_cv_debug = xno; then
  49    AC_MSG_RESULT([no])
  50 else
  51    AC_MSG_RESULT([yes])
  52    AC_DEFINE(DEBUG, 1, [Define if you want to see find's innards])
  53    AC_DEFINE(DEBUG_STAT, 1, [Define if you want to see a message every time find calls the stat() system call])
  54 fi
  55
  56 AC_MSG_CHECKING([for leaf optimisation])
  57 if test x$ac_cv_leaf_optimisation = xno; then
  58    AC_MSG_RESULT([no])
  59 else
  60    AC_MSG_RESULT([yes])
  61    AC_DEFINE(LEAF_OPTIMISATION, 1, [Define if you want to use the leaf optimisation (this can still be turned off with -noleaf)])
  62 fi
  63
  64
  65
  66 dnl Checks for programs.
  67 AC_PROG_CC
  68 AC_PROG_CPP
  69
  70 AC_AIX
  71
  72
  73 dnl AC_MINIX
  74 dnl for gnulib
  75 gl_EARLY
  76 dnl gl_EARLY calls AC_GNU_SOURCE anyway.
  77
  78
  79 AC_ISC_POSIX
  80 AM_C_PROTOTYPES
  81
  82 AC_PROG_INSTALL
  83 AC_PROG_RANLIB
  84 dnl AC_PROG_LIBTOOL
  85 AC_PROG_MAKE_SET
  86 AC_SYS_LARGEFILE
  87
  88
  89 gl_INIT
  90
  91
  92
  93 dnl Older versions of gnulib/m4/nls.m4 provide AM_MKINSTALLDIRS.
  94 dnl The current version of gnulib does not, but the version of
  95 dnl po/Makefile.in.in that comes with gettext-0.14.6 expects
  96 dnl that @MKINSTALLDIRS@ will be expanded.
  97 AM_MKINSTALLDIRS
  98
  99 dnl lib/regexprops needs to be a native program, because we need to
 100 dnl run it in order to generate the documentation about the properties
 101 dnl of regular expressions.  See lib/Makefile.am.
 102 AM_CONDITIONAL(CROSS_COMPILING, [[test "x$cross_compiling" = xyes]])
 103
 104 dnl Try to get a POSIX.1 environment.
 105
 106 dnl Checks for libraries.  If getpwnam() isn't present in the
 107 dnl C library, try -lsun.
 108 AC_CHECK_FUNC(getpwnam, [],
 109 [AC_CHECK_LIB(sun, getpwnam)])
 110
 111 AC_CHECK_LIB([m],[modf],[FINDLIBS="-lm $FINDLIBS"]
 112   AC_DEFINE_UNQUOTED(HAVE_MODF_IN_LIBM,1,[modf is defined in -lm]))
 113 AC_CHECK_LIB([m],[fabs],[FINDLIBS="-lm $FINDLIBS"]
 114   AC_DEFINE_UNQUOTED(HAVE_FABS_IN_LIBM,1,[fabs is defined in -lm]))
 115 AC_SUBST([FINDLIBS])
 116
 117 dnl Checks for header files.
 118 AC_HEADER_STDC
 119 dnl Assume unistd.h is present - coreutils does too.
 120 AC_CHECK_HEADERS(fcntl.h string.h limits.h errno.h stdlib.h stddef.h)
 121 AC_CHECK_HEADERS(unistd.h sys/types.h inttypes.h fcntl.h locale.h stdint.h)
 122 AC_CHECK_HEADERS(sys/param.h mntent.h sys/mnttab.h sys/mntio.h sys/mkdev.h)
 123 dnl find.c needs sys/utsname.h because it calls uname(2).
 124 AC_CHECK_HEADERS(sys/utsname.h)
 125 AC_HEADER_MAJOR
 126 AC_HEADER_DIRENT
 127 AC_HEADER_STAT
 128 AC_HEADER_SYS_WAIT
 129
 130
 131 dnl Checks for typedefs, structures, and compiler characteristics.
 132
 133 AC_TYPE_UID_T
 134 AC_TYPE_SIZE_T
 135 AC_CHECK_TYPE(ssize_t, int)
 136 AC_TYPE_PID_T
 137 AC_CHECK_TYPE(ino_t, unsigned long)
 138 AC_CHECK_TYPE(dev_t, unsigned long)
 139 AC_TYPE_MODE_T
 140 AC_STRUCT_ST_BLOCKS
 141 AC_CHECK_MEMBERS([struct stat.st_rdev])
 142
 143 AC_MSG_CHECKING([whether we should use struct dirent.d_type, if available])
 144 if test x$ac_cv_d_type = xno; then
 145    AC_MSG_RESULT([no])
 146 else
 147    AC_MSG_RESULT([yes])
 148    AC_DEFINE(USE_STRUCT_DIRENT_D_TYPE, 1,
 149    [Defined if you specify --enable-d_type-optimisation to configure.])
 150    AC_CHECK_MEMBERS([struct dirent.d_type],[
 151    AC_DEFINE(HAVE_STRUCT_DIRENT_D_TYPE, 1,
 152    [Define to 1 if your 'struct dirent' has a d_type member])],
 153    [],[
 154 #include <sys/types.h>
 155 #include <dirent.h>])
 156 fi
 157
 158
 159 AC_STRUCT_TM
 160 AC_STRUCT_TIMEZONE
 161
 162 dnl Checks for library functions that are provided by gnulib.
 163 AC_FUNC_STRFTIME
 164 AC_REPLACE_FUNCS(memcmp memset stpcpy strdup strstr strtol strtoul)
 165 AC_CHECK_FUNCS(fchdir getcwd strerror endgrent endpwent setlocale)
 166 AC_FUNC_VPRINTF
 167 AC_FUNC_ALLOCA
 168 AC_FUNC_CLOSEDIR_VOID
 169
 170 dnl We don't just use AC_FUNC_GETMNTENT directly because it
 171 dnl will try to use -lsun on platforms which have getmntent() in the
 172 dnl C library, for example UNICOS.
 173 AC_CHECK_FUNC(getmntent, [], [AC_FUNC_GETMNTENT])
 174 AC_CHECK_FUNCS(getmntent)
 175 AC_CHECK_FUNCS(setmntent endmntent)
 176
 177
 178 dnl Checks for library functions that are provided by findlib.
 179 FINDLIB_REPLACE_FUNCS(waitpid strspn)
 180 FINDLIB_REPLACE_FUNCS(forcefindlib)
 181
 182 dnl gl_XALLOC
 183 gl_FUNC_ALLOCA
 184
 185 dnl Use gl_INCLUDED_REGEX so that findutils will build on systems like
 186 dnl Solaris, which lacks those functions in libc (see GNU Savannah bug
 187 dnl #11710) (Sun Sep  4 20:15:11 2005: gl_INCLUDED_REGEX no longer seems
 188 dnl to be available in gnulib CVS)
 189 gl_REGEX
 190
 191 AC_PREREQ(2.59)
 192
 193 # Define intmax_t to 'signed long' or 'signed long long'
 194 # if it is not already defined in <stdint.h> or <inttypes.h>.
 195 dnl Derived from gnulib's uintmax_t which was from Paul Eggert.
 196 AC_DEFUN([jy_AC_TYPE_INTMAX_T],
 197 [
 198   if test $ac_cv_header_inttypes_h = no && test $ac_cv_header_stdint_h = no; then
 199     AC_REQUIRE([gl_AC_TYPE_LONG_LONG])
 200     test $ac_cv_type_long_long = yes \
 201       && ac_type='long long' \
 202       || ac_type='long'
 203     AC_DEFINE_UNQUOTED(intmax_t, $ac_type,
 204       [Define to signed long or signed long long
 205        if <stdint.h> and <inttypes.h> don't define.])
 206   else
 207     AC_DEFINE(HAVE_INTMAX_T, 1,
 208       [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
 209   fi
 210 ])
 211
 212 jy_AC_TYPE_INTMAX_T
 213 jy_SORTZ
 214
 215
 216 AC_CHECK_MEMBER(struct dirent.d_type,,,[
 217 #include <sys/types.h>
 218 #include <dirent.h>])
 219
 220 jy_AC_ATTRIBUTE_NORETURN
 221
 222 dnl internationalization macros
 223 AM_GNU_GETTEXT([external])
 224 AM_GNU_GETTEXT_VERSION(0.14.5)
 225
 226 dnl regextype.c and regexprops.c are designed to be usable outside findutils,
 227 dnl but findutils doesn't want to support all the regex types in gnulib,
 228 dnl and wants to support an additional one (RE_SYNTAX_EMACS|RE_DOT_NEWLINE).
 229 dnl Hence they need to know if they are being compiled into findutils or not.
 230 AC_DEFINE([FINDUTILS], 1, [Define if we are compiling GNU findutils])
 231
 232
 233 # This is necessary so that .o files in LIBOBJS are also built via
 234 # the ANSI2KNR-filtering rules.
 235 #LIBOBJS=`echo $LIBOBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
 236 ##AC_CONFIG_SUBDIRS(gnulib)
 237 AC_CONFIG_FILES(gnulib/Makefile gnulib/lib/Makefile)
 238 AC_CONFIG_FILES(m4/Makefile)
 239 AC_CONFIG_FILES([Makefile
 240          tests/Makefile build-aux/Makefile
 241         find/Makefile find/testsuite/Makefile
 242         xargs/Makefile xargs/testsuite/Makefile
 243         locate/Makefile locate/testsuite/Makefile
 244          po/Makefile.in po/Makefile
 245         doc/Makefile lib/Makefile
 246         ])
 247 AC_OUTPUT
 248 dnl intl/Makefile