configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.13)
   4 AC_INIT(src/main/main.c)
   5 AC_CONFIG_AUX_DIR(config)
   6
   7 PACKAGE=elinks
   8 VERSION=0.12.GIT
   9 AC_SUBST(PACKAGE)
  10 AC_SUBST(VERSION)
  11 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  12 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  13 AC_CONFIG_HEADERS(config.h)
  14
  15 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  16 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  17 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  18
  19 MAKE=
  20
  21 for make in gnumake gmake make false; do
  22         if test "x$MAKE" = x; then
  23                 AC_PATH_PROGS(MAKE, "$make")
  24         fi
  25 done
  26
  27 builddir="`pwd`"
  28
  29 # Cleanup if we are configuring with a previous build in the tree
  30 if test -e Makefile.config; then
  31         AC_MSG_CHECKING([for previous build to clean])
  32         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  33         AC_MSG_RESULT(done)
  34 fi
  35
  36 dnl ===================================================================
  37 dnl Load feature configuration file and start logging features.
  38 dnl ===================================================================
  39
  40 features="features.conf"
  41 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  42 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  43 echo "Feature summary:" > features.log
  44
  45 dnl ===================================================================
  46 dnl Checks for programs.
  47 dnl ===================================================================
  48
  49 AC_PROG_CC
  50 AC_PROG_AWK
  51 AC_PATH_PROGS(AWK, "$AWK")
  52 AC_PROG_RANLIB
  53 AC_PROG_INSTALL
  54
  55 AC_PATH_PROGS(CG_COMMIT_ID, "cg-commit-id")
  56 AC_PATH_PROGS(SPARSE, "sparse")
  57
  58 CONFIG_ASCIIDOC="no"
  59 CONFIG_POD2HTML="no"
  60 CONFIG_XMLTO="no"
  61 CONFIG_JW="no"
  62
  63 if test "x$CONFIG_DOC" != xno; then
  64         AC_PATH_PROGS(ASCIIDOC, "asciidoc")
  65         if test "x$ASCIIDOC" != "x"; then
  66                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  67                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  68                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  69
  70                 echo > config.asciidoc-unsafe.txt
  71                 if "$ASCIIDOC" --unsafe config.asciidoc-unsafe.txt >/dev/null 2>/dev/null; then
  72                         ASCIIDOC_FLAGS=--unsafe
  73                 fi
  74                 rm config.asciidoc-unsafe.*
  75         fi
  76
  77         AC_PATH_PROGS(XMLTO, "xmlto")
  78         if test "x$XMLTO" != "x"; then
  79                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  80                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  81                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  82         fi
  83
  84         AC_PATH_PROGS(JW, "jw")
  85         if test "x$JW" != "x"; then
  86                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  87                 EL_CONFIG(MANUAL_JW, [PDF])
  88         fi
  89
  90         AC_PATH_PROGS(POD2HTML, "pod2html")
  91         if test "x$POD2HTML" != "x"; then
  92                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
  93         fi
  94 fi
  95
  96 AC_SUBST(ASCIIDOC_FLAGS)
  97 AC_SUBST(CONFIG_ASCIIDOC)
  98 AC_SUBST(CONFIG_POD2HTML)
  99 AC_SUBST(CONFIG_XMLTO)
 100 AC_SUBST(CONFIG_JW)
 101
 102 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 103 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 104 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 105
 106 dnl gcc specific options (to be continued at the bottom of configure)
 107 if test "x$ac_cv_prog_gcc" = "xyes"; then
 108   dnl We want to see all warnings and live with none.
 109   dnl We can't set up -Werror here as there may be some warnings in test
 110   dnl suite of configure, and we don't want to fail them.
 111   CFLAGS="$CFLAGS -Wall"
 112 fi
 113
 114 dnl ===================================================================
 115 dnl Checks for special OSes.
 116 dnl ===================================================================
 117
 118 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 119 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 120 [
 121         AC_MSG_CHECKING([for $2])
 122
 123         for flag in $3; do
 124                 AC_TRY_COMPILE(, [#ifndef $flag
 125 kill me!
 126 #endif ], $1=yes, $1=no)
 127                 if test "[$]$1" = yes; then
 128                         EL_CONFIG([$1], [$2])
 129                         break
 130                 fi
 131         done
 132
 133         AC_MSG_RESULT([$]$1)
 134 ])
 135
 136 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 137 AC_SUBST(CONFIG_OS_BEOS)
 138
 139 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 140 AC_SUBST(CONFIG_OS_RISCOS)
 141
 142 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 143 AC_SUBST(CONFIG_OS_WIN32)
 144
 145 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 146 AC_SUBST(CONFIG_OS_OS2)
 147 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 148
 149 AC_MSG_CHECKING([for UNIX])
 150 dnl FIXME: some depend kind of mechanism
 151 if test "$CONFIG_OS_BEOS" = no && \
 152    test "$CONFIG_OS_RISCOS" = no && \
 153    test "$CONFIG_OS_WIN32" = no && \
 154    test "$CONFIG_OS_OS2" = no; then
 155         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 156 else
 157         CONFIG_OS_UNIX=no
 158 fi
 159 AC_MSG_RESULT($CONFIG_OS_UNIX)
 160 AC_SUBST(CONFIG_OS_UNIX)
 161
 162 dnl ===================================================================
 163 dnl Checks for header files.
 164 dnl ===================================================================
 165
 166 AC_HEADER_DIRENT
 167 AC_HEADER_STDC
 168 AC_HEADER_SYS_WAIT
 169 AC_HEADER_TIME
 170
 171 AC_CHECK_HEADERS(wctype.h)
 172 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 173 AC_CHECK_HEADERS(sigaction.h)
 174 AC_CHECK_HEADERS(arpa/inet.h)
 175 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 176 AC_CHECK_HEADERS(net/if.h netdb.h netinet/in.h netinet/in6_var.h)
 177 AC_CHECK_HEADERS(ifaddrs.h)
 178 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 179 AC_CHECK_HEADERS(sys/fmutex.h)
 180 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 181 AC_CHECK_HEADERS(sys/resource.h)
 182 AC_CHECK_HEADERS(sys/select.h)
 183 AC_CHECK_HEADERS(sys/signal.h)
 184 AC_CHECK_HEADERS(sys/socket.h)
 185 AC_CHECK_HEADERS(sys/time.h)
 186 AC_CHECK_HEADERS(sys/utsname.h)
 187 AC_CHECK_HEADERS(stdint.h inttypes.h)
 188 AC_CHECK_HEADERS(locale.h pwd.h)
 189 AC_CHECK_HEADERS(termios.h)
 190
 191
 192 AC_CHECK_HEADERS(sys/un.h,
 193         [CONFIG_INTERLINK=yes
 194          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 195         [CONFIG_INTERLINK=no])
 196 AC_SUBST(CONFIG_INTERLINK)
 197
 198 dnl ===================================================================
 199 dnl Checks for typedefs, structures, and compiler characteristics.
 200 dnl ===================================================================
 201
 202 AC_STRUCT_TM
 203 AC_C_CONST
 204 AC_C_INLINE
 205 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 206
 207 AC_SYS_LARGEFILE
 208 AC_TYPE_SIZE_T
 209 AC_TYPE_OFF_T
 210 EL_CHECK_TYPE(ssize_t, int)
 211 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 212 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 213 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 214 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 215 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 216
 217 AC_CHECK_SIZEOF(char, 1)
 218 AC_CHECK_SIZEOF(short, 2)
 219 AC_CHECK_SIZEOF(int, 4)
 220 AC_CHECK_SIZEOF(long, 4)
 221 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 222 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 223
 224 dnl Check for variadic macros
 225 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 226                 [#include <stdio.h>
 227                  #define a(b,c...) printf(b,##c)],
 228                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 229
 230 dnl Check for -rdynamic
 231 dnl
 232 dnl gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
 233 dnl the executable to its dynamic symbol table.  ELinks uses this for
 234 dnl two purposes:
 235 dnl
 236 dnl 1. If ELinks detects a bug, it can try to display a backtrace by
 237 dnl    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
 238 dnl    manual states users of GNU ld must pass -rdynamic to make the
 239 dnl    symbols available to the program.
 240 dnl
 241 dnl 2. It would eventually be nice to dynamically load shared
 242 dnl    libraries as plugins (bug 73).  The plugins must be able to
 243 dnl    call ELinks functions.  This can be implemented either by
 244 dnl    registering all callable functions in ELinks-specific data
 245 dnl    structures, or by letting the dynamic linker handle them.
 246 dnl    The latter way requires something equivalent to -rdynamic.
 247 dnl
 248 dnl Because backtraces are not needed for correct operation, and bug
 249 dnl 73 is not yet being fixed, the configure script and makefiles
 250 dnl should not complain to the user if they find that -rdynamic does
 251 dnl not work.  Besides, it was reported at elinks-users on 2006-09-12
 252 dnl that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
 253 dnl Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
 254 dnl -rdynamic but does something equivalent automatically.  (This was
 255 dnl tested with "nm -D elinks | grep redraw_from_window".)
 256 dnl
 257 dnl FIXME: This check doesn't work. Something to do with the compiler
 258 dnl happily ignoring it and stderr not being checked for error messages.
 259 AC_MSG_CHECKING([for -rdynamic])
 260 LDFLAGS_X="$LDFLAGS"
 261 LDFLAGS="$LDFLAGS -rdynamic"
 262 AC_TRY_LINK([], [], have_rdynamic=yes, have_rdynamic=no)
 263 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
 264 AC_MSG_RESULT($have_rdynamic)
 265
 266 dnl ===================================================================
 267 dnl Check for POSIX <regex.h>
 268 dnl ===================================================================
 269
 270 EL_CHECK_SYS_TYPE(regex_t, HAVE_REGEX_H, [#include <regex.h>])
 271
 272 dnl ===================================================================
 273 dnl Checks for library functions.
 274 dnl ===================================================================
 275
 276 AC_PROG_GCC_TRADITIONAL
 277 AC_FUNC_MEMCMP
 278 AC_FUNC_MMAP
 279 AC_FUNC_STRFTIME
 280 AC_CHECK_FUNCS(atoll cfmakeraw gethostbyaddr herror strerror)
 281 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 282 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 283 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 284 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 285 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 286 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 287 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 288
 289 AC_HAVE_FUNCS(cygwin_conv_to_full_win32_path)
 290
 291 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 292 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 293 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 294
 295 dnl These aren't probably needed now, as they are commented in links.h.
 296 dnl I've no idea about their historical background, but I keep them here
 297 dnl just in the case they will help later. --pasky
 298 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 299 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 300 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 301 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 302
 303 if test x"$HAVE_RAISE" = x; then
 304         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 305                 AC_ERROR([Unable to emulate raise()])
 306         fi
 307 fi
 308
 309 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 310 AC_TRY_LINK([#include <stdarg.h>
 311 va_list ap1,ap2;], [__va_copy(ap1,ap2);],
 312 el_cv_HAVE_VA_COPY=yes,el_cv_HAVE_VA_COPY=no)])
 313 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 314         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 315 fi
 316
 317 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 318 AC_TRY_LINK([#include <unistd.h>
 319 ], [int page_size = sysconf(_SC_PAGE_SIZE);],
 320 el_cv_HAVE_SC_PAGE_SIZE=yes,el_cv_HAVE_SC_PAGE_SIZE=no)])
 321 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 322         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 323 fi
 324
 325 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 326 AC_TRY_RUN([
 327 #include <stdio.h>
 328 #include <stdarg.h>
 329 #include <stdlib.h>
 330 #include <string.h>
 331
 332 char buf[8];
 333
 334 int bar(char *buf, const char *format, va_list ap)
 335 {
 336        return vsnprintf(buf, 0, format, ap);
 337 }
 338
 339 void foo(const char *format, ...) {
 340        va_list ap;
 341        int len;
 342
 343        va_start(ap, format);
 344        len = bar(buf, format, ap);
 345        va_end(ap);
 346        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 347
 348        va_start(ap, format);
 349        len = bar(buf, format, ap);
 350        va_end(ap);
 351        if ((len != 6) && (len != 7)) exit(1);
 352
 353        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 354
 355        exit(0);
 356 }
 357 main() { foo("hello\n"); }
 358 ],
 359 el_cv_HAVE_C99_VSNPRINTF=yes,el_cv_HAVE_C99_VSNPRINTF=no,el_cv_HAVE_C99_VSNPRINTF=cross)])
 360 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 361         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 362 fi
 363
 364 AC_CHECK_LIB(dl, dlopen) # OpenSSL and Lua frequently needs it
 365
 366 dnl ===================================================================
 367 dnl Checks for libraries.
 368 dnl ===================================================================
 369
 370 dnl Replace `main' with a function in -lsocket:
 371 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 372 if test "$cf_result" = no; then
 373         AC_CHECK_LIB(socket, socket)
 374 fi
 375
 376 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 377 if test "$cf_result" = no; then
 378         AC_CHECK_LIB(socket, setsockopt)
 379 fi
 380
 381 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 382 if test "$cf_result" = no; then
 383         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 384         if test "$cf_result" = no; then
 385                 AC_CHECK_LIB(nsl, gethostbyname)
 386         else
 387                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 388         fi
 389 fi
 390
 391 dnl ===================================================================
 392 dnl Checks for packaging specific options.
 393 dnl ===================================================================
 394
 395 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 396             [ if test "$withval" != no && test "$withval" != yes; then
 397                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 398               fi ])
 399
 400 dnl ===================================================================
 401 dnl Checks for a libraries, optional even if installed.
 402 dnl ===================================================================
 403
 404 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 405 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 406 [
 407         AC_MSG_CHECKING([for $2 support])
 408
 409         if test "[$]$1" != no; then
 410                 AC_MSG_RESULT(yes)
 411                 EL_SAVE_FLAGS
 412                 if test -n "$withval" && test -d "$withval"; then
 413                         # Be a little more careful when setting
 414                         # include and lib directories. This way
 415                         # $withval will work when includes are
 416                         # there but the library is in the common
 417                         # /usr/lib ... Does the right thing when
 418                         # looking for gc on Debian.
 419                         if test -d "$withval/include"; then
 420                                 CFLAGS="$CFLAGS -I$withval/include"
 421                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 422                         else
 423                                 CFLAGS="$CFLAGS -I$withval"
 424                                 CPPFLAGS="$CPPFLAGS -I$withval"
 425                         fi
 426                         if test -d "$withval/lib"; then
 427                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 428                         fi
 429                 fi
 430
 431                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 432                 if test "[$]$1" = yes; then
 433                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 434                 fi
 435
 436                 if test "[$]$1" = yes; then
 437                         EL_CONFIG([$1], [$2])
 438                         LIBS="$LIBS -l$4"
 439                 else
 440                         if test -n "[$]WITHVAL_$1" &&
 441                            test "[$]WITHVAL_$1" != xno; then
 442                                 AC_MSG_ERROR([$2 not found])
 443                         fi
 444                         EL_RESTORE_FLAGS
 445                 fi
 446         else
 447                 AC_MSG_RESULT(disabled)
 448         fi
 449 ])
 450
 451 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 452 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 453 [
 454         $1=yes
 455         WITHVAL_$1=
 456
 457         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 458         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 459
 460         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 461
 462         EL_LOG_CONFIG([$1], [$2], [])
 463 ])
 464
 465 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 466         [  --without-gpm           disable gpm (mouse) support])
 467
 468 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 469         [  --without-zlib          disable zlib support])
 470
 471 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 472         [  --without-bzlib         disable bzlib support])
 473
 474 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 475         [  --without-idn           disable international domain names support])
 476
 477 if test "x{with_gc}" != xno; then
 478         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 479                 [  --with-gc               enable Boehm's garbage collector])
 480 fi
 481
 482 EL_ARG_ENABLE(CONFIG_LZMA, lzma, [lzma],
 483               [  --enable-lzma           enable lzma encoding support])
 484
 485 dnl ===================================================================
 486 dnl Check for GSSAPI, optional even if installed.
 487 dnl ===================================================================
 488
 489 enable_gssapi="no";
 490
 491 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 492             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 493
 494 AC_MSG_CHECKING([for GSSAPI])
 495
 496 if test "$enable_gssapi" = "yes"; then
 497         AC_MSG_RESULT(yes)
 498         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 499         GSSAPI_LIBS=`krb5-config --libs gssapi`
 500         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 501         LIBS="$GSSAPI_LIBS $LIBS"
 502         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 503 else
 504         AC_MSG_RESULT(no)
 505 fi
 506
 507 AC_SUBST(CONFIG_GSSAPI)
 508
 509 dnl ===================================================================
 510 dnl Bookmark and XBEL support
 511 dnl ===================================================================
 512
 513 EL_SAVE_FLAGS
 514
 515 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 516               [  --disable-bookmarks     disable bookmark support])
 517
 518 # Check whether --enable-xbel or --disable-xbel was given.
 519 if test "x${enable_xbel}" != xno; then
 520         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 521
 522         if test "$HAVE_LIBEXPAT" = yes; then
 523                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 524                 if test "$HAVE_LIBEXPAT" = yes; then
 525                         LIBS="$LIBS -lexpat"
 526                 fi
 527         fi
 528 fi
 529
 530
 531 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 532               [XBEL bookmarks],
 533               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 534
 535 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 536         EL_RESTORE_FLAGS
 537 fi
 538
 539 dnl ===================================================================
 540 dnl Checks for BSD sysmouse
 541 dnl ===================================================================
 542
 543 HAVE_SYSMOUSE_HEADER="no"
 544
 545 # Either of these header files provides the (same) sysmouse interface
 546 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 547
 548 dnl ===================================================================
 549 dnl Checks for OS/2
 550 dnl ===================================================================
 551
 552 if test "$CONFIG_OS_OS2" = yes; then
 553         EL_CONFIG_OS_OS2
 554 fi
 555
 556 dnl ===================================================================
 557 dnl Checks for Win32
 558 dnl ===================================================================
 559
 560 if test "$CONFIG_OS_WIN32" = yes; then
 561         EL_CONFIG_OS_WIN32
 562 fi
 563
 564 dnl ===================================================================
 565 dnl Check for SEE (Simple Ecmascript Engine)
 566 dnl ===================================================================
 567 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 568             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 569
 570 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 571 # SEE_FLAGS but I really don't want to require people to have Guile in order
 572 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 573 # for Guile in $PATH etc. --pasky
 574
 575 CONFIG_ECMASCRIPT_SEE=no
 576
 577 if test "$enable_see" = "yes"; then
 578         ## Based on the SEE_FLAGS macro.
 579
 580         if test -d "$withval"; then
 581                 SEE_PATH="$withval:$PATH"
 582         else
 583                 SEE_PATH="$PATH"
 584         fi
 585
 586         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 587         AC_MSG_CHECKING([for SEE (2.0.1131 or later)])
 588         if test "$SEE_CONFIG" != no; then
 589                 EL_SAVE_FLAGS
 590                 SEE_LIBS="`$SEE_CONFIG --libs`"
 591                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 592                 CPPFLAGS="$SEE_CFLAGS $CPPFLAGS"
 593                 LIBS="$SEE_LIBS $LIBS_X"
 594                 AC_TRY_LINK([#include <see/see.h>],[#if SEE_VERSION_API_MAJOR < 2
 595                         choke_on_see();
 596                         #endif
 597                 ], cf_result=yes, cf_result=no)
 598                 EL_RESTORE_FLAGS
 599                 if test "$cf_result" = yes; then
 600                         LIBS="$SEE_LIBS $LIBS"
 601                         EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 602                         AC_SUBST(SEE_CFLAGS)
 603                 fi
 604                 AC_MSG_RESULT($cf_result)
 605         else
 606                 if test -n "$withval" && test "x$withval" != xno; then
 607                         AC_MSG_ERROR([SEE not found])
 608                 else
 609                         AC_MSG_WARN([SEE support disabled])
 610                 fi
 611         fi
 612 else
 613         AC_MSG_CHECKING([for SEE (2.0.1131 or later)])
 614         AC_MSG_RESULT(no);
 615 fi
 616
 617 dnl ===================================================================
 618 dnl Check for SpiderMonkey, optional even if installed.
 619 dnl ===================================================================
 620
 621 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 622             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 623 AC_MSG_CHECKING([for SpiderMonkey (1.5 RC3a or later)])
 624
 625 EL_SAVE_FLAGS
 626 cf_result=no
 627
 628 if test -z "$disable_spidermonkey"; then
 629         if test ! -d "$withval"; then
 630                 withval="";
 631         fi
 632         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 633                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 634                         for spidermonkeylib in js smjs mozjs; do
 635                                 if test "$cf_result" = no; then
 636                                         SPIDERMONKEY_LIBS="-l$spidermonkeylib"
 637
 638                                         if test ! -z "$spidermonkeydir"; then
 639                                                 SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib $SPIDERMONKEY_LIBS"
 640                                                 SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 641                                         fi
 642
 643                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 644                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 645                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 646
 647                                         AC_TRY_LINK([#define XP_UNIX
 648                                                      #include <jsapi.h>],
 649                                                      [JS_GetReservedSlot(NULL, NULL, 0, NULL)],
 650                                                      cf_result=yes, cf_result=no)
 651                                 fi
 652                         done
 653                 done
 654         done
 655 fi
 656
 657 AC_MSG_RESULT($cf_result)
 658 CONFIG_SPIDERMONKEY="$cf_result"
 659 EL_RESTORE_FLAGS
 660
 661 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 662    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 663         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 664 else
 665         CONFIG_ECMASCRIPT_SMJS=no
 666 fi
 667
 668 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 669 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 670 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 671
 672
 673 dnl ===================================================================
 674 dnl Optional Spidermonkey-based ECMAScript browser scripting
 675 dnl ===================================================================
 676
 677 AC_ARG_ENABLE(sm-scripting,
 678               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 679               [if test "$enableval" != no; then enableval="yes"; fi
 680                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 681
 682 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 683    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 684         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 685 else
 686         CONFIG_SCRIPTING_SPIDERMONKEY=no
 687 fi
 688
 689 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 690    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 691         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 692         AC_SUBST(SPIDERMONKEY_LIBS)
 693         AC_SUBST(SPIDERMONKEY_CFLAGS)
 694         AC_SUBST(CONFIG_SPIDERMONKEY)
 695 fi
 696
 697 dnl ===================================================================
 698 dnl Check for Guile, optional even if installed.
 699 dnl ===================================================================
 700
 701 enable_guile="no";
 702
 703 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 704             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 705
 706 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 707 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 708 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 709 # for Guile in $PATH etc. --pasky
 710
 711 AC_MSG_CHECKING([for Guile])
 712
 713 if test "$enable_guile" = "yes"; then
 714         AC_MSG_RESULT(yes);
 715         ## Based on the GUILE_FLAGS macro.
 716
 717         if test -d "$withval"; then
 718                 GUILE_PATH="$withval:$PATH"
 719         else
 720                 GUILE_PATH="$PATH"
 721         fi
 722
 723         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 724
 725         ## First, let's just see if we can find Guile at all.
 726         if test "$GUILE_CONFIG" != no; then
 727                 cf_result="yes";
 728
 729                 GUILE_LIBS="`guile-config link`"
 730                 GUILE_CFLAGS="`guile-config compile`"
 731                 LIBS="$GUILE_LIBS $LIBS"
 732                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 733                 AC_SUBST(GUILE_CFLAGS)
 734                 cat <<EOF
 735 ***********************************************************************
 736 The Guile support is incomplete and not so well integrated to ELinks
 737 yet. That means, e.g., that you have no Guile console and there might
 738 not be all the necessary hooks. Also, the Guile interface is not too
 739 well tested (success stories heartily welcomed!).  See
 740 src/scripting/guile/README for further details and hints.
 741 ***********************************************************************
 742 EOF
 743         else
 744                 if test -n "$withval" && test "x$withval" != xno; then
 745                         AC_MSG_ERROR([Guile not found])
 746                 else
 747                         AC_MSG_WARN([Guile support disabled])
 748                 fi
 749         fi
 750 else
 751         AC_MSG_RESULT(no);
 752 fi
 753
 754 dnl ===================================================================
 755 dnl Check for Perl
 756 dnl ===================================================================
 757 enable_perl="no";
 758
 759 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 760             [
 761 if test "$withval" = yes; then
 762         # FIXME: If withval is a valid directory append it to PATH
 763         # so that you can specify one of several perl installations.
 764         withval="";
 765         enable_perl=yes;
 766 fi
 767             ])
 768
 769 AC_MSG_CHECKING([for Perl])
 770
 771 cf_result=no
 772
 773 EL_SAVE_FLAGS
 774
 775 if test "$enable_perl" = "yes"; then
 776         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 777         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 778         LIBS="$PERL_LIBS $LIBS"
 779         CFLAGS="$PERL_CFLAGS $CFLAGS"
 780         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 781         AC_TRY_LINK([
 782 #include <EXTERN.h>
 783 #include <perl.h>
 784 #include <perlapi.h>
 785 ],
 786                     [PerlInterpreter *my_perl = perl_alloc();],
 787                     cf_result=yes, cf_result=no)
 788 fi
 789
 790 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 791
 792 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 793 AC_TRY_COMPILE([
 794 #include <EXTERN.h>
 795 #include <perl.h>
 796 extern PerlInterpreter *my_perl;
 797 ],
 798         [dSP; (void) POPpx;],
 799         [AC_MSG_RESULT([yes])
 800 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 801                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 802 no longer needs an "n_a" variable like it did in 5.8.7])],
 803         [AC_MSG_RESULT([no])])
 804
 805 if test "$cf_result" != "yes"; then
 806         EL_RESTORE_FLAGS
 807 else
 808         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 809
 810         CFLAGS="$CFLAGS_X"
 811         CPPFLAGS="$CPPFLAGS_X"
 812         AC_SUBST(PERL_LIBS)
 813         AC_SUBST(PERL_CFLAGS)
 814 fi
 815
 816 dnl ===================================================================
 817 dnl Check for Python
 818 dnl ===================================================================
 819 enable_python="no";
 820
 821 AC_ARG_WITH(python, [  --with-python=[DIR]     enable Python support],
 822             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 823
 824 EL_SAVE_FLAGS
 825 cf_result=no
 826
 827 AC_MSG_CHECKING([for Python])
 828
 829 if test "$enable_python" = "yes"; then
 830         AC_MSG_RESULT(yes);
 831
 832         if test -d "$withval"; then
 833                 PYTHON_PATH="$withval:$PATH"
 834         else
 835                 PYTHON_PATH="$PATH"
 836         fi
 837
 838         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 839
 840         if test "$PYTHON" != no; then
 841                 cf_result="yes";
 842
 843                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 844                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 845                 LIBS="$PYTHON_LIBS $LIBS"
 846                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 847                 AC_TRY_LINK([#include <Python.h>],
 848                     [Py_Initialize();],
 849                     cf_result=yes, cf_result=no)
 850
 851                 if test "$cf_result" != "yes"; then
 852                         EL_RESTORE_FLAGS
 853                 else
 854                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 855                         AC_SUBST(PYTHON_LIBS)
 856                         AC_SUBST(PYTHON_CFLAGS)
 857                         CPPFLAGS="$CPPFLAGS_X"
 858                         cat <<EOF
 859 ***********************************************************************
 860 The Python support is incomplete and not so well integrated to ELinks
 861 yet. That means, e.g., that you have no Python console and there might
 862 not be all the necessary hooks. Also, the Python interface is not too
 863 well tested (success stories heartily welcomed!).
 864 ***********************************************************************
 865 EOF
 866                 fi
 867         else
 868                 if test -n "$withval" && test "x$withval" != xno; then
 869                         AC_MSG_ERROR([Python not found])
 870                 else
 871                         AC_MSG_WARN([Python support disabled])
 872                 fi
 873         fi
 874 else
 875         AC_MSG_RESULT(no);
 876 fi
 877
 878
 879 dnl ===================================================================
 880 dnl Check for Lua, optional even if installed.
 881 dnl ===================================================================
 882
 883 dnl Do this the long way, as FreeBSD reportedly needs -L<dir> for
 884 dnl anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 885
 886 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 887             [if test "$withval" = no; then disable_lua=yes; fi])
 888 AC_MSG_CHECKING([for Lua])
 889
 890 EL_SAVE_FLAGS
 891 cf_result=no
 892
 893 if test -z "$disable_lua"; then
 894         if test ! -d "$withval"; then
 895                 withval="";
 896         fi
 897         for luadir in "$withval" "" /usr /usr/local; do
 898                 for suffix in "" 50 51; do
 899                         if test "$cf_result" = no; then
 900                                 LUA_LIBS="-llua$suffix -llualib$suffix -lm"
 901
 902                                 if test ! -z "$luadir"; then
 903                                         LUA_LIBS="-L$luadir/lib $LUA_LIBS"
 904                                         LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 905                                 fi
 906
 907                                 LIBS="$LUA_LIBS $LIBS_X"
 908                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 909                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 910
 911                                 # Check that it is a compatible Lua version
 912                                 AC_TRY_LINK([   #include <lua.h>
 913                                                 #include <lualib.h>],
 914                                             [   lua_State *L = lua_open();
 915                                                 luaopen_base(L);
 916                                                 luaopen_table(L);
 917                                                 luaopen_io(L);
 918                                                 luaopen_string(L);
 919                                                 luaopen_math(L);
 920                                                 lua_pushboolean(L, 1);
 921                                                 lua_close(L);],
 922                                             cf_result=yes, cf_result=no)
 923                         fi
 924                 done
 925         done
 926 fi
 927
 928 AC_MSG_RESULT($cf_result)
 929
 930 if test "$cf_result" != yes; then
 931         EL_RESTORE_FLAGS
 932 else
 933         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 934         AC_CHECK_HEADERS(lauxlib.h)
 935
 936         CFLAGS="$CFLAGS_X"
 937         CPPFLAGS="$CPPFLAGS_X"
 938         AC_SUBST(LUA_LIBS)
 939         AC_SUBST(LUA_CFLAGS)
 940 fi
 941
 942
 943 dnl ===================================================================
 944 dnl Check for Ruby, optional even if installed.
 945 dnl ===================================================================
 946
 947 EL_CONFIG_SCRIPTING_RUBY
 948
 949 dnl ===================================================================
 950 dnl Setup global scripting
 951 dnl ===================================================================
 952
 953 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
 954 AC_SUBST(CONFIG_SCRIPTING_GUILE)
 955 AC_SUBST(CONFIG_SCRIPTING_LUA)
 956 AC_SUBST(CONFIG_SCRIPTING_PERL)
 957 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
 958 AC_SUBST(CONFIG_SCRIPTING_RUBY)
 959 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
 960 AC_SUBST(CONFIG_SCRIPTING)
 961
 962
 963 dnl ===================================================================
 964 dnl Check for SSL support.
 965 dnl ===================================================================
 966
 967 dnl We by default use OpenSSL, and we always prefer it. However, when GNUTLS
 968 dnl is enabled, we won't try to use OpenSSL anymore.
 969
 970 dnl For wiping SSL hooks..
 971 #ifdef CONFIG_SSL
 972
 973 disable_openssl=""
 974 disable_gnutls=""
 975 enable_gnutls=""
 976
 977 AC_ARG_WITH(gnutls, [  --without-gnutls        disable GNUTLS SSL support],
 978             [if test "$with_gnutls" = no;  then disable_gnutls=yes; fi])
 979 AC_ARG_WITH(gnutls, [  --with-gnutls[=DIR]     enable GNUTLS SSL support],
 980             [if test "$with_gnutls" != no;  then enable_gnutls=yes; fi])
 981 gnutls_withval="$withval"
 982
 983 if test "$enable_gnutls" = yes; then
 984         disable_openssl=yes;
 985 fi
 986
 987 AC_ARG_WITH(openssl, [  --without-openssl       disable OpenSSL support],
 988             [if test "$with_openssl" = no;  then disable_openssl=yes; fi])
 989 AC_ARG_WITH(openssl, [  --with-openssl[=DIR]    enable OpenSSL support (default)])
 990 openssl_withval="$withval"
 991
 992 dnl ---- OpenSSL
 993
 994 AC_MSG_CHECKING([for OpenSSL])
 995
 996 EL_SAVE_FLAGS
 997 cf_result="no"
 998
 999 if test "$disable_openssl" = yes; then
1000         cf_result="not used"
1001 else
1002         for ssldir in "$openssl_withval" "" /usr /usr/local/openssl \
1003                          /usr/lib/openssl /usr/local/ssl \
1004                          /usr/local/www /usr/lib/ssl /usr/local \
1005                          /usr/pkg /opt /opt/openssl; do
1006                 if test "$cf_result" = no; then
1007                         if test -d "$ssldir"; then
1008                                 OPENSSL_CFLAGS="-I$ssldir/include"
1009                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1010                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1011                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1012 #                               # FIXME: This created serious portability problems. --pasky
1013 #                               if test "$CC" == "gcc"; then
1014 #                                       # I'm not sure about compatibility here. --pasky
1015 #                                       LIBS="$LIBS -R$ssldir/lib"
1016 #                               fi
1017                         else
1018                                 LIBS="-lssl -lcrypto $LIBS_X"
1019                         fi
1020                         AC_TRY_LINK([#include <openssl/ssl.h>],
1021                                     [OpenSSL_add_all_algorithms()],
1022                                     cf_result=yes, cf_result=no)
1023                         if test "$cf_result" != yes; then
1024                                 AC_TRY_LINK([#include <openssl/ssl.h>],
1025                                             [SSLeay_add_ssl_algorithms()],
1026                                             cf_result=yes, cf_result=no)
1027                         fi
1028                 fi
1029         done
1030
1031         if test "$cf_result" != yes; then
1032                 if test -n "$openssl_withval" && test "x$openssl_withval" != xno; then
1033                         AC_MSG_ERROR([OpenSSL not found])
1034                 fi
1035                 EL_RESTORE_FLAGS
1036         else
1037                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1038
1039                 CFLAGS="$CFLAGS_X"
1040                 AC_SUBST(OPENSSL_CFLAGS)
1041         fi
1042 fi
1043
1044 AC_MSG_RESULT($cf_result)
1045
1046 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1047 dnl ---- GNU TLS
1048 dnl We can't have AC_MSG_CHECKING here, because AC_PATH_PROG prints its own and
1049 dnl it looks ugly then.
1050
1051 if test "$cf_result" = yes; then
1052         cf_result="not used"
1053
1054 else
1055         EL_SAVE_FLAGS
1056         cf_result="no"
1057
1058         if test -z "$disable_gnutls"; then
1059                 # Sure, we maybe _could_ use their macro, but how to ensure
1060                 # that the ./configure script won't fail if the macro won't be
1061                 # found..? :( --pasky
1062
1063                 GNUTLS_PATH="$PATH:/usr/local/gnutls:/opt:/opt/gnutls"
1064
1065                 if test -d "$gnutls_withval"; then
1066                         GNUTLS_PATH="$gnutls_withval:$GNUTLS_PATH"
1067                 fi
1068
1069                 AC_PATH_PROG(LIBGNUTLS_CONFIG, libgnutls-config, no, $GNUTLS_PATH)
1070
1071                 if test "$LIBGNUTLS_CONFIG" = "no" ; then
1072                         cf_result=no
1073                 else
1074                         GNUTLS_CFLAGS=`$LIBGNUTLS_CONFIG --cflags`
1075                         GNUTLS_LIBS=`$LIBGNUTLS_CONFIG --libs`
1076
1077                         LIBS="$GNUTLS_LIBS $LIBS_X"
1078                         CFLAGS="$CFLAGS_X $GNUTLS_CFLAGS"
1079                         CPPFLAGS="$CPPFLAGS_X $GNUTLS_CFLAGS"
1080
1081                         # Verify if it's really usable.  gnutls_session was
1082                         # renamed to gnutls_session_t before GNU TLS 1.2.0
1083                         # (on 2004-06-13); ELinks now requires this.
1084                         AC_TRY_LINK([#include <gnutls/gnutls.h>],
1085                                     [gnutls_session_t dummy;
1086                                      gnutls_check_version(NULL)],
1087                                     cf_result=yes, cf_result=no)
1088                 fi
1089
1090                 if test "$cf_result" = yes; then
1091                         EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1092
1093                         CFLAGS="$CFLAGS_X"
1094                         AC_SUBST(GNUTLS_CFLAGS)
1095
1096                         # Verify if the MD5 compatibility layer is usable.
1097                         CONFIG_GNUTLS_OPENSSL_COMPAT=yes
1098                         EL_CHECK_OPTIONAL_LIBRARY(CONFIG_GNUTLS_OPENSSL_COMPAT,
1099                                                   [GNU TLS OpenSSL compatibility],
1100                                                   gnutls/openssl.h, gnutls-openssl,
1101                                                   MD5_Init)
1102                 else
1103                         if test -n "$gnutls_withval" && test "x$gnutls_withval" != xno; then
1104                                 AC_MSG_ERROR([GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.])
1105                         fi
1106                         EL_RESTORE_FLAGS
1107                 fi
1108         fi
1109 fi
1110
1111 AC_MSG_CHECKING([for GNU TLS (1.2 or later)])
1112 AC_MSG_RESULT($cf_result)
1113
1114 dnl Final SSL setup
1115
1116 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS], [SSL])
1117 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1118 AC_SUBST(CONFIG_OPENSSL)
1119 AC_SUBST(CONFIG_GNUTLS)
1120
1121 #endif
1122
1123 AC_MSG_CHECKING([whether to be or not to be])
1124 AC_MSG_RESULT([needs to be determined experimentally])
1125
1126 dnl ===================================================================
1127 dnl Check for IPv6 support and related functions.
1128 dnl ===================================================================
1129
1130 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1131 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1132 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1133
1134 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1135 if test "$HAVE_GETADDRINFO" != yes; then
1136         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1137         if test "$HAVE_GETADDRINFO" = yes; then
1138                 LIBS="$LIBS -linet6"
1139         fi
1140 fi
1141
1142
1143 dnl ===================================================================
1144 dnl Checking for X11 (window title restoring).
1145 dnl ===================================================================
1146
1147 AC_PATH_X
1148 if test x"$no_x" != xyes; then
1149         if test -n "$x_includes"; then
1150                 X_CFLAGS="-I$x_includes"
1151         fi
1152         if test -n "$x_libraries"; then
1153                 LDFLAGS="$LDFLAGS -L$x_libraries"
1154         fi
1155         LIBS="-lX11 $LIBS"
1156         EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1157         AC_SUBST(X_CFLAGS)
1158 fi
1159
1160
1161 dnl ===================================================================
1162 dnl Backtraces displaying support.
1163 dnl ===================================================================
1164
1165 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1166 # possible checks for other system-specific means go here
1167
1168
1169 dnl ===================================================================
1170 dnl Gettext grey zone. Beware.
1171 dnl ===================================================================
1172
1173 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1174
1175 AM_GNU_GETTEXT
1176
1177 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1178 dnl # f33r d4 l33t... I hope it's portable. :)
1179 dnl cf_result=$((48#z - 48#a + 1));
1180 dnl AC_MSG_RESULT($cf_result)
1181
1182
1183 dnl ===================================================================
1184 dnl Compile-time features control
1185 dnl ===================================================================
1186
1187 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1188               [  --disable-cookies       disable cookie support])
1189
1190 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1191               [  --disable-formhist      disable form history support])
1192
1193 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1194               [  --disable-globhist      disable global history support])
1195
1196
1197 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1198               [  --disable-mailcap       disable mailcap support])
1199
1200 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1201               [  --disable-mimetypes     disable mimetypes files support])
1202
1203
1204 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1205               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1206               [IPv6],
1207               [  --disable-ipv6          disable IPv6 support])
1208
1209 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1210               [  --enable-bittorrent     enable BitTorrent protocol support])
1211
1212 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1213               [  --disable-data          disable data protocol support])
1214
1215 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1216               [  --disable-uri-rewrite   disable URI rewrite support])
1217
1218 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1219               [  --enable-cgi            enable local CGI support])
1220
1221 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1222               [  --enable-finger         enable finger protocol support])
1223
1224 dnl ===================================================================
1225 dnl FSP protocol
1226 dnl ===================================================================
1227 EL_SAVE_FLAGS
1228
1229 if test "x${enable_fsp}" != xno; then
1230         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1231
1232         if test "$HAVE_FSPLIB" = yes; then
1233                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1234                 if test "$HAVE_FSPLIB" = yes; then
1235                         LIBS="$LIBS -lfsplib"
1236                 else
1237                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1238                         if test "$HAVE_FSPLIB" = yes; then
1239                                 LIBS="$LIBS -lfsp"
1240                         fi
1241                 fi
1242         fi
1243 fi
1244
1245 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1246               [  --enable-fsp            enable FSP protocol support])
1247
1248 if test "x$CONFIG_FSP" = xno; then
1249         EL_RESTORE_FLAGS
1250 fi
1251
1252 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1253               [  --disable-ftp           disable ftp protocol support])
1254
1255 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1256               [  --enable-gopher         enable gopher protocol support])
1257
1258 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1259               [  --enable-nntp           enable nntp protocol support])
1260
1261 dnl ===================================================================
1262 dnl SMB protocol support.
1263 dnl ===================================================================
1264 EL_SAVE_FLAGS
1265
1266 if test "x${enable_smb}" != xno; then
1267         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1268
1269         if test "$HAVE_SMBCLIENT" = yes; then
1270                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1271                 if test "$HAVE_SMBCLIENT" = yes; then
1272                         LIBS="$LIBS -lsmbclient"
1273                 fi
1274         fi
1275 fi
1276
1277 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1278               [  --enable-smb            enable Samba protocol support])
1279
1280 if test "x$CONFIG_SMB" = xno; then
1281         EL_RESTORE_FLAGS
1282 fi
1283
1284
1285 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1286               [  --disable-mouse         disable mouse support])
1287
1288 # GPM mouse is Linux specific, so ...
1289 CONFIG_SYSMOUSE=yes
1290 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1291               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1292               [BSD sysmouse],
1293               [  --disable-sysmouse      disable BSD sysmouse support])
1294
1295 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1296               [  --enable-88-colors      enable 88 color support])
1297
1298 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1299               [  --enable-256-colors     enable 256 color support])
1300
1301 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1302               [  --enable-true-color     enable true color support])
1303
1304 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1305               [  --enable-exmode         enable exmode (CLI) interface])
1306
1307 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1308               [  --disable-leds          disable LEDs support])
1309
1310 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1311               [  --disable-marks         disable document marks support])
1312
1313
1314 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1315               [  --disable-css           disable Cascading Style Sheet support])
1316
1317 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1318               [  --enable-html-highlight HTML highlighting using DOM engine])
1319
1320 dnl Everything in the tree already uses CONFIG_DOM
1321 dnl so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1322 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1323
1324 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1325               [  --disable-backtrace     disable backtrace support])
1326
1327 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1328               [  --enable-no-root        enable prevention of usage by root])
1329
1330
1331 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1332               [  --enable-debug          enable leak debug and internal error checking])
1333
1334 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1335               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1336
1337 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1338               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1339
1340 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1341               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1342
1343 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1344               [  --enable-utf-8          enable UTF-8 support])
1345
1346
1347 AC_ARG_ENABLE(weehoofooboomookerchoo,
1348               [
1349     Also check out the features.conf file for more information about features!
1350               ],
1351               [AC_MSG_ERROR(Are you strange, or what?)])
1352
1353
1354 dnl == EMX hack
1355
1356 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1357 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1358
1359
1360 dnl ===================================================================
1361 dnl Export directory paths
1362 dnl ===================================================================
1363
1364 # Set up the ``entry points'' if they were not supplied by builder
1365 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1366 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1367
1368 # Create CONFDIR #define for config.h
1369
1370 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1371 # it's autoconf fault to force us to do such hacks ;p.
1372 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1373   # sysconfdir is set to its default value... fine, let's append /elinks/
1374   # XXX: We can't modify listing of the default in ./configure --help :-(
1375   sysconfdir_n=`eval echo "$sysconfdir"`
1376   sysconfdir=$sysconfdir_n
1377   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1378         sysconfdir="$sysconfdir/elinks"
1379 fi
1380
1381 CONFDIR=$sysconfdir
1382 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1383 AC_SUBST(CONFDIR)
1384
1385 # Create LOCALEDIR #define for config.h
1386 LOCALEDIR=`eval echo "$datadir/locale"`
1387 while echo "$LOCALEDIR" | grep "\\$"
1388 do
1389         LOCALEDIR=`eval echo "$LOCALEDIR"`
1390 done > /dev/null 2> /dev/null
1391 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1392 AC_SUBST(LOCALEDIR)
1393
1394 # Create LIBDIR #define for config.h
1395 LIBDIR=`eval echo "$libdir"`
1396 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1397 AC_SUBST(LIBDIR)
1398
1399 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1400 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1401
1402 dnl ===================================================================
1403 dnl A little fine tuning of gcc specific options (continued)
1404 dnl ===================================================================
1405
1406 if test "x$ac_cv_prog_gcc" = "xyes"; then
1407   if test "$CONFIG_DEBUG" = "yes"; then
1408     dnl We want to see all warnings and live with none (in debug mode).
1409     CFLAGS="$CFLAGS -Werror"
1410   fi
1411
1412   case "`$CC -dumpversion`" in
1413     3.0|3.1|3.2)
1414       # These should be ok using -Werror
1415       ;;
1416     3.*)
1417       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1418       # "dereferencing type-punned pointer will break strict-aliasing rules"
1419       # warnings. Disable them by not doing any strict-aliasing. The
1420       # alternative is just too ugly. Thanks gcc guys!! ;)
1421       CFLAGS="$CFLAGS -fno-strict-aliasing"
1422       ;;
1423     4.*)
1424       # Do not show warnings related to (char * | unsigned char *) type
1425       # difference.
1426       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1427       ;;
1428     *)
1429       # These should be ok using -Werror
1430       ;;
1431   esac
1432
1433   # GCC 4.2 snapshots warn that comparisons like &object != NULL
1434   # always return true.  Some macros in ELinks check whether pointer
1435   # arguments are NULL, and giving them addresses of named objects
1436   # triggers the warning.  These warnings have not revealed any real
1437   # bugs, so shut them up instead of complicating the code.  GCC 4.1
1438   # does not recognize -Wno-always-true and exits with code 1 if it is
1439   # given.
1440   AC_MSG_CHECKING([whether $CC accepts -Wno-always-true])
1441   EL_SAVE_FLAGS
1442   CFLAGS="$CFLAGS -Wno-always-true"
1443   AC_TRY_COMPILE([], [],
1444     [AC_MSG_RESULT([yes])],
1445     [EL_RESTORE_FLAGS
1446      AC_MSG_RESULT([no])])
1447 fi
1448
1449 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1450 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1451 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1452 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1453
1454 dnl ===================================================================
1455 dnl Colored make output
1456 dnl ===================================================================
1457
1458 if test $(`which tput` colors) -ge 4; then
1459         MAKE_COLOR=1
1460         AC_SUBST(MAKE_COLOR)
1461 fi
1462
1463 dnl ===================================================================
1464 dnl Generated files
1465 dnl ===================================================================
1466
1467 AC_OUTPUT([ \
1468  Makefile.config \
1469  contrib/elinks.spec \
1470  contrib/lua/hooks.lua \
1471  contrib/conv/w3m2links.awk \
1472  doc/man/man1/elinks.1 \
1473  src/intl/gettext/ref-add.sed \
1474  src/intl/gettext/ref-del.sed
1475 ])
1476
1477 abs_srcdir="$(cd "$srcdir" && pwd)"
1478 # builddir is always absolute!
1479 if test "$abs_srcdir" != "$builddir"; then
1480         # Bootstrap the Makefile creation
1481         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1482         "$MAKE" "SRC=$abs_srcdir" init
1483
1484         # Make cg-status ignore this build directory
1485         echo "*" > "$builddir/.gitignore"
1486 fi
1487
1488 dnl ===================================================================
1489 dnl Configuration summary
1490 dnl ===================================================================
1491
1492 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1493 cat features.log