configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(find/pred.c)
   3 AM_CONFIG_HEADER(config.h)
   4
   5 AM_INIT_AUTOMAKE(findutils, 4.1.2)
   6
   7 AC_SUBST(INCLUDES)dnl
   8 AC_ARG_ENABLE(id-cache,
   9 [  --enable-id-cache       cache all UIDs & GIDs; avoid if using NIS or Hesiod],
  10   AC_DEFINE(CACHE_IDS))
  11 AC_ARG_WITH(afs,
  12 [  --with-afs              support -fstype afs],
  13 [  AC_DEFINE(AFS)
  14   CPPFLAGS="$CPPFLAGS -I/usr/afsws/include"
  15   LIBS="$LIBS -L/usr/afsws/lib -L/usr/afsws/lib/afs -lsys -lrx -llwp"])
  16 AC_ARG_PROGRAM
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC
  20 AC_AIX
  21 AC_MINIX
  22 AC_ISC_POSIX
  23 AC_PROG_CPP
  24 AM_C_PROTOTYPES
  25 AC_PROG_INSTALL
  26 AC_PROG_RANLIB
  27 AC_PROG_MAKE_SET
  28
  29 dnl Try to get a POSIX.1 environment.
  30
  31 dnl Checks for libraries.
  32 AC_CHECK_LIB(sun, getpwnam)
  33
  34 dnl Checks for header files.
  35 AC_CHECK_HEADERS(fcntl.h string.h limits.h unistd.h errno.h)
  36 AC_HEADER_STDC
  37 AC_HEADER_MAJOR
  38 AC_HEADER_DIRENT
  39 AC_HEADER_STAT
  40 AC_HEADER_SYS_WAIT
  41
  42 AC_MSG_CHECKING(how to get filesystem type)
  43 fstype=no
  44 # The order of these tests is important.
  45 AC_TRY_CPP([#include <sys/statvfs.h>
  46 #include <sys/fstyp.h>], AC_DEFINE(FSTYPE_STATVFS) fstype=SVR4)
  47 if test $fstype = no; then
  48 AC_TRY_CPP([#include <sys/statfs.h>
  49 #include <sys/fstyp.h>], AC_DEFINE(FSTYPE_USG_STATFS) fstype=SVR3)
  50 fi
  51 if test $fstype = no; then
  52 AC_TRY_CPP([#include <sys/statfs.h>
  53 #include <sys/vmount.h>], AC_DEFINE(FSTYPE_AIX_STATFS) fstype=AIX)
  54 fi
  55 if test $fstype = no; then
  56 AC_TRY_CPP([#include <mntent.h>], AC_DEFINE(FSTYPE_MNTENT) fstype=4.3BSD)
  57 fi
  58 if test $fstype = no; then
  59 AC_EGREP_HEADER(f_type;, sys/mount.h, AC_DEFINE(FSTYPE_STATFS) fstype=4.4BSD/OSF1)
  60 fi
  61 if test $fstype = no; then
  62 AC_TRY_CPP([#include <sys/mount.h>
  63 #include <sys/fs_types.h>], AC_DEFINE(FSTYPE_GETMNT) fstype=Ultrix)
  64 fi
  65 AC_MSG_RESULT($fstype)
  66
  67 dnl Checks for typedefs, structures, and compiler characteristics.
  68
  69 AC_TYPE_UID_T
  70 AC_TYPE_SIZE_T
  71 AC_TYPE_PID_T
  72 AC_CHECK_TYPE(ino_t, unsigned long)
  73 AC_CHECK_TYPE(dev_t, unsigned long)
  74 AC_TYPE_MODE_T
  75 AC_STRUCT_ST_BLOCKS
  76 AC_STRUCT_ST_RDEV
  77 AC_STRUCT_TM
  78 AC_STRUCT_TIMEZONE
  79 AC_C_CONST
  80
  81 dnl Checks for library functions.
  82
  83 AC_FUNC_STRFTIME
  84 AC_REPLACE_FUNCS(memcmp memset mktime stpcpy strdup strftime strspn strstr strtol)
  85
  86 jm_MACROS
  87 dnl AM_FUNC_GETLINE
  88 AC_CHECK_FUNC(getstr, ,
  89         LIBOBJS="$LIBOBJS getline.o"
  90         AC_SUBST(LIBOBJS)dnl
  91 )
  92
  93 AC_CHECK_FUNCS(fchdir getcwd strerror basename endgrent endpwent)
  94 AC_FUNC_VPRINTF
  95 AC_FUNC_ALLOCA
  96 AC_FUNC_GETMNTENT
  97 AC_FUNC_CLOSEDIR_VOID
  98
  99 # This is necessary so that .o files in LIBOBJS are also built via
 100 # the ANSI2KNR-filtering rules.
 101 LIBOBJS=`echo $LIBOBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`
 102 AC_OUTPUT(Makefile lib/Makefile find/Makefile find/testsuite/Makefile
 103         xargs/Makefile xargs/testsuite/Makefile locate/Makefile
 104         locate/updatedbnew
 105         doc/Makefile m4/Makefile,
 106           date > stamp-h)