configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT([GNU findutils], 4.3.0-CVSFTS, [bug-findutils@gnu.org])
   3 AM_INIT_AUTOMAKE
   4
   5 AC_CONFIG_SRCDIR([find/pred.c])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CANONICAL_HOST
   8 AC_CONFIG_MACRO_DIR(gnulib/m4)
   9
  10 dnl Set of available languages.
  11 ALL_LINGUAS="be ca da de el eo es et fi fr ga gl hr hu id it ja ko lg ms nl pl pt pt_BR ro ru sk sl sr sv tr vi zh_CN rw"
  12
  13 AC_SUBST(INCLUDES)dnl
  14
  15 dnl check for --with-fts
  16 FIND_WITH_FTS
  17
  18 AC_ARG_ENABLE(id-cache,
  19 [  --enable-id-cache       cache all UIDs & GIDs; avoid if using NIS or Hesiod],
  20   AC_DEFINE(CACHE_IDS, 1, [Define if you want find -nouser and -nogroup to make tables of
  21    used UIDs and GIDs at startup instead of using getpwuid or
  22    getgrgid when needed.  Speeds up -nouser and -nogroup unless you
  23    are running NIS or Hesiod, which make password and group calls
  24    very expensive.]))
  25
  26 AC_ARG_ENABLE(debug,
  27         AS_HELP_STRING(--enable-debug,Enable debugging output which is likely to be interesting to people debugging findutils),
  28         [ac_cv_debug=$enableval],[ac_cv_debug=no])
  29
  30 AC_ARG_ENABLE(leaf-optimisation,
  31         AS_HELP_STRING(--enable-leaf-optimisation,Enable an optimisation which saves lstat calls to identify subdirectories on filesystems having traditional Unix semantics),
  32         [ac_cv_leaf_optimisation=$enableval],[ac_cv_leaf_optimisation=yes])
  33
  34 AC_ARG_ENABLE(d_type-optimization,
  35         AS_HELP_STRING(--enable-d_type-optimization,Make use of the file type data returned in struct dirent.d_type by readdir()),
  36         [ac_cv_d_type=$enableval],[ac_cv_d_type=yes])
  37
  38 dnl This one has no default, because otherwise we would have to say
  39 dnl both --enable-d_type-optimisation=no and --enable-d_type-optimization=no
  40 dnl to turn it off.
  41 AC_ARG_ENABLE(d_type-optimisation,
  42         AS_HELP_STRING(--enable-d_type-optimisation,Synonym for --enable-d_type-optimization),
  43         [ac_cv_d_type=$enableval],[])
  44
  45
  46 AC_MSG_CHECKING([whether debug output should be produced])
  47 if test x$ac_cv_debug = xno; then
  48    AC_MSG_RESULT([no])
  49 else
  50    AC_MSG_RESULT([yes])
  51    AC_DEFINE(DEBUG, 1, [Define if you want to see find's innards])
  52    AC_DEFINE(DEBUG_STAT, 1, [Define if you want to see a message every time find calls the stat() system call])
  53 fi
  54
  55 AC_MSG_CHECKING([for leaf optimisation])
  56 if test x$ac_cv_leaf_optimisation = xno; then
  57    AC_MSG_RESULT([no])
  58 else
  59    AC_MSG_RESULT([yes])
  60    AC_DEFINE(LEAF_OPTIMISATION, 1, [Define if you want to use the leaf optimisation (this can still be turned off with -noleaf)])
  61 fi
  62
  63
  64
  65 dnl Checks for programs.
  66 AC_PROG_CC
  67 AC_PROG_CPP
  68
  69 AC_AIX
  70
  71
  72 dnl AC_MINIX
  73 dnl for gnulib
  74 gl_EARLY
  75 dnl gl_EARLY calls AC_GNU_SOURCE anyway.
  76
  77
  78 AC_ISC_POSIX
  79 AM_C_PROTOTYPES
  80
  81 AC_PROG_INSTALL
  82 AC_PROG_RANLIB
  83 dnl AC_PROG_LIBTOOL
  84 AC_PROG_MAKE_SET
  85 AC_SYS_LARGEFILE
  86
  87
  88 gl_INIT
  89
  90 dnl lib/regexprops needs to be a native program, because we need to
  91 dnl run it in order to generate the documentation about the properties
  92 dnl of regular expressions.  See lib/Makefile.am.
  93 AM_CONDITIONAL(CROSS_COMPILING, [[test "x$cross_compiling" = xyes]])
  94
  95 dnl Try to get a POSIX.1 environment.
  96
  97 dnl Checks for libraries.  If getpwnam() isn't present in the
  98 dnl C library, try -lsun.
  99 AC_CHECK_FUNC(getpwnam, [],
 100 [AC_CHECK_LIB(sun, getpwnam)])
 101
 102 dnl Checks for header files.
 103 AC_HEADER_STDC
 104 dnl Assume unistd.h is present - coreutils does too.
 105 AC_CHECK_HEADERS(fcntl.h string.h limits.h errno.h stdlib.h stddef.h)
 106 AC_CHECK_HEADERS(unistd.h sys/types.h inttypes.h fcntl.h locale.h stdint.h)
 107 AC_CHECK_HEADERS(sys/param.h mntent.h sys/mnttab.h sys/mntio.h sys/mkdev.h)
 108 dnl find.c needs sys/utsname.h because it calls uname(2).
 109 AC_CHECK_HEADERS(sys/utsname.h)
 110 AC_HEADER_MAJOR
 111 AC_HEADER_DIRENT
 112 AC_HEADER_STAT
 113 AC_HEADER_SYS_WAIT
 114
 115
 116 dnl Checks for typedefs, structures, and compiler characteristics.
 117
 118 AC_TYPE_UID_T
 119 AC_TYPE_SIZE_T
 120 AC_CHECK_TYPE(ssize_t, int)
 121 AC_TYPE_PID_T
 122 AC_CHECK_TYPE(ino_t, unsigned long)
 123 AC_CHECK_TYPE(dev_t, unsigned long)
 124 AC_TYPE_MODE_T
 125 AC_STRUCT_ST_BLOCKS
 126 AC_CHECK_MEMBERS([struct stat.st_rdev])
 127
 128 AC_MSG_CHECKING([whether we should use struct dirent.d_type, if available])
 129 if test x$ac_cv_d_type = xno; then
 130    AC_MSG_RESULT([no])
 131 else
 132    AC_MSG_RESULT([yes])
 133    AC_DEFINE(USE_STRUCT_DIRENT_D_TYPE, 1,
 134    [Defined if you specify --enable-d_type-optimisation to configure.])
 135    AC_CHECK_MEMBERS([struct dirent.d_type],[
 136    AC_DEFINE(HAVE_STRUCT_DIRENT_D_TYPE, 1,
 137    [Define to 1 if your 'struct dirent' has a d_type member])],
 138    [],[
 139 #include <sys/types.h>
 140 #include <dirent.h>])
 141 fi
 142
 143
 144 AC_STRUCT_TM
 145 AC_STRUCT_TIMEZONE
 146
 147 dnl Checks for library functions that are provided by gnulib.
 148 AC_FUNC_STRFTIME
 149 AC_REPLACE_FUNCS(memcmp memset stpcpy strdup strstr strtol strtoul)
 150 AC_CHECK_FUNCS(fchdir getcwd strerror endgrent endpwent setlocale)
 151 AC_FUNC_VPRINTF
 152 AC_FUNC_ALLOCA
 153 AC_FUNC_CLOSEDIR_VOID
 154
 155 dnl We don't just use AC_FUNC_GETMNTENT directly because it
 156 dnl will try to use -lsun on platforms which have getmntent() in the
 157 dnl C library, for example UNICOS.
 158 AC_CHECK_FUNC(getmntent, [], [AC_FUNC_GETMNTENT])
 159 AC_CHECK_FUNCS(getmntent)
 160 AC_CHECK_FUNCS(setmntent endmntent)
 161
 162
 163 dnl Checks for library functions that are provided by findlib.
 164 FINDLIB_REPLACE_FUNCS(waitpid strspn)
 165 FINDLIB_REPLACE_FUNCS(forcefindlib)
 166
 167 dnl gl_XALLOC
 168 gl_FUNC_ALLOCA
 169
 170 dnl Use gl_INCLUDED_REGEX so that findutils will build on systems like
 171 dnl Solaris, which lacks those functions in libc (see GNU Savannah bug
 172 dnl #11710)
 173 gl_INCLUDED_REGEX([gnulib/lib/regex.c])
 174
 175 AC_PREREQ(2.59)
 176
 177 # Define intmax_t to 'signed long' or 'signed long long'
 178 # if it is not already defined in <stdint.h> or <inttypes.h>.
 179 dnl Derived from gnulib's uintmax_t which was from Paul Eggert.
 180 AC_DEFUN([jy_AC_TYPE_INTMAX_T],
 181 [
 182   if test $ac_cv_header_inttypes_h = no && test $ac_cv_header_stdint_h = no; then
 183     AC_REQUIRE([gl_AC_TYPE_LONG_LONG])
 184     test $ac_cv_type_long_long = yes \
 185       && ac_type='long long' \
 186       || ac_type='long'
 187     AC_DEFINE_UNQUOTED(intmax_t, $ac_type,
 188       [Define to signed long or signed long long
 189        if <stdint.h> and <inttypes.h> don't define.])
 190   else
 191     AC_DEFINE(HAVE_INTMAX_T, 1,
 192       [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
 193   fi
 194 ])
 195
 196 jy_AC_TYPE_INTMAX_T
 197 jy_SORTZ
 198
 199
 200 AC_CHECK_MEMBER(struct dirent.d_type,,,[
 201 #include <sys/types.h>
 202 #include <dirent.h>])
 203
 204
 205 dnl internationalization macros
 206 AM_GNU_GETTEXT([external])
 207
 208
 209 dnl regextype.c and regexprops.c are designed to be usable outside findutils,
 210 dnl but findutils doesn't want to support all the regex types in gnulib,
 211 dnl and wants to support an additional one (RE_SYNTAX_EMACS|RE_DOT_NEWLINE).
 212 dnl Hence they need to know if they are being compiled into findutils or not.
 213 AC_DEFINE([FINDUTILS], 1, [Define if we are compiling GNU findutils])
 214
 215
 216 # This is necessary so that .o files in LIBOBJS are also built via
 217 # the ANSI2KNR-filtering rules.
 218 #LIBOBJS=`echo $LIBOBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
 219 ##AC_CONFIG_SUBDIRS(gnulib)
 220 AC_CONFIG_FILES(gnulib/Makefile gnulib/lib/Makefile)
 221 AC_CONFIG_FILES(m4/Makefile)
 222 AC_CONFIG_FILES([Makefile
 223         find/Makefile find/testsuite/Makefile
 224         xargs/Makefile xargs/testsuite/Makefile
 225         locate/Makefile locate/testsuite/Makefile
 226          po/Makefile.in po/Makefile
 227         doc/Makefile lib/Makefile
 228         ])
 229 AC_OUTPUT
 230 dnl intl/Makefile