configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(find/pred.c)
   3 AM_CONFIG_HEADER(config.h)
   4
   5 AM_INIT_AUTOMAKE(findutils, 4.1.1)
   6
   7 AC_SUBST(INCLUDES)dnl
   8 AC_ARG_ENABLE(id-cache,
   9 [  --enable-id-cache       cache all UIDs & GIDs; avoid if using NIS or Hesiod],
  10   AC_DEFINE(CACHE_IDS))
  11 AC_ARG_WITH(afs,
  12 [  --with-afs              support -fstype afs],
  13 [  AC_DEFINE(AFS)
  14   CPPFLAGS="$CPPFLAGS -I/usr/afsws/include"
  15   LIBS="$LIBS -L/usr/afsws/lib -L/usr/afsws/lib/afs -lsys -lrx -llwp"])
  16 AC_ARG_PROGRAM
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_PROG_CPP
  21 AC_PROG_INSTALL
  22 AC_PROG_RANLIB
  23 AC_PROG_MAKE_SET
  24
  25 dnl Try to get a POSIX.1 environment.
  26 AC_AIX
  27 AC_MINIX
  28 AC_ISC_POSIX
  29
  30 dnl Checks for libraries.
  31 AC_CHECK_LIB(sun, getpwnam)
  32
  33 dnl Checks for header files.
  34 AC_CHECK_HEADERS(fcntl.h string.h limits.h unistd.h errno.h)
  35 AC_HEADER_STDC
  36 AC_HEADER_MAJOR
  37 AC_HEADER_DIRENT
  38 AC_HEADER_STAT
  39 AC_HEADER_SYS_WAIT
  40
  41 AC_MSG_CHECKING(how to get filesystem type)
  42 fstype=no
  43 # The order of these tests is important.
  44 AC_TRY_CPP([#include <sys/statvfs.h>
  45 #include <sys/fstyp.h>], AC_DEFINE(FSTYPE_STATVFS) fstype=SVR4)
  46 if test $fstype = no; then
  47 AC_TRY_CPP([#include <sys/statfs.h>
  48 #include <sys/fstyp.h>], AC_DEFINE(FSTYPE_USG_STATFS) fstype=SVR3)
  49 fi
  50 if test $fstype = no; then
  51 AC_TRY_CPP([#include <sys/statfs.h>
  52 #include <sys/vmount.h>], AC_DEFINE(FSTYPE_AIX_STATFS) fstype=AIX)
  53 fi
  54 if test $fstype = no; then
  55 AC_TRY_CPP([#include <mntent.h>], AC_DEFINE(FSTYPE_MNTENT) fstype=4.3BSD)
  56 fi
  57 if test $fstype = no; then
  58 AC_EGREP_HEADER(f_type;, sys/mount.h, AC_DEFINE(FSTYPE_STATFS) fstype=4.4BSD/OSF1)
  59 fi
  60 if test $fstype = no; then
  61 AC_TRY_CPP([#include <sys/mount.h>
  62 #include <sys/fs_types.h>], AC_DEFINE(FSTYPE_GETMNT) fstype=Ultrix)
  63 fi
  64 AC_MSG_RESULT($fstype)
  65
  66 dnl Checks for typedefs, structures, and compiler characteristics.
  67
  68 AC_TYPE_UID_T
  69 AC_TYPE_SIZE_T
  70 AC_TYPE_PID_T
  71 AC_CHECK_TYPE(ino_t, unsigned long)
  72 AC_CHECK_TYPE(dev_t, unsigned long)
  73 AC_STRUCT_ST_BLOCKS
  74 AC_STRUCT_ST_RDEV
  75 AC_STRUCT_TM
  76 AC_STRUCT_TIMEZONE
  77 AC_C_CONST
  78
  79 dnl Checks for library functions.
  80
  81 AC_FUNC_STRFTIME
  82 AC_REPLACE_FUNCS(memcmp memset mktime stpcpy strdup strftime strspn strstr strtol)
  83 AC_CHECK_FUNCS(fchdir getcwd strerror basename endgrent endpwent)
  84 AC_FUNC_VPRINTF
  85 AC_FUNC_ALLOCA
  86 AC_FUNC_GETMNTENT
  87 AC_FUNC_CLOSEDIR_VOID
  88
  89 AC_OUTPUT(Makefile lib/Makefile find/Makefile xargs/Makefile \
  90 locate/Makefile doc/Makefile testsuite/Makefile,
  91   date > stamp-h)