basis/checksums/sha/sha.factor

   1 ! Copyright (C) 2008 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types arrays checksums checksums.common
   4 combinators combinators.smart fry grouping io.binary kernel
   5 kernel.private literals locals math math.bitwise math.ranges
   6 sequences sequences.generalizations sequences.private
   7 specialized-arrays ;
   8 SPECIALIZED-ARRAY: uint
   9 SPECIALIZED-ARRAY: ulong
  10 IN: checksums.sha
  11
  12 MIXIN: sha
  13 INSTANCE: sha block-checksum
  14
  15 SINGLETON: sha1
  16 INSTANCE: sha1 sha
  17
  18 SINGLETON: sha-224
  19 SINGLETON: sha-256
  20
  21 INSTANCE: sha-224 sha
  22 INSTANCE: sha-256 sha
  23
  24 <PRIVATE
  25
  26 TUPLE: sha1-state < block-checksum-state
  27 { K uint-array }
  28 { H uint-array }
  29 { W uint-array }
  30 { word-size fixnum } ;
  31
  32 CONSTANT: initial-H-sha1
  33     uint-array{
  34         0x67452301
  35         0xefcdab89
  36         0x98badcfe
  37         0x10325476
  38         0xc3d2e1f0
  39     }
  40
  41 CONSTANT: K-sha1
  42     $[
  43         20 0x5a827999 <repetition>
  44         20 0x6ed9eba1 <repetition>
  45         20 0x8f1bbcdc <repetition>
  46         20 0xca62c1d6 <repetition>
  47         4 uint-array{ } nappend-as
  48     ]
  49
  50 TUPLE: sha2-state < block-checksum-state
  51 { K uint-array }
  52 { H uint-array }
  53 { word-size fixnum } ;
  54
  55 TUPLE: sha2-short < sha2-state ;
  56
  57 TUPLE: sha2-long < sha2-state ;
  58
  59 TUPLE: sha-224-state < sha2-short ;
  60
  61 TUPLE: sha-256-state < sha2-short ;
  62
  63 M: sha2-state clone
  64     call-next-method
  65     [ clone ] change-H
  66     [ clone ] change-K ;
  67
  68 CONSTANT: a 0
  69 CONSTANT: b 1
  70 CONSTANT: c 2
  71 CONSTANT: d 3
  72 CONSTANT: e 4
  73 CONSTANT: f 5
  74 CONSTANT: g 6
  75 CONSTANT: h 7
  76
  77 CONSTANT: initial-H-224
  78     uint-array{
  79         0xc1059ed8 0x367cd507 0x3070dd17 0xf70e5939
  80         0xffc00b31 0x68581511 0x64f98fa7 0xbefa4fa4
  81     }
  82
  83 CONSTANT: initial-H-256
  84     uint-array{
  85         0x6a09e667 0xbb67ae85 0x3c6ef372 0xa54ff53a
  86         0x510e527f 0x9b05688c 0x1f83d9ab 0x5be0cd19
  87     }
  88
  89 CONSTANT: initial-H-384
  90     ulong-array{
  91         0xcbbb9d5dc1059ed8
  92         0x629a292a367cd507
  93         0x9159015a3070dd17
  94         0x152fecd8f70e5939
  95         0x67332667ffc00b31
  96         0x8eb44a8768581511
  97         0xdb0c2e0d64f98fa7
  98         0x47b5481dbefa4fa4
  99     }
 100
 101 CONSTANT: initial-H-512
 102     ulong-array{
 103         0x6a09e667f3bcc908
 104         0xbb67ae8584caa73b
 105         0x3c6ef372fe94f82b
 106         0xa54ff53a5f1d36f1
 107         0x510e527fade682d1
 108         0x9b05688c2b3e6c1f
 109         0x1f83d9abfb41bd6b
 110         0x5be0cd19137e2179
 111     }
 112
 113 CONSTANT: K-256
 114     uint-array{
 115         0x428a2f98 0x71374491 0xb5c0fbcf 0xe9b5dba5
 116         0x3956c25b 0x59f111f1 0x923f82a4 0xab1c5ed5
 117         0xd807aa98 0x12835b01 0x243185be 0x550c7dc3
 118         0x72be5d74 0x80deb1fe 0x9bdc06a7 0xc19bf174
 119         0xe49b69c1 0xefbe4786 0x0fc19dc6 0x240ca1cc
 120         0x2de92c6f 0x4a7484aa 0x5cb0a9dc 0x76f988da
 121         0x983e5152 0xa831c66d 0xb00327c8 0xbf597fc7
 122         0xc6e00bf3 0xd5a79147 0x06ca6351 0x14292967
 123         0x27b70a85 0x2e1b2138 0x4d2c6dfc 0x53380d13
 124         0x650a7354 0x766a0abb 0x81c2c92e 0x92722c85
 125         0xa2bfe8a1 0xa81a664b 0xc24b8b70 0xc76c51a3
 126         0xd192e819 0xd6990624 0xf40e3585 0x106aa070
 127         0x19a4c116 0x1e376c08 0x2748774c 0x34b0bcb5
 128         0x391c0cb3 0x4ed8aa4a 0x5b9cca4f 0x682e6ff3
 129         0x748f82ee 0x78a5636f 0x84c87814 0x8cc70208
 130         0x90befffa 0xa4506ceb 0xbef9a3f7 0xc67178f2
 131     }
 132
 133 CONSTANT: K-384
 134     ulong-array{
 135         0x428a2f98d728ae22 0x7137449123ef65cd 0xb5c0fbcfec4d3b2f 0xe9b5dba58189dbbc
 136         0x3956c25bf348b538 0x59f111f1b605d019 0x923f82a4af194f9b 0xab1c5ed5da6d8118
 137         0xd807aa98a3030242 0x12835b0145706fbe 0x243185be4ee4b28c 0x550c7dc3d5ffb4e2
 138         0x72be5d74f27b896f 0x80deb1fe3b1696b1 0x9bdc06a725c71235 0xc19bf174cf692694
 139         0xe49b69c19ef14ad2 0xefbe4786384f25e3 0x0fc19dc68b8cd5b5 0x240ca1cc77ac9c65
 140         0x2de92c6f592b0275 0x4a7484aa6ea6e483 0x5cb0a9dcbd41fbd4 0x76f988da831153b5
 141         0x983e5152ee66dfab 0xa831c66d2db43210 0xb00327c898fb213f 0xbf597fc7beef0ee4
 142         0xc6e00bf33da88fc2 0xd5a79147930aa725 0x06ca6351e003826f 0x142929670a0e6e70
 143         0x27b70a8546d22ffc 0x2e1b21385c26c926 0x4d2c6dfc5ac42aed 0x53380d139d95b3df
 144         0x650a73548baf63de 0x766a0abb3c77b2a8 0x81c2c92e47edaee6 0x92722c851482353b
 145         0xa2bfe8a14cf10364 0xa81a664bbc423001 0xc24b8b70d0f89791 0xc76c51a30654be30
 146         0xd192e819d6ef5218 0xd69906245565a910 0xf40e35855771202a 0x106aa07032bbd1b8
 147         0x19a4c116b8d2d0c8 0x1e376c085141ab53 0x2748774cdf8eeb99 0x34b0bcb5e19b48a8
 148         0x391c0cb3c5c95a63 0x4ed8aa4ae3418acb 0x5b9cca4f7763e373 0x682e6ff3d6b2b8a3
 149         0x748f82ee5defb2fc 0x78a5636f43172f60 0x84c87814a1f0ab72 0x8cc702081a6439ec
 150         0x90befffa23631e28 0xa4506cebde82bde9 0xbef9a3f7b2c67915 0xc67178f2e372532b
 151         0xca273eceea26619c 0xd186b8c721c0c207 0xeada7dd6cde0eb1e 0xf57d4f7fee6ed178
 152         0x06f067aa72176fba 0x0a637dc5a2c898a6 0x113f9804bef90dae 0x1b710b35131c471b
 153         0x28db77f523047d84 0x32caab7b40c72493 0x3c9ebe0a15c9bebc 0x431d67c49c100d4c
 154         0x4cc5d4becb3e42b6 0x597f299cfc657e2a 0x5fcb6fab3ad6faec 0x6c44198c4a475817
 155     }
 156
 157 ALIAS: K-512 K-384
 158
 159 : <sha1-state> ( -- sha1-state )
 160     sha1-state new-checksum-state
 161         64 >>block-size
 162         K-sha1 >>K
 163         initial-H-sha1 >>H
 164         4 >>word-size ;
 165
 166 : <sha-224-state> ( -- sha2-state )
 167     sha-224-state new-checksum-state
 168         64 >>block-size
 169         K-256 >>K
 170         initial-H-224 >>H
 171         4 >>word-size ;
 172
 173 : <sha-256-state> ( -- sha2-state )
 174     sha-256-state new-checksum-state
 175         64 >>block-size
 176         K-256 >>K
 177         initial-H-256 >>H
 178         4 >>word-size ;
 179
 180 M: sha1 initialize-checksum-state drop <sha1-state> ;
 181
 182 M: sha-224 initialize-checksum-state drop <sha-224-state> ;
 183
 184 M: sha-256 initialize-checksum-state drop <sha-256-state> ;
 185
 186 : s0-256 ( x -- x' )
 187     [
 188         [ -7 bitroll-32 ]
 189         [ -18 bitroll-32 ]
 190         [ -3 shift ] tri
 191     ] [ bitxor ] reduce-outputs ; inline
 192
 193 : s1-256 ( x -- x' )
 194     [
 195         [ -17 bitroll-32 ]
 196         [ -19 bitroll-32 ]
 197         [ -10 shift ] tri
 198     ] [ bitxor ] reduce-outputs ; inline
 199
 200 : S0-256 ( x -- x' )
 201     [
 202         [ -2 bitroll-32 ]
 203         [ -13 bitroll-32 ]
 204         [ -22 bitroll-32 ] tri
 205     ] [ bitxor ] reduce-outputs ; inline
 206
 207 : S1-256 ( x -- x' )
 208     [
 209         [ -6 bitroll-32 ]
 210         [ -11 bitroll-32 ]
 211         [ -25 bitroll-32 ] tri
 212     ] [ bitxor ] reduce-outputs ; inline
 213
 214 : s0-512 ( x -- x' )
 215     [
 216         [ -1 bitroll-64 ]
 217         [ -8 bitroll-64 ]
 218         [ -7 shift ] tri
 219     ] [ bitxor ] reduce-outputs ; inline
 220
 221 : s1-512 ( x -- x' )
 222     [
 223         [ -19 bitroll-64 ]
 224         [ -61 bitroll-64 ]
 225         [ -6 shift ] tri
 226     ] [ bitxor ] reduce-outputs ; inline
 227
 228 : S0-512 ( x -- x' )
 229     [
 230         [ -28 bitroll-64 ]
 231         [ -34 bitroll-64 ]
 232         [ -39 bitroll-64 ] tri
 233     ] [ bitxor ] reduce-outputs ; inline
 234
 235 : S1-512 ( x -- x' )
 236     [
 237         [ -14 bitroll-64 ]
 238         [ -18 bitroll-64 ]
 239         [ -41 bitroll-64 ] tri
 240     ] [ bitxor ] reduce-outputs ; inline
 241
 242 : prepare-M-256 ( n seq -- )
 243     { uint-array } declare
 244     {
 245         [ [ 16 - ] dip nth-unsafe ]
 246         [ [ 15 - ] dip nth-unsafe s0-256 ]
 247         [ [ 7 - ] dip nth-unsafe ]
 248         [ [ 2 - ] dip nth-unsafe s1-256 w+ w+ w+ ]
 249         [ ]
 250     } 2cleave set-nth-unsafe ; inline
 251
 252 : prepare-M-512 ( n seq -- )
 253     { ulong-array } declare
 254     {
 255         [ [ 16 - ] dip nth-unsafe ]
 256         [ [ 15 - ] dip nth-unsafe s0-512 ]
 257         [ [ 7 - ] dip nth-unsafe ]
 258         [ [ 2 - ] dip nth-unsafe s1-512 w+ w+ w+ ]
 259         [ ]
 260     } 2cleave set-nth-unsafe ; inline
 261
 262 : ch ( x y z -- x' )
 263     [ bitxor bitand ] keep bitxor ; inline
 264
 265 : maj ( x y z -- x' )
 266     [ [ bitand ] [ bitor ] 2bi ] dip bitand bitor ; inline
 267
 268 : slice3 ( n seq -- a b c )
 269     [ dup 3 + ] dip <slice> first3 ; inline
 270
 271 GENERIC: pad-initial-bytes ( string sha2 -- padded-string )
 272
 273 :: T1-256 ( n M H sha2 -- T1 )
 274     n M nth-unsafe
 275     n sha2 K>> nth-unsafe +
 276     e H slice3 ch w+
 277     e H nth-unsafe S1-256 w+
 278     h H nth-unsafe w+ ; inline
 279
 280 :: T2-256 ( H -- T2 )
 281     a H nth-unsafe S0-256
 282     a H slice3 maj w+ ; inline
 283
 284 :: T1-512 ( n M H sha2 -- T1 )
 285     n M nth-unsafe
 286     n sha2 K>> nth-unsafe +
 287     e H slice3 ch w+
 288     e H nth-unsafe S1-512 w+
 289     h H nth-unsafe w+ ; inline
 290
 291 :: T2-512 ( H -- T2 )
 292     a H nth-unsafe S0-512
 293     a H slice3 maj w+ ; inline
 294
 295 :: update-H ( T1 T2 H -- )
 296     h g H exchange-unsafe
 297     g f H exchange-unsafe
 298     f e H exchange-unsafe
 299     T1 d H nth-unsafe w+ e H set-nth-unsafe
 300     d c H exchange-unsafe
 301     c b H exchange-unsafe
 302     b a H exchange-unsafe
 303     T1 T2 w+ a H set-nth-unsafe ; inline
 304
 305 : prepare-message-schedule ( seq sha2 -- w-seq )
 306     [ word-size>> <groups> ] [ block-size>> <uint-array> ] bi
 307     [ '[ [ be> ] dip _ set-nth-unsafe ] each-index ]
 308     [ 16 over length [a,b) over '[ _ prepare-M-256 ] each ] bi ; inline
 309
 310 :: process-chunk ( M block-size cloned-H sha2 -- )
 311     block-size [
 312         M cloned-H sha2 T1-256
 313         cloned-H T2-256
 314         cloned-H update-H
 315     ] each-integer
 316     sha2 [ cloned-H [ w+ ] 2map ] change-H drop ; inline
 317
 318 M: sha2-short checksum-block
 319     [ prepare-message-schedule ]
 320     [ [ block-size>> ] [ H>> clone ] [ ] tri process-chunk ] bi ;
 321
 322 : sequence>byte-array ( seq n -- bytes )
 323     '[ _ >be ] { } map-as B{ } concat-as ; inline
 324
 325 : sha1>checksum ( sha2 -- bytes )
 326     H>> 4 sequence>byte-array ; inline
 327
 328 : sha-224>checksum ( sha2 -- bytes )
 329     H>> 7 head 4 sequence>byte-array ; inline
 330
 331 : sha-256>checksum ( sha2 -- bytes )
 332     H>> 4 sequence>byte-array ; inline
 333
 334 : pad-last-short-block ( state -- )
 335     [ bytes>> t ] [ bytes-read>> pad-last-block ] [ ] tri
 336     [ checksum-block ] curry each ; inline
 337
 338 M: sha-224-state get-checksum
 339     clone
 340     [ pad-last-short-block ] [ sha-224>checksum ] bi ;
 341
 342 M: sha-256-state get-checksum
 343     clone
 344     [ pad-last-short-block ] [ sha-256>checksum ] bi ;
 345
 346 : sha1-W ( t seq -- )
 347     { uint-array } declare
 348     {
 349         [ [ 3 - ] dip nth-unsafe ]
 350         [ [ 8 - ] dip nth-unsafe bitxor ]
 351         [ [ 14 - ] dip nth-unsafe bitxor ]
 352         [ [ 16 - ] dip nth-unsafe bitxor 1 bitroll-32 ]
 353         [ ]
 354     } 2cleave set-nth-unsafe ; inline
 355
 356 : prepare-sha1-message-schedule ( seq -- w-seq )
 357     4 <groups> 80 <uint-array>
 358     [ '[ [ be> ] dip _ set-nth-unsafe ] each-index ]
 359     [ 16 80 [a,b) over '[ _ sha1-W ] each ] bi ; inline
 360
 361 : sha1-f ( B C D n -- f_nbcd )
 362     20 /i
 363     {
 364         { 0 [ [ over bitnot ] dip bitand [ bitand ] dip bitor ] }
 365         { 1 [ bitxor bitxor ] }
 366         { 2 [ 2dup bitand [ pick bitand [ bitand ] dip ] dip bitor bitor ] }
 367         { 3 [ bitxor bitxor ] }
 368     } case ; inline
 369
 370 :: inner-loop ( n H W K -- temp )
 371     a H nth-unsafe :> A
 372     b H nth-unsafe :> B
 373     c H nth-unsafe :> C
 374     d H nth-unsafe :> D
 375     e H nth-unsafe :> E
 376     [
 377         A 5 bitroll-32
 378
 379         B C D n sha1-f
 380
 381         E
 382
 383         n K nth-unsafe
 384
 385         n W nth-unsafe
 386     ] sum-outputs 32 bits ; inline
 387
 388 :: process-sha1-chunk ( H W K state -- )
 389     80 [
 390         H W K inner-loop
 391         d H nth-unsafe e H set-nth-unsafe
 392         c H nth-unsafe d H set-nth-unsafe
 393         b H nth-unsafe 30 bitroll-32 c H set-nth-unsafe
 394         a H nth-unsafe b H set-nth-unsafe
 395         a H set-nth-unsafe
 396     ] each-integer
 397     state [ H [ w+ ] 2map ] change-H drop ; inline
 398
 399 M:: sha1-state checksum-block ( bytes state -- )
 400     bytes prepare-sha1-message-schedule state W<<
 401
 402     state [ H>> clone ] [ W>> ] [ K>> ] tri state process-sha1-chunk ;
 403
 404 M: sha1-state get-checksum
 405     clone
 406     [ pad-last-short-block ] [ sha-256>checksum ] bi ;
 407
 408 PRIVATE>