configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(find/pred.c)
   3 AM_CONFIG_HEADER(config.h)
   4
   5 dnl Set of available languages.
   6 ALL_LINGUAS="de es fr it ko nl pl pt_BR ru sv"
   7
   8 AM_INIT_AUTOMAKE(findutils, 4.1.3)
   9
  10 AC_SUBST(INCLUDES)dnl
  11 AC_ARG_ENABLE(id-cache,
  12 [  --enable-id-cache       cache all UIDs & GIDs; avoid if using NIS or Hesiod],
  13   AC_DEFINE(CACHE_IDS))
  14 AC_ARG_WITH(afs,
  15 [  --with-afs              support -fstype afs],
  16 [  AC_DEFINE(AFS)
  17   CPPFLAGS="$CPPFLAGS -I/usr/afsws/include"
  18   LIBS="$LIBS -L/usr/afsws/lib -L/usr/afsws/lib/afs -lsys -lrx -llwp"])
  19 AC_ARG_PROGRAM
  20
  21 dnl Checks for programs.
  22 AC_PROG_CC
  23 AC_AIX
  24 AC_MINIX
  25 AC_ISC_POSIX
  26 AC_PROG_CPP
  27 AM_C_PROTOTYPES
  28 AC_PROG_INSTALL
  29 AC_PROG_RANLIB
  30 AC_PROG_MAKE_SET
  31
  32 dnl Try to get a POSIX.1 environment.
  33
  34 dnl Checks for libraries.
  35 AC_CHECK_LIB(sun, getpwnam)
  36
  37 dnl Checks for header files.
  38 AC_CHECK_HEADERS(fcntl.h string.h limits.h unistd.h errno.h)
  39 AC_HEADER_STDC
  40 AC_HEADER_MAJOR
  41 AC_HEADER_DIRENT
  42 AC_HEADER_STAT
  43 AC_HEADER_SYS_WAIT
  44
  45 AC_MSG_CHECKING(how to get filesystem type)
  46 fstype=no
  47 # The order of these tests is important.
  48 AC_TRY_CPP([#include <sys/statvfs.h>
  49 #include <sys/fstyp.h>], AC_DEFINE(FSTYPE_STATVFS) fstype=SVR4)
  50 if test $fstype = no; then
  51 AC_TRY_CPP([#include <sys/statfs.h>
  52 #include <sys/fstyp.h>], AC_DEFINE(FSTYPE_USG_STATFS) fstype=SVR3)
  53 fi
  54 if test $fstype = no; then
  55 AC_TRY_CPP([#include <sys/statfs.h>
  56 #include <sys/vmount.h>], AC_DEFINE(FSTYPE_AIX_STATFS) fstype=AIX)
  57 fi
  58 if test $fstype = no; then
  59 AC_TRY_CPP([#include <mntent.h>], AC_DEFINE(FSTYPE_MNTENT) fstype=4.3BSD)
  60 fi
  61 if test $fstype = no; then
  62 AC_EGREP_HEADER(f_type;, sys/mount.h, AC_DEFINE(FSTYPE_STATFS) fstype=4.4BSD/OSF1)
  63 fi
  64 if test $fstype = no; then
  65 AC_TRY_CPP([#include <sys/mount.h>
  66 #include <sys/fs_types.h>], AC_DEFINE(FSTYPE_GETMNT) fstype=Ultrix)
  67 fi
  68 AC_MSG_RESULT($fstype)
  69
  70 dnl Checks for typedefs, structures, and compiler characteristics.
  71
  72 AC_TYPE_UID_T
  73 AC_TYPE_SIZE_T
  74 AC_TYPE_PID_T
  75 AC_CHECK_TYPE(ino_t, unsigned long)
  76 AC_CHECK_TYPE(dev_t, unsigned long)
  77 AC_TYPE_MODE_T
  78 AC_STRUCT_ST_BLOCKS
  79 AC_STRUCT_ST_RDEV
  80 AC_STRUCT_TM
  81 AC_STRUCT_TIMEZONE
  82 AC_C_CONST
  83
  84 dnl Checks for library functions.
  85
  86 AC_FUNC_STRFTIME
  87 AC_REPLACE_FUNCS(memcmp memset mktime stpcpy strdup strftime strspn strstr strtol)
  88
  89 jm_MACROS
  90 dnl AM_FUNC_GETLINE
  91 dnl AC_CHECK_FUNC(getstr, ,
  92 dnl     LIBOBJS="$LIBOBJS getline.o"
  93 dnl     AC_SUBST(LIBOBJS)dnl
  94 dnl )
  95
  96 AC_CHECK_FUNCS(fchdir getcwd strerror basename endgrent endpwent)
  97 AC_FUNC_VPRINTF
  98 AC_FUNC_ALLOCA
  99 AC_FUNC_GETMNTENT
 100 AC_FUNC_CLOSEDIR_VOID
 101
 102 dnl internationalization macros
 103 AM_GNU_GETTEXT
 104
 105 # This is necessary so that .o files in LIBOBJS are also built via
 106 # the ANSI2KNR-filtering rules.
 107 LIBOBJS=`echo $LIBOBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
 108 AC_OUTPUT(Makefile lib/Makefile find/Makefile find/testsuite/Makefile
 109         xargs/Makefile xargs/testsuite/Makefile locate/Makefile
 110         locate/updatedb
 111         intl/Makefile po/Makefile.in
 112         doc/Makefile m4/Makefile,
 113           date > stamp-h)