configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl There are two types of comments in this file.
   4 dnl Comments that refer to Autoconf macros begin with "dnl", and m4
   5 dnl discards them.  Other comments begin with "#", and they get copied
   6 dnl to the configure script, hopefully making it easier to read.
   7
   8 dnl Autoconf 2.13 generates an incomplete config.h.in; see ELinks bug 936.
   9 dnl Autoconf 2.59 is installed in the computer that generates our nightly
  10 dnl snapshots, so we need to be compatible with that.
  11 AC_PREREQ(2.59)
  12 AC_INIT
  13 AC_CONFIG_SRCDIR([src/main/main.c])
  14 AC_CONFIG_AUX_DIR(config)
  15
  16 PACKAGE=elinks
  17 VERSION=0.13.GIT
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  21 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  22 AC_CONFIG_HEADERS(config.h)
  23
  24 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  25 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  26 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  27
  28 MAKE=
  29
  30 for make in gnumake gmake make false; do
  31         if test "x$MAKE" = x; then
  32                 AC_PATH_PROGS(MAKE, "$make")
  33         fi
  34 done
  35
  36 builddir="`pwd`"
  37
  38 # Cleanup if we are configuring with a previous build in the tree
  39 if test -e Makefile.config; then
  40         AC_MSG_CHECKING([for previous build to clean])
  41         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  42         AC_MSG_RESULT(done)
  43 fi
  44
  45 # ===================================================================
  46 # Load feature configuration file and start logging features.
  47 # ===================================================================
  48
  49 features="features.conf"
  50 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  51 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  52 echo "Feature summary:" > features.log
  53
  54 # ===================================================================
  55 # Checks for programs.
  56 # ===================================================================
  57
  58 AC_PROG_CC
  59 AC_PROG_AWK
  60 AC_PATH_PROGS(AWK, "$AWK")
  61 AC_PROG_RANLIB
  62 AC_PROG_INSTALL
  63
  64 AC_PATH_PROGS(GIT, "git")
  65 AC_PATH_PROGS(SPARSE, "sparse")
  66
  67 CONFIG_ASCIIDOC="no"
  68 CONFIG_POD2HTML="no"
  69 CONFIG_XMLTO="no"
  70 CONFIG_JW="no"
  71
  72 if test "x$CONFIG_DOC" != xno; then
  73         AC_PATH_PROGS(ASCIIDOC, "asciidoc")
  74         if test "x$ASCIIDOC" != "x"; then
  75                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  76                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  77                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  78
  79                 echo > config.asciidoc-unsafe.txt
  80                 if "$ASCIIDOC" --unsafe config.asciidoc-unsafe.txt >/dev/null 2>/dev/null; then
  81                         ASCIIDOC_FLAGS=--unsafe
  82                 fi
  83                 rm config.asciidoc-unsafe.*
  84         fi
  85
  86         AC_PATH_PROGS(XMLTO, "xmlto")
  87         if test "x$XMLTO" != "x"; then
  88                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  89                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  90                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  91         fi
  92
  93         AC_PATH_PROGS(JW, "jw")
  94         if test "x$JW" != "x"; then
  95                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  96                 EL_CONFIG(MANUAL_JW, [PDF])
  97         fi
  98
  99         AC_PATH_PROGS(POD2HTML, "pod2html")
 100         if test "x$POD2HTML" != "x"; then
 101                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
 102         fi
 103
 104         AC_PATH_PROGS(DOXYGEN, "doxygen")
 105         if test "x$DOXYGEN" != "x"; then
 106                 EL_CONFIG(CONFIG_DOXYGEN, [Doxygen])
 107                 api_srcdir="$(cd "$srcdir" && pwd)/src"
 108                 AC_SUBST(api_srcdir)
 109         fi
 110 fi
 111
 112 AC_SUBST(ASCIIDOC_FLAGS)
 113 AC_SUBST(CONFIG_ASCIIDOC)
 114 AC_SUBST(CONFIG_DOXYGEN)
 115 AC_SUBST(CONFIG_POD2HTML)
 116 AC_SUBST(CONFIG_XMLTO)
 117 AC_SUBST(CONFIG_JW)
 118
 119 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 120 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 121 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 122 EL_CONFIG_DEPENDS(CONFIG_APIDOCS, [CONFIG_DOXYGEN], [API Documentation])
 123
 124 # gcc specific options (to be continued at the bottom of configure)
 125 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
 126   # We want to see all warnings and live with none.
 127   # We can't set up -Werror here as there may be some warnings in test
 128   # suite of configure, and we don't want to fail them.
 129   CFLAGS="$CFLAGS -Wall"
 130 fi
 131
 132 # ===================================================================
 133 # Checks for special OSes.
 134 # ===================================================================
 135
 136 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 137 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 138 [
 139         AC_MSG_CHECKING([for $2])
 140
 141         for flag in $3; do
 142                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[#ifndef $flag
 143 kill me!
 144 #endif ]])],[$1=yes],[$1=no])
 145                 if test "[$]$1" = yes; then
 146                         EL_CONFIG([$1], [$2])
 147                         break
 148                 fi
 149         done
 150
 151         AC_MSG_RESULT([$]$1)
 152 ])
 153
 154 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 155 AC_SUBST(CONFIG_OS_BEOS)
 156
 157 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 158 AC_SUBST(CONFIG_OS_RISCOS)
 159
 160 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 161 AC_SUBST(CONFIG_OS_WIN32)
 162
 163 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 164 AC_SUBST(CONFIG_OS_OS2)
 165 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 166
 167 AC_MSG_CHECKING([for UNIX])
 168 dnl FIXME: some depend kind of mechanism
 169 if test "$CONFIG_OS_BEOS" = no && \
 170    test "$CONFIG_OS_RISCOS" = no && \
 171    test "$CONFIG_OS_WIN32" = no && \
 172    test "$CONFIG_OS_OS2" = no; then
 173         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 174 else
 175         CONFIG_OS_UNIX=no
 176 fi
 177 AC_MSG_RESULT($CONFIG_OS_UNIX)
 178 AC_SUBST(CONFIG_OS_UNIX)
 179
 180 # ===================================================================
 181 # Checks for header files.
 182 # ===================================================================
 183
 184 AC_HEADER_DIRENT
 185 AC_HEADER_STDC
 186 AC_HEADER_SYS_WAIT
 187 AC_HEADER_TIME
 188
 189 AC_CHECK_HEADERS(wchar.h wctype.h)
 190 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 191 AC_CHECK_HEADERS(sigaction.h)
 192 AC_CHECK_HEADERS(arpa/inet.h)
 193 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 194 AC_CHECK_HEADERS(netdb.h netinet/in.h netinet/in6_var.h)
 195 AC_CHECK_HEADERS(ifaddrs.h)
 196 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 197 AC_CHECK_HEADERS(sys/fmutex.h)
 198 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 199 AC_CHECK_HEADERS(sys/resource.h)
 200 AC_CHECK_HEADERS(sys/select.h)
 201 AC_CHECK_HEADERS(sys/signal.h)
 202 AC_CHECK_HEADERS(sys/socket.h)
 203 AC_CHECK_HEADERS(sys/time.h)
 204 AC_CHECK_HEADERS(sys/utsname.h)
 205 AC_CHECK_HEADERS([net/if.h], [], [],
 206 [[#ifdef HAVE_SYS_SOCKET_H
 207 # include <sys/socket.h> /* <net/if.h> on Mac OS X 10.5.4 needs this */
 208 #endif
 209 ]])
 210 AC_CHECK_HEADERS(stdint.h inttypes.h)
 211 AC_CHECK_HEADERS(locale.h pwd.h)
 212 AC_CHECK_HEADERS(termios.h)
 213
 214
 215 AC_CHECK_HEADERS(sys/un.h,
 216         [CONFIG_INTERLINK=yes
 217          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 218         [CONFIG_INTERLINK=no])
 219 AC_SUBST(CONFIG_INTERLINK)
 220
 221 # ===================================================================
 222 # Checks for typedefs, structures, and compiler characteristics.
 223 # ===================================================================
 224
 225 AC_STRUCT_TM
 226 AC_C_CONST
 227 AC_C_INLINE
 228 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 229
 230 AC_SYS_LARGEFILE
 231 AC_TYPE_SIZE_T
 232 AC_TYPE_OFF_T
 233 EL_CHECK_TYPE(ssize_t, int)
 234 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 235 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 236 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 237 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 238 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 239
 240 AC_CHECK_SIZEOF(char, 1)
 241 AC_CHECK_SIZEOF(short, 2)
 242 AC_CHECK_SIZEOF(int, 4)
 243 AC_CHECK_SIZEOF(long, 4)
 244 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 245 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 246
 247 # Check for variadic macros
 248 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 249                 [#include <stdio.h>
 250                  #define a(b,c...) printf(b,##c)],
 251                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 252
 253 # ===================================================================
 254 # Check for POSIX <regex.h>
 255 # ===================================================================
 256
 257 EL_CHECK_SYS_TYPE(regex_t, HAVE_REGEX_H, [#include <regex.h>])
 258
 259 # ===================================================================
 260 # Checks for library functions.
 261 # ===================================================================
 262
 263 AC_PROG_GCC_TRADITIONAL
 264 AC_FUNC_MEMCMP
 265 AC_FUNC_MMAP
 266 AC_FUNC_STRFTIME
 267 AC_CHECK_FUNCS(atoll gethostbyaddr herror strerror)
 268 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 269 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 270 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 271 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 272 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 273 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 274 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 275
 276 AC_CHECK_FUNCS([cygwin_conv_to_full_win32_path])
 277
 278 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 279 AC_CHECK_FUNCS(unsetenv)
 280 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 281 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 282
 283 AC_CHECK_FUNCS(wcwidth, HAVE_WCWIDTH=yes)
 284
 285 # These aren't probably needed now, as they are commented in links.h.
 286 # I've no idea about their historical background, but I keep them here
 287 # just in the case they will help later. --pasky
 288 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 289 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 290 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 291 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 292
 293 if test x"$HAVE_RAISE" = x; then
 294         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 295                 AC_MSG_ERROR([Unable to emulate raise()])
 296         fi
 297 fi
 298
 299 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 300 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 301 va_list ap1,ap2;]], [[__va_copy(ap1,ap2);]])],[el_cv_HAVE_VA_COPY=yes],[el_cv_HAVE_VA_COPY=no])])
 302 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 303         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 304 fi
 305
 306 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 307 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
 308 ]], [[int page_size = sysconf(_SC_PAGE_SIZE);]])],[el_cv_HAVE_SC_PAGE_SIZE=yes],[el_cv_HAVE_SC_PAGE_SIZE=no])])
 309 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 310         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 311 fi
 312
 313 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 314 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 315 #include <stdio.h>
 316 #include <stdarg.h>
 317 #include <stdlib.h>
 318 #include <string.h>
 319
 320 char buf[8];
 321
 322 int bar(char *buf, const char *format, va_list ap)
 323 {
 324        return vsnprintf(buf, 0, format, ap);
 325 }
 326
 327 void foo(const char *format, ...) {
 328        va_list ap;
 329        int len;
 330
 331        va_start(ap, format);
 332        len = bar(buf, format, ap);
 333        va_end(ap);
 334        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 335
 336        va_start(ap, format);
 337        len = bar(buf, format, ap);
 338        va_end(ap);
 339        if ((len != 6) && (len != 7)) exit(1);
 340
 341        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 342
 343        exit(0);
 344 }
 345 main() { foo("hello\n"); }
 346 ]])],[el_cv_HAVE_C99_VSNPRINTF=yes],[el_cv_HAVE_C99_VSNPRINTF=no],[el_cv_HAVE_C99_VSNPRINTF=cross])])
 347 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 348         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 349 fi
 350
 351 # OpenSSL and Lua frequently need dlopen
 352 AC_CHECK_LIB(dl, dlopen)
 353
 354 # ===================================================================
 355 # Checks for libraries.
 356 # ===================================================================
 357
 358 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 359 if test "$cf_result" = no; then
 360         AC_CHECK_LIB(socket, socket)
 361 fi
 362
 363 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 364 if test "$cf_result" = no; then
 365         AC_CHECK_LIB(socket, setsockopt)
 366 fi
 367
 368 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 369 if test "$cf_result" = no; then
 370         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 371         if test "$cf_result" = no; then
 372                 AC_CHECK_LIB(nsl, gethostbyname)
 373         else
 374                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 375         fi
 376 fi
 377
 378 # ===================================================================
 379 # Checks for packaging specific options.
 380 # ===================================================================
 381
 382 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 383             [ if test "$withval" != no && test "$withval" != yes; then
 384                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 385               fi ])
 386
 387 # ===================================================================
 388 # Checks for a libraries, optional even if installed.
 389 # ===================================================================
 390
 391 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 392 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 393 [
 394         AC_MSG_CHECKING([for $2 support])
 395
 396         if test "[$]$1" != no; then
 397                 AC_MSG_RESULT(yes)
 398                 EL_SAVE_FLAGS
 399                 if test -n "$withval" && test -d "$withval"; then
 400                         # Be a little more careful when setting
 401                         # include and lib directories. This way
 402                         # $withval will work when includes are
 403                         # there but the library is in the common
 404                         # /usr/lib ... Does the right thing when
 405                         # looking for gc on Debian.
 406                         if test -d "$withval/include"; then
 407                                 CFLAGS="$CFLAGS -I$withval/include"
 408                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 409                         else
 410                                 CFLAGS="$CFLAGS -I$withval"
 411                                 CPPFLAGS="$CPPFLAGS -I$withval"
 412                         fi
 413                         if test -d "$withval/lib"; then
 414                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 415                         fi
 416                 fi
 417
 418                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 419                 if test "[$]$1" = yes; then
 420                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 421                 fi
 422
 423                 if test "[$]$1" = yes; then
 424                         EL_CONFIG([$1], [$2])
 425                         LIBS="$LIBS -l$4"
 426                 else
 427                         if test -n "[$]WITHVAL_$1" &&
 428                            test "[$]WITHVAL_$1" != xno; then
 429                                 AC_MSG_ERROR([$2 not found])
 430                         fi
 431                         EL_RESTORE_FLAGS
 432                 fi
 433         else
 434                 AC_MSG_RESULT(disabled)
 435         fi
 436 ])
 437
 438 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 439 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 440 [
 441         $1=yes
 442         WITHVAL_$1=
 443
 444         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 445         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 446
 447         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 448
 449         EL_LOG_CONFIG([$1], [$2], [])
 450 ])
 451
 452 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 453         [  --without-gpm           disable gpm (mouse) support])
 454
 455 # ELinks calls deflateInit2 with windowBits = MAX_WBITS | 32, to
 456 # enable automatic decoding of both zlib and gzip headers.  This
 457 # feature was added in zlib 1.2.0.2; earlier versions return an error.
 458 # The gzclearerr function was also added in zlib 1.2.0.2, so check for
 459 # that, even though ELinks does not actually call gzclearerr.
 460 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 461         [  --without-zlib          disable zlib support])
 462
 463 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 464         [  --without-bzlib         disable bzlib support])
 465
 466 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 467         [  --without-idn           disable international domain names support])
 468
 469 if test "x{with_gc}" != xno; then
 470         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 471                 [  --with-gc               enable Boehm's garbage collector])
 472 fi
 473
 474 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_LZMA, lzma, lzma.h, lzma, lzma_code,
 475         [  --without-lzma          disable lzma encoding support])
 476
 477 # ===================================================================
 478 # Check for GSSAPI, optional even if installed.
 479 # ===================================================================
 480
 481 enable_gssapi="no";
 482
 483 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 484             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 485
 486 AC_MSG_CHECKING([for GSSAPI])
 487
 488 if test "$enable_gssapi" = "yes"; then
 489         AC_MSG_RESULT(yes)
 490         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 491         GSSAPI_LIBS=`krb5-config --libs gssapi`
 492         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 493         LIBS="$GSSAPI_LIBS $LIBS"
 494         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 495 else
 496         AC_MSG_RESULT(no)
 497 fi
 498
 499 AC_SUBST(CONFIG_GSSAPI)
 500
 501 # ===================================================================
 502 # Bookmark and XBEL support
 503 # ===================================================================
 504
 505 EL_SAVE_FLAGS
 506
 507 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 508               [  --disable-bookmarks     disable bookmark support])
 509
 510 # Check whether --enable-xbel or --disable-xbel was given.
 511 if test "x${enable_xbel}" != xno; then
 512         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 513
 514         if test "$HAVE_LIBEXPAT" = yes; then
 515                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 516                 if test "$HAVE_LIBEXPAT" = yes; then
 517                         LIBS="$LIBS -lexpat"
 518                 fi
 519         fi
 520 fi
 521
 522
 523 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 524               [XBEL bookmarks],
 525               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 526
 527 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 528         EL_RESTORE_FLAGS
 529 fi
 530
 531 # ===================================================================
 532 # Checks for BSD sysmouse
 533 # ===================================================================
 534
 535 HAVE_SYSMOUSE_HEADER="no"
 536
 537 # Either of these header files provides the (same) sysmouse interface
 538 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 539
 540 # ===================================================================
 541 # Checks for OS/2
 542 # ===================================================================
 543
 544 if test "$CONFIG_OS_OS2" = yes; then
 545         EL_CONFIG_OS_OS2
 546 fi
 547
 548 # ===================================================================
 549 # Checks for Win32
 550 # ===================================================================
 551
 552 if test "$CONFIG_OS_WIN32" = yes; then
 553         EL_CONFIG_OS_WIN32
 554 fi
 555
 556 # ===================================================================
 557 # Check for SEE (Simple Ecmascript Engine)
 558 # ===================================================================
 559 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 560             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 561
 562 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 563 # SEE_FLAGS but I really don't want to require people to have Guile in order
 564 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 565 # for Guile in $PATH etc. --pasky
 566
 567 CONFIG_ECMASCRIPT_SEE=no
 568
 569 if test "$enable_see" = "yes"; then
 570         if test -d "$withval"; then
 571                 SEE_PATH="$withval:$PATH"
 572         else
 573                 SEE_PATH="$PATH"
 574         fi
 575
 576         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 577         AC_MSG_CHECKING([for SEE (2.0.1131 or later)])
 578         if test "$SEE_CONFIG" != no; then
 579                 EL_SAVE_FLAGS
 580                 SEE_LIBS="`$SEE_CONFIG --libs`"
 581                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 582                 CPPFLAGS="$SEE_CFLAGS $CPPFLAGS"
 583                 LIBS="$SEE_LIBS $LIBS_X"
 584                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <see/see.h>]], [[#if SEE_VERSION_API_MAJOR < 2
 585                         #error SEE too old
 586                         #endif
 587                 ]])],[cf_result=yes],[cf_result=no])
 588                 EL_RESTORE_FLAGS
 589                 if test "$cf_result" = yes; then
 590                         LIBS="$SEE_LIBS $LIBS"
 591                         EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 592                         AC_SUBST(SEE_CFLAGS)
 593                 fi
 594                 AC_MSG_RESULT($cf_result)
 595         else
 596                 if test -n "$withval" && test "x$withval" != xno; then
 597                         AC_MSG_ERROR([SEE not found])
 598                 else
 599                         AC_MSG_WARN([SEE support disabled])
 600                 fi
 601         fi
 602 fi
 603
 604 # ===================================================================
 605 # Check for SpiderMonkey, optional even if installed.
 606 # ===================================================================
 607
 608 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 609             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 610 AC_MSG_CHECKING([for SpiderMonkey (1.5 RC3a or later)])
 611
 612 EL_SAVE_FLAGS
 613 cf_result=no
 614
 615 if test -z "$disable_spidermonkey"; then
 616         if test ! -d "$withval"; then
 617                 withval="";
 618         fi
 619         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 620                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 621                         for spidermonkeylib in js smjs mozjs; do
 622                                 if test "$cf_result" = no &&
 623                                    test -f "$spidermonkeydir$spidermonkeyinclude/jsapi.h"; then
 624                                         SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib -l$spidermonkeylib"
 625                                         SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 626
 627                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 628                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 629                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 630
 631                                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define XP_UNIX
 632                                                      #include <jsapi.h>]], [[JS_GetReservedSlot(NULL, NULL, 0, NULL)]])],[cf_result=yes],[cf_result=no])
 633                                 fi
 634                         done
 635                 done
 636         done
 637 fi
 638
 639 AC_MSG_RESULT($cf_result)
 640 CONFIG_SPIDERMONKEY="$cf_result"
 641 EL_RESTORE_FLAGS
 642
 643 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 644    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 645         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 646 else
 647         CONFIG_ECMASCRIPT_SMJS=no
 648 fi
 649
 650 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 651 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 652 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 653
 654
 655 # ===================================================================
 656 # Optional Spidermonkey-based ECMAScript browser scripting
 657 # ===================================================================
 658
 659 AC_ARG_ENABLE(sm-scripting,
 660               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 661               [if test "$enableval" != no; then enableval="yes"; fi
 662                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 663
 664 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 665    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 666         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 667 else
 668         CONFIG_SCRIPTING_SPIDERMONKEY=no
 669 fi
 670
 671 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 672    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 673         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 674         AC_SUBST(SPIDERMONKEY_LIBS)
 675         AC_SUBST(SPIDERMONKEY_CFLAGS)
 676         AC_SUBST(CONFIG_SPIDERMONKEY)
 677 fi
 678
 679 # ===================================================================
 680 # Check for Guile, optional even if installed.
 681 # ===================================================================
 682
 683 enable_guile="no";
 684
 685 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 686             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 687
 688 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 689 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 690 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 691 # for Guile in $PATH etc. --pasky
 692
 693 AC_MSG_CHECKING([for Guile])
 694
 695 if test "$enable_guile" = "yes"; then
 696         AC_MSG_RESULT(yes);
 697         ## Based on the GUILE_FLAGS macro.
 698
 699         if test -d "$withval"; then
 700                 GUILE_PATH="$withval:$PATH"
 701         else
 702                 GUILE_PATH="$PATH"
 703         fi
 704
 705         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 706
 707         ## First, let's just see if we can find Guile at all.
 708         if test "$GUILE_CONFIG" != no; then
 709                 cf_result="yes";
 710
 711                 GUILE_LIBS="`guile-config link`"
 712                 GUILE_CFLAGS="`guile-config compile`"
 713                 LIBS="$GUILE_LIBS $LIBS"
 714                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 715                 AC_SUBST(GUILE_CFLAGS)
 716                 cat <<EOF
 717 ***********************************************************************
 718 The Guile support is incomplete and not so well integrated to ELinks
 719 yet. That means, e.g., that you have no Guile console and there might
 720 not be all the necessary hooks. Also, the Guile interface is not too
 721 well tested (success stories heartily welcomed!).  See
 722 src/scripting/guile/README for further details and hints.
 723 ***********************************************************************
 724 EOF
 725         else
 726                 if test -n "$withval" && test "x$withval" != xno; then
 727                         AC_MSG_ERROR([Guile not found])
 728                 else
 729                         AC_MSG_WARN([Guile support disabled])
 730                 fi
 731         fi
 732 else
 733         AC_MSG_RESULT(no);
 734 fi
 735
 736 # ===================================================================
 737 # Check for Perl
 738 # ===================================================================
 739 enable_perl="no";
 740
 741 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 742             [
 743 if test "$withval" = yes; then
 744         # FIXME: If withval is a valid directory append it to PATH
 745         # so that you can specify one of several perl installations.
 746         withval="";
 747         enable_perl=yes;
 748 fi
 749             ])
 750
 751 AC_MSG_CHECKING([for Perl])
 752
 753 cf_result=no
 754
 755 EL_SAVE_FLAGS
 756
 757 if test "$enable_perl" = "yes"; then
 758         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 759         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 760         LIBS="$PERL_LIBS $LIBS"
 761         CFLAGS="$PERL_CFLAGS $CFLAGS"
 762         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 763         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 764 #include <EXTERN.h>
 765 #include <perl.h>
 766 #include <perlapi.h>
 767 ]], [[PerlInterpreter *my_perl = perl_alloc();]])],[cf_result=yes],[cf_result=no])
 768 fi
 769
 770 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 771
 772 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 773 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 774 #include <EXTERN.h>
 775 #include <perl.h>
 776 extern PerlInterpreter *my_perl;
 777 ]], [[dSP; (void) POPpx;]])],[AC_MSG_RESULT([yes])
 778 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 779                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 780 no longer needs an "n_a" variable like it did in 5.8.7])],[AC_MSG_RESULT([no])])
 781
 782 if test "$cf_result" != "yes"; then
 783         EL_RESTORE_FLAGS
 784 else
 785         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 786
 787         CFLAGS="$CFLAGS_X"
 788         CPPFLAGS="$CPPFLAGS_X"
 789         AC_SUBST(PERL_LIBS)
 790         AC_SUBST(PERL_CFLAGS)
 791 fi
 792
 793 # ===================================================================
 794 # Check for Python
 795 # ===================================================================
 796 enable_python="no";
 797
 798 AC_ARG_WITH(python, [[  --with-python[=DIR]     enable Python support]],
 799             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 800
 801 EL_SAVE_FLAGS
 802 cf_result=no
 803
 804 AC_MSG_CHECKING([for Python])
 805
 806 if test "$enable_python" = "yes"; then
 807         AC_MSG_RESULT(yes);
 808
 809         if test -d "$withval"; then
 810                 PYTHON_PATH="$withval:$PATH"
 811         else
 812                 PYTHON_PATH="$PATH"
 813         fi
 814
 815         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 816
 817         if test "$PYTHON" != no; then
 818                 cf_result="yes";
 819
 820                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 821                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 822                 LIBS="$PYTHON_LIBS $LIBS"
 823                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 824                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[Py_Initialize();]])],[cf_result=yes],[cf_result=no])
 825
 826                 if test "$cf_result" != "yes"; then
 827                         EL_RESTORE_FLAGS
 828                 else
 829                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 830                         AC_SUBST(PYTHON_LIBS)
 831                         AC_SUBST(PYTHON_CFLAGS)
 832                         CPPFLAGS="$CPPFLAGS_X"
 833                         cat <<EOF
 834 ***********************************************************************
 835 The Python support is incomplete and not so well integrated to ELinks
 836 yet. That means, e.g., that you have no Python console and there might
 837 not be all the necessary hooks. Also, the Python interface is not too
 838 well tested (success stories heartily welcomed!).
 839 ***********************************************************************
 840 EOF
 841                 fi
 842         else
 843                 if test -n "$withval" && test "x$withval" != xno; then
 844                         AC_MSG_ERROR([Python not found])
 845                 else
 846                         AC_MSG_WARN([Python support disabled])
 847                 fi
 848         fi
 849 else
 850         AC_MSG_RESULT(no);
 851 fi
 852
 853
 854 # ===================================================================
 855 # Check for Lua, optional even if installed.
 856 # ===================================================================
 857
 858 # Do this the long way, as FreeBSD reportedly needs -L<dir> for
 859 # anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 860
 861 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 862             [if test "$withval" = no; then disable_lua=yes; fi])
 863 AC_MSG_CHECKING([for Lua])
 864
 865 EL_SAVE_FLAGS
 866 cf_result=no
 867
 868 if test -z "$disable_lua"; then
 869         if test ! -d "$withval"; then
 870                 withval="";
 871         fi
 872         for luadir in "$withval" "" /usr /usr/local; do
 873                 for suffix in "" 50; do
 874                         if test "$cf_result" = no && ( test -f "$luadir/include/lua.h" || \
 875                            test -f "$luadir/include/lua$suffix/lua.h" ) ; then
 876                                 LUA_LIBS="-L$luadir/lib -llua$suffix -llualib$suffix -lm"
 877                                 LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 878
 879                                 LIBS="$LUA_LIBS $LIBS_X"
 880                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 881                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 882
 883                                 # Check that it is a compatible Lua version
 884                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[      #include <lua.h>
 885                                                 #include <lualib.h>]], [[       lua_State *L = lua_open();
 886                                                 luaopen_base(L);
 887                                                 luaopen_table(L);
 888                                                 luaopen_io(L);
 889                                                 luaopen_string(L);
 890                                                 luaopen_math(L);
 891                                                 lua_pushboolean(L, 1);
 892                                                 lua_close(L);]])],[cf_result=yes],[cf_result=no])
 893                         fi
 894                 done
 895         done
 896 fi
 897
 898 AC_MSG_RESULT($cf_result)
 899
 900 if test "$cf_result" != yes; then
 901         EL_RESTORE_FLAGS
 902 else
 903         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 904         AC_CHECK_HEADERS(lauxlib.h)
 905
 906         CFLAGS="$CFLAGS_X"
 907         CPPFLAGS="$CPPFLAGS_X"
 908         AC_SUBST(LUA_LIBS)
 909         AC_SUBST(LUA_CFLAGS)
 910 fi
 911
 912
 913 # ===================================================================
 914 # Check for Ruby, optional even if installed.
 915 # ===================================================================
 916
 917 EL_CONFIG_SCRIPTING_RUBY
 918
 919 # ===================================================================
 920 # Setup global scripting
 921 # ===================================================================
 922
 923 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
 924 AC_SUBST(CONFIG_SCRIPTING_GUILE)
 925 AC_SUBST(CONFIG_SCRIPTING_LUA)
 926 AC_SUBST(CONFIG_SCRIPTING_PERL)
 927 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
 928 AC_SUBST(CONFIG_SCRIPTING_RUBY)
 929 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
 930 AC_SUBST(CONFIG_SCRIPTING)
 931
 932
 933 # ===================================================================
 934 # Check for SSL support.
 935 # ===================================================================
 936
 937 # We by default use OpenSSL, and we always prefer it. However, when GNUTLS
 938 # is enabled, we won't try to use OpenSSL anymore.
 939
 940 # For wiping SSL hooks..
 941 #ifdef CONFIG_SSL
 942
 943 disable_openssl=""
 944 disable_gnutls=""
 945 enable_gnutls=""
 946
 947 AC_ARG_WITH(gnutls, [  --without-gnutls        disable GNUTLS SSL support],
 948             [if test "$with_gnutls" = no;  then disable_gnutls=yes; fi])
 949 AC_ARG_WITH(gnutls, [[  --with-gnutls[=DIR]     enable GNUTLS SSL support]],
 950             [if test "$with_gnutls" != no;  then enable_gnutls=yes; fi])
 951 gnutls_withval="$withval"
 952
 953 if test "$enable_gnutls" = yes; then
 954         disable_openssl=yes;
 955         with_nss_compat_ossl=no;
 956 fi
 957
 958 AC_ARG_WITH(openssl, [  --without-openssl       disable OpenSSL support],
 959             [if test "$with_openssl" = no;  then disable_openssl=yes; fi])
 960 AC_ARG_WITH(openssl, [[  --with-openssl[=DIR]    enable OpenSSL support (default)]])
 961 openssl_withval="$withval"
 962
 963 AC_ARG_WITH(nss_compat_ossl, [[  --with-nss_compat_ossl[=DIR]
 964                           NSS compatibility SSL libraries/include files]])
 965
 966 # nss_compat_ossl
 967 if test -n "$with_nss_compat_ossl" && test "$with_nss_compat_ossl" != "no"; then
 968         EL_SAVE_FLAGS
 969         if test "$with_nss_compat_ossl" = yes; then
 970                 if pkg-config nss; then
 971                         CFLAGS="$CFLAGS_X `pkg-config --cflags nss`"
 972                         LIBS="$LIBS_X `pkg-config --libs nss`"
 973                 else
 974                         with_nss_compat_ossl=no
 975                 fi
 976         else
 977                 # Without pkg-config, we'll kludge in some defaults
 978                 CFLAGS="$CFLAGS_X -I$with_nss_compat_ossl/include -I/usr/include/nss3 -I/usr/include/nspr4"
 979                 LIBS="$LIBS_X -L$with_nss_compat_ossl/lib -lssl3 -lsmime3 -lnss3 -lplds4 -lplc4 -lnspr4 -lpthread -ldl"
 980         fi
 981         AC_CHECK_HEADERS(nss_compat_ossl/nss_compat_ossl.h,, [with_nss_compat_ossl=no], [#define NSS_COMPAT_OSSL_H])
 982         AC_CHECK_LIB(nss_compat_ossl, X509_free,, [with_nss_compat_ossl=no])
 983
 984         if test "$with_nss_compat_ossl" = "no"; then
 985                 EL_RESTORE_FLAGS
 986         else
 987                 LIBS="$LIBS -lnss_compat_ossl"
 988                 EL_CONFIG(CONFIG_NSS_COMPAT_OSSL, [nss_compat_ossl])
 989                 disable_openssl="yes"
 990                 disable_gnutls="yes"
 991         fi
 992 fi
 993
 994 # ---- OpenSSL
 995
 996 AC_MSG_CHECKING([for OpenSSL])
 997
 998 EL_SAVE_FLAGS
 999 cf_result="no"
1000
1001 if test "$disable_openssl" = yes; then
1002         cf_result="not used"
1003 else
1004         for ssldir in "$openssl_withval" "" /usr /usr/local/openssl \
1005                          /usr/lib/openssl /usr/local/ssl \
1006                          /usr/local/www /usr/lib/ssl /usr/local \
1007                          /usr/pkg /opt /opt/openssl; do
1008                 if test "$cf_result" = no; then
1009                         if test -d "$ssldir"; then
1010                                 OPENSSL_CFLAGS="-I$ssldir/include"
1011                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1012                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1013                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1014 #                               # FIXME: This created serious portability problems. --pasky
1015 #                               if test "$CC" == "gcc"; then
1016 #                                       # I'm not sure about compatibility here. --pasky
1017 #                                       LIBS="$LIBS -R$ssldir/lib"
1018 #                               fi
1019                         else
1020                                 LIBS="-lssl -lcrypto $LIBS_X"
1021                         fi
1022                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[OpenSSL_add_all_algorithms()]])],[cf_result=yes],[cf_result=no])
1023                         if test "$cf_result" != yes; then
1024                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[SSLeay_add_ssl_algorithms()]])],[cf_result=yes],[cf_result=no])
1025                         fi
1026                 fi
1027         done
1028
1029         if test "$cf_result" != yes; then
1030                 if test -n "$openssl_withval" && test "x$openssl_withval" != xno; then
1031                         AC_MSG_ERROR([OpenSSL not found])
1032                 fi
1033                 EL_RESTORE_FLAGS
1034         else
1035                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1036
1037                 CFLAGS="$CFLAGS_X"
1038                 AC_SUBST(OPENSSL_CFLAGS)
1039         fi
1040 fi
1041
1042 AC_MSG_RESULT($cf_result)
1043
1044 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1045 # ---- GNU TLS
1046 dnl We can't have AC_MSG_CHECKING here, because AC_PATH_PROG prints its own and
1047 dnl it looks ugly then.
1048
1049 if test "$cf_result" = yes; then
1050         cf_result="not used"
1051
1052 else
1053         EL_SAVE_FLAGS
1054         cf_result="no"
1055
1056         if test -z "$disable_gnutls"; then
1057                 # Sure, we maybe _could_ use their macro, but how to ensure
1058                 # that the ./configure script won't fail if the macro won't be
1059                 # found..? :( --pasky
1060
1061                 GNUTLS_PATH="$PATH:/usr/local/gnutls:/opt:/opt/gnutls"
1062
1063                 if test -d "$gnutls_withval"; then
1064                         GNUTLS_PATH="$gnutls_withval:$GNUTLS_PATH"
1065                 fi
1066
1067                 AC_PATH_PROG(LIBGNUTLS_CONFIG, libgnutls-config, no, $GNUTLS_PATH)
1068
1069                 if test "$LIBGNUTLS_CONFIG" = "no" ; then
1070                         cf_result=no
1071                 else
1072                         GNUTLS_CFLAGS=`$LIBGNUTLS_CONFIG --cflags`
1073                         GNUTLS_LIBS=`$LIBGNUTLS_CONFIG --libs`
1074
1075                         LIBS="$GNUTLS_LIBS $LIBS_X"
1076                         CFLAGS="$CFLAGS_X $GNUTLS_CFLAGS"
1077                         CPPFLAGS="$CPPFLAGS_X $GNUTLS_CFLAGS"
1078
1079                         # Verify if it's really usable.  gnutls_session was
1080                         # renamed to gnutls_session_t before GNU TLS 1.2.0
1081                         # (on 2004-06-13); ELinks now requires this.
1082                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[gnutls_session_t dummy;
1083                                      gnutls_check_version(NULL)]])],[cf_result=yes],[cf_result=no])
1084                 fi
1085
1086                 if test "$cf_result" = yes; then
1087                         EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1088
1089                         CFLAGS="$CFLAGS_X"
1090                         AC_SUBST(GNUTLS_CFLAGS)
1091
1092                         # GnuTLS 2.2.0 changed libgnutls-openssl from GPLv2+
1093                         # to GPLv3+.  Don't link that with the GPLv2 ELinks.
1094                         # ELinks will use its internal MD5 code instead.
1095                         CONFIG_GNUTLS_OPENSSL_COMPAT=no
1096                 else
1097                         if test -n "$gnutls_withval" && test "x$gnutls_withval" != xno; then
1098                                 AC_MSG_ERROR([GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.])
1099                         fi
1100                         EL_RESTORE_FLAGS
1101                 fi
1102         fi
1103 fi
1104
1105 AC_MSG_CHECKING([for GNU TLS (1.2 or later)])
1106 AC_MSG_RESULT($cf_result)
1107
1108 # Final SSL setup
1109
1110 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS CONFIG_NSS_COMPAT_OSSL], [SSL])
1111 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1112 AC_SUBST(CONFIG_OPENSSL)
1113 AC_SUBST(CONFIG_GNUTLS)
1114 AC_SUBST(CONFIG_NSS_COMPAT_OSSL)
1115
1116 #endif
1117
1118 AC_MSG_CHECKING([whether to be or not to be])
1119 AC_MSG_RESULT([needs to be determined experimentally])
1120
1121 # ===================================================================
1122 # Check for IPv6 support and related functions.
1123 # ===================================================================
1124
1125 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1126 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1127 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1128
1129 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1130 if test "$HAVE_GETADDRINFO" != yes; then
1131         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1132         if test "$HAVE_GETADDRINFO" = yes; then
1133                 LIBS="$LIBS -linet6"
1134         fi
1135 fi
1136
1137
1138 # ===================================================================
1139 # Checking for X11 (window title restoring).
1140 # ===================================================================
1141
1142 AC_PATH_X
1143 if test x"$no_x" != xyes; then
1144         EL_SAVE_FLAGS
1145         if test -n "$x_includes"; then
1146                 X_CFLAGS="-I$x_includes"
1147                 CPPFLAGS="$CPPLAGS $X_CFLAGS"
1148                 CFLAGS="$CFLAGS $X_CFLAGS"
1149         fi
1150         if test -n "$x_libraries"; then
1151                 LDFLAGS="$LDFLAGS -L$x_libraries"
1152         fi
1153         LIBS="-lX11 $LIBS"
1154         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XrmInitialize()]])],[cf_result=yes],[cf_result=no])
1155         EL_RESTORE_FLAGS
1156         if test "$cf_result" = yes; then
1157                 if test -n "$x_libraries"; then
1158                         LDFLAGS="$LDFLAGS -L$x_libraries"
1159                 fi
1160                 LIBS="-lX11 $LIBS"
1161                 EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1162                 AC_SUBST(X_CFLAGS)
1163         fi
1164 fi
1165
1166
1167 # ===================================================================
1168 # Backtraces displaying support.
1169 # ===================================================================
1170
1171 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1172 # possible checks for other system-specific means go here
1173
1174
1175 # ===================================================================
1176 # Gettext grey zone. Beware.
1177 # ===================================================================
1178
1179 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1180
1181 AM_GNU_GETTEXT
1182
1183 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1184 dnl # f33r d4 l33t... I hope it's portable. :)
1185 dnl cf_result=$((48#z - 48#a + 1));
1186 dnl AC_MSG_RESULT($cf_result)
1187
1188
1189 # ===================================================================
1190 # Compile-time features control
1191 # ===================================================================
1192
1193 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1194               [  --disable-cookies       disable cookie support])
1195
1196 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1197               [  --disable-formhist      disable form history support])
1198
1199 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1200               [  --disable-globhist      disable global history support])
1201
1202
1203 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1204               [  --disable-mailcap       disable mailcap support])
1205
1206 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1207               [  --disable-mimetypes     disable mimetypes files support])
1208
1209
1210 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1211               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1212               [IPv6],
1213               [  --disable-ipv6          disable IPv6 support])
1214
1215 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1216               [  --enable-bittorrent     enable BitTorrent protocol support])
1217
1218 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1219               [  --disable-data          disable data protocol support])
1220
1221 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1222               [  --disable-uri-rewrite   disable URI rewrite support])
1223
1224 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1225               [  --enable-cgi            enable local CGI support])
1226
1227 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1228               [  --enable-finger         enable finger protocol support])
1229
1230 # ===================================================================
1231 # FSP protocol
1232 # ===================================================================
1233 EL_SAVE_FLAGS
1234
1235 if test "x${enable_fsp}" != xno; then
1236         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1237
1238         if test "$HAVE_FSPLIB" = yes; then
1239                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1240                 if test "$HAVE_FSPLIB" = yes; then
1241                         LIBS="$LIBS -lfsplib"
1242                 else
1243                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1244                         if test "$HAVE_FSPLIB" = yes; then
1245                                 LIBS="$LIBS -lfsp"
1246                         fi
1247                 fi
1248         fi
1249 fi
1250
1251 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1252               [  --enable-fsp            enable FSP protocol support])
1253
1254 if test "x$CONFIG_FSP" = xno; then
1255         EL_RESTORE_FLAGS
1256 fi
1257
1258 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1259               [  --disable-ftp           disable ftp protocol support])
1260
1261 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1262               [  --enable-gopher         enable gopher protocol support])
1263
1264 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1265               [  --enable-nntp           enable nntp protocol support])
1266
1267 # ===================================================================
1268 # SMB protocol support.
1269 # ===================================================================
1270 EL_SAVE_FLAGS
1271
1272 if test "x${enable_smb}" != xno; then
1273         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1274
1275         if test "$HAVE_SMBCLIENT" = yes; then
1276                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1277                 if test "$HAVE_SMBCLIENT" = yes; then
1278                         LIBS="$LIBS -lsmbclient"
1279                 fi
1280         fi
1281 fi
1282
1283 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1284               [  --enable-smb            enable Samba protocol support])
1285
1286 if test "x$CONFIG_SMB" = xno; then
1287         EL_RESTORE_FLAGS
1288 fi
1289
1290
1291 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1292               [  --disable-mouse         disable mouse support])
1293
1294 # GPM mouse is Linux specific, so ...
1295 CONFIG_SYSMOUSE=yes
1296 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1297               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1298               [BSD sysmouse],
1299               [  --disable-sysmouse      disable BSD sysmouse support])
1300
1301 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1302               [  --enable-88-colors      enable 88 color support])
1303
1304 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1305               [  --enable-256-colors     enable 256 color support])
1306
1307 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1308               [  --enable-true-color     enable true color support])
1309
1310 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1311               [  --enable-exmode         enable exmode (CLI) interface])
1312
1313 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1314               [  --disable-leds          disable LEDs support])
1315
1316 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1317               [  --disable-marks         disable document marks support])
1318
1319
1320 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1321               [  --disable-css           disable Cascading Style Sheet support])
1322
1323 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1324               [  --enable-html-highlight HTML highlighting using DOM engine])
1325
1326 # Everything in the tree already uses CONFIG_DOM
1327 # so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1328 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1329
1330 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1331               [  --disable-backtrace     disable backtrace support])
1332
1333 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1334               [  --enable-no-root        enable prevention of usage by root])
1335
1336
1337 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1338               [  --enable-debug          enable leak debug and internal error checking])
1339
1340 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1341               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1342
1343 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1344               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1345
1346 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1347               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1348
1349 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1350               [  --disable-utf-8         disable UTF-8 support])
1351
1352 EL_ARG_DEPEND(CONFIG_COMBINE, combining, [CONFIG_UTF8:yes HAVE_WCWIDTH:yes], [Combining characters],
1353               [  --enable-combining      support Unicode combining characters (experimental)])
1354
1355
1356 AC_ARG_ENABLE(weehoofooboomookerchoo,
1357               [
1358     Also check out the features.conf file for more information about features!
1359               ],
1360               [AC_MSG_ERROR(Are you strange, or what?)])
1361
1362
1363 # ===================================================================
1364 # Further LDFLAGS tweaks
1365 # ===================================================================
1366
1367 # == EMX hack
1368
1369 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1370 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1371
1372
1373 # Check for -rdynamic
1374 #
1375 # gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
1376 # the executable to its dynamic symbol table.  ELinks uses this for
1377 # two purposes:
1378 #
1379 # 1. If ELinks detects a bug, it can try to display a backtrace by
1380 #    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
1381 #    manual states users of GNU ld must pass -rdynamic to make the
1382 #    symbols available to the program.
1383 #
1384 # 2. It would eventually be nice to dynamically load shared
1385 #    libraries as plugins (bug 73).  The plugins must be able to
1386 #    call ELinks functions.  This can be implemented either by
1387 #    registering all callable functions in ELinks-specific data
1388 #    structures, or by letting the dynamic linker handle them.
1389 #    The latter way requires something equivalent to -rdynamic.
1390 #
1391 # Because backtraces are not needed for correct operation, and bug
1392 # 73 is not yet being fixed, the configure script and makefiles
1393 # should not complain to the user if they find that -rdynamic does
1394 # not work.  Besides, it was reported at elinks-users on 2006-09-12
1395 # that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
1396 # Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
1397 # -rdynamic but does something equivalent automatically.  (This was
1398 # tested with "nm -D elinks | grep redraw_from_window".)
1399 #
1400 # With Sun Studio 11 on Solaris 9, we get "cc: Warning: illegal option
1401 # -dynamic"; then, cc proceeds anyway, but the option can prevent the
1402 # linker from finding the libraries listed in -l operands.  So this
1403 # -rdynamic check needs to happen after the libraries have already
1404 # been added to $LDFLAGS.
1405 AC_MSG_CHECKING([for -rdynamic])
1406 LDFLAGS_X="$LDFLAGS"
1407 LDFLAGS="-rdynamic $LDFLAGS"
1408 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[have_rdynamic=yes],[have_rdynamic=no])
1409 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
1410 AC_MSG_RESULT($have_rdynamic)
1411
1412 # ===================================================================
1413 # Export directory paths
1414 # ===================================================================
1415
1416 # Set up the ``entry points'' if they were not supplied by builder
1417 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1418 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1419
1420 # Create CONFDIR #define for config.h
1421
1422 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1423 # it's autoconf fault to force us to do such hacks ;p.
1424 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1425   # sysconfdir is set to its default value... fine, let's append /elinks/
1426   # XXX: We can't modify listing of the default in ./configure --help :-(
1427   sysconfdir_n=`eval echo "$sysconfdir"`
1428   sysconfdir=$sysconfdir_n
1429   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1430         sysconfdir="$sysconfdir/elinks"
1431 fi
1432
1433 CONFDIR=$sysconfdir
1434 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1435 AC_SUBST(CONFDIR)
1436
1437 # Create LOCALEDIR #define for config.h
1438 LOCALEDIR=`eval echo "$datadir/locale"`
1439 while echo "$LOCALEDIR" | grep "\\$"
1440 do
1441         LOCALEDIR=`eval echo "$LOCALEDIR"`
1442 done > /dev/null 2> /dev/null
1443 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1444 AC_SUBST(LOCALEDIR)
1445
1446 # Create LIBDIR #define for config.h
1447 LIBDIR=`eval echo "$libdir"`
1448 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1449 AC_SUBST(LIBDIR)
1450
1451 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1452 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1453
1454
1455 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
1456 ]], [[#if !defined(__TINYC__) || !defined(alloca)
1457         #error not tcc
1458         #endif ]])],[cf_result=yes],[cf_result=no])
1459
1460 if test "$cf_result" = "yes"; then
1461         AC_DEFINE([HAVE_ALLOCA])
1462         AC_DEFINE([_ALLOCA_H], [1], [Define as 1 if you are using Tiny C Compiler
1463                 with the GNU C Library, and <alloca.h> of glibc would otherwise
1464                 override the alloca macro defined in <stddef.h> of TCC.
1465                 If <alloca.h> of glibc sees the _ALLOCA_H macro, it assumes
1466                 it has already been included, and does not redefine alloca.
1467                 This might not work in future glibc versions though, because
1468                 the names of the #include guard macros are not documented.
1469                 The incompatibility has been reported to the tinycc-devel
1470                 mailing list on 2008-07-14.  If a future version of TCC provides
1471                 an <alloca.h> of its own, this hack won't be needed.])
1472 fi
1473 # ===================================================================
1474 # A little fine tuning of gcc specific options (continued)
1475 # ===================================================================
1476
1477 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
1478   if test "$CONFIG_DEBUG" = "yes"; then
1479     # We want to see all warnings and live with none (in debug mode).
1480     CFLAGS="$CFLAGS -Werror"
1481   fi
1482
1483   case "`$CC -dumpversion`" in
1484     3.0|3.1|3.2)
1485       # These should be ok using -Werror
1486       ;;
1487     3.*)
1488       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1489       # "dereferencing type-punned pointer will break strict-aliasing rules"
1490       # warnings. Disable them by not doing any strict-aliasing. The
1491       # alternative is just too ugly. Thanks gcc guys!! ;)
1492       CFLAGS="$CFLAGS -fno-strict-aliasing"
1493       ;;
1494     4.*)
1495       # Do not show warnings related to (char * | unsigned char *) type
1496       # difference.
1497       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1498       ;;
1499     *)
1500       # These should be ok using -Werror
1501       ;;
1502   esac
1503
1504   # GCC 4.2.1 warns if we use the address of an object in Boolean context:
1505   # warning: the address of `builtin_modules' will always evaluate as `true'
1506   # This hits the object_lock and foreach_module macros in particular.
1507   # It would be okay to put something in the macros to avoid the warning,
1508   # but currently this seems to require defining parallel macros that skip
1509   # the NULL check, and that's too ugly.  So we instead disable the warning.
1510   # GCC 4.2.1 needs -Wno-address, but GCC 4.2 snapshots need -Wno-always-true.
1511   # GCC 4.1.3 recognizes neither and exits with code 1 if they are given.
1512   for warning_flag in -Wno-address -Wno-always-true; do
1513     AC_MSG_CHECKING([whether $CC accepts $warning_flag])
1514     EL_SAVE_FLAGS
1515     CFLAGS="$CFLAGS $warning_flag"
1516     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1517       [AC_MSG_RESULT([yes])
1518        break],
1519       [AC_MSG_RESULT([no])])
1520     EL_RESTORE_FLAGS
1521   done
1522
1523   # Bug 1012: Some parts of ELinks do arithmetic with signed integers
1524   # in such a way that an overflow is possible.  GCC 4.2.1 warns
1525   # "warning: assuming signed overflow does not occur when assuming
1526   # that (X + c) > X is always true", which may be an incorrect
1527   # optimization (although allowed by the standard), and breaks the
1528   # build with -Werror.
1529   #
1530   # All of the following tests included -S -Wall -Wextra:
1531   #
1532   # GCC: (GNU) 4.0.4 20060507 (prerelease) (Debian 4.0.3-3)
1533   # * gcc-4.0 -O0: OK, compares the values
1534   # * gcc-4.0 -O2: assumes no overflow, does not warn
1535   # * gcc-4.0 -O0 -fno-strict-overflow: unrecognized command line option
1536   # * gcc-4.0 -O0 -fwrapv: OK, compares the values
1537   # * gcc-4.0 -O2 -fwrapv: OK, compares the values
1538   # * gcc-4.0 -O0 -ftrapv: OK, calls __addvsi3
1539   # * gcc-4.0 -O2 -ftrapv: assumes no overflow, does not warn
1540   # * gcc-4.0 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1541   # * gcc-4.0 -O2 -fwrapv -ftrapv: compares the values
1542   #
1543   # GCC: (GNU) 4.1.3 20070812 (prerelease) (Debian 4.1.2-15)
1544   # * gcc-4.1 -O0: assumes no overflow, does not warn
1545   # * gcc-4.1 -O2: assumes no overflow, does not warn
1546   # * gcc-4.1 -O0 -fno-strict-overflow: unrecognized command line option
1547   # * gcc-4.1 -O0 -fwrapv: OK, compares the values
1548   # * gcc-4.1 -O2 -fwrapv: OK, compares the values
1549   # * gcc-4.1 -O0 -ftrapv: OK, calls __addvsi3
1550   # * gcc-4.1 -O2 -ftrapv: compares the values
1551   # * gcc-4.1 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1552   # * gcc-4.1 -O2 -fwrapv -ftrapv: compares the values
1553   #
1554   # GCC: (GNU) 4.2.1 (Debian 4.2.1-5)
1555   # * gcc-4.2 -O0: OK, compares the values
1556   # * gcc-4.2 -O2: assumes no overflow, warns about it
1557   # * gcc-4.2 -O0 -fno-strict-overflow: OK, compares the values
1558   # * gcc-4.2 -O2 -fno-strict-overflow: OK, compares the values
1559   # * gcc-4.2 -O0 -fwrapv: OK, compares the values
1560   # * gcc-4.2 -O2 -fwrapv: OK, compares the values
1561   # * gcc-4.2 -O0 -ftrapv: OK, calls __addvsi3
1562   # * gcc-4.2 -O2 -ftrapv: compares the values
1563   # * gcc-4.2 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1564   # * gcc-4.2 -O2 -fwrapv -ftrapv: compares the values
1565   #
1566   # Apparently, -ftrapv does not work reliably at all.
1567   for overflow_flag in -fno-strict-overflow -fwrapv; do
1568     AC_MSG_CHECKING([whether $CC accepts $overflow_flag])
1569     EL_SAVE_FLAGS
1570     CFLAGS="$CFLAGS $overflow_flag"
1571     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1572       [AC_MSG_RESULT([yes])
1573        break],
1574       [AC_MSG_RESULT([no])])
1575     EL_RESTORE_FLAGS
1576   done
1577 fi
1578
1579 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1580 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1581 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1582 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1583
1584 # ===================================================================
1585 # Colored make output
1586 # ===================================================================
1587
1588 if test $(`which tput` colors) -ge 4; then
1589         MAKE_COLOR=1
1590         AC_SUBST(MAKE_COLOR)
1591 fi
1592
1593 # ===================================================================
1594 # Generated files
1595 # ===================================================================
1596
1597 AC_CONFIG_FILES([ \
1598  Makefile.config \
1599  contrib/elinks.spec \
1600  contrib/lua/hooks.lua \
1601  contrib/conv/w3m2links.awk \
1602  doc/Doxyfile \
1603  doc/man/man1/elinks.1 \
1604  src/intl/gettext/ref-add.sed \
1605  src/intl/gettext/ref-del.sed
1606 ])
1607 AC_OUTPUT
1608
1609 abs_srcdir="$(cd "$srcdir" && pwd)"
1610 # builddir is always absolute!
1611 if test "$abs_srcdir" != "$builddir"; then
1612         # Bootstrap the Makefile creation
1613         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1614         "$MAKE" "SRC=$abs_srcdir" init
1615
1616         # Make cg-status ignore this build directory
1617         echo "*" > "$builddir/.gitignore"
1618 fi
1619
1620 # ===================================================================
1621 # Configuration summary
1622 # ===================================================================
1623
1624 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1625 cat features.log