configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl There are two types of comments in this file.
   4 dnl Comments that refer to Autoconf macros begin with "dnl", and m4
   5 dnl discards them.  Other comments begin with "#", and they get copied
   6 dnl to the configure script, hopefully making it easier to read.
   7
   8 dnl Autoconf 2.13 generates an incomplete config.h.in; see ELinks bug 936.
   9 dnl Autoconf 2.59 is installed in the computer that generates our nightly
  10 dnl snapshots, so we need to be compatible with that.
  11 AC_PREREQ(2.59)
  12 AC_INIT
  13 AC_CONFIG_SRCDIR([src/main/main.c])
  14 AC_CONFIG_AUX_DIR(config)
  15
  16 PACKAGE=elinks
  17 VERSION=0.12pre2.GIT
  18 AC_SUBST(PACKAGE)
  19 AC_SUBST(VERSION)
  20 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Package version])
  21 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Package version])
  22 AC_CONFIG_HEADERS(config.h)
  23
  24 AC_CHECK_PROG(ACLOCAL,[aclocal],[aclocal],[config/missing aclocal])
  25 AC_CHECK_PROG(AUTOCONF,[autoconf],[autoconf],[config/missing autoconf])
  26 AC_CHECK_PROG(AUTOHEADER,[autoheader],[autoheader],[config/missing autoheader])
  27
  28 MAKE=
  29
  30 for make in gnumake gmake make false; do
  31         if test "x$MAKE" = x; then
  32                 AC_PATH_PROGS(MAKE, "$make")
  33         fi
  34 done
  35
  36 builddir="`pwd`"
  37
  38 # Cleanup if we are configuring with a previous build in the tree
  39 if test -e Makefile.config; then
  40         AC_MSG_CHECKING([for previous build to clean])
  41         "$MAKE" -C "$builddir/src" cleanall >/dev/null 2>/dev/null
  42         AC_MSG_RESULT(done)
  43 fi
  44
  45 # ===================================================================
  46 # Load feature configuration file and start logging features.
  47 # ===================================================================
  48
  49 features="features.conf"
  50 AC_CHECK_FILE("$srcdir/$features", [ . $srcdir/$features ])
  51 AC_CHECK_FILE("$builddir/$features", [ . $builddir/$features ])
  52 echo "Feature summary:" > features.log
  53
  54 # ===================================================================
  55 # Checks for programs.
  56 # ===================================================================
  57
  58 AC_PROG_CC
  59 AC_PROG_AWK
  60 AC_PATH_PROGS(AWK, "$AWK")
  61 AC_PROG_RANLIB
  62 AC_PROG_INSTALL
  63
  64 AC_PATH_PROGS(GIT, "git")
  65 AC_PATH_PROGS(SPARSE, "sparse")
  66
  67 CONFIG_ASCIIDOC="no"
  68 CONFIG_POD2HTML="no"
  69 CONFIG_XMLTO="no"
  70 CONFIG_JW="no"
  71
  72 if test "x$CONFIG_DOC" != xno; then
  73         AC_PATH_PROGS(ASCIIDOC, "asciidoc")
  74         if test "x$ASCIIDOC" != "x"; then
  75                 EL_CONFIG(CONFIG_ASCIIDOC, [AsciiDoc])
  76                 EL_CONFIG(MANUAL_ASCIIDOC, [HTML (one file)])
  77                 EL_CONFIG(MAN_ASCIIDOC, [HTML])
  78
  79                 echo > config.asciidoc-unsafe.txt
  80                 if "$ASCIIDOC" --unsafe config.asciidoc-unsafe.txt >/dev/null 2>/dev/null; then
  81                         ASCIIDOC_FLAGS=--unsafe
  82                 fi
  83                 rm config.asciidoc-unsafe.*
  84         fi
  85
  86         AC_PATH_PROGS(XMLTO, "xmlto")
  87         if test "x$XMLTO" != "x"; then
  88                 EL_CONFIG(CONFIG_XMLTO, [XmlTo])
  89                 EL_CONFIG(MANUAL_XMLTO, [HTML (multiple files)])
  90                 EL_CONFIG(MAN_XMLTO, [man (groff)])
  91         fi
  92
  93         AC_PATH_PROGS(JW, "jw")
  94         if test "x$JW" != "x"; then
  95                 EL_CONFIG(CONFIG_JW, [JadeWrapper])
  96                 EL_CONFIG(MANUAL_JW, [PDF])
  97         fi
  98
  99         AC_PATH_PROGS(POD2HTML, "pod2html")
 100         if test "x$POD2HTML" != "x"; then
 101                 EL_CONFIG(CONFIG_POD2HTML, [Pod2HTML])
 102         fi
 103
 104         AC_PATH_PROGS(DOXYGEN, "doxygen")
 105         if test "x$DOXYGEN" != "x"; then
 106                 EL_CONFIG(CONFIG_DOXYGEN, [Doxygen])
 107                 api_srcdir="$(cd "$srcdir" && pwd)/src"
 108                 AC_SUBST(api_srcdir)
 109         fi
 110 fi
 111
 112 AC_SUBST(ASCIIDOC_FLAGS)
 113 AC_SUBST(CONFIG_ASCIIDOC)
 114 AC_SUBST(CONFIG_DOXYGEN)
 115 AC_SUBST(CONFIG_POD2HTML)
 116 AC_SUBST(CONFIG_XMLTO)
 117 AC_SUBST(CONFIG_JW)
 118
 119 EL_CONFIG_DEPENDS(CONFIG_DOC, [CONFIG_ASCIIDOC CONFIG_XMLTO CONFIG_JW CONFIG_POD2HTML], [Documentation Tools])
 120 EL_CONFIG_DEPENDS(CONFIG_MANUAL, [MANUAL_ASCIIDOC MANUAL_XMLTO MANUAL_JW], [Manual Formats])
 121 EL_CONFIG_DEPENDS(CONFIG_MANPAGE, [MAN_ASCIIDOC MAN_XMLTO], [Man Page Formats])
 122 EL_CONFIG_DEPENDS(CONFIG_APIDOCS, [CONFIG_DOXYGEN], [API Documentation])
 123
 124 # gcc specific options (to be continued at the bottom of configure)
 125 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
 126   # We want to see all warnings and live with none.
 127   # We can't set up -Werror here as there may be some warnings in test
 128   # suite of configure, and we don't want to fail them.
 129   CFLAGS="$CFLAGS -Wall"
 130 fi
 131
 132 # ===================================================================
 133 # Checks for special OSes.
 134 # ===================================================================
 135
 136 dnl EL_CHECK_COMPILER_MACRO(define, name, flagname)
 137 AC_DEFUN([EL_CHECK_COMPILER_MACROS],
 138 [
 139         AC_MSG_CHECKING([for $2])
 140
 141         for flag in $3; do
 142                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[#ifndef $flag
 143 kill me!
 144 #endif ]])],[$1=yes],[$1=no])
 145                 if test "[$]$1" = yes; then
 146                         EL_CONFIG([$1], [$2])
 147                         break
 148                 fi
 149         done
 150
 151         AC_MSG_RESULT([$]$1)
 152 ])
 153
 154 EL_CHECK_COMPILER_MACROS(CONFIG_OS_BEOS, [BEOS], [__BEOS__])
 155 AC_SUBST(CONFIG_OS_BEOS)
 156
 157 EL_CHECK_COMPILER_MACROS(CONFIG_OS_RISCOS, [RISCOS], [__riscos__])
 158 AC_SUBST(CONFIG_OS_RISCOS)
 159
 160 EL_CHECK_COMPILER_MACROS(CONFIG_OS_WIN32, [WIN32], [_WIN32 __WIN32__])
 161 AC_SUBST(CONFIG_OS_WIN32)
 162
 163 EL_CHECK_COMPILER_MACROS(CONFIG_OS_OS2, [EMX], [__EMX__])
 164 AC_SUBST(CONFIG_OS_OS2)
 165 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zexe//g"`
 166
 167 AC_MSG_CHECKING([for UNIX])
 168 dnl FIXME: some depend kind of mechanism
 169 if test "$CONFIG_OS_BEOS" = no && \
 170    test "$CONFIG_OS_RISCOS" = no && \
 171    test "$CONFIG_OS_WIN32" = no && \
 172    test "$CONFIG_OS_OS2" = no; then
 173         EL_CONFIG(CONFIG_OS_UNIX, [UNIX])
 174 else
 175         CONFIG_OS_UNIX=no
 176 fi
 177 AC_MSG_RESULT($CONFIG_OS_UNIX)
 178 AC_SUBST(CONFIG_OS_UNIX)
 179
 180 # ===================================================================
 181 # Checks for header files.
 182 # ===================================================================
 183
 184 AC_HEADER_DIRENT
 185 AC_HEADER_STDC
 186 AC_HEADER_SYS_WAIT
 187 AC_HEADER_TIME
 188
 189 AC_CHECK_HEADERS(wctype.h)
 190 AC_CHECK_HEADERS(fcntl.h limits.h time.h unistd.h)
 191 AC_CHECK_HEADERS(sigaction.h)
 192 AC_CHECK_HEADERS(arpa/inet.h)
 193 AC_CHECK_HEADERS(netinet/in_systm.h netinet/in_system.h netinet/ip.h)
 194 AC_CHECK_HEADERS(netdb.h netinet/in.h netinet/in6_var.h)
 195 AC_CHECK_HEADERS(ifaddrs.h)
 196 AC_CHECK_HEADERS(sys/cygwin.h io.h)
 197 AC_CHECK_HEADERS(sys/fmutex.h)
 198 AC_CHECK_HEADERS(sys/ioctl.h sys/sockio.h)
 199 AC_CHECK_HEADERS(sys/resource.h)
 200 AC_CHECK_HEADERS(sys/select.h)
 201 AC_CHECK_HEADERS(sys/signal.h)
 202 AC_CHECK_HEADERS(sys/socket.h)
 203 AC_CHECK_HEADERS(sys/time.h)
 204 AC_CHECK_HEADERS(sys/utsname.h)
 205 AC_CHECK_HEADERS([net/if.h], [], [],
 206 [[#ifdef HAVE_SYS_SOCKET_H
 207 # include <sys/socket.h> /* <net/if.h> on Mac OS X 10.5.4 needs this */
 208 #endif
 209 ]])
 210 AC_CHECK_HEADERS(stdint.h inttypes.h)
 211 AC_CHECK_HEADERS(locale.h pwd.h)
 212 AC_CHECK_HEADERS(termios.h)
 213
 214
 215 AC_CHECK_HEADERS(sys/un.h,
 216         [CONFIG_INTERLINK=yes
 217          EL_CONFIG([CONFIG_INTERLINK], [interlinking])],
 218         [CONFIG_INTERLINK=no])
 219 AC_SUBST(CONFIG_INTERLINK)
 220
 221 # ===================================================================
 222 # Checks for typedefs, structures, and compiler characteristics.
 223 # ===================================================================
 224
 225 AC_STRUCT_TM
 226 AC_C_CONST
 227 AC_C_INLINE
 228 EL_CHECK_CODE(typeof, HAVE_TYPEOF, [], [int a; typeof(a) b;])
 229
 230 AC_SYS_LARGEFILE
 231 AC_TYPE_SIZE_T
 232 AC_TYPE_OFF_T
 233 EL_CHECK_TYPE(ssize_t, int)
 234 EL_CHECK_SYS_TYPE(long long, HAVE_LONG_LONG, [])
 235 EL_CHECK_SYS_TYPE(off_t, HAVE_OFF_T, [])
 236 EL_CHECK_INT_TYPE(int32_t, HAVE_INT32_T)
 237 EL_CHECK_INT_TYPE(uint32_t, HAVE_UINT32_T)
 238 EL_CHECK_INT_TYPE(uint16_t, HAVE_UINT16_T)
 239
 240 AC_CHECK_SIZEOF(char, 1)
 241 AC_CHECK_SIZEOF(short, 2)
 242 AC_CHECK_SIZEOF(int, 4)
 243 AC_CHECK_SIZEOF(long, 4)
 244 test "x$HAVE_LONG_LONG" = xyes && AC_CHECK_SIZEOF(long long, 8)
 245 test "x$HAVE_OFF_T" = xyes && AC_CHECK_SIZEOF(off_t, 4)
 246
 247 # Check for variadic macros
 248 EL_CHECK_CODE([variadic macros], HAVE_VARIADIC_MACROS,
 249                 [#include <stdio.h>
 250                  #define a(b,c...) printf(b,##c)],
 251                 [a("foo");a("%s","bar");a("%s%s","baz","quux");])
 252
 253 # ===================================================================
 254 # Checks for library functions.
 255 # ===================================================================
 256
 257 AC_PROG_GCC_TRADITIONAL
 258 AC_FUNC_MEMCMP
 259 AC_FUNC_MMAP
 260 AC_FUNC_STRFTIME
 261 AC_CHECK_FUNCS(atoll gethostbyaddr herror strerror)
 262 AC_CHECK_FUNCS(popen uname access chmod alarm timegm mremap)
 263 AC_CHECK_FUNCS(strcasecmp strncasecmp strcasestr strstr strchr strrchr)
 264 AC_CHECK_FUNCS(memmove bcopy stpcpy strdup index isdigit mempcpy memrchr)
 265 AC_CHECK_FUNCS(snprintf vsnprintf asprintf vasprintf)
 266 AC_CHECK_FUNCS(getifaddrs getpwnam inet_pton inet_ntop)
 267 AC_CHECK_FUNCS(fflush fsync fseeko ftello sigaction)
 268 AC_CHECK_FUNCS(gettimeofday clock_gettime)
 269
 270 AC_CHECK_FUNCS([cygwin_conv_to_full_win32_path])
 271
 272 AC_CHECK_FUNCS(setenv putenv, HAVE_SETENV_OR_PUTENV=yes)
 273 AC_CHECK_FUNCS(getuid, HAVE_GETUID=yes)
 274 AC_CHECK_FUNCS(geteuid, HAVE_GETEUID=yes)
 275
 276 # These aren't probably needed now, as they are commented in links.h.
 277 # I've no idea about their historical background, but I keep them here
 278 # just in the case they will help later. --pasky
 279 AC_CHECK_FUNCS(getpid, HAVE_GETPID=yes)
 280 AC_CHECK_FUNCS(setpgid getpgid setpgrp getpgrp)
 281 AC_CHECK_FUNCS(raise, HAVE_RAISE=yes)
 282 AC_CHECK_FUNCS(kill, HAVE_KILL=yes)
 283
 284 if test x"$HAVE_RAISE" = x; then
 285         if test x"$HAVE_KILL" = x || test x"$HAVE_GETPID" = x; then
 286                 AC_MSG_ERROR([Unable to emulate raise()])
 287         fi
 288 fi
 289
 290 AC_CACHE_CHECK([for __va_copy],el_cv_HAVE_VA_COPY,[
 291 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>
 292 va_list ap1,ap2;]], [[__va_copy(ap1,ap2);]])],[el_cv_HAVE_VA_COPY=yes],[el_cv_HAVE_VA_COPY=no])])
 293 if test x"$el_cv_HAVE_VA_COPY" = x"yes"; then
 294         EL_DEFINE(HAVE_VA_COPY, __va_copy)
 295 fi
 296
 297 AC_CACHE_CHECK([for sysconf(_SC_PAGE_SIZE)],el_cv_HAVE_SC_PAGE_SIZE,[
 298 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <unistd.h>
 299 ]], [[int page_size = sysconf(_SC_PAGE_SIZE);]])],[el_cv_HAVE_SC_PAGE_SIZE=yes],[el_cv_HAVE_SC_PAGE_SIZE=no])])
 300 if test x"$el_cv_HAVE_SC_PAGE_SIZE" = x"yes"; then
 301         EL_DEFINE(HAVE_SC_PAGE_SIZE, _SC_PAGE_SIZE)
 302 fi
 303
 304 AC_CACHE_CHECK([for C99 vsnprintf],el_cv_HAVE_C99_VSNPRINTF,[
 305 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 306 #include <stdio.h>
 307 #include <stdarg.h>
 308 #include <stdlib.h>
 309 #include <string.h>
 310
 311 char buf[8];
 312
 313 int bar(char *buf, const char *format, va_list ap)
 314 {
 315        return vsnprintf(buf, 0, format, ap);
 316 }
 317
 318 void foo(const char *format, ...) {
 319        va_list ap;
 320        int len;
 321
 322        va_start(ap, format);
 323        len = bar(buf, format, ap);
 324        va_end(ap);
 325        if ((len != 6) && (len != 7)) exit(1); /* \n -> \r\n */
 326
 327        va_start(ap, format);
 328        len = bar(buf, format, ap);
 329        va_end(ap);
 330        if ((len != 6) && (len != 7)) exit(1);
 331
 332        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 333
 334        exit(0);
 335 }
 336 main() { foo("hello\n"); }
 337 ]])],[el_cv_HAVE_C99_VSNPRINTF=yes],[el_cv_HAVE_C99_VSNPRINTF=no],[el_cv_HAVE_C99_VSNPRINTF=cross])])
 338 if test x"$el_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 339         EL_DEFINE(HAVE_C99_VSNPRINTF, [C99 compliant vsnprintf()])
 340 fi
 341
 342 # OpenSSL and Lua frequently need dlopen
 343 AC_CHECK_LIB(dl, dlopen)
 344
 345 # ===================================================================
 346 # Checks for libraries.
 347 # ===================================================================
 348
 349 AC_CHECK_FUNC(socket, cf_result=yes, cf_result=no)
 350 if test "$cf_result" = no; then
 351         AC_CHECK_LIB(socket, socket)
 352 fi
 353
 354 AC_CHECK_FUNC(setsockopt, cf_result=yes, cf_result=no)
 355 if test "$cf_result" = no; then
 356         AC_CHECK_LIB(socket, setsockopt)
 357 fi
 358
 359 AC_CHECK_FUNC(gethostbyname, cf_result=yes, cf_result=no)
 360 if test "$cf_result" = no; then
 361         AC_CHECK_LIB(socket, gethostbyname, cf_result=yes, cf_result=no)
 362         if test "$cf_result" = no; then
 363                 AC_CHECK_LIB(nsl, gethostbyname)
 364         else
 365                 test -z "`echo $LIBS | grep -- -lsocket`" && LIBS="$LIBS -lsocket"
 366         fi
 367 fi
 368
 369 # ===================================================================
 370 # Checks for packaging specific options.
 371 # ===================================================================
 372
 373 AC_ARG_WITH(xterm, [  --with-xterm            how to invoke the X terminal emulator],
 374             [ if test "$withval" != no && test "$withval" != yes; then
 375                 AC_DEFINE_UNQUOTED(XTERM, "$withval", [How to invoke XTerm])
 376               fi ])
 377
 378 # ===================================================================
 379 # Checks for a libraries, optional even if installed.
 380 # ===================================================================
 381
 382 dnl EL_CHECK_OPTIONAL_LIBRARY(define, name, header, lib, function)
 383 AC_DEFUN([EL_CHECK_OPTIONAL_LIBRARY],
 384 [
 385         AC_MSG_CHECKING([for $2 support])
 386
 387         if test "[$]$1" != no; then
 388                 AC_MSG_RESULT(yes)
 389                 EL_SAVE_FLAGS
 390                 if test -n "$withval" && test -d "$withval"; then
 391                         # Be a little more careful when setting
 392                         # include and lib directories. This way
 393                         # $withval will work when includes are
 394                         # there but the library is in the common
 395                         # /usr/lib ... Does the right thing when
 396                         # looking for gc on Debian.
 397                         if test -d "$withval/include"; then
 398                                 CFLAGS="$CFLAGS -I$withval/include"
 399                                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 400                         else
 401                                 CFLAGS="$CFLAGS -I$withval"
 402                                 CPPFLAGS="$CPPFLAGS -I$withval"
 403                         fi
 404                         if test -d "$withval/lib"; then
 405                                 LDFLAGS="$LDFLAGS -L$withval/lib"
 406                         fi
 407                 fi
 408
 409                 AC_CHECK_HEADERS([$3], [$1=yes], [$1=no; break;])
 410                 if test "[$]$1" = yes; then
 411                         AC_CHECK_LIB([$4], [$5], [$1=yes], [$1=no])
 412                 fi
 413
 414                 if test "[$]$1" = yes; then
 415                         EL_CONFIG([$1], [$2])
 416                         LIBS="$LIBS -l$4"
 417                 else
 418                         if test -n "[$]WITHVAL_$1" &&
 419                            test "[$]WITHVAL_$1" != xno; then
 420                                 AC_MSG_ERROR([$2 not found])
 421                         fi
 422                         EL_RESTORE_FLAGS
 423                 fi
 424         else
 425                 AC_MSG_RESULT(disabled)
 426         fi
 427 ])
 428
 429 dnl EL_CONFIG_OPTIONAL_LIBRARY(define, name, header, lib, function, confhelp)
 430 AC_DEFUN([EL_CONFIG_OPTIONAL_LIBRARY],
 431 [
 432         if test "x[$]$1" != xno; then $1=yes; fi
 433         WITHVAL_$1=
 434
 435         AC_ARG_WITH([$2], [$6], [WITHVAL_$1="[$]withval"])
 436         if test "x[$]WITHVAL_$1" = xno; then $1=no; fi
 437         if test "x[$]WITHVAL_$1" = xyes; then $1=yes; fi
 438
 439         EL_CHECK_OPTIONAL_LIBRARY([$1], [$2], [$3], [$4], [$5])
 440
 441         EL_LOG_CONFIG([$1], [$2], [])
 442 ])
 443
 444 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GPM, gpm, gpm.h, gpm, Gpm_Open,
 445         [  --without-gpm           disable gpm (mouse) support])
 446
 447 # ELinks calls deflateInit2 with windowBits = MAX_WBITS | 32, to
 448 # enable automatic decoding of both zlib and gzip headers.  This
 449 # feature was added in zlib 1.2.0.2; earlier versions return an error.
 450 # The gzclearerr function was also added in zlib 1.2.0.2, so check for
 451 # that, even though ELinks does not actually call gzclearerr.
 452 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GZIP, zlib, zlib.h, z, gzclearerr,
 453         [  --without-zlib          disable zlib support])
 454
 455 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_BZIP2, bzlib, bzlib.h, bz2, BZ2_bzReadOpen,
 456         [  --without-bzlib         disable bzlib support])
 457
 458 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_IDN, idn, idna.h, idn, stringprep_check_version,
 459         [  --without-idn           disable international domain names support])
 460
 461 if test "x${with_gc}" != xno; then
 462         EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_GC, gc, gc.h, gc, GC_init,
 463                 [  --with-gc               enable Boehm's garbage collector])
 464 fi
 465
 466 # LZMA disabled by default, because of little usability and compilation problems
 467 # with new xz
 468 EL_CONFIG_OPTIONAL_LIBRARY(CONFIG_LZMA, lzma, lzma.h, lzma, lzma_code,
 469         [  --with-lzma             enable lzma encoding support])
 470
 471 # ===================================================================
 472 # Check for GSSAPI, optional even if installed.
 473 # ===================================================================
 474
 475 enable_gssapi="no";
 476
 477 AC_ARG_WITH(gssapi, [  --with-gssapi           enable GSSAPI support],
 478             [ if test "x$withval" != xno; then enable_gssapi=yes; fi ])
 479
 480 AC_MSG_CHECKING([for GSSAPI])
 481
 482 if test "$enable_gssapi" = "yes"; then
 483         AC_MSG_RESULT(yes)
 484         GSSAPI_CFLAGS=`krb5-config --cflags gssapi`
 485         GSSAPI_LIBS=`krb5-config --libs gssapi`
 486         CFLAGS="$GSSAPI_CFLAGS $CFLAGS"
 487         LIBS="$GSSAPI_LIBS $LIBS"
 488         EL_CONFIG(CONFIG_GSSAPI, [GssApi])
 489 else
 490         AC_MSG_RESULT(no)
 491 fi
 492
 493 AC_SUBST(CONFIG_GSSAPI)
 494
 495 # ===================================================================
 496 # Bookmark and XBEL support
 497 # ===================================================================
 498
 499 EL_SAVE_FLAGS
 500
 501 EL_ARG_ENABLE(CONFIG_BOOKMARKS, bookmarks, [Bookmarks],
 502               [  --disable-bookmarks     disable bookmark support])
 503
 504 # Check whether --enable-xbel or --disable-xbel was given.
 505 if test "x${enable_xbel}" != xno; then
 506         AC_CHECK_HEADERS(expat.h, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 507
 508         if test "$HAVE_LIBEXPAT" = yes; then
 509                 AC_CHECK_LIB(expat, XML_ParserCreate, HAVE_LIBEXPAT=yes, HAVE_LIBEXPAT=no)
 510                 if test "$HAVE_LIBEXPAT" = yes; then
 511                         LIBS="$LIBS -lexpat"
 512                 fi
 513         fi
 514 fi
 515
 516
 517 EL_ARG_DEPEND(CONFIG_XBEL_BOOKMARKS, xbel, [CONFIG_BOOKMARKS:yes HAVE_LIBEXPAT:yes],
 518               [XBEL bookmarks],
 519               [  --disable-xbel          disable XBEL bookmark support (requires expat)])
 520
 521 if test "$CONFIG_XBEL_BOOKMARKS" != yes; then
 522         EL_RESTORE_FLAGS
 523 fi
 524
 525 # ===================================================================
 526 # Checks for BSD sysmouse
 527 # ===================================================================
 528
 529 HAVE_SYSMOUSE_HEADER="no"
 530
 531 # Either of these header files provides the (same) sysmouse interface
 532 AC_CHECK_HEADERS(sys/consio.h machine/console.h, [HAVE_SYSMOUSE_HEADER="yes"])
 533
 534 # ===================================================================
 535 # Checks for OS/2
 536 # ===================================================================
 537
 538 if test "$CONFIG_OS_OS2" = yes; then
 539         EL_CONFIG_OS_OS2
 540 fi
 541
 542 # ===================================================================
 543 # Checks for Win32
 544 # ===================================================================
 545
 546 if test "$CONFIG_OS_WIN32" = yes; then
 547         EL_CONFIG_OS_WIN32
 548 fi
 549
 550 # ===================================================================
 551 # Check for SEE (Simple Ecmascript Engine)
 552 # ===================================================================
 553 AC_ARG_WITH(see, [  --with-see              enable Simple Ecmascript Engine (SEE) support],
 554             [ if test "x$withval" != xno; then enable_see=yes; fi ])
 555
 556 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 557 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 558 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 559 # for Guile in $PATH etc. --pasky
 560
 561 CONFIG_ECMASCRIPT_SEE=no
 562
 563 if test "$enable_see" = "yes"; then
 564         if test -d "$withval"; then
 565                 SEE_PATH="$withval:$PATH"
 566         else
 567                 SEE_PATH="$PATH"
 568         fi
 569
 570         AC_PATH_PROG(SEE_CONFIG, libsee-config, no, $SEE_PATH)
 571         AC_MSG_CHECKING([for SEE (2.0.1131 or later)])
 572         if test "$SEE_CONFIG" != no; then
 573                 EL_SAVE_FLAGS
 574                 SEE_LIBS="`$SEE_CONFIG --libs`"
 575                 SEE_CFLAGS="`$SEE_CONFIG --cppflags`"
 576                 CPPFLAGS="$SEE_CFLAGS $CPPFLAGS"
 577                 LIBS="$SEE_LIBS $LIBS_X"
 578                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <see/see.h>]], [[#if SEE_VERSION_API_MAJOR < 2
 579                         #error SEE too old
 580                         #endif
 581                 ]])],[cf_result=yes],[cf_result=no])
 582                 EL_RESTORE_FLAGS
 583                 if test "$cf_result" = yes; then
 584                         LIBS="$SEE_LIBS $LIBS"
 585                         EL_CONFIG(CONFIG_ECMASCRIPT_SEE, [SEE])
 586                         AC_SUBST(SEE_CFLAGS)
 587                 fi
 588                 AC_MSG_RESULT($cf_result)
 589         else
 590                 if test -n "$withval" && test "x$withval" != xno; then
 591                         AC_MSG_ERROR([SEE not found])
 592                 else
 593                         AC_MSG_WARN([SEE support disabled])
 594                 fi
 595         fi
 596 fi
 597
 598 # ===================================================================
 599 # Check for SpiderMonkey, optional even if installed.
 600 # ===================================================================
 601
 602 AC_ARG_WITH(spidermonkey, [  --without-spidermonkey  disable SpiderMonkey Mozilla JavaScript engine support],
 603             [if test "$withval" = no; then disable_spidermonkey=yes; fi])
 604 AC_MSG_CHECKING([for SpiderMonkey (1.5 RC3a or later)])
 605
 606 EL_SAVE_FLAGS
 607 cf_result=no
 608
 609 if test -z "$disable_spidermonkey"; then
 610         if test ! -d "$withval"; then
 611                 withval="";
 612         fi
 613         for spidermonkeydir in "$withval" "" /usr /usr/local /opt/spidermonkey /opt/js; do
 614                 for spidermonkeyinclude in "/include" "/include/js" "/include/smjs" "/include/mozjs"; do
 615                         for spidermonkeylib in js smjs mozjs; do
 616                                 if test "$cf_result" = no &&
 617                                    test -f "$spidermonkeydir$spidermonkeyinclude/jsapi.h"; then
 618                                         SPIDERMONKEY_LIBS="-L$spidermonkeydir/lib -l$spidermonkeylib"
 619                                         SPIDERMONKEY_CFLAGS="-I$spidermonkeydir$spidermonkeyinclude"
 620
 621                                         LIBS="$SPIDERMONKEY_LIBS $LIBS_X"
 622                                         CFLAGS="$CFLAGS_X $SPIDERMONKEY_CFLAGS"
 623                                         CPPFLAGS="$CPPFLAGS_X $SPIDERMONKEY_CFLAGS"
 624
 625                                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#define XP_UNIX
 626                                                      #include <jsapi.h>]], [[JS_GetReservedSlot(NULL, NULL, 0, NULL)]])],[cf_result=yes],[cf_result=no])
 627                                 fi
 628                         done
 629                 done
 630         done
 631 fi
 632
 633 AC_MSG_RESULT($cf_result)
 634 CONFIG_SPIDERMONKEY="$cf_result"
 635 if test "$cf_result" = "yes"; then
 636         AC_CHECK_FUNCS([[JS_ReportAllocationOverflow]])
 637 fi
 638 EL_RESTORE_FLAGS
 639
 640 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 641    test "x$CONFIG_ECMASCRIPT_SEE" != xyes; then
 642         EL_CONFIG(CONFIG_ECMASCRIPT_SMJS, [SpiderMonkey document scripting])
 643 else
 644         CONFIG_ECMASCRIPT_SMJS=no
 645 fi
 646
 647 EL_CONFIG_DEPENDS(CONFIG_ECMASCRIPT, [CONFIG_ECMASCRIPT_SEE CONFIG_ECMASCRIPT_SMJS], [ECMAScript (JavaScript)])
 648 AC_SUBST(CONFIG_ECMASCRIPT_SEE)
 649 AC_SUBST(CONFIG_ECMASCRIPT_SMJS)
 650
 651
 652 # ===================================================================
 653 # Optional Spidermonkey-based ECMAScript browser scripting
 654 # ===================================================================
 655
 656 AC_ARG_ENABLE(sm-scripting,
 657               [  --disable-sm-scripting  ECMAScript browser scripting (requires Spidermonkey)],
 658               [if test "$enableval" != no; then enableval="yes"; fi
 659                CONFIG_SCRIPTING_SPIDERMONKEY="$enableval";])
 660
 661 if test "x$CONFIG_SPIDERMONKEY" = xyes &&
 662    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 663         EL_CONFIG(CONFIG_SCRIPTING_SPIDERMONKEY, [SpiderMonkey])
 664 else
 665         CONFIG_SCRIPTING_SPIDERMONKEY=no
 666 fi
 667
 668 if test "x$CONFIG_ECMASCRIPT_SMJS" = xyes ||
 669    test "x$CONFIG_SCRIPTING_SPIDERMONKEY" = xyes; then
 670         LIBS="$LIBS $SPIDERMONKEY_LIBS"
 671         AC_SUBST(SPIDERMONKEY_LIBS)
 672         AC_SUBST(SPIDERMONKEY_CFLAGS)
 673         AC_SUBST(CONFIG_SPIDERMONKEY)
 674 fi
 675
 676 # ===================================================================
 677 # Check for Guile, optional even if installed.
 678 # ===================================================================
 679
 680 enable_guile="no";
 681
 682 AC_ARG_WITH(guile, [  --with-guile            enable Guile support],
 683             [ if test "x$withval" != xno; then enable_guile=yes; fi ])
 684
 685 # The following is probably bad, ugly and so on. Stolen from Guile's (1.4)
 686 # GUILE_FLAGS but I really don't want to require people to have Guile in order
 687 # to compile CVS. Also, the macro seems to be really stupid regarding searching
 688 # for Guile in $PATH etc. --pasky
 689
 690 AC_MSG_CHECKING([for Guile])
 691
 692 if test "$enable_guile" = "yes"; then
 693         AC_MSG_RESULT(yes);
 694         ## Based on the GUILE_FLAGS macro.
 695
 696         if test -d "$withval"; then
 697                 GUILE_PATH="$withval:$PATH"
 698         else
 699                 GUILE_PATH="$PATH"
 700         fi
 701
 702         AC_PATH_PROG(GUILE_CONFIG, guile-config, no, $GUILE_PATH)
 703
 704         ## First, let's just see if we can find Guile at all.
 705         if test "$GUILE_CONFIG" != no; then
 706                 cf_result="yes";
 707
 708                 GUILE_LIBS="`guile-config link`"
 709                 GUILE_CFLAGS="`guile-config compile`"
 710                 LIBS="$GUILE_LIBS $LIBS"
 711                 EL_CONFIG(CONFIG_SCRIPTING_GUILE, [Guile])
 712                 AC_SUBST(GUILE_CFLAGS)
 713                 cat <<EOF
 714 ***********************************************************************
 715 The Guile support is incomplete and not so well integrated to ELinks
 716 yet. That means, e.g., that you have no Guile console and there might
 717 not be all the necessary hooks. Also, the Guile interface is not too
 718 well tested (success stories heartily welcomed!).  See
 719 src/scripting/guile/README for further details and hints.
 720 ***********************************************************************
 721 EOF
 722         else
 723                 if test -n "$withval" && test "x$withval" != xno; then
 724                         AC_MSG_ERROR([Guile not found])
 725                 else
 726                         AC_MSG_WARN([Guile support disabled])
 727                 fi
 728         fi
 729 else
 730         AC_MSG_RESULT(no);
 731 fi
 732
 733 # ===================================================================
 734 # Check for Perl
 735 # ===================================================================
 736 enable_perl="no";
 737
 738 AC_ARG_WITH(perl, [  --with-perl             enable Perl support],
 739             [
 740 if test "$withval" = yes; then
 741         # FIXME: If withval is a valid directory append it to PATH
 742         # so that you can specify one of several perl installations.
 743         withval="";
 744         enable_perl=yes;
 745 fi
 746             ])
 747
 748 AC_MSG_CHECKING([for Perl])
 749
 750 cf_result=no
 751
 752 EL_SAVE_FLAGS
 753
 754 if test "$enable_perl" = "yes"; then
 755         PERL_LIBS="`perl -MExtUtils::Embed -e ldopts`"
 756         PERL_CFLAGS="`perl -MExtUtils::Embed -e ccopts`"
 757         LIBS="$PERL_LIBS $LIBS"
 758         CFLAGS="$PERL_CFLAGS $CFLAGS"
 759         CPPFLAGS="$CPPFLAGS $PERL_CFLAGS"
 760         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 761 #include <EXTERN.h>
 762 #include <perl.h>
 763 #include <perlapi.h>
 764 ]], [[PerlInterpreter *my_perl = perl_alloc();]])],[cf_result=yes],[cf_result=no])
 765 fi
 766
 767 if test "$cf_result"; then AC_MSG_RESULT($cf_result); fi
 768
 769 AC_MSG_CHECKING([whether POPpx works without an n_a variable])
 770 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 771 #include <EXTERN.h>
 772 #include <perl.h>
 773 extern PerlInterpreter *my_perl;
 774 ]], [[dSP; (void) POPpx;]])],[AC_MSG_RESULT([yes])
 775 AC_DEFINE([CONFIG_PERL_POPPX_WITHOUT_N_A], [1],
 776                 [Define if using Perl 5.8.8 or later, where the "POPpx" macro
 777 no longer needs an "n_a" variable like it did in 5.8.7])],[AC_MSG_RESULT([no])])
 778
 779 if test "$cf_result" != "yes"; then
 780         EL_RESTORE_FLAGS
 781 else
 782         EL_CONFIG(CONFIG_SCRIPTING_PERL, [Perl])
 783
 784         CFLAGS="$CFLAGS_X"
 785         CPPFLAGS="$CPPFLAGS_X"
 786         AC_SUBST(PERL_LIBS)
 787         AC_SUBST(PERL_CFLAGS)
 788 fi
 789
 790 # ===================================================================
 791 # Check for Python
 792 # ===================================================================
 793 enable_python="no";
 794
 795 AC_ARG_WITH(python, [[  --with-python[=DIR]     enable Python support]],
 796             [ if test "x$withval" != xno; then enable_python=yes; fi ])
 797
 798 EL_SAVE_FLAGS
 799 cf_result=no
 800
 801 AC_MSG_CHECKING([for Python])
 802
 803 if test "$enable_python" = "yes"; then
 804         AC_MSG_RESULT(yes);
 805
 806         if test -d "$withval"; then
 807                 PYTHON_PATH="$withval:$PATH"
 808         else
 809                 PYTHON_PATH="$PATH"
 810         fi
 811
 812         AC_PATH_PROG(PYTHON, python, no, $PYTHON_PATH)
 813
 814         if test "$PYTHON" != no; then
 815                 cf_result="yes";
 816
 817                 PYTHON_CFLAGS="`$PYTHON -c 'from distutils import sysconfig; print "-I%s -I%s" % (sysconfig.get_python_inc(), sysconfig.get_python_inc(plat_specific=True))'`"
 818                 PYTHON_LIBS="`$PYTHON -c 'from distutils import sysconfig; var = sysconfig.get_config_var; print "%s %s %s -L%s -lpython%s" % (var("LINKFORSHARED"), var("LIBS"), var("SYSLIBS"), var("LIBPL"), var("VERSION"))'`"
 819                 LIBS="$PYTHON_LIBS $LIBS"
 820                 CPPFLAGS="$CPPFLAGS $PYTHON_CFLAGS"
 821                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <Python.h>]], [[Py_Initialize();]])],[cf_result=yes],[cf_result=no])
 822
 823                 if test "$cf_result" != "yes"; then
 824                         EL_RESTORE_FLAGS
 825                 else
 826                         EL_CONFIG(CONFIG_SCRIPTING_PYTHON, [Python])
 827                         AC_SUBST(PYTHON_LIBS)
 828                         AC_SUBST(PYTHON_CFLAGS)
 829                         CPPFLAGS="$CPPFLAGS_X"
 830                         cat <<EOF
 831 ***********************************************************************
 832 The Python support is incomplete and not so well integrated to ELinks
 833 yet. That means, e.g., that you have no Python console and there might
 834 not be all the necessary hooks. Also, the Python interface is not too
 835 well tested (success stories heartily welcomed!).
 836 ***********************************************************************
 837 EOF
 838                 fi
 839         else
 840                 if test -n "$withval" && test "x$withval" != xno; then
 841                         AC_MSG_ERROR([Python not found])
 842                 else
 843                         AC_MSG_WARN([Python support disabled])
 844                 fi
 845         fi
 846 else
 847         AC_MSG_RESULT(no);
 848 fi
 849
 850
 851 # ===================================================================
 852 # Check for Lua, optional even if installed.
 853 # ===================================================================
 854
 855 # Do this the long way, as FreeBSD reportedly needs -L<dir> for
 856 # anything other than /usr/lib, and Lua is very often in /usr/local/lib.
 857
 858 AC_ARG_WITH(lua, [  --without-lua           disable Lua support],
 859             [if test "$withval" = no; then disable_lua=yes; fi])
 860 AC_MSG_CHECKING([for Lua])
 861
 862 EL_SAVE_FLAGS
 863 cf_result=no
 864
 865 if test -z "$disable_lua"; then
 866         if test ! -d "$withval"; then
 867                 withval="";
 868         fi
 869         for luadir in "$withval" "" /usr /usr/local; do
 870                 for suffix in "" 50; do
 871                         if test "$cf_result" = no && ( test -f "$luadir/include/lua.h" || \
 872                            test -f "$luadir/include/lua$suffix/lua.h" ) ; then
 873                                 LUA_LIBS="-L$luadir/lib -llua$suffix -llualib$suffix -lm"
 874                                 LUA_CFLAGS="-I$luadir/include -I$luadir/include/lua$suffix"
 875
 876                                 LIBS="$LUA_LIBS $LIBS_X"
 877                                 CFLAGS="$CFLAGS_X $LUA_CFLAGS"
 878                                 CPPFLAGS="$CPPFLAGS_X $LUA_CFLAGS"
 879
 880                                 # Check that it is a compatible Lua version
 881                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[      #include <lua.h>
 882                                                 #include <lualib.h>]], [[       lua_State *L = lua_open();
 883                                                 luaopen_base(L);
 884                                                 luaopen_table(L);
 885                                                 luaopen_io(L);
 886                                                 luaopen_string(L);
 887                                                 luaopen_math(L);
 888                                                 lua_pushboolean(L, 1);
 889                                                 lua_close(L);]])],[cf_result=yes],[cf_result=no])
 890                         fi
 891                 done
 892         done
 893 fi
 894
 895 AC_MSG_RESULT($cf_result)
 896
 897 if test "$cf_result" != yes; then
 898         EL_RESTORE_FLAGS
 899 else
 900         EL_CONFIG(CONFIG_SCRIPTING_LUA, [Lua])
 901         AC_CHECK_HEADERS(lauxlib.h)
 902
 903         CFLAGS="$CFLAGS_X"
 904         CPPFLAGS="$CPPFLAGS_X"
 905         AC_SUBST(LUA_LIBS)
 906         AC_SUBST(LUA_CFLAGS)
 907 fi
 908
 909 # ===================================================================
 910 # Check for TRE library
 911 # ===================================================================
 912
 913 AC_MSG_CHECKING([[for TRE in pkg-config]])
 914 if pkg-config tre; then
 915         TRE_CFLAGS=`pkg-config --cflags tre`
 916         TRE_LIBS=`pkg-config --libs tre`
 917         AC_MSG_RESULT([[yes]])
 918 else
 919         # <http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=513055>
 920         # "libtre-dev: /usr/lib/pkgconfig/tre.pc missing"
 921         # so we look for the library even if pkg-config doesn't know about it.
 922         TRE_CFLAGS=
 923         TRE_LIBS=-ltre
 924         AC_MSG_RESULT([[no, but let's try defaults]])
 925 fi
 926
 927 AC_MSG_CHECKING([[for TRE header and library]])
 928 EL_SAVE_FLAGS
 929 CFLAGS="$TRE_CFLAGS $CFLAGS"
 930 LIBS="$TRE_LIBS $LIBS"
 931 AC_TRY_LINK([#include <tre/regex.h>],
 932             [regex_t re;
 933              regmatch_t match[1];
 934              regwcomp(&re, L"zap", REG_ICASE);
 935              regwexec(&re, L"ELIZAPROGRAM", 1, match, 0);],
 936             [AC_MSG_RESULT([[yes]])
 937              AC_DEFINE([HAVE_TRE_REGEX_H], [1],
 938                        [Define to 1 if you have the <tre/regex.h> header file.])
 939              # TRE_CFLAGS will be used only where needed.
 940              # TRE_LIBS will be kept in LIBS and used everywhere.
 941              EL_RESTORE_FLAGS
 942              LIBS="$TRE_LIBS $LIBS"],
 943             [AC_MSG_RESULT([[no]])
 944              TRE_CFLAGS=
 945              TRE_LIBS=
 946              EL_RESTORE_FLAGS])
 947 AC_SUBST(TRE_CFLAGS)
 948 AC_SUBST(TRE_LIBS)
 949
 950 AC_CHECK_SIZEOF([wchar_t], [4], [[#include <wchar.h>]])
 951
 952 # ===================================================================
 953 # Check for Ruby, optional even if installed.
 954 # ===================================================================
 955
 956 EL_CONFIG_SCRIPTING_RUBY
 957
 958 # ===================================================================
 959 # Setup global scripting
 960 # ===================================================================
 961
 962 EL_CONFIG_DEPENDS(CONFIG_SCRIPTING, [CONFIG_SCRIPTING_GUILE CONFIG_SCRIPTING_LUA CONFIG_SCRIPTING_PERL CONFIG_SCRIPTING_PYTHON CONFIG_SCRIPTING_RUBY CONFIG_SCRIPTING_SPIDERMONKEY], [Browser scripting])
 963 AC_SUBST(CONFIG_SCRIPTING_GUILE)
 964 AC_SUBST(CONFIG_SCRIPTING_LUA)
 965 AC_SUBST(CONFIG_SCRIPTING_PERL)
 966 AC_SUBST(CONFIG_SCRIPTING_PYTHON)
 967 AC_SUBST(CONFIG_SCRIPTING_RUBY)
 968 AC_SUBST(CONFIG_SCRIPTING_SPIDERMONKEY)
 969 AC_SUBST(CONFIG_SCRIPTING)
 970
 971
 972 # ===================================================================
 973 # Check for SSL support.
 974 # ===================================================================
 975
 976 # We by default use OpenSSL, and we always prefer it. However, when GNUTLS
 977 # is enabled, we won't try to use OpenSSL anymore.
 978
 979 # For wiping SSL hooks..
 980 #ifdef CONFIG_SSL
 981
 982 disable_openssl=""
 983 disable_gnutls=""
 984 enable_gnutls=""
 985
 986 AC_ARG_WITH(gnutls, [  --without-gnutls        disable GNUTLS SSL support],
 987             [if test "$with_gnutls" = no;  then disable_gnutls=yes; fi])
 988 AC_ARG_WITH(gnutls, [[  --with-gnutls[=DIR]     enable GNUTLS SSL support]],
 989             [if test "$with_gnutls" != no;  then enable_gnutls=yes; fi])
 990 gnutls_withval="$withval"
 991
 992 if test "$enable_gnutls" = yes; then
 993         disable_openssl=yes;
 994 fi
 995
 996 AC_ARG_WITH(openssl, [  --without-openssl       disable OpenSSL support],
 997             [if test "$with_openssl" = no;  then disable_openssl=yes; fi])
 998 AC_ARG_WITH(openssl, [[  --with-openssl[=DIR]    enable OpenSSL support (default)]])
 999 openssl_withval="$withval"
1000
1001 # ---- OpenSSL
1002
1003 AC_MSG_CHECKING([for OpenSSL])
1004
1005 EL_SAVE_FLAGS
1006 cf_result="no"
1007
1008 if test "$disable_openssl" = yes; then
1009         cf_result="not used"
1010 else
1011         for ssldir in "$openssl_withval" "" /usr /usr/local/openssl \
1012                          /usr/lib/openssl /usr/local/ssl \
1013                          /usr/local/www /usr/lib/ssl /usr/local \
1014                          /usr/pkg /opt /opt/openssl; do
1015                 if test "$cf_result" = no; then
1016                         if test -d "$ssldir"; then
1017                                 OPENSSL_CFLAGS="-I$ssldir/include"
1018                                 LIBS="-L$ssldir/lib -lssl -lcrypto $LIBS_X"
1019                                 CFLAGS="$CFLAGS_X $OPENSSL_CFLAGS"
1020                                 CPPFLAGS="$CPPFLAGS_X $OPENSSL_CFLAGS"
1021 #                               # FIXME: This created serious portability problems. --pasky
1022 #                               if test "$CC" == "gcc"; then
1023 #                                       # I'm not sure about compatibility here. --pasky
1024 #                                       LIBS="$LIBS -R$ssldir/lib"
1025 #                               fi
1026                         else
1027                                 LIBS="-lssl -lcrypto $LIBS_X"
1028                         fi
1029                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[OpenSSL_add_all_algorithms()]])],[cf_result=yes],[cf_result=no])
1030                         if test "$cf_result" != yes; then
1031                                 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <openssl/ssl.h>]], [[SSLeay_add_ssl_algorithms()]])],[cf_result=yes],[cf_result=no])
1032                         fi
1033                 fi
1034         done
1035
1036         if test "$cf_result" != yes; then
1037                 if test -n "$openssl_withval" && test "x$openssl_withval" != xno; then
1038                         AC_MSG_ERROR([OpenSSL not found])
1039                 fi
1040                 EL_RESTORE_FLAGS
1041         else
1042                 EL_CONFIG(CONFIG_OPENSSL, [OpenSSL])
1043
1044                 CFLAGS="$CFLAGS_X"
1045                 AC_SUBST(OPENSSL_CFLAGS)
1046         fi
1047 fi
1048
1049 AC_MSG_RESULT($cf_result)
1050
1051 CONFIG_GNUTLS_OPENSSL_COMPAT=no
1052 # ---- GNU TLS
1053 dnl We can't have AC_MSG_CHECKING here, because AC_PATH_PROG prints its own and
1054 dnl it looks ugly then.
1055
1056 if test "$cf_result" = yes; then
1057         cf_result="not used"
1058
1059 else
1060         EL_SAVE_FLAGS
1061         cf_result="no"
1062
1063         if test -z "$disable_gnutls"; then
1064                 # Sure, we maybe _could_ use their macro, but how to ensure
1065                 # that the ./configure script won't fail if the macro won't be
1066                 # found..? :( --pasky
1067
1068                 GNUTLS_PATH="$PATH:/usr/local/gnutls:/opt:/opt/gnutls"
1069
1070                 if test -d "$gnutls_withval"; then
1071                         GNUTLS_PATH="$gnutls_withval:$GNUTLS_PATH"
1072                 fi
1073
1074                 AC_PATH_PROG(LIBGNUTLS_CONFIG, libgnutls-config, no, $GNUTLS_PATH)
1075
1076                 if test "$LIBGNUTLS_CONFIG" = "no" ; then
1077                         cf_result=no
1078                 else
1079                         GNUTLS_CFLAGS=`$LIBGNUTLS_CONFIG --cflags`
1080                         GNUTLS_LIBS=`$LIBGNUTLS_CONFIG --libs`
1081
1082                         LIBS="$GNUTLS_LIBS $LIBS_X"
1083                         CFLAGS="$CFLAGS_X $GNUTLS_CFLAGS"
1084                         CPPFLAGS="$CPPFLAGS_X $GNUTLS_CFLAGS"
1085
1086                         # Verify if it's really usable.  gnutls_session was
1087                         # renamed to gnutls_session_t before GNU TLS 1.2.0
1088                         # (on 2004-06-13); ELinks now requires this.
1089                         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[gnutls_session_t dummy;
1090                                      gnutls_check_version(NULL)]])],[cf_result=yes],[cf_result=no])
1091                 fi
1092
1093                 if test "$cf_result" = yes; then
1094                         EL_CONFIG(CONFIG_GNUTLS, [GNUTLS])
1095
1096                         CFLAGS="$CFLAGS_X"
1097                         AC_SUBST(GNUTLS_CFLAGS)
1098
1099                         # GnuTLS 2.2.0 changed libgnutls-openssl from GPLv2+
1100                         # to GPLv3+.  Don't link that with the GPLv2 ELinks.
1101                         # ELinks will use its internal MD5 code instead.
1102                         CONFIG_GNUTLS_OPENSSL_COMPAT=no
1103                 else
1104                         if test -n "$gnutls_withval" && test "x$gnutls_withval" != xno; then
1105                                 AC_MSG_ERROR([GNUTLS (1.2 or later) not found.  ELinks no longer supports GNUTLS 1.1.])
1106                         fi
1107                         EL_RESTORE_FLAGS
1108                 fi
1109         fi
1110 fi
1111
1112 AC_MSG_CHECKING([for GNU TLS (1.2 or later)])
1113 AC_MSG_RESULT($cf_result)
1114
1115 # Final SSL setup
1116
1117 EL_CONFIG_DEPENDS(CONFIG_SSL, [CONFIG_OPENSSL CONFIG_GNUTLS], [SSL])
1118 AC_SUBST(CONFIG_GNUTLS_OPENSSL_COMPAT)
1119 AC_SUBST(CONFIG_OPENSSL)
1120 AC_SUBST(CONFIG_GNUTLS)
1121
1122 #endif
1123
1124 AC_MSG_CHECKING([whether to be or not to be])
1125 AC_MSG_RESULT([needs to be determined experimentally])
1126
1127 # ===================================================================
1128 # Check for IPv6 support and related functions.
1129 # ===================================================================
1130
1131 EL_CHECK_NET_TYPE(struct sockaddr_storage, HAVE_SA_STORAGE, [])
1132 EL_CHECK_NET_TYPE(struct sockaddr_in6, HAVE_SA_IN6, [#include <netinet/in.h>])
1133 EL_CHECK_NET_TYPE(struct addrinfo, HAVE_ADDRINFO, [#include <netdb.h>])
1134
1135 AC_CHECK_FUNC(getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1136 if test "$HAVE_GETADDRINFO" != yes; then
1137         AC_CHECK_LIB(inet6, getaddrinfo, HAVE_GETADDRINFO=yes, HAVE_GETADDRINFO=no)
1138         if test "$HAVE_GETADDRINFO" = yes; then
1139                 LIBS="$LIBS -linet6"
1140         fi
1141 fi
1142
1143
1144 # ===================================================================
1145 # Checking for X11 (window title restoring).
1146 # ===================================================================
1147
1148 AC_PATH_X
1149 if test x"$no_x" != xyes; then
1150         EL_SAVE_FLAGS
1151         if test -n "$x_includes"; then
1152                 X_CFLAGS="-I$x_includes"
1153                 CPPFLAGS="$CPPLAGS $X_CFLAGS"
1154                 CFLAGS="$CFLAGS $X_CFLAGS"
1155         fi
1156         if test -n "$x_libraries"; then
1157                 LDFLAGS="$LDFLAGS -L$x_libraries"
1158         fi
1159         LIBS="-lX11 $LIBS"
1160         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]], [[XrmInitialize()]])],[cf_result=yes],[cf_result=no])
1161         EL_RESTORE_FLAGS
1162         if test "$cf_result" = yes; then
1163                 if test -n "$x_libraries"; then
1164                         LDFLAGS="$LDFLAGS -L$x_libraries"
1165                 fi
1166                 LIBS="-lX11 $LIBS"
1167                 EL_DEFINE(HAVE_X11, [X11 for restoring window titles])
1168                 AC_SUBST(X_CFLAGS)
1169         fi
1170 fi
1171
1172
1173 # ===================================================================
1174 # Backtraces displaying support.
1175 # ===================================================================
1176
1177 AC_CHECK_HEADERS(execinfo.h, HAVE_EXECINFO=yes, HAVE_EXECINFO=no)
1178 # possible checks for other system-specific means go here
1179
1180
1181 # ===================================================================
1182 # Gettext grey zone. Beware.
1183 # ===================================================================
1184
1185 ALL_LINGUAS="af be bg ca cs da de el es et fi fr gl hr hu id is it lt nl nb pl pt pt_BR ro ru sk sr sv tr uk"
1186
1187 AM_GNU_GETTEXT
1188
1189 dnl AC_MSG_CHECKING([how many characters your English alphabet has])
1190 dnl # f33r d4 l33t... I hope it's portable. :)
1191 dnl cf_result=$((48#z - 48#a + 1));
1192 dnl AC_MSG_RESULT($cf_result)
1193
1194
1195 # ===================================================================
1196 # Compile-time features control
1197 # ===================================================================
1198
1199 EL_ARG_ENABLE(CONFIG_COOKIES, cookies, [Cookies],
1200               [  --disable-cookies       disable cookie support])
1201
1202 EL_ARG_ENABLE(CONFIG_FORMHIST, formhist, [Form history],
1203               [  --disable-formhist      disable form history support])
1204
1205 EL_ARG_ENABLE(CONFIG_GLOBHIST, globhist, [Global history],
1206               [  --disable-globhist      disable global history support])
1207
1208
1209 EL_ARG_ENABLE(CONFIG_MAILCAP, mailcap, [Mailcap],
1210               [  --disable-mailcap       disable mailcap support])
1211
1212 EL_ARG_ENABLE(CONFIG_MIMETYPES, mimetypes, [Mimetypes files],
1213               [  --disable-mimetypes     disable mimetypes files support])
1214
1215
1216 EL_ARG_DEPEND(CONFIG_IPV6, ipv6,
1217               [HAVE_SA_STORAGE:yes HAVE_SA_IN6:yes HAVE_ADDRINFO:yes HAVE_GETADDRINFO:yes],
1218               [IPv6],
1219               [  --disable-ipv6          disable IPv6 support])
1220
1221 EL_ARG_ENABLE(CONFIG_BITTORRENT, bittorrent, [BitTorrent protocol],
1222               [  --enable-bittorrent     enable BitTorrent protocol support])
1223
1224 EL_ARG_ENABLE(CONFIG_DATA, data, [Data protocol],
1225               [  --disable-data          disable data protocol support])
1226
1227 EL_ARG_ENABLE(CONFIG_URI_REWRITE, uri-rewrite, [URI rewriting],
1228               [  --disable-uri-rewrite   disable URI rewrite support])
1229
1230 EL_ARG_DEPEND(CONFIG_CGI, cgi, [HAVE_SETENV_OR_PUTENV:yes], [Local CGI],
1231               [  --enable-cgi            enable local CGI support])
1232
1233 EL_ARG_ENABLE(CONFIG_FINGER, finger, [Finger protocol],
1234               [  --enable-finger         enable finger protocol support])
1235
1236 # ===================================================================
1237 # FSP protocol
1238 # ===================================================================
1239 EL_SAVE_FLAGS
1240
1241 if test "x${enable_fsp}" != xno; then
1242         AC_CHECK_HEADERS(fsplib.h, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1243
1244         if test "$HAVE_FSPLIB" = yes; then
1245                 AC_CHECK_LIB(fsplib, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1246                 if test "$HAVE_FSPLIB" = yes; then
1247                         LIBS="$LIBS -lfsplib"
1248                 else
1249                         AC_CHECK_LIB(fsp, fsp_open_session, HAVE_FSPLIB=yes, HAVE_FSPLIB=no)
1250                         if test "$HAVE_FSPLIB" = yes; then
1251                                 LIBS="$LIBS -lfsp"
1252                         fi
1253                 fi
1254         fi
1255 fi
1256
1257 EL_ARG_DEPEND(CONFIG_FSP, fsp, [HAVE_FSPLIB:yes], [FSP protocol],
1258               [  --enable-fsp            enable FSP protocol support])
1259
1260 if test "x$CONFIG_FSP" = xno; then
1261         EL_RESTORE_FLAGS
1262 fi
1263
1264 EL_ARG_ENABLE(CONFIG_FTP, ftp, [FTP protocol],
1265               [  --disable-ftp           disable ftp protocol support])
1266
1267 EL_ARG_ENABLE(CONFIG_GOPHER, gopher, [Gopher protocol],
1268               [  --enable-gopher         enable gopher protocol support])
1269
1270 EL_ARG_ENABLE(CONFIG_NNTP, nntp, [NNTP protocol],
1271               [  --enable-nntp           enable nntp protocol support])
1272
1273 # ===================================================================
1274 # SMB protocol support.
1275 # ===================================================================
1276 EL_SAVE_FLAGS
1277
1278 if test "x${enable_smb}" != xno; then
1279         AC_CHECK_HEADERS(libsmbclient.h, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1280
1281         if test "$HAVE_SMBCLIENT" = yes; then
1282                 AC_CHECK_LIB(smbclient, smbc_init, HAVE_SMBCLIENT=yes, HAVE_SMBCLIENT=no)
1283                 if test "$HAVE_SMBCLIENT" = yes; then
1284                         LIBS="$LIBS -lsmbclient"
1285                 fi
1286         fi
1287 fi
1288
1289 EL_ARG_DEPEND(CONFIG_SMB, smb, [HAVE_SMBCLIENT:yes], [Samba protocol],
1290               [  --enable-smb            enable Samba protocol support])
1291
1292 if test "x$CONFIG_SMB" = xno; then
1293         EL_RESTORE_FLAGS
1294 fi
1295
1296
1297 EL_ARG_ENABLE(CONFIG_MOUSE, mouse, [Mouse handling],
1298               [  --disable-mouse         disable mouse support])
1299
1300 # GPM mouse is Linux specific, so ...
1301 CONFIG_SYSMOUSE=yes
1302 EL_ARG_DEPEND(CONFIG_SYSMOUSE, sysmouse,
1303               [CONFIG_MOUSE:yes CONFIG_GPM:no HAVE_SYSMOUSE_HEADER:yes],
1304               [BSD sysmouse],
1305               [  --disable-sysmouse      disable BSD sysmouse support])
1306
1307 EL_ARG_ENABLE(CONFIG_88_COLORS, 88-colors, [88 colors],
1308               [  --enable-88-colors      enable 88 color support])
1309
1310 EL_ARG_ENABLE(CONFIG_256_COLORS, 256-colors, [256 colors],
1311               [  --enable-256-colors     enable 256 color support])
1312
1313 EL_ARG_ENABLE(CONFIG_TRUE_COLOR, true-color, [true color],
1314               [  --enable-true-color     enable true color support])
1315
1316 EL_ARG_ENABLE(CONFIG_EXMODE, exmode, [Exmode interface],
1317               [  --enable-exmode         enable exmode (CLI) interface])
1318
1319 EL_ARG_ENABLE(CONFIG_LEDS, leds, [LEDs],
1320               [  --disable-leds          disable LEDs support])
1321
1322 EL_ARG_ENABLE(CONFIG_MARKS, marks, [Marks],
1323               [  --disable-marks         disable document marks support])
1324
1325
1326 EL_ARG_ENABLE(CONFIG_CSS, css, [Cascading Style Sheets],
1327               [  --disable-css           disable Cascading Style Sheet support])
1328
1329 EL_ARG_DEPEND(CONFIG_HTML_HIGHLIGHT, html-highlight, [CONFIG_CSS:yes], [HTML highlighting],
1330               [  --enable-html-highlight HTML highlighting using DOM engine])
1331
1332 # Everything in the tree already uses CONFIG_DOM
1333 # so resolve CONFIG_HTML_HIGHLIGHT to CONFIG_DOM
1334 EL_CONFIG_DEPENDS(CONFIG_DOM, [CONFIG_HTML_HIGHLIGHT], [DOM engine])
1335
1336 EL_ARG_DEPEND(CONFIG_BACKTRACE, backtrace, [HAVE_EXECINFO:yes], [Backtrace],
1337               [  --disable-backtrace     disable backtrace support])
1338
1339 EL_ARG_DEPEND(CONFIG_NO_ROOT_EXEC, no-root, [HAVE_GETUID:yes HAVE_GETEUID:yes], [No root exec],
1340               [  --enable-no-root        enable prevention of usage by root])
1341
1342
1343 EL_ARG_ENABLE(CONFIG_DEBUG, debug, [Debug mode],
1344               [  --enable-debug          enable leak debug and internal error checking])
1345
1346 EL_ARG_DEPEND(CONFIG_FASTMEM, fastmem, [CONFIG_DEBUG:no], [Fast mode],
1347               [  --enable-fastmem        enable direct use of system allocation functions, not usable with --enable-debug])
1348
1349 EL_ARG_ENABLE(CONFIG_OWN_LIBC, own-libc, [Own libc stubs],
1350               [  --enable-own-libc       force use of internal functions instead of those of system libc])
1351
1352 EL_ARG_ENABLE(CONFIG_SMALL, small, [Small binary],
1353               [  --enable-small          reduce binary size as far as possible (but see the bottom of doc/small.txt!)])
1354
1355 EL_ARG_ENABLE(CONFIG_UTF8, utf-8, [UTF-8],
1356               [  --disable-utf-8         disable UTF-8 support])
1357
1358
1359 AC_ARG_ENABLE(weehoofooboomookerchoo,
1360               [
1361     Also check out the features.conf file for more information about features!
1362               ],
1363               [AC_MSG_ERROR(Are you strange, or what?)])
1364
1365
1366 # ===================================================================
1367 # Further LDFLAGS tweaks
1368 # ===================================================================
1369
1370 # == EMX hack
1371
1372 test "$CONFIG_OS_OS2" = yes && LDFLAGS="$LDFLAGS -Zexe"
1373 test "$CONFIG_OS_OS2" = yes && LDFLAGS=`echo "$LDFLAGS" | sed "s/-Zbin-files//g"`
1374
1375
1376 # Check for -rdynamic
1377 #
1378 # gcc -rdynamic calls ld -export-dynamic, which adds all symbols of
1379 # the executable to its dynamic symbol table.  ELinks uses this for
1380 # two purposes:
1381 #
1382 # 1. If ELinks detects a bug, it can try to display a backtrace by
1383 #    calling backtrace_symbols_fd() in the GNU libc.  The glibc-2.3.6
1384 #    manual states users of GNU ld must pass -rdynamic to make the
1385 #    symbols available to the program.
1386 #
1387 # 2. It would eventually be nice to dynamically load shared
1388 #    libraries as plugins (bug 73).  The plugins must be able to
1389 #    call ELinks functions.  This can be implemented either by
1390 #    registering all callable functions in ELinks-specific data
1391 #    structures, or by letting the dynamic linker handle them.
1392 #    The latter way requires something equivalent to -rdynamic.
1393 #
1394 # Because backtraces are not needed for correct operation, and bug
1395 # 73 is not yet being fixed, the configure script and makefiles
1396 # should not complain to the user if they find that -rdynamic does
1397 # not work.  Besides, it was reported at elinks-users on 2006-09-12
1398 # that gcc-3.4.2 with "ld: Software Generation Utilities - Solaris
1399 # Link Editors: 5.8-1.284" on Sun Solaris 8 Sparc does not support
1400 # -rdynamic but does something equivalent automatically.  (This was
1401 # tested with "nm -D elinks | grep redraw_from_window".)
1402 #
1403 # With Sun Studio 11 on Solaris 9, we get "cc: Warning: illegal option
1404 # -dynamic"; then, cc proceeds anyway, but the option can prevent the
1405 # linker from finding the libraries listed in -l operands.  So this
1406 # -rdynamic check needs to happen after the libraries have already
1407 # been added to $LDFLAGS.
1408 AC_MSG_CHECKING([for -rdynamic])
1409 LDFLAGS_X="$LDFLAGS"
1410 LDFLAGS="-rdynamic $LDFLAGS"
1411 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[]])],[have_rdynamic=yes],[have_rdynamic=no])
1412 test "$have_rdynamic" = no && LDFLAGS="$LDFLAGS_X"
1413 AC_MSG_RESULT($have_rdynamic)
1414
1415 # ===================================================================
1416 # Export directory paths
1417 # ===================================================================
1418
1419 # Set up the ``entry points'' if they were not supplied by builder
1420 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1421 test "x$exec_prefix" = xNONE && exec_prefix=${prefix}
1422
1423 # Create CONFDIR #define for config.h
1424
1425 # XXX: This may be dependent on a particular version of autoconf. Whatever,
1426 # it's autoconf fault to force us to do such hacks ;p.
1427 if test x"$sysconfdir" = x"\${prefix}/etc"; then
1428   # sysconfdir is set to its default value... fine, let's append /elinks/
1429   # XXX: We can't modify listing of the default in ./configure --help :-(
1430   sysconfdir_n=`eval echo "$sysconfdir"`
1431   sysconfdir=$sysconfdir_n
1432   (echo "$sysconfdir" | grep elinks >/dev/null 2>/dev/null) || \
1433         sysconfdir="$sysconfdir/elinks"
1434 fi
1435
1436 CONFDIR=$sysconfdir
1437 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR", [Directory containing default config])
1438 AC_SUBST(CONFDIR)
1439
1440 # Create LOCALEDIR #define for config.h
1441 LOCALEDIR=`eval echo "$datadir/locale"`
1442 while echo "$LOCALEDIR" | grep "\\$"
1443 do
1444         LOCALEDIR=`eval echo "$LOCALEDIR"`
1445 done > /dev/null 2> /dev/null
1446 AC_DEFINE_UNQUOTED(LOCALEDIR, "$LOCALEDIR", [Directory containing locales])
1447 AC_SUBST(LOCALEDIR)
1448
1449 # Create LIBDIR #define for config.h
1450 LIBDIR=`eval echo "$libdir"`
1451 AC_DEFINE_UNQUOTED(LIBDIR, "$LIBDIR", [Directory containing libraries])
1452 AC_SUBST(LIBDIR)
1453
1454 EL_LOG_CONFIG(CONFDIR, [System configuration directory], [])
1455 EL_LOG_CONFIG(LOCALEDIR, [Locale catalogs directory], [])
1456
1457
1458 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stddef.h>
1459 ]], [[#if !defined(__TINYC__) || !defined(alloca)
1460         #error not tcc
1461         #endif ]])],[cf_result=yes],[cf_result=no])
1462
1463 if test "$cf_result" = "yes"; then
1464         AC_DEFINE([HAVE_ALLOCA])
1465         AC_DEFINE([_ALLOCA_H], [1], [Define as 1 if you are using Tiny C Compiler
1466                 with the GNU C Library, and <alloca.h> of glibc would otherwise
1467                 override the alloca macro defined in <stddef.h> of TCC.
1468                 If <alloca.h> of glibc sees the _ALLOCA_H macro, it assumes
1469                 it has already been included, and does not redefine alloca.
1470                 This might not work in future glibc versions though, because
1471                 the names of the #include guard macros are not documented.
1472                 The incompatibility has been reported to the tinycc-devel
1473                 mailing list on 2008-07-14.  If a future version of TCC provides
1474                 an <alloca.h> of its own, this hack won't be needed.])
1475 fi
1476 # ===================================================================
1477 # A little fine tuning of gcc specific options (continued)
1478 # ===================================================================
1479
1480 if test "x$ac_cv_c_compiler_gnu" = "xyes"; then
1481   if test "$CONFIG_DEBUG" = "yes"; then
1482     # We want to see all warnings and live with none (in debug mode).
1483     CFLAGS="$CFLAGS -Werror"
1484   fi
1485
1486   case "`$CC -dumpversion`" in
1487     3.0|3.1|3.2)
1488       # These should be ok using -Werror
1489       ;;
1490     3.*)
1491       # If gcc is version 3.3 (or higher?) it emits lots of false positive
1492       # "dereferencing type-punned pointer will break strict-aliasing rules"
1493       # warnings. Disable them by not doing any strict-aliasing. The
1494       # alternative is just too ugly. Thanks gcc guys!! ;)
1495       CFLAGS="$CFLAGS -fno-strict-aliasing"
1496       ;;
1497     4.*)
1498       # Do not show warnings related to (char * | unsigned char *) type
1499       # difference.
1500       CFLAGS="$CFLAGS -fno-strict-aliasing -Wno-pointer-sign"
1501       ;;
1502     *)
1503       # These should be ok using -Werror
1504       ;;
1505   esac
1506
1507   # GCC 4.2.1 warns if we use the address of an object in Boolean context:
1508   # warning: the address of `builtin_modules' will always evaluate as `true'
1509   # This hits the object_lock and foreach_module macros in particular.
1510   # It would be okay to put something in the macros to avoid the warning,
1511   # but currently this seems to require defining parallel macros that skip
1512   # the NULL check, and that's too ugly.  So we instead disable the warning.
1513   # GCC 4.2.1 needs -Wno-address, but GCC 4.2 snapshots need -Wno-always-true.
1514   # GCC 4.1.3 recognizes neither and exits with code 1 if they are given.
1515   for warning_flag in -Wno-address -Wno-always-true; do
1516     AC_MSG_CHECKING([whether $CC accepts $warning_flag])
1517     EL_SAVE_FLAGS
1518     CFLAGS="$CFLAGS $warning_flag"
1519     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1520       [AC_MSG_RESULT([yes])
1521        break],
1522       [AC_MSG_RESULT([no])])
1523     EL_RESTORE_FLAGS
1524   done
1525
1526   # Bug 1012: Some parts of ELinks do arithmetic with signed integers
1527   # in such a way that an overflow is possible.  GCC 4.2.1 warns
1528   # "warning: assuming signed overflow does not occur when assuming
1529   # that (X + c) > X is always true", which may be an incorrect
1530   # optimization (although allowed by the standard), and breaks the
1531   # build with -Werror.
1532   #
1533   # All of the following tests included -S -Wall -Wextra:
1534   #
1535   # GCC: (GNU) 4.0.4 20060507 (prerelease) (Debian 4.0.3-3)
1536   # * gcc-4.0 -O0: OK, compares the values
1537   # * gcc-4.0 -O2: assumes no overflow, does not warn
1538   # * gcc-4.0 -O0 -fno-strict-overflow: unrecognized command line option
1539   # * gcc-4.0 -O0 -fwrapv: OK, compares the values
1540   # * gcc-4.0 -O2 -fwrapv: OK, compares the values
1541   # * gcc-4.0 -O0 -ftrapv: OK, calls __addvsi3
1542   # * gcc-4.0 -O2 -ftrapv: assumes no overflow, does not warn
1543   # * gcc-4.0 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1544   # * gcc-4.0 -O2 -fwrapv -ftrapv: compares the values
1545   #
1546   # GCC: (GNU) 4.1.3 20070812 (prerelease) (Debian 4.1.2-15)
1547   # * gcc-4.1 -O0: assumes no overflow, does not warn
1548   # * gcc-4.1 -O2: assumes no overflow, does not warn
1549   # * gcc-4.1 -O0 -fno-strict-overflow: unrecognized command line option
1550   # * gcc-4.1 -O0 -fwrapv: OK, compares the values
1551   # * gcc-4.1 -O2 -fwrapv: OK, compares the values
1552   # * gcc-4.1 -O0 -ftrapv: OK, calls __addvsi3
1553   # * gcc-4.1 -O2 -ftrapv: compares the values
1554   # * gcc-4.1 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1555   # * gcc-4.1 -O2 -fwrapv -ftrapv: compares the values
1556   #
1557   # GCC: (GNU) 4.2.1 (Debian 4.2.1-5)
1558   # * gcc-4.2 -O0: OK, compares the values
1559   # * gcc-4.2 -O2: assumes no overflow, warns about it
1560   # * gcc-4.2 -O0 -fno-strict-overflow: OK, compares the values
1561   # * gcc-4.2 -O2 -fno-strict-overflow: OK, compares the values
1562   # * gcc-4.2 -O0 -fwrapv: OK, compares the values
1563   # * gcc-4.2 -O2 -fwrapv: OK, compares the values
1564   # * gcc-4.2 -O0 -ftrapv: OK, calls __addvsi3
1565   # * gcc-4.2 -O2 -ftrapv: compares the values
1566   # * gcc-4.2 -O0 -fwrapv -ftrapv: OK, calls __addvsi3
1567   # * gcc-4.2 -O2 -fwrapv -ftrapv: compares the values
1568   #
1569   # Apparently, -ftrapv does not work reliably at all.
1570   for overflow_flag in -fno-strict-overflow -fwrapv; do
1571     AC_MSG_CHECKING([whether $CC accepts $overflow_flag])
1572     EL_SAVE_FLAGS
1573     CFLAGS="$CFLAGS $overflow_flag"
1574     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1575       [AC_MSG_RESULT([yes])
1576        break],
1577       [AC_MSG_RESULT([no])])
1578     EL_RESTORE_FLAGS
1579   done
1580 fi
1581
1582 EL_LOG_CONFIG(CFLAGS, [Compiler flags (CFLAGS)], [])
1583 EL_LOG_CONFIG(CPPFLAGS, [Preprocessor flags (CPPFLAGS)], [])
1584 EL_LOG_CONFIG(LDFLAGS, [Linker flags (LDFLAGS)], [])
1585 EL_LOG_CONFIG(LIBS, [Library flags (LIBS)], [])
1586
1587 # ===================================================================
1588 # Colored make output
1589 # ===================================================================
1590
1591 if test $(`which tput` colors) -ge 4; then
1592         MAKE_COLOR=1
1593         AC_SUBST(MAKE_COLOR)
1594 fi
1595
1596 # ===================================================================
1597 # Generated files
1598 # ===================================================================
1599
1600 AC_CONFIG_FILES([ \
1601  Makefile.config \
1602  contrib/elinks.spec \
1603  contrib/lua/hooks.lua \
1604  contrib/conv/w3m2links.awk \
1605  doc/Doxyfile \
1606  doc/man/man1/elinks.1 \
1607  src/intl/gettext/ref-add.sed \
1608  src/intl/gettext/ref-del.sed
1609 ])
1610 AC_OUTPUT
1611
1612 abs_srcdir="$(cd "$srcdir" && pwd)"
1613 # builddir is always absolute!
1614 if test "$abs_srcdir" != "$builddir"; then
1615         # Bootstrap the Makefile creation
1616         echo "include $abs_srcdir/Makefile" > "$builddir/Makefile"
1617         "$MAKE" "SRC=$abs_srcdir" init
1618
1619         # Make cg-status ignore this build directory
1620         echo "*" > "$builddir/.gitignore"
1621 fi
1622
1623 # ===================================================================
1624 # Configuration summary
1625 # ===================================================================
1626
1627 AC_MSG_RESULT(The following feature summary has been saved to features.log)
1628 cat features.log